qcsrc/server/command/cmd.qc

   1 #include "cmd.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5
   6 #include <common/command/_mod.qh>
   7
   8 #include "common.qh"
   9 #include "vote.qh"
  10
  11 #include "../campaign.qh"
  12 #include "../cheats.qh"
  13 #include "../client.qh"
  14 #include "../player.qh"
  15 #include "../ipban.qh"
  16 #include "../mapvoting.qh"
  17 #include "../scores.qh"
  18 #include "../teamplay.qh"
  19
  20 #include <server/mutators/_mod.qh>
  21 #include <common/gamemodes/_mod.qh>
  22
  23 #ifdef SVQC
  24         #include <common/vehicles/all.qh>
  25 #endif
  26
  27 #include <common/constants.qh>
  28 #include <common/deathtypes/all.qh>
  29 #include <common/effects/all.qh>
  30 #include <common/mapinfo.qh>
  31 #include <common/notifications/all.qh>
  32 #include <common/physics/player.qh>
  33 #include <common/teams.qh>
  34 #include <common/util.qh>
  35 #include <common/mapobjects/triggers.qh>
  36
  37 #include <common/minigames/sv_minigames.qh>
  38
  39 #include <common/monsters/_mod.qh>
  40 #include <common/monsters/sv_spawn.qh>
  41 #include <common/monsters/sv_monsters.qh>
  42
  43 #include <lib/warpzone/common.qh>
  44
  45 // =========================================================
  46 //  Server side networked commands code, reworked by Samual
  47 //  Last updated: December 28th, 2011
  48 // =========================================================
  49
  50 bool SV_ParseClientCommand_floodcheck(entity this)
  51 {
  52         entity store = IS_CLIENT(this) ? CS(this) : this; // unfortunately, we need to store these on the client initially
  53
  54         if (!timeout_status)  // not while paused
  55         {
  56                 if (time <= (store.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  57                 {
  58                         store.cmd_floodcount += 1;
  59                         if (store.cmd_floodcount > autocvar_sv_clientcommand_antispam_count)   return false;  // too much spam, halt
  60                 }
  61                 else
  62                 {
  63                         store.cmd_floodtime = time;
  64                         store.cmd_floodcount = 1;
  65                 }
  66         }
  67         return true;  // continue, as we're not flooding yet
  68 }
  69
  70
  71 // =======================
  72 //  Command Sub-Functions
  73 // =======================
  74
  75 void ClientCommand_autoswitch(entity caller, int request, int argc)
  76 {
  77         switch (request)
  78         {
  79                 case CMD_REQUEST_COMMAND:
  80                 {
  81                         if (argv(1) != "")
  82                         {
  83                                 CS(caller).autoswitch = InterpretBoolean(argv(1));
  84                                 sprint(caller, strcat("^1autoswitch is currently turned ", (CS(caller).autoswitch ? "on" : "off"), ".\n"));
  85                                 return;
  86                         }
  87                 }
  88
  89                 default:
  90                         sprint(caller, "Incorrect parameters for ^2autoswitch^7\n");
  91                 case CMD_REQUEST_USAGE:
  92                 {
  93                         sprint(caller, "\nUsage:^3 cmd autoswitch selection\n");
  94                         sprint(caller, "  Where 'selection' controls if autoswitch is on or off.\n");
  95                         return;
  96                 }
  97         }
  98 }
  99
 100 void ClientCommand_clientversion(entity caller, int request, int argc)  // internal command, used only by code
 101 {
 102         switch (request)
 103         {
 104                 case CMD_REQUEST_COMMAND:
 105                 {
 106                         if (argv(1) != "")
 107                         {
 108                                 if (IS_CLIENT(caller))
 109                                 {
 110                                         CS(caller).version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
 111
 112                                         if (CS(caller).version < autocvar_gameversion_min || CS(caller).version > autocvar_gameversion_max)
 113                                         {
 114                                                 CS(caller).version_mismatch = true;
 115                                                 ClientKill_TeamChange(caller, -2);  // observe
 116                                         }
 117                                         else if (autocvar_g_campaign || autocvar_g_balance_teams)
 118                                         {
 119                                                 // JoinBestTeam(caller, false, true);
 120                                         }
 121                                         else if (teamplay && !autocvar_sv_spectate && !(caller.team_forced > 0))
 122                                         {
 123                                                 TRANSMUTE(Observer, caller);  // really?
 124                                                 stuffcmd(caller, "menu_showteamselect\n");
 125                                         }
 126                                 }
 127
 128                                 return;
 129                         }
 130                 }
 131
 132                 default:
 133                         sprint(caller, "Incorrect parameters for ^2clientversion^7\n");
 134                 case CMD_REQUEST_USAGE:
 135                 {
 136                         sprint(caller, "\nUsage:^3 cmd clientversion version\n");
 137                         sprint(caller, "  Where 'version' is the game version reported by caller.\n");
 138                         return;
 139                 }
 140         }
 141 }
 142
 143 void ClientCommand_mv_getpicture(entity caller, int request, int argc)  // internal command, used only by code
 144 {
 145         switch (request)
 146         {
 147                 case CMD_REQUEST_COMMAND:
 148                 {
 149                         if (argv(1) != "")
 150                         {
 151                                 if (intermission_running) MapVote_SendPicture(caller, stof(argv(1)));
 152
 153                                 return;
 154                         }
 155                 }
 156
 157                 default:
 158                         sprint(caller, "Incorrect parameters for ^2mv_getpicture^7\n");
 159                 case CMD_REQUEST_USAGE:
 160                 {
 161                         sprint(caller, "\nUsage:^3 cmd mv_getpicture mapid\n");
 162                         sprint(caller, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 163                         return;
 164                 }
 165         }
 166 }
 167
 168 void ClientCommand_join(entity caller, int request)
 169 {
 170         switch (request)
 171         {
 172                 case CMD_REQUEST_COMMAND:
 173                 {
 174                         if (!game_stopped)
 175                         if (IS_CLIENT(caller) && !IS_PLAYER(caller))
 176                         if (joinAllowed(caller))
 177                                 Join(caller);
 178
 179                         return;  // never fall through to usage
 180                 }
 181
 182                 default:
 183                 case CMD_REQUEST_USAGE:
 184                 {
 185                         sprint(caller, "\nUsage:^3 cmd join\n");
 186                         sprint(caller, "  No arguments required.\n");
 187                         return;
 188                 }
 189         }
 190 }
 191
 192 void ClientCommand_physics(entity caller, int request, int argc)
 193 {
 194         switch (request)
 195         {
 196                 case CMD_REQUEST_COMMAND:
 197                 {
 198                         string command = strtolower(argv(1));
 199
 200                         if (!autocvar_g_physics_clientselect)
 201                         {
 202                                 sprint(caller, "Client physics selection is currently disabled.\n");
 203                                 return;
 204                         }
 205
 206                         if (command == "list" || command == "help")
 207                         {
 208                                 sprint(caller, strcat("Available physics sets: \n\n", autocvar_g_physics_clientselect_options, " default\n"));
 209                                 return;
 210                         }
 211
 212                         if (Physics_Valid(command) || command == "default")
 213                         {
 214                                 stuffcmd(caller, strcat("\nseta cl_physics ", command, "\nsendcvar cl_physics\n"));
 215                                 sprint(caller, strcat("^2Physics set successfully changed to ^3", command, "\n"));
 216                                 return;
 217                         }
 218                 }
 219
 220                 default:
 221                         sprint(caller, strcat("Current physics set: ^3", CS(caller).cvar_cl_physics, "\n"));
 222                 case CMD_REQUEST_USAGE:
 223                 {
 224                         sprint(caller, "\nUsage:^3 cmd physics <physics>\n");
 225                         sprint(caller, "  See 'cmd physics list' for available physics sets.\n");
 226                         sprint(caller, "  Argument 'default' resets to standard physics.\n");
 227                         return;
 228                 }
 229         }
 230 }
 231
 232 void ClientCommand_ready(entity caller, int request)  // todo: anti-spam for toggling readyness
 233 {
 234         switch (request)
 235         {
 236                 case CMD_REQUEST_COMMAND:
 237                 {
 238                         if (IS_CLIENT(caller))
 239                         {
 240                                 if (warmup_stage || sv_ready_restart || g_race_qualifying == 2)
 241                                 {
 242                                         if (!readyrestart_happened || sv_ready_restart_repeatable)
 243                                         {
 244                                                 if (time < game_starttime) // game is already restarting
 245                                                         return;
 246                                                 if (caller.ready)            // toggle
 247                                                 {
 248                                                         caller.ready = false;
 249                                                         if(IS_PLAYER(caller) || caller.caplayer == 1)
 250                                                                 bprint(playername(caller, false), "^2 is ^1NOT^2 ready\n");
 251                                                 }
 252                                                 else
 253                                                 {
 254                                                         caller.ready = true;
 255                                                         if(IS_PLAYER(caller) || caller.caplayer == 1)
 256                                                                 bprint(playername(caller, false), "^2 is ready\n");
 257                                                 }
 258
 259                                                 // cannot reset the game while a timeout is active!
 260                                                 if (!timeout_status) ReadyCount();
 261                                         }
 262                                         else
 263                                         {
 264                                                 sprint(caller, "^1Game has already been restarted\n");
 265                                         }
 266                                 }
 267                         }
 268                         return;  // never fall through to usage
 269                 }
 270
 271                 default:
 272                 case CMD_REQUEST_USAGE:
 273                 {
 274                         sprint(caller, "\nUsage:^3 cmd ready\n");
 275                         sprint(caller, "  No arguments required.\n");
 276                         return;
 277                 }
 278         }
 279 }
 280
 281 void ClientCommand_say(entity caller, int request, int argc, string command)
 282 {
 283         switch (request)
 284         {
 285                 case CMD_REQUEST_COMMAND:
 286                 {
 287                         if (argc >= 2)   Say(caller, false, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 288                         return;  // never fall through to usage
 289                 }
 290
 291                 default:
 292                 case CMD_REQUEST_USAGE:
 293                 {
 294                         sprint(caller, "\nUsage:^3 cmd say <message>\n");
 295                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 296                         return;
 297                 }
 298         }
 299 }
 300
 301 void ClientCommand_say_team(entity caller, int request, int argc, string command)
 302 {
 303         switch (request)
 304         {
 305                 case CMD_REQUEST_COMMAND:
 306                 {
 307                         if (argc >= 2)
 308                         {
 309                                 string _classname = string_null;
 310                                 if (!IS_PLAYER(caller) && caller.caplayer)
 311                                 {
 312                                         // CA: make work team chat for killed players
 313                                         _classname = caller.classname;
 314                                         caller.classname = STR_PLAYER;
 315                                 }
 316
 317                                 Say(caller, true, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 318                                 if (_classname)
 319                                         caller.classname = _classname;
 320                         }
 321                         return;  // never fall through to usage
 322                 }
 323
 324                 default:
 325                 case CMD_REQUEST_USAGE:
 326                 {
 327                         sprint(caller, "\nUsage:^3 cmd say_team <message>\n");
 328                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 329                         return;
 330                 }
 331         }
 332 }
 333
 334 .bool team_selected;
 335 void ClientCommand_selectteam(entity caller, int request, int argc)
 336 {
 337         switch (request)
 338         {
 339                 case CMD_REQUEST_COMMAND:
 340                 {
 341                         if (argv(1) == "")
 342                         {
 343                                 return;
 344                         }
 345                         if (!IS_CLIENT(caller))
 346                         {
 347                                 return;
 348                         }
 349                         if (!teamplay)
 350                         {
 351                                 sprint(caller, "^7selectteam can only be used in teamgames\n");
 352                                 return;
 353                         }
 354                         if (caller.team_forced > 0)
 355                         {
 356                                 sprint(caller, "^7selectteam can not be used as your team is forced\n");
 357                                 return;
 358                         }
 359                         if (lockteams)
 360                         {
 361                                 sprint(caller, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 362                                 return;
 363                         }
 364                         float selection;
 365                         switch (argv(1))
 366                         {
 367                                 case "red":
 368                                 {
 369                                         selection = NUM_TEAM_1;
 370                                         break;
 371                                 }
 372                                 case "blue":
 373                                 {
 374                                         selection = NUM_TEAM_2;
 375                                         break;
 376                                 }
 377                                 case "yellow":
 378                                 {
 379                                         selection = NUM_TEAM_3;
 380                                         break;
 381                                 }
 382                                 case "pink":
 383                                 {
 384                                         selection = NUM_TEAM_4;
 385                                         break;
 386                                 }
 387                                 case "auto":
 388                                 {
 389                                         selection = (-1);
 390                                         break;
 391                                 }
 392                                 default:
 393                                 {
 394                                         return;
 395                                 }
 396                         }
 397                         if (caller.team == selection && selection != -1 && !IS_DEAD(caller))
 398                         {
 399                                 sprint(caller, "^7You already are on that team.\n");
 400                                 return;
 401                         }
 402                         if (CS(caller).wasplayer && autocvar_g_changeteam_banned)
 403                         {
 404                                 sprint(caller, "^1You cannot change team, forbidden by the server.\n");
 405                                 return;
 406                         }
 407                         if ((selection != -1) && autocvar_g_balance_teams &&
 408                                 autocvar_g_balance_teams_prevent_imbalance)
 409                         {
 410                                 entity balance = TeamBalance_CheckAllowedTeams(caller);
 411                                 TeamBalance_GetTeamCounts(balance, caller);
 412                                 if ((Team_IndexToBit(Team_TeamToIndex(selection)) &
 413                                         TeamBalance_FindBestTeams(balance, caller, false)) == 0)
 414                                 {
 415                                         Send_Notification(NOTIF_ONE, caller, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 416                                         TeamBalance_Destroy(balance);
 417                                         return;
 418                                 }
 419                                 TeamBalance_Destroy(balance);
 420                         }
 421                         ClientKill_TeamChange(caller, selection);
 422                         if (!IS_PLAYER(caller))
 423                         {
 424                                 caller.team_selected = true; // avoids asking again for team selection on join
 425                         }
 426                         return;
 427                 }
 428                 default:
 429                         sprint(caller, "Incorrect parameters for ^2selectteam^7\n");
 430                 case CMD_REQUEST_USAGE:
 431                 {
 432                         sprint(caller, "\nUsage:^3 cmd selectteam team\n");
 433                         sprint(caller, "  Where 'team' is the prefered team to try and join.\n");
 434                         sprint(caller, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 435                         return;
 436                 }
 437         }
 438 }
 439
 440 void ClientCommand_selfstuff(entity caller, int request, string command)
 441 {
 442         switch (request)
 443         {
 444                 case CMD_REQUEST_COMMAND:
 445                 {
 446                         if (argv(1) != "")
 447                         {
 448                                 stuffcmd(caller, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 449                                 return;
 450                         }
 451                 }
 452
 453                 default:
 454                         sprint(caller, "Incorrect parameters for ^2selfstuff^7\n");
 455                 case CMD_REQUEST_USAGE:
 456                 {
 457                         sprint(caller, "\nUsage:^3 cmd selfstuff <command>\n");
 458                         sprint(caller, "  Where 'command' is the string to be stuffed to your client.\n");
 459                         return;
 460                 }
 461         }
 462 }
 463
 464 void ClientCommand_sentcvar(entity caller, int request, int argc, string command)
 465 {
 466         switch (request)
 467         {
 468                 case CMD_REQUEST_COMMAND:
 469                 {
 470                         if (argv(1) != "")
 471                         {
 472                                 // float tokens;
 473                                 string s;
 474
 475                                 if (argc == 2)  // undefined cvar: use the default value on the server then
 476                                 {
 477                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 478                                         tokenize_console(s);
 479                                 }
 480
 481                                 GetCvars(caller, CS(caller), 1);
 482
 483                                 return;
 484                         }
 485                 }
 486
 487                 default:
 488                         sprint(caller, "Incorrect parameters for ^2sentcvar^7\n");
 489                 case CMD_REQUEST_USAGE:
 490                 {
 491                         sprint(caller, "\nUsage:^3 cmd sentcvar <cvar>\n");
 492                         sprint(caller, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 493                         return;
 494                 }
 495         }
 496 }
 497
 498 void ClientCommand_spectate(entity caller, int request)
 499 {
 500         switch (request)
 501         {
 502                 case CMD_REQUEST_COMMAND:
 503                 {
 504                         if (!intermission_running && IS_CLIENT(caller))
 505                         {
 506                                 if((IS_SPEC(caller) || IS_OBSERVER(caller)) && argv(1) != "")
 507                                 {
 508                                         entity client = GetFilteredEntity(argv(1));
 509                                         int spec_accepted = VerifyClientEntity(client, false, false);
 510                                         if(spec_accepted > 0 && IS_PLAYER(client))
 511                                         {
 512                                                 if(Spectate(caller, client))
 513                                                         return; // fall back to regular handling
 514                                         }
 515                                 }
 516
 517                                 int mutator_returnvalue = MUTATOR_CALLHOOK(ClientCommand_Spectate, caller);
 518
 519                                 if (mutator_returnvalue == MUT_SPECCMD_RETURN) return;
 520
 521                                 if ((IS_PLAYER(caller) || mutator_returnvalue == MUT_SPECCMD_FORCE))
 522                                 if (autocvar_sv_spectate == 1)
 523                                         ClientKill_TeamChange(caller, -2); // observe
 524                         }
 525                         return; // never fall through to usage
 526                 }
 527
 528                 default:
 529                 case CMD_REQUEST_USAGE:
 530                 {
 531                         sprint(caller, "\nUsage:^3 cmd spectate <client>\n");
 532                         sprint(caller, "  Where 'client' can be the player to spectate.\n");
 533                         return;
 534                 }
 535         }
 536 }
 537
 538 void ClientCommand_suggestmap(entity caller, int request, int argc)
 539 {
 540         switch (request)
 541         {
 542                 case CMD_REQUEST_COMMAND:
 543                 {
 544                         if (argv(1) != "")
 545                         {
 546                                 sprint(caller, strcat(MapVote_Suggest(caller, argv(1)), "\n"));
 547                                 return;
 548                         }
 549                 }
 550
 551                 default:
 552                         sprint(caller, "Incorrect parameters for ^2suggestmap^7\n");
 553                 case CMD_REQUEST_USAGE:
 554                 {
 555                         sprint(caller, "\nUsage:^3 cmd suggestmap map\n");
 556                         sprint(caller, "  Where 'map' is the name of the map to suggest.\n");
 557                         return;
 558                 }
 559         }
 560 }
 561
 562 void ClientCommand_tell(entity caller, int request, int argc, string command)
 563 {
 564         switch (request)
 565         {
 566                 case CMD_REQUEST_COMMAND:
 567                 {
 568                         if (argc >= 3)
 569                         {
 570                                 if(!IS_CLIENT(caller) && IS_REAL_CLIENT(caller)) // connecting
 571                                 {
 572                                         print_to(caller, "You can't ^2tell^7 a message while connecting.");
 573                                         return;
 574                                 }
 575
 576                                 entity tell_to = GetIndexedEntity(argc, 1);
 577                                 float tell_accepted = VerifyClientEntity(tell_to, true, false);
 578
 579                                 if (tell_accepted > 0)   // the target is a real client
 580                                 {
 581                                         if (tell_to != caller) // and we're allowed to send to them :D
 582                                         {
 583                                                 // workaround for argv indexes indexing ascii chars instead of utf8 chars
 584                                                 // In this case when the player name contains utf8 chars
 585                                                 // the message gets partially trimmed in the beginning.
 586                                                 // Potentially this bug affects any substring call that uses
 587                                                 // argv_start_index and argv_end_index.
 588
 589                                                 string utf8_enable_save = cvar_string("utf8_enable");
 590                                                 cvar_set("utf8_enable", "0");
 591                                                 string msg = substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token));
 592                                                 cvar_set("utf8_enable", utf8_enable_save);
 593
 594                                                 Say(caller, false, tell_to, msg, true);
 595                                                 return;
 596                                         }
 597                                         else { print_to(caller, "You can't ^2tell^7 a message to yourself."); return; }
 598                                 }
 599                                 else if (argv(1) == "#0")
 600                                 {
 601                                         trigger_magicear_processmessage_forallears(caller, -1, NULL, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 602                                         return;
 603                                 }
 604                                 else { print_to(caller, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 605                         }
 606                 }
 607
 608                 default:
 609                         sprint(caller, "Incorrect parameters for ^2tell^7\n");
 610                 case CMD_REQUEST_USAGE:
 611                 {
 612                         sprint(caller, "\nUsage:^3 cmd tell client <message>\n");
 613                         sprint(caller, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 614                         return;
 615                 }
 616         }
 617 }
 618
 619 void ClientCommand_voice(entity caller, int request, int argc, string command)
 620 {
 621         switch (request)
 622         {
 623                 case CMD_REQUEST_COMMAND:
 624                 {
 625                         if (argv(1) != "")
 626                         {
 627                                 entity e = GetVoiceMessage(argv(1));
 628                                 if (!e)
 629                                 {
 630                                         sprint(caller, sprintf("Invalid voice. Use one of: %s\n", allvoicesamples));
 631                                         return;
 632                                 }
 633                                 string msg = "";
 634                                 if (argc >= 3)
 635                                         msg = substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
 636                                 VoiceMessage(caller, e, msg);
 637
 638                                 return;
 639                         }
 640                 }
 641
 642                 default:
 643                         sprint(caller, "Incorrect parameters for ^2voice^7\n");
 644                 case CMD_REQUEST_USAGE:
 645                 {
 646                         sprint(caller, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 647                         sprint(caller, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 648                         sprint(caller, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 649                         return;
 650                 }
 651         }
 652 }
 653
 654 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 655 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 656 void ClientCommand_(entity caller, int request)
 657 {
 658     switch(request)
 659     {
 660         case CMD_REQUEST_COMMAND:
 661         {
 662
 663             return; // never fall through to usage
 664         }
 665
 666         default:
 667         case CMD_REQUEST_USAGE:
 668         {
 669             sprint(caller, "\nUsage:^3 cmd \n");
 670             sprint(caller, "  No arguments required.\n");
 671             return;
 672         }
 673     }
 674 }
 675 */
 676
 677
 678 // =====================================
 679 //  Macro system for networked commands
 680 // =====================================
 681
 682 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 683 #define CLIENT_COMMANDS(ent, request, arguments, command) \
 684         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(ent, request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 685         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(ent, request, arguments), "Release version of the game") \
 686         CLIENT_COMMAND("join", ClientCommand_join(ent, request), "Become a player in the game") \
 687         CLIENT_COMMAND("minigame", ClientCommand_minigame(ent, request, arguments, command), "Start a minigame") \
 688         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(ent, request, arguments), "Retrieve mapshot picture from the server") \
 689         CLIENT_COMMAND("physics", ClientCommand_physics(ent, request, arguments), "Change physics set") \
 690         CLIENT_COMMAND("ready", ClientCommand_ready(ent, request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 691         CLIENT_COMMAND("say", ClientCommand_say(ent, request, arguments, command), "Print a message to chat to all players") \
 692         CLIENT_COMMAND("say_team", ClientCommand_say_team(ent, request, arguments, command), "Print a message to chat to all team mates") \
 693         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(ent, request, arguments), "Attempt to choose a team to join into") \
 694         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(ent, request, command), "Stuffcmd a command to your own client") \
 695         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(ent, request, arguments, command), "New system for sending a client cvar to the server") \
 696         CLIENT_COMMAND("spectate", ClientCommand_spectate(ent, request), "Become an observer") \
 697         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(ent, request, arguments), "Suggest a map to the mapvote at match end") \
 698         CLIENT_COMMAND("tell", ClientCommand_tell(ent, request, arguments, command), "Send a message directly to a player") \
 699         CLIENT_COMMAND("voice", ClientCommand_voice(ent, request, arguments, command), "Send voice message via sound") \
 700         /* nothing */
 701
 702 void ClientCommand_macro_help(entity caller)
 703 {
 704         #define CLIENT_COMMAND(name, function, description) \
 705                 { sprint(caller, "  ^2", name, "^7: ", description, "\n"); }
 706
 707         CLIENT_COMMANDS(NULL, 0, 0, "");
 708 #undef CLIENT_COMMAND
 709 }
 710
 711 float ClientCommand_macro_command(int argc, entity caller, string command)
 712 {
 713         #define CLIENT_COMMAND(name, function, description) \
 714                 { if (name == strtolower(argv(0))) { function; return true; } }
 715
 716         CLIENT_COMMANDS(caller, CMD_REQUEST_COMMAND, argc, command);
 717 #undef CLIENT_COMMAND
 718
 719         return false;
 720 }
 721
 722 float ClientCommand_macro_usage(int argc, entity caller)
 723 {
 724         #define CLIENT_COMMAND(name, function, description) \
 725                 { if (name == strtolower(argv(1))) { function; return true; } }
 726
 727         CLIENT_COMMANDS(caller, CMD_REQUEST_USAGE, argc, "");
 728 #undef CLIENT_COMMAND
 729
 730         return false;
 731 }
 732
 733 void ClientCommand_macro_write_aliases(float fh)
 734 {
 735         #define CLIENT_COMMAND(name, function, description) \
 736                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 737
 738         CLIENT_COMMANDS(NULL, 0, 0, "");
 739 #undef CLIENT_COMMAND
 740 }
 741
 742 // ======================================
 743 //  Main Function Called By Engine (cmd)
 744 // ======================================
 745 // If this function exists, server game code parses clientcommand before the engine code gets it.
 746
 747 void SV_ParseClientCommand(entity this, string command)
 748 {
 749         // If invalid UTF-8, don't even parse it
 750         string command2 = "";
 751         float len = strlen(command);
 752         float i;
 753         for (i = 0; i < len; ++i)
 754                 command2 = strcat(command2, chr2str(str2chr(command, i)));
 755         if (command != command2) return;
 756
 757         // if we're banned, don't even parse the command
 758         if (Ban_MaybeEnforceBanOnce(this)) return;
 759
 760         int argc = tokenize_console(command);
 761
 762         // Guide for working with argc arguments by example:
 763         // argc:   1    - 2      - 3     - 4
 764         // argv:   0    - 1      - 2     - 3
 765         // cmd     vote - master - login - password
 766
 767         // for floodcheck
 768         switch (strtolower(argv(0)))
 769         {
 770                 // exempt commands which are not subject to floodcheck
 771                 case "begin": break;                               // handled by engine in host_cmd.c
 772                 case "download": break;                            // handled by engine in cl_parse.c
 773                 case "mv_getpicture": break;                       // handled by server in this file
 774                 case "pause": break;                               // handled by engine in host_cmd.c
 775                 case "prespawn": break;                            // handled by engine in host_cmd.c
 776                 case "sentcvar": break;                            // handled by server in this file
 777                 case "spawn": break;                               // handled by engine in host_cmd.c
 778                 case "c2s": Net_ClientCommand(this, command); return; // handled by net.qh
 779
 780                 default:
 781                         if (SV_ParseClientCommand_floodcheck(this)) break; // "true": continue, as we're not flooding yet
 782                         else return;                                   // "false": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 783         }
 784
 785         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 786         if (argv(0) == "help")
 787         {
 788                 if (argc == 1)
 789                 {
 790                         sprint(this, "\nClient networked commands:\n");
 791                         ClientCommand_macro_help(this);
 792
 793                         sprint(this, "\nCommon networked commands:\n");
 794                         CommonCommand_macro_help(this);
 795
 796                         sprint(this, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 797                         sprint(this, "For help about a specific command, type cmd help COMMAND\n");
 798                         return;
 799                 }
 800                 else if (CommonCommand_macro_usage(argc, this))  // Instead of trying to call a command, we're going to see detailed information about it
 801                 {
 802                         return;
 803                 }
 804                 else if (ClientCommand_macro_usage(argc, this))  // same, but for normal commands now
 805                 {
 806                         return;
 807                 }
 808         }
 809         else if (MUTATOR_CALLHOOK(SV_ParseClientCommand, this, strtolower(argv(0)), argc, command))
 810         {
 811                 return;  // handled by a mutator
 812         }
 813         else if (CheatCommand(this, argc))
 814         {
 815                 return;  // handled by server/cheats.qc
 816         }
 817         else if (CommonCommand_macro_command(argc, this, command))
 818         {
 819                 return;                                          // handled by server/command/common.qc
 820         }
 821         else if (ClientCommand_macro_command(argc, this, command)) // continue as usual and scan for normal commands
 822         {
 823                 return;                                          // handled by one of the above ClientCommand_* functions
 824         }
 825         else
 826         {
 827                 clientcommand(this, command);
 828         }
 829 }