qcsrc/server/command/sv_cmd.qc

   1 #include "sv_cmd.qh"
   2
   3 #include <common/constants.qh>
   4 #include <common/effects/all.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/mapinfo.qh>
   7 #include <common/monsters/sv_monsters.qh>
   8 #include <common/net_linked.qh>
   9 #include <common/notifications/all.qh>
  10 #include <common/teams.qh>
  11 #include <common/util.qh>
  12 #include <server/anticheat.qh>
  13 #include <server/bot/api.qh>
  14 #include <server/campaign.qh>
  15 #include <server/client.qh>
  16 #include <server/command/_mod.qh>
  17 #include <server/command/banning.qh>
  18 #include <server/command/cmd.qh>
  19 #include <server/command/common.qh>
  20 #include <server/command/getreplies.qh>
  21 #include <server/command/radarmap.qh>
  22 #include <server/intermission.qh>
  23 #include <server/ipban.qh>
  24 #include <server/mutators/_mod.qh>
  25 #include <server/player.qh>
  26 #include <server/teamplay.qh>
  27 #include <server/world.qh>
  28
  29 //  used by GameCommand_make_mapinfo()
  30 void make_mapinfo_Think(entity this)
  31 {
  32         if (_MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
  33         {
  34                 LOG_INFO("Done rebuiling mapinfos.");
  35                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
  36                 delete(this);
  37         }
  38         else
  39         {
  40                 setthink(this, make_mapinfo_Think);
  41                 this.nextthink = time;
  42         }
  43 }
  44
  45 //  used by GameCommand_extendmatchtime() and GameCommand_reducematchtime()
  46 void changematchtime(float delta, float mi, float ma)
  47 {
  48         float cur;
  49         float update;
  50         float lim;
  51
  52         if (delta == 0) return;
  53         if (autocvar_timelimit < 0) return;
  54
  55         if (mi <= 10) mi = 10;  // at least ten sec in the future
  56         cur = time - game_starttime;
  57         if (cur > 0) mi += cur; // from current time!
  58
  59         lim = autocvar_timelimit * 60;
  60
  61         if (delta > 0)
  62         {
  63                 if (lim == 0) return; // cannot increase any further
  64                 else if (lim < ma) update = min(ma, lim + delta);
  65                 else                  // already above maximum: FAIL
  66                         return;
  67         }
  68         else
  69         {
  70                 if (lim == 0)      // infinite: try reducing to max, if we are allowed to
  71                         update = max(mi, ma);
  72                 else if (lim > mi) // above minimum: decrease
  73                         update = max(mi, lim + delta);
  74                 else               // already below minimum: FAIL
  75                         return;
  76         }
  77
  78         cvar_set("timelimit", ftos(update / 60));
  79 }
  80
  81
  82 // =======================
  83 //  Command Sub-Functions
  84 // =======================
  85
  86 void GameCommand_adminmsg(int request, int argc)
  87 {
  88         switch (request)
  89         {
  90                 case CMD_REQUEST_COMMAND:
  91                 {
  92                         entity client;
  93                         float accepted;
  94
  95                         string targets = strreplace(",", " ", argv(1));
  96                         string original_targets = strreplace(" ", ", ", targets);
  97                         string admin_message = argv(2);
  98                         float infobartime = stof(argv(3));
  99
 100                         string successful, t;
 101                         successful = string_null;
 102
 103                         if ((targets) && (admin_message))
 104                         {
 105                                 for ( ; targets; )
 106                                 {
 107                                         t = car(targets);
 108                                         targets = cdr(targets);
 109
 110                                         // Check to see if the player is a valid target
 111                                         client = GetFilteredEntity(t);
 112                                         accepted = VerifyClientEntity(client, true, false);
 113
 114                                         if (accepted <= 0)
 115                                         {
 116                                                 LOG_INFO("adminmsg: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : "."));
 117                                                 continue;
 118                                         }
 119
 120                                         // send the centerprint/console print or infomessage
 121                                         if (infobartime)
 122                                         {
 123                                                 stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", infobartime, MakeConsoleSafe(admin_message)));
 124                                         }
 125                                         else
 126                                         {
 127                                                 centerprint(client, strcat("^3", GetCallerName(NULL), ":\n^7", admin_message));
 128                                                 sprint(client, strcat("\{1}\{13}^3", GetCallerName(NULL), "^7: ", admin_message, "\n"));
 129                                         }
 130
 131                                         successful = strcat(successful, (successful ? ", " : ""), playername(client.netname, client.team, false));
 132                                         LOG_TRACE("Message sent to ", playername(client.netname, client.team, false));
 133                                         continue;
 134                                 }
 135
 136                                 if (successful) bprint("Successfully sent message '", admin_message, "' to ", successful, ".\n");
 137                                 else LOG_INFO("No players given (", original_targets, ") could receive the message.");
 138
 139                                 return;
 140                         }
 141                 }
 142
 143                 default:
 144                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 145                 case CMD_REQUEST_USAGE:
 146                 {
 147                         LOG_HELP("Usage:^3 sv_cmd adminmsg <clients> \"<message>\" [<infobartime>]");
 148                         LOG_HELP("  <clients> is a list (separated by commas) of player entity ID's or nicknames");
 149                         LOG_HELP("  If <infobartime> is provided, the message will be sent to infobar.");
 150                         LOG_HELP("  Otherwise, it will just be sent as a centerprint message.");
 151                         LOG_HELP("Examples: adminmsg 2,4 \"this infomessage will last for ten seconds\" 10");
 152                         LOG_HELP("          adminmsg 2,5 \"this message will be a centerprint\"");
 153                         return;
 154                 }
 155         }
 156 }
 157
 158 void GameCommand_allready(int request)
 159 {
 160         switch (request)
 161         {
 162                 case CMD_REQUEST_COMMAND:
 163                 {
 164                         ReadyRestart();
 165                         return;
 166                 }
 167
 168                 default:
 169                 case CMD_REQUEST_USAGE:
 170                 {
 171                         LOG_HELP("Usage:^3 sv_cmd allready");
 172                         LOG_HELP("  No arguments required.");
 173                         return;
 174                 }
 175         }
 176 }
 177
 178 void GameCommand_allspec(int request, int argc)
 179 {
 180         switch (request)
 181         {
 182                 case CMD_REQUEST_COMMAND:
 183                 {
 184                         string reason = argv(1);
 185                         int n = 0;
 186                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 187                                 PutObserverInServer(it, true);
 188                                 ++n;
 189                         });
 190                         if (n)   bprint(strcat("Successfully forced all (", ftos(n), ") players to spectate", (reason ? strcat(" for reason: '", reason, "'") : ""), ".\n"));
 191                         else   LOG_INFO("No players found to spectate.");
 192                         return;
 193                 }
 194
 195                 default:
 196                 case CMD_REQUEST_USAGE:
 197                 {
 198                         LOG_HELP("Usage:^3 sv_cmd allspec [<reason>]");
 199                         LOG_HELP("  Where <reason> is an optional argument for explanation of allspec command.");
 200                         LOG_HELP("See also: ^2moveplayer, shuffleteams^7");
 201                         return;
 202                 }
 203         }
 204 }
 205
 206 void GameCommand_anticheat(int request, int argc)
 207 {
 208         switch (request)
 209         {
 210                 case CMD_REQUEST_COMMAND:
 211                 {
 212                         entity client = GetIndexedEntity(argc, 1);
 213                         float accepted = VerifyClientEntity(client, false, false);
 214
 215                         if (accepted > 0)
 216                         {
 217                                 anticheat_report_to_eventlog(client);
 218                                 return;
 219                         }
 220                         else
 221                         {
 222                                 LOG_INFO("anticheat: ", GetClientErrorString(accepted, argv(1)), ".");
 223                         }
 224                 }
 225
 226                 default:
 227                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 228                 case CMD_REQUEST_USAGE:
 229                 {
 230                         LOG_HELP("Usage:^3 sv_cmd anticheat <client>");
 231                         LOG_HELP("  <client> is the entity number or name of the player.");
 232                         return;
 233                 }
 234         }
 235 }
 236
 237 void GameCommand_bbox(int request)
 238 {
 239         switch (request)
 240         {
 241                 case CMD_REQUEST_COMMAND:
 242                 {
 243                         vector size_min = '0 0 0';
 244                         vector size_max = '0 0 0';
 245                         tracebox('1 0 0' * world.absmin.x,
 246                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 247                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 248                                 '1 0 0' * world.absmax.x,
 249                                 MOVE_WORLDONLY,
 250                                 NULL);
 251                         size_min.x = (trace_startsolid) ? world.absmin.x : trace_endpos.x;
 252
 253                         tracebox('0 1 0' * world.absmin.y,
 254                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 255                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 256                                 '0 1 0' * world.absmax.y,
 257                                 MOVE_WORLDONLY,
 258                                 NULL);
 259                         size_min.y = (trace_startsolid) ? world.absmin.y : trace_endpos.y;
 260
 261                         tracebox('0 0 1' * world.absmin.z,
 262                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 263                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 264                                 '0 0 1' * world.absmax.z,
 265                                 MOVE_WORLDONLY,
 266                                 NULL);
 267                         size_min.z = (trace_startsolid) ? world.absmin.z : trace_endpos.z;
 268
 269                         tracebox('1 0 0' * world.absmax.x,
 270                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 271                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 272                                 '1 0 0' * world.absmin.x,
 273                                 MOVE_WORLDONLY,
 274                                 NULL);
 275                         size_max.x = (trace_startsolid) ? world.absmax.x : trace_endpos.x;
 276
 277                         tracebox('0 1 0' * world.absmax.y,
 278                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 279                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 280                                 '0 1 0' * world.absmin.y,
 281                                 MOVE_WORLDONLY,
 282                                 NULL);
 283                         size_max.y = (trace_startsolid) ? world.absmax.y : trace_endpos.y;
 284
 285                         tracebox('0 0 1' * world.absmax.z,
 286                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 287                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 288                                 '0 0 1' * world.absmin.z,
 289                                 MOVE_WORLDONLY,
 290                                 NULL);
 291                         size_max.z = (trace_startsolid) ? world.absmax.z : trace_endpos.z;
 292
 293                         LOG_INFOF("Original size: %v %v", world.absmin, world.absmax);
 294                         LOG_INFOF("Currently set size: %v %v", world.mins, world.maxs);
 295                         LOG_INFOF("Solid bounding box size: %v %v", size_min, size_max);
 296                         return;
 297                 }
 298
 299                 default:
 300                 case CMD_REQUEST_USAGE:
 301                 {
 302                         LOG_HELP("Usage:^3 sv_cmd bbox");
 303                         LOG_HELP("  No arguments required.");
 304                         LOG_HELP("See also: ^2gettaginfo, trace^7");
 305                         return;
 306                 }
 307         }
 308 }
 309
 310 void GameCommand_bot_cmd(int request, int argc, string command)
 311 {
 312         switch (request)
 313         {
 314                 case CMD_REQUEST_COMMAND:
 315                 {
 316                         entity bot;
 317
 318                         if (argv(1) == "reset")
 319                         {
 320                                 bot_resetqueues();
 321                                 return;
 322                         }
 323                         else if (argv(1) == "setbots")
 324                         {
 325                                 cvar_settemp("bot_vs_human", "0");
 326                                 cvar_settemp("minplayers", "0");
 327                                 cvar_settemp("minplayers_per_team", "0");
 328                                 cvar_settemp("bot_number", "0");
 329                                 bot_fixcount();
 330                                 cvar_settemp("bot_number", argv(2));
 331                                 if (!bot_fixcount()) LOG_INFO("Sorry, could not set requested bot count");
 332                                 return;
 333                         }
 334                         else if (argv(1) == "load" && argc == 3)
 335                         {
 336                                 float fh, i;
 337                                 string s;
 338                                 fh = fopen(argv(2), FILE_READ);
 339                                 if (fh < 0)
 340                                 {
 341                                         LOG_INFO("cannot open the file");
 342                                         return;
 343                                 }
 344
 345                                 i = 0;
 346                                 while ((s = fgets(fh)))
 347                                 {
 348                                         argc = tokenize_console(s);
 349
 350                                         if (argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
 351                                         {
 352                                                 if (argv(2) == "reset")
 353                                                 {
 354                                                         bot_resetqueues();
 355                                                 }
 356                                                 else if (argv(2) == "setbots")
 357                                                 {
 358                                                         cvar_settemp("bot_vs_human", "0");
 359                                                         cvar_settemp("minplayers", "0");
 360                                                         cvar_settemp("minplayers_per_team", "0");
 361                                                         cvar_settemp("bot_number", "0");
 362                                                         bot_fixcount();
 363                                                         cvar_settemp("bot_number", argv(3));
 364                                                         if (!bot_fixcount()) LOG_INFO("Sorry, could not set requested bot count");
 365                                                 }
 366                                                 else
 367                                                 {
 368                                                         if(argv(2) == "*" || argv(2) == "all")
 369                                                                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 370                                                                         bot_queuecommand(it, substring(s, argv_start_index(3), -1));
 371                                                                 });
 372                                                         else
 373                                                         {
 374                                                                 bot = find_bot_by_number(stof(argv(2)));
 375                                                                 if (bot == NULL) bot = find_bot_by_name(argv(2));
 376                                                                 if (bot) bot_queuecommand(bot, substring(s, argv_start_index(3), -1));
 377                                                         }
 378                                                 }
 379                                         }
 380                                         else
 381                                         {
 382                                                 localcmd(strcat(s, "\n"));
 383                                         }
 384
 385                                         ++i;
 386                                 }
 387                                 LOG_INFO(ftos(i), " commands read");
 388                                 fclose(fh);
 389                                 return;
 390                         }
 391                         else if (argv(1) == "help")
 392                         {
 393                                 if (argv(2)) bot_cmdhelp(argv(2));
 394                                 else bot_list_commands();
 395                                 return;
 396                         }
 397                         else if (argc >= 3)  // this comes last
 398                         {
 399                                 if(argv(1) == "*" || argv(1) == "all")
 400                                 {
 401                                         int bot_num = 0;
 402                                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 403                                                 bot_queuecommand(it, substring(command, argv_start_index(2), -1));
 404                                                 bot_num++;
 405                                         });
 406                                         if(bot_num)
 407                                                 LOG_INFO("Command '", substring(command, argv_start_index(2), -1), "' sent to all bots (", ftos(bot_num), ")");
 408                                         return;
 409                                 }
 410                                 else
 411                                 {
 412                                         bot = find_bot_by_number(stof(argv(1)));
 413                                         if (bot == NULL) bot = find_bot_by_name(argv(1));
 414                                         if (bot)
 415                                         {
 416                                                 LOG_INFO("Command '", substring(command, argv_start_index(2), -1), "' sent to bot ", bot.netname);
 417                                                 bot_queuecommand(bot, substring(command, argv_start_index(2), -1));
 418                                                 return;
 419                                         }
 420                                         else
 421                                         {
 422                                                 LOG_INFO("Error: Can't find bot with the name or id '", argv(1), "' - Did you mistype the command?");  // don't return so that usage is shown
 423                                         }
 424                                 }
 425                         }
 426                 }
 427
 428                 default:
 429                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 430                 case CMD_REQUEST_USAGE:
 431                 {
 432                         LOG_HELP("Usage:^3 sv_cmd bot_cmd <client> <command> [<arguments>]");
 433                         LOG_HELP("  <client> can be either the name of the bot or a progressive number (not the entity number!)");
 434                         LOG_HELP("           can also be '*' or 'all' to allow sending the command to all the bots");
 435                         LOG_HELP("  For full list of commands, see bot_cmd help [<command>].");
 436                         LOG_HELP("Examples: sv_cmd bot_cmd 1 cc \"say something\"");
 437                         LOG_HELP("          sv_cmd bot_cmd 1 presskey jump");
 438                         LOG_HELP("          sv_cmd bot_cmd * pause");
 439                         return;
 440                 }
 441         }
 442 }
 443
 444 void GameCommand_cointoss(int request, int argc)
 445 {
 446         switch (request)
 447         {
 448                 case CMD_REQUEST_COMMAND:
 449                 {
 450                         string result1 = (argv(2) ? strcat("^7", argv(1)) : "^1HEADS");
 451                         string result2 = (argv(2) ? strcat("^7", argv(2)) : "^4TAILS");
 452                         string choice = ((random() > 0.5) ? result1 : result2);
 453
 454                         Send_Notification(NOTIF_ALL, NULL, MSG_MULTI, MULTI_COINTOSS, choice);
 455                         return;
 456                 }
 457
 458                 default:
 459                 case CMD_REQUEST_USAGE:
 460                 {
 461                         LOG_HELP("Usage:^3 sv_cmd cointoss [<result1> <result2>]");
 462                         LOG_HELP("  Where <result1> and <result2> are user created options.");
 463                         return;
 464                 }
 465         }
 466 }
 467
 468 void GameCommand_database(int request, int argc)
 469 {
 470         switch (request)
 471         {
 472                 case CMD_REQUEST_COMMAND:
 473                 {
 474                         if (argc == 3)
 475                         {
 476                                 if (argv(1) == "save")
 477                                 {
 478                                         db_save(ServerProgsDB, argv(2));
 479                                         LOG_INFO("Copied serverprogs database to '", argv(2), "' in the data directory.");
 480                                         return;
 481                                 }
 482                                 else if (argv(1) == "dump")
 483                                 {
 484                                         db_dump(ServerProgsDB, argv(2));
 485                                         LOG_INFO("DB dumped.");  // wtf does this do?
 486                                         return;
 487                                 }
 488                                 else if (argv(1) == "load")
 489                                 {
 490                                         db_close(ServerProgsDB);
 491                                         ServerProgsDB = db_load(argv(2));
 492                                         LOG_INFO("Loaded '", argv(2), "' as new serverprogs database.");
 493                                         return;
 494                                 }
 495                         }
 496                 }
 497
 498                 default:
 499                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 500                 case CMD_REQUEST_USAGE:
 501                 {
 502                         LOG_HELP("Usage:^3 sv_cmd database <action> <filename>");
 503                         LOG_HELP("  Where <action> is the command to complete,");
 504                         LOG_HELP("  and <filename> is what it acts upon.");
 505                         LOG_HELP("  Full list of commands here: save, dump, load.");
 506                         return;
 507                 }
 508         }
 509 }
 510
 511 void GameCommand_defer_clear(int request, int argc)
 512 {
 513         switch (request)
 514         {
 515                 case CMD_REQUEST_COMMAND:
 516                 {
 517                         entity client;
 518                         float accepted;
 519
 520                         if (argc >= 2)
 521                         {
 522                                 client = GetIndexedEntity(argc, 1);
 523                                 accepted = VerifyClientEntity(client, true, false);
 524
 525                                 if (accepted > 0)
 526                                 {
 527                                         stuffcmd(client, "defer clear\n");
 528                                         LOG_INFO("defer clear stuffed to ", playername(client.netname, client.team, false));
 529                                 }
 530                                 else { LOG_INFO("defer_clear: ", GetClientErrorString(accepted, argv(1)), "."); }
 531
 532                                 return;
 533                         }
 534                 }
 535
 536                 default:
 537                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 538                 case CMD_REQUEST_USAGE:
 539                 {
 540                         LOG_HELP("Usage:^3 sv_cmd defer_clear <client>");
 541                         LOG_HELP("  <client> is the entity number or name of the player.");
 542                         LOG_HELP("See also: ^2defer_clear_all^7");
 543                         return;
 544                 }
 545         }
 546 }
 547
 548 void GameCommand_defer_clear_all(int request)
 549 {
 550         switch (request)
 551         {
 552                 case CMD_REQUEST_COMMAND:
 553                 {
 554                         int n = 0;
 555                         int argc;
 556
 557                         FOREACH_CLIENT(true, {
 558                                 argc = tokenize_console(strcat("defer_clear ", ftos(etof(it))));
 559                                 GameCommand_defer_clear(CMD_REQUEST_COMMAND, argc);
 560                                 ++n;
 561                         });
 562                         if (n)   LOG_INFO("Successfully stuffed defer clear to all clients (", ftos(n), ")");  // should a message be added if no players were found?
 563                         return;
 564                 }
 565
 566                 default:
 567                 case CMD_REQUEST_USAGE:
 568                 {
 569                         LOG_HELP("Usage:^3 sv_cmd defer_clear_all");
 570                         LOG_HELP("  No arguments required.");
 571                         LOG_HELP("See also: ^2defer_clear^7");
 572                         return;
 573                 }
 574         }
 575 }
 576
 577 void GameCommand_delrec(int request, int argc)  // perhaps merge later with records and printstats and such?
 578 {
 579         switch (request)
 580         {
 581                 case CMD_REQUEST_COMMAND:
 582                 {
 583                         if (argv(1))
 584                         {
 585                                 if (argv(2)) race_deleteTime(argv(2), stof(argv(1)));
 586                                 else race_deleteTime(GetMapname(), stof(argv(1)));
 587                                 return;
 588                         }
 589                 }
 590
 591                 default:
 592                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 593                 case CMD_REQUEST_USAGE:
 594                 {
 595                         LOG_HELP("Usage:^3 sv_cmd delrec <ranking> [<map>]");
 596                         LOG_HELP("  <ranking> is which ranking level to clear up to, ");
 597                         LOG_HELP("  it will clear all records up to nth place.");
 598                         LOG_HELP("  if <map> is not provided it will use current map.");
 599                         return;
 600                 }
 601         }
 602 }
 603
 604 void print_Effect_Index(int d, string effect_name)
 605 {
 606         // this is inside a function to avoid expanding it on compilation everytime
 607         LOG_INFO("effect ", effect_name, " is ", ftos(_particleeffectnum(effect_name)), "\n");
 608         db_put(d, effect_name, "1");
 609 }
 610
 611 void GameCommand_effectindexdump(int request)
 612 {
 613         switch (request)
 614         {
 615                 case CMD_REQUEST_COMMAND:
 616                 {
 617                         float fh, d;
 618                         string s;
 619
 620                         d = db_create();
 621                         LOG_INFO("begin of effects list");
 622
 623                         print_Effect_Index(d, "TE_GUNSHOT");
 624                         print_Effect_Index(d, "TE_GUNSHOTQUAD");
 625                         print_Effect_Index(d, "TE_SPIKE");
 626                         print_Effect_Index(d, "TE_SPIKEQUAD");
 627                         print_Effect_Index(d, "TE_SUPERSPIKE");
 628                         print_Effect_Index(d, "TE_SUPERSPIKEQUAD");
 629                         print_Effect_Index(d, "TE_WIZSPIKE");
 630                         print_Effect_Index(d, "TE_KNIGHTSPIKE");
 631                         print_Effect_Index(d, "TE_EXPLOSION");
 632                         print_Effect_Index(d, "TE_EXPLOSIONQUAD");
 633                         print_Effect_Index(d, "TE_TAREXPLOSION");
 634                         print_Effect_Index(d, "TE_TELEPORT");
 635                         print_Effect_Index(d, "TE_LAVASPLASH");
 636                         print_Effect_Index(d, "TE_SMALLFLASH");
 637                         print_Effect_Index(d, "TE_FLAMEJET");
 638                         print_Effect_Index(d, "EF_FLAME");
 639                         print_Effect_Index(d, "TE_BLOOD");
 640                         print_Effect_Index(d, "TE_SPARK");
 641                         print_Effect_Index(d, "TE_PLASMABURN");
 642                         print_Effect_Index(d, "TE_TEI_G3");
 643                         print_Effect_Index(d, "TE_TEI_SMOKE");
 644                         print_Effect_Index(d, "TE_TEI_BIGEXPLOSION");
 645                         print_Effect_Index(d, "TE_TEI_PLASMAHIT");
 646                         print_Effect_Index(d, "EF_STARDUST");
 647                         print_Effect_Index(d, "TR_ROCKET");
 648                         print_Effect_Index(d, "TR_GRENADE");
 649                         print_Effect_Index(d, "TR_BLOOD");
 650                         print_Effect_Index(d, "TR_WIZSPIKE");
 651                         print_Effect_Index(d, "TR_SLIGHTBLOOD");
 652                         print_Effect_Index(d, "TR_KNIGHTSPIKE");
 653                         print_Effect_Index(d, "TR_VORESPIKE");
 654                         print_Effect_Index(d, "TR_NEHAHRASMOKE");
 655                         print_Effect_Index(d, "TR_NEXUIZPLASMA");
 656                         print_Effect_Index(d, "TR_GLOWTRAIL");
 657                         print_Effect_Index(d, "TR_SEEKER");
 658                         print_Effect_Index(d, "SVC_PARTICLE");
 659
 660                         fh = fopen("effectinfo.txt", FILE_READ);
 661                         while ((s = fgets(fh)))
 662                         {
 663                                 tokenize_console(s);
 664                                 if (argv(0) == "effect")
 665                                 {
 666                                         if (db_get(d, argv(1)) != "1")
 667                                         {
 668                                                 int i = _particleeffectnum(argv(1));
 669                                                 if (i >= 0) LOG_INFO("effect ", argv(1), " is ", ftos(i));
 670                                                 db_put(d, argv(1), "1");
 671                                         }
 672                                 }
 673                         }
 674                         LOG_INFO("end of effects list");
 675
 676                         db_close(d);
 677                         return;
 678                 }
 679
 680                 default:
 681                 case CMD_REQUEST_USAGE:
 682                 {
 683                         LOG_HELP("Usage:^3 sv_cmd effectindexdump");
 684                         LOG_HELP("  No arguments required.");
 685                         return;
 686                 }
 687         }
 688 }
 689
 690 void GameCommand_extendmatchtime(int request)
 691 {
 692         switch (request)
 693         {
 694                 case CMD_REQUEST_COMMAND:
 695                 {
 696                         changematchtime(autocvar_timelimit_increment * 60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
 697                         return;
 698                 }
 699
 700                 default:
 701                 case CMD_REQUEST_USAGE:
 702                 {
 703                         LOG_HELP("Usage:^3 sv_cmd extendmatchtime");
 704                         LOG_HELP("  No arguments required.");
 705                         LOG_HELP("See also: ^2reducematchtime^7");
 706                         return;
 707                 }
 708         }
 709 }
 710
 711 void GameCommand_gametype(int request, int argc)
 712 {
 713         switch (request)
 714         {
 715                 case CMD_REQUEST_COMMAND:
 716                 {
 717                         if (!world_initialized)
 718                         {
 719                                 LOG_INFOF("This command works only when the server is running.");
 720                                 return;
 721                         }
 722                         if (argv(1) != "")
 723                         {
 724                                 string s = argv(1);
 725                                 Gametype t = MapInfo_Type_FromString(s, false), tsave = MapInfo_CurrentGametype();
 726
 727                                 if (t)
 728                                 {
 729                                         MapInfo_SwitchGameType(t);
 730                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 731                                         if (MapInfo_count > 0)
 732                                         {
 733                                                 // update lsmaps in case the gametype changed, this way people can easily list maps for it
 734                                                 if (lsmaps_reply != "")   strunzone(lsmaps_reply);
 735                                                 lsmaps_reply = strzone(getlsmaps());
 736                                                 bprint("Game type successfully switched to ", s, "\n");
 737                                         }
 738                                         else
 739                                         {
 740                                                 bprint("Cannot use this game type: no map for it found\n");
 741                                                 MapInfo_SwitchGameType(tsave);
 742                                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 743                                         }
 744                                 }
 745                                 else
 746                                 {
 747                                         bprint("Failed to switch to ", s, ": this game type does not exist!\n");
 748                                 }
 749
 750                                 return;
 751                         }
 752                 }
 753
 754                 default:
 755                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 756                 case CMD_REQUEST_USAGE:
 757                 {
 758                         LOG_HELP("Usage:^3 sv_cmd gametype <mode>");
 759                         LOG_HELP("  Where <mode> is the gametype mode to switch to.");
 760                         LOG_HELP("See also: ^2gotomap^7");
 761                         return;
 762                 }
 763         }
 764 }
 765
 766 void GameCommand_gettaginfo(int request, int argc)
 767 {
 768         switch (request)
 769         {
 770                 case CMD_REQUEST_COMMAND:
 771                 {
 772                         entity tmp_entity;
 773                         float i;
 774                         vector v;
 775
 776                         if (argc >= 4)
 777                         {
 778                                 tmp_entity = spawn();
 779                                 if (argv(1) == "w")
 780                                 {
 781                                         .entity weaponentity = weaponentities[0];
 782                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
 783                                 }
 784                                 else
 785                                 {
 786                                         precache_model(argv(1));
 787                                         _setmodel(tmp_entity, argv(1));
 788                                 }
 789                                 tmp_entity.frame = stof(argv(2));
 790                                 if (substring(argv(3), 0, 1) == "#") i = stof(substring(argv(3), 1, -1));
 791                                 else i = gettagindex(tmp_entity, argv(3));
 792                                 if (i)
 793                                 {
 794                                         v = gettaginfo(tmp_entity, i);
 795                                         LOG_HELPF("model %s frame %s tag %s index %s parent %s",
 796                                                 tmp_entity.model, ftos(tmp_entity.frame), gettaginfo_name, ftos(i), ftos(gettaginfo_parent)
 797                                         );
 798                                         LOG_HELPF(" vector = %s %s %s", ftos(v.x), ftos(v.y), ftos(v.z));
 799                                         LOG_HELPF(" offset = %s %s %s", ftos(gettaginfo_offset.x), ftos(gettaginfo_offset.y), ftos(gettaginfo_offset.z));
 800                                         LOG_HELPF(" forward = %s %s %s", ftos(gettaginfo_forward.x), ftos(gettaginfo_forward.y), ftos(gettaginfo_forward.z));
 801                                         LOG_HELPF(" right = %s %s %s", ftos(gettaginfo_right.x), ftos(gettaginfo_right.y), ftos(gettaginfo_right.z));
 802                                         LOG_HELPF(" up = %s %s %s", ftos(gettaginfo_up.x), ftos(gettaginfo_up.y), ftos(gettaginfo_up.z));
 803                                         if (argc >= 6)
 804                                         {
 805                                                 v.y = -v.y;
 806                                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
 807                                         }
 808                                 }
 809                                 else
 810                                 {
 811                                         LOG_INFO("bone not found");
 812                                 }
 813
 814                                 delete(tmp_entity);
 815                                 return;
 816                         }
 817                 }
 818
 819                 default:
 820                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 821                 case CMD_REQUEST_USAGE:
 822                 {
 823                         LOG_HELP("Usage:^3 sv_cmd gettaginfo <model> <frame> <index> [<command1>] [<command2>]");
 824                         LOG_HELP("See also: ^2bbox, trace^7");
 825                         return;
 826                 }
 827         }
 828 }
 829
 830 void GameCommand_animbench(int request, int argc)
 831 {
 832         switch (request)
 833         {
 834                 case CMD_REQUEST_COMMAND:
 835                 {
 836                         entity tmp_entity;
 837
 838                         if (argc >= 4)
 839                         {
 840                                 tmp_entity = spawn();
 841                                 if (argv(1) == "w")
 842                                 {
 843                                         .entity weaponentity = weaponentities[0];
 844                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
 845                                 }
 846                                 else
 847                                 {
 848                                         precache_model(argv(1));
 849                                         _setmodel(tmp_entity, argv(1));
 850                                 }
 851                                 float f1 = stof(argv(2));
 852                                 float f2 = stof(argv(3));
 853                                 float t0;
 854                                 float t1 = 0;
 855                                 float t2 = 0;
 856                                 float n = 0;
 857
 858                                 while (t1 + t2 < 1)
 859                                 {
 860                                         tmp_entity.frame = f1;
 861                                         t0 = gettime(GETTIME_HIRES);
 862                                         getsurfacepoint(tmp_entity, 0, 0);
 863                                         t1 += gettime(GETTIME_HIRES) - t0;
 864                                         tmp_entity.frame = f2;
 865                                         t0 = gettime(GETTIME_HIRES);
 866                                         getsurfacepoint(tmp_entity, 0, 0);
 867                                         t2 += gettime(GETTIME_HIRES) - t0;
 868                                         n += 1;
 869                                 }
 870                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f1), " animtime ", ftos(n / t1), "/s");
 871                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f2), " animtime ", ftos(n / t2), "/s");
 872
 873                                 delete(tmp_entity);
 874                                 return;
 875                         }
 876                 }
 877
 878                 default:
 879                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 880                 case CMD_REQUEST_USAGE:
 881                 {
 882                         LOG_HELP("Usage:^3 sv_cmd animbench <model> <frame1> <frame2>");
 883                         LOG_HELP("See also: ^2bbox, trace^7");
 884                         return;
 885                 }
 886         }
 887 }
 888
 889 void GameCommand_gotomap(int request, int argc)
 890 {
 891         switch (request)
 892         {
 893                 case CMD_REQUEST_COMMAND:
 894                 {
 895                         if (!world_initialized)
 896                         {
 897                                 LOG_INFOF("This command works only when the server is running.");
 898                                 return;
 899                         }
 900                         if (argv(1))
 901                         {
 902                                 LOG_INFO(GotoMap(argv(1)));
 903                                 return;
 904                         }
 905                 }
 906
 907                 default:
 908                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 909                 case CMD_REQUEST_USAGE:
 910                 {
 911                         LOG_HELP("Usage:^3 sv_cmd gotomap <map>");
 912                         LOG_HELP("  Where <map> is the *.bsp file to change to.");
 913                         LOG_HELP("See also: ^2gametype^7");
 914                         return;
 915                 }
 916         }
 917 }
 918
 919 void GameCommand_lockteams(int request)
 920 {
 921         switch (request)
 922         {
 923                 case CMD_REQUEST_COMMAND:
 924                 {
 925                         if (teamplay)
 926                         {
 927                                 lockteams = 1;
 928                                 bprint("^1The teams are now locked.\n");
 929                         }
 930                         else
 931                         {
 932                                 bprint("lockteams command can only be used in a team-based gamemode.\n");
 933                         }
 934                         return;
 935                 }
 936
 937                 default:
 938                 case CMD_REQUEST_USAGE:
 939                 {
 940                         LOG_HELP("Usage:^3 sv_cmd lockteams");
 941                         LOG_HELP("  No arguments required.");
 942                         LOG_HELP("See also: ^2unlockteams^7");
 943                         return;
 944                 }
 945         }
 946 }
 947
 948 void GameCommand_make_mapinfo(int request)
 949 {
 950         switch (request)
 951         {
 952                 case CMD_REQUEST_COMMAND:
 953                 {
 954                         entity tmp_entity;
 955
 956                         tmp_entity = new(make_mapinfo);
 957                         setthink(tmp_entity, make_mapinfo_Think);
 958                         tmp_entity.nextthink = time;
 959                         MapInfo_Enumerate();
 960                         return;
 961                 }
 962
 963                 default:
 964                 case CMD_REQUEST_USAGE:
 965                 {
 966                         LOG_HELP("Usage:^3 sv_cmd make_mapinfo");
 967                         LOG_HELP("  No arguments required.");
 968                         LOG_HELP("See also: ^2radarmap^7");
 969                         return;
 970                 }
 971         }
 972 }
 973
 974 void GameCommand_moveplayer(int request, int argc)
 975 {
 976         switch (request)
 977         {
 978                 case CMD_REQUEST_COMMAND:
 979                 {
 980                         float accepted;
 981                         entity client;
 982
 983                         string targets = strreplace(",", " ", argv(1));
 984                         string original_targets = strreplace(" ", ", ", targets);
 985                         string destination = argv(2);
 986                         if (destination == "spec")
 987                                 destination = "spectator";
 988
 989                         if ((targets) && (destination))
 990                         {
 991                                 string successful = string_null;
 992                                 string t;
 993                                 for ( ; targets; )
 994                                 {
 995                                         t = car(targets);
 996                                         targets = cdr(targets);
 997
 998                                         // Check to see if the player is a valid target
 999                                         client = GetFilteredEntity(t);
1000                                         accepted = VerifyClientEntity(client, false, false);
1001
1002                                         if (accepted <= 0)
1003                                         {
1004                                                 LOG_INFO("moveplayer: ", GetClientErrorString(accepted, t), ".");
1005                                         }
1006                                         else if (destination == "spectator")
1007                                         {
1008                                                 string pl_name = playername(client.netname, client.team, false);
1009                                                 if (!IS_SPEC(client) && !IS_OBSERVER(client))
1010                                                 {
1011                                                         PutObserverInServer(client, true);
1012
1013                                                         successful = strcat(successful, (successful ? ", " : ""), pl_name);
1014                                                 }
1015                                                 else
1016                                                 {
1017                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", pl_name, ") is already spectating.");
1018                                                 }
1019                                         }
1020                                         else
1021                                         {
1022                                                 if (!teamplay)
1023                                                 {
1024                                                         LOG_INFO("Can't change teams when currently not playing a team game.");
1025                                                         return;
1026                                                 }
1027
1028                                                 string pl_name = playername(client.netname, client.team, false);
1029                                                 if (IS_SPEC(client) || IS_OBSERVER(client))
1030                                                 {
1031                                                         // well technically we could, but should we allow that? :P
1032                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", pl_name, ") is not in the game.");
1033                                                         continue;
1034                                                 }
1035
1036                                                 // set up
1037                                                 int save = Player_GetForcedTeamIndex(client);
1038                                                 Player_SetForcedTeamIndex(client, TEAM_FORCE_DEFAULT);
1039
1040                                                 // find the team to move the player to
1041                                                 int team_num = Team_ColorToTeam(destination);
1042                                                 entity balance;
1043                                                 if (team_num == client.team)  // already on the destination team
1044                                                 {
1045                                                         // keep the forcing undone
1046                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", pl_name, ") is already on the ", Team_ColoredFullName(team_num), "^7.");
1047                                                         continue;
1048                                                 }
1049                                                 else if (team_num == 0)  // auto team
1050                                                 {
1051                                                         balance = TeamBalance_CheckAllowedTeams(client);
1052                                                         team_num = Team_IndexToTeam(TeamBalance_FindBestTeam(balance, client, false));
1053                                                 }
1054                                                 else
1055                                                 {
1056                                                         balance = TeamBalance_CheckAllowedTeams(client);
1057                                                 }
1058                                                 Player_SetForcedTeamIndex(client, save);
1059
1060                                                 // Check to see if the destination team is even available
1061                                                 int team_id = Team_TeamToIndex(team_num);
1062                                                 if (team_id == -1)
1063                                                 {
1064                                                         LOG_INFO("Can't move player to ", destination, " team because it doesn't exist.");
1065                                                         TeamBalance_Destroy(balance);
1066                                                         return;
1067                                                 }
1068                                                 if (!IsTeamAvailable(team_num))
1069                                                 {
1070                                                         LOG_INFO("Can't move player to ", destination, " team because it isn't available.");
1071                                                         TeamBalance_Destroy(balance);
1072                                                         return;
1073                                                 }
1074                                                 if (!TeamBalance_IsTeamAllowed(balance, team_id))
1075                                                 {
1076                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", pl_name, ") is not allowed to join the ", Team_ColoredFullName(team_num), "^7.");
1077                                                         TeamBalance_Destroy(balance);
1078                                                         continue;
1079                                                 }
1080                                                 TeamBalance_Destroy(balance);
1081
1082                                                 // If so, lets continue and finally move the player
1083                                                 Player_SetForcedTeamIndex(client, TEAM_FORCE_DEFAULT);
1084                                                 if (MoveToTeam(client, team_id, 6))
1085                                                 {
1086                                                         successful = strcat(successful, (successful ? ", " : ""), pl_name);
1087                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", pl_name, ") has been moved to the ", Team_ColoredFullName(team_num), "^7.");
1088                                                 }
1089                                                 else
1090                                                 {
1091                                                         LOG_INFO("Unable to move player ", ftos(GetFilteredNumber(t)), " (", pl_name, ")");
1092                                                 }
1093                                         }
1094                                 } // loop end
1095
1096                                 if (successful) bprint("Successfully moved players ", successful, " to destination ", destination, ".\n");
1097                                 else LOG_INFO("No players given (", original_targets, ") are able to move.");
1098
1099                                 return;  // still correct parameters so return to avoid usage print
1100                         }
1101                 }
1102
1103                 default:
1104                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1105                 case CMD_REQUEST_USAGE:
1106                 {
1107                         LOG_HELP("Usage:^3 sv_cmd moveplayer <clients> <destination>");
1108                         LOG_HELP("  <clients> is a list (separated by commas) of player entity ID's or nicknames");
1109                         LOG_HELP("  <destination> is what to send the player to, be it team or spectating");
1110                         LOG_HELP("  Full list of destinations here: spec, spectator, red, blue, yellow, pink, auto.");
1111                         LOG_HELP("Examples: sv_cmd moveplayer 1,3,5 red");
1112                         LOG_HELP("          sv_cmd moveplayer 2 spec");
1113                         LOG_HELP("See also: ^2allspec, shuffleteams^7");
1114                         return;
1115                 }
1116         }
1117 }
1118
1119 void GameCommand_nospectators(int request)
1120 {
1121         switch (request)
1122         {
1123                 case CMD_REQUEST_COMMAND:
1124                 {
1125                         blockSpectators = 1;
1126                         // give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
1127                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_SPEC(it) || IS_OBSERVER(it)) && !it.caplayer, {
1128                                 if(!it.caplayer)
1129                                 {
1130                                         CS(it).spectatortime = time;
1131                                         Send_Notification(NOTIF_ONE_ONLY, it, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1132                                 }
1133                         });
1134                         bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
1135                         return;
1136                 }
1137
1138                 default:
1139                 case CMD_REQUEST_USAGE:
1140                 {
1141                         LOG_HELP("Usage:^3 sv_cmd nospectators");
1142                         LOG_HELP("  No arguments required.");
1143                         return;
1144                 }
1145         }
1146 }
1147
1148 void GameCommand_printstats(int request)
1149 {
1150         switch (request)
1151         {
1152                 case CMD_REQUEST_COMMAND:
1153                 {
1154                         DumpStats(false);
1155                         LOG_INFO("stats dumped.");
1156                         return;
1157                 }
1158
1159                 default:
1160                 case CMD_REQUEST_USAGE:
1161                 {
1162                         LOG_HELP("Usage:^3 sv_cmd printstats");
1163                         LOG_HELP("  No arguments required.");
1164                         return;
1165                 }
1166         }
1167 }
1168
1169 void GameCommand_radarmap(int request, int argc)
1170 {
1171         switch (request)
1172         {
1173                 case CMD_REQUEST_COMMAND:
1174                 {
1175                         if (RadarMap_Make(argc)) return;
1176                 }
1177
1178                 default:
1179                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1180                 case CMD_REQUEST_USAGE:
1181                 {
1182                         LOG_HELP("Usage:^3 sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]");
1183                         LOG_HELP("  The quality factor Q is roughly proportional to the time taken.");
1184                         LOG_HELP("  trace supports no quality factor; its result should look like --block with infinite quality factor.");
1185                         LOG_HELP("See also: ^2make_mapinfo^7");
1186                         return;
1187                 }
1188         }
1189 }
1190
1191 void GameCommand_reducematchtime(int request)
1192 {
1193         switch (request)
1194         {
1195                 case CMD_REQUEST_COMMAND:
1196                 {
1197                         changematchtime(autocvar_timelimit_decrement * -60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
1198                         return;
1199                 }
1200
1201                 default:
1202                 case CMD_REQUEST_USAGE:
1203                 {
1204                         LOG_HELP("Usage:^3 sv_cmd reducematchtime");
1205                         LOG_HELP("  No arguments required.");
1206                         LOG_HELP("See also: ^2extendmatchtime^7");
1207                         return;
1208                 }
1209         }
1210 }
1211
1212 void GameCommand_setbots(int request, int argc)
1213 {
1214         switch (request)
1215         {
1216                 case CMD_REQUEST_COMMAND:
1217                 {
1218                         if (argc >= 2)
1219                         {
1220                                 cvar_settemp("minplayers", "0");
1221                                 cvar_settemp("minplayers_per_team", "0");
1222                                 cvar_settemp("bot_number", argv(1));
1223                                 bot_fixcount();
1224                                 return;
1225                         }
1226                 }
1227
1228                 default:
1229                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1230                 case CMD_REQUEST_USAGE:
1231                 {
1232                         LOG_HELP("Usage:^3 sv_cmd setbots <botnumber>");
1233                         LOG_HELP("  Where <botnumber> is the amount of bots to set bot_number cvar to.");
1234                         LOG_HELP("See also: ^2bot_cmd^7");
1235                         return;
1236                 }
1237         }
1238 }
1239
1240 void shuffleteams()
1241 {
1242         if (!teamplay)
1243         {
1244                 LOG_INFO("Can't shuffle teams when currently not playing a team game.");
1245                 return;
1246         }
1247
1248         FOREACH_CLIENT(IS_PLAYER(it) || it.caplayer, {
1249                 if (Player_HasRealForcedTeam(it)) {
1250                         // we could theoretically assign forced players to their teams
1251                         // and shuffle the rest to fill the empty spots but in practise
1252                         // either all players or none are gonna have forced teams
1253                         LOG_INFO("Can't shuffle teams because at least one player has a forced team.");
1254                         return;
1255                 }
1256         });
1257
1258         int number_of_teams = 0;
1259         entity balance = TeamBalance_CheckAllowedTeams(NULL);
1260         for (int i = 1; i <= NUM_TEAMS; ++i)
1261         {
1262                 if (TeamBalance_IsTeamAllowed(balance, i))
1263                 {
1264                         number_of_teams = max(i, number_of_teams);
1265                 }
1266         }
1267         TeamBalance_Destroy(balance);
1268
1269         int team_index = 0;
1270         FOREACH_CLIENT_RANDOM(IS_PLAYER(it) || it.caplayer, {
1271                 int target_team_index = team_index + 1;
1272                 if (Entity_GetTeamIndex(it) != target_team_index)
1273                 {
1274                         MoveToTeam(it, target_team_index, 6);
1275                 }
1276                 team_index = (team_index + 1) % number_of_teams;
1277         });
1278
1279         bprint("Successfully shuffled the players around randomly.\n");
1280 }
1281
1282 void GameCommand_shuffleteams(int request)
1283 {
1284         switch (request)
1285         {
1286                 case CMD_REQUEST_COMMAND:
1287                 {
1288                         if (shuffleteams_on_reset_map)
1289                         {
1290                                 bprint("Players will be shuffled when this round is over.\n");
1291                                 shuffleteams_on_reset_map = true;
1292                         }
1293                         else
1294                                 shuffleteams();
1295                         return;
1296                 }
1297
1298                 default:
1299                 case CMD_REQUEST_USAGE:
1300                 {
1301                         LOG_HELP("Usage:^3 sv_cmd shuffleteams");
1302                         LOG_HELP("  No arguments required.");
1303                         LOG_HELP("See also: ^2moveplayer, allspec^7");
1304                         return;
1305                 }
1306         }
1307 }
1308
1309 void GameCommand_stuffto(int request, int argc)
1310 {
1311         // This... is a fairly dangerous and powerful command... - It allows any arguments to be sent to a client via rcon.
1312         // Because of this, it is disabled by default and must be enabled by the server owner when doing compilation. That way,
1313         // we can be certain they understand the risks of it... So to enable, compile server with -DSTUFFTO_ENABLED argument.
1314
1315 #ifdef STUFFTO_ENABLED
1316                 switch (request)
1317                 {
1318                         case CMD_REQUEST_COMMAND:
1319                         {
1320                                 if (argv(2))
1321                                 {
1322                                         entity client = GetIndexedEntity(argc, 1);
1323                                         float accepted = VerifyClientEntity(client, true, false);
1324
1325                                         if (accepted > 0)
1326                                         {
1327                                                 stuffcmd(client, strcat("\n", argv(next_token), "\n"));
1328                                                 LOG_INFO("Command: \"", argv(next_token), "\" sent to ", GetCallerName(client), " (", argv(1), ").");
1329                                         }
1330                                         else
1331                                         {
1332                                                 LOG_INFO("stuffto: ", GetClientErrorString(accepted, argv(1)), ".");
1333                                         }
1334
1335                                         return;
1336                                 }
1337                         }
1338
1339                         default:
1340                                 LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1341                         case CMD_REQUEST_USAGE:
1342                         {
1343                                 LOG_HELP("Usage:^3 sv_cmd stuffto <client> \"<command>\"");
1344                                 LOG_HELP("  <client> is the entity number or name of the player,");
1345                                 LOG_HELP("  and <command> is the command to be sent to that player.");
1346                                 return;
1347                         }
1348                 }
1349 #else
1350                 if (request)
1351                 {
1352                         LOG_HELP("stuffto command is not enabled on this server.");
1353                         return;
1354                 }
1355 #endif
1356 }
1357
1358 void GameCommand_trace(int request, int argc)
1359 {
1360         switch (request)
1361         {
1362                 case CMD_REQUEST_COMMAND:
1363                 {
1364                         entity e;
1365                         vector org, delta, start, end, p, q, q0, pos, vv, dv;
1366                         float i, f, safe, unsafe, dq, dqf;
1367
1368                         switch (argv(1))
1369                         {
1370                                 case "debug":
1371                                 {
1372                                         float hitcount = 0;
1373                                         LOG_INFO("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.");
1374                                         float worst_endpos_bug = 0;
1375                                         for ( ; ; )
1376                                         {
1377                                                 org = world.mins;
1378                                                 delta = world.maxs - world.mins;
1379
1380                                                 start.x = org.x + random() * delta.x;
1381                                                 start.y = org.y + random() * delta.y;
1382                                                 start.z = org.z + random() * delta.z;
1383
1384                                                 end.x = org.x + random() * delta.x;
1385                                                 end.y = org.y + random() * delta.y;
1386                                                 end.z = org.z + random() * delta.z;
1387
1388                                                 start = stov(vtos(start));
1389                                                 end = stov(vtos(end));
1390
1391                                                 tracebox(start, PL_MIN_CONST, PL_MAX_CONST, end, MOVE_NOMONSTERS, NULL);
1392                                                 if (!trace_startsolid && trace_fraction < 1)
1393                                                 {
1394                                                         p = trace_endpos;
1395                                                         tracebox(p, PL_MIN_CONST, PL_MAX_CONST, p, MOVE_NOMONSTERS, NULL);
1396                                                         if (trace_startsolid)
1397                                                         {
1398                                                                 rint(42);  // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
1399                                                                 tracebox(start, PL_MIN_CONST, PL_MAX_CONST, end, MOVE_NOMONSTERS, NULL);
1400
1401                                                                 // how much do we need to back off?
1402                                                                 safe = 1;
1403                                                                 unsafe = 0;
1404                                                                 for ( ; ; )
1405                                                                 {
1406                                                                         pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
1407                                                                         tracebox(pos, PL_MIN_CONST, PL_MAX_CONST, pos, MOVE_NOMONSTERS, NULL);
1408                                                                         if (trace_startsolid)
1409                                                                         {
1410                                                                                 if ((safe + unsafe) * 0.5 == unsafe) break;
1411                                                                                 unsafe = (safe + unsafe) * 0.5;
1412                                                                         }
1413                                                                         else
1414                                                                         {
1415                                                                                 if ((safe + unsafe) * 0.5 == safe) break;
1416                                                                                 safe = (safe + unsafe) * 0.5;
1417                                                                         }
1418                                                                 }
1419
1420                                                                 LOG_INFO("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu");
1421                                                                 LOG_INFO("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu");
1422
1423                                                                 tracebox(p, PL_MIN_CONST + '0.1 0.1 0.1', PL_MAX_CONST - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, NULL);
1424                                                                 if (trace_startsolid) LOG_INFO("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1425                                                                 else LOG_INFO("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1426                                                                 if (++hitcount >= 10) break;
1427                                                         }
1428                                                         else
1429                                                         {
1430                                                                 q0 = p;
1431                                                                 dq = 0;
1432                                                                 dqf = 1;
1433                                                                 for ( ; ; )
1434                                                                 {
1435                                                                         q = p + normalize(end - p) * (dq + dqf);
1436                                                                         if (q == q0) break;
1437                                                                         tracebox(p, PL_MIN_CONST, PL_MAX_CONST, q, MOVE_NOMONSTERS, NULL);
1438                                                                         if (trace_startsolid) error("THIS ONE cannot happen");
1439                                                                         if (trace_fraction > 0) dq += dqf * trace_fraction;
1440                                                                         dqf *= 0.5;
1441                                                                         q0 = q;
1442                                                                 }
1443                                                                 if (dq > worst_endpos_bug)
1444                                                                 {
1445                                                                         worst_endpos_bug = dq;
1446                                                                         LOG_INFO("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1447                                                                         LOG_INFO("could go ", ftos(dq), " units further to ", vtos(q));
1448                                                                         if (++hitcount >= 10) break;
1449                                                                 }
1450                                                         }
1451                                                 }
1452                                         }
1453                                         return;
1454                                 }
1455
1456                                 case "debug2":
1457                                 {
1458                                         e = nextent(NULL);
1459                                         tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
1460                                         vv = trace_endpos;
1461                                         if (trace_fraction == 1)
1462                                         {
1463                                                 LOG_INFO("not above ground, aborting");
1464                                                 return;
1465                                         }
1466                                         f = 0;
1467                                         for (i = 0; i < 100000; ++i)
1468                                         {
1469                                                 dv = randomvec();
1470                                                 if (dv.z > 0) dv = -1 * dv;
1471                                                 tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
1472                                                 if (trace_startsolid) LOG_INFO("bug 1");
1473                                                 if (trace_fraction == 1)
1474                                                 {
1475                                                         if (dv.z < f)
1476                                                         {
1477                                                                 LOG_INFO("bug 2: ", ftos(dv.x), " ", ftos(dv.y), " ", ftos(dv.z));
1478                                                                 LOG_INFO(" (", ftos(asin(dv.z / vlen(dv)) * 180 / M_PI), " degrees)");
1479                                                                 f = dv.z;
1480                                                         }
1481                                                 }
1482                                         }
1483                                         LOG_INFO("highest possible dist: ", ftos(f));
1484                                         return;
1485                                 }
1486
1487                                 case "walk":
1488                                 {
1489                                         if (argc == 4 || argc == 5)
1490                                         {
1491                                                 e = nextent(NULL);
1492                                                 int dphitcontentsmask_save = e.dphitcontentsmask;
1493                                                 e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
1494                                                 if (tracewalk(e, stov(argv(2)), e.mins, e.maxs, stov(argv(3)), stof(argv(4)), MOVE_NORMAL))
1495                                                         LOG_INFO("can walk");
1496                                                 else
1497                                                         LOG_INFO("cannot walk");
1498                                                 e.dphitcontentsmask = dphitcontentsmask_save;
1499                                                 return;
1500                                         }
1501                                 }
1502
1503                                 case "showline":
1504                                 {
1505                                         if (argc == 4)
1506                                         {
1507                                                 vv = stov(argv(2));
1508                                                 dv = stov(argv(3));
1509                                                 traceline(vv, dv, MOVE_NORMAL, NULL);
1510                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_NEXUIZPLASMA), vv, trace_endpos);
1511                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_CRYLINKPLASMA), trace_endpos, dv);
1512                                                 return;
1513                                         }
1514                                 }
1515
1516                                 // no default case, just go straight to invalid
1517                         }
1518                 }
1519
1520                 default:
1521                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1522                 case CMD_REQUEST_USAGE:
1523                 {
1524                         LOG_HELP("Usage:^3 sv_cmd trace <command> [<startpos> <endpos>] [<endpos_height>]");
1525                         LOG_HELP("  Where <startpos> and <endpos> are parameters for the 'walk' and 'showline' commands,");
1526                         LOG_HELP("  <endpos_height> is an optional parameter for the 'walk' command,");
1527                         LOG_HELP("  Full list of commands here: debug, debug2, walk, showline.");
1528                         LOG_HELP("See also: ^2bbox, gettaginfo^7");
1529                         return;
1530                 }
1531         }
1532 }
1533
1534 void GameCommand_unlockteams(int request)
1535 {
1536         switch (request)
1537         {
1538                 case CMD_REQUEST_COMMAND:
1539                 {
1540                         if (teamplay)
1541                         {
1542                                 lockteams = 0;
1543                                 bprint("^1The teams are now unlocked.\n");
1544                         }
1545                         else
1546                         {
1547                                 bprint("unlockteams command can only be used in a team-based gamemode.\n");
1548                         }
1549                         return;
1550                 }
1551
1552                 default:
1553                 case CMD_REQUEST_USAGE:
1554                 {
1555                         LOG_HELP("Usage:^3 sv_cmd unlockteams");
1556                         LOG_HELP("  No arguments required.");
1557                         LOG_HELP("See also: ^2lockteams^7");
1558                         return;
1559                 }
1560         }
1561 }
1562
1563 void GameCommand_warp(int request, int argc)
1564 {
1565         switch (request)
1566         {
1567                 case CMD_REQUEST_COMMAND:
1568                 {
1569                         if (autocvar_g_campaign)
1570                         {
1571                                 if (argc >= 2)
1572                                 {
1573                                         CampaignLevelWarp(stof(argv(1)));
1574                                         LOG_INFO("Successfully warped to campaign level ", argv(1), ".");
1575                                 }
1576                                 else
1577                                 {
1578                                         CampaignLevelWarp(-1);
1579                                         LOG_INFO("Successfully warped to next campaign level.");
1580                                 }
1581                         }
1582                         else
1583                         {
1584                                 LOG_INFO("Not in campaign, can't level warp");
1585                         }
1586                         return;
1587                 }
1588
1589                 default:
1590                 case CMD_REQUEST_USAGE:
1591                 {
1592                         LOG_HELP("Usage:^3 sv_cmd warp [<level>]");
1593                         LOG_HELP("  <level> is the level to change campaign mode to.");
1594                         LOG_HELP("  if <level> is not provided it will change to the next level.");
1595                         return;
1596                 }
1597         }
1598 }
1599
1600 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1601 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1602 void GameCommand_(int request)
1603 {
1604     switch(request)
1605     {
1606         case CMD_REQUEST_COMMAND:
1607         {
1608
1609             return;
1610         }
1611
1612         default:
1613         case CMD_REQUEST_USAGE:
1614         {
1615             LOG_HELP("Usage:^3 sv_cmd ");
1616             LOG_HELP("  No arguments required.");
1617             return;
1618         }
1619     }
1620 }
1621 */
1622
1623
1624 // ==================================
1625 //  Macro system for server commands
1626 // ==================================
1627
1628 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1629 SERVER_COMMAND(adminmsg, "Send an admin message to a client directly") { GameCommand_adminmsg(request, arguments); }
1630 SERVER_COMMAND(allready, "Restart the server and reset the players") { GameCommand_allready(request); }
1631 SERVER_COMMAND(allspec, "Force all players to spectate") { GameCommand_allspec(request, arguments); }
1632 SERVER_COMMAND(anticheat, "Create an anticheat report for a client") { GameCommand_anticheat(request, arguments); }
1633 SERVER_COMMAND(animbench, "Benchmark model animation (LAGS)") { GameCommand_animbench(request, arguments); }
1634 SERVER_COMMAND(bbox, "Print detailed information about world size") { GameCommand_bbox(request); }
1635 SERVER_COMMAND(bot_cmd, "Control and send commands to bots") { GameCommand_bot_cmd(request, arguments, command); }
1636 SERVER_COMMAND(cointoss, "Flip a virtual coin and give random result") { GameCommand_cointoss(request, arguments); }
1637 SERVER_COMMAND(database, "Extra controls of the serverprogs database") { GameCommand_database(request, arguments); }
1638 SERVER_COMMAND(defer_clear, "Clear all queued defer commands for a specific client") { GameCommand_defer_clear(request, arguments); }
1639 SERVER_COMMAND(defer_clear_all, "Clear all queued defer commands for all clients") { GameCommand_defer_clear_all(request); }
1640 SERVER_COMMAND(delrec, "Delete race time record for a map") { GameCommand_delrec(request, arguments); }
1641 SERVER_COMMAND(effectindexdump, "Dump list of effects from code and effectinfo.txt") { GameCommand_effectindexdump(request); }
1642 SERVER_COMMAND(extendmatchtime, "Increase the timelimit value incrementally") { GameCommand_extendmatchtime(request); }
1643 SERVER_COMMAND(gametype, "Simple command to change the active gametype") { GameCommand_gametype(request, arguments); }
1644 SERVER_COMMAND(gettaginfo, "Get specific information about a weapon model") { GameCommand_gettaginfo(request, arguments); }
1645 SERVER_COMMAND(gotomap, "Simple command to switch to another map") { GameCommand_gotomap(request, arguments); }
1646 SERVER_COMMAND(lockteams, "Disable the ability for players to switch or enter teams") { GameCommand_lockteams(request); }
1647 SERVER_COMMAND(make_mapinfo, "Automatically rebuild mapinfo files") { GameCommand_make_mapinfo(request); }
1648 SERVER_COMMAND(moveplayer, "Change the team/status of a player") { GameCommand_moveplayer(request, arguments); }
1649 SERVER_COMMAND(nospectators, "Automatically remove spectators from a match") { GameCommand_nospectators(request); }
1650 SERVER_COMMAND(printstats, "Dump eventlog player stats and other score information") { GameCommand_printstats(request); }
1651 SERVER_COMMAND(radarmap, "Generate a radar image of the map") { GameCommand_radarmap(request, arguments); }
1652 SERVER_COMMAND(reducematchtime, "Decrease the timelimit value incrementally") { GameCommand_reducematchtime(request); }
1653 SERVER_COMMAND(setbots, "Adjust how many bots are in the match") { GameCommand_setbots(request, arguments); }
1654 SERVER_COMMAND(shuffleteams, "Randomly move players to different teams") { GameCommand_shuffleteams(request); }
1655 SERVER_COMMAND(stuffto, "Send a command to be executed on a client") { GameCommand_stuffto(request, arguments); }
1656 SERVER_COMMAND(trace, "Various debugging tools with tracing") { GameCommand_trace(request, arguments); }
1657 SERVER_COMMAND(unlockteams, "Enable the ability for players to switch or enter teams") { GameCommand_unlockteams(request); }
1658 SERVER_COMMAND(warp, "Choose different level in campaign") { GameCommand_warp(request, arguments); }
1659
1660 void GameCommand_macro_help()
1661 {
1662         FOREACH(SERVER_COMMANDS, true, { LOG_HELPF("  ^2%s^7: %s", it.m_name, it.m_description); });
1663 }
1664
1665 float GameCommand_macro_command(int argc, string command)
1666 {
1667         string c = strtolower(argv(0));
1668         FOREACH(SERVER_COMMANDS, it.m_name == c, {
1669                 it.m_invokecmd(it, CMD_REQUEST_COMMAND, NULL, argc, command);
1670                 return true;
1671         });
1672         return false;
1673 }
1674
1675 float GameCommand_macro_usage(int argc)
1676 {
1677         string c = strtolower(argv(1));
1678         FOREACH(SERVER_COMMANDS, it.m_name == c, {
1679                 it.m_invokecmd(it, CMD_REQUEST_USAGE, NULL, argc, "");
1680                 return true;
1681         });
1682         return false;
1683 }
1684
1685 void GameCommand_macro_write_aliases(float fh)
1686 {
1687         FOREACH(SERVER_COMMANDS, true, { CMD_Write_Alias("qc_cmd_sv", it.m_name, it.m_description); });
1688 }
1689
1690
1691 // =========================================
1692 //  Main Function Called By Engine (sv_cmd)
1693 // =========================================
1694 // If this function exists, game code handles gamecommand instead of the engine code.
1695
1696 void GameCommand(string command)
1697 {
1698         int argc = tokenize_console(command);
1699
1700         // Guide for working with argc arguments by example:
1701         // argc:   1    - 2      - 3     - 4
1702         // argv:   0    - 1      - 2     - 3
1703         // cmd     vote - master - login - password
1704
1705         if (strtolower(argv(0)) == "help")
1706         {
1707                 if (argc == 1)
1708                 {
1709                         LOG_HELP("Server console commands:");
1710                         GameCommand_macro_help();
1711
1712                         LOG_HELP("\nBanning commands:");
1713                         BanCommand_macro_help();
1714
1715                         LOG_HELP("\nCommon networked commands:");
1716                         CommonCommand_macro_help(NULL);
1717
1718                         LOG_HELP("\nGeneric commands shared by all programs:");
1719                         GenericCommand_macro_help();
1720
1721                         LOG_HELP("\nUsage:^3 sv_cmd <command>^7, where possible commands are listed above.\n"
1722                                 "For help about a specific command, type sv_cmd help <command>");
1723
1724                         return;
1725                 }
1726                 else if (BanCommand_macro_usage(argc))  // Instead of trying to call a command, we're going to see detailed information about it
1727                 {
1728                         return;
1729                 }
1730                 else if (CommonCommand_macro_usage(argc, NULL))  // same here, but for common commands instead
1731                 {
1732                         return;
1733                 }
1734                 else if (GenericCommand_macro_usage(argc))  // same here, but for generic commands instead
1735                 {
1736                         return;
1737                 }
1738                 else if (GameCommand_macro_usage(argc))  // finally try for normal commands too
1739                 {
1740                         return;
1741                 }
1742         }
1743         else if (MUTATOR_CALLHOOK(SV_ParseServerCommand, strtolower(argv(0)), argc, command))
1744         {
1745                 return;  // handled by a mutator
1746         }
1747         else if (BanCommand(command))
1748         {
1749                 return;  // handled by server/command/ipban.qc
1750         }
1751         else if (CommonCommand_macro_command(argc, NULL, command))
1752         {
1753                 return;  // handled by server/command/common.qc
1754         }
1755         else if (GenericCommand(command))
1756         {
1757                 return;                                        // handled by common/command/generic.qc
1758         }
1759         else if (GameCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
1760         {
1761                 return;                                        // handled by one of the above GameCommand_* functions
1762         }
1763
1764         // nothing above caught the command, must be invalid
1765         LOG_INFO(((command != "") ? strcat("Unknown server command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try sv_cmd help.");
1766 }