qcsrc/server/command/common.qc

   1 #include "common.qh"
   2 #include <common/command/command.qh>
   3 #include "common.qh"
   4
   5 #include "../scores.qh"
   6
   7 #include <common/monsters/all.qh>
   8 #include <common/notifications/all.qh>
   9 #include <lib/warpzone/common.qh>
  10
  11
  12 // ====================================================
  13 //  Shared code for server commands, written by Samual
  14 //  Last updated: December 27th, 2011
  15 // ====================================================
  16
  17 // select the proper prefix for usage and other messages
  18 string GetCommandPrefix(entity caller)
  19 {
  20         if (caller) return "cmd";
  21         else return "sv_cmd";
  22 }
  23
  24 // if client return player nickname, or if server return admin nickname
  25 string GetCallerName(entity caller)
  26 {
  27         if (caller) return caller.netname;
  28         else return admin_name();  // ((autocvar_sv_adminnick != "") ? autocvar_sv_adminnick : autocvar_hostname);
  29 }
  30
  31 // verify that the client provided is acceptable for kicking
  32 float VerifyKickableEntity(entity client)
  33 {
  34         if (!IS_REAL_CLIENT(client)) return CLIENT_NOT_REAL;
  35         return CLIENT_ACCEPTABLE;
  36 }
  37
  38 // verify that the client provided is acceptable for use
  39 float VerifyClientEntity(entity client, float must_be_real, float must_be_bots)
  40 {
  41         if (!IS_CLIENT(client)) return CLIENT_DOESNT_EXIST;
  42         else if (must_be_real && !IS_REAL_CLIENT(client)) return CLIENT_NOT_REAL;
  43         else if (must_be_bots && !IS_BOT_CLIENT(client)) return CLIENT_NOT_BOT;
  44
  45         return CLIENT_ACCEPTABLE;
  46 }
  47
  48 // if the client is not acceptable, return a string to be used for error messages
  49 string GetClientErrorString_color(float clienterror, string original_input, string col)
  50 {
  51         switch (clienterror)
  52         {
  53                 case CLIENT_DOESNT_EXIST:
  54                 { return strcat(col, "Client '", original_input, col, "' doesn't exist");
  55                 }
  56                 case CLIENT_NOT_REAL:
  57                 { return strcat(col, "Client '", original_input, col, "' is not real");
  58                 }
  59                 case CLIENT_NOT_BOT:
  60                 { return strcat(col, "Client '", original_input, col, "' is not a bot");
  61                 }
  62                 default:
  63                 { return "Incorrect usage of GetClientErrorString";
  64                 }
  65         }
  66 }
  67
  68 // is this entity number even in the possible range of entities?
  69 float VerifyClientNumber(float tmp_number)
  70 {
  71         if ((tmp_number < 1) || (tmp_number > maxclients)) return false;
  72         else return true;
  73 }
  74
  75 entity GetIndexedEntity(float argc, float start_index)
  76 {
  77         entity selection;
  78         float tmp_number, index;
  79         string tmp_string;
  80
  81         next_token = -1;
  82         index = start_index;
  83         selection = world;
  84
  85         if (argc > start_index)
  86         {
  87                 if (substring(argv(index), 0, 1) == "#")
  88                 {
  89                         tmp_string = substring(argv(index), 1, -1);
  90                         ++index;
  91
  92                         if (tmp_string != "")  // is it all one token? like #1
  93                         {
  94                                 tmp_number = stof(tmp_string);
  95                         }
  96                         else if (argc > index)  // no, it's two tokens? # 1
  97                         {
  98                                 tmp_number = stof(argv(index));
  99                                 ++index;
 100                         }
 101                         else
 102                         {
 103                                 tmp_number = 0;
 104                         }
 105                 }
 106                 else  // maybe it's ONLY a number?
 107                 {
 108                         tmp_number = stof(argv(index));
 109                         ++index;
 110                 }
 111
 112                 if (VerifyClientNumber(tmp_number))
 113                 {
 114                         selection = edict_num(tmp_number);  // yes, it was a number
 115                 }
 116                 else  // no, maybe it's a name?
 117                 {
 118                         FOREACH_CLIENT(true, LAMBDA(
 119                                 if(strdecolorize(it.netname) == strdecolorize(argv(start_index)))
 120                                 {
 121                                         selection = it;
 122                                         break; // no reason to keep looking
 123                                 }
 124                         ));
 125
 126                         index = (start_index + 1);
 127                 }
 128         }
 129
 130         next_token = index;
 131         // print(strcat("start_index: ", ftos(start_index), ", next_token: ", ftos(next_token), ", edict: ", ftos(num_for_edict(selection)), ".\n"));
 132         return selection;
 133 }
 134
 135 // find a player which matches the input string, and return their entity
 136 entity GetFilteredEntity(string input)
 137 {
 138         entity selection;
 139         float tmp_number;
 140
 141         if (substring(input, 0, 1) == "#") tmp_number = stof(substring(input, 1, -1));
 142         else tmp_number = stof(input);
 143
 144         if (VerifyClientNumber(tmp_number))
 145         {
 146                 selection = edict_num(tmp_number);
 147         }
 148         else
 149         {
 150                 selection = world;
 151                 FOREACH_CLIENT(true, LAMBDA(
 152                         if(strdecolorize(it.netname) == strdecolorize(input))
 153                         {
 154                                 selection = it;
 155                                 break; // no reason to keep looking
 156                         }
 157                 ));
 158         }
 159
 160         return selection;
 161 }
 162
 163 // same thing, but instead return their edict number
 164 float GetFilteredNumber(string input)
 165 {
 166         entity selection = GetFilteredEntity(input);
 167         float output;
 168
 169         output = etof(selection);
 170
 171         return output;
 172 }
 173
 174 // switch between sprint and print depending on whether the receiver is the server or a player
 175 void print_to(entity to, string input)
 176 {
 177         if (to) sprint(to, strcat(input, "\n"));
 178         else LOG_INFO(input, "\n");
 179 }
 180
 181 // ==========================================
 182 //  Supporting functions for common commands
 183 // ==========================================
 184
 185 // used by CommonCommand_timeout() and CommonCommand_timein() to handle game pausing and messaging and such.
 186 void timeout_handler_reset()
 187 {
 188         SELFPARAM();
 189         timeout_caller = world;
 190         timeout_time = 0;
 191         timeout_leadtime = 0;
 192
 193         remove(self);
 194 }
 195
 196 void timeout_handler_think()
 197 {
 198         SELFPARAM();
 199         switch (timeout_status)
 200         {
 201                 case TIMEOUT_ACTIVE:
 202                 {
 203                         if (timeout_time > 0)  // countdown is still going
 204                         {
 205                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_TIMEOUT_ENDING, timeout_time);
 206
 207                                 if (timeout_time == autocvar_sv_timeout_resumetime) // play a warning sound when only <sv_timeout_resumetime> seconds are left
 208                                         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_PREPARE);
 209
 210                                 self.nextthink = time + TIMEOUT_SLOWMO_VALUE;       // think again in one second
 211                                 timeout_time -= 1;                                  // decrease the time counter
 212                         }
 213                         else  // time to end the timeout
 214                         {
 215                                 timeout_status = TIMEOUT_INACTIVE;
 216
 217                                 // reset the slowmo value back to normal
 218                                 cvar_set("slowmo", ftos(orig_slowmo));
 219
 220                                 // unlock the view for players so they can move around again
 221                                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(
 222                                         it.fixangle = false;
 223                                 ));
 224
 225                                 timeout_handler_reset();
 226                         }
 227
 228                         return;
 229                 }
 230
 231                 case TIMEOUT_LEADTIME:
 232                 {
 233                         if (timeout_leadtime > 0)  // countdown is still going
 234                         {
 235                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_TIMEOUT_BEGINNING, timeout_leadtime);
 236
 237                                 self.nextthink = time + 1; // think again in one second
 238                                 timeout_leadtime -= 1;     // decrease the time counter
 239                         }
 240                         else  // time to begin the timeout
 241                         {
 242                                 timeout_status = TIMEOUT_ACTIVE;
 243
 244                                 // set the slowmo value to the timeout default slowmo value
 245                                 cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 246
 247                                 // reset all the flood variables
 248                                 FOREACH_CLIENT(true, LAMBDA(
 249                                         it.nickspamcount = it.nickspamtime = it.floodcontrol_chat =
 250                                                 it.floodcontrol_chatteam = it.floodcontrol_chattell =
 251                                                         it.floodcontrol_voice = it.floodcontrol_voiceteam = 0;
 252                                 ));
 253
 254                                 // copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 255                                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(
 256                                         it.lastV_angle = it.v_angle;
 257                                 ));
 258
 259                                 self.nextthink = time;  // think again next frame to handle it under TIMEOUT_ACTIVE code
 260                         }
 261
 262                         return;
 263                 }
 264
 265
 266                 case TIMEOUT_INACTIVE:
 267                 default:
 268                 {
 269                         timeout_handler_reset();
 270                         return;
 271                 }
 272         }
 273 }
 274
 275
 276 // ===================================================
 277 //  Common commands used in both sv_cmd.qc and cmd.qc
 278 // ===================================================
 279
 280 void CommonCommand_cvar_changes(float request, entity caller)
 281 {
 282         switch (request)
 283         {
 284                 case CMD_REQUEST_COMMAND:
 285                 {
 286                         print_to(caller, cvar_changes);
 287                         return;  // never fall through to usage
 288                 }
 289
 290                 default:
 291                 case CMD_REQUEST_USAGE:
 292                 {
 293                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_changes"));
 294                         print_to(caller, "  No arguments required.");
 295                         print_to(caller, "See also: ^2cvar_purechanges^7");
 296                         return;
 297                 }
 298         }
 299 }
 300
 301 void CommonCommand_cvar_purechanges(float request, entity caller)
 302 {
 303         switch (request)
 304         {
 305                 case CMD_REQUEST_COMMAND:
 306                 {
 307                         print_to(caller, cvar_purechanges);
 308                         return;  // never fall through to usage
 309                 }
 310
 311                 default:
 312                 case CMD_REQUEST_USAGE:
 313                 {
 314                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_purechanges"));
 315                         print_to(caller, "  No arguments required.");
 316                         print_to(caller, "See also: ^2cvar_changes^7");
 317                         return;
 318                 }
 319         }
 320 }
 321
 322 void CommonCommand_editmob(int request, entity caller, int argc)
 323 {
 324         SELFPARAM();
 325         switch (request)
 326         {
 327                 case CMD_REQUEST_COMMAND:
 328                 {
 329                         if (autocvar_g_campaign) { print_to(caller, "Monster editing is disabled in singleplayer"); return; }
 330                         // no checks for g_monsters here, as it may be toggled mid match which existing monsters
 331
 332                         if (caller)
 333                         {
 334                                 makevectors(caller.v_angle);
 335                                 WarpZone_TraceLine(caller.origin + caller.view_ofs, caller.origin + caller.view_ofs + v_forward * 100, MOVE_NORMAL, caller);
 336                         }
 337
 338                         entity mon = trace_ent;
 339                         bool is_visible = IS_MONSTER(mon);
 340                         string argument = argv(2);
 341
 342                         switch (argv(1))
 343                         {
 344                                 case "name":
 345                                 {
 346                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
 347                                         if (!argument)   break;  // escape to usage
 348                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 349                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 350                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 351
 352                                         string mon_oldname = mon.monster_name;
 353
 354                                         mon.monster_name = argument;
 355                                         if (mon.sprite)   WaypointSprite_UpdateSprites(mon.sprite, WP_Monster, WP_Null, WP_Null);
 356                                         print_to(caller, sprintf("Your pet '%s' is now known as '%s'", mon_oldname, mon.monster_name));
 357                                         return;
 358                                 }
 359                                 case "spawn":
 360                                 {
 361                                         if (!caller) { print_to(caller, "Only players can spawn monsters"); return; }
 362                                         if (!argv(2))   break;  // escape to usage
 363
 364                                         int moveflag, tmp_moncount = 0;
 365                                         string arg_lower = strtolower(argument);
 366                                         moveflag = (argv(3)) ? stof(argv(3)) : 1;  // follow owner if not defined
 367                                         ret_string = "Monster spawning is currently disabled by a mutator";
 368
 369                                         if (arg_lower == "list") { print_to(caller, monsterlist_reply); return; }
 370
 371                                         FOREACH_ENTITY_FLAGS(flags, FL_MONSTER, LAMBDA(
 372                                                 if(it.realowner == caller)
 373                                                         ++tmp_moncount;
 374                                         ));
 375
 376                                         if (!autocvar_g_monsters) { print_to(caller, "Monsters are disabled"); return; }
 377                                         if (autocvar_g_monsters_max <= 0 || autocvar_g_monsters_max_perplayer <= 0) { print_to(caller, "Monster spawning is disabled"); return; }
 378                                         if (!IS_PLAYER(caller)) { print_to(caller, "You must be playing to spawn a monster"); return; }
 379                                         if (MUTATOR_CALLHOOK(AllowMobSpawning)) { print_to(caller, ret_string); return; }
 380                                         if (caller.vehicle) { print_to(caller, "You can't spawn monsters while driving a vehicle"); return; }
 381                                         if (STAT(FROZEN, caller)) { print_to(caller, "You can't spawn monsters while frozen"); return; }
 382                                         if (IS_DEAD(caller)) { print_to(caller, "You can't spawn monsters while dead"); return; }
 383                                         if (tmp_moncount >= autocvar_g_monsters_max) { print_to(caller, "The maximum monster count has been reached"); return; }
 384                                         if (tmp_moncount >= autocvar_g_monsters_max_perplayer) { print_to(caller, "You can't spawn any more monsters"); return; }
 385
 386                                         bool found = false;
 387                                         for (int i = MON_FIRST; i <= MON_LAST; ++i)
 388                                         {
 389                                                 mon = get_monsterinfo(i);
 390                                                 if (mon.netname == arg_lower) { found = true; break; }
 391                                         }
 392
 393                                         if (!found && arg_lower != "random") { print_to(caller, "Invalid monster"); return; }
 394
 395                                         totalspawned += 1;
 396                                         WarpZone_TraceBox(CENTER_OR_VIEWOFS(caller), caller.mins, caller.maxs, CENTER_OR_VIEWOFS(caller) + v_forward * 150, true, caller);
 397                                         mon = spawnmonster(arg_lower, 0, caller, caller, trace_endpos, false, false, moveflag);
 398                                         print_to(caller, strcat("Spawned ", mon.monster_name));
 399                                         return;
 400                                 }
 401                                 case "kill":
 402                                 {
 403                                         if (!caller) { print_to(caller, "Only players can kill monsters"); return; }
 404                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 405                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 406
 407                                         Damage(mon, world, world, mon.health + mon.max_health + 200, DEATH_KILL.m_id, mon.origin, '0 0 0');
 408                                         print_to(caller, strcat("Your pet '", mon.monster_name, "' has been brutally mutilated"));
 409                                         return;
 410                                 }
 411                                 case "skin":
 412                                 {
 413                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
 414                                         if (!argument)   break;  // escape to usage
 415                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 416                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 417                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 418                                         if (mon.monsterid == MON_MAGE.monsterid) { print_to(caller, "Mage skins can't be changed"); return; }  // TODO
 419
 420                                         mon.skin = stof(argument);
 421                                         print_to(caller, strcat("Monster skin successfully changed to ", ftos(mon.skin)));
 422                                         return;
 423                                 }
 424                                 case "movetarget":
 425                                 {
 426                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
 427                                         if (!argument)   break;  // escape to usage
 428                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 429                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 430                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 431
 432                                         mon.monster_moveflags = stof(argument);
 433                                         print_to(caller, strcat("Monster move target successfully changed to ", ftos(mon.monster_moveflags)));
 434                                         return;
 435                                 }
 436                                 case "butcher":
 437                                 {
 438                                         if (caller) { print_to(caller, "This command is not available to players"); return; }
 439                                         if (MUTATOR_CALLHOOK(AllowMobButcher)) { LOG_INFO(ret_string, "\n"); return; }
 440
 441                                         int tmp_remcount = 0;
 442
 443                                         FOREACH_ENTITY_FLAGS(flags, FL_MONSTER, LAMBDA(
 444                                                 Monster_Remove(it);
 445                                                 ++tmp_remcount;
 446                                         ));
 447
 448                                         monsters_total = monsters_killed = totalspawned = 0;
 449
 450                                         print_to(caller, (tmp_remcount) ? sprintf("Killed %d monster%s", tmp_remcount, (tmp_remcount == 1) ? "" : "s") : "No monsters to kill");
 451                                         return;
 452                                 }
 453                         }
 454                 }
 455
 456                 default:
 457                 case CMD_REQUEST_USAGE:
 458                 {
 459                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " editmob command [arguments]"));
 460                         print_to(caller, "  Where 'command' can be butcher spawn skin movetarget kill name");
 461                         print_to(caller, "  spawn, skin, movetarget and name require 'arguments'");
 462                         print_to(caller, "  spawn also takes arguments list and random");
 463                         print_to(caller, "  Monster will follow owner if third argument of spawn command is not defined");
 464                         return;
 465                 }
 466         }
 467 }
 468
 469 void CommonCommand_info(float request, entity caller, float argc)
 470 {
 471         switch (request)
 472         {
 473                 case CMD_REQUEST_COMMAND:
 474                 {
 475                         string command = builtin_cvar_string(strcat("sv_info_", argv(1)));
 476
 477                         if (command) wordwrap_sprint(command, 1000);
 478                         else print_to(caller, "ERROR: unsupported info command");
 479
 480                         return;  // never fall through to usage
 481                 }
 482
 483                 default:
 484                 case CMD_REQUEST_USAGE:
 485                 {
 486                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " info request"));
 487                         print_to(caller, "  Where 'request' is the suffixed string appended onto the request for cvar.");
 488                         return;
 489                 }
 490         }
 491 }
 492
 493 void CommonCommand_ladder(float request, entity caller)
 494 {
 495         switch (request)
 496         {
 497                 case CMD_REQUEST_COMMAND:
 498                 {
 499                         print_to(caller, ladder_reply);
 500                         return;  // never fall through to usage
 501                 }
 502
 503                 default:
 504                 case CMD_REQUEST_USAGE:
 505                 {
 506                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " ladder"));
 507                         print_to(caller, "  No arguments required.");
 508                         return;
 509                 }
 510         }
 511 }
 512
 513 void CommonCommand_lsmaps(float request, entity caller)
 514 {
 515         switch (request)
 516         {
 517                 case CMD_REQUEST_COMMAND:
 518                 {
 519                         print_to(caller, lsmaps_reply);
 520                         return;  // never fall through to usage
 521                 }
 522
 523                 default:
 524                 case CMD_REQUEST_USAGE:
 525                 {
 526                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " lsmaps"));
 527                         print_to(caller, "  No arguments required.");
 528                         return;
 529                 }
 530         }
 531 }
 532
 533 void CommonCommand_printmaplist(float request, entity caller)
 534 {
 535         switch (request)
 536         {
 537                 case CMD_REQUEST_COMMAND:
 538                 {
 539                         print_to(caller, maplist_reply);
 540                         return;  // never fall through to usage
 541                 }
 542
 543                 default:
 544                 case CMD_REQUEST_USAGE:
 545                 {
 546                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " printmaplist"));
 547                         print_to(caller, "  No arguments required.");
 548                         return;
 549                 }
 550         }
 551 }
 552
 553 void CommonCommand_rankings(float request, entity caller)
 554 {
 555         switch (request)
 556         {
 557                 case CMD_REQUEST_COMMAND:
 558                 {
 559                         print_to(caller, rankings_reply);
 560                         return;  // never fall through to usage
 561                 }
 562
 563                 default:
 564                 case CMD_REQUEST_USAGE:
 565                 {
 566                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " rankings"));
 567                         print_to(caller, "  No arguments required.");
 568                         return;
 569                 }
 570         }
 571 }
 572
 573 void CommonCommand_records(float request, entity caller)
 574 {
 575         switch (request)
 576         {
 577                 case CMD_REQUEST_COMMAND:
 578                 {
 579                         for (int i = 0; i < 10; ++i)
 580                                 if (records_reply[i] != "") print_to(caller, records_reply[i]);
 581
 582                         return;  // never fall through to usage
 583                 }
 584
 585                 default:
 586                 case CMD_REQUEST_USAGE:
 587                 {
 588                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " records"));
 589                         print_to(caller, "  No arguments required.");
 590                         return;
 591                 }
 592         }
 593 }
 594
 595 void CommonCommand_teamstatus(float request, entity caller)
 596 {
 597         switch (request)
 598         {
 599                 case CMD_REQUEST_COMMAND:
 600                 {
 601                         Score_NicePrint(caller);
 602                         return;  // never fall through to usage
 603                 }
 604
 605                 default:
 606                 case CMD_REQUEST_USAGE:
 607                 {
 608                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " teamstatus"));
 609                         print_to(caller, "  No arguments required.");
 610                         return;
 611                 }
 612         }
 613 }
 614
 615 void CommonCommand_time(float request, entity caller)
 616 {
 617         switch (request)
 618         {
 619                 case CMD_REQUEST_COMMAND:
 620                 {
 621                         print_to(caller, strcat("time = ", ftos(time)));
 622                         print_to(caller, strcat("frame start = ", ftos(gettime(GETTIME_FRAMESTART))));
 623                         print_to(caller, strcat("realtime = ", ftos(gettime(GETTIME_REALTIME))));
 624                         print_to(caller, strcat("hires = ", ftos(gettime(GETTIME_HIRES))));
 625                         print_to(caller, strcat("uptime = ", ftos(gettime(GETTIME_UPTIME))));
 626                         print_to(caller, strcat("localtime = ", strftime(true, "%a %b %e %H:%M:%S %Z %Y")));
 627                         print_to(caller, strcat("gmtime = ", strftime(false, "%a %b %e %H:%M:%S %Z %Y")));
 628                         return;
 629                 }
 630
 631                 default:
 632                 case CMD_REQUEST_USAGE:
 633                 {
 634                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " time"));
 635                         print_to(caller, "  No arguments required.");
 636                         return;
 637                 }
 638         }
 639 }
 640
 641 void CommonCommand_timein(float request, entity caller)
 642 {
 643         switch (request)
 644         {
 645                 case CMD_REQUEST_COMMAND:
 646                 {
 647                         if (!caller || autocvar_sv_timeout)
 648                         {
 649                                 if (!timeout_status) { print_to(caller, "^7Error: There is no active timeout called."); }
 650                                 else if (caller && (caller != timeout_caller))
 651                                 {
 652                                         print_to(caller, "^7Error: You are not allowed to stop the active timeout.");
 653                                 }
 654
 655                                 else  // everything should be okay, continue aborting timeout
 656                                 {
 657                                         switch (timeout_status)
 658                                         {
 659                                                 case TIMEOUT_LEADTIME:
 660                                                 {
 661                                                         timeout_status = TIMEOUT_INACTIVE;
 662                                                         timeout_time = 0;
 663                                                         timeout_handler.nextthink = time;  // timeout_handler has to take care of it immediately
 664                                                         bprint(strcat("^7The timeout was aborted by ", GetCallerName(caller), " !\n"));
 665                                                         return;
 666                                                 }
 667
 668                                                 case TIMEOUT_ACTIVE:
 669                                                 {
 670                                                         timeout_time = autocvar_sv_timeout_resumetime;
 671                                                         timeout_handler.nextthink = time;  // timeout_handler has to take care of it immediately
 672                                                         bprint(strcat("^1Attention: ^7", GetCallerName(caller), " resumed the game! Prepare for battle!\n"));
 673                                                         return;
 674                                                 }
 675
 676                                                 default: LOG_TRACE("timeout status was inactive, but this code was executed anyway?");
 677                                                         return;
 678                                         }
 679                                 }
 680                         }
 681                         else { print_to(caller, "^1Timeins are not allowed to be called, enable them with sv_timeout 1.\n"); }
 682
 683                         return;  // never fall through to usage
 684                 }
 685
 686                 default:
 687                 case CMD_REQUEST_USAGE:
 688                 {
 689                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timein"));
 690                         print_to(caller, "  No arguments required.");
 691                         return;
 692                 }
 693         }
 694 }
 695
 696 void CommonCommand_timeout(float request, entity caller)  // DEAR GOD THIS COMMAND IS TERRIBLE.
 697 {
 698         switch (request)
 699         {
 700                 case CMD_REQUEST_COMMAND:
 701                 {
 702                         if (!caller || autocvar_sv_timeout)
 703                         {
 704                                 float last_possible_timeout = ((autocvar_timelimit * 60) - autocvar_sv_timeout_leadtime - 1);
 705
 706                                 if (timeout_status) { print_to(caller, "^7Error: A timeout is already active."); }
 707                                 else if (vote_called)
 708                                 {
 709                                         print_to(caller, "^7Error: You can not call a timeout while a vote is active.");
 710                                 }
 711                                 else if (warmup_stage && !g_warmup_allow_timeout)
 712                                 {
 713                                         print_to(caller, "^7Error: You can not call a timeout in warmup-stage.");
 714                                 }
 715                                 else if (time < game_starttime)
 716                                 {
 717                                         print_to(caller, "^7Error: You can not call a timeout while the map is being restarted.");
 718                                 }
 719                                 else if (caller && (caller.allowed_timeouts < 1))
 720                                 {
 721                                         print_to(caller, "^7Error: You already used all your timeout calls for this map.");
 722                                 }
 723                                 else if (caller && !IS_PLAYER(caller))
 724                                 {
 725                                         print_to(caller, "^7Error: You must be a player to call a timeout.");
 726                                 }
 727                                 else if ((autocvar_timelimit) && (last_possible_timeout < time - game_starttime))
 728                                 {
 729                                         print_to(caller, "^7Error: It is too late to call a timeout now!");
 730                                 }
 731
 732                                 else  // everything should be okay, proceed with starting the timeout
 733                                 {
 734                                         if (caller)   caller.allowed_timeouts -= 1;
 735                                         // write a bprint who started the timeout (and how many they have left)
 736                                         bprint(GetCallerName(caller), " ^7called a timeout", (caller ? strcat(" (", ftos(caller.allowed_timeouts), " timeout(s) left)") : ""), "!\n");
 737
 738                                         timeout_status = TIMEOUT_LEADTIME;
 739                                         timeout_caller = caller;
 740                                         timeout_time = autocvar_sv_timeout_length;
 741                                         timeout_leadtime = autocvar_sv_timeout_leadtime;
 742
 743                                         timeout_handler = spawn();
 744                                         timeout_handler.think = timeout_handler_think;
 745                                         timeout_handler.nextthink = time;  // always let the entity think asap
 746
 747                                         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_TIMEOUT);
 748                                 }
 749                         }
 750                         else { print_to(caller, "^1Timeouts are not allowed to be called, enable them with sv_timeout 1.\n"); }
 751
 752                         return;  // never fall through to usage
 753                 }
 754
 755                 default:
 756                 case CMD_REQUEST_USAGE:
 757                 {
 758                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timeout"));
 759                         print_to(caller, "  No arguments required.");
 760                         return;
 761                 }
 762         }
 763 }
 764
 765 void CommonCommand_who(float request, entity caller, float argc)
 766 {
 767         switch (request)
 768         {
 769                 case CMD_REQUEST_COMMAND:
 770                 {
 771                         float total_listed_players, is_bot;
 772
 773                         float privacy = (caller && autocvar_sv_status_privacy);
 774                         string separator = strreplace("%", " ", strcat((argv(1) ? argv(1) : " "), "^7"));
 775                         string tmp_netaddress, tmp_crypto_idfp;
 776
 777                         print_to(caller, strcat("List of client information", (privacy ? " (some data is hidden for privacy)" : ""), ":"));
 778                         print_to(caller, sprintf(strreplace(" ", separator, " %-4s %-20s %-5s %-3s %-9s %-16s %s "),
 779                                 "ent", "nickname", "ping", "pl", "time", "ip", "crypto_id"));
 780
 781                         total_listed_players = 0;
 782                         FOREACH_CLIENT(true, LAMBDA(
 783                                 is_bot = (IS_BOT_CLIENT(it));
 784
 785                                 if (is_bot)
 786                                 {
 787                                         tmp_netaddress = "null/botclient";
 788                                         tmp_crypto_idfp = "null/botclient";
 789                                 }
 790                                 else if (privacy)
 791                                 {
 792                                         tmp_netaddress = "hidden";
 793                                         tmp_crypto_idfp = "hidden";
 794                                 }
 795                                 else
 796                                 {
 797                                         tmp_netaddress = it.netaddress;
 798                                         tmp_crypto_idfp = it.crypto_idfp;
 799                                 }
 800
 801                                 print_to(caller, sprintf(strreplace(" ", separator, " #%-3d %-20.20s %-5d %-3d %-9s %-16s %s "),
 802                                         etof(it),
 803                                         it.netname,
 804                                         it.ping,
 805                                         it.ping_packetloss,
 806                                         process_time(1, time - it.jointime),
 807                                         tmp_netaddress,
 808                                         tmp_crypto_idfp));
 809
 810                                 ++total_listed_players;
 811                         ));
 812
 813                         print_to(caller, strcat("Finished listing ", ftos(total_listed_players), " client(s) out of ", ftos(maxclients), " slots."));
 814
 815                         return;  // never fall through to usage
 816                 }
 817
 818                 default:
 819                 case CMD_REQUEST_USAGE:
 820                 {
 821                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " who [separator]"));
 822                         print_to(caller, "  Where 'separator' is the optional string to separate the values with, default is a space.");
 823                         return;
 824                 }
 825         }
 826 }
 827
 828 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 829 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 830 void CommonCommand_(float request, entity caller)
 831 {
 832     switch(request)
 833     {
 834         case CMD_REQUEST_COMMAND:
 835         {
 836
 837             return; // never fall through to usage
 838         }
 839
 840         default:
 841         case CMD_REQUEST_USAGE:
 842         {
 843             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " "));
 844             print_to(caller, "  No arguments required.");
 845             return;
 846         }
 847     }
 848 }
 849 */