qcsrc/server/command/common.qc

   1 // ====================================================
   2 //  Shared code for server commands, written by Samual
   3 //  Last updated: December 27th, 2011
   4 // ====================================================
   5
   6 // select the proper prefix for usage and other messages
   7 string GetCommandPrefix(entity caller)
   8 {
   9         if(caller)
  10                 return "cmd";
  11         else
  12                 return "sv_cmd";
  13 }
  14
  15 // if client return player nickname, or if server return admin nickname
  16 string GetCallerName(entity caller)
  17 {
  18         if(caller)
  19                 return caller.netname;
  20         else
  21                 return admin_name(); //((autocvar_sv_adminnick != "") ? autocvar_sv_adminnick : autocvar_hostname);
  22 }
  23
  24 // verify that the client provided is acceptable for use
  25 float VerifyClientEntity(entity client, float must_be_real, float must_be_bots)
  26 {
  27         if not(client.flags & FL_CLIENT)
  28                 return CLIENT_DOESNT_EXIST;
  29         else if(must_be_real && (clienttype(client) != CLIENTTYPE_REAL))
  30                 return CLIENT_NOT_REAL;
  31         else if(must_be_bots && (clienttype(client) != CLIENTTYPE_BOT))
  32                 return CLIENT_NOT_BOT;
  33
  34         return CLIENT_ACCEPTABLE;
  35 }
  36
  37 // if the client is not acceptable, return a string to be used for error messages
  38 string GetClientErrorString(float clienterror, string original_input)
  39 {
  40         switch(clienterror)
  41         {
  42                 case CLIENT_DOESNT_EXIST: { return strcat("Client '", original_input, "' doesn't exist"); }
  43                 case CLIENT_NOT_REAL: { return strcat("Client '", original_input, "' is not real"); }
  44                 case CLIENT_NOT_BOT: { return strcat("Client '", original_input, "' is not a bot"); }
  45                 default: { return "Incorrect usage of GetClientErrorString"; }
  46         }
  47 }
  48
  49 // is this entity number even in the possible range of entities?
  50 float VerifyClientNumber(float tmp_number)
  51 {
  52         if((tmp_number < 1) || (tmp_number > maxclients))
  53                 return FALSE;
  54         else
  55                 return TRUE;
  56 }
  57
  58 // find a player which matches the input string, and return their entity
  59 entity GetFilteredEntity(string input)
  60 {
  61         entity tmp_player, selection;
  62         float tmp_number;
  63
  64         if(substring(input, 0, 1) == "#")
  65                 tmp_number = stof(substring(input, 1, -1));
  66         else
  67                 tmp_number = stof(input);
  68
  69         if(VerifyClientNumber(tmp_number))
  70         {
  71                 selection = edict_num(tmp_number);
  72         }
  73         else
  74         {
  75                 FOR_EACH_CLIENT(tmp_player)
  76                         if (strdecolorize(tmp_player.netname) == strdecolorize(input))
  77                                 selection = tmp_player;
  78         }
  79
  80         return selection;
  81 }
  82
  83 // same thing, but instead return their edict number
  84 float GetFilteredNumber(string input)
  85 {
  86         entity selection = GetFilteredEntity(input);
  87         float output;
  88
  89         if(selection) { output = num_for_edict(selection); }
  90
  91         return output;
  92 }
  93
  94 // switch between sprint and print depending on whether the reciever is the server or a player
  95 void print_to(entity to, string input)
  96 {
  97     if(to)
  98         sprint(to, strcat(input, "\n"));
  99     else
 100         print(input, "\n");
 101 }
 102
 103 // ==========================================
 104 //  Supporting functions for common commands
 105 // ==========================================
 106
 107 // used by CommonCommand_timeout() and CommonCommand_timein() to handle game pausing and messaging and such.
 108 void timeout_handler_reset()
 109 {
 110         entity tmp_player;
 111
 112         timeout_caller = world;
 113         timeout_time = 0;
 114         timeout_leadtime = 0;
 115
 116         FOR_EACH_REALPLAYER(tmp_player)
 117                 Send_CSQC_Centerprint_Generic_Expire(tmp_player, CPID_TIMEOUT_COUNTDOWN);
 118
 119         remove(self);
 120 }
 121
 122 void timeout_handler_think()
 123 {
 124         entity tmp_player;
 125
 126         switch(timeout_status)
 127         {
 128                 case TIMEOUT_ACTIVE:
 129                 {
 130                         if(timeout_time > 0) // countdown is still going
 131                         {
 132                                 FOR_EACH_REALPLAYER(tmp_player)
 133                                         Send_CSQC_Centerprint_Generic(tmp_player, CPID_TIMEOUT_COUNTDOWN, "Timeout ends in %d seconds!", 1, timeout_time);
 134
 135                                 if(timeout_time == autocvar_sv_timeout_resumetime) // play a warning sound when only <sv_timeout_resumetime> seconds are left
 136                                         Announce("prepareforbattle");
 137
 138                                 self.nextthink = time + TIMEOUT_SLOWMO_VALUE; // think again in one second
 139                                 timeout_time -= 1; // decrease the time counter
 140                         }
 141                         else // time to end the timeout
 142                         {
 143                                 timeout_status = TIMEOUT_INACTIVE;
 144
 145                                 // reset the slowmo value back to normal
 146                                 cvar_set("slowmo", ftos(orig_slowmo));
 147
 148                                 // unlock the view for players so they can move around again
 149                                 FOR_EACH_REALPLAYER(tmp_player)
 150                                         tmp_player.fixangle = FALSE;
 151
 152                                 timeout_handler_reset();
 153                         }
 154
 155                         return;
 156                 }
 157
 158                 case TIMEOUT_LEADTIME:
 159                 {
 160                         if (timeout_leadtime > 0) // countdown is still going
 161                         {
 162                                 // centerprint the information to every player
 163                                 FOR_EACH_REALPLAYER(tmp_player)
 164                                         Send_CSQC_Centerprint_Generic(tmp_player, CPID_TIMEOUT_COUNTDOWN, "Timeout begins in %d seconds!", 1, timeout_leadtime);
 165
 166                                 self.nextthink = time + 1; // think again in one second
 167                                 timeout_leadtime -= 1; // decrease the time counter
 168                         }
 169                         else // time to begin the timeout
 170                         {
 171                                 timeout_status = TIMEOUT_ACTIVE;
 172
 173                                 // set the slowmo value to the timeout default slowmo value
 174                                 cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 175
 176                                 // reset all the flood variables
 177                                 FOR_EACH_CLIENT(tmp_player)
 178                                         tmp_player.nickspamcount = tmp_player.nickspamtime = tmp_player.floodcontrol_chat =
 179                                         tmp_player.floodcontrol_chatteam = tmp_player.floodcontrol_chattell =
 180                                         tmp_player.floodcontrol_voice = tmp_player.floodcontrol_voiceteam = 0;
 181
 182                                 // copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 183                                 FOR_EACH_REALPLAYER(tmp_player)
 184                                         tmp_player.lastV_angle = tmp_player.v_angle;
 185
 186                                 self.nextthink = time; // think again next frame to handle it under TIMEOUT_ACTIVE code
 187                         }
 188                 }
 189
 190
 191                 case TIMEOUT_INACTIVE:
 192                 default:
 193                 {
 194                         timeout_handler_reset();
 195                         return;
 196                 }
 197         }
 198 }
 199
 200
 201
 202 // ===================================================
 203 //  Common commands used in both sv_cmd.qc and cmd.qc
 204 // ===================================================
 205
 206 void CommonCommand_cvar_changes(float request, entity caller)
 207 {
 208         switch(request)
 209         {
 210                 case CMD_REQUEST_COMMAND:
 211                 {
 212                         print_to(caller, cvar_changes);
 213                         return; // never fall through to usage
 214                 }
 215
 216                 default:
 217                 case CMD_REQUEST_USAGE:
 218                 {
 219                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_changes"));
 220                         print_to(caller, "  No arguments required.");
 221                         print_to(caller, "See also: ^2cvar_purechanges^7");
 222                         return;
 223                 }
 224         }
 225 }
 226
 227 void CommonCommand_cvar_purechanges(float request, entity caller)
 228 {
 229         switch(request)
 230         {
 231                 case CMD_REQUEST_COMMAND:
 232                 {
 233                         print_to(caller, cvar_purechanges);
 234                         return; // never fall through to usage
 235                 }
 236
 237                 default:
 238                 case CMD_REQUEST_USAGE:
 239                 {
 240                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_purechanges"));
 241                         print_to(caller, "  No arguments required.");
 242                         print_to(caller, "See also: ^2cvar_changes^7");
 243                         return;
 244                 }
 245         }
 246 }
 247
 248 void CommonCommand_info(float request, entity caller, float argc) // legacy
 249 {
 250         switch(request)
 251         {
 252                 case CMD_REQUEST_COMMAND:
 253                 {
 254                         string command = builtin_cvar_string(strcat("sv_info_", argv(1)));
 255
 256                         if(command)
 257                                 wordwrap_sprint(command, 1000);
 258                         else
 259                                 print_to(caller, "ERROR: unsupported info command");
 260
 261                         return; // never fall through to usage
 262                 }
 263
 264                 default:
 265                 case CMD_REQUEST_USAGE:
 266                 {
 267                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " info request"));
 268                         print_to(caller, "  Where 'request' is the suffixed string appended onto the request for cvar.");
 269                         return;
 270                 }
 271         }
 272 }
 273
 274 void CommonCommand_ladder(float request, entity caller)
 275 {
 276         switch(request)
 277         {
 278                 case CMD_REQUEST_COMMAND:
 279                 {
 280                         print_to(caller, ladder_reply);
 281                         return; // never fall through to usage
 282                 }
 283
 284                 default:
 285                 case CMD_REQUEST_USAGE:
 286                 {
 287                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " ladder"));
 288                         print_to(caller, "  No arguments required.");
 289                         return;
 290                 }
 291         }
 292 }
 293
 294 void CommonCommand_lsmaps(float request, entity caller)
 295 {
 296         switch(request)
 297         {
 298                 case CMD_REQUEST_COMMAND:
 299                 {
 300                         print_to(caller, lsmaps_reply);
 301                         return; // never fall through to usage
 302                 }
 303
 304                 default:
 305                 case CMD_REQUEST_USAGE:
 306                 {
 307                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " lsmaps"));
 308                         print_to(caller, "  No arguments required.");
 309                         return;
 310                 }
 311         }
 312 }
 313
 314 void CommonCommand_lsnewmaps(float request, entity caller)
 315 {
 316         switch(request)
 317         {
 318                 case CMD_REQUEST_COMMAND:
 319                 {
 320                         print_to(caller, lsnewmaps_reply);
 321                         return; // never fall through to usage
 322                 }
 323
 324                 default:
 325                 case CMD_REQUEST_USAGE:
 326                 {
 327                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " lsnewmaps"));
 328                         print_to(caller, "  No arguments required.");
 329                         return;
 330                 }
 331         }
 332 }
 333
 334 void CommonCommand_maplist(float request, entity caller)
 335 {
 336         switch(request)
 337         {
 338                 case CMD_REQUEST_COMMAND:
 339                 {
 340                         print_to(caller, maplist_reply);
 341                         return; // never fall through to usage
 342                 }
 343
 344                 default:
 345                 case CMD_REQUEST_USAGE:
 346                 {
 347                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " maplist"));
 348                         print_to(caller, "  No arguments required.");
 349                         return;
 350                 }
 351         }
 352 }
 353
 354 /*
 355 void GameCommand_rankings(float request) // this is OLD.... jeez.
 356 {
 357         switch(request)
 358         {
 359                 case CMD_REQUEST_COMMAND:
 360                 {
 361                         strunzone(rankings_reply);
 362                         rankings_reply = strzone(getrankings());
 363                         print(rankings_reply);
 364                         return;
 365                 }
 366
 367                 default:
 368                 case CMD_REQUEST_USAGE:
 369                 {
 370                         print("\nUsage:^3 sv_cmd rankings");
 371                         print("  No arguments required.");
 372                         return;
 373                 }
 374         }
 375 }
 376 */
 377
 378 void CommonCommand_rankings(float request, entity caller)
 379 {
 380         switch(request)
 381         {
 382                 case CMD_REQUEST_COMMAND:
 383                 {
 384                         print_to(caller, rankings_reply);
 385                         return; // never fall through to usage
 386                 }
 387
 388                 default:
 389                 case CMD_REQUEST_USAGE:
 390                 {
 391                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " rankings"));
 392                         print_to(caller, "  No arguments required.");
 393                         return;
 394                 }
 395         }
 396 }
 397
 398 void CommonCommand_records(float request, entity caller)
 399 {
 400         switch(request)
 401         {
 402                 case CMD_REQUEST_COMMAND:
 403                 {
 404                         float i;
 405
 406                         for(i = 0; i < 10; ++i)
 407                                 print_to(caller, records_reply[i]);
 408
 409                         return; // never fall through to usage
 410                 }
 411
 412                 default:
 413                 case CMD_REQUEST_USAGE:
 414                 {
 415                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " records"));
 416                         print_to(caller, "  No arguments required.");
 417                         return;
 418                 }
 419         }
 420 }
 421
 422 void CommonCommand_teamstatus(float request, entity caller)
 423 {
 424         switch(request)
 425         {
 426                 case CMD_REQUEST_COMMAND:
 427                 {
 428                         Score_NicePrint(caller);
 429                         return; // never fall through to usage
 430                 }
 431
 432                 default:
 433                 case CMD_REQUEST_USAGE:
 434                 {
 435                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " teamstatus"));
 436                         print_to(caller, "  No arguments required.");
 437                         return;
 438                 }
 439         }
 440 }
 441
 442 void CommonCommand_time(float request, entity caller)
 443 {
 444         switch(request)
 445         {
 446                 case CMD_REQUEST_COMMAND:
 447                 {
 448                         print_to(caller, strcat("time = ", ftos(time)));
 449                         print_to(caller, strcat("frame start = ", ftos(gettime(GETTIME_FRAMESTART))));
 450                         print_to(caller, strcat("realtime = ", ftos(gettime(GETTIME_REALTIME))));
 451                         print_to(caller, strcat("hires = ", ftos(gettime(GETTIME_HIRES))));
 452                         print_to(caller, strcat("uptime = ", ftos(gettime(GETTIME_UPTIME))));
 453                         print_to(caller, strcat("localtime = ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y")));
 454                         print_to(caller, strcat("gmtime = ", strftime(FALSE, "%a %b %e %H:%M:%S %Z %Y")));
 455                         return;
 456                 }
 457
 458                 default:
 459                 case CMD_REQUEST_USAGE:
 460                 {
 461                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " time"));
 462                         print_to(caller, "  No arguments required.");
 463                         return;
 464                 }
 465         }
 466 }
 467
 468 void CommonCommand_timein(float request, entity caller)
 469 {
 470         switch(request)
 471         {
 472                 case CMD_REQUEST_COMMAND:
 473                 {
 474                         if(autocvar_sv_timeout)
 475                         {
 476                                 if not(timeout_status) { print_to(caller, "^7Error: There is no active timeout called."); }
 477                                 else if(caller && (caller != timeout_caller)) { print_to(caller, "^7Error: You are not allowed to stop the active timeout."); }
 478
 479                                 else // everything should be okay, continue aborting timeout
 480                                 {
 481                                         switch(timeout_status)
 482                                         {
 483                                                 case TIMEOUT_LEADTIME:
 484                                                 {
 485                                                         timeout_status = TIMEOUT_INACTIVE;
 486                                                         timeout_time = 0;
 487                                                         timeout_handler.nextthink = time; // timeout_handler has to take care of it immediately
 488                                                         bprint(strcat("^7The timeout was aborted by ", caller.netname, " !\n"));
 489                                                         return;
 490                                                 }
 491
 492                                                 case TIMEOUT_ACTIVE:
 493                                                 {
 494                                                         timeout_time = autocvar_sv_timeout_resumetime;
 495                                                         timeout_handler.nextthink = time; // timeout_handler has to take care of it immediately
 496                                                         bprint(strcat("^1Attention: ^7", caller.netname, " resumed the game! Prepare for battle!\n"));
 497                                                         return;
 498                                                 }
 499
 500                                                 default: dprint("timeout status was inactive, but this code was executed anyway?"); return;
 501                                         }
 502                                 }
 503                         }
 504                         return; // never fall through to usage
 505                 }
 506
 507                 default:
 508                 case CMD_REQUEST_USAGE:
 509                 {
 510                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timein"));
 511                         print_to(caller, "  No arguments required.");
 512                         return;
 513                 }
 514         }
 515 }
 516
 517 void CommonCommand_timeout(float request, entity caller) // DEAR GOD THIS COMMAND IS TERRIBLE.
 518 {
 519         switch(request)
 520         {
 521                 case CMD_REQUEST_COMMAND:
 522                 {
 523                         if(autocvar_sv_timeout)
 524                         {
 525                                 float last_possible_timeout = ((autocvar_timelimit * 60) - autocvar_sv_timeout_leadtime - 1);
 526
 527                                 if(timeout_status) { print_to(caller, "^7Error: A timeout is already active."); }
 528                                 else if(vote_called) { print_to(caller, "^7Error: You can not call a timeout while a vote is active."); }
 529                                 else if(inWarmupStage && !g_warmup_allow_timeout) { print_to(caller, "^7Error: You can not call a timeout in warmup-stage."); }
 530                                 else if(time < game_starttime) { print_to(caller, "^7Error: You can not call a timeout while the map is being restarted."); }
 531                                 else if(caller && (caller.allowed_timeouts < 1)) { print_to(caller, "^7Error: You already used all your timeout calls for this map."); }
 532                                 else if(caller && (caller.classname != "player")) { print_to(caller, "^7Error: You must be a player to call a timeout."); }
 533                                 else if((autocvar_timelimit) && (last_possible_timeout < time - game_starttime)) { print_to(caller, "^7Error: It is too late to call a timeout now!"); }
 534
 535                                 else // everything should be okay, proceed with starting the timeout
 536                                 {
 537                                         if(caller) { caller.allowed_timeouts -= 1; }
 538
 539                                         bprint(GetCallerName(caller), " ^7called a timeout", (caller ? strcat(" (", ftos(caller.allowed_timeouts), " timeouts left)") : string_null), "!\n"); // write a bprint who started the timeout (and how many they have left)
 540
 541                                         timeout_status = TIMEOUT_LEADTIME;
 542                                         timeout_caller = caller;
 543                                         timeout_time = autocvar_sv_timeout_length;
 544                                         timeout_leadtime = autocvar_sv_timeout_leadtime;
 545
 546                                         timeout_handler = spawn();
 547                                         timeout_handler.think = timeout_handler_think;
 548                                         timeout_handler.nextthink = time; // always let the entity think asap
 549
 550                                         Announce("timeoutcalled");
 551                                 }
 552                         }
 553                         return; // never fall through to usage
 554                 }
 555
 556                 default:
 557                 case CMD_REQUEST_USAGE:
 558                 {
 559                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timeout"));
 560                         print_to(caller, "  No arguments required.");
 561                         return;
 562                 }
 563         }
 564 }
 565
 566 void CommonCommand_who(float request, entity caller, float argc)
 567 {
 568         switch(request)
 569         {
 570                 case CMD_REQUEST_COMMAND:
 571                 {
 572                         float total_listed_players, tmp_hours, tmp_minutes, tmp_seconds, is_bot;
 573                         entity tmp_player;
 574
 575                         float privacy = (caller && autocvar_sv_status_privacy);
 576                         string separator = strreplace("%", " ", strcat((argv(1) ? argv(1) : " "), "^7"));
 577                         string tmp_netaddress, tmp_crypto_idfp;
 578
 579                         print_to(caller, strcat("List of client information", (privacy ? " (some data is hidden for privacy)" : string_null), ":"));
 580                         print_to(caller, sprintf(strreplace(" ", separator, " %-4s %-20s %-5s %-3s %-9s %-16s %s "),
 581                                 "ent", "nickname", "ping", "pl", "time", "ip", "crypto_id"));
 582
 583                         FOR_EACH_CLIENT(tmp_player)
 584                         {
 585                                 is_bot = (clienttype(tmp_player) == CLIENTTYPE_BOT);
 586
 587                                 if(is_bot)
 588                                 {
 589                                         tmp_netaddress = "null/botclient";
 590                                         tmp_crypto_idfp = "null/botclient";
 591                                 }
 592                                 else if(privacy)
 593                                 {
 594                                         tmp_netaddress = "hidden";
 595                                         tmp_crypto_idfp = "hidden";
 596                                 }
 597                                 else
 598                                 {
 599                                         tmp_netaddress = tmp_player.netaddress;
 600                                         tmp_crypto_idfp = tmp_player.crypto_idfp;
 601                                 }
 602
 603                                 tmp_hours = tmp_minutes = tmp_seconds = 0;
 604
 605                                 tmp_seconds = floor(time - tmp_player.jointime);
 606                                 tmp_minutes = floor(tmp_seconds / 60);
 607                                 tmp_hours = floor(tmp_minutes / 60);
 608
 609                                 if(tmp_minutes) { tmp_seconds -= (tmp_minutes * 60); }
 610                                 if(tmp_hours) { tmp_minutes -= (tmp_hours * 60); }
 611
 612                                 print_to(caller, sprintf(strreplace(" ", separator, " #%-3d %-20.20s %-5d %-3d %-9s %-16s %s "),
 613                                         num_for_edict(tmp_player),
 614                                         tmp_player.netname,
 615                                         tmp_player.ping,
 616                                         tmp_player.ping_packetloss,
 617                                         sprintf("%02d:%02d:%02d", tmp_hours, tmp_minutes, tmp_seconds),
 618                                         tmp_netaddress,
 619                                         tmp_crypto_idfp));
 620
 621                                 ++total_listed_players;
 622                         }
 623
 624                         print_to(caller, strcat("Finished listing ", ftos(total_listed_players), " client(s) out of ", ftos(maxclients), " slots."));
 625
 626                         return; // never fall through to usage
 627                 }
 628
 629                 default:
 630                 case CMD_REQUEST_USAGE:
 631                 {
 632                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " who [separator]"));
 633                         print_to(caller, "  Where 'separator' is the optional string to separate the values with, default is a space.");
 634                         return;
 635                 }
 636         }
 637 }
 638
 639 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 640 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 641 void CommonCommand_(float request, entity caller)
 642 {
 643         switch(request)
 644         {
 645                 case CMD_REQUEST_COMMAND:
 646                 {
 647
 648                         return; // never fall through to usage
 649                 }
 650
 651                 default:
 652                 case CMD_REQUEST_USAGE:
 653                 {
 654                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " "));
 655                         print_to(caller, "  No arguments required.");
 656                         return;
 657                 }
 658         }
 659 }
 660 */