qcsrc/server/command/cmd.qc

   1 #include "cmd.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5
   6 #include <common/command/_mod.qh>
   7
   8 #include "common.qh"
   9 #include "vote.qh"
  10
  11 #include "../bot/api.qh"
  12
  13 #include "../campaign.qh"
  14 #include "../cheats.qh"
  15 #include "../client.qh"
  16 #include "../clientkill.qh"
  17 #include "../player.qh"
  18 #include "../ipban.qh"
  19 #include "../mapvoting.qh"
  20 #include "../scores.qh"
  21 #include "../teamplay.qh"
  22
  23 #include <server/mutators/_mod.qh>
  24 #include <common/gamemodes/_mod.qh>
  25
  26 #ifdef SVQC
  27         #include <common/vehicles/all.qh>
  28 #endif
  29
  30 #include <common/constants.qh>
  31 #include <common/deathtypes/all.qh>
  32 #include <common/effects/all.qh>
  33 #include <common/mapinfo.qh>
  34 #include <common/notifications/all.qh>
  35 #include <common/physics/player.qh>
  36 #include <common/teams.qh>
  37 #include <common/util.qh>
  38 #include <common/mapobjects/triggers.qh>
  39
  40 #include <common/minigames/sv_minigames.qh>
  41
  42 #include <common/monsters/_mod.qh>
  43 #include <common/monsters/sv_spawn.qh>
  44 #include <common/monsters/sv_monsters.qh>
  45
  46 #include <lib/warpzone/common.qh>
  47
  48 // =========================================================
  49 //  Server side networked commands code, reworked by Samual
  50 //  Last updated: December 28th, 2011
  51 // =========================================================
  52
  53 bool SV_ParseClientCommand_floodcheck(entity this)
  54 {
  55         entity store = IS_CLIENT(this) ? CS(this) : this; // unfortunately, we need to store these on the client initially
  56
  57         if (!timeout_status)  // not while paused
  58         {
  59                 if (time <= (store.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  60                 {
  61                         store.cmd_floodcount += 1;
  62                         if (store.cmd_floodcount > autocvar_sv_clientcommand_antispam_count)   return false;  // too much spam, halt
  63                 }
  64                 else
  65                 {
  66                         store.cmd_floodtime = time;
  67                         store.cmd_floodcount = 1;
  68                 }
  69         }
  70         return true;  // continue, as we're not flooding yet
  71 }
  72
  73
  74 // =======================
  75 //  Command Sub-Functions
  76 // =======================
  77
  78 void ClientCommand_autoswitch(entity caller, int request, int argc)
  79 {
  80         switch (request)
  81         {
  82                 case CMD_REQUEST_COMMAND:
  83                 {
  84                         if (argv(1) != "")
  85                         {
  86                                 CS(caller).autoswitch = InterpretBoolean(argv(1));
  87                                 sprint(caller, strcat("^1autoswitch is currently turned ", (CS(caller).autoswitch ? "on" : "off"), ".\n"));
  88                                 return;
  89                         }
  90                 }
  91
  92                 default:
  93                         sprint(caller, "Incorrect parameters for ^2autoswitch^7\n");
  94                 case CMD_REQUEST_USAGE:
  95                 {
  96                         sprint(caller, "\nUsage:^3 cmd autoswitch selection\n");
  97                         sprint(caller, "  Where 'selection' controls if autoswitch is on or off.\n");
  98                         return;
  99                 }
 100         }
 101 }
 102
 103 void ClientCommand_clientversion(entity caller, int request, int argc)  // internal command, used only by code
 104 {
 105         switch (request)
 106         {
 107                 case CMD_REQUEST_COMMAND:
 108                 {
 109                         if (argv(1) != "")
 110                         {
 111                                 if (IS_CLIENT(caller))
 112                                 {
 113                                         CS(caller).version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
 114
 115                                         if (CS(caller).version < autocvar_gameversion_min || CS(caller).version > autocvar_gameversion_max)
 116                                         {
 117                                                 CS(caller).version_mismatch = true;
 118                                                 ClientKill_TeamChange(caller, -2);  // observe
 119                                         }
 120                                         else if (autocvar_g_campaign || autocvar_g_balance_teams)
 121                                         {
 122                                                 // JoinBestTeam(caller, false, true);
 123                                         }
 124                                         else if (teamplay && !autocvar_sv_spectate && !(caller.team_forced > 0))
 125                                         {
 126                                                 TRANSMUTE(Observer, caller);  // really?
 127                                                 stuffcmd(caller, "menu_showteamselect\n");
 128                                         }
 129                                 }
 130
 131                                 return;
 132                         }
 133                 }
 134
 135                 default:
 136                         sprint(caller, "Incorrect parameters for ^2clientversion^7\n");
 137                 case CMD_REQUEST_USAGE:
 138                 {
 139                         sprint(caller, "\nUsage:^3 cmd clientversion version\n");
 140                         sprint(caller, "  Where 'version' is the game version reported by caller.\n");
 141                         return;
 142                 }
 143         }
 144 }
 145
 146 void ClientCommand_mv_getpicture(entity caller, int request, int argc)  // internal command, used only by code
 147 {
 148         switch (request)
 149         {
 150                 case CMD_REQUEST_COMMAND:
 151                 {
 152                         if (argv(1) != "")
 153                         {
 154                                 if (intermission_running) MapVote_SendPicture(caller, stof(argv(1)));
 155
 156                                 return;
 157                         }
 158                 }
 159
 160                 default:
 161                         sprint(caller, "Incorrect parameters for ^2mv_getpicture^7\n");
 162                 case CMD_REQUEST_USAGE:
 163                 {
 164                         sprint(caller, "\nUsage:^3 cmd mv_getpicture mapid\n");
 165                         sprint(caller, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 166                         return;
 167                 }
 168         }
 169 }
 170
 171 void ClientCommand_wpeditor(entity caller, int request, int argc)
 172 {
 173         switch (request)
 174         {
 175                 case CMD_REQUEST_COMMAND:
 176                 {
 177                         if (!autocvar_g_waypointeditor)
 178                         {
 179                                 sprint(caller, "ERROR: this command works only if the waypoint editor is on\n");
 180                                 return;
 181                         }
 182
 183                         if (argv(1) != "")
 184                         {
 185                                 if (argv(1) == "spawn")
 186                                 {
 187                                         if (!IS_PLAYER(caller))
 188                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 189                                         else
 190                                                 waypoint_spawn_fromeditor(caller);
 191                                 }
 192                                 else if (argv(1) == "remove")
 193                                 {
 194                                         if (!IS_PLAYER(caller))
 195                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 196                                         else
 197                                                 waypoint_remove_fromeditor(caller);
 198                                 }
 199                                 else if (argv(1) == "unreachable")
 200                                 {
 201                                         if (!IS_PLAYER(caller))
 202                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 203                                         else
 204                                                 waypoint_unreachable(caller);
 205                                 }
 206                                 else if (argv(1) == "saveall")
 207                                         waypoint_saveall();
 208                                 else if (argv(1) == "relinkall")
 209                                         waypoint_schedulerelinkall();
 210
 211                                 return;
 212                         }
 213                 }
 214
 215                 default:
 216                         sprint(caller, "Incorrect parameters for ^2wpeditor^7\n");
 217                 case CMD_REQUEST_USAGE:
 218                 {
 219                         sprint(caller, "\nUsage:^3 cmd wpeditor action\n");
 220                         sprint(caller, "  Where 'action' can be: spawn, remove, unreachable, saveall, relinkall\n");
 221                         return;
 222                 }
 223         }
 224 }
 225
 226 void ClientCommand_join(entity caller, int request)
 227 {
 228         switch (request)
 229         {
 230                 case CMD_REQUEST_COMMAND:
 231                 {
 232                         if (!game_stopped)
 233                         if (IS_CLIENT(caller) && !IS_PLAYER(caller))
 234                         if (joinAllowed(caller))
 235                                 Join(caller);
 236
 237                         return;  // never fall through to usage
 238                 }
 239
 240                 default:
 241                 case CMD_REQUEST_USAGE:
 242                 {
 243                         sprint(caller, "\nUsage:^3 cmd join\n");
 244                         sprint(caller, "  No arguments required.\n");
 245                         return;
 246                 }
 247         }
 248 }
 249
 250 void ClientCommand_physics(entity caller, int request, int argc)
 251 {
 252         switch (request)
 253         {
 254                 case CMD_REQUEST_COMMAND:
 255                 {
 256                         string command = strtolower(argv(1));
 257
 258                         if (!autocvar_g_physics_clientselect)
 259                         {
 260                                 sprint(caller, "Client physics selection is currently disabled.\n");
 261                                 return;
 262                         }
 263
 264                         if (command == "list" || command == "help")
 265                         {
 266                                 sprint(caller, strcat("Available physics sets: \n\n", autocvar_g_physics_clientselect_options, " default\n"));
 267                                 return;
 268                         }
 269
 270                         if (Physics_Valid(command) || command == "default")
 271                         {
 272                                 stuffcmd(caller, strcat("\nseta cl_physics ", command, "\nsendcvar cl_physics\n"));
 273                                 sprint(caller, strcat("^2Physics set successfully changed to ^3", command, "\n"));
 274                                 return;
 275                         }
 276                 }
 277
 278                 default:
 279                         sprint(caller, strcat("Current physics set: ^3", CS(caller).cvar_cl_physics, "\n"));
 280                 case CMD_REQUEST_USAGE:
 281                 {
 282                         sprint(caller, "\nUsage:^3 cmd physics <physics>\n");
 283                         sprint(caller, "  See 'cmd physics list' for available physics sets.\n");
 284                         sprint(caller, "  Argument 'default' resets to standard physics.\n");
 285                         return;
 286                 }
 287         }
 288 }
 289
 290 void ClientCommand_ready(entity caller, int request)  // todo: anti-spam for toggling readyness
 291 {
 292         switch (request)
 293         {
 294                 case CMD_REQUEST_COMMAND:
 295                 {
 296                         if (IS_CLIENT(caller))
 297                         {
 298                                 if (warmup_stage || sv_ready_restart || g_race_qualifying == 2)
 299                                 {
 300                                         if (!readyrestart_happened || sv_ready_restart_repeatable)
 301                                         {
 302                                                 if (time < game_starttime) // game is already restarting
 303                                                         return;
 304                                                 if (caller.ready)            // toggle
 305                                                 {
 306                                                         caller.ready = false;
 307                                                         if(IS_PLAYER(caller) || caller.caplayer == 1)
 308                                                                 bprint(playername(caller, false), "^2 is ^1NOT^2 ready\n");
 309                                                 }
 310                                                 else
 311                                                 {
 312                                                         caller.ready = true;
 313                                                         if(IS_PLAYER(caller) || caller.caplayer == 1)
 314                                                                 bprint(playername(caller, false), "^2 is ready\n");
 315                                                 }
 316
 317                                                 // cannot reset the game while a timeout is active!
 318                                                 if (!timeout_status) ReadyCount();
 319                                         }
 320                                         else
 321                                         {
 322                                                 sprint(caller, "^1Game has already been restarted\n");
 323                                         }
 324                                 }
 325                         }
 326                         return;  // never fall through to usage
 327                 }
 328
 329                 default:
 330                 case CMD_REQUEST_USAGE:
 331                 {
 332                         sprint(caller, "\nUsage:^3 cmd ready\n");
 333                         sprint(caller, "  No arguments required.\n");
 334                         return;
 335                 }
 336         }
 337 }
 338
 339 void ClientCommand_say(entity caller, int request, int argc, string command)
 340 {
 341         switch (request)
 342         {
 343                 case CMD_REQUEST_COMMAND:
 344                 {
 345                         if (argc >= 2)   Say(caller, false, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 346                         return;  // never fall through to usage
 347                 }
 348
 349                 default:
 350                 case CMD_REQUEST_USAGE:
 351                 {
 352                         sprint(caller, "\nUsage:^3 cmd say <message>\n");
 353                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 354                         return;
 355                 }
 356         }
 357 }
 358
 359 void ClientCommand_say_team(entity caller, int request, int argc, string command)
 360 {
 361         switch (request)
 362         {
 363                 case CMD_REQUEST_COMMAND:
 364                 {
 365                         if (argc >= 2)
 366                         {
 367                                 string _classname = string_null;
 368                                 if (!IS_PLAYER(caller) && caller.caplayer)
 369                                 {
 370                                         // CA: make work team chat for killed players
 371                                         _classname = caller.classname;
 372                                         caller.classname = STR_PLAYER;
 373                                 }
 374
 375                                 Say(caller, true, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 376                                 if (_classname)
 377                                         caller.classname = _classname;
 378                         }
 379                         return;  // never fall through to usage
 380                 }
 381
 382                 default:
 383                 case CMD_REQUEST_USAGE:
 384                 {
 385                         sprint(caller, "\nUsage:^3 cmd say_team <message>\n");
 386                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 387                         return;
 388                 }
 389         }
 390 }
 391
 392 .bool team_selected;
 393 void ClientCommand_selectteam(entity caller, int request, int argc)
 394 {
 395         switch (request)
 396         {
 397                 case CMD_REQUEST_COMMAND:
 398                 {
 399                         if (argv(1) == "")
 400                         {
 401                                 return;
 402                         }
 403                         if (!IS_CLIENT(caller))
 404                         {
 405                                 return;
 406                         }
 407                         if (!teamplay)
 408                         {
 409                                 sprint(caller, "^7selectteam can only be used in teamgames\n");
 410                                 return;
 411                         }
 412                         if (caller.team_forced > 0)
 413                         {
 414                                 sprint(caller, "^7selectteam can not be used as your team is forced\n");
 415                                 return;
 416                         }
 417                         if (lockteams)
 418                         {
 419                                 sprint(caller, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 420                                 return;
 421                         }
 422                         float selection;
 423                         switch (argv(1))
 424                         {
 425                                 case "red":
 426                                 {
 427                                         selection = NUM_TEAM_1;
 428                                         break;
 429                                 }
 430                                 case "blue":
 431                                 {
 432                                         selection = NUM_TEAM_2;
 433                                         break;
 434                                 }
 435                                 case "yellow":
 436                                 {
 437                                         selection = NUM_TEAM_3;
 438                                         break;
 439                                 }
 440                                 case "pink":
 441                                 {
 442                                         selection = NUM_TEAM_4;
 443                                         break;
 444                                 }
 445                                 case "auto":
 446                                 {
 447                                         selection = (-1);
 448                                         break;
 449                                 }
 450                                 default:
 451                                 {
 452                                         return;
 453                                 }
 454                         }
 455                         if (caller.team == selection && selection != -1 && !IS_DEAD(caller))
 456                         {
 457                                 sprint(caller, "^7You already are on that team.\n");
 458                                 return;
 459                         }
 460                         if (CS(caller).wasplayer && autocvar_g_changeteam_banned)
 461                         {
 462                                 sprint(caller, "^1You cannot change team, forbidden by the server.\n");
 463                                 return;
 464                         }
 465                         if ((selection != -1) && autocvar_g_balance_teams &&
 466                                 autocvar_g_balance_teams_prevent_imbalance)
 467                         {
 468                                 entity balance = TeamBalance_CheckAllowedTeams(caller);
 469                                 TeamBalance_GetTeamCounts(balance, caller);
 470                                 if ((Team_IndexToBit(Team_TeamToIndex(selection)) &
 471                                         TeamBalance_FindBestTeams(balance, caller, false)) == 0)
 472                                 {
 473                                         Send_Notification(NOTIF_ONE, caller, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 474                                         TeamBalance_Destroy(balance);
 475                                         return;
 476                                 }
 477                                 TeamBalance_Destroy(balance);
 478                         }
 479                         ClientKill_TeamChange(caller, selection);
 480                         if (!IS_PLAYER(caller))
 481                         {
 482                                 caller.team_selected = true; // avoids asking again for team selection on join
 483                         }
 484                         return;
 485                 }
 486                 default:
 487                         sprint(caller, "Incorrect parameters for ^2selectteam^7\n");
 488                 case CMD_REQUEST_USAGE:
 489                 {
 490                         sprint(caller, "\nUsage:^3 cmd selectteam team\n");
 491                         sprint(caller, "  Where 'team' is the prefered team to try and join.\n");
 492                         sprint(caller, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 493                         return;
 494                 }
 495         }
 496 }
 497
 498 void ClientCommand_selfstuff(entity caller, int request, string command)
 499 {
 500         switch (request)
 501         {
 502                 case CMD_REQUEST_COMMAND:
 503                 {
 504                         if (argv(1) != "")
 505                         {
 506                                 stuffcmd(caller, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 507                                 return;
 508                         }
 509                 }
 510
 511                 default:
 512                         sprint(caller, "Incorrect parameters for ^2selfstuff^7\n");
 513                 case CMD_REQUEST_USAGE:
 514                 {
 515                         sprint(caller, "\nUsage:^3 cmd selfstuff <command>\n");
 516                         sprint(caller, "  Where 'command' is the string to be stuffed to your client.\n");
 517                         return;
 518                 }
 519         }
 520 }
 521
 522 void ClientCommand_sentcvar(entity caller, int request, int argc, string command)
 523 {
 524         switch (request)
 525         {
 526                 case CMD_REQUEST_COMMAND:
 527                 {
 528                         if (argv(1) != "")
 529                         {
 530                                 // float tokens;
 531                                 string s;
 532
 533                                 if (argc == 2)  // undefined cvar: use the default value on the server then
 534                                 {
 535                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 536                                         tokenize_console(s);
 537                                 }
 538
 539                                 GetCvars(caller, CS(caller), 1);
 540
 541                                 return;
 542                         }
 543                 }
 544
 545                 default:
 546                         sprint(caller, "Incorrect parameters for ^2sentcvar^7\n");
 547                 case CMD_REQUEST_USAGE:
 548                 {
 549                         sprint(caller, "\nUsage:^3 cmd sentcvar <cvar>\n");
 550                         sprint(caller, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 551                         return;
 552                 }
 553         }
 554 }
 555
 556 void ClientCommand_spectate(entity caller, int request)
 557 {
 558         switch (request)
 559         {
 560                 case CMD_REQUEST_COMMAND:
 561                 {
 562                         if (!intermission_running && IS_CLIENT(caller))
 563                         {
 564                                 if((IS_SPEC(caller) || IS_OBSERVER(caller)) && argv(1) != "")
 565                                 {
 566                                         entity client = GetFilteredEntity(argv(1));
 567                                         int spec_accepted = VerifyClientEntity(client, false, false);
 568                                         if(spec_accepted > 0 && IS_PLAYER(client))
 569                                         {
 570                                                 if(Spectate(caller, client))
 571                                                         return; // fall back to regular handling
 572                                         }
 573                                 }
 574
 575                                 int mutator_returnvalue = MUTATOR_CALLHOOK(ClientCommand_Spectate, caller);
 576
 577                                 if (mutator_returnvalue == MUT_SPECCMD_RETURN) return;
 578
 579                                 if ((IS_PLAYER(caller) || mutator_returnvalue == MUT_SPECCMD_FORCE))
 580                                 if (autocvar_sv_spectate == 1)
 581                                         ClientKill_TeamChange(caller, -2); // observe
 582                         }
 583                         return; // never fall through to usage
 584                 }
 585
 586                 default:
 587                 case CMD_REQUEST_USAGE:
 588                 {
 589                         sprint(caller, "\nUsage:^3 cmd spectate <client>\n");
 590                         sprint(caller, "  Where 'client' can be the player to spectate.\n");
 591                         return;
 592                 }
 593         }
 594 }
 595
 596 void ClientCommand_suggestmap(entity caller, int request, int argc)
 597 {
 598         switch (request)
 599         {
 600                 case CMD_REQUEST_COMMAND:
 601                 {
 602                         if (argv(1) != "")
 603                         {
 604                                 sprint(caller, strcat(MapVote_Suggest(caller, argv(1)), "\n"));
 605                                 return;
 606                         }
 607                 }
 608
 609                 default:
 610                         sprint(caller, "Incorrect parameters for ^2suggestmap^7\n");
 611                 case CMD_REQUEST_USAGE:
 612                 {
 613                         sprint(caller, "\nUsage:^3 cmd suggestmap map\n");
 614                         sprint(caller, "  Where 'map' is the name of the map to suggest.\n");
 615                         return;
 616                 }
 617         }
 618 }
 619
 620 void ClientCommand_tell(entity caller, int request, int argc, string command)
 621 {
 622         switch (request)
 623         {
 624                 case CMD_REQUEST_COMMAND:
 625                 {
 626                         if (argc >= 3)
 627                         {
 628                                 if(!IS_CLIENT(caller) && IS_REAL_CLIENT(caller)) // connecting
 629                                 {
 630                                         print_to(caller, "You can't ^2tell^7 a message while connecting.");
 631                                         return;
 632                                 }
 633
 634                                 entity tell_to = GetIndexedEntity(argc, 1);
 635                                 float tell_accepted = VerifyClientEntity(tell_to, true, false);
 636
 637                                 if (tell_accepted > 0)   // the target is a real client
 638                                 {
 639                                         if (tell_to != caller) // and we're allowed to send to them :D
 640                                         {
 641                                                 // workaround for argv indexes indexing ascii chars instead of utf8 chars
 642                                                 // In this case when the player name contains utf8 chars
 643                                                 // the message gets partially trimmed in the beginning.
 644                                                 // Potentially this bug affects any substring call that uses
 645                                                 // argv_start_index and argv_end_index.
 646
 647                                                 string utf8_enable_save = cvar_string("utf8_enable");
 648                                                 cvar_set("utf8_enable", "0");
 649                                                 string msg = substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token));
 650                                                 cvar_set("utf8_enable", utf8_enable_save);
 651
 652                                                 Say(caller, false, tell_to, msg, true);
 653                                                 return;
 654                                         }
 655                                         else { print_to(caller, "You can't ^2tell^7 a message to yourself."); return; }
 656                                 }
 657                                 else if (argv(1) == "#0")
 658                                 {
 659                                         trigger_magicear_processmessage_forallears(caller, -1, NULL, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 660                                         return;
 661                                 }
 662                                 else { print_to(caller, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 663                         }
 664                 }
 665
 666                 default:
 667                         sprint(caller, "Incorrect parameters for ^2tell^7\n");
 668                 case CMD_REQUEST_USAGE:
 669                 {
 670                         sprint(caller, "\nUsage:^3 cmd tell client <message>\n");
 671                         sprint(caller, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 672                         return;
 673                 }
 674         }
 675 }
 676
 677 void ClientCommand_voice(entity caller, int request, int argc, string command)
 678 {
 679         switch (request)
 680         {
 681                 case CMD_REQUEST_COMMAND:
 682                 {
 683                         if (argv(1) != "")
 684                         {
 685                                 entity e = GetVoiceMessage(argv(1));
 686                                 if (!e)
 687                                 {
 688                                         sprint(caller, sprintf("Invalid voice. Use one of: %s\n", allvoicesamples));
 689                                         return;
 690                                 }
 691                                 string msg = "";
 692                                 if (argc >= 3)
 693                                         msg = substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
 694                                 VoiceMessage(caller, e, msg);
 695
 696                                 return;
 697                         }
 698                 }
 699
 700                 default:
 701                         sprint(caller, "Incorrect parameters for ^2voice^7\n");
 702                 case CMD_REQUEST_USAGE:
 703                 {
 704                         sprint(caller, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 705                         sprint(caller, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 706                         sprint(caller, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 707                         return;
 708                 }
 709         }
 710 }
 711
 712 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 713 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 714 void ClientCommand_(entity caller, int request)
 715 {
 716     switch(request)
 717     {
 718         case CMD_REQUEST_COMMAND:
 719         {
 720
 721             return; // never fall through to usage
 722         }
 723
 724         default:
 725         case CMD_REQUEST_USAGE:
 726         {
 727             sprint(caller, "\nUsage:^3 cmd \n");
 728             sprint(caller, "  No arguments required.\n");
 729             return;
 730         }
 731     }
 732 }
 733 */
 734
 735
 736 // =====================================
 737 //  Macro system for networked commands
 738 // =====================================
 739
 740 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 741 #define CLIENT_COMMANDS(ent, request, arguments, command) \
 742         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(ent, request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 743         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(ent, request, arguments), "Release version of the game") \
 744         CLIENT_COMMAND("join", ClientCommand_join(ent, request), "Become a player in the game") \
 745         CLIENT_COMMAND("minigame", ClientCommand_minigame(ent, request, arguments, command), "Start a minigame") \
 746         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(ent, request, arguments), "Retrieve mapshot picture from the server") \
 747         CLIENT_COMMAND("physics", ClientCommand_physics(ent, request, arguments), "Change physics set") \
 748         CLIENT_COMMAND("ready", ClientCommand_ready(ent, request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 749         CLIENT_COMMAND("say", ClientCommand_say(ent, request, arguments, command), "Print a message to chat to all players") \
 750         CLIENT_COMMAND("say_team", ClientCommand_say_team(ent, request, arguments, command), "Print a message to chat to all team mates") \
 751         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(ent, request, arguments), "Attempt to choose a team to join into") \
 752         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(ent, request, command), "Stuffcmd a command to your own client") \
 753         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(ent, request, arguments, command), "New system for sending a client cvar to the server") \
 754         CLIENT_COMMAND("spectate", ClientCommand_spectate(ent, request), "Become an observer") \
 755         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(ent, request, arguments), "Suggest a map to the mapvote at match end") \
 756         CLIENT_COMMAND("tell", ClientCommand_tell(ent, request, arguments, command), "Send a message directly to a player") \
 757         CLIENT_COMMAND("voice", ClientCommand_voice(ent, request, arguments, command), "Send voice message via sound") \
 758         CLIENT_COMMAND("wpeditor", ClientCommand_wpeditor(ent, request, arguments), "Waypoint editor commands") \
 759         /* nothing */
 760
 761 void ClientCommand_macro_help(entity caller)
 762 {
 763         #define CLIENT_COMMAND(name, function, description) \
 764                 { sprint(caller, "  ^2", name, "^7: ", description, "\n"); }
 765
 766         CLIENT_COMMANDS(NULL, 0, 0, "");
 767 #undef CLIENT_COMMAND
 768 }
 769
 770 float ClientCommand_macro_command(int argc, entity caller, string command)
 771 {
 772         #define CLIENT_COMMAND(name, function, description) \
 773                 { if (name == strtolower(argv(0))) { function; return true; } }
 774
 775         CLIENT_COMMANDS(caller, CMD_REQUEST_COMMAND, argc, command);
 776 #undef CLIENT_COMMAND
 777
 778         return false;
 779 }
 780
 781 float ClientCommand_macro_usage(int argc, entity caller)
 782 {
 783         #define CLIENT_COMMAND(name, function, description) \
 784                 { if (name == strtolower(argv(1))) { function; return true; } }
 785
 786         CLIENT_COMMANDS(caller, CMD_REQUEST_USAGE, argc, "");
 787 #undef CLIENT_COMMAND
 788
 789         return false;
 790 }
 791
 792 void ClientCommand_macro_write_aliases(float fh)
 793 {
 794         #define CLIENT_COMMAND(name, function, description) \
 795                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 796
 797         CLIENT_COMMANDS(NULL, 0, 0, "");
 798 #undef CLIENT_COMMAND
 799 }
 800
 801 // ======================================
 802 //  Main Function Called By Engine (cmd)
 803 // ======================================
 804 // If this function exists, server game code parses clientcommand before the engine code gets it.
 805
 806 void SV_ParseClientCommand(entity this, string command)
 807 {
 808         // If invalid UTF-8, don't even parse it
 809         string command2 = "";
 810         float len = strlen(command);
 811         float i;
 812         for (i = 0; i < len; ++i)
 813                 command2 = strcat(command2, chr2str(str2chr(command, i)));
 814         if (command != command2) return;
 815
 816         // if we're banned, don't even parse the command
 817         if (Ban_MaybeEnforceBanOnce(this)) return;
 818
 819         int argc = tokenize_console(command);
 820
 821         // Guide for working with argc arguments by example:
 822         // argc:   1    - 2      - 3     - 4
 823         // argv:   0    - 1      - 2     - 3
 824         // cmd     vote - master - login - password
 825
 826         // for floodcheck
 827         switch (strtolower(argv(0)))
 828         {
 829                 // exempt commands which are not subject to floodcheck
 830                 case "begin": break;                               // handled by engine in host_cmd.c
 831                 case "download": break;                            // handled by engine in cl_parse.c
 832                 case "mv_getpicture": break;                       // handled by server in this file
 833                 case "wpeditor": break;                            // handled by server in this file
 834                 case "pause": break;                               // handled by engine in host_cmd.c
 835                 case "prespawn": break;                            // handled by engine in host_cmd.c
 836                 case "sentcvar": break;                            // handled by server in this file
 837                 case "spawn": break;                               // handled by engine in host_cmd.c
 838                 case "c2s": Net_ClientCommand(this, command); return; // handled by net.qh
 839
 840                 default:
 841                         if (SV_ParseClientCommand_floodcheck(this)) break; // "true": continue, as we're not flooding yet
 842                         else return;                                   // "false": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 843         }
 844
 845         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 846         if (argv(0) == "help")
 847         {
 848                 if (argc == 1)
 849                 {
 850                         sprint(this, "\nClient networked commands:\n");
 851                         ClientCommand_macro_help(this);
 852
 853                         sprint(this, "\nCommon networked commands:\n");
 854                         CommonCommand_macro_help(this);
 855
 856                         sprint(this, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 857                         sprint(this, "For help about a specific command, type cmd help COMMAND\n");
 858                         return;
 859                 }
 860                 else if (CommonCommand_macro_usage(argc, this))  // Instead of trying to call a command, we're going to see detailed information about it
 861                 {
 862                         return;
 863                 }
 864                 else if (ClientCommand_macro_usage(argc, this))  // same, but for normal commands now
 865                 {
 866                         return;
 867                 }
 868         }
 869         else if (MUTATOR_CALLHOOK(SV_ParseClientCommand, this, strtolower(argv(0)), argc, command))
 870         {
 871                 return;  // handled by a mutator
 872         }
 873         else if (CheatCommand(this, argc))
 874         {
 875                 return;  // handled by server/cheats.qc
 876         }
 877         else if (CommonCommand_macro_command(argc, this, command))
 878         {
 879                 return;                                          // handled by server/command/common.qc
 880         }
 881         else if (ClientCommand_macro_command(argc, this, command)) // continue as usual and scan for normal commands
 882         {
 883                 return;                                          // handled by one of the above ClientCommand_* functions
 884         }
 885         else
 886         {
 887                 clientcommand(this, command);
 888         }
 889 }