qcsrc/server/command/cmd.qc

   1 // =========================================================
   2 //  Server side networked commands code, reworked by Samual
   3 //  Last updated: December 28th, 2011
   4 // =========================================================
   5
   6 float SV_ParseClientCommand_floodcheck()
   7 {
   8         if (!timeout_status) // not while paused
   9         {
  10                 if(time <= (self.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  11                 {
  12                         self.cmd_floodcount += 1;
  13                         if(self.cmd_floodcount > autocvar_sv_clientcommand_antispam_count) { return FALSE; } // too much spam, halt
  14                 }
  15                 else
  16                 {
  17                         self.cmd_floodtime = time;
  18                         self.cmd_floodcount = 1;
  19                 }
  20         }
  21         return TRUE; // continue, as we're not flooding yet
  22 }
  23
  24
  25 // =======================
  26 //  Command Sub-Functions
  27 // =======================
  28
  29 void ClientCommand_autoswitch(float request, float argc)
  30 {
  31         switch(request)
  32         {
  33                 case CMD_REQUEST_COMMAND:
  34                 {
  35                         if(argv(1) != "")
  36                         {
  37                                 self.autoswitch = InterpretBoolean(argv(1));
  38                                 sprint(self, strcat("^1autoswitch is currently turned ", (self.autoswitch ? "on" : "off"), ".\n"));
  39                                 return;
  40                         }
  41                 }
  42
  43                 default:
  44                         sprint(self, "Incorrect parameters for ^2autoswitch^7\n");
  45                 case CMD_REQUEST_USAGE:
  46                 {
  47                         sprint(self, "\nUsage:^3 cmd autoswitch selection\n");
  48                         sprint(self, "  Where 'selection' controls if autoswitch is on or off.\n");
  49                         return;
  50                 }
  51         }
  52 }
  53
  54 void ClientCommand_checkfail(float request, string command) // internal command, used only by code
  55 {
  56         switch(request)
  57         {
  58                 case CMD_REQUEST_COMMAND:
  59                 {
  60                         print(sprintf("CHECKFAIL: %s (%s) epically failed check %s\n", self.netname, self.netaddress, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1))));
  61                         self.checkfail = 1;
  62                         return; // never fall through to usage
  63                 }
  64
  65                 default:
  66                         sprint(self, "Incorrect parameters for ^2checkfail^7\n");
  67                 case CMD_REQUEST_USAGE:
  68                 {
  69                         sprint(self, "\nUsage:^3 cmd checkfail <message>\n");
  70                         sprint(self, "  Where 'message' is the message reported by client about the fail.\n");
  71                         return;
  72                 }
  73         }
  74 }
  75
  76 void ClientCommand_clientversion(float request, float argc) // internal command, used only by code
  77 {
  78         switch(request)
  79         {
  80                 case CMD_REQUEST_COMMAND:
  81                 {
  82                         if(argv(1) != "")
  83                         {
  84                                 if(IS_CLIENT(self))
  85                                 {
  86                                         self.version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
  87
  88                                         if(self.version < autocvar_gameversion_min || self.version > autocvar_gameversion_max)
  89                                         {
  90                                                 self.version_mismatch = 1;
  91                                                 ClientKill_TeamChange(-2); // observe
  92                                         }
  93                                         else if(autocvar_g_campaign || autocvar_g_balance_teams)
  94                                         {
  95                                                 //JoinBestTeam(self, FALSE, TRUE);
  96                                         }
  97                                         else if(teamplay && !autocvar_sv_spectate && !(self.team_forced > 0))
  98                                         {
  99                                                 self.classname = "observer"; // really?
 100                                                 stuffcmd(self, "menu_showteamselect\n");
 101                                         }
 102                                 }
 103
 104                                 return;
 105                         }
 106                 }
 107
 108                 default:
 109                         sprint(self, "Incorrect parameters for ^2clientversion^7\n");
 110                 case CMD_REQUEST_USAGE:
 111                 {
 112                         sprint(self, "\nUsage:^3 cmd clientversion version\n");
 113                         sprint(self, "  Where 'version' is the game version reported by self.\n");
 114                         return;
 115                 }
 116         }
 117 }
 118
 119 void ClientCommand_mv_getpicture(float request, float argc) // internal command, used only by code
 120 {
 121         switch(request)
 122         {
 123                 case CMD_REQUEST_COMMAND:
 124                 {
 125                         if(argv(1) != "")
 126                         {
 127                                 if(intermission_running)
 128                                         MapVote_SendPicture(stof(argv(1)));
 129
 130                                 return;
 131                         }
 132                 }
 133
 134                 default:
 135                         sprint(self, "Incorrect parameters for ^2mv_getpicture^7\n");
 136                 case CMD_REQUEST_USAGE:
 137                 {
 138                         sprint(self, "\nUsage:^3 cmd mv_getpicture mapid\n");
 139                         sprint(self, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 140                         return;
 141                 }
 142         }
 143 }
 144
 145 void ClientCommand_join(float request)
 146 {
 147         switch(request)
 148         {
 149                 case CMD_REQUEST_COMMAND:
 150                 {
 151                         if(IS_CLIENT(self))
 152                         {
 153                                 if(!IS_PLAYER(self) && !lockteams)
 154                                 {
 155                                         if(nJoinAllowed(self))
 156                                         {
 157                                                 if(autocvar_g_campaign) { campaign_bots_may_start = 1; }
 158
 159                                                 self.classname = "player";
 160                                                 PlayerScore_Clear(self);
 161                                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
 162                                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname);
 163                                                 PutClientInServer();
 164                                         }
 165                                         else
 166                                         {
 167                                                 //player may not join because of g_maxplayers is set
 168                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
 169                                         }
 170                                 }
 171                         }
 172                         return; // never fall through to usage
 173                 }
 174
 175                 default:
 176                 case CMD_REQUEST_USAGE:
 177                 {
 178                         sprint(self, "\nUsage:^3 cmd join\n");
 179                         sprint(self, "  No arguments required.\n");
 180                         return;
 181                 }
 182         }
 183 }
 184
 185 void ClientCommand_mobedit(float request, float argc)
 186 {
 187         switch(request)
 188         {
 189                 case CMD_REQUEST_COMMAND:
 190                 {
 191                         if(argv(1) && argv(2))
 192                         {
 193                                 makevectors(self.v_angle);
 194                                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 195
 196                                 if(!(trace_ent.flags & FL_MONSTER)) { sprint(self, "You need to aim at your monster to edit its properties.\n"); }
 197                                 else if(trace_ent.realowner != self) { sprint(self, "That monster does not belong to you.\n"); }
 198                                 else // all went well, continue
 199                                 {
 200                                         switch(argv(1))
 201                                         {
 202                                                 case "skin":
 203                                                 {
 204                                                         if(trace_ent.monsterid != MON_MAGE)
 205                                                                 trace_ent.skin = stof(argv(2));
 206                                                         break;
 207                                                 }
 208                                                 case "movetarget":
 209                                                 {
 210                                                         trace_ent.monster_moveflags = stof(argv(2));
 211                                                         break;
 212                                                 }
 213                                         }
 214                                 }
 215
 216                                 return;
 217                         }
 218                 }
 219                 default:
 220                         sprint(self, "Incorrect parameters for ^2mobedit^7\n");
 221                 case CMD_REQUEST_USAGE:
 222                 {
 223                         sprint(self, "\nUsage:^3 cmd mobedit [argument]\n");
 224                         sprint(self, "  Where 'argument' can be skin or movetarget.\n");
 225                         return;
 226                 }
 227         }
 228 }
 229
 230 void ClientCommand_mobkill(float request)
 231 {
 232         switch(request)
 233         {
 234                 case CMD_REQUEST_COMMAND:
 235                 {
 236                         makevectors(self.v_angle);
 237                         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 238
 239                         if(trace_ent.flags & FL_MONSTER)
 240                         {
 241                                 if(trace_ent.realowner != self)
 242                                 {
 243                                         sprint(self, "That monster does not belong to you.\n");
 244                                         return;
 245                                 }
 246                                 sprint(self, strcat("Your pet '", trace_ent.monster_name, "' has been brutally mutilated.\n"));
 247                                 Damage (trace_ent, world, world, trace_ent.health + trace_ent.max_health + 200, DEATH_KILL, trace_ent.origin, '0 0 0');
 248                                 return;
 249                         }
 250                         else
 251                                 sprint(self, "You need to aim at your monster to kill it.\n");
 252
 253                         return;
 254                 }
 255
 256                 default:
 257                         sprint(self, "Incorrect parameters for ^2mobkill^7\n");
 258                 case CMD_REQUEST_USAGE:
 259                 {
 260                         sprint(self, "\nUsage:^3 cmd mobkill\n");
 261                         sprint(self, "  Aim at your monster to kill it.\n");
 262                         return;
 263                 }
 264         }
 265 }
 266
 267 void ClientCommand_mobspawn(float request, float argc)
 268 {
 269         switch(request)
 270         {
 271                 case CMD_REQUEST_COMMAND:
 272                 {
 273                         entity e;
 274                         string tospawn;
 275                         float moveflag;
 276
 277                         moveflag = (argv(2) ? stof(argv(2)) : 1); // follow owner if not defined
 278                         tospawn = strtolower(argv(1));
 279
 280                         if(tospawn == "list")
 281                         {
 282                                 sprint(self, monsterlist_reply);
 283                                 return;
 284                         }
 285
 286                         if(autocvar_g_monsters_max <= 0 || autocvar_g_monsters_max_perplayer <= 0) { sprint(self, "Monster spawning is disabled.\n"); }
 287                         else if(!IS_PLAYER(self)) { sprint(self, "You can't spawn monsters while spectating.\n"); }
 288                         else if(tospawn == "") { sprint(self, "No argument specified.\n"); }
 289                         else if(g_invasion) { sprint(self, "You can't spawn monsters during an invasion!\n"); }
 290                         else if(!autocvar_g_monsters) { Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_MONSTERS_DISABLED); }
 291                         else if(self.vehicle) { sprint(self, "You can't spawn monsters while driving a vehicle.\n"); }
 292                         else if(autocvar_g_campaign) { sprint(self, "You can't spawn monsters in campaign mode.\n"); }
 293                         else if(self.deadflag != DEAD_NO) { sprint(self, "You can't spawn monsters while dead.\n"); }
 294                         else if(self.monstercount >= autocvar_g_monsters_max_perplayer) { sprint(self, "You have spawned too many monsters, kill some before trying to spawn any more.\n"); }
 295                         else if(totalspawned >= autocvar_g_monsters_max) { sprint(self, "The global maximum monster count has been reached, kill some before trying to spawn any more.\n"); }
 296                         else // all worked out, so continue
 297                         {
 298                                 self.monstercount += 1;
 299                                 totalspawned += 1;
 300
 301                                 makevectors(self.v_angle);
 302                                 WarpZone_TraceBox (CENTER_OR_VIEWOFS(self), PL_MIN, PL_MAX, CENTER_OR_VIEWOFS(self) + v_forward * 150, TRUE, self);
 303                                 //WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 150, MOVE_NORMAL, self);
 304
 305                                 e = spawnmonster(tospawn, 0, self, self, trace_endpos, FALSE, moveflag);
 306
 307                                 sprint(self, strcat("Spawned ", e.monster_name, "\n"));
 308                         }
 309
 310                         return;
 311                 }
 312
 313                 default:
 314                         sprint(self, "Incorrect parameters for ^2mobspawn^7\n");
 315                 case CMD_REQUEST_USAGE:
 316                 {
 317                         sprint(self, "\nUsage:^3 cmd mobspawn <random> <monster> [movetype]\n");
 318                         sprint(self, "  See 'cmd mobspawn list' for available arguments.\n");
 319                         sprint(self, "  Argument 'random' spawns a random monster.\n");
 320                         sprint(self, "  Monster will follow the owner if second argument is not defined.\n");
 321                         return;
 322                 }
 323         }
 324 }
 325
 326 void ClientCommand_ready(float request) // todo: anti-spam for toggling readyness
 327 {
 328         switch(request)
 329         {
 330                 case CMD_REQUEST_COMMAND:
 331                 {
 332                         if(IS_CLIENT(self))
 333                         {
 334                                 if(warmup_stage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 335                                 {
 336                                         if(!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 337                                         {
 338                                                 if(time < game_starttime) // game is already restarting
 339                                                         return;
 340                                                 if (self.ready) // toggle
 341                                                 {
 342                                                         self.ready = FALSE;
 343                                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
 344                                                 }
 345                                                 else
 346                                                 {
 347                                                         self.ready = TRUE;
 348                                                         bprint(self.netname, "^2 is ready\n");
 349                                                 }
 350
 351                                                 // cannot reset the game while a timeout is active!
 352                                                 if (!timeout_status)
 353                                                         ReadyCount();
 354                                         } else {
 355                                                 sprint(self, "^1Game has already been restarted\n");
 356                                         }
 357                                 }
 358                         }
 359                         return; // never fall through to usage
 360                 }
 361
 362                 default:
 363                 case CMD_REQUEST_USAGE:
 364                 {
 365                         sprint(self, "\nUsage:^3 cmd ready\n");
 366                         sprint(self, "  No arguments required.\n");
 367                         return;
 368                 }
 369         }
 370 }
 371
 372 void ClientCommand_say(float request, float argc, string command)
 373 {
 374         switch(request)
 375         {
 376                 case CMD_REQUEST_COMMAND:
 377                 {
 378                         if(argc >= 2) { Say(self, FALSE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 379                         return; // never fall through to usage
 380                 }
 381
 382                 default:
 383                 case CMD_REQUEST_USAGE:
 384                 {
 385                         sprint(self, "\nUsage:^3 cmd say <message>\n");
 386                         sprint(self, "  Where 'message' is the string of text to say.\n");
 387                         return;
 388                 }
 389         }
 390 }
 391
 392 void ClientCommand_say_team(float request, float argc, string command)
 393 {
 394         switch(request)
 395         {
 396                 case CMD_REQUEST_COMMAND:
 397                 {
 398                         if(argc >= 2) { Say(self, TRUE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 399                         return; // never fall through to usage
 400                 }
 401
 402                 default:
 403                 case CMD_REQUEST_USAGE:
 404                 {
 405                         sprint(self, "\nUsage:^3 cmd say_team <message>\n");
 406                         sprint(self, "  Where 'message' is the string of text to say.\n");
 407                         return;
 408                 }
 409         }
 410 }
 411
 412 void ClientCommand_selectteam(float request, float argc)
 413 {
 414         switch(request)
 415         {
 416                 case CMD_REQUEST_COMMAND:
 417                 {
 418                         if(argv(1) != "")
 419                         {
 420                                 if(IS_CLIENT(self))
 421                                 {
 422                                         if(teamplay)
 423                                                 if(self.team_forced <= 0)
 424                                                         if (!lockteams)
 425                                                         {
 426                                                                 float selection;
 427
 428                                                                 switch(argv(1))
 429                                                                 {
 430                                                                         case "red": selection = NUM_TEAM_1; break;
 431                                                                         case "blue": selection = NUM_TEAM_2; break;
 432                                                                         case "yellow": selection = NUM_TEAM_3; break;
 433                                                                         case "pink": selection = NUM_TEAM_4; break;
 434                                                                         case "auto": selection = (-1); break;
 435
 436                                                                         default: selection = 0; break;
 437                                                                 }
 438
 439                                                                 if(selection)
 440                                                                 {
 441                                                                         if(self.team == selection && self.deadflag == DEAD_NO)
 442                                                                                 sprint(self, "^7You already are on that team.\n");
 443                                                                         else if(self.wasplayer && autocvar_g_changeteam_banned)
 444                                                                                 sprint(self, "^1You cannot change team, forbidden by the server.\n");
 445                                                                         else
 446                                                                                 ClientKill_TeamChange(selection);
 447                                                                 }
 448                                                         }
 449                                                         else
 450                                                                 sprint(self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 451                                                 else
 452                                                         sprint(self, "^7selectteam can not be used as your team is forced\n");
 453                                         else
 454                                                 sprint(self, "^7selectteam can only be used in teamgames\n");
 455                                 }
 456                                 return;
 457                         }
 458                 }
 459
 460                 default:
 461                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 462                 case CMD_REQUEST_USAGE:
 463                 {
 464                         sprint(self, "\nUsage:^3 cmd selectteam team\n");
 465                         sprint(self, "  Where 'team' is the prefered team to try and join.\n");
 466                         sprint(self, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 467                         return;
 468                 }
 469         }
 470 }
 471
 472 void ClientCommand_selfstuff(float request, string command)
 473 {
 474         switch(request)
 475         {
 476                 case CMD_REQUEST_COMMAND:
 477                 {
 478                         if(argv(1) != "")
 479                         {
 480                                 stuffcmd(self, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 481                                 return;
 482                         }
 483                 }
 484
 485                 default:
 486                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 487                 case CMD_REQUEST_USAGE:
 488                 {
 489                         sprint(self, "\nUsage:^3 cmd selfstuff <command>\n");
 490                         sprint(self, "  Where 'command' is the string to be stuffed to your client.\n");
 491                         return;
 492                 }
 493         }
 494 }
 495
 496 void ClientCommand_sentcvar(float request, float argc, string command)
 497 {
 498         switch(request)
 499         {
 500                 case CMD_REQUEST_COMMAND:
 501                 {
 502                         if(argv(1) != "")
 503                         {
 504                                 //float tokens;
 505                                 string s;
 506
 507                                 if(argc == 2) // undefined cvar: use the default value on the server then
 508                                 {
 509                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 510                                         tokenize_console(s);
 511                                 }
 512
 513                                 GetCvars(1);
 514
 515                                 return;
 516                         }
 517                 }
 518
 519                 default:
 520                         sprint(self, "Incorrect parameters for ^2sentcvar^7\n");
 521                 case CMD_REQUEST_USAGE:
 522                 {
 523                         sprint(self, "\nUsage:^3 cmd sentcvar <cvar>\n");
 524                         sprint(self, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 525                         return;
 526                 }
 527         }
 528 }
 529
 530 void ClientCommand_spectate(float request)
 531 {
 532         switch(request)
 533         {
 534                 case CMD_REQUEST_COMMAND:
 535                 {
 536                         if(IS_CLIENT(self))
 537                         {
 538                                 if(g_lms)
 539                                 {
 540                                         if(self.lms_spectate_warning)
 541                                         {
 542                                                 // for the forfeit message...
 543                                                 self.lms_spectate_warning = 2;
 544                                                 // mark player as spectator
 545                                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 546                                         }
 547                                         else
 548                                         {
 549                                                 self.lms_spectate_warning = 1;
 550                                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 551                                                 return;
 552                                         }
 553                                 }
 554
 555                                 if(IS_PLAYER(self) && autocvar_sv_spectate == 1)
 556                                         ClientKill_TeamChange(-2); // observe
 557
 558                                 // in CA, allow a dead player to move to spectators (without that, caplayer!=0 will be moved back to the player list)
 559                                 // note: if arena game mode is ever done properly, this needs to be removed.
 560                                 if(self.caplayer && (IS_SPEC(self) || IS_OBSERVER(self)))
 561                                 {
 562                                         sprint(self, "WARNING: you will spectate in the next round.\n");
 563                                         self.caplayer = 0;
 564                                 }
 565                         }
 566                         return; // never fall through to usage
 567                 }
 568
 569                 default:
 570                 case CMD_REQUEST_USAGE:
 571                 {
 572                         sprint(self, "\nUsage:^3 cmd spectate\n");
 573                         sprint(self, "  No arguments required.\n");
 574                         return;
 575                 }
 576         }
 577 }
 578
 579 void ClientCommand_suggestmap(float request, float argc)
 580 {
 581         switch(request)
 582         {
 583                 case CMD_REQUEST_COMMAND:
 584                 {
 585                         if(argv(1) != "")
 586                         {
 587                                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 588                                 return;
 589                         }
 590                 }
 591
 592                 default:
 593                         sprint(self, "Incorrect parameters for ^2suggestmap^7\n");
 594                 case CMD_REQUEST_USAGE:
 595                 {
 596                         sprint(self, "\nUsage:^3 cmd suggestmap map\n");
 597                         sprint(self, "  Where 'map' is the name of the map to suggest.\n");
 598                         return;
 599                 }
 600         }
 601 }
 602
 603 void ClientCommand_tell(float request, float argc, string command)
 604 {
 605         switch(request)
 606         {
 607                 case CMD_REQUEST_COMMAND:
 608                 {
 609                         if(argc >= 3)
 610                         {
 611                                 entity tell_to = GetIndexedEntity(argc, 1);
 612                                 float tell_accepted = VerifyClientEntity(tell_to, TRUE, FALSE);
 613
 614                                 if(tell_accepted > 0) // the target is a real client
 615                                 {
 616                                         if(tell_to != self) // and we're allowed to send to them :D
 617                                         {
 618                                                 Say(self, FALSE, tell_to, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)), TRUE);
 619                                                 return;
 620                                         }
 621                                         else { print_to(self, "You can't ^2tell^7 a message to yourself."); return; }
 622                                 }
 623                                 else if(argv(1) == "#0")
 624                                 {
 625                                         trigger_magicear_processmessage_forallears(self, -1, world, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 626                                         return;
 627                                 }
 628                                 else { print_to(self, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 629                         }
 630                 }
 631
 632                 default:
 633                         sprint(self, "Incorrect parameters for ^2tell^7\n");
 634                 case CMD_REQUEST_USAGE:
 635                 {
 636                         sprint(self, "\nUsage:^3 cmd tell client <message>\n");
 637                         sprint(self, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 638                         return;
 639                 }
 640         }
 641 }
 642
 643 void ClientCommand_voice(float request, float argc, string command)
 644 {
 645         switch(request)
 646         {
 647                 case CMD_REQUEST_COMMAND:
 648                 {
 649                         if(argv(1) != "")
 650                         {
 651                                 if(argc >= 3)
 652                                         VoiceMessage(argv(1), substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 653                                 else
 654                                         VoiceMessage(argv(1), "");
 655
 656                                 return;
 657                         }
 658                 }
 659
 660                 default:
 661                         sprint(self, "Incorrect parameters for ^2voice^7\n");
 662                 case CMD_REQUEST_USAGE:
 663                 {
 664                         sprint(self, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 665                         sprint(self, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 666                         sprint(self, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 667                         return;
 668                 }
 669         }
 670 }
 671
 672 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 673 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 674 void ClientCommand_(float request)
 675 {
 676         switch(request)
 677         {
 678                 case CMD_REQUEST_COMMAND:
 679                 {
 680
 681                         return; // never fall through to usage
 682                 }
 683
 684                 default:
 685                 case CMD_REQUEST_USAGE:
 686                 {
 687                         sprint(self, "\nUsage:^3 cmd \n");
 688                         sprint(self, "  No arguments required.\n");
 689                         return;
 690                 }
 691         }
 692 }
 693 */
 694
 695
 696 // =====================================
 697 //  Macro system for networked commands
 698 // =====================================
 699
 700 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 701 #define CLIENT_COMMANDS(request,arguments,command) \
 702         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 703         CLIENT_COMMAND("checkfail", ClientCommand_checkfail(request, command), "Report if a client-side check failed") \
 704         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(request, arguments), "Release version of the game") \
 705         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(request, arguments), "Retrieve mapshot picture from the server") \
 706         CLIENT_COMMAND("join", ClientCommand_join(request), "Become a player in the game") \
 707         CLIENT_COMMAND("mobedit", ClientCommand_mobedit(request, arguments), "Edit your monster's properties") \
 708         CLIENT_COMMAND("mobkill", ClientCommand_mobkill(request), "Kills your monster") \
 709         CLIENT_COMMAND("mobspawn", ClientCommand_mobspawn(request, arguments), "Spawn monsters infront of yourself") \
 710         CLIENT_COMMAND("ready", ClientCommand_ready(request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 711         CLIENT_COMMAND("say", ClientCommand_say(request, arguments, command), "Print a message to chat to all players") \
 712         CLIENT_COMMAND("say_team", ClientCommand_say_team(request, arguments, command), "Print a message to chat to all team mates") \
 713         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(request, arguments), "Attempt to choose a team to join into") \
 714         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(request, command), "Stuffcmd a command to your own client") \
 715         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(request, arguments, command), "New system for sending a client cvar to the server") \
 716         CLIENT_COMMAND("spectate", ClientCommand_spectate(request), "Become an observer") \
 717         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(request, arguments), "Suggest a map to the mapvote at match end") \
 718         CLIENT_COMMAND("tell", ClientCommand_tell(request, arguments, command), "Send a message directly to a player") \
 719         CLIENT_COMMAND("voice", ClientCommand_voice(request, arguments, command), "Send voice message via sound") \
 720         /* nothing */
 721
 722 void ClientCommand_macro_help()
 723 {
 724         #define CLIENT_COMMAND(name,function,description) \
 725                 { sprint(self, "  ^2", name, "^7: ", description, "\n"); }
 726
 727         CLIENT_COMMANDS(0, 0, "")
 728         #undef CLIENT_COMMAND
 729
 730         return;
 731 }
 732
 733 float ClientCommand_macro_command(float argc, string command)
 734 {
 735         #define CLIENT_COMMAND(name,function,description) \
 736                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 737
 738         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
 739         #undef CLIENT_COMMAND
 740
 741         return FALSE;
 742 }
 743
 744 float ClientCommand_macro_usage(float argc)
 745 {
 746         #define CLIENT_COMMAND(name,function,description) \
 747                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 748
 749         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc, "")
 750         #undef CLIENT_COMMAND
 751
 752         return FALSE;
 753 }
 754
 755 void ClientCommand_macro_write_aliases(float fh)
 756 {
 757         #define CLIENT_COMMAND(name,function,description) \
 758                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 759
 760         CLIENT_COMMANDS(0, 0, "")
 761         #undef CLIENT_COMMAND
 762
 763         return;
 764 }
 765
 766 // ======================================
 767 //  Main Function Called By Engine (cmd)
 768 // ======================================
 769 // If this function exists, server game code parses clientcommand before the engine code gets it.
 770
 771 void SV_ParseClientCommand(string command)
 772 {
 773         // if we're banned, don't even parse the command
 774         if(Ban_MaybeEnforceBanOnce(self))
 775                 return;
 776
 777         float argc = tokenize_console(command);
 778
 779         // for the mutator hook system
 780         cmd_name = strtolower(argv(0));
 781         cmd_argc = argc;
 782         cmd_string = command;
 783
 784         // Guide for working with argc arguments by example:
 785         // argc:   1    - 2      - 3     - 4
 786         // argv:   0    - 1      - 2     - 3
 787         // cmd     vote - master - login - password
 788
 789         // for floodcheck
 790         switch(strtolower(argv(0)))
 791         {
 792                 // exempt commands which are not subject to floodcheck
 793                 case "begin": break; // handled by engine in host_cmd.c
 794                 case "download": break; // handled by engine in cl_parse.c
 795                 case "mv_getpicture": break; // handled by server in this file
 796                 case "pause": break; // handled by engine in host_cmd.c
 797                 case "prespawn": break; // handled by engine in host_cmd.c
 798                 case "sentcvar": break; // handled by server in this file
 799                 case "spawn": break; // handled by engine in host_cmd.c
 800
 801                 default:
 802                         if(SV_ParseClientCommand_floodcheck())
 803                                 break; // "TRUE": continue, as we're not flooding yet
 804                         else
 805                                 return; // "FALSE": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 806         }
 807
 808         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 809         if(argv(0) == "help")
 810         {
 811                 if(argc == 1)
 812                 {
 813                         sprint(self, "\nClient networked commands:\n");
 814                         ClientCommand_macro_help();
 815
 816                         sprint(self, "\nCommon networked commands:\n");
 817                         CommonCommand_macro_help(self);
 818
 819                         sprint(self, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 820                         sprint(self, "For help about a specific command, type cmd help COMMAND\n");
 821                         return;
 822                 }
 823                 else if(CommonCommand_macro_usage(argc, self)) // Instead of trying to call a command, we're going to see detailed information about it
 824                 {
 825                         return;
 826                 }
 827                 else if(ClientCommand_macro_usage(argc)) // same, but for normal commands now
 828                 {
 829                         return;
 830                 }
 831         }
 832         else if(MUTATOR_CALLHOOK(SV_ParseClientCommand))
 833         {
 834                 return; // handled by a mutator
 835         }
 836         else if(CheatCommand(argc))
 837         {
 838                 return; // handled by server/cheats.qc
 839         }
 840         else if(CommonCommand_macro_command(argc, self, command))
 841         {
 842                 return; // handled by server/command/common.qc
 843         }
 844         else if(ClientCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 845         {
 846                 return; // handled by one of the above ClientCommand_* functions
 847         }
 848         else
 849                 clientcommand(self, command);
 850 }