qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "playerdemo.qh"
  14 #include "spawnpoints.qh"
  15 #include "resources.qh"
  16 #include "g_damage.qh"
  17 #include "handicap.qh"
  18 #include "g_hook.qh"
  19 #include "command/common.qh"
  20 #include "cheats.qh"
  21 #include "g_world.qh"
  22 #include "race.qh"
  23 #include "antilag.qh"
  24 #include "campaign.qh"
  25 #include "command/common.qh"
  26 #include "scores_rules.qh"
  27
  28 #include "bot/api.qh"
  29
  30 #include "../common/ent_cs.qh"
  31 #include "../common/wepent.qh"
  32 #include <common/state.qh>
  33
  34 #include <common/effects/qc/globalsound.qh>
  35
  36 #include "../common/triggers/func/conveyor.qh"
  37 #include "../common/triggers/teleporters.qh"
  38 #include "../common/triggers/target/spawnpoint.qh"
  39
  40 #include "../common/vehicles/all.qh"
  41
  42 #include "weapons/hitplot.qh"
  43 #include "weapons/weaponsystem.qh"
  44
  45 #include "../common/net_notice.qh"
  46 #include "../common/net_linked.qh"
  47 #include "../common/physics/player.qh"
  48
  49 #include "../common/items/_mod.qh"
  50
  51 #include "../common/mutators/mutator/waypoints/all.qh"
  52
  53 #include "../common/triggers/subs.qh"
  54 #include "../common/triggers/triggers.qh"
  55 #include "../common/triggers/trigger/secret.qh"
  56
  57 #include "../common/minigames/sv_minigames.qh"
  58
  59 #include "../common/items/inventory.qh"
  60
  61 #include "../common/monsters/sv_monsters.qh"
  62
  63 #include "../lib/warpzone/server.qh"
  64
  65 STATIC_METHOD(Client, Add, void(Client this, int _team))
  66 {
  67     ClientConnect(this);
  68     TRANSMUTE(Player, this);
  69     this.frame = 12; // 7
  70     this.team = _team;
  71     PutClientInServer(this);
  72 }
  73
  74 void PutObserverInServer(entity this);
  75
  76 STATIC_METHOD(Client, Remove, void(Client this))
  77 {
  78     TRANSMUTE(Observer, this);
  79     PutClientInServer(this);
  80     ClientDisconnect(this);
  81 }
  82
  83 void send_CSQC_teamnagger() {
  84         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  85 }
  86
  87 int CountSpectators(entity player, entity to)
  88 {
  89         if(!player) { return 0; } // not sure how, but best to be safe
  90
  91         int spec_count = 0;
  92
  93         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  94         {
  95                 spec_count++;
  96         });
  97
  98         return spec_count;
  99 }
 100
 101 void WriteSpectators(entity player, entity to)
 102 {
 103         if(!player) { return; } // not sure how, but best to be safe
 104
 105         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 106         {
 107                 WriteByte(MSG_ENTITY, num_for_edict(it));
 108         });
 109 }
 110
 111 bool ClientData_Send(entity this, entity to, int sf)
 112 {
 113         assert(to == this.owner, return false);
 114
 115         entity e = to;
 116         if (IS_SPEC(e)) e = e.enemy;
 117
 118         sf = 0;
 119         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 120         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 121         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 122         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 123
 124         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 125         WriteByte(MSG_ENTITY, sf);
 126
 127         if (sf & BIT(1))
 128                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 129
 130         if(sf & BIT(4))
 131         {
 132                 float specs = CountSpectators(e, to);
 133                 WriteByte(MSG_ENTITY, specs);
 134                 WriteSpectators(e, to);
 135         }
 136
 137         return true;
 138 }
 139
 140 void ClientData_Attach(entity this)
 141 {
 142         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 143         CS(this).clientdata.drawonlytoclient = this;
 144         CS(this).clientdata.owner = this;
 145 }
 146
 147 void ClientData_Detach(entity this)
 148 {
 149         delete(CS(this).clientdata);
 150         CS(this).clientdata = NULL;
 151 }
 152
 153 void ClientData_Touch(entity e)
 154 {
 155         CS(e).clientdata.SendFlags = 1;
 156
 157         // make it spectatable
 158         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, { CS(it).clientdata.SendFlags = 1; });
 159 }
 160
 161 void SetSpectatee(entity this, entity spectatee);
 162 void SetSpectatee_status(entity this, int spectatee_num);
 163
 164
 165 /*
 166 =============
 167 CheckPlayerModel
 168
 169 Checks if the argument string can be a valid playermodel.
 170 Returns a valid one in doubt.
 171 =============
 172 */
 173 string FallbackPlayerModel;
 174 string CheckPlayerModel(string plyermodel) {
 175         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 176         {
 177                 // note: we cannot summon Don Strunzone here, some player may
 178                 // still have the model string set. In case anyone manages how
 179                 // to change a cvar default, we'll have a small leak here.
 180                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 181         }
 182         // only in right path
 183         if( substring(plyermodel,0,14) != "models/player/")
 184                 return FallbackPlayerModel;
 185         // only good file extensions
 186         if(substring(plyermodel,-4,4) != ".zym")
 187         if(substring(plyermodel,-4,4) != ".dpm")
 188         if(substring(plyermodel,-4,4) != ".iqm")
 189         if(substring(plyermodel,-4,4) != ".md3")
 190         if(substring(plyermodel,-4,4) != ".psk")
 191                 return FallbackPlayerModel;
 192         // forbid the LOD models
 193         if(substring(plyermodel, -9,5) == "_lod1")
 194                 return FallbackPlayerModel;
 195         if(substring(plyermodel, -9,5) == "_lod2")
 196                 return FallbackPlayerModel;
 197         if(plyermodel != strtolower(plyermodel))
 198                 return FallbackPlayerModel;
 199         // also, restrict to server models
 200         if(autocvar_sv_servermodelsonly)
 201         {
 202                 if(!fexists(plyermodel))
 203                         return FallbackPlayerModel;
 204         }
 205         return plyermodel;
 206 }
 207
 208 void setplayermodel(entity e, string modelname)
 209 {
 210         precache_model(modelname);
 211         _setmodel(e, modelname);
 212         player_setupanimsformodel(e);
 213         if(!autocvar_g_debug_globalsounds)
 214                 UpdatePlayerSounds(e);
 215 }
 216
 217 void FixPlayermodel(entity player);
 218 /** putting a client as observer in the server */
 219 void PutObserverInServer(entity this)
 220 {
 221     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 222         PlayerState_detach(this);
 223
 224         if (IS_PLAYER(this))
 225         {
 226                 if(this.health >= 1)
 227                 {
 228                         // despawn effect
 229                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 230                 }
 231
 232                 // was a player, recount votes and ready status
 233                 if(IS_REAL_CLIENT(this))
 234                 {
 235                         if (vote_called) { VoteCount(false); }
 236                         ReadyCount();
 237                 }
 238     }
 239
 240     {
 241         entity spot = SelectSpawnPoint(this, true);
 242         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 243         this.angles = vec2(spot.angles);
 244         this.fixangle = true;
 245         // offset it so that the spectator spawns higher off the ground, looks better this way
 246         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 247         if (IS_REAL_CLIENT(this))
 248         {
 249             msg_entity = this;
 250             WriteByte(MSG_ONE, SVC_SETVIEW);
 251             WriteEntity(MSG_ONE, this);
 252         }
 253         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 254         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 255         if(!autocvar_g_debug_globalsounds)
 256         {
 257                 // needed for player sounds
 258                 this.model = "";
 259                 FixPlayermodel(this);
 260         }
 261         setmodel(this, MDL_Null);
 262         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 263         this.view_ofs = '0 0 0';
 264     }
 265
 266     RemoveGrapplingHooks(this);
 267         Portal_ClearAll(this);
 268         Unfreeze(this);
 269         SetSpectatee(this, NULL);
 270
 271         if (this.alivetime)
 272         {
 273                 if (!warmup_stage)
 274                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 275                 this.alivetime = 0;
 276         }
 277
 278         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 279
 280         WaypointSprite_PlayerDead(this);
 281
 282         if (mutator_returnvalue) {
 283             // mutator prevents resetting teams+score
 284         } else {
 285                 int old_team_index = Team_TeamToIndex(this.team);
 286                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 287                 MUTATOR_CALLHOOK(Player_ChangedTeam, this, old_team_index, -1);
 288         this.frags = FRAGS_SPECTATOR;
 289         PlayerScore_Clear(this);  // clear scores when needed
 290     }
 291
 292         if (CS(this).killcount != FRAGS_SPECTATOR)
 293         {
 294                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 295                 if(!game_stopped)
 296                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 297                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 298
 299                 if(!CS(this).just_joined)
 300                         LogTeamchange(this.playerid, -1, 4);
 301                 else
 302                         CS(this).just_joined = false;
 303         }
 304
 305         accuracy_resend(this);
 306
 307         CS(this).spectatortime = time;
 308         if(this.bot_attack)
 309                 IL_REMOVE(g_bot_targets, this);
 310         this.bot_attack = false;
 311         if(this.monster_attack)
 312                 IL_REMOVE(g_monster_targets, this);
 313         this.monster_attack = false;
 314     STAT(HUD, this) = HUD_NORMAL;
 315         TRANSMUTE(Observer, this);
 316         this.iscreature = false;
 317         this.teleportable = TELEPORT_SIMPLE;
 318         if(this.damagedbycontents)
 319                 IL_REMOVE(g_damagedbycontents, this);
 320         this.damagedbycontents = false;
 321         this.health = FRAGS_SPECTATOR;
 322         SetSpectatee_status(this, etof(this));
 323         this.takedamage = DAMAGE_NO;
 324         this.solid = SOLID_NOT;
 325         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 326         this.flags = FL_CLIENT | FL_NOTARGET;
 327         this.armorvalue = 666;
 328         this.effects = 0;
 329         this.armorvalue = autocvar_g_balance_armor_start;
 330         this.pauserotarmor_finished = 0;
 331         this.pauserothealth_finished = 0;
 332         this.pauseregen_finished = 0;
 333         this.damageforcescale = 0;
 334         this.death_time = 0;
 335         this.respawn_flags = 0;
 336         this.respawn_time = 0;
 337         STAT(RESPAWN_TIME, this) = 0;
 338         this.alpha = 0;
 339         this.scale = 0;
 340         this.fade_time = 0;
 341         this.pain_frame = 0;
 342         this.pain_finished = 0;
 343         this.strength_finished = 0;
 344         this.invincible_finished = 0;
 345         this.superweapons_finished = 0;
 346         this.dphitcontentsmask = 0;
 347         this.pushltime = 0;
 348         this.istypefrag = 0;
 349         setthink(this, func_null);
 350         this.nextthink = 0;
 351         this.deadflag = DEAD_NO;
 352         this.crouch = false;
 353         STAT(REVIVE_PROGRESS, this) = 0;
 354         this.revival_time = 0;
 355
 356         this.items = 0;
 357         this.weapons = '0 0 0';
 358         this.drawonlytoclient = this;
 359
 360         this.viewloc = NULL;
 361
 362         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 363
 364         this.weaponmodel = "";
 365         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 366         {
 367                 this.weaponentities[slot] = NULL;
 368         }
 369         this.exteriorweaponentity = NULL;
 370         CS(this).killcount = FRAGS_SPECTATOR;
 371         this.velocity = '0 0 0';
 372         this.avelocity = '0 0 0';
 373         this.punchangle = '0 0 0';
 374         this.punchvector = '0 0 0';
 375         this.oldvelocity = this.velocity;
 376         this.fire_endtime = -1;
 377         this.event_damage = func_null;
 378
 379         for(int slot = 0; slot < MAX_AXH; ++slot)
 380         {
 381                 entity axh = this.(AuxiliaryXhair[slot]);
 382                 this.(AuxiliaryXhair[slot]) = NULL;
 383
 384                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 385                         delete(axh);
 386         }
 387 }
 388
 389 int player_getspecies(entity this)
 390 {
 391         get_model_parameters(this.model, this.skin);
 392         int s = get_model_parameters_species;
 393         get_model_parameters(string_null, 0);
 394         if (s < 0) return SPECIES_HUMAN;
 395         return s;
 396 }
 397
 398 .float model_randomizer;
 399 void FixPlayermodel(entity player)
 400 {
 401         string defaultmodel = "";
 402         int defaultskin = 0;
 403         if(autocvar_sv_defaultcharacter)
 404         {
 405                 if(teamplay)
 406                 {
 407                         switch(player.team)
 408                         {
 409                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 410                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 411                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 412                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 413                         }
 414                 }
 415
 416                 if(defaultmodel == "")
 417                 {
 418                         defaultmodel = autocvar_sv_defaultplayermodel;
 419                         defaultskin = autocvar_sv_defaultplayerskin;
 420                 }
 421
 422                 int n = tokenize_console(defaultmodel);
 423                 if(n > 0)
 424                 {
 425                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 426                         // However, do NOT randomize if the player-selected model is in the list.
 427                         for (int i = 0; i < n; ++i)
 428                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 429                                         defaultmodel = argv(i);
 430                 }
 431
 432                 int i = strstrofs(defaultmodel, ":", 0);
 433                 if(i >= 0)
 434                 {
 435                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 436                         defaultmodel = substring(defaultmodel, 0, i);
 437                 }
 438         }
 439         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 440         {
 441                 if(teamplay)
 442                 {
 443                         switch(player.team)
 444                         {
 445                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 446                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 447                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 448                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 449                         }
 450                 }
 451
 452                 if(!defaultskin)
 453                         defaultskin = autocvar_sv_defaultplayerskin;
 454         }
 455
 456         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 457         defaultmodel = M_ARGV(0, string);
 458         defaultskin = M_ARGV(1, int);
 459
 460         bool chmdl = false;
 461         int oldskin;
 462         if(defaultmodel != "")
 463         {
 464                 if (defaultmodel != player.model)
 465                 {
 466                         vector m1 = player.mins;
 467                         vector m2 = player.maxs;
 468                         setplayermodel (player, defaultmodel);
 469                         setsize (player, m1, m2);
 470                         chmdl = true;
 471                 }
 472
 473                 oldskin = player.skin;
 474                 player.skin = defaultskin;
 475         } else {
 476                 if (player.playermodel != player.model || player.playermodel == "")
 477                 {
 478                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 479                         vector m1 = player.mins;
 480                         vector m2 = player.maxs;
 481                         setplayermodel (player, player.playermodel);
 482                         setsize (player, m1, m2);
 483                         chmdl = true;
 484                 }
 485
 486                 if(!autocvar_sv_defaultcharacterskin)
 487                 {
 488                         oldskin = player.skin;
 489                         player.skin = stof(player.playerskin);
 490                 }
 491                 else
 492                 {
 493                         oldskin = player.skin;
 494                         player.skin = defaultskin;
 495                 }
 496         }
 497
 498         if(chmdl || oldskin != player.skin) // model or skin has changed
 499         {
 500                 player.species = player_getspecies(player); // update species
 501                 if(!autocvar_g_debug_globalsounds)
 502                         UpdatePlayerSounds(player); // update skin sounds
 503         }
 504
 505         if(!teamplay)
 506                 if(strlen(autocvar_sv_defaultplayercolors))
 507                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 508                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 509 }
 510
 511 void PutPlayerInServer(entity this)
 512 {
 513         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 514
 515         PlayerState_attach(this);
 516         accuracy_resend(this);
 517
 518         if (this.team < 0)
 519                 TeamBalance_JoinBestTeam(this, true);
 520
 521         entity spot = SelectSpawnPoint(this, false);
 522         if (!spot) {
 523                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 524                 return; // spawn failed
 525         }
 526
 527         TRANSMUTE(Player, this);
 528
 529         CS(this).wasplayer = true;
 530         this.iscreature = true;
 531         this.teleportable = TELEPORT_NORMAL;
 532         if(!this.damagedbycontents)
 533                 IL_PUSH(g_damagedbycontents, this);
 534         this.damagedbycontents = true;
 535         set_movetype(this, MOVETYPE_WALK);
 536         this.solid = SOLID_SLIDEBOX;
 537         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 538         if (autocvar_g_playerclip_collisions)
 539                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 540         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 541                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 542         this.frags = FRAGS_PLAYER;
 543         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 544         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 545         if (autocvar__notarget)
 546                 this.flags |= FL_NOTARGET;
 547         this.takedamage = DAMAGE_AIM;
 548         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 549
 550         if (warmup_stage) {
 551                 this.ammo_shells = warmup_start_ammo_shells;
 552                 this.ammo_nails = warmup_start_ammo_nails;
 553                 this.ammo_rockets = warmup_start_ammo_rockets;
 554                 this.ammo_cells = warmup_start_ammo_cells;
 555                 this.ammo_plasma = warmup_start_ammo_plasma;
 556                 this.ammo_fuel = warmup_start_ammo_fuel;
 557                 this.health = warmup_start_health;
 558                 this.armorvalue = warmup_start_armorvalue;
 559                 this.weapons = WARMUP_START_WEAPONS;
 560         } else {
 561                 this.ammo_shells = start_ammo_shells;
 562                 this.ammo_nails = start_ammo_nails;
 563                 this.ammo_rockets = start_ammo_rockets;
 564                 this.ammo_cells = start_ammo_cells;
 565                 this.ammo_plasma = start_ammo_plasma;
 566                 this.ammo_fuel = start_ammo_fuel;
 567                 this.health = start_health;
 568                 this.armorvalue = start_armorvalue;
 569                 this.weapons = start_weapons;
 570                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 571                 {
 572                         GiveRandomWeapons(this, random_start_weapons_count,
 573                                 autocvar_g_random_start_weapons, random_start_ammo);
 574                 }
 575         }
 576         SetSpectatee_status(this, 0);
 577
 578         PS(this).dual_weapons = '0 0 0';
 579
 580         this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 581
 582         this.items = start_items;
 583
 584         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 585         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 586         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 587         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 588         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 589         if (!sv_ready_restart_after_countdown && time < game_starttime)
 590         {
 591                 float f = game_starttime - time;
 592                 this.spawnshieldtime += f;
 593                 this.pauserotarmor_finished += f;
 594                 this.pauserothealth_finished += f;
 595                 this.pauseregen_finished += f;
 596         }
 597
 598         this.damageforcescale = 2;
 599         this.death_time = 0;
 600         this.respawn_flags = 0;
 601         this.respawn_time = 0;
 602         STAT(RESPAWN_TIME, this) = 0;
 603         this.scale = autocvar_sv_player_scale;
 604         this.fade_time = 0;
 605         this.pain_frame = 0;
 606         this.pain_finished = 0;
 607         this.pushltime = 0;
 608         setthink(this, func_null); // players have no think function
 609         this.nextthink = 0;
 610         this.dmg_team = 0;
 611         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 612
 613         this.deadflag = DEAD_NO;
 614
 615         this.angles = spot.angles;
 616         this.angles_z = 0; // never spawn tilted even if the spot says to
 617         if (IS_BOT_CLIENT(this))
 618                 this.v_angle = this.angles;
 619         this.fixangle = true; // turn this way immediately
 620         this.oldvelocity = this.velocity = '0 0 0';
 621         this.avelocity = '0 0 0';
 622         this.punchangle = '0 0 0';
 623         this.punchvector = '0 0 0';
 624
 625         this.strength_finished = 0;
 626         this.invincible_finished = 0;
 627         this.fire_endtime = -1;
 628         STAT(REVIVE_PROGRESS, this) = 0;
 629         this.revival_time = 0;
 630
 631         this.air_finished = time + 12;
 632         this.waterlevel = WATERLEVEL_NONE;
 633         this.watertype = CONTENT_EMPTY;
 634
 635         entity spawnevent = new_pure(spawnevent);
 636         spawnevent.owner = this;
 637         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 638
 639         // Cut off any still running player sounds.
 640         stopsound(this, CH_PLAYER_SINGLE);
 641
 642         this.model = "";
 643         FixPlayermodel(this);
 644         this.drawonlytoclient = NULL;
 645
 646         this.viewloc = NULL;
 647
 648         for(int slot = 0; slot < MAX_AXH; ++slot)
 649         {
 650                 entity axh = this.(AuxiliaryXhair[slot]);
 651                 this.(AuxiliaryXhair[slot]) = NULL;
 652
 653                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 654                         delete(axh);
 655         }
 656
 657         this.spawnpoint_targ = NULL;
 658
 659         this.crouch = false;
 660         this.view_ofs = STAT(PL_VIEW_OFS, this);
 661         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 662         this.spawnorigin = spot.origin;
 663         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 664         // don't reset back to last position, even if new position is stuck in solid
 665         this.oldorigin = this.origin;
 666         if(this.conveyor)
 667                 IL_REMOVE(g_conveyed, this);
 668         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 669         STAT(HUD, this) = HUD_NORMAL;
 670
 671         this.event_damage = PlayerDamage;
 672
 673         if(!this.bot_attack)
 674                 IL_PUSH(g_bot_targets, this);
 675         this.bot_attack = true;
 676         if(!this.monster_attack)
 677                 IL_PUSH(g_monster_targets, this);
 678         this.monster_attack = true;
 679         navigation_dynamicgoal_init(this, false);
 680
 681         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 682
 683         // player was spectator
 684         if (CS(this).killcount == FRAGS_SPECTATOR) {
 685                 PlayerScore_Clear(this);
 686                 CS(this).killcount = 0;
 687                 CS(this).startplaytime = time;
 688         }
 689
 690         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 691         {
 692                 .entity weaponentity = weaponentities[slot];
 693                 entity oldwep = this.(weaponentity);
 694                 CL_SpawnWeaponentity(this, weaponentity);
 695                 if(oldwep && oldwep.owner == this)
 696                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 697         }
 698         this.alpha = default_player_alpha;
 699         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 700         this.exteriorweaponentity.alpha = default_weapon_alpha;
 701
 702         this.speedrunning = false;
 703
 704         target_voicescript_clear(this);
 705
 706         // reset fields the weapons may use
 707         FOREACH(Weapons, true, {
 708                 it.wr_resetplayer(it, this);
 709                         // reload all reloadable weapons
 710                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 711                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 712                         {
 713                                 .entity weaponentity = weaponentities[slot];
 714                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 715                         }
 716                 }
 717         });
 718
 719         {
 720                 string s = spot.target;
 721                 spot.target = string_null;
 722                 SUB_UseTargets(spot, this, NULL);
 723                 spot.target = s;
 724         }
 725
 726         Unfreeze(this);
 727
 728         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 729
 730         if (autocvar_spawn_debug)
 731         {
 732                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 733                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 734         }
 735
 736         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 737         {
 738                 .entity weaponentity = weaponentities[slot];
 739                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 740                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 741                 else
 742                         this.(weaponentity).m_switchweapon = WEP_Null;
 743                 this.(weaponentity).m_weapon = WEP_Null;
 744                 this.(weaponentity).weaponname = "";
 745                 this.(weaponentity).m_switchingweapon = WEP_Null;
 746                 this.(weaponentity).cnt = -1;
 747         }
 748
 749         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 750
 751         if (!warmup_stage && !this.alivetime)
 752                 this.alivetime = time;
 753
 754         antilag_clear(this, CS(this));
 755 }
 756
 757 /** Called when a client spawns in the server */
 758 void PutClientInServer(entity this)
 759 {
 760         if (IS_BOT_CLIENT(this)) {
 761                 TRANSMUTE(Player, this);
 762         } else if (IS_REAL_CLIENT(this)) {
 763                 msg_entity = this;
 764                 WriteByte(MSG_ONE, SVC_SETVIEW);
 765                 WriteEntity(MSG_ONE, this);
 766         }
 767         if (game_stopped)
 768                 TRANSMUTE(Observer, this);
 769
 770         SetSpectatee(this, NULL);
 771
 772         // reset player keys
 773         if(PS(this))
 774                 PS(this).itemkeys = 0;
 775
 776         MUTATOR_CALLHOOK(PutClientInServer, this);
 777
 778         if (IS_OBSERVER(this)) {
 779                 PutObserverInServer(this);
 780         } else if (IS_PLAYER(this)) {
 781                 PutPlayerInServer(this);
 782         }
 783 }
 784
 785 void ClientInit_misc(entity this);
 786
 787 // TODO do we need all these fields, or should we stop autodetecting runtime
 788 // changes and just have a console command to update this?
 789 bool ClientInit_SendEntity(entity this, entity to, int sf)
 790 {
 791         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 792         return = true;
 793         msg_entity = to;
 794         // MSG_INIT replacement
 795         // TODO: make easier to use
 796         Registry_send_all();
 797         W_PROP_reload(MSG_ONE, to);
 798         ClientInit_misc(this);
 799         MUTATOR_CALLHOOK(Ent_Init);
 800 }
 801 void ClientInit_misc(entity this)
 802 {
 803         int channel = MSG_ONE;
 804         WriteHeader(channel, ENT_CLIENT_INIT);
 805         WriteByte(channel, g_nexball_meter_period * 32);
 806         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 807         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 808         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 809         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 810         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 811         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 812         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 813         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 814
 815         if(sv_foginterval && world.fog != "")
 816                 WriteString(channel, world.fog);
 817         else
 818                 WriteString(channel, "");
 819         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 820         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 821         WriteByte(channel, serverflags);
 822         WriteCoord(channel, autocvar_g_trueaim_minrange);
 823 }
 824
 825 void ClientInit_CheckUpdate(entity this)
 826 {
 827         this.nextthink = time;
 828         if(this.count != autocvar_g_balance_armor_blockpercent)
 829         {
 830                 this.count = autocvar_g_balance_armor_blockpercent;
 831                 this.SendFlags |= 1;
 832         }
 833         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 834         {
 835                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 836                 this.SendFlags |= 1;
 837         }
 838 }
 839
 840 void ClientInit_Spawn()
 841 {
 842         entity e = new_pure(clientinit);
 843         setthink(e, ClientInit_CheckUpdate);
 844         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 845
 846         ClientInit_CheckUpdate(e);
 847 }
 848
 849 /*
 850 =============
 851 SetNewParms
 852 =============
 853 */
 854 void SetNewParms ()
 855 {
 856         // initialize parms for a new player
 857         parm1 = -(86400 * 366);
 858
 859         MUTATOR_CALLHOOK(SetNewParms);
 860 }
 861
 862 /*
 863 =============
 864 SetChangeParms
 865 =============
 866 */
 867 void SetChangeParms (entity this)
 868 {
 869         // save parms for level change
 870         parm1 = CS(this).parm_idlesince - time;
 871
 872         MUTATOR_CALLHOOK(SetChangeParms);
 873 }
 874
 875 /*
 876 =============
 877 DecodeLevelParms
 878 =============
 879 */
 880 void DecodeLevelParms(entity this)
 881 {
 882         // load parms
 883         CS(this).parm_idlesince = parm1;
 884         if (CS(this).parm_idlesince == -(86400 * 366))
 885                 CS(this).parm_idlesince = time;
 886
 887         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 888         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 889
 890         MUTATOR_CALLHOOK(DecodeLevelParms);
 891 }
 892
 893 /*
 894 =============
 895 ClientKill
 896
 897 Called when a client types 'kill' in the console
 898 =============
 899 */
 900
 901 .float clientkill_nexttime;
 902 void ClientKill_Now_TeamChange(entity this)
 903 {
 904         if(this.killindicator_teamchange == -1)
 905         {
 906                 TeamBalance_JoinBestTeam(this, true);
 907         }
 908         else if(this.killindicator_teamchange == -2)
 909         {
 910                 if(blockSpectators)
 911                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 912                 PutObserverInServer(this);
 913         }
 914         else
 915                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 916         this.killindicator_teamchange = 0;
 917 }
 918
 919 void ClientKill_Now(entity this)
 920 {
 921         if(this.vehicle)
 922         {
 923             vehicles_exit(this.vehicle, VHEF_RELEASE);
 924             if(!this.killindicator_teamchange)
 925             {
 926             this.vehicle_health = -1;
 927             Damage(this, this, this, 1 , DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 928             }
 929         }
 930
 931         if(this.killindicator && !wasfreed(this.killindicator))
 932                 delete(this.killindicator);
 933
 934         this.killindicator = NULL;
 935
 936         if(this.killindicator_teamchange)
 937                 ClientKill_Now_TeamChange(this);
 938
 939         if (!IS_SPEC(this) && !IS_OBSERVER(this) && MUTATOR_CALLHOOK(ClientKill_Now, this) == false)
 940         {
 941                 Damage(this, this, this, 100000, DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 942         }
 943
 944         // now I am sure the player IS dead
 945 }
 946 void KillIndicator_Think(entity this)
 947 {
 948         if (game_stopped)
 949         {
 950                 this.owner.killindicator = NULL;
 951                 delete(this);
 952                 return;
 953         }
 954
 955         if (this.owner.alpha < 0 && !this.owner.vehicle)
 956         {
 957                 this.owner.killindicator = NULL;
 958                 delete(this);
 959                 return;
 960         }
 961
 962         if(this.cnt <= 0)
 963         {
 964                 ClientKill_Now(this.owner);
 965                 return;
 966         }
 967     else if(this.health == 1) // health == 1 means that it's silent
 968     {
 969         this.nextthink = time + 1;
 970         this.cnt -= 1;
 971     }
 972         else
 973         {
 974                 if(this.cnt <= 10)
 975                         setmodel(this, MDL_NUM(this.cnt));
 976                 if(IS_REAL_CLIENT(this.owner))
 977                 {
 978                         if(this.cnt <= 10)
 979                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 980                 }
 981                 this.nextthink = time + 1;
 982                 this.cnt -= 1;
 983         }
 984 }
 985
 986 float clientkilltime;
 987 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 988 {
 989         float killtime;
 990         float starttime;
 991
 992         if (game_stopped)
 993                 return;
 994
 995         killtime = autocvar_g_balance_kill_delay;
 996
 997     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 998         return;
 999     killtime = M_ARGV(1, float);
1000
1001         this.killindicator_teamchange = targetteam;
1002
1003     if(!this.killindicator)
1004         {
1005                 if(!IS_DEAD(this))
1006                 {
1007                         killtime = max(killtime, this.clientkill_nexttime - time);
1008                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1009                 }
1010
1011                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
1012                 {
1013                         ClientKill_Now(this);
1014                 }
1015                 else
1016                 {
1017                         starttime = max(time, clientkilltime);
1018
1019                         this.killindicator = spawn();
1020                         this.killindicator.owner = this;
1021                         this.killindicator.scale = 0.5;
1022                         setattachment(this.killindicator, this, "");
1023                         setorigin(this.killindicator, '0 0 52');
1024                         setthink(this.killindicator, KillIndicator_Think);
1025                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
1026                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
1027                         this.killindicator.cnt = ceil(killtime);
1028                         this.killindicator.count = bound(0, ceil(killtime), 10);
1029                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
1030
1031                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
1032                         {
1033                                 it.killindicator = spawn();
1034                                 it.killindicator.owner = it;
1035                                 it.killindicator.scale = 0.5;
1036                                 setattachment(it.killindicator, it, "");
1037                                 setorigin(it.killindicator, '0 0 52');
1038                                 setthink(it.killindicator, KillIndicator_Think);
1039                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
1040                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
1041                                 it.killindicator.cnt = ceil(killtime);
1042                         });
1043                         this.lip = 0;
1044                 }
1045         }
1046         if(this.killindicator)
1047         {
1048                 if(targetteam == 0) // just die
1049                 {
1050                         this.killindicator.colormod = '0 0 0';
1051                         if(IS_REAL_CLIENT(this))
1052                         if(this.killindicator.cnt > 0)
1053                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1054                 }
1055                 else if(targetteam == -1) // auto
1056                 {
1057                         this.killindicator.colormod = '0 1 0';
1058                         if(IS_REAL_CLIENT(this))
1059                         if(this.killindicator.cnt > 0)
1060                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1061                 }
1062                 else if(targetteam == -2) // spectate
1063                 {
1064                         this.killindicator.colormod = '0.5 0.5 0.5';
1065                         if(IS_REAL_CLIENT(this))
1066                         if(this.killindicator.cnt > 0)
1067                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1068                 }
1069                 else
1070                 {
1071                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1072                         if(IS_REAL_CLIENT(this))
1073                         if(this.killindicator.cnt > 0)
1074                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1075                 }
1076         }
1077
1078 }
1079
1080 void ClientKill (entity this)
1081 {
1082         if(game_stopped) return;
1083         if(this.player_blocked) return;
1084         if(STAT(FROZEN, this)) return;
1085
1086         ClientKill_TeamChange(this, 0);
1087 }
1088
1089 void FixClientCvars(entity e)
1090 {
1091         // send prediction settings to the client
1092         stuffcmd(e, "\nin_bindmap 0 0\n");
1093         if(autocvar_g_antilag == 3) // client side hitscan
1094                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1095         if(autocvar_sv_gentle)
1096                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1097
1098         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1099         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1100
1101         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
1102
1103         MUTATOR_CALLHOOK(FixClientCvars, e);
1104 }
1105
1106 bool findinlist_abbrev(string tofind, string list)
1107 {
1108         if(list == "" || tofind == "")
1109                 return false; // empty list or search, just return
1110
1111         // this function allows abbreviated strings!
1112         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1113         {
1114                 return true;
1115         });
1116
1117         return false;
1118 }
1119
1120 bool PlayerInIPList(entity p, string iplist)
1121 {
1122         // some safety checks (never allow local?)
1123         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1124                 return false;
1125
1126         return findinlist_abbrev(p.netaddress, iplist);
1127 }
1128
1129 bool PlayerInIDList(entity p, string idlist)
1130 {
1131         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1132         if(!p.crypto_idfp)
1133                 return false;
1134
1135         return findinlist_abbrev(p.crypto_idfp, idlist);
1136 }
1137
1138 bool PlayerInList(entity player, string list)
1139 {
1140         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1141 }
1142
1143 #ifdef DP_EXT_PRECONNECT
1144 /*
1145 =============
1146 ClientPreConnect
1147
1148 Called once (not at each match start) when a client begins a connection to the server
1149 =============
1150 */
1151 void ClientPreConnect(entity this)
1152 {
1153         if(autocvar_sv_eventlog)
1154         {
1155                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1156                         this.playerid,
1157                         etof(this),
1158                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1159                 ));
1160         }
1161 }
1162 #endif
1163
1164 /**
1165 =============
1166 ClientConnect
1167
1168 Called when a client connects to the server
1169 =============
1170 */
1171 void ClientConnect(entity this)
1172 {
1173         if (Ban_MaybeEnforceBanOnce(this)) return;
1174         assert(!IS_CLIENT(this), return);
1175         this.flags |= FL_CLIENT;
1176         assert(player_count >= 0, player_count = 0);
1177
1178 #ifdef WATERMARK
1179         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1180 #endif
1181         TRANSMUTE(Client, this);
1182         CS(this).version_nagtime = time + 10 + random() * 10;
1183
1184         // identify the right forced team
1185         if (autocvar_g_campaign)
1186         {
1187                 if (IS_REAL_CLIENT(this)) // only players, not bots
1188                 {
1189                         switch (autocvar_g_campaign_forceteam)
1190                         {
1191                                 case 1: this.team_forced = NUM_TEAM_1; break;
1192                                 case 2: this.team_forced = NUM_TEAM_2; break;
1193                                 case 3: this.team_forced = NUM_TEAM_3; break;
1194                                 case 4: this.team_forced = NUM_TEAM_4; break;
1195                                 default: this.team_forced = 0;
1196                         }
1197                 }
1198         }
1199         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1200         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1201         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1202         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1203         else switch (autocvar_g_forced_team_otherwise)
1204         {
1205                 default: this.team_forced = 0; break;
1206                 case "red": this.team_forced = NUM_TEAM_1; break;
1207                 case "blue": this.team_forced = NUM_TEAM_2; break;
1208                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1209                 case "pink": this.team_forced = NUM_TEAM_4; break;
1210                 case "spectate":
1211                 case "spectator":
1212                         this.team_forced = -1;
1213                         break;
1214         }
1215         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1216
1217         int playerid_save = this.playerid;
1218         this.playerid = 0; // silent
1219         TeamBalance_JoinBestTeam(this, false); // if the team number is valid, keep it
1220         this.playerid = playerid_save;
1221
1222         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1223                 TRANSMUTE(Observer, this);
1224         } else {
1225                 if (!teamplay || autocvar_g_balance_teams) {
1226                         TRANSMUTE(Player, this);
1227                         campaign_bots_may_start = true;
1228                 } else {
1229                         TRANSMUTE(Observer, this); // do it anyway
1230                 }
1231         }
1232
1233         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1234
1235         // always track bots, don't ask for cl_allow_uidtracking
1236         if (IS_BOT_CLIENT(this))
1237                 PlayerStats_GameReport_AddPlayer(this);
1238         else
1239                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1240
1241         if (autocvar_sv_eventlog)
1242                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1243
1244         LogTeamchange(this.playerid, this.team, 1);
1245
1246         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1247
1248         if(teamplay && IS_PLAYER(this))
1249                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1250         else
1251                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1252
1253         stuffcmd(this, clientstuff, "\n");
1254         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1255
1256         FixClientCvars(this);
1257
1258         // get version info from player
1259         stuffcmd(this, "cmd clientversion $gameversion\n");
1260
1261         // notify about available teams
1262         if (teamplay)
1263         {
1264                 entity balance = TeamBalance_CheckAllowedTeams(this);
1265                 int t = TeamBalance_GetAllowedTeams(balance);
1266                 TeamBalance_Destroy(balance);
1267                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1268         }
1269         else
1270         {
1271                 stuffcmd(this, "set _teams_available 0\n");
1272         }
1273
1274         bot_relinkplayerlist();
1275
1276         CS(this).spectatortime = time;
1277         if (blockSpectators)
1278         {
1279                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1280         }
1281
1282         CS(this).jointime = time;
1283
1284         if (IS_REAL_CLIENT(this))
1285         {
1286                 if (g_weaponarena_weapons == WEPSET(TUBA))
1287                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1288         }
1289
1290         if (!sv_foginterval && world.fog != "")
1291                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1292
1293         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1294                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1295                         send_CSQC_teamnagger();
1296
1297         CSQCMODEL_AUTOINIT(this);
1298
1299         CS(this).model_randomizer = random();
1300
1301         if (IS_REAL_CLIENT(this))
1302                 sv_notice_join(this);
1303
1304         // update physics stats (players can spawn before physics runs)
1305         Physics_UpdateStats(this);
1306
1307         IL_EACH(g_initforplayer, it.init_for_player, {
1308                 it.init_for_player(it, this);
1309         });
1310
1311         Handicap_Initialize(this);
1312
1313         MUTATOR_CALLHOOK(ClientConnect, this);
1314
1315         if (IS_REAL_CLIENT(this))
1316         {
1317                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1318                 {
1319                         CS(this).motd_actived_time = -1;
1320                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1321                 }
1322         }
1323 }
1324 /*
1325 =============
1326 ClientDisconnect
1327
1328 Called when a client disconnects from the server
1329 =============
1330 */
1331 .entity chatbubbleentity;
1332 void ReadyCount();
1333 void ClientDisconnect(entity this)
1334 {
1335         assert(IS_CLIENT(this), return);
1336
1337         PlayerStats_GameReport_FinalizePlayer(this);
1338         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1339         if (CS(this).active_minigame) part_minigame(this);
1340         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1341
1342         if (autocvar_sv_eventlog)
1343                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1344
1345         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1346
1347         if(IS_SPEC(this))
1348                 SetSpectatee(this, NULL);
1349
1350     MUTATOR_CALLHOOK(ClientDisconnect, this);
1351
1352         if (CS(this).netname_previous) strunzone(CS(this).netname_previous); // needs to be before the CS entity is removed!
1353         if (CS(this).weaponorder_byimpulse) strunzone(CS(this).weaponorder_byimpulse);
1354         ClientState_detach(this);
1355
1356         Portal_ClearAll(this);
1357
1358         Unfreeze(this);
1359
1360         RemoveGrapplingHooks(this);
1361
1362         // Here, everything has been done that requires this player to be a client.
1363
1364         this.flags &= ~FL_CLIENT;
1365
1366         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1367         if (this.killindicator) delete(this.killindicator);
1368
1369         WaypointSprite_PlayerGone(this);
1370
1371         bot_relinkplayerlist();
1372
1373         if (this.clientstatus) strunzone(this.clientstatus);
1374         if (this.personal) delete(this.personal);
1375
1376         this.playerid = 0;
1377         ReadyCount();
1378         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1379
1380         ONREMOVE(this);
1381 }
1382
1383 void ChatBubbleThink(entity this)
1384 {
1385         this.nextthink = time;
1386         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1387         {
1388                 if(this.owner) // but why can that ever be NULL?
1389                         this.owner.chatbubbleentity = NULL;
1390                 delete(this);
1391                 return;
1392         }
1393
1394         this.mdl = "";
1395
1396         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1397         {
1398                 if ( CS(this.owner).active_minigame )
1399                         this.mdl = "models/sprites/minigame_busy.iqm";
1400                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1401                         this.mdl = "models/misc/chatbubble.spr";
1402         }
1403
1404         if ( this.model != this.mdl )
1405                 _setmodel(this, this.mdl);
1406
1407 }
1408
1409 void UpdateChatBubble(entity this)
1410 {
1411         if (this.alpha < 0)
1412                 return;
1413         // spawn a chatbubble entity if needed
1414         if (!this.chatbubbleentity)
1415         {
1416                 this.chatbubbleentity = new(chatbubbleentity);
1417                 this.chatbubbleentity.owner = this;
1418                 this.chatbubbleentity.exteriormodeltoclient = this;
1419                 setthink(this.chatbubbleentity, ChatBubbleThink);
1420                 this.chatbubbleentity.nextthink = time;
1421                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1422                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1423                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1424                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1425                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1426                 //this.chatbubbleentity.model = "";
1427                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1428         }
1429 }
1430
1431
1432 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1433 // added to the model skins
1434 /*void UpdateColorModHack()
1435 {
1436         float c;
1437         c = this.clientcolors & 15;
1438         // LordHavoc: only bothering to support white, green, red, yellow, blue
1439              if (!teamplay) this.colormod = '0 0 0';
1440         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1441         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1442         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1443         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1444         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1445         else this.colormod = '1 1 1';
1446 }*/
1447
1448 void respawn(entity this)
1449 {
1450         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1451         {
1452                 this.solid = SOLID_NOT;
1453                 this.takedamage = DAMAGE_NO;
1454                 set_movetype(this, MOVETYPE_FLY);
1455                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1456                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1457                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1458                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1459                 if(autocvar_g_respawn_ghosts_maxtime)
1460                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1461         }
1462
1463         CopyBody(this, 1);
1464
1465         this.effects |= EF_NODRAW; // prevent another CopyBody
1466         PutClientInServer(this);
1467 }
1468
1469 void play_countdown(entity this, float finished, Sound samp)
1470 {
1471     TC(Sound, samp);
1472         if(IS_REAL_CLIENT(this))
1473                 if(floor(finished - time - frametime) != floor(finished - time))
1474                         if(finished - time < 6)
1475                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1476 }
1477
1478 void player_powerups(entity this)
1479 {
1480         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1481         int items_prev = this.items;
1482
1483         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1484                 this.modelflags |= MF_ROCKET;
1485         else
1486                 this.modelflags &= ~MF_ROCKET;
1487
1488         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1489
1490         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1491                 return;
1492
1493         Fire_ApplyDamage(this);
1494         Fire_ApplyEffect(this);
1495
1496         if (!g_instagib)
1497         {
1498                 if (this.items & ITEM_Strength.m_itemid)
1499                 {
1500                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1501                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1502                         if (time > this.strength_finished)
1503                         {
1504                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1505                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1506                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1507                         }
1508                 }
1509                 else
1510                 {
1511                         if (time < this.strength_finished)
1512                         {
1513                                 this.items = this.items | ITEM_Strength.m_itemid;
1514                                 if(!g_cts)
1515                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1516                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1517                         }
1518                 }
1519                 if (this.items & ITEM_Shield.m_itemid)
1520                 {
1521                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1522                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1523                         if (time > this.invincible_finished)
1524                         {
1525                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1526                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1527                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1528                         }
1529                 }
1530                 else
1531                 {
1532                         if (time < this.invincible_finished)
1533                         {
1534                                 this.items = this.items | ITEM_Shield.m_itemid;
1535                                 if(!g_cts)
1536                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1537                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1538                         }
1539                 }
1540                 if (this.items & IT_SUPERWEAPON)
1541                 {
1542                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1543                         {
1544                                 this.superweapons_finished = 0;
1545                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1546                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1547                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1548                         }
1549                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1550                         {
1551                                 // don't let them run out
1552                         }
1553                         else
1554                         {
1555                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1556                                 if (time > this.superweapons_finished)
1557                                 {
1558                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1559                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1560                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1561                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1562                                 }
1563                         }
1564                 }
1565                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1566                 {
1567                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1568                         {
1569                                 this.items = this.items | IT_SUPERWEAPON;
1570                                 if(!g_cts)
1571                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1572                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1573                         }
1574                         else
1575                         {
1576                                 this.superweapons_finished = 0;
1577                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1578                         }
1579                 }
1580                 else
1581                 {
1582                         this.superweapons_finished = 0;
1583                 }
1584         }
1585
1586         if(autocvar_g_nodepthtestplayers)
1587                 this.effects = this.effects | EF_NODEPTHTEST;
1588
1589         if(autocvar_g_fullbrightplayers)
1590                 this.effects = this.effects | EF_FULLBRIGHT;
1591
1592         if (time >= game_starttime)
1593         if (time < this.spawnshieldtime)
1594                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1595
1596         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1597 }
1598
1599 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1600 {
1601         if(current > stable)
1602                 return current;
1603         else if(current > stable - 0.25) // when close enough, "snap"
1604                 return stable;
1605         else
1606                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1607 }
1608
1609 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1610 {
1611         if(current < stable)
1612                 return current;
1613         else if(current < stable + 0.25) // when close enough, "snap"
1614                 return stable;
1615         else
1616                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1617 }
1618
1619 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1620 {
1621         if(current > rotstable)
1622         {
1623                 if(rotframetime > 0)
1624                 {
1625                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1626                         current = max(rotstable, current - rotlinear * rotframetime);
1627                 }
1628         }
1629         else if(current < regenstable)
1630         {
1631                 if(regenframetime > 0)
1632                 {
1633                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1634                         current = min(regenstable, current + regenlinear * regenframetime);
1635                 }
1636         }
1637
1638         if(current > limit)
1639                 current = limit;
1640
1641         return current;
1642 }
1643
1644 void player_regen(entity this)
1645 {
1646         float max_mod, regen_mod, rot_mod, limit_mod;
1647         max_mod = regen_mod = rot_mod = limit_mod = 1;
1648
1649         float regen_health = autocvar_g_balance_health_regen;
1650         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1651         float regen_health_rot = autocvar_g_balance_health_rot;
1652         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1653         float regen_health_stable = autocvar_g_balance_health_regenstable;
1654         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1655         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1656                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1657         max_mod = M_ARGV(1, float);
1658         regen_mod = M_ARGV(2, float);
1659         rot_mod = M_ARGV(3, float);
1660         limit_mod = M_ARGV(4, float);
1661         regen_health = M_ARGV(5, float);
1662         regen_health_linear = M_ARGV(6, float);
1663         regen_health_rot = M_ARGV(7, float);
1664         regen_health_rotlinear = M_ARGV(8, float);
1665         regen_health_stable = M_ARGV(9, float);
1666         regen_health_rotstable = M_ARGV(10, float);
1667
1668         if(!mutator_returnvalue)
1669         if(!STAT(FROZEN, this))
1670         {
1671                 float mina, maxa, limith, limita;
1672                 maxa = autocvar_g_balance_armor_rotstable;
1673                 mina = autocvar_g_balance_armor_regenstable;
1674                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1675                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1676
1677                 regen_health_rotstable = regen_health_rotstable * max_mod;
1678                 regen_health_stable = regen_health_stable * max_mod;
1679                 limith = limith * limit_mod;
1680                 limita = limita * limit_mod;
1681
1682                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1683                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1684         }
1685
1686         // if player rotted to death...  die!
1687         // check this outside above checks, as player may still be able to rot to death
1688         if(this.health < 1)
1689         {
1690                 if(this.vehicle)
1691                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1692                 if(this.event_damage)
1693                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1694         }
1695
1696         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1697         {
1698                 float minf, maxf, limitf;
1699
1700                 maxf = autocvar_g_balance_fuel_rotstable;
1701                 minf = autocvar_g_balance_fuel_regenstable;
1702                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1703
1704                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1705         }
1706         // Ugly hack to make sure the health and armor don't go beyond hard limit.
1707         // TODO: Remove this hack when all code uses GivePlayerHealth and
1708         // GivePlayerArmor.
1709         if (this.health > RESOURCE_AMOUNT_HARD_LIMIT)
1710         {
1711                 this.health = RESOURCE_AMOUNT_HARD_LIMIT;
1712         }
1713         if (this.armorvalue > RESOURCE_AMOUNT_HARD_LIMIT)
1714         {
1715                 this.armorvalue = RESOURCE_AMOUNT_HARD_LIMIT;
1716         }
1717         // End hack.
1718 }
1719
1720 bool zoomstate_set;
1721 void SetZoomState(entity this, float newzoom)
1722 {
1723         if(newzoom != CS(this).zoomstate)
1724         {
1725                 CS(this).zoomstate = newzoom;
1726                 ClientData_Touch(this);
1727         }
1728         zoomstate_set = true;
1729 }
1730
1731 void GetPressedKeys(entity this)
1732 {
1733         MUTATOR_CALLHOOK(GetPressedKeys, this);
1734         int keys = STAT(PRESSED_KEYS, this);
1735         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1736         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1737         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1738         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1739
1740         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1741         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1742         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1743         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1744         CS(this).pressedkeys = keys; // store for other users
1745
1746         STAT(PRESSED_KEYS, this) = keys;
1747 }
1748
1749 /*
1750 ======================
1751 spectate mode routines
1752 ======================
1753 */
1754
1755 void SpectateCopy(entity this, entity spectatee)
1756 {
1757     TC(Client, this); TC(Client, spectatee);
1758
1759         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1760         PS(this) = PS(spectatee);
1761         this.armortype = spectatee.armortype;
1762         this.armorvalue = spectatee.armorvalue;
1763         this.ammo_cells = spectatee.ammo_cells;
1764         this.ammo_plasma = spectatee.ammo_plasma;
1765         this.ammo_shells = spectatee.ammo_shells;
1766         this.ammo_nails = spectatee.ammo_nails;
1767         this.ammo_rockets = spectatee.ammo_rockets;
1768         this.ammo_fuel = spectatee.ammo_fuel;
1769         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1770         this.health = spectatee.health;
1771         CS(this).impulse = 0;
1772         this.items = spectatee.items;
1773         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1774         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1775         this.strength_finished = spectatee.strength_finished;
1776         this.invincible_finished = spectatee.invincible_finished;
1777         this.superweapons_finished = spectatee.superweapons_finished;
1778         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1779         this.weapons = spectatee.weapons;
1780         this.punchangle = spectatee.punchangle;
1781         this.view_ofs = spectatee.view_ofs;
1782         this.velocity = spectatee.velocity;
1783         this.dmg_take = spectatee.dmg_take;
1784         this.dmg_save = spectatee.dmg_save;
1785         this.dmg_inflictor = spectatee.dmg_inflictor;
1786         this.v_angle = spectatee.v_angle;
1787         this.angles = spectatee.v_angle;
1788         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1789         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1790         this.viewloc = spectatee.viewloc;
1791         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1792                 this.fixangle = true;
1793         setorigin(this, spectatee.origin);
1794         setsize(this, spectatee.mins, spectatee.maxs);
1795         SetZoomState(this, CS(spectatee).zoomstate);
1796
1797     anticheat_spectatecopy(this, spectatee);
1798         STAT(HUD, this) = STAT(HUD, spectatee);
1799         if(spectatee.vehicle)
1800     {
1801         this.angles = spectatee.v_angle;
1802
1803         //this.fixangle = false;
1804         //this.velocity = spectatee.vehicle.velocity;
1805         this.vehicle_health = spectatee.vehicle_health;
1806         this.vehicle_shield = spectatee.vehicle_shield;
1807         this.vehicle_energy = spectatee.vehicle_energy;
1808         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1809         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1810         this.vehicle_reload1 = spectatee.vehicle_reload1;
1811         this.vehicle_reload2 = spectatee.vehicle_reload2;
1812
1813         //msg_entity = this;
1814
1815        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1816             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1817            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1818            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1819
1820         //WriteByte (MSG_ONE, SVC_SETVIEW);
1821         //    WriteEntity(MSG_ONE, this);
1822         //makevectors(spectatee.v_angle);
1823         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1824     }
1825 }
1826
1827 bool SpectateUpdate(entity this)
1828 {
1829         if(!this.enemy)
1830                 return false;
1831
1832         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1833         {
1834                 SetSpectatee(this, NULL);
1835                 return false;
1836         }
1837
1838         SpectateCopy(this, this.enemy);
1839
1840         return true;
1841 }
1842
1843 bool SpectateSet(entity this)
1844 {
1845         if(!IS_PLAYER(this.enemy))
1846                 return false;
1847
1848         ClientData_Touch(this.enemy);
1849
1850         msg_entity = this;
1851         WriteByte(MSG_ONE, SVC_SETVIEW);
1852         WriteEntity(MSG_ONE, this.enemy);
1853         set_movetype(this, MOVETYPE_NONE);
1854         accuracy_resend(this);
1855
1856         if(!SpectateUpdate(this))
1857                 PutObserverInServer(this);
1858
1859         return true;
1860 }
1861
1862 void SetSpectatee_status(entity this, int spectatee_num)
1863 {
1864         int oldspectatee_status = CS(this).spectatee_status;
1865         CS(this).spectatee_status = spectatee_num;
1866
1867         if (CS(this).spectatee_status != oldspectatee_status)
1868         {
1869                 ClientData_Touch(this);
1870                 if (g_race || g_cts) race_InitSpectator();
1871         }
1872 }
1873
1874 void SetSpectatee(entity this, entity spectatee)
1875 {
1876         if(IS_BOT_CLIENT(this))
1877                 return; // bots abuse .enemy, this code is useless to them
1878
1879         entity old_spectatee = this.enemy;
1880
1881         this.enemy = spectatee;
1882
1883         // WEAPONTODO
1884         // these are required to fix the spectator bug with arc
1885         if(old_spectatee)
1886         {
1887                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1888                 {
1889                         .entity weaponentity = weaponentities[slot];
1890                         if(old_spectatee.(weaponentity).arc_beam)
1891                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1892                 }
1893         }
1894         if(this.enemy)
1895         {
1896                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1897                 {
1898                         .entity weaponentity = weaponentities[slot];
1899                         if(this.enemy.(weaponentity).arc_beam)
1900                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1901                 }
1902         }
1903
1904         if (this.enemy)
1905                 SetSpectatee_status(this, etof(this.enemy));
1906
1907         // needed to update spectator list
1908         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1909 }
1910
1911 bool Spectate(entity this, entity pl)
1912 {
1913         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1914                 return false;
1915         pl = M_ARGV(1, entity);
1916
1917         SetSpectatee(this, pl);
1918         return SpectateSet(this);
1919 }
1920
1921 bool SpectateNext(entity this)
1922 {
1923         entity ent = find(this.enemy, classname, STR_PLAYER);
1924
1925         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1926                 ent = M_ARGV(1, entity);
1927         else if (!ent)
1928                 ent = find(ent, classname, STR_PLAYER);
1929
1930         if(ent) { SetSpectatee(this, ent); }
1931
1932         return SpectateSet(this);
1933 }
1934
1935 bool SpectatePrev(entity this)
1936 {
1937         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1938         entity ent = findchain(classname, STR_PLAYER);
1939         if (!ent) // no player
1940                 return false;
1941
1942         entity first = ent;
1943         // skip players until current spectated player
1944         if(this.enemy)
1945         while(ent && ent != this.enemy)
1946                 ent = ent.chain;
1947
1948         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1949         {
1950                 case MUT_SPECPREV_FOUND:
1951                     ent = M_ARGV(1, entity);
1952                     break;
1953                 case MUT_SPECPREV_RETURN:
1954                     return true;
1955                 case MUT_SPECPREV_CONTINUE:
1956                 default:
1957                 {
1958                         if(ent.chain)
1959                                 ent = ent.chain;
1960                         else
1961                                 ent = first;
1962                         break;
1963                 }
1964         }
1965
1966         SetSpectatee(this, ent);
1967         return SpectateSet(this);
1968 }
1969
1970 /*
1971 =============
1972 ShowRespawnCountdown()
1973
1974 Update a respawn countdown display.
1975 =============
1976 */
1977 void ShowRespawnCountdown(entity this)
1978 {
1979         float number;
1980         if(!IS_DEAD(this)) // just respawned?
1981                 return;
1982         else
1983         {
1984                 number = ceil(this.respawn_time - time);
1985                 if(number <= 0)
1986                         return;
1987                 if(number <= this.respawn_countdown)
1988                 {
1989                         this.respawn_countdown = number - 1;
1990                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1991                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1992                 }
1993         }
1994 }
1995
1996 .bool team_selected;
1997 bool ShowTeamSelection(entity this)
1998 {
1999         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
2000                 return false;
2001         stuffcmd(this, "menu_showteamselect\n");
2002         return true;
2003 }
2004 void Join(entity this)
2005 {
2006         TRANSMUTE(Player, this);
2007
2008         if(!this.team_selected)
2009         if(autocvar_g_campaign || autocvar_g_balance_teams)
2010                 TeamBalance_JoinBestTeam(this, true);
2011
2012         if(autocvar_g_campaign)
2013                 campaign_bots_may_start = true;
2014
2015         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2016
2017         PutClientInServer(this);
2018
2019         if(IS_PLAYER(this))
2020         if(teamplay && this.team != -1)
2021                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
2022         else
2023                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2024         this.team_selected = false;
2025 }
2026
2027 /**
2028  * Determines whether the player is allowed to join. This depends on cvar
2029  * g_maxplayers, if it isn't used this function always return true, otherwise
2030  * it checks whether the number of currently playing players exceeds g_maxplayers.
2031  * @return int number of free slots for players, 0 if none
2032  */
2033 int nJoinAllowed(entity this, entity ignore)
2034 {
2035         if(!ignore)
2036         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2037         // so report 0 free slots if restricted
2038         {
2039                 if(autocvar_g_forced_team_otherwise == "spectate")
2040                         return 0;
2041                 if(autocvar_g_forced_team_otherwise == "spectator")
2042                         return 0;
2043         }
2044
2045         if(this && this.team_forced < 0)
2046                 return 0; // forced spectators can never join
2047
2048         // TODO simplify this
2049         int totalClients = 0;
2050         int currentlyPlaying = 0;
2051         FOREACH_CLIENT(true, {
2052                 if(it != ignore)
2053                         ++totalClients;
2054                 if(IS_REAL_CLIENT(it))
2055                 if(IS_PLAYER(it) || it.caplayer)
2056                         ++currentlyPlaying;
2057         });
2058
2059         float free_slots = 0;
2060         if (!autocvar_g_maxplayers)
2061                 free_slots = maxclients - totalClients;
2062         else if(currentlyPlaying < autocvar_g_maxplayers)
2063                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2064
2065         static float join_prevent_msg_time = 0;
2066         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2067         {
2068                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2069                 join_prevent_msg_time = time + 3;
2070         }
2071
2072         return free_slots;
2073 }
2074
2075 /**
2076  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2077  * g_maxplayers_spectator_blocktime seconds
2078  */
2079 void checkSpectatorBlock(entity this)
2080 {
2081         if(IS_SPEC(this) || IS_OBSERVER(this))
2082         if(!this.caplayer)
2083         if(IS_REAL_CLIENT(this))
2084         {
2085                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2086                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2087                         dropclient(this);
2088                 }
2089         }
2090 }
2091
2092 void PrintWelcomeMessage(entity this)
2093 {
2094         if(CS(this).motd_actived_time == 0)
2095         {
2096                 if (autocvar_g_campaign) {
2097                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2098                                 CS(this).motd_actived_time = time;
2099                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2100                         }
2101                 } else {
2102                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2103                                 CS(this).motd_actived_time = time;
2104                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2105                         }
2106                 }
2107         }
2108         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2109         {
2110                 if (autocvar_g_campaign) {
2111                         if (PHYS_INPUT_BUTTON_INFO(this))
2112                                 CS(this).motd_actived_time = time;
2113                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2114                                 CS(this).motd_actived_time = 0;
2115                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2116                         }
2117                 } else {
2118                         if (PHYS_INPUT_BUTTON_INFO(this))
2119                                 CS(this).motd_actived_time = time;
2120                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2121                                 CS(this).motd_actived_time = 0;
2122                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2123                         }
2124                 }
2125         }
2126         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2127         {
2128                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2129                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2130                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2131                 {
2132                         // instanctly hide MOTD
2133                         CS(this).motd_actived_time = 0;
2134                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2135                 }
2136         }
2137 }
2138
2139 bool joinAllowed(entity this)
2140 {
2141         if (CS(this).version_mismatch) return false;
2142         if (!nJoinAllowed(this, this)) return false;
2143         if (teamplay && lockteams) return false;
2144         if (ShowTeamSelection(this)) return false;
2145         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2146         return true;
2147 }
2148
2149 .int items_added;
2150 .string shootfromfixedorigin;
2151 bool PlayerThink(entity this)
2152 {
2153         if (game_stopped || intermission_running) {
2154                 this.modelflags &= ~MF_ROCKET;
2155                 if(intermission_running)
2156                         IntermissionThink(this);
2157                 return false;
2158         }
2159
2160         if (timeout_status == TIMEOUT_ACTIVE) {
2161         // don't allow the player to turn around while game is paused
2162                 // FIXME turn this into CSQC stuff
2163                 this.v_angle = this.lastV_angle;
2164                 this.angles = this.lastV_angle;
2165                 this.fixangle = true;
2166         }
2167
2168         if (frametime) player_powerups(this);
2169
2170         if (IS_DEAD(this)) {
2171                 if (this.personal && g_race_qualifying) {
2172                         if (time > this.respawn_time) {
2173                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2174                                 respawn(this);
2175                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2176                         }
2177                 } else {
2178                         if (frametime) player_anim(this);
2179
2180                         if (this.respawn_flags & RESPAWN_DENY)
2181                         {
2182                                 STAT(RESPAWN_TIME, this) = 0;
2183                                 return false;
2184                         }
2185
2186                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2187
2188                         switch(this.deadflag)
2189                         {
2190                                 case DEAD_DYING:
2191                                 {
2192                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2193                                                 this.deadflag = DEAD_RESPAWNING;
2194                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2195                                                 this.deadflag = DEAD_DEAD;
2196                                         break;
2197                                 }
2198                                 case DEAD_DEAD:
2199                                 {
2200                                         if (button_pressed)
2201                                                 this.deadflag = DEAD_RESPAWNABLE;
2202                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2203                                                 this.deadflag = DEAD_RESPAWNING;
2204                                         break;
2205                                 }
2206                                 case DEAD_RESPAWNABLE:
2207                                 {
2208                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2209                                                 this.deadflag = DEAD_RESPAWNING;
2210                                         break;
2211                                 }
2212                                 case DEAD_RESPAWNING:
2213                                 {
2214                                         if (time > this.respawn_time)
2215                                         {
2216                                                 this.respawn_time = time + 1; // only retry once a second
2217                                                 this.respawn_time_max = this.respawn_time;
2218                                                 respawn(this);
2219                                         }
2220                                         break;
2221                                 }
2222                         }
2223
2224                         ShowRespawnCountdown(this);
2225
2226                         if (this.respawn_flags & RESPAWN_SILENT)
2227                                 STAT(RESPAWN_TIME, this) = 0;
2228                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2229                         {
2230                                 if (time < this.respawn_time)
2231                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2232                                 else if (this.deadflag != DEAD_RESPAWNING)
2233                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2234                         }
2235                         else
2236                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2237                 }
2238
2239                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2240                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2241                         STAT(RESPAWN_TIME, this) *= -1;
2242
2243                 return false;
2244         }
2245
2246         bool have_hook = false;
2247         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2248         {
2249                 .entity weaponentity = weaponentities[slot];
2250                 if(this.(weaponentity).hook.state)
2251                 {
2252                         have_hook = true;
2253                         break;
2254                 }
2255         }
2256         bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2257         if (have_hook) {
2258                 do_crouch = false;
2259         //} else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2260                 //do_crouch = false;
2261         } else if (this.vehicle) {
2262                 do_crouch = false;
2263         } else if (STAT(FROZEN, this)) {
2264                 do_crouch = false;
2265     }
2266
2267         if (do_crouch) {
2268                 if (!this.crouch) {
2269                         this.crouch = true;
2270                         this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2271                         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2272                         // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2273                 }
2274         } else if (this.crouch) {
2275         tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2276         if (!trace_startsolid) {
2277             this.crouch = false;
2278             this.view_ofs = STAT(PL_VIEW_OFS, this);
2279             setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2280         }
2281         }
2282
2283         FixPlayermodel(this);
2284
2285         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2286                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2287                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2288         }
2289
2290         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2291         //if(frametime)
2292         {
2293                 this.items &= ~this.items_added;
2294
2295                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2296                 {
2297                         .entity weaponentity = weaponentities[slot];
2298                         W_WeaponFrame(this, weaponentity);
2299                 }
2300
2301                 this.items_added = 0;
2302                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || this.ammo_fuel >= 0.01))
2303             this.items_added |= IT_FUEL;
2304
2305                 this.items |= this.items_added;
2306         }
2307
2308         player_regen(this);
2309
2310         // WEAPONTODO: Add a weapon request for this
2311         // rot vortex charge to the charge limit
2312         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2313         {
2314                 .entity weaponentity = weaponentities[slot];
2315                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2316                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2317         }
2318
2319         if (frametime) player_anim(this);
2320
2321         // secret status
2322         secrets_setstatus(this);
2323
2324         // monsters status
2325         monsters_setstatus(this);
2326
2327         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2328
2329         return true;
2330 }
2331
2332 void ObserverThink(entity this)
2333 {
2334         if ( CS(this).impulse )
2335         {
2336                 MinigameImpulse(this, CS(this).impulse);
2337                 CS(this).impulse = 0;
2338         }
2339
2340         if (this.flags & FL_JUMPRELEASED) {
2341                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2342                         this.flags &= ~FL_JUMPRELEASED;
2343                         this.flags |= FL_SPAWNING;
2344                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) {
2345                         this.flags &= ~FL_JUMPRELEASED;
2346                         if(SpectateNext(this)) {
2347                                 TRANSMUTE(Spectator, this);
2348                         }
2349                 } else {
2350                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2351                         set_movetype(this, preferred_movetype);
2352                 }
2353         } else {
2354                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2355                         this.flags |= FL_JUMPRELEASED;
2356                         if(this.flags & FL_SPAWNING)
2357                         {
2358                                 this.flags &= ~FL_SPAWNING;
2359                                 Join(this);
2360                                 return;
2361                         }
2362                 }
2363         }
2364 }
2365
2366 void SpectatorThink(entity this)
2367 {
2368         if ( CS(this).impulse )
2369         {
2370                 if(MinigameImpulse(this, CS(this).impulse))
2371                         CS(this).impulse = 0;
2372
2373                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2374                 {
2375                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2376                         CS(this).impulse = 0;
2377                         return;
2378                 }
2379         }
2380
2381         if (this.flags & FL_JUMPRELEASED) {
2382                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2383                         this.flags &= ~FL_JUMPRELEASED;
2384                         this.flags |= FL_SPAWNING;
2385                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2386                         this.flags &= ~FL_JUMPRELEASED;
2387                         if(SpectateNext(this)) {
2388                                 TRANSMUTE(Spectator, this);
2389                         } else {
2390                                 TRANSMUTE(Observer, this);
2391                                 PutClientInServer(this);
2392                         }
2393                         CS(this).impulse = 0;
2394                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2395                         this.flags &= ~FL_JUMPRELEASED;
2396                         if(SpectatePrev(this)) {
2397                                 TRANSMUTE(Spectator, this);
2398                         } else {
2399                                 TRANSMUTE(Observer, this);
2400                                 PutClientInServer(this);
2401                         }
2402                         CS(this).impulse = 0;
2403                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2404                         this.flags &= ~FL_JUMPRELEASED;
2405                         TRANSMUTE(Observer, this);
2406                         PutClientInServer(this);
2407                 } else {
2408                         if(!SpectateUpdate(this))
2409                                 PutObserverInServer(this);
2410                 }
2411         } else {
2412                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2413                         this.flags |= FL_JUMPRELEASED;
2414                         if(this.flags & FL_SPAWNING)
2415                         {
2416                                 this.flags &= ~FL_SPAWNING;
2417                                 Join(this);
2418                                 return;
2419                         }
2420                 }
2421                 if(!SpectateUpdate(this))
2422                         PutObserverInServer(this);
2423         }
2424
2425         this.flags |= FL_CLIENT | FL_NOTARGET;
2426 }
2427
2428 void vehicles_enter (entity pl, entity veh);
2429 void PlayerUseKey(entity this)
2430 {
2431         if (!IS_PLAYER(this))
2432                 return;
2433
2434         if(this.vehicle)
2435         {
2436                 if(!game_stopped)
2437                 {
2438                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2439                         return;
2440                 }
2441         }
2442         else if(autocvar_g_vehicles_enter)
2443         {
2444                 if(!STAT(FROZEN, this))
2445                 if(!IS_DEAD(this))
2446                 if(!game_stopped)
2447                 {
2448                         entity head, closest_target = NULL;
2449                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2450
2451                         while(head) // find the closest acceptable target to enter
2452                         {
2453                                 if(IS_VEHICLE(head))
2454                                 if(!IS_DEAD(head))
2455                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2456                                 if(head.takedamage != DAMAGE_NO)
2457                                 {
2458                                         if(closest_target)
2459                                         {
2460                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2461                                                 { closest_target = head; }
2462                                         }
2463                                         else { closest_target = head; }
2464                                 }
2465
2466                                 head = head.chain;
2467                         }
2468
2469                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2470                 }
2471         }
2472
2473         // a use key was pressed; call handlers
2474         MUTATOR_CALLHOOK(PlayerUseKey, this);
2475 }
2476
2477
2478 /*
2479 =============
2480 PlayerPreThink
2481
2482 Called every frame for each client before the physics are run
2483 =============
2484 */
2485 .float last_vehiclecheck;
2486 void PlayerPreThink (entity this)
2487 {
2488         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2489         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2490
2491         WarpZone_PlayerPhysics_FixVAngle(this);
2492
2493         if (frametime) {
2494                 // physics frames: update anticheat stuff
2495                 anticheat_prethink(this);
2496         }
2497
2498         if (blockSpectators && frametime) {
2499                 // WORKAROUND: only use dropclient in server frames (frametime set).
2500                 // Never use it in cl_movement frames (frametime zero).
2501                 checkSpectatorBlock(this);
2502         }
2503
2504         zoomstate_set = false;
2505
2506         // Check for nameless players
2507         if (this.netname == "" || this.netname != CS(this).netname_previous)
2508         {
2509                 bool assume_unchanged = (CS(this).netname_previous == "");
2510                 if (isInvisibleString(this.netname))
2511                 {
2512                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2513                         assume_unchanged = false;
2514                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2515                 }
2516                 if (!assume_unchanged && autocvar_sv_eventlog)
2517                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2518                 if (CS(this).netname_previous) strunzone(CS(this).netname_previous);
2519                 CS(this).netname_previous = strzone(this.netname);
2520         }
2521
2522         // version nagging
2523         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2524         CS(this).version_nagtime = 0;
2525         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2526             // git client
2527         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2528             // git server
2529             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2530         } else {
2531             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2532             if (r < 0) { // old client
2533                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2534             } else if (r > 0) { // old server
2535                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2536             }
2537         }
2538     }
2539
2540         // GOD MODE info
2541         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2542         {
2543                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2544                 this.max_armorvalue = 0;
2545         }
2546
2547         if(IS_PLAYER(this))
2548         {
2549                 if (STAT(FROZEN, this) == 2)
2550                 {
2551                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2552                         this.health = max(1, STAT(REVIVE_PROGRESS, this) * start_health);
2553                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2554
2555                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2556                                 Unfreeze(this);
2557                 }
2558                 else if (STAT(FROZEN, this) == 3)
2559                 {
2560                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2561                         this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this) );
2562
2563                         if (this.health < 1)
2564                         {
2565                                 if (this.vehicle)
2566                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2567                                 if(this.event_damage)
2568                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2569                         }
2570                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2571                                 Unfreeze(this);
2572                 }
2573         }
2574
2575         MUTATOR_CALLHOOK(PlayerPreThink, this);
2576
2577         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2578         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2579         {
2580                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2581                 {
2582                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2583                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2584                         {
2585                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2586                         }
2587                         else if(!it.owner)
2588                         {
2589                                 if(!it.team || SAME_TEAM(this, it))
2590                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2591                                 else if(autocvar_g_vehicles_steal)
2592                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2593                         }
2594                 });
2595
2596                 this.last_vehiclecheck = time + 1;
2597         }
2598
2599         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2600         {
2601                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2602                         PlayerUseKey(this);
2603                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2604         }
2605
2606         if (IS_REAL_CLIENT(this))
2607                 PrintWelcomeMessage(this);
2608
2609         if (IS_PLAYER(this)) {
2610                 if(!PlayerThink(this))
2611                         return;
2612         }
2613         else if (game_stopped || intermission_running) {
2614                 if(intermission_running)
2615                         IntermissionThink(this);
2616                 return;
2617         }
2618         else if (IS_OBSERVER(this)) {
2619                 ObserverThink(this);
2620         }
2621         else if (IS_SPEC(this)) {
2622                 SpectatorThink(this);
2623         }
2624
2625         // WEAPONTODO: Add weapon request for this
2626         if (!zoomstate_set) {
2627                 bool wep_zoomed = false;
2628                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2629                 {
2630                         .entity weaponentity = weaponentities[slot];
2631                         Weapon thiswep = this.(weaponentity).m_weapon;
2632                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2633                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2634                 }
2635                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2636     }
2637
2638         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2639         {
2640                 CS(this).teamkill_soundtime = 0;
2641
2642                 entity e = CS(this).teamkill_soundsource;
2643                 entity oldpusher = e.pusher;
2644                 e.pusher = this;
2645                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2646                 e.pusher = oldpusher;
2647         }
2648
2649         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2650                 CS(this).taunt_soundtime = 0;
2651                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2652         }
2653
2654         target_voicescript_next(this);
2655
2656         // WEAPONTODO: Move into weaponsystem somehow
2657         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2658         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2659         {
2660                 .entity weaponentity = weaponentities[slot];
2661                 if(this.(weaponentity).m_weapon == WEP_Null)
2662                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2663         }
2664 }
2665
2666 void DrownPlayer(entity this)
2667 {
2668         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2669                 return;
2670
2671         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2672         {
2673                 if(this.air_finished < time)
2674                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2675                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2676         }
2677         else if (this.air_finished < time)
2678         {       // drown!
2679                 if (this.pain_finished < time)
2680                 {
2681                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2682                         this.pain_finished = time + 0.5;
2683                 }
2684         }
2685 }
2686
2687 .bool move_qcphysics;
2688
2689 void Player_Physics(entity this)
2690 {
2691         set_movetype(this, this.move_movetype);
2692
2693         if(!this.move_qcphysics)
2694                 return;
2695
2696         if(!frametime && !CS(this).pm_frametime)
2697                 return;
2698
2699         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2700
2701         CS(this).pm_frametime = 0;
2702 }
2703
2704 /*
2705 =============
2706 PlayerPostThink
2707
2708 Called every frame for each client after the physics are run
2709 =============
2710 */
2711 void PlayerPostThink (entity this)
2712 {
2713         Player_Physics(this);
2714
2715         if (sv_maxidle > 0)
2716         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2717         if (IS_REAL_CLIENT(this))
2718         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2719         {
2720                 int totalClients = 0;
2721                 if(sv_maxidle_slots > 0)
2722                 {
2723                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2724                         {
2725                                 ++totalClients;
2726                         });
2727                 }
2728
2729                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2730                 { /* do nothing */ }
2731                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2732                 {
2733                         if (CS(this).idlekick_lasttimeleft)
2734                         {
2735                                 CS(this).idlekick_lasttimeleft = 0;
2736                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2737                         }
2738                 }
2739                 else
2740                 {
2741                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2742                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2743                                 if (!CS(this).idlekick_lasttimeleft)
2744                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2745                         }
2746                         if (timeleft <= 0) {
2747                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2748                                 dropclient(this);
2749                                 return;
2750                         }
2751                         else if (timeleft <= 10) {
2752                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2753                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2754                 }
2755                                 CS(this).idlekick_lasttimeleft = timeleft;
2756                         }
2757                 }
2758         }
2759
2760         CheatFrame(this);
2761
2762         if (game_stopped)
2763         {
2764                 this.solid = SOLID_NOT;
2765                 this.takedamage = DAMAGE_NO;
2766                 set_movetype(this, MOVETYPE_NONE);
2767         }
2768
2769         if (IS_PLAYER(this)) {
2770                 if(this.death_time == time && IS_DEAD(this))
2771                 {
2772                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2773                         // once all the damage events of this frame have been processed with normal size
2774                         this.maxs.z = 5;
2775                         setsize(this, this.mins, this.maxs);
2776                 }
2777                 DrownPlayer(this);
2778                 UpdateChatBubble(this);
2779                 if (CS(this).impulse) ImpulseCommands(this);
2780                 if (game_stopped)
2781                 {
2782                         CSQCMODEL_AUTOUPDATE(this);
2783                         return;
2784                 }
2785                 GetPressedKeys(this);
2786         }
2787
2788         if (this.waypointsprite_attachedforcarrier) {
2789             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2790                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2791     }
2792
2793         playerdemo_write(this);
2794
2795         CSQCMODEL_AUTOUPDATE(this);
2796 }
2797
2798 // hack to copy the button fields from the client entity to the Client State
2799 void PM_UpdateButtons(entity this, entity store)
2800 {
2801         if(this.impulse)
2802                 store.impulse = this.impulse;
2803         this.impulse = 0;
2804
2805         store.button0 = this.button0;
2806         store.button2 = this.button2;
2807         store.button3 = this.button3;
2808         store.button4 = this.button4;
2809         store.button5 = this.button5;
2810         store.button6 = this.button6;
2811         store.button7 = this.button7;
2812         store.button8 = this.button8;
2813         store.button9 = this.button9;
2814         store.button10 = this.button10;
2815         store.button11 = this.button11;
2816         store.button12 = this.button12;
2817         store.button13 = this.button13;
2818         store.button14 = this.button14;
2819         store.button15 = this.button15;
2820         store.button16 = this.button16;
2821         store.buttonuse = this.buttonuse;
2822         store.buttonchat = this.buttonchat;
2823
2824         store.cursor_active = this.cursor_active;
2825         store.cursor_screen = this.cursor_screen;
2826         store.cursor_trace_start = this.cursor_trace_start;
2827         store.cursor_trace_endpos = this.cursor_trace_endpos;
2828         store.cursor_trace_ent = this.cursor_trace_ent;
2829
2830         store.ping = this.ping;
2831         store.ping_packetloss = this.ping_packetloss;
2832         store.ping_movementloss = this.ping_movementloss;
2833
2834         store.v_angle = this.v_angle;
2835         store.movement = this.movement;
2836 }
2837
2838 NET_HANDLE(fpsreport, bool)
2839 {
2840         int fps = ReadShort();
2841         PlayerScore_Set(sender, SP_FPS, fps);
2842         return true;
2843 }