qcsrc/server/command/cmd.qc

   1 #include "cmd.qh"
   2
   3 #include <common/command/_mod.qh>
   4 #include <common/constants.qh>
   5 #include <common/deathtypes/all.qh>
   6 #include <common/effects/all.qh>
   7 #include <common/gamemodes/_mod.qh>
   8 #include <common/mapinfo.qh>
   9 #include <common/mapobjects/triggers.qh>
  10 #include <common/minigames/sv_minigames.qh>
  11 #include <common/monsters/_mod.qh>
  12 #include <common/monsters/sv_monsters.qh>
  13 #include <common/monsters/sv_spawn.qh>
  14 #include <common/notifications/all.qh>
  15 #include <common/physics/player.qh>
  16 #include <common/teams.qh>
  17 #include <common/util.qh>
  18 #include <common/vehicles/all.qh>
  19 #include <lib/warpzone/common.qh>
  20 #include <server/bot/api.qh>
  21 #include <server/bot/default/waypoints.qh>
  22 #include <server/campaign.qh>
  23 #include <server/chat.qh>
  24 #include <server/cheats.qh>
  25 #include <server/client.qh>
  26 #include <server/clientkill.qh>
  27 #include <server/command/common.qh>
  28 #include <server/command/getreplies.qh>
  29 #include <server/command/vote.qh>
  30 #include <server/ipban.qh>
  31 #include <server/mapvoting.qh>
  32 #include <server/mutators/_mod.qh>
  33 #include <server/player.qh>
  34 #include <server/scores.qh>
  35 #include <server/teamplay.qh>
  36 #include <server/world.qh>
  37
  38 // =========================================================
  39 //  Server side networked commands code, reworked by Samual
  40 //  Last updated: December 28th, 2011
  41 // =========================================================
  42
  43 bool SV_ParseClientCommand_floodcheck(entity this)
  44 {
  45         entity store = IS_CLIENT(this) ? CS(this) : this; // unfortunately, we need to store these on the client initially
  46
  47         if (!timeout_status)  // not while paused
  48         {
  49                 if (time <= (store.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  50                 {
  51                         store.cmd_floodcount += 1;
  52                         if (store.cmd_floodcount > autocvar_sv_clientcommand_antispam_count)   return false;  // too much spam, halt
  53                 }
  54                 else
  55                 {
  56                         store.cmd_floodtime = time;
  57                         store.cmd_floodcount = 1;
  58                 }
  59         }
  60         return true;  // continue, as we're not flooding yet
  61 }
  62
  63
  64 // =======================
  65 //  Command Sub-Functions
  66 // =======================
  67
  68 void ClientCommand_autoswitch(entity caller, int request, int argc)
  69 {
  70         switch (request)
  71         {
  72                 case CMD_REQUEST_COMMAND:
  73                 {
  74                         if (argv(1) != "")
  75                         {
  76                                 CS_CVAR(caller).cvar_cl_autoswitch = InterpretBoolean(argv(1));
  77                                 sprint(caller, strcat("^1autoswitch is currently turned ", (CS_CVAR(caller).cvar_cl_autoswitch ? "on" : "off"), ".\n"));
  78                                 return;
  79                         }
  80                 }
  81
  82                 default:
  83                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
  84                 case CMD_REQUEST_USAGE:
  85                 {
  86                         sprint(caller, "\nUsage:^3 cmd autoswitch <selection>\n");
  87                         sprint(caller, "  Where <selection> controls if autoswitch is on or off.\n");
  88                         return;
  89                 }
  90         }
  91 }
  92
  93 void ClientCommand_clientversion(entity caller, int request, int argc)  // internal command, used only by code
  94 {
  95         switch (request)
  96         {
  97                 case CMD_REQUEST_COMMAND:
  98                 {
  99                         if (argv(1) != "")
 100                         {
 101                                 if (IS_CLIENT(caller))
 102                                 {
 103                                         CS(caller).version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
 104
 105                                         if (CS(caller).version < autocvar_gameversion_min || CS(caller).version > autocvar_gameversion_max)
 106                                         {
 107                                                 CS(caller).version_mismatch = true;
 108                                                 ClientKill_TeamChange(caller, -2);  // observe
 109                                         }
 110                                         else if (autocvar_g_campaign || autocvar_g_balance_teams)
 111                                         {
 112                                                 // JoinBestTeam(caller, false, true);
 113                                         }
 114                                         else if (teamplay && !autocvar_sv_spectate && !(Player_GetForcedTeamIndex(caller) > 0))
 115                                         {
 116                                                 TRANSMUTE(Observer, caller);  // really?
 117                                                 stuffcmd(caller, "scoreboard_team_selection\n");
 118                                         }
 119                                 }
 120
 121                                 return;
 122                         }
 123                 }
 124
 125                 default:
 126                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 127                 case CMD_REQUEST_USAGE:
 128                 {
 129                         sprint(caller, "\nUsage:^3 cmd clientversion <version>\n");
 130                         sprint(caller, "  Where <version> is the game version reported by caller.\n");
 131                         return;
 132                 }
 133         }
 134 }
 135
 136 void ClientCommand_mv_getpicture(entity caller, int request, int argc)  // internal command, used only by code
 137 {
 138         switch (request)
 139         {
 140                 case CMD_REQUEST_COMMAND:
 141                 {
 142                         if (argv(1) != "")
 143                         {
 144                                 if (intermission_running) MapVote_SendPicture(caller, stof(argv(1)));
 145
 146                                 return;
 147                         }
 148                 }
 149
 150                 default:
 151                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 152                 case CMD_REQUEST_USAGE:
 153                 {
 154                         sprint(caller, "\nUsage:^3 cmd mv_getpicture <mapid>\n");
 155                         sprint(caller, "  Where <mapid> is the id number of the map to request an image of on the map vote selection menu.\n");
 156                         return;
 157                 }
 158         }
 159 }
 160
 161 void ClientCommand_wpeditor(entity caller, int request, int argc)
 162 {
 163         switch (request)
 164         {
 165                 case CMD_REQUEST_COMMAND:
 166                 {
 167                         if (!waypointeditor_enabled)
 168                         {
 169                                 sprint(caller, "ERROR: this command works only if the waypoint editor is on\n");
 170                                 return;
 171                         }
 172
 173                         if (argv(1) != "")
 174                         {
 175                                 if (argv(1) == "spawn")
 176                                 {
 177                                         string s = argv(2);
 178                                         if (!IS_PLAYER(caller))
 179                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 180                                         else
 181                                                 waypoint_spawn_fromeditor(caller, (s == "crosshair"), (s == "jump"), (s == "crouch"), (s == "support"));
 182                                         return;
 183                                 }
 184                                 else if (argv(1) == "remove")
 185                                 {
 186                                         if (!IS_PLAYER(caller))
 187                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 188                                         else
 189                                                 waypoint_remove_fromeditor(caller);
 190                                         return;
 191                                 }
 192                                 else if (argv(1) == "hardwire")
 193                                 {
 194                                         string s = argv(2);
 195                                         waypoint_start_hardwiredlink(caller, (s == "crosshair"));
 196                                         return;
 197                                 }
 198                                 else if (argv(1) == "lock")
 199                                 {
 200                                         waypoint_lock(caller);
 201                                         return;
 202                                 }
 203                                 else if (argv(1) == "unreachable")
 204                                 {
 205                                         if (!IS_PLAYER(caller))
 206                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 207                                         else
 208                                                 waypoint_unreachable(caller);
 209                                         return;
 210                                 }
 211                                 else if (argv(1) == "saveall")
 212                                 {
 213                                         waypoint_saveall();
 214                                         return;
 215                                 }
 216                                 else if (argv(1) == "relinkall")
 217                                 {
 218                                         waypoint_schedulerelinkall();
 219                                         return;
 220                                 }
 221                                 else if (argv(1) == "symaxis")
 222                                 {
 223                                         if (argv(2) == "set" || argv(2) == "get")
 224                                         {
 225                                                 waypoint_getSymmetricalAxis_cmd(caller, (argv(2) == "set"), 3);
 226                                                 return;
 227                                         }
 228                                 }
 229                                 else if (argv(1) == "symorigin")
 230                                 {
 231                                         if (argv(2) == "set" || argv(2) == "get")
 232                                         {
 233                                                 waypoint_getSymmetricalOrigin_cmd(caller, (argv(2) == "set"), 3);
 234                                                 return;
 235                                         }
 236                                 }
 237                         }
 238                 }
 239
 240                 default:
 241                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 242                 case CMD_REQUEST_USAGE:
 243                 {
 244                         sprint(caller, "\nUsage:^3 cmd wpeditor <action>\n");
 245                         sprint(caller, "  Where <action> can be:\n");
 246                         sprint(caller, "   ^2spawn^7: spawns a waypoint at player's position\n");
 247                         sprint(caller, "   ^2remove^7: removes player's nearest waypoint\n");
 248                         sprint(caller, "   ^2unreachable^7: reveals waypoints and items unreachable from the current position and spawnpoints without a nearest waypoint\n");
 249                         sprint(caller, "   ^2saveall^7: saves all waypoints and links to file\n");
 250                         sprint(caller, "   ^2relinkall^7: relinks all waypoints as if they were respawned\n");
 251                         sprint(caller, "   ^2spawn crosshair^7: spawns a waypoint at crosshair's position\n");
 252                         sprint(caller, "   ^7 in general useful to create special and hardwired links with ease from existing waypoints\n");
 253                         sprint(caller, "   ^7 in particular it's the only way to create custom jumppad waypoints (spawn another waypoint to create destination))\n");
 254                         sprint(caller, "   ^2spawn jump^7: spawns a jump waypoint (place it at least 60 qu before jump start, spawn another waypoint to create destination)\n");
 255                         sprint(caller, "   ^2spawn crouch^7: spawns a crouch waypoint (it links only to very close waypoints)\n");
 256                         sprint(caller, "   ^2spawn support^7: spawns a support waypoint (spawn another waypoint to create destination from which all incoming links are removed)\n");
 257                         sprint(caller, "   ^7 useful to replace links to problematic jumppad/teleport waypoints\n");
 258                         sprint(caller, "   ^2hardwire^7: marks the nearest waypoint as origin of a new hardwired link (spawn another waypoint over an existing one to create destination)\n");
 259                         sprint(caller, "   ^2hardwire crosshair^7: marks the waypoint at crosshair instead of the nearest waypoint\n");
 260                         sprint(caller, "   ^2lock^7: locks link display of the aimed waypoint (unlocks if no waypoint is found at crosshair's position)\n");
 261                         sprint(caller, "   ^2symorigin get|set\n");
 262                         sprint(caller, "   ^2symorigin get|set <p1> <p2> ... <pX>\n");
 263                         sprint(caller, "   ^2symaxis get|set <p1> <p2>\n");
 264                         sprint(caller, "   ^7 where <p1> <p2> ... <pX> are positions (\"x y z\", z can be omitted) that you know are perfectly symmetrical"
 265                                                                 " so you can determine origin/axis of symmetry of maps without ctf flags or where flags aren't perfectly symmetrical\n");
 266                         sprint(caller, "  See ^5wpeditor_menu^7 for a selectable list of various commands and useful settings to edit waypoints.\n");
 267                         return;
 268                 }
 269         }
 270 }
 271
 272 void ClientCommand_join(entity caller, int request)
 273 {
 274         switch (request)
 275         {
 276                 case CMD_REQUEST_COMMAND:
 277                 {
 278                         if (!game_stopped && IS_CLIENT(caller) && !IS_PLAYER(caller))
 279                         {
 280                                 if (joinAllowed(caller))
 281                                         Join(caller);
 282                                 else if(time < CS(caller).jointime + MIN_SPEC_TIME)
 283                                         CS(caller).autojoin_checked = -1;
 284                         }
 285                         CS(caller).parm_idlesince = time;
 286
 287                         return;  // never fall through to usage
 288                 }
 289
 290                 default:
 291                 case CMD_REQUEST_USAGE:
 292                 {
 293                         sprint(caller, "\nUsage:^3 cmd join\n");
 294                         sprint(caller, "  No arguments required.\n");
 295                         return;
 296                 }
 297         }
 298 }
 299
 300 void ClientCommand_kill(entity caller, int request)
 301 {
 302         switch (request)
 303         {
 304                 case CMD_REQUEST_COMMAND:
 305                 {
 306                         if(IS_SPEC(caller) || IS_OBSERVER(caller))
 307                                 return; // no point warning about this, command does nothing
 308
 309                         if(GetResource(caller, RES_HEALTH) <= 0)
 310                         {
 311                                 sprint(caller, "Can't die - you are already dead!\n");
 312                                 return;
 313                         }
 314
 315                         ClientKill(caller);
 316
 317                         return;  // never fall through to usage
 318                 }
 319
 320                 default:
 321                 case CMD_REQUEST_USAGE:
 322                 {
 323                         sprint(caller, "\nUsage:^3 cmd kill\n");
 324                         sprint(caller, "  No arguments required.\n");
 325                         return;
 326                 }
 327         }
 328 }
 329
 330 void ClientCommand_physics(entity caller, int request, int argc)
 331 {
 332         switch (request)
 333         {
 334                 case CMD_REQUEST_COMMAND:
 335                 {
 336                         string command = strtolower(argv(1));
 337
 338                         if (!autocvar_g_physics_clientselect)
 339                         {
 340                                 sprint(caller, "Client physics selection is currently disabled.\n");
 341                                 return;
 342                         }
 343
 344                         if (command == "list" || command == "help")
 345                         {
 346                                 sprint(caller, strcat("Available physics sets: \n\n", autocvar_g_physics_clientselect_options, " default\n"));
 347                                 return;
 348                         }
 349
 350                         if (Physics_Valid(command) || command == "default")
 351                         {
 352                                 stuffcmd(caller, strcat("\nseta cl_physics ", command, "\n"));
 353                                 sprint(caller, strcat("^2Physics set successfully changed to ^3", command, "\n"));
 354                                 return;
 355                         }
 356                 }
 357
 358                 default:
 359                         sprint(caller, strcat("Current physics set: ^3", CS_CVAR(caller).cvar_cl_physics, "\n"));
 360                 case CMD_REQUEST_USAGE:
 361                 {
 362                         sprint(caller, "\nUsage:^3 cmd physics <physics>\n");
 363                         sprint(caller, "  See 'cmd physics list' for available physics sets.\n");
 364                         sprint(caller, "  Argument 'default' resets to standard physics.\n");
 365                         return;
 366                 }
 367         }
 368 }
 369
 370 void ClientCommand_ready(entity caller, int request)
 371 {
 372         switch (request)
 373         {
 374                 case CMD_REQUEST_COMMAND:
 375                 {
 376                         if (IS_CLIENT(caller) && caller.last_ready < time - 3)
 377                         {
 378                                 if (warmup_stage || g_race_qualifying == 2)
 379                                 {
 380                                         if (time < game_starttime) // game is already restarting
 381                                                 return;
 382                                         if (caller.ready)            // toggle
 383                                         {
 384                                                 caller.ready = false;
 385                                                 if (IS_PLAYER(caller) || INGAME_JOINED(caller))
 386                                                         bprint(playername(caller.netname, caller.team, false), "^2 is ^1NOT^2 ready\n");
 387                                         }
 388                                         else
 389                                         {
 390                                                 caller.ready = true;
 391                                                 if (IS_PLAYER(caller) || INGAME_JOINED(caller))
 392                                                         bprint(playername(caller.netname, caller.team, false), "^2 is ready\n");
 393                                         }
 394
 395                                         caller.last_ready = time;
 396                                         ReadyCount();
 397                                 }
 398                         }
 399                         return;  // never fall through to usage
 400                 }
 401
 402                 default:
 403                 case CMD_REQUEST_USAGE:
 404                 {
 405                         sprint(caller, "\nUsage:^3 cmd ready\n");
 406                         sprint(caller, "  No arguments required.\n");
 407                         return;
 408                 }
 409         }
 410 }
 411
 412 void ClientCommand_say(entity caller, int request, int argc, string command)
 413 {
 414         switch (request)
 415         {
 416                 case CMD_REQUEST_COMMAND:
 417                 {
 418                         if (argc >= 2)   Say(caller, false, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 419                         return;  // never fall through to usage
 420                 }
 421
 422                 default:
 423                 case CMD_REQUEST_USAGE:
 424                 {
 425                         sprint(caller, "\nUsage:^3 cmd say <message>\n");
 426                         sprint(caller, "  Where <message> is the string of text to say.\n");
 427                         return;
 428                 }
 429         }
 430 }
 431
 432 void ClientCommand_say_team(entity caller, int request, int argc, string command)
 433 {
 434         switch (request)
 435         {
 436                 case CMD_REQUEST_COMMAND:
 437                 {
 438                         if (argc >= 2)
 439                                 Say(caller, true, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 440                         return;  // never fall through to usage
 441                 }
 442
 443                 default:
 444                 case CMD_REQUEST_USAGE:
 445                 {
 446                         sprint(caller, "\nUsage:^3 cmd say_team <message>\n");
 447                         sprint(caller, "  Where <message> is the string of text to say.\n");
 448                         return;
 449                 }
 450         }
 451 }
 452
 453 .bool team_selected;
 454 void ClientCommand_selectteam(entity caller, int request, int argc)
 455 {
 456         switch (request)
 457         {
 458                 case CMD_REQUEST_COMMAND:
 459                 {
 460                         if (argv(1) == "")
 461                         {
 462                                 return;
 463                         }
 464                         if (!IS_CLIENT(caller))
 465                         {
 466                                 return;
 467                         }
 468                         if (!teamplay)
 469                         {
 470                                 sprint(caller, "^7selectteam can only be used in teamgames\n");
 471                                 return;
 472                         }
 473                         if (Player_GetForcedTeamIndex(caller) > 0)
 474                         {
 475                                 sprint(caller, "^7selectteam can not be used as your team is forced\n");
 476                                 return;
 477                         }
 478                         if (lockteams)
 479                         {
 480                                 sprint(caller, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 481                                 return;
 482                         }
 483
 484                         float team_num = Team_ColorToTeam(argv(1));
 485                         if (team_num == -1) // invalid
 486                                 return;
 487                         if (caller.team == team_num && team_num && !IS_DEAD(caller))
 488                         {
 489                                 sprint(caller, "^7You already are on that team.\n");
 490                                 return;
 491                         }
 492                         if (CS(caller).wasplayer && autocvar_g_changeteam_banned)
 493                         {
 494                                 sprint(caller, "^1You cannot change team, forbidden by the server.\n");
 495                                 return;
 496                         }
 497                         if (team_num && autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 498                         {
 499                                 entity balance = TeamBalance_CheckAllowedTeams(caller);
 500                                 TeamBalance_GetTeamCounts(balance, caller);
 501                                 if ((Team_IndexToBit(Team_TeamToIndex(team_num)) &
 502                                         TeamBalance_FindBestTeams(balance, caller, false)) == 0)
 503                                 {
 504                                         Send_Notification(NOTIF_ONE, caller, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 505                                         TeamBalance_Destroy(balance);
 506                                         return;
 507                                 }
 508                                 TeamBalance_Destroy(balance);
 509                         }
 510                         if (team_num)
 511                                 ClientKill_TeamChange(caller, team_num);
 512                         else // auto
 513                                 ClientKill_TeamChange(caller, -1);
 514
 515                         if (!IS_PLAYER(caller))
 516                         {
 517                                 caller.team_selected = true; // avoids asking again for team selection on join
 518                         }
 519                         return;
 520                 }
 521                 default:
 522                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 523                 case CMD_REQUEST_USAGE:
 524                 {
 525                         sprint(caller, "\nUsage:^3 cmd selectteam <team>\n");
 526                         sprint(caller, "  Where <team> is the prefered team to try and join.\n");
 527                         sprint(caller, "  Full list of options here: red, blue, yellow, pink, auto.\n");
 528                         return;
 529                 }
 530         }
 531 }
 532
 533 void ClientCommand_selfstuff(entity caller, int request, string command)
 534 {
 535         switch (request)
 536         {
 537                 case CMD_REQUEST_COMMAND:
 538                 {
 539                         if (argv(1) != "")
 540                         {
 541                                 stuffcmd(caller, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 542                                 return;
 543                         }
 544                 }
 545
 546                 default:
 547                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 548                 case CMD_REQUEST_USAGE:
 549                 {
 550                         sprint(caller, "\nUsage:^3 cmd selfstuff <command>\n");
 551                         sprint(caller, "  Where <command> is the string to be stuffed to your client.\n");
 552                         return;
 553                 }
 554         }
 555 }
 556
 557 void ClientCommand_sentcvar(entity caller, int request, int argc)
 558 {
 559         switch (request)
 560         {
 561                 case CMD_REQUEST_COMMAND:
 562                 {
 563                         if (argc >= 3)
 564                         {
 565                         // NOTE: client-side settings do not exist on the server, this functionality has been deprecated
 566                         #if 0
 567                                 if (argc == 2)  // undefined cvar: use the default value on the server then
 568                                 {
 569                                         string s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 570                                         tokenize_console(s);
 571                                 }
 572                         #endif
 573
 574                                 GetCvars(caller, CS_CVAR(caller), 1);
 575
 576                                 return;
 577                         }
 578                 }
 579
 580                 default:
 581                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 582                 case CMD_REQUEST_USAGE:
 583                 {
 584                         sprint(caller, "\nUsage:^3 cmd sentcvar <cvar> <arguments>\n");
 585                         sprint(caller, "  Where <cvar> is the cvar plus arguments to send to the server.\n");
 586                         return;
 587                 }
 588         }
 589 }
 590
 591 void ClientCommand_spectate(entity caller, int request)
 592 {
 593         switch (request)
 594         {
 595                 case CMD_REQUEST_COMMAND:
 596                 {
 597                         if (!intermission_running && IS_CLIENT(caller))
 598                         {
 599                                 if(argv(1) != "")
 600                                 {
 601                                         if(IS_SPEC(caller) || IS_OBSERVER(caller))
 602                                         {
 603                                                 entity client = GetFilteredEntity(argv(1));
 604                                                 int spec_accepted = VerifyClientEntity(client, false, false);
 605                                                 if(spec_accepted > 0 && IS_PLAYER(client))
 606                                                 {
 607                                                         bool caller_is_observer = (IS_OBSERVER(caller));
 608                                                         Spectate(caller, client);
 609                                                         if (caller_is_observer)
 610                                                                 TRANSMUTE(Spectator, caller);
 611                                                 }
 612                                                 else
 613                                                         sprint(caller, "Can't spectate ", argv(1), "^7\n");
 614                                         }
 615                                         else
 616                                                 sprint(caller, "cmd spectate <client> only works when you are spectator/observer\n");
 617                                         return;
 618                                 }
 619
 620                                 int mutator_returnvalue = MUTATOR_CALLHOOK(ClientCommand_Spectate, caller);
 621
 622                                 if (mutator_returnvalue == MUT_SPECCMD_RETURN) return;
 623
 624                                 if ((IS_PLAYER(caller) || mutator_returnvalue == MUT_SPECCMD_FORCE))
 625                                 if (autocvar_sv_spectate == 1)
 626                                         ClientKill_TeamChange(caller, -2); // observe
 627                         }
 628                         return; // never fall through to usage
 629                 }
 630
 631                 default:
 632                 case CMD_REQUEST_USAGE:
 633                 {
 634                         sprint(caller, "\nUsage:^3 cmd spectate [<client>]\n");
 635                         sprint(caller, "  Where <client> can be the player to spectate.\n");
 636                         return;
 637                 }
 638         }
 639 }
 640
 641 void ClientCommand_suggestmap(entity caller, int request, int argc)
 642 {
 643         switch (request)
 644         {
 645                 case CMD_REQUEST_COMMAND:
 646                 {
 647                         if (argv(1) != "")
 648                         {
 649                                 sprint(caller, strcat(MapVote_Suggest(caller, argv(1)), "\n"));
 650                                 return;
 651                         }
 652                 }
 653
 654                 default:
 655                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 656                 case CMD_REQUEST_USAGE:
 657                 {
 658                         sprint(caller, "\nUsage:^3 cmd suggestmap <map>\n");
 659                         sprint(caller, "  Where <map> is the name of the map to suggest.\n");
 660                         return;
 661                 }
 662         }
 663 }
 664
 665 void ClientCommand_tell(entity caller, int request, int argc, string command)
 666 {
 667         switch (request)
 668         {
 669                 case CMD_REQUEST_COMMAND:
 670                 {
 671                         if (argc >= 3)
 672                         {
 673                                 if(!IS_CLIENT(caller) && IS_REAL_CLIENT(caller)) // connecting
 674                                 {
 675                                         print_to(caller, "You can't ^2tell^7 a message while connecting.");
 676                                         return;
 677                                 }
 678
 679                                 entity tell_to = GetIndexedEntity(argc, 1);
 680                                 float tell_accepted = VerifyClientEntity(tell_to, true, false);
 681
 682                                 if (tell_accepted > 0)   // the target is a real client
 683                                 {
 684                                         if (tell_to != caller) // and we're allowed to send to them :D
 685                                         {
 686                                                 // workaround for argv indexes indexing ascii chars instead of utf8 chars
 687                                                 // In this case when the player name contains utf8 chars
 688                                                 // the message gets partially trimmed in the beginning.
 689                                                 // Potentially this bug affects any substring call that uses
 690                                                 // argv_start_index and argv_end_index.
 691
 692                                                 string utf8_enable_save = cvar_string("utf8_enable");
 693                                                 cvar_set("utf8_enable", "0");
 694                                                 string msg = substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token));
 695                                                 cvar_set("utf8_enable", utf8_enable_save);
 696
 697                                                 Say(caller, false, tell_to, msg, true);
 698                                                 return;
 699                                         }
 700                                         else { print_to(caller, "You can't ^2tell^7 a message to yourself."); return; }
 701                                 }
 702                                 else if (argv(1) == "#0")
 703                                 {
 704                                         trigger_magicear_processmessage_forallears(caller, -1, NULL, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 705                                         return;
 706                                 }
 707                                 else { print_to(caller, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 708                         }
 709                 }
 710
 711                 default:
 712                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 713                 case CMD_REQUEST_USAGE:
 714                 {
 715                         sprint(caller, "\nUsage:^3 cmd tell <client> <message>\n");
 716                         sprint(caller, "  Where <client> is the entity number or name of the player to send <message> to.\n");
 717                         return;
 718                 }
 719         }
 720 }
 721
 722 void ClientCommand_voice(entity caller, int request, int argc, string command)
 723 {
 724         switch (request)
 725         {
 726                 case CMD_REQUEST_COMMAND:
 727                 {
 728                         if (argv(1) != "")
 729                         {
 730                                 entity e = GetVoiceMessage(argv(1));
 731                                 if (!e)
 732                                 {
 733                                         sprint(caller, sprintf("Invalid voice. Use one of: %s\n", allvoicesamples));
 734                                         return;
 735                                 }
 736                                 if (IS_DEAD(caller))
 737                                 {
 738                                         // don't warn the caller when trying to taunt while dead, just don't play any sounds!
 739                                         // we still allow them to see warnings if it's invalid, so a dead player can find out the sounds in peace
 740                                         return;
 741                                 }
 742                                 if (IS_SPEC(caller) || IS_OBSERVER(caller))
 743                                 {
 744                                         // observers/spectators have no player model of their own to play taunts from
 745                                         // again, allow them to see warnings
 746                                         return;
 747                                 }
 748                                 string msg = "";
 749                                 if (argc >= 3)
 750                                         msg = substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
 751                                 VoiceMessage(caller, e, msg);
 752
 753                                 return;
 754                         }
 755                 }
 756
 757                 default:
 758                         sprint(caller, sprintf("Incorrect parameters for ^2%s^7\n", argv(0)));
 759                 case CMD_REQUEST_USAGE:
 760                 {
 761                         sprint(caller, "\nUsage:^3 cmd voice <voicetype> [<message>]\n");
 762                         sprint(caller, "  <voicetype> is the type of voice message, it can be one of these:\n");
 763                         sprint(caller, sprintf("   %s\n", allvoicesamples));
 764                         sprint(caller, "  and <message> is the text message to send.\n");
 765                         return;
 766                 }
 767         }
 768 }
 769
 770 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 771 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 772 void ClientCommand_(entity caller, int request)
 773 {
 774     switch(request)
 775     {
 776         case CMD_REQUEST_COMMAND:
 777         {
 778
 779             return; // never fall through to usage
 780         }
 781
 782         default:
 783         case CMD_REQUEST_USAGE:
 784         {
 785             sprint(caller, "\nUsage:^3 cmd \n");
 786             sprint(caller, "  No arguments required.\n");
 787             return;
 788         }
 789     }
 790 }
 791 */
 792
 793
 794 // =====================================
 795 //  Macro system for networked commands
 796 // =====================================
 797
 798 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 799 #define CLIENT_COMMANDS(ent, request, arguments, command) \
 800         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(ent, request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 801         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(ent, request, arguments), "Release version of the game") \
 802         CLIENT_COMMAND("join", ClientCommand_join(ent, request), "Become a player in the game") \
 803         CLIENT_COMMAND("kill", ClientCommand_kill(ent, request), "Become a member of the dead") \
 804         CLIENT_COMMAND("minigame", ClientCommand_minigame(ent, request, arguments, command), "Start a minigame") \
 805         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(ent, request, arguments), "Retrieve mapshot picture from the server") \
 806         CLIENT_COMMAND("physics", ClientCommand_physics(ent, request, arguments), "Change physics set") \
 807         CLIENT_COMMAND("ready", ClientCommand_ready(ent, request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 808         CLIENT_COMMAND("say", ClientCommand_say(ent, request, arguments, command), "Print a message to chat to all players") \
 809         CLIENT_COMMAND("say_team", ClientCommand_say_team(ent, request, arguments, command), "Print a message to chat to all team mates") \
 810         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(ent, request, arguments), "Attempt to choose a team to join into") \
 811         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(ent, request, command), "Stuffcmd a command to your own client") \
 812         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(ent, request, arguments), "New system for sending a client cvar to the server") \
 813         CLIENT_COMMAND("spectate", ClientCommand_spectate(ent, request), "Become an observer") \
 814         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(ent, request, arguments), "Suggest a map to the mapvote at match end") \
 815         CLIENT_COMMAND("tell", ClientCommand_tell(ent, request, arguments, command), "Send a message directly to a player") \
 816         CLIENT_COMMAND("voice", ClientCommand_voice(ent, request, arguments, command), "Send voice message via sound") \
 817         CLIENT_COMMAND("wpeditor", ClientCommand_wpeditor(ent, request, arguments), "Waypoint editor commands") \
 818         /* nothing */
 819
 820 void ClientCommand_macro_help(entity caller)
 821 {
 822         #define CLIENT_COMMAND(name, function, description) \
 823                 { sprint(caller, "  ^2", name, "^7: ", description, "\n"); }
 824
 825         CLIENT_COMMANDS(NULL, 0, 0, "");
 826 #undef CLIENT_COMMAND
 827 }
 828
 829 float ClientCommand_macro_command(int argc, entity caller, string command)
 830 {
 831         #define CLIENT_COMMAND(name, function, description) \
 832                 { if (name == strtolower(argv(0))) { function; return true; } }
 833
 834         CLIENT_COMMANDS(caller, CMD_REQUEST_COMMAND, argc, command);
 835 #undef CLIENT_COMMAND
 836
 837         return false;
 838 }
 839
 840 float ClientCommand_macro_usage(int argc, entity caller)
 841 {
 842         #define CLIENT_COMMAND(name, function, description) \
 843                 { if (name == strtolower(argv(1))) { function; return true; } }
 844
 845         CLIENT_COMMANDS(caller, CMD_REQUEST_USAGE, argc, "");
 846 #undef CLIENT_COMMAND
 847
 848         return false;
 849 }
 850
 851 void ClientCommand_macro_write_aliases(float fh)
 852 {
 853         #define CLIENT_COMMAND(name, function, description) \
 854                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 855
 856         CLIENT_COMMANDS(NULL, 0, 0, "");
 857 #undef CLIENT_COMMAND
 858 }
 859
 860 // ======================================
 861 //  Main Function Called By Engine (cmd)
 862 // ======================================
 863 // If this function exists, server game code parses clientcommand before the engine code gets it.
 864
 865 void SV_ParseClientCommand(entity this, string command)
 866 {
 867         // If invalid UTF-8, don't even parse it
 868         string command2 = "";
 869         float len = strlen(command);
 870         float i;
 871         for (i = 0; i < len; ++i)
 872                 command2 = strcat(command2, chr2str(str2chr(command, i)));
 873         if (command != command2) return;
 874
 875         // if we're banned, don't even parse the command
 876         if (Ban_MaybeEnforceBanOnce(this)) return;
 877
 878         int argc = tokenize_console(command);
 879
 880         // Guide for working with argc arguments by example:
 881         // argc:   1    - 2      - 3     - 4
 882         // argv:   0    - 1      - 2     - 3
 883         // cmd     vote - master - login - password
 884
 885         // for floodcheck
 886         switch (strtolower(argv(0)))
 887         {
 888                 // exempt commands which are not subject to floodcheck
 889                 case "begin": break;                               // handled by engine in host_cmd.c
 890                 case "download": break;                            // handled by engine in cl_parse.c
 891                 case "mv_getpicture": break;                       // handled by server in this file
 892                 case "wpeditor": break;                            // handled by server in this file
 893                 case "pause": break;                               // handled by engine in host_cmd.c
 894                 case "prespawn": break;                            // handled by engine in host_cmd.c
 895                 case "sentcvar": break;                            // handled by server in this file
 896                 case "spawn": break;                               // handled by engine in host_cmd.c
 897                 case "color": case "topcolor": case "bottomcolor": // handled by engine in host_cmd.c
 898                         if(!IS_CLIENT(this)) // on connection
 899                         {
 900                                 // since gamecode doesn't have any calls earlier than this, do the connecting message here
 901                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_CONNECTING, this.netname);
 902                         }
 903                         if(teamplay)
 904                                 return;
 905                         break;
 906                 case "c2s": Net_ClientCommand(this, command); return; // handled by net.qh
 907
 908                 default:
 909                         if (SV_ParseClientCommand_floodcheck(this)) break; // "true": continue, as we're not flooding yet
 910                         else return;                                   // "false": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 911         }
 912
 913         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 914         if (argv(0) == "help")
 915         {
 916                 if (argc == 1)
 917                 {
 918                         sprint(this, "\nClient networked commands:\n");
 919                         ClientCommand_macro_help(this);
 920
 921                         sprint(this, "\nCommon networked commands:\n");
 922                         CommonCommand_macro_help(this);
 923
 924                         sprint(this, "\nUsage:^3 cmd <command>^7, where possible commands are listed above.\n");
 925                         sprint(this, "For help about a specific command, type cmd help <command>\n");
 926                         return;
 927                 }
 928                 else if (CommonCommand_macro_usage(argc, this))  // Instead of trying to call a command, we're going to see detailed information about it
 929                 {
 930                         return;
 931                 }
 932                 else if (ClientCommand_macro_usage(argc, this))  // same, but for normal commands now
 933                 {
 934                         return;
 935                 }
 936         }
 937         else if (MUTATOR_CALLHOOK(SV_ParseClientCommand, this, strtolower(argv(0)), argc, command))
 938         {
 939                 return;  // handled by a mutator
 940         }
 941         else if (CheatCommand(this, argc))
 942         {
 943                 return;  // handled by server/cheats.qc
 944         }
 945         else if (CommonCommand_macro_command(argc, this, command))
 946         {
 947                 return;                                          // handled by server/command/common.qc
 948         }
 949         else if (ClientCommand_macro_command(argc, this, command)) // continue as usual and scan for normal commands
 950         {
 951                 return;                                          // handled by one of the above ClientCommand_* functions
 952         }
 953         else
 954         {
 955                 clientcommand(this, command);
 956         }
 957 }