qcsrc/server/command/cmd.qc

   1 #include "cmd.qh"
   2
   3 #include <common/command/_mod.qh>
   4 #include <common/constants.qh>
   5 #include <common/deathtypes/all.qh>
   6 #include <common/effects/all.qh>
   7 #include <common/gamemodes/_mod.qh>
   8 #include <common/mapinfo.qh>
   9 #include <common/mapobjects/triggers.qh>
  10 #include <common/minigames/sv_minigames.qh>
  11 #include <common/monsters/_mod.qh>
  12 #include <common/monsters/sv_monsters.qh>
  13 #include <common/monsters/sv_spawn.qh>
  14 #include <common/notifications/all.qh>
  15 #include <common/physics/player.qh>
  16 #include <common/teams.qh>
  17 #include <common/util.qh>
  18 #include <common/vehicles/all.qh>
  19 #include <lib/warpzone/common.qh>
  20 #include <server/bot/api.qh>
  21 #include <server/bot/default/waypoints.qh>
  22 #include <server/campaign.qh>
  23 #include <server/chat.qh>
  24 #include <server/cheats.qh>
  25 #include <server/client.qh>
  26 #include <server/clientkill.qh>
  27 #include <server/command/common.qh>
  28 #include <server/command/getreplies.qh>
  29 #include <server/command/vote.qh>
  30 #include <server/ipban.qh>
  31 #include <server/mapvoting.qh>
  32 #include <server/mutators/_mod.qh>
  33 #include <server/player.qh>
  34 #include <server/scores.qh>
  35 #include <server/teamplay.qh>
  36 #include <server/world.qh>
  37
  38 // =========================================================
  39 //  Server side networked commands code, reworked by Samual
  40 //  Last updated: December 28th, 2011
  41 // =========================================================
  42
  43
  44 // =======================
  45 //  Command Sub-Functions
  46 // =======================
  47
  48 void ClientCommand_autoswitch(entity caller, int request, int argc)
  49 {
  50         switch (request)
  51         {
  52                 case CMD_REQUEST_COMMAND:
  53                 {
  54                         if (argv(1) != "")
  55                         {
  56                                 CS_CVAR(caller).cvar_cl_autoswitch = InterpretBoolean(argv(1));
  57                                 sprint(caller, strcat("^1autoswitch is currently turned ", (CS_CVAR(caller).cvar_cl_autoswitch ? "on" : "off"), ".\n"));
  58                                 return;
  59                         }
  60                 }
  61
  62                 default:
  63                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
  64                 case CMD_REQUEST_USAGE:
  65                 {
  66                         sprint(caller, "\nUsage:^3 cmd autoswitch <selection>\n");
  67                         sprint(caller, "  Where <selection> controls if autoswitch is on or off.\n");
  68                         return;
  69                 }
  70         }
  71 }
  72
  73 void ClientCommand_clientversion(entity caller, int request, int argc)  // internal command, used only by code
  74 {
  75         switch (request)
  76         {
  77                 case CMD_REQUEST_COMMAND:
  78                 {
  79                         if (argv(1) != "")
  80                         {
  81                                 if (IS_CLIENT(caller))
  82                                 {
  83                                         CS(caller).version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
  84
  85                                         if (CS(caller).version < autocvar_gameversion_min || CS(caller).version > autocvar_gameversion_max)
  86                                         {
  87                                                 CS(caller).version_mismatch = true;
  88                                                 ClientKill_TeamChange(caller, -2);  // observe
  89                                         }
  90                                         else if (autocvar_g_campaign || autocvar_g_balance_teams)
  91                                         {
  92                                                 // JoinBestTeam(caller, false, true);
  93                                         }
  94                                         else if (teamplay && !autocvar_sv_spectate && !(Player_GetForcedTeamIndex(caller) > 0))
  95                                         {
  96                                                 TRANSMUTE(Observer, caller);  // really?
  97                                                 stuffcmd(caller, "scoreboard_team_selection\n");
  98                                         }
  99                                 }
 100
 101                                 return;
 102                         }
 103                 }
 104
 105                 default:
 106                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 107                 case CMD_REQUEST_USAGE:
 108                 {
 109                         sprint(caller, "\nUsage:^3 cmd clientversion <version>\n");
 110                         sprint(caller, "  Where <version> is the game version reported by caller.\n");
 111                         return;
 112                 }
 113         }
 114 }
 115
 116 void ClientCommand_mv_getpicture(entity caller, int request, int argc)  // internal command, used only by code
 117 {
 118         switch (request)
 119         {
 120                 case CMD_REQUEST_COMMAND:
 121                 {
 122                         if (argv(1) != "")
 123                         {
 124                                 if (intermission_running) MapVote_SendPicture(caller, stof(argv(1)));
 125
 126                                 return;
 127                         }
 128                 }
 129
 130                 default:
 131                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 132                 case CMD_REQUEST_USAGE:
 133                 {
 134                         sprint(caller, "\nUsage:^3 cmd mv_getpicture <mapid>\n");
 135                         sprint(caller, "  Where <mapid> is the id number of the map to request an image of on the map vote selection menu.\n");
 136                         return;
 137                 }
 138         }
 139 }
 140
 141 void ClientCommand_wpeditor(entity caller, int request, int argc)
 142 {
 143         switch (request)
 144         {
 145                 case CMD_REQUEST_COMMAND:
 146                 {
 147                         if (!waypointeditor_enabled)
 148                         {
 149                                 sprint(caller, "ERROR: this command works only if the waypoint editor is on\n");
 150                                 return;
 151                         }
 152
 153                         if (argv(1) != "")
 154                         {
 155                                 if (argv(1) == "spawn")
 156                                 {
 157                                         string s = argv(2);
 158                                         if (!IS_PLAYER(caller))
 159                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 160                                         else
 161                                                 waypoint_spawn_fromeditor(caller, (s == "crosshair"), (s == "jump"), (s == "crouch"), (s == "support"));
 162                                         return;
 163                                 }
 164                                 else if (argv(1) == "remove")
 165                                 {
 166                                         if (!IS_PLAYER(caller))
 167                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 168                                         else
 169                                                 waypoint_remove_fromeditor(caller);
 170                                         return;
 171                                 }
 172                                 else if (argv(1) == "hardwire")
 173                                 {
 174                                         string s = argv(2);
 175                                         waypoint_start_hardwiredlink(caller, (s == "crosshair"));
 176                                         return;
 177                                 }
 178                                 else if (argv(1) == "lock")
 179                                 {
 180                                         waypoint_lock(caller);
 181                                         return;
 182                                 }
 183                                 else if (argv(1) == "unreachable")
 184                                 {
 185                                         if (!IS_PLAYER(caller))
 186                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 187                                         else
 188                                                 waypoint_unreachable(caller);
 189                                         return;
 190                                 }
 191                                 else if (argv(1) == "saveall")
 192                                 {
 193                                         waypoint_saveall();
 194                                         return;
 195                                 }
 196                                 else if (argv(1) == "relinkall")
 197                                 {
 198                                         waypoint_schedulerelinkall();
 199                                         return;
 200                                 }
 201                                 else if (argv(1) == "symaxis")
 202                                 {
 203                                         if (argv(2) == "set" || argv(2) == "get")
 204                                         {
 205                                                 waypoint_getSymmetricalAxis_cmd(caller, (argv(2) == "set"), 3);
 206                                                 return;
 207                                         }
 208                                 }
 209                                 else if (argv(1) == "symorigin")
 210                                 {
 211                                         if (argv(2) == "set" || argv(2) == "get")
 212                                         {
 213                                                 waypoint_getSymmetricalOrigin_cmd(caller, (argv(2) == "set"), 3);
 214                                                 return;
 215                                         }
 216                                 }
 217                         }
 218                 }
 219
 220                 default:
 221                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 222                 case CMD_REQUEST_USAGE:
 223                 {
 224                         sprint(caller, "\nUsage:^3 cmd wpeditor <action>\n");
 225                         sprint(caller, "  Where <action> can be:\n");
 226                         sprint(caller, "   ^2spawn^7: spawns a waypoint at player's position\n");
 227                         sprint(caller, "   ^2remove^7: removes player's nearest waypoint\n");
 228                         sprint(caller, "   ^2unreachable^7: reveals waypoints and items unreachable from the current position and spawnpoints without a nearest waypoint\n");
 229                         sprint(caller, "   ^2saveall^7: saves all waypoints and links to file\n");
 230                         sprint(caller, "   ^2relinkall^7: relinks all waypoints as if they were respawned\n");
 231                         sprint(caller, "   ^2spawn crosshair^7: spawns a waypoint at crosshair's position\n");
 232                         sprint(caller, "   ^7 in general useful to create special and hardwired links with ease from existing waypoints\n");
 233                         sprint(caller, "   ^7 in particular it's the only way to create custom jumppad waypoints (spawn another waypoint to create destination))\n");
 234                         sprint(caller, "   ^2spawn jump^7: spawns a jump waypoint (place it at least 60 qu before jump start, spawn another waypoint to create destination)\n");
 235                         sprint(caller, "   ^2spawn crouch^7: spawns a crouch waypoint (it links only to very close waypoints)\n");
 236                         sprint(caller, "   ^2spawn support^7: spawns a support waypoint (spawn another waypoint to create destination from which all incoming links are removed)\n");
 237                         sprint(caller, "   ^7 useful to replace links to problematic jumppad/teleport waypoints\n");
 238                         sprint(caller, "   ^2hardwire^7: marks the nearest waypoint as origin of a new hardwired link (spawn another waypoint over an existing one to create destination)\n");
 239                         sprint(caller, "   ^2hardwire crosshair^7: marks the waypoint at crosshair instead of the nearest waypoint\n");
 240                         sprint(caller, "   ^2lock^7: locks link display of the aimed waypoint (unlocks if no waypoint is found at crosshair's position)\n");
 241                         sprint(caller, "   ^2symorigin get|set\n");
 242                         sprint(caller, "   ^2symorigin get|set <p1> <p2> ... <pX>\n");
 243                         sprint(caller, "   ^2symaxis get|set <p1> <p2>\n");
 244                         sprint(caller, "   ^7 where <p1> <p2> ... <pX> are positions (\"x y z\", z can be omitted) that you know are perfectly symmetrical"
 245                                                                 " so you can determine origin/axis of symmetry of maps without ctf flags or where flags aren't perfectly symmetrical\n");
 246                         sprint(caller, "  See ^5wpeditor_menu^7 for a selectable list of various commands and useful settings to edit waypoints.\n");
 247                         return;
 248                 }
 249         }
 250 }
 251
 252 void ClientCommand_join(entity caller, int request)
 253 {
 254         switch (request)
 255         {
 256                 case CMD_REQUEST_COMMAND:
 257                 {
 258                         if (!game_stopped && IS_CLIENT(caller) && !IS_PLAYER(caller))
 259                         {
 260                                 if (joinAllowed(caller))
 261                                         Join(caller);
 262                                 else if(time < CS(caller).jointime + MIN_SPEC_TIME)
 263                                         CS(caller).autojoin_checked = -1;
 264                         }
 265                         CS(caller).parm_idlesince = time;
 266
 267                         return;  // never fall through to usage
 268                 }
 269
 270                 default:
 271                 case CMD_REQUEST_USAGE:
 272                 {
 273                         sprint(caller, "\nUsage:^3 cmd join\n");
 274                         sprint(caller, "  No arguments required.\n");
 275                         return;
 276                 }
 277         }
 278 }
 279
 280 void ClientCommand_kill(entity caller, int request)
 281 {
 282         switch (request)
 283         {
 284                 case CMD_REQUEST_COMMAND:
 285                 {
 286                         if(IS_SPEC(caller) || IS_OBSERVER(caller))
 287                                 return; // no point warning about this, command does nothing
 288
 289                         if(GetResource(caller, RES_HEALTH) <= 0)
 290                         {
 291                                 sprint(caller, "Can't die - you are already dead!\n");
 292                                 return;
 293                         }
 294
 295                         ClientKill(caller);
 296
 297                         return;  // never fall through to usage
 298                 }
 299
 300                 default:
 301                 case CMD_REQUEST_USAGE:
 302                 {
 303                         sprint(caller, "\nUsage:^3 cmd kill\n");
 304                         sprint(caller, "  No arguments required.\n");
 305                         return;
 306                 }
 307         }
 308 }
 309
 310 void ClientCommand_physics(entity caller, int request, int argc)
 311 {
 312         switch (request)
 313         {
 314                 case CMD_REQUEST_COMMAND:
 315                 {
 316                         string command = strtolower(argv(1));
 317
 318                         if (!autocvar_g_physics_clientselect)
 319                         {
 320                                 sprint(caller, "Client physics selection is currently disabled.\n");
 321                                 return;
 322                         }
 323
 324                         if (command == "list" || command == "help")
 325                         {
 326                                 sprint(caller, strcat("Available physics sets: \n\n", autocvar_g_physics_clientselect_options, " default\n"));
 327                                 return;
 328                         }
 329
 330                         if (Physics_Valid(command) || command == "default")
 331                         {
 332                                 stuffcmd(caller, strcat("\nseta cl_physics ", command, "\n"));
 333                                 sprint(caller, strcat("^2Physics set successfully changed to ^3", command, "\n"));
 334                                 return;
 335                         }
 336                 }
 337
 338                 default:
 339                         sprint(caller, strcat("Current physics set: ^3", CS_CVAR(caller).cvar_cl_physics, "\n"));
 340                 case CMD_REQUEST_USAGE:
 341                 {
 342                         sprint(caller, "\nUsage:^3 cmd physics <physics>\n");
 343                         sprint(caller, "  See 'cmd physics list' for available physics sets.\n");
 344                         sprint(caller, "  Argument 'default' resets to standard physics.\n");
 345                         return;
 346                 }
 347         }
 348 }
 349
 350 void ClientCommand_ready(entity caller, int request)
 351 {
 352         switch (request)
 353         {
 354                 case CMD_REQUEST_COMMAND:
 355                 {
 356                         if (warmup_stage || g_race_qualifying == 2)
 357                         if (IS_PLAYER(caller) || INGAME_JOINED(caller))
 358                         {
 359                                 if (caller.ready) // toggle
 360                                 {
 361                                         caller.ready = false;
 362                                         bprint(playername(caller.netname, caller.team, false), "^2 is ^1NOT^2 ready\n");
 363                                 }
 364                                 else
 365                                 {
 366                                         caller.ready = true;
 367                                         bprint(playername(caller.netname, caller.team, false), "^2 is ready\n");
 368                                 }
 369                                 ReadyCount();
 370                         }
 371                         return;  // never fall through to usage
 372                 }
 373
 374                 default:
 375                 case CMD_REQUEST_USAGE:
 376                 {
 377                         sprint(caller, "\nUsage:^3 cmd ready\n");
 378                         sprint(caller, "  No arguments required.\n");
 379                         return;
 380                 }
 381         }
 382 }
 383
 384 void ClientCommand_say(entity caller, int request, int argc, string command)
 385 {
 386         switch (request)
 387         {
 388                 case CMD_REQUEST_COMMAND:
 389                 {
 390                         if (argc >= 2)   Say(caller, false, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 391                         return;  // never fall through to usage
 392                 }
 393
 394                 default:
 395                 case CMD_REQUEST_USAGE:
 396                 {
 397                         sprint(caller, "\nUsage:^3 cmd say <message>\n");
 398                         sprint(caller, "  Where <message> is the string of text to say.\n");
 399                         return;
 400                 }
 401         }
 402 }
 403
 404 void ClientCommand_say_team(entity caller, int request, int argc, string command)
 405 {
 406         switch (request)
 407         {
 408                 case CMD_REQUEST_COMMAND:
 409                 {
 410                         if (argc >= 2)
 411                                 Say(caller, true, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 412                         return;  // never fall through to usage
 413                 }
 414
 415                 default:
 416                 case CMD_REQUEST_USAGE:
 417                 {
 418                         sprint(caller, "\nUsage:^3 cmd say_team <message>\n");
 419                         sprint(caller, "  Where <message> is the string of text to say.\n");
 420                         return;
 421                 }
 422         }
 423 }
 424
 425 .bool team_selected;
 426 void ClientCommand_selectteam(entity caller, int request, int argc)
 427 {
 428         switch (request)
 429         {
 430                 case CMD_REQUEST_COMMAND:
 431                 {
 432                         if (argv(1) == "")
 433                         {
 434                                 return;
 435                         }
 436                         if (!IS_CLIENT(caller))
 437                         {
 438                                 return;
 439                         }
 440                         if (!teamplay)
 441                         {
 442                                 sprint(caller, "^7selectteam can only be used in teamgames\n");
 443                                 return;
 444                         }
 445                         if (Player_GetForcedTeamIndex(caller) > 0)
 446                         {
 447                                 sprint(caller, "^7selectteam can not be used as your team is forced\n");
 448                                 return;
 449                         }
 450                         if (lockteams)
 451                         {
 452                                 sprint(caller, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 453                                 return;
 454                         }
 455
 456                         float team_num = Team_ColorToTeam(argv(1));
 457                         if (team_num == -1) // invalid
 458                                 return;
 459                         if (caller.team == team_num && team_num && !IS_DEAD(caller))
 460                         {
 461                                 sprint(caller, "^7You already are on that team.\n");
 462                                 return;
 463                         }
 464                         if (CS(caller).wasplayer && autocvar_g_changeteam_banned)
 465                         {
 466                                 sprint(caller, "^1You cannot change team, forbidden by the server.\n");
 467                                 return;
 468                         }
 469                         if (team_num && autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 470                         {
 471                                 entity balance = TeamBalance_CheckAllowedTeams(caller);
 472                                 TeamBalance_GetTeamCounts(balance, caller);
 473                                 if ((Team_IndexToBit(Team_TeamToIndex(team_num)) &
 474                                         TeamBalance_FindBestTeams(balance, caller, false)) == 0)
 475                                 {
 476                                         Send_Notification(NOTIF_ONE, caller, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 477                                         TeamBalance_Destroy(balance);
 478                                         return;
 479                                 }
 480                                 TeamBalance_Destroy(balance);
 481                         }
 482                         if (team_num)
 483                                 ClientKill_TeamChange(caller, team_num);
 484                         else // auto
 485                                 ClientKill_TeamChange(caller, -1);
 486
 487                         if (!IS_PLAYER(caller))
 488                         {
 489                                 caller.team_selected = true; // avoids asking again for team selection on join
 490                         }
 491                         return;
 492                 }
 493                 default:
 494                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 495                 case CMD_REQUEST_USAGE:
 496                 {
 497                         sprint(caller, "\nUsage:^3 cmd selectteam <team>\n");
 498                         sprint(caller, "  Where <team> is the prefered team to try and join.\n");
 499                         sprint(caller, "  Full list of options here: red, blue, yellow, pink, auto.\n");
 500                         return;
 501                 }
 502         }
 503 }
 504
 505 void ClientCommand_selfstuff(entity caller, int request, string command)
 506 {
 507         switch (request)
 508         {
 509                 case CMD_REQUEST_COMMAND:
 510                 {
 511                         if (argv(1) != "")
 512                         {
 513                                 stuffcmd(caller, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 514                                 return;
 515                         }
 516                 }
 517
 518                 default:
 519                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 520                 case CMD_REQUEST_USAGE:
 521                 {
 522                         sprint(caller, "\nUsage:^3 cmd selfstuff <command>\n");
 523                         sprint(caller, "  Where <command> is the string to be stuffed to your client.\n");
 524                         return;
 525                 }
 526         }
 527 }
 528
 529 void ClientCommand_sentcvar(entity caller, int request, int argc)
 530 {
 531         switch (request)
 532         {
 533                 case CMD_REQUEST_COMMAND:
 534                 {
 535                         if (argc >= 3)
 536                         {
 537                         // NOTE: client-side settings do not exist on the server, this functionality has been deprecated
 538                         #if 0
 539                                 if (argc == 2)  // undefined cvar: use the default value on the server then
 540                                 {
 541                                         string s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 542                                         tokenize_console(s);
 543                                 }
 544                         #endif
 545
 546                                 GetCvars(caller, CS_CVAR(caller), 1);
 547
 548                                 return;
 549                         }
 550                 }
 551
 552                 default:
 553                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 554                 case CMD_REQUEST_USAGE:
 555                 {
 556                         sprint(caller, "\nUsage:^3 cmd sentcvar <cvar> <arguments>\n");
 557                         sprint(caller, "  Where <cvar> is the cvar plus arguments to send to the server.\n");
 558                         return;
 559                 }
 560         }
 561 }
 562
 563 void ClientCommand_spectate(entity caller, int request)
 564 {
 565         switch (request)
 566         {
 567                 case CMD_REQUEST_COMMAND:
 568                 {
 569                         if (!intermission_running && IS_CLIENT(caller))
 570                         {
 571                                 if(argv(1) != "")
 572                                 {
 573                                         if(IS_SPEC(caller) || IS_OBSERVER(caller))
 574                                         {
 575                                                 entity client = GetFilteredEntity(argv(1));
 576                                                 int spec_accepted = VerifyClientEntity(client, false, false);
 577                                                 if(spec_accepted > 0 && IS_PLAYER(client))
 578                                                 {
 579                                                         bool caller_is_observer = (IS_OBSERVER(caller));
 580                                                         Spectate(caller, client);
 581                                                         if (caller_is_observer)
 582                                                                 TRANSMUTE(Spectator, caller);
 583                                                 }
 584                                                 else
 585                                                         sprint(caller, "Can't spectate ", argv(1), "^7\n");
 586                                         }
 587                                         else
 588                                                 sprint(caller, "cmd spectate <client> only works when you are spectator/observer\n");
 589                                         return;
 590                                 }
 591
 592                                 int mutator_returnvalue = MUTATOR_CALLHOOK(ClientCommand_Spectate, caller);
 593
 594                                 if (mutator_returnvalue == MUT_SPECCMD_RETURN) return;
 595
 596                                 if ((IS_PLAYER(caller) || mutator_returnvalue == MUT_SPECCMD_FORCE))
 597                                 if (autocvar_sv_spectate == 1)
 598                                         ClientKill_TeamChange(caller, -2); // observe
 599                         }
 600                         return; // never fall through to usage
 601                 }
 602
 603                 default:
 604                 case CMD_REQUEST_USAGE:
 605                 {
 606                         sprint(caller, "\nUsage:^3 cmd spectate [<client>]\n");
 607                         sprint(caller, "  Where <client> can be the player to spectate.\n");
 608                         return;
 609                 }
 610         }
 611 }
 612
 613 void ClientCommand_suggestmap(entity caller, int request, int argc)
 614 {
 615         switch (request)
 616         {
 617                 case CMD_REQUEST_COMMAND:
 618                 {
 619                         if (argv(1) != "")
 620                         {
 621                                 sprint(caller, strcat(MapVote_Suggest(caller, argv(1)), "\n"));
 622                                 return;
 623                         }
 624                 }
 625
 626                 default:
 627                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 628                 case CMD_REQUEST_USAGE:
 629                 {
 630                         sprint(caller, "\nUsage:^3 cmd suggestmap <map>\n");
 631                         sprint(caller, "  Where <map> is the name of the map to suggest.\n");
 632                         return;
 633                 }
 634         }
 635 }
 636
 637 void ClientCommand_tell(entity caller, int request, int argc, string command)
 638 {
 639         switch (request)
 640         {
 641                 case CMD_REQUEST_COMMAND:
 642                 {
 643                         if (argc >= 3)
 644                         {
 645                                 if(!IS_CLIENT(caller) && IS_REAL_CLIENT(caller)) // connecting
 646                                 {
 647                                         print_to(caller, "You can't ^2tell^7 a message while connecting.");
 648                                         return;
 649                                 }
 650
 651                                 entity tell_to = GetIndexedEntity(argc, 1);
 652                                 float tell_accepted = VerifyClientEntity(tell_to, true, false);
 653
 654                                 if (tell_accepted > 0)   // the target is a real client
 655                                 {
 656                                         if (tell_to != caller) // and we're allowed to send to them :D
 657                                         {
 658                                                 // workaround for argv indexes indexing ascii chars instead of utf8 chars
 659                                                 // In this case when the player name contains utf8 chars
 660                                                 // the message gets partially trimmed in the beginning.
 661                                                 // Potentially this bug affects any substring call that uses
 662                                                 // argv_start_index and argv_end_index.
 663
 664                                                 string utf8_enable_save = cvar_string("utf8_enable");
 665                                                 cvar_set("utf8_enable", "0");
 666                                                 string msg = substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token));
 667                                                 cvar_set("utf8_enable", utf8_enable_save);
 668
 669                                                 Say(caller, false, tell_to, msg, true);
 670                                                 return;
 671                                         }
 672                                         else { print_to(caller, "You can't ^2tell^7 a message to yourself."); return; }
 673                                 }
 674                                 else if (argv(1) == "#0")
 675                                 {
 676                                         trigger_magicear_processmessage_forallears(caller, -1, NULL, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 677                                         return;
 678                                 }
 679                                 else { print_to(caller, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 680                         }
 681                 }
 682
 683                 default:
 684                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 685                 case CMD_REQUEST_USAGE:
 686                 {
 687                         sprint(caller, "\nUsage:^3 cmd tell <client> <message>\n");
 688                         sprint(caller, "  Where <client> is the entity number or name of the player to send <message> to.\n");
 689                         return;
 690                 }
 691         }
 692 }
 693
 694 void ClientCommand_voice(entity caller, int request, int argc, string command)
 695 {
 696         switch (request)
 697         {
 698                 case CMD_REQUEST_COMMAND:
 699                 {
 700                         if (argv(1) != "")
 701                         {
 702                                 entity e = GetVoiceMessage(argv(1));
 703                                 if (!e)
 704                                 {
 705                                         sprint(caller, sprintf("Invalid voice. Use one of: %s\n", allvoicesamples));
 706                                         return;
 707                                 }
 708                                 if (IS_DEAD(caller))
 709                                 {
 710                                         // don't warn the caller when trying to taunt while dead, just don't play any sounds!
 711                                         // we still allow them to see warnings if it's invalid, so a dead player can find out the sounds in peace
 712                                         return;
 713                                 }
 714                                 if (IS_SPEC(caller) || IS_OBSERVER(caller))
 715                                 {
 716                                         // observers/spectators have no player model of their own to play taunts from
 717                                         // again, allow them to see warnings
 718                                         return;
 719                                 }
 720                                 string msg = "";
 721                                 if (argc >= 3)
 722                                         msg = substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
 723                                 VoiceMessage(caller, e, msg);
 724
 725                                 return;
 726                         }
 727                 }
 728
 729                 default:
 730                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 731                 case CMD_REQUEST_USAGE:
 732                 {
 733                         sprint(caller, "\nUsage:^3 cmd voice <voicetype> [<message>]\n");
 734                         sprint(caller, "  <voicetype> is the type of voice message, it can be one of these:\n");
 735                         sprint(caller, sprintf("   %s\n", allvoicesamples));
 736                         sprint(caller, "  and <message> is the text message to send.\n");
 737                         return;
 738                 }
 739         }
 740 }
 741
 742 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 743 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 744 void ClientCommand_(entity caller, int request)
 745 {
 746     switch(request)
 747     {
 748         case CMD_REQUEST_COMMAND:
 749         {
 750
 751             return; // never fall through to usage
 752         }
 753
 754         default:
 755         case CMD_REQUEST_USAGE:
 756         {
 757             sprint(caller, "\nUsage:^3 cmd \n");
 758             sprint(caller, "  No arguments required.\n");
 759             return;
 760         }
 761     }
 762 }
 763 */
 764
 765
 766 // =====================================
 767 //  Macro system for networked commands
 768 // =====================================
 769
 770 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 771 #define CLIENT_COMMANDS(ent, request, arguments, command) \
 772         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(ent, request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 773         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(ent, request, arguments), "Release version of the game") \
 774         CLIENT_COMMAND("join", ClientCommand_join(ent, request), "Become a player in the game") \
 775         CLIENT_COMMAND("kill", ClientCommand_kill(ent, request), "Become a member of the dead") \
 776         CLIENT_COMMAND("minigame", ClientCommand_minigame(ent, request, arguments, command), "Start a minigame") \
 777         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(ent, request, arguments), "Retrieve mapshot picture from the server") \
 778         CLIENT_COMMAND("physics", ClientCommand_physics(ent, request, arguments), "Change physics set") \
 779         CLIENT_COMMAND("ready", ClientCommand_ready(ent, request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 780         CLIENT_COMMAND("say", ClientCommand_say(ent, request, arguments, command), "Print a message to chat to all players") \
 781         CLIENT_COMMAND("say_team", ClientCommand_say_team(ent, request, arguments, command), "Print a message to chat to all team mates") \
 782         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(ent, request, arguments), "Attempt to choose a team to join into") \
 783         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(ent, request, command), "Stuffcmd a command to your own client") \
 784         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(ent, request, arguments), "New system for sending a client cvar to the server") \
 785         CLIENT_COMMAND("spectate", ClientCommand_spectate(ent, request), "Become an observer") \
 786         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(ent, request, arguments), "Suggest a map to the mapvote at match end") \
 787         CLIENT_COMMAND("tell", ClientCommand_tell(ent, request, arguments, command), "Send a message directly to a player") \
 788         CLIENT_COMMAND("voice", ClientCommand_voice(ent, request, arguments, command), "Send voice message via sound") \
 789         CLIENT_COMMAND("wpeditor", ClientCommand_wpeditor(ent, request, arguments), "Waypoint editor commands") \
 790         /* nothing */
 791
 792 void ClientCommand_macro_help(entity caller)
 793 {
 794         #define CLIENT_COMMAND(name, function, description) \
 795                 { sprint(caller, "  ^2", name, "^7: ", description, "\n"); }
 796
 797         CLIENT_COMMANDS(NULL, 0, 0, "");
 798 #undef CLIENT_COMMAND
 799 }
 800
 801 float ClientCommand_macro_command(int argc, entity caller, string command)
 802 {
 803         #define CLIENT_COMMAND(name, function, description) \
 804                 { if (name == strtolower(argv(0))) { function; return true; } }
 805
 806         CLIENT_COMMANDS(caller, CMD_REQUEST_COMMAND, argc, command);
 807 #undef CLIENT_COMMAND
 808
 809         return false;
 810 }
 811
 812 float ClientCommand_macro_usage(int argc, entity caller)
 813 {
 814         #define CLIENT_COMMAND(name, function, description) \
 815                 { if (name == strtolower(argv(1))) { function; return true; } }
 816
 817         CLIENT_COMMANDS(caller, CMD_REQUEST_USAGE, argc, "");
 818 #undef CLIENT_COMMAND
 819
 820         return false;
 821 }
 822
 823 void ClientCommand_macro_write_aliases(float fh)
 824 {
 825         #define CLIENT_COMMAND(name, function, description) \
 826                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 827
 828         CLIENT_COMMANDS(NULL, 0, 0, "");
 829 #undef CLIENT_COMMAND
 830 }
 831
 832 // ======================================
 833 //  Main Function Called By Engine (cmd)
 834 // ======================================
 835 // If this function exists, server game code parses clientcommand before the engine code gets it.
 836
 837 void SV_ParseClientCommand(entity this, string command)
 838 {
 839         // If invalid UTF-8, don't even parse it
 840         string command2 = "";
 841         float len = strlen(command);
 842         float i;
 843         for (i = 0; i < len; ++i)
 844                 command2 = strcat(command2, chr2str(str2chr(command, i)));
 845         if (command != command2) return;
 846
 847         // if we're banned, don't even parse the command
 848         if (Ban_MaybeEnforceBanOnce(this)) return;
 849
 850         int argc = tokenize_console(command);
 851
 852         // Guide for working with argc arguments by example:
 853         // argc:   1    - 2      - 3     - 4
 854         // argv:   0    - 1      - 2     - 3
 855         // cmd     vote - master - login - password
 856
 857         // for floodcheck
 858         switch (strtolower(argv(0)))
 859         {
 860                 // exempt commands which are not subject to floodcheck
 861                 case "begin": break;                               // handled by engine in host_cmd.c
 862                 case "download": break;                            // handled by engine in cl_parse.c
 863                 case "mv_getpicture": break;                       // handled by server in this file
 864                 case "wpeditor": break;                            // handled by server in this file
 865                 case "pause": break;                               // handled by engine in host_cmd.c
 866                 case "prespawn": break;                            // handled by engine in host_cmd.c
 867                 case "sentcvar": break;                            // handled by server in this file
 868                 case "spawn": break;                               // handled by engine in host_cmd.c
 869                 case "say": case "say_team": case "tell": break;   // chat has its own flood control in chat.qc
 870                 case "color": case "topcolor": case "bottomcolor": // handled by engine in host_cmd.c
 871                         if(!IS_CLIENT(this)) // on connection
 872                         {
 873                                 // since gamecode doesn't have any calls earlier than this, do the connecting message here
 874                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_CONNECTING, this.netname);
 875                         }
 876                         if(teamplay)
 877                                 return;
 878                         break;
 879                 case "c2s": Net_ClientCommand(this, command); return; // handled by net.qh
 880
 881                 // on connection, client sends all of these
 882                 case "name": case "rate": case "rate_burstsize": case "playermodel": case "playerskin": case "clientversion":
 883                         if(!IS_CLIENT(this)) break;
 884                         // else fall through to default: flood control
 885                 default:
 886                         if (!timeout_status)  // not while paused
 887                         {
 888                                 entity store = IS_CLIENT(this) ? CS(this) : this; // unfortunately, we need to store these on the client initially
 889                                 // this is basically the same as the chat flood control
 890                                 if (time < store.cmd_floodtime)
 891                                 {
 892                                         sprint(this, strcat("^3CMD FLOOD CONTROL: wait ^1", ftos(store.cmd_floodtime - time), "^3 seconds, command was: ", command, "\n"));
 893                                         return;  // too much spam, halt
 894                                 }
 895                                 else
 896                                         store.cmd_floodtime = max(time - autocvar_sv_clientcommand_antispam_count * autocvar_sv_clientcommand_antispam_time, store.cmd_floodtime) + autocvar_sv_clientcommand_antispam_time;
 897                         }
 898                         break;  // continue, as we're not flooding yet
 899         }
 900
 901         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 902         if (argv(0) == "help")
 903         {
 904                 if (argc == 1)
 905                 {
 906                         sprint(this, "\nClient networked commands:\n");
 907                         ClientCommand_macro_help(this);
 908
 909                         sprint(this, "\nCommon networked commands:\n");
 910                         CommonCommand_macro_help(this);
 911
 912                         sprint(this, "\nUsage:^3 cmd <command>^7, where possible commands are listed above.\n");
 913                         sprint(this, "For help about a specific command, type cmd help <command>\n");
 914                         return;
 915                 }
 916                 else if (CommonCommand_macro_usage(argc, this))  // Instead of trying to call a command, we're going to see detailed information about it
 917                 {
 918                         return;
 919                 }
 920                 else if (ClientCommand_macro_usage(argc, this))  // same, but for normal commands now
 921                 {
 922                         return;
 923                 }
 924         }
 925         else if (MUTATOR_CALLHOOK(SV_ParseClientCommand, this, strtolower(argv(0)), argc, command))
 926         {
 927                 return;  // handled by a mutator
 928         }
 929         else if (CheatCommand(this, argc))
 930         {
 931                 return;  // handled by server/cheats.qc
 932         }
 933         else if (CommonCommand_macro_command(argc, this, command))
 934         {
 935                 return;                                          // handled by server/command/common.qc
 936         }
 937         else if (ClientCommand_macro_command(argc, this, command)) // continue as usual and scan for normal commands
 938         {
 939                 return;                                          // handled by one of the above ClientCommand_* functions
 940         }
 941         else
 942         {
 943                 clientcommand(this, command);
 944         }
 945 }