qcsrc/server/command/sv_cmd.qc

   1 #include "sv_cmd.qh"
   2
   3 #include <common/constants.qh>
   4 #include <common/effects/all.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/mapinfo.qh>
   7 #include <common/monsters/sv_monsters.qh>
   8 #include <common/net_linked.qh>
   9 #include <common/notifications/all.qh>
  10 #include <common/teams.qh>
  11 #include <common/util.qh>
  12 #include <server/anticheat.qh>
  13 #include <server/bot/api.qh>
  14 #include <server/campaign.qh>
  15 #include <server/client.qh>
  16 #include <server/command/_mod.qh>
  17 #include <server/command/banning.qh>
  18 #include <server/command/cmd.qh>
  19 #include <server/command/common.qh>
  20 #include <server/command/getreplies.qh>
  21 #include <server/command/radarmap.qh>
  22 #include <server/intermission.qh>
  23 #include <server/ipban.qh>
  24 #include <server/mutators/_mod.qh>
  25 #include <server/player.qh>
  26 #include <server/teamplay.qh>
  27 #include <server/world.qh>
  28
  29 //  used by GameCommand_make_mapinfo()
  30 void make_mapinfo_Think(entity this)
  31 {
  32         if (_MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
  33         {
  34                 LOG_INFO("Done rebuiling mapinfos.");
  35                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
  36                 delete(this);
  37         }
  38         else
  39         {
  40                 setthink(this, make_mapinfo_Think);
  41                 this.nextthink = time;
  42         }
  43 }
  44
  45 //  used by GameCommand_extendmatchtime() and GameCommand_reducematchtime()
  46 void changematchtime(float delta, float mi, float ma)
  47 {
  48         float cur;
  49         float update;
  50         float lim;
  51
  52         if (delta == 0) return;
  53         if (autocvar_timelimit < 0) return;
  54
  55         if (mi <= 10) mi = 10;  // at least ten sec in the future
  56         cur = time - game_starttime;
  57         if (cur > 0) mi += cur; // from current time!
  58
  59         lim = autocvar_timelimit * 60;
  60
  61         if (delta > 0)
  62         {
  63                 if (lim == 0) return; // cannot increase any further
  64                 else if (lim < ma) update = min(ma, lim + delta);
  65                 else                  // already above maximum: FAIL
  66                         return;
  67         }
  68         else
  69         {
  70                 if (lim == 0)      // infinite: try reducing to max, if we are allowed to
  71                         update = max(mi, ma);
  72                 else if (lim > mi) // above minimum: decrease
  73                         update = max(mi, lim + delta);
  74                 else               // already below minimum: FAIL
  75                         return;
  76         }
  77
  78         cvar_set("timelimit", ftos(update / 60));
  79 }
  80
  81
  82 // =======================
  83 //  Command Sub-Functions
  84 // =======================
  85
  86 void GameCommand_adminmsg(int request, int argc)
  87 {
  88         switch (request)
  89         {
  90                 case CMD_REQUEST_COMMAND:
  91                 {
  92                         entity client;
  93                         float accepted;
  94
  95                         string targets = strreplace(",", " ", argv(1));
  96                         string original_targets = strreplace(" ", ", ", targets);
  97                         string admin_message = argv(2);
  98                         float infobartime = stof(argv(3));
  99
 100                         string successful, t;
 101                         successful = string_null;
 102
 103                         if ((targets) && (admin_message))
 104                         {
 105                                 for ( ; targets; )
 106                                 {
 107                                         t = car(targets);
 108                                         targets = cdr(targets);
 109
 110                                         // Check to see if the player is a valid target
 111                                         client = GetFilteredEntity(t);
 112                                         accepted = VerifyClientEntity(client, true, false);
 113
 114                                         if (accepted <= 0)
 115                                         {
 116                                                 LOG_INFO("adminmsg: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : "."));
 117                                                 continue;
 118                                         }
 119
 120                                         // send the centerprint/console print or infomessage
 121                                         if (infobartime)
 122                                         {
 123                                                 stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", infobartime, MakeConsoleSafe(admin_message)));
 124                                         }
 125                                         else
 126                                         {
 127                                                 centerprint(client, strcat("^3", GetCallerName(NULL), ":\n^7", admin_message));
 128                                                 sprint(client, strcat("\{1}\{13}^3", GetCallerName(NULL), "^7: ", admin_message, "\n"));
 129                                         }
 130
 131                                         successful = strcat(successful, (successful ? ", " : ""), playername(client.netname, client.team, false));
 132                                         LOG_TRACE("Message sent to ", playername(client.netname, client.team, false));
 133                                         continue;
 134                                 }
 135
 136                                 if (successful) bprint("Successfully sent message '", admin_message, "' to ", successful, ".\n");
 137                                 else LOG_INFO("No players given (", original_targets, ") could receive the message.");
 138
 139                                 return;
 140                         }
 141                 }
 142
 143                 default:
 144                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 145                 case CMD_REQUEST_USAGE:
 146                 {
 147                         LOG_HELP("Usage:^3 sv_cmd adminmsg <clients> \"<message>\" [<infobartime>]");
 148                         LOG_HELP("  <clients> is a list (separated by commas) of player entity ID's or nicknames");
 149                         LOG_HELP("  If <infobartime> is provided, the message will be sent to infobar.");
 150                         LOG_HELP("  Otherwise, it will just be sent as a centerprint message.");
 151                         LOG_HELP("Examples: adminmsg 2,4 \"this infomessage will last for ten seconds\" 10");
 152                         LOG_HELP("          adminmsg 2,5 \"this message will be a centerprint\"");
 153                         return;
 154                 }
 155         }
 156 }
 157
 158 void GameCommand_allready(int request)
 159 {
 160         switch (request)
 161         {
 162                 case CMD_REQUEST_COMMAND:
 163                 {
 164                         if(warmup_stage)
 165                         {
 166                                 ReadyRestart(true);
 167                         }
 168                         else
 169                                 LOG_INFO("Not in warmup.");
 170
 171                         return;
 172                 }
 173
 174                 default:
 175                 case CMD_REQUEST_USAGE:
 176                 {
 177                         LOG_HELP("Usage:^3 sv_cmd allready");
 178                         LOG_HELP("  No arguments required.");
 179                         return;
 180                 }
 181         }
 182 }
 183
 184 void GameCommand_allspec(int request, int argc)
 185 {
 186         switch (request)
 187         {
 188                 case CMD_REQUEST_COMMAND:
 189                 {
 190                         string reason = argv(1);
 191                         int n = 0;
 192                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 193                                 PutObserverInServer(it, true);
 194                                 ++n;
 195                         });
 196                         if (n)   bprint(strcat("Successfully forced all (", ftos(n), ") players to spectate", (reason ? strcat(" for reason: '", reason, "'") : ""), ".\n"));
 197                         else   LOG_INFO("No players found to spectate.");
 198                         return;
 199                 }
 200
 201                 default:
 202                 case CMD_REQUEST_USAGE:
 203                 {
 204                         LOG_HELP("Usage:^3 sv_cmd allspec [<reason>]");
 205                         LOG_HELP("  Where <reason> is an optional argument for explanation of allspec command.");
 206                         LOG_HELP("See also: ^2moveplayer, shuffleteams^7");
 207                         return;
 208                 }
 209         }
 210 }
 211
 212 void GameCommand_anticheat(int request, int argc)
 213 {
 214         switch (request)
 215         {
 216                 case CMD_REQUEST_COMMAND:
 217                 {
 218                         entity client = GetIndexedEntity(argc, 1);
 219                         float accepted = VerifyClientEntity(client, false, false);
 220
 221                         if (accepted > 0)
 222                         {
 223                                 anticheat_report_to_eventlog(client);
 224                                 return;
 225                         }
 226                         else
 227                         {
 228                                 LOG_INFO("anticheat: ", GetClientErrorString(accepted, argv(1)), ".");
 229                         }
 230                 }
 231
 232                 default:
 233                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 234                 case CMD_REQUEST_USAGE:
 235                 {
 236                         LOG_HELP("Usage:^3 sv_cmd anticheat <client>");
 237                         LOG_HELP("  <client> is the entity number or name of the player.");
 238                         return;
 239                 }
 240         }
 241 }
 242
 243 void GameCommand_bbox(int request)
 244 {
 245         switch (request)
 246         {
 247                 case CMD_REQUEST_COMMAND:
 248                 {
 249                         vector size_min = '0 0 0';
 250                         vector size_max = '0 0 0';
 251                         tracebox('1 0 0' * world.absmin.x,
 252                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 253                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 254                                 '1 0 0' * world.absmax.x,
 255                                 MOVE_WORLDONLY,
 256                                 NULL);
 257                         size_min.x = (trace_startsolid) ? world.absmin.x : trace_endpos.x;
 258
 259                         tracebox('0 1 0' * world.absmin.y,
 260                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 261                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 262                                 '0 1 0' * world.absmax.y,
 263                                 MOVE_WORLDONLY,
 264                                 NULL);
 265                         size_min.y = (trace_startsolid) ? world.absmin.y : trace_endpos.y;
 266
 267                         tracebox('0 0 1' * world.absmin.z,
 268                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 269                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 270                                 '0 0 1' * world.absmax.z,
 271                                 MOVE_WORLDONLY,
 272                                 NULL);
 273                         size_min.z = (trace_startsolid) ? world.absmin.z : trace_endpos.z;
 274
 275                         tracebox('1 0 0' * world.absmax.x,
 276                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 277                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 278                                 '1 0 0' * world.absmin.x,
 279                                 MOVE_WORLDONLY,
 280                                 NULL);
 281                         size_max.x = (trace_startsolid) ? world.absmax.x : trace_endpos.x;
 282
 283                         tracebox('0 1 0' * world.absmax.y,
 284                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 285                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 286                                 '0 1 0' * world.absmin.y,
 287                                 MOVE_WORLDONLY,
 288                                 NULL);
 289                         size_max.y = (trace_startsolid) ? world.absmax.y : trace_endpos.y;
 290
 291                         tracebox('0 0 1' * world.absmax.z,
 292                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 293                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 294                                 '0 0 1' * world.absmin.z,
 295                                 MOVE_WORLDONLY,
 296                                 NULL);
 297                         size_max.z = (trace_startsolid) ? world.absmax.z : trace_endpos.z;
 298
 299                         LOG_INFOF("Original size: %v %v", world.absmin, world.absmax);
 300                         LOG_INFOF("Currently set size: %v %v", world.mins, world.maxs);
 301                         LOG_INFOF("Solid bounding box size: %v %v", size_min, size_max);
 302                         return;
 303                 }
 304
 305                 default:
 306                 case CMD_REQUEST_USAGE:
 307                 {
 308                         LOG_HELP("Usage:^3 sv_cmd bbox");
 309                         LOG_HELP("  No arguments required.");
 310                         LOG_HELP("See also: ^2gettaginfo, trace^7");
 311                         return;
 312                 }
 313         }
 314 }
 315
 316 void GameCommand_bot_cmd(int request, int argc, string command)
 317 {
 318         switch (request)
 319         {
 320                 case CMD_REQUEST_COMMAND:
 321                 {
 322                         entity bot;
 323
 324                         if (argv(1) == "reset")
 325                         {
 326                                 bot_resetqueues();
 327                                 return;
 328                         }
 329                         else if (argv(1) == "setbots")
 330                         {
 331                                 cvar_settemp("bot_vs_human", "0");
 332                                 cvar_settemp("minplayers", "0");
 333                                 cvar_settemp("minplayers_per_team", "0");
 334                                 cvar_settemp("bot_number", "0");
 335                                 bot_fixcount();
 336                                 cvar_settemp("bot_number", argv(2));
 337                                 if (!bot_fixcount()) LOG_INFO("Sorry, could not set requested bot count");
 338                                 return;
 339                         }
 340                         else if (argv(1) == "load" && argc == 3)
 341                         {
 342                                 float fh, i;
 343                                 string s;
 344                                 fh = fopen(argv(2), FILE_READ);
 345                                 if (fh < 0)
 346                                 {
 347                                         LOG_INFO("cannot open the file");
 348                                         return;
 349                                 }
 350
 351                                 i = 0;
 352                                 while ((s = fgets(fh)))
 353                                 {
 354                                         argc = tokenize_console(s);
 355
 356                                         if (argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
 357                                         {
 358                                                 if (argv(2) == "reset")
 359                                                 {
 360                                                         bot_resetqueues();
 361                                                 }
 362                                                 else if (argv(2) == "setbots")
 363                                                 {
 364                                                         cvar_settemp("bot_vs_human", "0");
 365                                                         cvar_settemp("minplayers", "0");
 366                                                         cvar_settemp("minplayers_per_team", "0");
 367                                                         cvar_settemp("bot_number", "0");
 368                                                         bot_fixcount();
 369                                                         cvar_settemp("bot_number", argv(3));
 370                                                         if (!bot_fixcount()) LOG_INFO("Sorry, could not set requested bot count");
 371                                                 }
 372                                                 else
 373                                                 {
 374                                                         if(argv(2) == "*" || argv(2) == "all")
 375                                                                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 376                                                                         bot_queuecommand(it, substring(s, argv_start_index(3), -1));
 377                                                                 });
 378                                                         else
 379                                                         {
 380                                                                 bot = find_bot_by_number(stof(argv(2)));
 381                                                                 if (bot == NULL) bot = find_bot_by_name(argv(2));
 382                                                                 if (bot) bot_queuecommand(bot, substring(s, argv_start_index(3), -1));
 383                                                         }
 384                                                 }
 385                                         }
 386                                         else
 387                                         {
 388                                                 localcmd(strcat(s, "\n"));
 389                                         }
 390
 391                                         ++i;
 392                                 }
 393                                 LOG_INFO(ftos(i), " commands read");
 394                                 fclose(fh);
 395                                 return;
 396                         }
 397                         else if (argv(1) == "help")
 398                         {
 399                                 if (argv(2)) bot_cmdhelp(argv(2));
 400                                 else bot_list_commands();
 401                                 return;
 402                         }
 403                         else if (argc >= 3)  // this comes last
 404                         {
 405                                 if(argv(1) == "*" || argv(1) == "all")
 406                                 {
 407                                         int bot_num = 0;
 408                                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 409                                                 bot_queuecommand(it, substring(command, argv_start_index(2), -1));
 410                                                 bot_num++;
 411                                         });
 412                                         if(bot_num)
 413                                                 LOG_INFO("Command '", substring(command, argv_start_index(2), -1), "' sent to all bots (", ftos(bot_num), ")");
 414                                         return;
 415                                 }
 416                                 else
 417                                 {
 418                                         bot = find_bot_by_number(stof(argv(1)));
 419                                         if (bot == NULL) bot = find_bot_by_name(argv(1));
 420                                         if (bot)
 421                                         {
 422                                                 LOG_INFO("Command '", substring(command, argv_start_index(2), -1), "' sent to bot ", bot.netname);
 423                                                 bot_queuecommand(bot, substring(command, argv_start_index(2), -1));
 424                                                 return;
 425                                         }
 426                                         else
 427                                         {
 428                                                 LOG_INFO("Error: Can't find bot with the name or id '", argv(1), "' - Did you mistype the command?");  // don't return so that usage is shown
 429                                         }
 430                                 }
 431                         }
 432                 }
 433
 434                 default:
 435                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 436                 case CMD_REQUEST_USAGE:
 437                 {
 438                         LOG_HELP("Usage:^3 sv_cmd bot_cmd <client> <command> [<arguments>]");
 439                         LOG_HELP("  <client> can be either the name of the bot or a progressive number (not the entity number!)");
 440                         LOG_HELP("           can also be '*' or 'all' to allow sending the command to all the bots");
 441                         LOG_HELP("  For full list of commands, see bot_cmd help [<command>].");
 442                         LOG_HELP("Examples: sv_cmd bot_cmd 1 cc \"say something\"");
 443                         LOG_HELP("          sv_cmd bot_cmd 1 presskey jump");
 444                         LOG_HELP("          sv_cmd bot_cmd * pause");
 445                         return;
 446                 }
 447         }
 448 }
 449
 450 void GameCommand_cointoss(int request, int argc)
 451 {
 452         switch (request)
 453         {
 454                 case CMD_REQUEST_COMMAND:
 455                 {
 456                         string result1 = (argv(2) ? strcat("^7", argv(1)) : "^1HEADS");
 457                         string result2 = (argv(2) ? strcat("^7", argv(2)) : "^4TAILS");
 458                         string choice = ((random() > 0.5) ? result1 : result2);
 459
 460                         Send_Notification(NOTIF_ALL, NULL, MSG_MULTI, MULTI_COINTOSS, choice);
 461                         return;
 462                 }
 463
 464                 default:
 465                 case CMD_REQUEST_USAGE:
 466                 {
 467                         LOG_HELP("Usage:^3 sv_cmd cointoss [<result1> <result2>]");
 468                         LOG_HELP("  Where <result1> and <result2> are user created options.");
 469                         return;
 470                 }
 471         }
 472 }
 473
 474 void GameCommand_database(int request, int argc)
 475 {
 476         switch (request)
 477         {
 478                 case CMD_REQUEST_COMMAND:
 479                 {
 480                         if (argc == 3)
 481                         {
 482                                 if (argv(1) == "save")
 483                                 {
 484                                         db_save(ServerProgsDB, argv(2));
 485                                         LOG_INFO("Copied serverprogs database to '", argv(2), "' in the data directory.");
 486                                         return;
 487                                 }
 488                                 else if (argv(1) == "dump")
 489                                 {
 490                                         db_dump(ServerProgsDB, argv(2));
 491                                         LOG_INFO("DB dumped.");  // wtf does this do?
 492                                         return;
 493                                 }
 494                                 else if (argv(1) == "load")
 495                                 {
 496                                         db_close(ServerProgsDB);
 497                                         ServerProgsDB = db_load(argv(2));
 498                                         LOG_INFO("Loaded '", argv(2), "' as new serverprogs database.");
 499                                         return;
 500                                 }
 501                         }
 502                 }
 503
 504                 default:
 505                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 506                 case CMD_REQUEST_USAGE:
 507                 {
 508                         LOG_HELP("Usage:^3 sv_cmd database <action> <filename>");
 509                         LOG_HELP("  Where <action> is the command to complete,");
 510                         LOG_HELP("  and <filename> is what it acts upon.");
 511                         LOG_HELP("  Full list of commands here: save, dump, load.");
 512                         return;
 513                 }
 514         }
 515 }
 516
 517 void GameCommand_defer_clear(int request, int argc)
 518 {
 519         switch (request)
 520         {
 521                 case CMD_REQUEST_COMMAND:
 522                 {
 523                         entity client;
 524                         float accepted;
 525
 526                         if (argc >= 2)
 527                         {
 528                                 client = GetIndexedEntity(argc, 1);
 529                                 accepted = VerifyClientEntity(client, true, false);
 530
 531                                 if (accepted > 0)
 532                                 {
 533                                         stuffcmd(client, "defer clear\n");
 534                                         LOG_INFO("defer clear stuffed to ", playername(client.netname, client.team, false));
 535                                 }
 536                                 else { LOG_INFO("defer_clear: ", GetClientErrorString(accepted, argv(1)), "."); }
 537
 538                                 return;
 539                         }
 540                 }
 541
 542                 default:
 543                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 544                 case CMD_REQUEST_USAGE:
 545                 {
 546                         LOG_HELP("Usage:^3 sv_cmd defer_clear <client>");
 547                         LOG_HELP("  <client> is the entity number or name of the player.");
 548                         LOG_HELP("See also: ^2defer_clear_all^7");
 549                         return;
 550                 }
 551         }
 552 }
 553
 554 void GameCommand_defer_clear_all(int request)
 555 {
 556         switch (request)
 557         {
 558                 case CMD_REQUEST_COMMAND:
 559                 {
 560                         int n = 0;
 561                         int argc;
 562
 563                         FOREACH_CLIENT(true, {
 564                                 argc = tokenize_console(strcat("defer_clear ", ftos(etof(it))));
 565                                 GameCommand_defer_clear(CMD_REQUEST_COMMAND, argc);
 566                                 ++n;
 567                         });
 568                         if (n)   LOG_INFO("Successfully stuffed defer clear to all clients (", ftos(n), ")");  // should a message be added if no players were found?
 569                         return;
 570                 }
 571
 572                 default:
 573                 case CMD_REQUEST_USAGE:
 574                 {
 575                         LOG_HELP("Usage:^3 sv_cmd defer_clear_all");
 576                         LOG_HELP("  No arguments required.");
 577                         LOG_HELP("See also: ^2defer_clear^7");
 578                         return;
 579                 }
 580         }
 581 }
 582
 583 void GameCommand_delrec(int request, int argc)  // perhaps merge later with records and printstats and such?
 584 {
 585         switch (request)
 586         {
 587                 case CMD_REQUEST_COMMAND:
 588                 {
 589                         if (argv(1))
 590                         {
 591                                 if (argv(2)) race_deleteTime(argv(2), stof(argv(1)));
 592                                 else race_deleteTime(GetMapname(), stof(argv(1)));
 593                                 return;
 594                         }
 595                 }
 596
 597                 default:
 598                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 599                 case CMD_REQUEST_USAGE:
 600                 {
 601                         LOG_HELP("Usage:^3 sv_cmd delrec <ranking> [<map>]");
 602                         LOG_HELP("  <ranking> is which ranking level to clear up to, ");
 603                         LOG_HELP("  it will clear all records up to nth place.");
 604                         LOG_HELP("  if <map> is not provided it will use current map.");
 605                         return;
 606                 }
 607         }
 608 }
 609
 610 void print_Effect_Index(int d, string effect_name)
 611 {
 612         // this is inside a function to avoid expanding it on compilation everytime
 613         LOG_INFO("effect ", effect_name, " is ", ftos(_particleeffectnum(effect_name)), "\n");
 614         db_put(d, effect_name, "1");
 615 }
 616
 617 void GameCommand_effectindexdump(int request)
 618 {
 619         switch (request)
 620         {
 621                 case CMD_REQUEST_COMMAND:
 622                 {
 623                         float fh, d;
 624                         string s;
 625
 626                         d = db_create();
 627                         LOG_INFO("begin of effects list");
 628
 629                         print_Effect_Index(d, "TE_GUNSHOT");
 630                         print_Effect_Index(d, "TE_GUNSHOTQUAD");
 631                         print_Effect_Index(d, "TE_SPIKE");
 632                         print_Effect_Index(d, "TE_SPIKEQUAD");
 633                         print_Effect_Index(d, "TE_SUPERSPIKE");
 634                         print_Effect_Index(d, "TE_SUPERSPIKEQUAD");
 635                         print_Effect_Index(d, "TE_WIZSPIKE");
 636                         print_Effect_Index(d, "TE_KNIGHTSPIKE");
 637                         print_Effect_Index(d, "TE_EXPLOSION");
 638                         print_Effect_Index(d, "TE_EXPLOSIONQUAD");
 639                         print_Effect_Index(d, "TE_TAREXPLOSION");
 640                         print_Effect_Index(d, "TE_TELEPORT");
 641                         print_Effect_Index(d, "TE_LAVASPLASH");
 642                         print_Effect_Index(d, "TE_SMALLFLASH");
 643                         print_Effect_Index(d, "TE_FLAMEJET");
 644                         print_Effect_Index(d, "EF_FLAME");
 645                         print_Effect_Index(d, "TE_BLOOD");
 646                         print_Effect_Index(d, "TE_SPARK");
 647                         print_Effect_Index(d, "TE_PLASMABURN");
 648                         print_Effect_Index(d, "TE_TEI_G3");
 649                         print_Effect_Index(d, "TE_TEI_SMOKE");
 650                         print_Effect_Index(d, "TE_TEI_BIGEXPLOSION");
 651                         print_Effect_Index(d, "TE_TEI_PLASMAHIT");
 652                         print_Effect_Index(d, "EF_STARDUST");
 653                         print_Effect_Index(d, "TR_ROCKET");
 654                         print_Effect_Index(d, "TR_GRENADE");
 655                         print_Effect_Index(d, "TR_BLOOD");
 656                         print_Effect_Index(d, "TR_WIZSPIKE");
 657                         print_Effect_Index(d, "TR_SLIGHTBLOOD");
 658                         print_Effect_Index(d, "TR_KNIGHTSPIKE");
 659                         print_Effect_Index(d, "TR_VORESPIKE");
 660                         print_Effect_Index(d, "TR_NEHAHRASMOKE");
 661                         print_Effect_Index(d, "TR_NEXUIZPLASMA");
 662                         print_Effect_Index(d, "TR_GLOWTRAIL");
 663                         print_Effect_Index(d, "TR_SEEKER");
 664                         print_Effect_Index(d, "SVC_PARTICLE");
 665
 666                         fh = fopen("effectinfo.txt", FILE_READ);
 667                         while ((s = fgets(fh)))
 668                         {
 669                                 tokenize_console(s);
 670                                 if (argv(0) == "effect")
 671                                 {
 672                                         if (db_get(d, argv(1)) != "1")
 673                                         {
 674                                                 int i = _particleeffectnum(argv(1));
 675                                                 if (i >= 0) LOG_INFO("effect ", argv(1), " is ", ftos(i));
 676                                                 db_put(d, argv(1), "1");
 677                                         }
 678                                 }
 679                         }
 680                         LOG_INFO("end of effects list");
 681
 682                         db_close(d);
 683                         return;
 684                 }
 685
 686                 default:
 687                 case CMD_REQUEST_USAGE:
 688                 {
 689                         LOG_HELP("Usage:^3 sv_cmd effectindexdump");
 690                         LOG_HELP("  No arguments required.");
 691                         return;
 692                 }
 693         }
 694 }
 695
 696 void GameCommand_extendmatchtime(int request)
 697 {
 698         switch (request)
 699         {
 700                 case CMD_REQUEST_COMMAND:
 701                 {
 702                         changematchtime(autocvar_timelimit_increment * 60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
 703                         return;
 704                 }
 705
 706                 default:
 707                 case CMD_REQUEST_USAGE:
 708                 {
 709                         LOG_HELP("Usage:^3 sv_cmd extendmatchtime");
 710                         LOG_HELP("  No arguments required.");
 711                         LOG_HELP("See also: ^2reducematchtime^7");
 712                         return;
 713                 }
 714         }
 715 }
 716
 717 void GameCommand_gametype(int request, int argc)
 718 {
 719         switch (request)
 720         {
 721                 case CMD_REQUEST_COMMAND:
 722                 {
 723                         if (!world_initialized)
 724                         {
 725                                 LOG_INFOF("This command works only when the server is running.");
 726                                 return;
 727                         }
 728                         if (argv(1) != "")
 729                         {
 730                                 string s = argv(1);
 731                                 Gametype t = MapInfo_Type_FromString(s, false), tsave = MapInfo_CurrentGametype();
 732
 733                                 if (t)
 734                                 {
 735                                         MapInfo_SwitchGameType(t);
 736                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 737                                         if (MapInfo_count > 0)
 738                                         {
 739                                                 // update lsmaps in case the gametype changed, this way people can easily list maps for it
 740                                                 if (lsmaps_reply != "")   strunzone(lsmaps_reply);
 741                                                 lsmaps_reply = strzone(getlsmaps());
 742                                                 bprint("Game type successfully switched to ", s, "\n");
 743                                         }
 744                                         else
 745                                         {
 746                                                 bprint("Cannot use this game type: no map for it found\n");
 747                                                 MapInfo_SwitchGameType(tsave);
 748                                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 749                                         }
 750                                 }
 751                                 else
 752                                 {
 753                                         bprint("Failed to switch to ", s, ": this game type does not exist!\n");
 754                                 }
 755
 756                                 return;
 757                         }
 758                 }
 759
 760                 default:
 761                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 762                 case CMD_REQUEST_USAGE:
 763                 {
 764                         LOG_HELP("Usage:^3 sv_cmd gametype <mode>");
 765                         LOG_HELP("  Where <mode> is the gametype mode to switch to.");
 766                         LOG_HELP("See also: ^2gotomap^7");
 767                         return;
 768                 }
 769         }
 770 }
 771
 772 void GameCommand_gettaginfo(int request, int argc)
 773 {
 774         switch (request)
 775         {
 776                 case CMD_REQUEST_COMMAND:
 777                 {
 778                         entity tmp_entity;
 779                         float i;
 780                         vector v;
 781
 782                         if (argc >= 4)
 783                         {
 784                                 tmp_entity = spawn();
 785                                 if (argv(1) == "w")
 786                                 {
 787                                         .entity weaponentity = weaponentities[0];
 788                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
 789                                 }
 790                                 else
 791                                 {
 792                                         precache_model(argv(1));
 793                                         _setmodel(tmp_entity, argv(1));
 794                                 }
 795                                 tmp_entity.frame = stof(argv(2));
 796                                 if (substring(argv(3), 0, 1) == "#") i = stof(substring(argv(3), 1, -1));
 797                                 else i = gettagindex(tmp_entity, argv(3));
 798                                 if (i)
 799                                 {
 800                                         v = gettaginfo(tmp_entity, i);
 801                                         LOG_HELPF("model %s frame %s tag %s index %s parent %s",
 802                                                 tmp_entity.model, ftos(tmp_entity.frame), gettaginfo_name, ftos(i), ftos(gettaginfo_parent)
 803                                         );
 804                                         LOG_HELPF(" vector = %s %s %s", ftos(v.x), ftos(v.y), ftos(v.z));
 805                                         LOG_HELPF(" offset = %s %s %s", ftos(gettaginfo_offset.x), ftos(gettaginfo_offset.y), ftos(gettaginfo_offset.z));
 806                                         LOG_HELPF(" forward = %s %s %s", ftos(gettaginfo_forward.x), ftos(gettaginfo_forward.y), ftos(gettaginfo_forward.z));
 807                                         LOG_HELPF(" right = %s %s %s", ftos(gettaginfo_right.x), ftos(gettaginfo_right.y), ftos(gettaginfo_right.z));
 808                                         LOG_HELPF(" up = %s %s %s", ftos(gettaginfo_up.x), ftos(gettaginfo_up.y), ftos(gettaginfo_up.z));
 809                                         if (argc >= 6)
 810                                         {
 811                                                 v.y = -v.y;
 812                                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
 813                                         }
 814                                 }
 815                                 else
 816                                 {
 817                                         LOG_INFO("bone not found");
 818                                 }
 819
 820                                 delete(tmp_entity);
 821                                 return;
 822                         }
 823                 }
 824
 825                 default:
 826                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 827                 case CMD_REQUEST_USAGE:
 828                 {
 829                         LOG_HELP("Usage:^3 sv_cmd gettaginfo <model> <frame> <index> [<command1>] [<command2>]");
 830                         LOG_HELP("See also: ^2bbox, trace^7");
 831                         return;
 832                 }
 833         }
 834 }
 835
 836 void GameCommand_animbench(int request, int argc)
 837 {
 838         switch (request)
 839         {
 840                 case CMD_REQUEST_COMMAND:
 841                 {
 842                         entity tmp_entity;
 843
 844                         if (argc >= 4)
 845                         {
 846                                 tmp_entity = spawn();
 847                                 if (argv(1) == "w")
 848                                 {
 849                                         .entity weaponentity = weaponentities[0];
 850                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
 851                                 }
 852                                 else
 853                                 {
 854                                         precache_model(argv(1));
 855                                         _setmodel(tmp_entity, argv(1));
 856                                 }
 857                                 float f1 = stof(argv(2));
 858                                 float f2 = stof(argv(3));
 859                                 float t0;
 860                                 float t1 = 0;
 861                                 float t2 = 0;
 862                                 float n = 0;
 863
 864                                 while (t1 + t2 < 1)
 865                                 {
 866                                         tmp_entity.frame = f1;
 867                                         t0 = gettime(GETTIME_HIRES);
 868                                         getsurfacepoint(tmp_entity, 0, 0);
 869                                         t1 += gettime(GETTIME_HIRES) - t0;
 870                                         tmp_entity.frame = f2;
 871                                         t0 = gettime(GETTIME_HIRES);
 872                                         getsurfacepoint(tmp_entity, 0, 0);
 873                                         t2 += gettime(GETTIME_HIRES) - t0;
 874                                         n += 1;
 875                                 }
 876                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f1), " animtime ", ftos(n / t1), "/s");
 877                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f2), " animtime ", ftos(n / t2), "/s");
 878
 879                                 delete(tmp_entity);
 880                                 return;
 881                         }
 882                 }
 883
 884                 default:
 885                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 886                 case CMD_REQUEST_USAGE:
 887                 {
 888                         LOG_HELP("Usage:^3 sv_cmd animbench <model> <frame1> <frame2>");
 889                         LOG_HELP("See also: ^2bbox, trace^7");
 890                         return;
 891                 }
 892         }
 893 }
 894
 895 void GameCommand_gotomap(int request, int argc)
 896 {
 897         switch (request)
 898         {
 899                 case CMD_REQUEST_COMMAND:
 900                 {
 901                         if (!world_initialized)
 902                         {
 903                                 LOG_INFOF("This command works only when the server is running.");
 904                                 return;
 905                         }
 906                         if (argv(1))
 907                         {
 908                                 LOG_INFO(GotoMap(argv(1)));
 909                                 return;
 910                         }
 911                 }
 912
 913                 default:
 914                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 915                 case CMD_REQUEST_USAGE:
 916                 {
 917                         LOG_HELP("Usage:^3 sv_cmd gotomap <map>");
 918                         LOG_HELP("  Where <map> is the *.bsp file to change to.");
 919                         LOG_HELP("See also: ^2gametype^7");
 920                         return;
 921                 }
 922         }
 923 }
 924
 925 void GameCommand_lockteams(int request)
 926 {
 927         switch (request)
 928         {
 929                 case CMD_REQUEST_COMMAND:
 930                 {
 931                         if (teamplay)
 932                         {
 933                                 lockteams = 1;
 934                                 bprint("^1The teams are now locked.\n");
 935                         }
 936                         else
 937                         {
 938                                 bprint("lockteams command can only be used in a team-based gamemode.\n");
 939                         }
 940                         return;
 941                 }
 942
 943                 default:
 944                 case CMD_REQUEST_USAGE:
 945                 {
 946                         LOG_HELP("Usage:^3 sv_cmd lockteams");
 947                         LOG_HELP("  No arguments required.");
 948                         LOG_HELP("See also: ^2unlockteams^7");
 949                         return;
 950                 }
 951         }
 952 }
 953
 954 void GameCommand_make_mapinfo(int request)
 955 {
 956         switch (request)
 957         {
 958                 case CMD_REQUEST_COMMAND:
 959                 {
 960                         entity tmp_entity;
 961
 962                         tmp_entity = new(make_mapinfo);
 963                         setthink(tmp_entity, make_mapinfo_Think);
 964                         tmp_entity.nextthink = time;
 965                         MapInfo_Enumerate();
 966                         return;
 967                 }
 968
 969                 default:
 970                 case CMD_REQUEST_USAGE:
 971                 {
 972                         LOG_HELP("Usage:^3 sv_cmd make_mapinfo");
 973                         LOG_HELP("  No arguments required.");
 974                         LOG_HELP("See also: ^2radarmap^7");
 975                         return;
 976                 }
 977         }
 978 }
 979
 980 void GameCommand_moveplayer(int request, int argc)
 981 {
 982         switch (request)
 983         {
 984                 case CMD_REQUEST_COMMAND:
 985                 {
 986                         float accepted;
 987                         entity client;
 988
 989                         string targets = strreplace(",", " ", argv(1));
 990                         string original_targets = strreplace(" ", ", ", targets);
 991                         string destination = argv(2);
 992                         if (destination == "spec")
 993                                 destination = "spectator";
 994
 995                         if ((targets) && (destination))
 996                         {
 997                                 string successful = string_null;
 998                                 string t;
 999                                 for ( ; targets; )
1000                                 {
1001                                         t = car(targets);
1002                                         targets = cdr(targets);
1003
1004                                         // Check to see if the player is a valid target
1005                                         client = GetFilteredEntity(t);
1006                                         accepted = VerifyClientEntity(client, false, false);
1007
1008                                         if (accepted <= 0)
1009                                         {
1010                                                 LOG_INFO("moveplayer: ", GetClientErrorString(accepted, t), ".");
1011                                         }
1012                                         else if (destination == "spectator")
1013                                         {
1014                                                 string pl_name = playername(client.netname, client.team, false);
1015                                                 if (!IS_SPEC(client) && !IS_OBSERVER(client))
1016                                                 {
1017                                                         PutObserverInServer(client, true);
1018
1019                                                         successful = strcat(successful, (successful ? ", " : ""), pl_name);
1020                                                 }
1021                                                 else
1022                                                 {
1023                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", pl_name, ") is already spectating.");
1024                                                 }
1025                                         }
1026                                         else
1027                                         {
1028                                                 if (!teamplay)
1029                                                 {
1030                                                         LOG_INFO("Can't change teams when currently not playing a team game.");
1031                                                         return;
1032                                                 }
1033
1034                                                 string pl_name = playername(client.netname, client.team, false);
1035                                                 if (IS_SPEC(client) || IS_OBSERVER(client))
1036                                                 {
1037                                                         // well technically we could, but should we allow that? :P
1038                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", pl_name, ") is not in the game.");
1039                                                         continue;
1040                                                 }
1041
1042                                                 // set up
1043                                                 int save = Player_GetForcedTeamIndex(client);
1044                                                 Player_SetForcedTeamIndex(client, TEAM_FORCE_DEFAULT);
1045
1046                                                 // find the team to move the player to
1047                                                 int team_num = Team_ColorToTeam(destination);
1048                                                 entity balance;
1049                                                 if (team_num == client.team)  // already on the destination team
1050                                                 {
1051                                                         // keep the forcing undone
1052                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", pl_name, ") is already on the ", Team_ColoredFullName(team_num), ".");
1053                                                         continue;
1054                                                 }
1055                                                 else if (team_num == 0)  // auto team
1056                                                 {
1057                                                         balance = TeamBalance_CheckAllowedTeams(client);
1058                                                         team_num = Team_IndexToTeam(TeamBalance_FindBestTeam(balance, client, false));
1059                                                 }
1060                                                 else
1061                                                 {
1062                                                         balance = TeamBalance_CheckAllowedTeams(client);
1063                                                 }
1064                                                 Player_SetForcedTeamIndex(client, save);
1065
1066                                                 // Check to see if the destination team is even available
1067                                                 int team_id = Team_TeamToIndex(team_num);
1068                                                 if (team_id == -1)
1069                                                 {
1070                                                         LOG_INFO("Sorry, can't move player here if team ", destination, " doesn't exist.");
1071                                                         TeamBalance_Destroy(balance);
1072                                                         return;
1073                                                 }
1074                                                 if (!TeamBalance_IsTeamAllowed(balance, team_id))
1075                                                 {
1076                                                         LOG_INFOF("Sorry, can't move player to %s team if it doesn't exist.", destination);
1077                                                         TeamBalance_Destroy(balance);
1078                                                         return;
1079                                                 }
1080                                                 TeamBalance_Destroy(balance);
1081
1082                                                 // If so, lets continue and finally move the player
1083                                                 Player_SetForcedTeamIndex(client, TEAM_FORCE_DEFAULT);
1084                                                 if (MoveToTeam(client, team_id, 6))
1085                                                 {
1086                                                         successful = strcat(successful, (successful ? ", " : ""), pl_name);
1087                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", pl_name, ") has been moved to the ", Team_ColoredFullName(team_num), "^7.");
1088                                                 }
1089                                                 else
1090                                                 {
1091                                                         LOG_INFO("Unable to move player ", ftos(GetFilteredNumber(t)), " (", pl_name, ")");
1092                                                 }
1093                                         }
1094                                 } // loop end
1095
1096                                 if (successful) bprint("Successfully moved players ", successful, " to destination ", destination, ".\n");
1097                                 else LOG_INFO("No players given (", original_targets, ") are able to move.");
1098
1099                                 return;  // still correct parameters so return to avoid usage print
1100                         }
1101                 }
1102
1103                 default:
1104                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1105                 case CMD_REQUEST_USAGE:
1106                 {
1107                         LOG_HELP("Usage:^3 sv_cmd moveplayer <clients> <destination>");
1108                         LOG_HELP("  <clients> is a list (separated by commas) of player entity ID's or nicknames");
1109                         LOG_HELP("  <destination> is what to send the player to, be it team or spectating");
1110                         LOG_HELP("  Full list of destinations here: spec, spectator, red, blue, yellow, pink, auto.");
1111                         LOG_HELP("Examples: sv_cmd moveplayer 1,3,5 red");
1112                         LOG_HELP("          sv_cmd moveplayer 2 spec");
1113                         LOG_HELP("See also: ^2allspec, shuffleteams^7");
1114                         return;
1115                 }
1116         }
1117 }
1118
1119 void GameCommand_nospectators(int request)
1120 {
1121         switch (request)
1122         {
1123                 case CMD_REQUEST_COMMAND:
1124                 {
1125                         blockSpectators = 1;
1126                         // give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
1127                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_SPEC(it) || IS_OBSERVER(it)) && !it.caplayer, {
1128                                 if(!it.caplayer)
1129                                 {
1130                                         CS(it).spectatortime = time;
1131                                         Send_Notification(NOTIF_ONE_ONLY, it, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1132                                 }
1133                         });
1134                         bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
1135                         return;
1136                 }
1137
1138                 default:
1139                 case CMD_REQUEST_USAGE:
1140                 {
1141                         LOG_HELP("Usage:^3 sv_cmd nospectators");
1142                         LOG_HELP("  No arguments required.");
1143                         return;
1144                 }
1145         }
1146 }
1147
1148 void GameCommand_printstats(int request)
1149 {
1150         switch (request)
1151         {
1152                 case CMD_REQUEST_COMMAND:
1153                 {
1154                         DumpStats(false);
1155                         LOG_INFO("stats dumped.");
1156                         return;
1157                 }
1158
1159                 default:
1160                 case CMD_REQUEST_USAGE:
1161                 {
1162                         LOG_HELP("Usage:^3 sv_cmd printstats");
1163                         LOG_HELP("  No arguments required.");
1164                         return;
1165                 }
1166         }
1167 }
1168
1169 void GameCommand_radarmap(int request, int argc)
1170 {
1171         switch (request)
1172         {
1173                 case CMD_REQUEST_COMMAND:
1174                 {
1175                         if (RadarMap_Make(argc)) return;
1176                 }
1177
1178                 default:
1179                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1180                 case CMD_REQUEST_USAGE:
1181                 {
1182                         LOG_HELP("Usage:^3 sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]");
1183                         LOG_HELP("  The quality factor Q is roughly proportional to the time taken.");
1184                         LOG_HELP("  trace supports no quality factor; its result should look like --block with infinite quality factor.");
1185                         LOG_HELP("See also: ^2make_mapinfo^7");
1186                         return;
1187                 }
1188         }
1189 }
1190
1191 void GameCommand_reducematchtime(int request)
1192 {
1193         switch (request)
1194         {
1195                 case CMD_REQUEST_COMMAND:
1196                 {
1197                         changematchtime(autocvar_timelimit_decrement * -60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
1198                         return;
1199                 }
1200
1201                 default:
1202                 case CMD_REQUEST_USAGE:
1203                 {
1204                         LOG_HELP("Usage:^3 sv_cmd reducematchtime");
1205                         LOG_HELP("  No arguments required.");
1206                         LOG_HELP("See also: ^2extendmatchtime^7");
1207                         return;
1208                 }
1209         }
1210 }
1211
1212 void GameCommand_setbots(int request, int argc)
1213 {
1214         switch (request)
1215         {
1216                 case CMD_REQUEST_COMMAND:
1217                 {
1218                         if (argc >= 2)
1219                         {
1220                                 cvar_settemp("minplayers", "0");
1221                                 cvar_settemp("minplayers_per_team", "0");
1222                                 cvar_settemp("bot_number", argv(1));
1223                                 bot_fixcount();
1224                                 return;
1225                         }
1226                 }
1227
1228                 default:
1229                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1230                 case CMD_REQUEST_USAGE:
1231                 {
1232                         LOG_HELP("Usage:^3 sv_cmd setbots <botnumber>");
1233                         LOG_HELP("  Where <botnumber> is the amount of bots to set bot_number cvar to.");
1234                         LOG_HELP("See also: ^2bot_cmd^7");
1235                         return;
1236                 }
1237         }
1238 }
1239
1240 void shuffleteams()
1241 {
1242         if (!teamplay)
1243         {
1244                 LOG_INFO("Can't shuffle teams when currently not playing a team game.");
1245                 return;
1246         }
1247
1248         FOREACH_CLIENT(IS_PLAYER(it) || it.caplayer, {
1249                 if (Player_HasRealForcedTeam(it)) {
1250                         // we could theoretically assign forced players to their teams
1251                         // and shuffle the rest to fill the empty spots but in practise
1252                         // either all players or none are gonna have forced teams
1253                         LOG_INFO("Can't shuffle teams because at least one player has a forced team.");
1254                         return;
1255                 }
1256         });
1257
1258         int number_of_teams = 0;
1259         entity balance = TeamBalance_CheckAllowedTeams(NULL);
1260         for (int i = 1; i <= NUM_TEAMS; ++i)
1261         {
1262                 if (TeamBalance_IsTeamAllowed(balance, i))
1263                 {
1264                         number_of_teams = max(i, number_of_teams);
1265                 }
1266         }
1267         TeamBalance_Destroy(balance);
1268
1269         int team_index = 0;
1270         FOREACH_CLIENT_RANDOM(IS_PLAYER(it) || it.caplayer, {
1271                 int target_team_index = team_index + 1;
1272                 if (Entity_GetTeamIndex(it) != target_team_index)
1273                 {
1274                         MoveToTeam(it, target_team_index, 6);
1275                 }
1276                 team_index = (team_index + 1) % number_of_teams;
1277         });
1278
1279         bprint("Successfully shuffled the players around randomly.\n");
1280 }
1281
1282 void GameCommand_shuffleteams(int request)
1283 {
1284         switch (request)
1285         {
1286                 case CMD_REQUEST_COMMAND:
1287                 {
1288                         if (shuffleteams_on_reset_map)
1289                         {
1290                                 bprint("Players will be shuffled when this round is over.\n");
1291                                 shuffleteams_on_reset_map = true;
1292                         }
1293                         else
1294                                 shuffleteams();
1295                         return;
1296                 }
1297
1298                 default:
1299                 case CMD_REQUEST_USAGE:
1300                 {
1301                         LOG_HELP("Usage:^3 sv_cmd shuffleteams");
1302                         LOG_HELP("  No arguments required.");
1303                         LOG_HELP("See also: ^2moveplayer, allspec^7");
1304                         return;
1305                 }
1306         }
1307 }
1308
1309 void GameCommand_reset(int request)
1310 {
1311         switch (request)
1312         {
1313                 case CMD_REQUEST_COMMAND:
1314                 {
1315                         ReadyRestart(false);
1316                         return;
1317                 }
1318
1319                 default:
1320                 case CMD_REQUEST_USAGE:
1321                 {
1322                         LOG_HELP("Usage:^3 sv_cmd reset");
1323                         LOG_HELP("  No arguments required.");
1324                         return;
1325                 }
1326         }
1327 }
1328
1329 void GameCommand_stuffto(int request, int argc)
1330 {
1331         // This... is a fairly dangerous and powerful command... - It allows any arguments to be sent to a client via rcon.
1332         // Because of this, it is disabled by default and must be enabled by the server owner when doing compilation. That way,
1333         // we can be certain they understand the risks of it... So to enable, compile server with -DSTUFFTO_ENABLED argument.
1334
1335 #ifdef STUFFTO_ENABLED
1336                 switch (request)
1337                 {
1338                         case CMD_REQUEST_COMMAND:
1339                         {
1340                                 if (argv(2))
1341                                 {
1342                                         entity client = GetIndexedEntity(argc, 1);
1343                                         float accepted = VerifyClientEntity(client, true, false);
1344
1345                                         if (accepted > 0)
1346                                         {
1347                                                 stuffcmd(client, strcat("\n", argv(next_token), "\n"));
1348                                                 LOG_INFO("Command: \"", argv(next_token), "\" sent to ", GetCallerName(client), " (", argv(1), ").");
1349                                         }
1350                                         else
1351                                         {
1352                                                 LOG_INFO("stuffto: ", GetClientErrorString(accepted, argv(1)), ".");
1353                                         }
1354
1355                                         return;
1356                                 }
1357                         }
1358
1359                         default:
1360                                 LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1361                         case CMD_REQUEST_USAGE:
1362                         {
1363                                 LOG_HELP("Usage:^3 sv_cmd stuffto <client> \"<command>\"");
1364                                 LOG_HELP("  <client> is the entity number or name of the player,");
1365                                 LOG_HELP("  and <command> is the command to be sent to that player.");
1366                                 return;
1367                         }
1368                 }
1369 #else
1370                 if (request)
1371                 {
1372                         LOG_HELP("stuffto command is not enabled on this server.");
1373                         return;
1374                 }
1375 #endif
1376 }
1377
1378 void GameCommand_trace(int request, int argc)
1379 {
1380         switch (request)
1381         {
1382                 case CMD_REQUEST_COMMAND:
1383                 {
1384                         entity e;
1385                         vector org, delta, start, end, p, q, q0, pos, vv, dv;
1386                         float i, f, safe, unsafe, dq, dqf;
1387
1388                         switch (argv(1))
1389                         {
1390                                 case "debug":
1391                                 {
1392                                         float hitcount = 0;
1393                                         LOG_INFO("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.");
1394                                         float worst_endpos_bug = 0;
1395                                         for ( ; ; )
1396                                         {
1397                                                 org = world.mins;
1398                                                 delta = world.maxs - world.mins;
1399
1400                                                 start.x = org.x + random() * delta.x;
1401                                                 start.y = org.y + random() * delta.y;
1402                                                 start.z = org.z + random() * delta.z;
1403
1404                                                 end.x = org.x + random() * delta.x;
1405                                                 end.y = org.y + random() * delta.y;
1406                                                 end.z = org.z + random() * delta.z;
1407
1408                                                 start = stov(vtos(start));
1409                                                 end = stov(vtos(end));
1410
1411                                                 tracebox(start, PL_MIN_CONST, PL_MAX_CONST, end, MOVE_NOMONSTERS, NULL);
1412                                                 if (!trace_startsolid && trace_fraction < 1)
1413                                                 {
1414                                                         p = trace_endpos;
1415                                                         tracebox(p, PL_MIN_CONST, PL_MAX_CONST, p, MOVE_NOMONSTERS, NULL);
1416                                                         if (trace_startsolid)
1417                                                         {
1418                                                                 rint(42);  // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
1419                                                                 tracebox(start, PL_MIN_CONST, PL_MAX_CONST, end, MOVE_NOMONSTERS, NULL);
1420
1421                                                                 // how much do we need to back off?
1422                                                                 safe = 1;
1423                                                                 unsafe = 0;
1424                                                                 for ( ; ; )
1425                                                                 {
1426                                                                         pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
1427                                                                         tracebox(pos, PL_MIN_CONST, PL_MAX_CONST, pos, MOVE_NOMONSTERS, NULL);
1428                                                                         if (trace_startsolid)
1429                                                                         {
1430                                                                                 if ((safe + unsafe) * 0.5 == unsafe) break;
1431                                                                                 unsafe = (safe + unsafe) * 0.5;
1432                                                                         }
1433                                                                         else
1434                                                                         {
1435                                                                                 if ((safe + unsafe) * 0.5 == safe) break;
1436                                                                                 safe = (safe + unsafe) * 0.5;
1437                                                                         }
1438                                                                 }
1439
1440                                                                 LOG_INFO("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu");
1441                                                                 LOG_INFO("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu");
1442
1443                                                                 tracebox(p, PL_MIN_CONST + '0.1 0.1 0.1', PL_MAX_CONST - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, NULL);
1444                                                                 if (trace_startsolid) LOG_INFO("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1445                                                                 else LOG_INFO("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1446                                                                 if (++hitcount >= 10) break;
1447                                                         }
1448                                                         else
1449                                                         {
1450                                                                 q0 = p;
1451                                                                 dq = 0;
1452                                                                 dqf = 1;
1453                                                                 for ( ; ; )
1454                                                                 {
1455                                                                         q = p + normalize(end - p) * (dq + dqf);
1456                                                                         if (q == q0) break;
1457                                                                         tracebox(p, PL_MIN_CONST, PL_MAX_CONST, q, MOVE_NOMONSTERS, NULL);
1458                                                                         if (trace_startsolid) error("THIS ONE cannot happen");
1459                                                                         if (trace_fraction > 0) dq += dqf * trace_fraction;
1460                                                                         dqf *= 0.5;
1461                                                                         q0 = q;
1462                                                                 }
1463                                                                 if (dq > worst_endpos_bug)
1464                                                                 {
1465                                                                         worst_endpos_bug = dq;
1466                                                                         LOG_INFO("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1467                                                                         LOG_INFO("could go ", ftos(dq), " units further to ", vtos(q));
1468                                                                         if (++hitcount >= 10) break;
1469                                                                 }
1470                                                         }
1471                                                 }
1472                                         }
1473                                         return;
1474                                 }
1475
1476                                 case "debug2":
1477                                 {
1478                                         e = nextent(NULL);
1479                                         tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
1480                                         vv = trace_endpos;
1481                                         if (trace_fraction == 1)
1482                                         {
1483                                                 LOG_INFO("not above ground, aborting");
1484                                                 return;
1485                                         }
1486                                         f = 0;
1487                                         for (i = 0; i < 100000; ++i)
1488                                         {
1489                                                 dv = randomvec();
1490                                                 if (dv.z > 0) dv = -1 * dv;
1491                                                 tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
1492                                                 if (trace_startsolid) LOG_INFO("bug 1");
1493                                                 if (trace_fraction == 1)
1494                                                 {
1495                                                         if (dv.z < f)
1496                                                         {
1497                                                                 LOG_INFO("bug 2: ", ftos(dv.x), " ", ftos(dv.y), " ", ftos(dv.z));
1498                                                                 LOG_INFO(" (", ftos(asin(dv.z / vlen(dv)) * 180 / M_PI), " degrees)");
1499                                                                 f = dv.z;
1500                                                         }
1501                                                 }
1502                                         }
1503                                         LOG_INFO("highest possible dist: ", ftos(f));
1504                                         return;
1505                                 }
1506
1507                                 case "walk":
1508                                 {
1509                                         if (argc == 4 || argc == 5)
1510                                         {
1511                                                 e = nextent(NULL);
1512                                                 int dphitcontentsmask_save = e.dphitcontentsmask;
1513                                                 e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
1514                                                 if (tracewalk(e, stov(argv(2)), e.mins, e.maxs, stov(argv(3)), stof(argv(4)), MOVE_NORMAL))
1515                                                         LOG_INFO("can walk");
1516                                                 else
1517                                                         LOG_INFO("cannot walk");
1518                                                 e.dphitcontentsmask = dphitcontentsmask_save;
1519                                                 return;
1520                                         }
1521                                 }
1522
1523                                 case "showline":
1524                                 {
1525                                         if (argc == 4)
1526                                         {
1527                                                 vv = stov(argv(2));
1528                                                 dv = stov(argv(3));
1529                                                 traceline(vv, dv, MOVE_NORMAL, NULL);
1530                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_NEXUIZPLASMA), vv, trace_endpos);
1531                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_CRYLINKPLASMA), trace_endpos, dv);
1532                                                 return;
1533                                         }
1534                                 }
1535
1536                                 // no default case, just go straight to invalid
1537                         }
1538                 }
1539
1540                 default:
1541                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1542                 case CMD_REQUEST_USAGE:
1543                 {
1544                         LOG_HELP("Usage:^3 sv_cmd trace <command> [<startpos> <endpos>] [<endpos_height>]");
1545                         LOG_HELP("  Where <startpos> and <endpos> are parameters for the 'walk' and 'showline' commands,");
1546                         LOG_HELP("  <endpos_height> is an optional parameter for the 'walk' command,");
1547                         LOG_HELP("  Full list of commands here: debug, debug2, walk, showline.");
1548                         LOG_HELP("See also: ^2bbox, gettaginfo^7");
1549                         return;
1550                 }
1551         }
1552 }
1553
1554 void GameCommand_unlockteams(int request)
1555 {
1556         switch (request)
1557         {
1558                 case CMD_REQUEST_COMMAND:
1559                 {
1560                         if (teamplay)
1561                         {
1562                                 lockteams = 0;
1563                                 bprint("^1The teams are now unlocked.\n");
1564                         }
1565                         else
1566                         {
1567                                 bprint("unlockteams command can only be used in a team-based gamemode.\n");
1568                         }
1569                         return;
1570                 }
1571
1572                 default:
1573                 case CMD_REQUEST_USAGE:
1574                 {
1575                         LOG_HELP("Usage:^3 sv_cmd unlockteams");
1576                         LOG_HELP("  No arguments required.");
1577                         LOG_HELP("See also: ^2lockteams^7");
1578                         return;
1579                 }
1580         }
1581 }
1582
1583 void GameCommand_warp(int request, int argc)
1584 {
1585         switch (request)
1586         {
1587                 case CMD_REQUEST_COMMAND:
1588                 {
1589                         if (autocvar_g_campaign)
1590                         {
1591                                 if (argc >= 2)
1592                                 {
1593                                         CampaignLevelWarp(stof(argv(1)));
1594                                         LOG_INFO("Successfully warped to campaign level ", argv(1), ".");
1595                                 }
1596                                 else
1597                                 {
1598                                         CampaignLevelWarp(-1);
1599                                         LOG_INFO("Successfully warped to next campaign level.");
1600                                 }
1601                         }
1602                         else
1603                         {
1604                                 LOG_INFO("Not in campaign, can't level warp");
1605                         }
1606                         return;
1607                 }
1608
1609                 default:
1610                 case CMD_REQUEST_USAGE:
1611                 {
1612                         LOG_HELP("Usage:^3 sv_cmd warp [<level>]");
1613                         LOG_HELP("  <level> is the level to change campaign mode to.");
1614                         LOG_HELP("  if <level> is not provided it will change to the next level.");
1615                         return;
1616                 }
1617         }
1618 }
1619
1620 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1621 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1622 void GameCommand_(int request)
1623 {
1624     switch(request)
1625     {
1626         case CMD_REQUEST_COMMAND:
1627         {
1628
1629             return;
1630         }
1631
1632         default:
1633         case CMD_REQUEST_USAGE:
1634         {
1635             LOG_HELP("Usage:^3 sv_cmd ");
1636             LOG_HELP("  No arguments required.");
1637             return;
1638         }
1639     }
1640 }
1641 */
1642
1643
1644 // ==================================
1645 //  Macro system for server commands
1646 // ==================================
1647
1648 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1649 SERVER_COMMAND(adminmsg, "Send an admin message to a client directly") { GameCommand_adminmsg(request, arguments); }
1650 SERVER_COMMAND(allready, "Ends warmup and starts the match") { GameCommand_allready(request); }
1651 SERVER_COMMAND(allspec, "Force all players to spectate") { GameCommand_allspec(request, arguments); }
1652 SERVER_COMMAND(anticheat, "Create an anticheat report for a client") { GameCommand_anticheat(request, arguments); }
1653 SERVER_COMMAND(animbench, "Benchmark model animation (LAGS)") { GameCommand_animbench(request, arguments); }
1654 SERVER_COMMAND(bbox, "Print detailed information about world size") { GameCommand_bbox(request); }
1655 SERVER_COMMAND(bot_cmd, "Control and send commands to bots") { GameCommand_bot_cmd(request, arguments, command); }
1656 SERVER_COMMAND(cointoss, "Flip a virtual coin and give random result") { GameCommand_cointoss(request, arguments); }
1657 SERVER_COMMAND(database, "Extra controls of the serverprogs database") { GameCommand_database(request, arguments); }
1658 SERVER_COMMAND(defer_clear, "Clear all queued defer commands for a specific client") { GameCommand_defer_clear(request, arguments); }
1659 SERVER_COMMAND(defer_clear_all, "Clear all queued defer commands for all clients") { GameCommand_defer_clear_all(request); }
1660 SERVER_COMMAND(delrec, "Delete race time record for a map") { GameCommand_delrec(request, arguments); }
1661 SERVER_COMMAND(effectindexdump, "Dump list of effects from code and effectinfo.txt") { GameCommand_effectindexdump(request); }
1662 SERVER_COMMAND(extendmatchtime, "Increase the timelimit value incrementally") { GameCommand_extendmatchtime(request); }
1663 SERVER_COMMAND(gametype, "Simple command to change the active gametype") { GameCommand_gametype(request, arguments); }
1664 SERVER_COMMAND(gettaginfo, "Get specific information about a weapon model") { GameCommand_gettaginfo(request, arguments); }
1665 SERVER_COMMAND(gotomap, "Simple command to switch to another map") { GameCommand_gotomap(request, arguments); }
1666 SERVER_COMMAND(lockteams, "Disable the ability for players to switch or enter teams") { GameCommand_lockteams(request); }
1667 SERVER_COMMAND(make_mapinfo, "Automatically rebuild mapinfo files") { GameCommand_make_mapinfo(request); }
1668 SERVER_COMMAND(moveplayer, "Change the team/status of a player") { GameCommand_moveplayer(request, arguments); }
1669 SERVER_COMMAND(nospectators, "Automatically remove spectators from a match") { GameCommand_nospectators(request); }
1670 SERVER_COMMAND(printstats, "Dump eventlog player stats and other score information") { GameCommand_printstats(request); }
1671 SERVER_COMMAND(radarmap, "Generate a radar image of the map") { GameCommand_radarmap(request, arguments); }
1672 SERVER_COMMAND(reducematchtime, "Decrease the timelimit value incrementally") { GameCommand_reducematchtime(request); }
1673 SERVER_COMMAND(reset, "Soft restart the game without changing teams; goes back to warmup if enabled") { GameCommand_reset(request); }
1674 SERVER_COMMAND(setbots, "Adjust how many bots are in the match") { GameCommand_setbots(request, arguments); }
1675 SERVER_COMMAND(shuffleteams, "Randomly move players to different teams") { GameCommand_shuffleteams(request); }
1676 SERVER_COMMAND(stuffto, "Send a command to be executed on a client") { GameCommand_stuffto(request, arguments); }
1677 SERVER_COMMAND(trace, "Various debugging tools with tracing") { GameCommand_trace(request, arguments); }
1678 SERVER_COMMAND(unlockteams, "Enable the ability for players to switch or enter teams") { GameCommand_unlockteams(request); }
1679 SERVER_COMMAND(warp, "Choose different level in campaign") { GameCommand_warp(request, arguments); }
1680
1681 void GameCommand_macro_help()
1682 {
1683         FOREACH(SERVER_COMMANDS, true, { LOG_HELPF("  ^2%s^7: %s", it.m_name, it.m_description); });
1684 }
1685
1686 float GameCommand_macro_command(int argc, string command)
1687 {
1688         string c = strtolower(argv(0));
1689         FOREACH(SERVER_COMMANDS, it.m_name == c, {
1690                 it.m_invokecmd(it, CMD_REQUEST_COMMAND, NULL, argc, command);
1691                 return true;
1692         });
1693         return false;
1694 }
1695
1696 float GameCommand_macro_usage(int argc)
1697 {
1698         string c = strtolower(argv(1));
1699         FOREACH(SERVER_COMMANDS, it.m_name == c, {
1700                 it.m_invokecmd(it, CMD_REQUEST_USAGE, NULL, argc, "");
1701                 return true;
1702         });
1703         return false;
1704 }
1705
1706 void GameCommand_macro_write_aliases(float fh)
1707 {
1708         FOREACH(SERVER_COMMANDS, true, { CMD_Write_Alias("qc_cmd_sv", it.m_name, it.m_description); });
1709 }
1710
1711
1712 // =========================================
1713 //  Main Function Called By Engine (sv_cmd)
1714 // =========================================
1715 // If this function exists, game code handles gamecommand instead of the engine code.
1716
1717 void GameCommand(string command)
1718 {
1719         int argc = tokenize_console(command);
1720
1721         // Guide for working with argc arguments by example:
1722         // argc:   1    - 2      - 3     - 4
1723         // argv:   0    - 1      - 2     - 3
1724         // cmd     vote - master - login - password
1725
1726         if (strtolower(argv(0)) == "help")
1727         {
1728                 if (argc == 1)
1729                 {
1730                         LOG_HELP("Server console commands:");
1731                         GameCommand_macro_help();
1732
1733                         LOG_HELP("\nBanning commands:");
1734                         BanCommand_macro_help();
1735
1736                         LOG_HELP("\nCommon networked commands:");
1737                         CommonCommand_macro_help(NULL);
1738
1739                         LOG_HELP("\nGeneric commands shared by all programs:");
1740                         GenericCommand_macro_help();
1741
1742                         LOG_HELP("\nUsage:^3 sv_cmd <command>^7, where possible commands are listed above.\n"
1743                                 "For help about a specific command, type sv_cmd help <command>");
1744
1745                         return;
1746                 }
1747                 else if (BanCommand_macro_usage(argc))  // Instead of trying to call a command, we're going to see detailed information about it
1748                 {
1749                         return;
1750                 }
1751                 else if (CommonCommand_macro_usage(argc, NULL))  // same here, but for common commands instead
1752                 {
1753                         return;
1754                 }
1755                 else if (GenericCommand_macro_usage(argc))  // same here, but for generic commands instead
1756                 {
1757                         return;
1758                 }
1759                 else if (GameCommand_macro_usage(argc))  // finally try for normal commands too
1760                 {
1761                         return;
1762                 }
1763         }
1764         else if (MUTATOR_CALLHOOK(SV_ParseServerCommand, strtolower(argv(0)), argc, command))
1765         {
1766                 return;  // handled by a mutator
1767         }
1768         else if (BanCommand(command))
1769         {
1770                 return;  // handled by server/command/ipban.qc
1771         }
1772         else if (CommonCommand_macro_command(argc, NULL, command))
1773         {
1774                 return;  // handled by server/command/common.qc
1775         }
1776         else if (GenericCommand(command))
1777         {
1778                 return;                                        // handled by common/command/generic.qc
1779         }
1780         else if (GameCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
1781         {
1782                 return;                                        // handled by one of the above GameCommand_* functions
1783         }
1784
1785         // nothing above caught the command, must be invalid
1786         LOG_INFO(((command != "") ? strcat("Unknown server command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try sv_cmd help.");
1787 }