qcsrc/server/command/sv_cmd.qc

   1 // =====================================================
   2 //  Server side game commands code, reworked by Samual
   3 //  Last updated: December 29th, 2011
   4 // =====================================================
   5
   6 //  used by GameCommand_make_mapinfo()
   7 void make_mapinfo_Think()
   8 {
   9         if(MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
  10         {
  11                 print("Done rebuiling mapinfos.\n");
  12                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
  13                 remove(self);
  14         }
  15         else
  16         {
  17                 self.think = make_mapinfo_Think;
  18                 self.nextthink = time;
  19         }
  20 }
  21
  22 //  used by GameCommand_extendmatchtime() and GameCommand_reducematchtime()
  23 void changematchtime(float delta, float mi, float ma)
  24 {
  25         float cur;
  26         float new;
  27         float lim;
  28
  29         if(delta == 0)
  30                 return;
  31         if(autocvar_timelimit < 0)
  32                 return;
  33
  34         if(mi <= 10)
  35                 mi = 10; // at least ten sec in the future
  36         cur = time - game_starttime;
  37         if(cur > 0)
  38                 mi += cur; // from current time!
  39
  40         lim = autocvar_timelimit * 60;
  41
  42         if(delta > 0)
  43         {
  44                 if(lim == 0)
  45                         return; // cannot increase any further
  46                 else if(lim < ma)
  47                         new = min(ma, lim + delta);
  48                 else // already above maximum: FAIL
  49                         return;
  50         }
  51         else
  52         {
  53                 if(lim == 0) // infinite: try reducing to max, if we are allowed to
  54                         new = max(mi, ma);
  55                 else if(lim > mi) // above minimum: decrease
  56                         new = max(mi, lim + delta);
  57                 else // already below minimum: FAIL
  58                         return;
  59         }
  60
  61         cvar_set("timelimit", ftos(new / 60));
  62 }
  63
  64
  65 // =======================
  66 //  Command Sub-Functions
  67 // =======================
  68
  69 void GameCommand_adminmsg(float request, float argc)
  70 {
  71         switch(request)
  72         {
  73                 case CMD_REQUEST_COMMAND:
  74                 {
  75                         entity client;
  76                         float accepted;
  77
  78                         string targets = strreplace(",", " ", argv(1));
  79                         string original_targets = strreplace(" ", ", ", targets);
  80                         string admin_message = argv(2);
  81                         float infobartime = stof(argv(3));
  82
  83                         string successful, t;
  84                         successful = string_null;
  85
  86                         if((targets) && (admin_message))
  87                         {
  88                                 for(;targets;)
  89                                 {
  90                                         t = car(targets); targets = cdr(targets);
  91
  92                                         // Check to see if the player is a valid target
  93                                         client = GetFilteredEntity(t);
  94                                         accepted = VerifyClientEntity(client, TRUE, FALSE);
  95
  96                                         if not(accepted > 0)
  97                                         {
  98                                                 print("adminmsg: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
  99                                                 continue;
 100                                         }
 101
 102                                         // send the centerprint/console print or infomessage
 103                                         if(infobartime)
 104                                         {
 105                                                 stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", infobartime, MakeConsoleSafe(admin_message)));
 106                                         }
 107                                         else
 108                                         {
 109                                                 centerprint(client, strcat("^3", admin_name(), ":\n^7", admin_message));
 110                                                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: ", admin_message, "\n"));
 111                                         }
 112
 113                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
 114                                         dprint("Message sent to ", client.netname, "\n");
 115                                         continue;
 116                                 }
 117
 118                                 if(successful)
 119                                         bprint("Successfully sent message '", admin_message, "' to ", successful, ".\n");
 120                                 else
 121                                         print("No players given (", original_targets, ") could receive the message.\n");
 122
 123                                 return;
 124                         }
 125                 }
 126
 127                 default:
 128                         print("Incorrect parameters for ^2adminmsg^7\n");
 129                 case CMD_REQUEST_USAGE:
 130                 {
 131                         print("\nUsage:^3 sv_cmd adminmsg clients \"message\" [infobartime]\n");
 132                         print("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
 133                         print("  If infobartime is provided, the message will be sent to infobar.\n");
 134                         print("  Otherwise, it will just be sent as a centerprint message.\n");
 135                         print("Examples: adminmsg 2,4 \"this infomessage will last for ten seconds\" 10\n");
 136                         print("          adminmsg 2,5 \"this message will be a centerprint\"\n");
 137                         return;
 138                 }
 139         }
 140 }
 141
 142 void GameCommand_allready(float request)
 143 {
 144         switch(request)
 145         {
 146                 case CMD_REQUEST_COMMAND:
 147                 {
 148                         ReadyRestart();
 149                         return;
 150                 }
 151
 152                 default:
 153                 case CMD_REQUEST_USAGE:
 154                 {
 155                         print("\nUsage:^3 sv_cmd allready\n");
 156                         print("  No arguments required.\n");
 157                         return;
 158                 }
 159         }
 160 }
 161
 162 void GameCommand_allspec(float request, float argc)
 163 {
 164         switch(request)
 165         {
 166                 case CMD_REQUEST_COMMAND:
 167                 {
 168                         entity client;
 169                         string reason = argv(1);
 170                         float i = 0;
 171
 172                         FOR_EACH_REALPLAYER(client)
 173                         {
 174                                 self = client;
 175                                 PutObserverInServer();
 176                                 ++i;
 177                         }
 178                         if(i) { bprint(strcat("Successfully forced all (", ftos(i), ") players to spectate", (reason ? strcat(" for reason: '", reason, "'") : ""), ".\n")); }
 179                         else { print("No players found to spectate.\n"); }
 180                         return;
 181                 }
 182
 183                 default:
 184                 case CMD_REQUEST_USAGE:
 185                 {
 186                         print("\nUsage:^3 sv_cmd allspec [reason]\n");
 187                         print("  Where 'reason' is an optional argument for explanation of allspec command.\n");
 188                         print("See also: ^2moveplayer, shuffleteams^7\n");
 189                         return;
 190                 }
 191         }
 192 }
 193
 194 void GameCommand_anticheat(float request, float argc)
 195 {
 196         switch(request)
 197         {
 198                 case CMD_REQUEST_COMMAND:
 199                 {
 200                         entity client = GetIndexedEntity(argc, 1);
 201                         float accepted = VerifyClientEntity(client, FALSE, FALSE);
 202
 203                         if(accepted > 0)
 204                         {
 205                                 self = client;
 206                                 anticheat_report();
 207                                 return;
 208                         }
 209                         else
 210                         {
 211                                 print("anticheat: ", GetClientErrorString(accepted, argv(1)), ".\n");
 212                         }
 213                 }
 214
 215                 default:
 216                         print("Incorrect parameters for ^2anticheat^7\n");
 217                 case CMD_REQUEST_USAGE:
 218                 {
 219                         print("\nUsage:^3 sv_cmd anticheat client\n");
 220                         print("  'client' is the entity number or name of the player.\n");
 221                         return;
 222                 }
 223         }
 224 }
 225
 226 void GameCommand_bbox(float request)
 227 {
 228         switch(request)
 229         {
 230                 case CMD_REQUEST_COMMAND:
 231                 {
 232                         print("Original size: ", ftos(world.absmin_x), " ", ftos(world.absmin_y), " ", ftos(world.absmin_z));
 233                         print(" ", ftos(world.absmax_x), " ", ftos(world.absmax_y), " ", ftos(world.absmax_z), "\n");
 234                         print("Currently set size: ", ftos(world.mins_x), " ", ftos(world.mins_y), " ", ftos(world.mins_z));
 235                         print(" ", ftos(world.maxs_x), " ", ftos(world.maxs_y), " ", ftos(world.maxs_z), "\n");
 236                         print("Solid bounding box size:");
 237
 238                         tracebox('1 0 0' * world.absmin_x,
 239                                                         '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
 240                                                         '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
 241                                                         '1 0 0' * world.absmax_x,
 242                                         MOVE_WORLDONLY,
 243                                         world);
 244                         if(trace_startsolid)
 245                                 print(" ", ftos(world.absmin_x));
 246                         else
 247                                 print(" ", ftos(trace_endpos_x));
 248
 249                         tracebox('0 1 0' * world.absmin_y,
 250                                                         '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
 251                                                         '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
 252                                                         '0 1 0' * world.absmax_y,
 253                                         MOVE_WORLDONLY,
 254                                         world);
 255                         if(trace_startsolid)
 256                                 print(" ", ftos(world.absmin_y));
 257                         else
 258                                 print(" ", ftos(trace_endpos_y));
 259
 260                         tracebox('0 0 1' * world.absmin_z,
 261                                                         '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
 262                                                         '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
 263                                                         '0 0 1' * world.absmax_z,
 264                                         MOVE_WORLDONLY,
 265                                         world);
 266                         if(trace_startsolid)
 267                                 print(" ", ftos(world.absmin_z));
 268                         else
 269                                 print(" ", ftos(trace_endpos_z));
 270
 271                         tracebox('1 0 0' * world.absmax_x,
 272                                                         '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
 273                                                         '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
 274                                                         '1 0 0' * world.absmin_x,
 275                                         MOVE_WORLDONLY,
 276                                         world);
 277                         if(trace_startsolid)
 278                                 print(" ", ftos(world.absmax_x));
 279                         else
 280                                 print(" ", ftos(trace_endpos_x));
 281
 282                         tracebox('0 1 0' * world.absmax_y,
 283                                                         '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
 284                                                         '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
 285                                                         '0 1 0' * world.absmin_y,
 286                                         MOVE_WORLDONLY,
 287                                         world);
 288                         if(trace_startsolid)
 289                                 print(" ", ftos(world.absmax_y));
 290                         else
 291                                 print(" ", ftos(trace_endpos_y));
 292
 293                         tracebox('0 0 1' * world.absmax_z,
 294                                                         '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
 295                                                         '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
 296                                                         '0 0 1' * world.absmin_z,
 297                                         MOVE_WORLDONLY,
 298                                         world);
 299                         if(trace_startsolid)
 300                                 print(" ", ftos(world.absmax_z));
 301                         else
 302                                 print(" ", ftos(trace_endpos_z));
 303
 304                         print("\n");
 305                         return;
 306                 }
 307
 308                 default:
 309                 case CMD_REQUEST_USAGE:
 310                 {
 311                         print("\nUsage:^3 sv_cmd bbox\n");
 312                         print("  No arguments required.\n");
 313                         print("See also: ^2gettaginfo, trace^7\n");
 314                         return;
 315                 }
 316         }
 317 }
 318
 319 void GameCommand_bot_cmd(float request, float argc, string command)
 320 {
 321         switch(request)
 322         {
 323                 case CMD_REQUEST_COMMAND:
 324                 {
 325                         entity bot;
 326
 327                         if(argv(1) == "reset")
 328                         {
 329                                 bot_resetqueues();
 330                                 return;
 331                         }
 332                         else if(argv(1) == "setbots")
 333                         {
 334                                 cvar_settemp("bot_vs_human", "0");
 335                                 cvar_settemp("minplayers", "0");
 336                                 cvar_settemp("bot_number", "0");
 337                                 bot_fixcount();
 338                                 cvar_settemp("bot_number", argv(2));
 339                                 if(!bot_fixcount())
 340                                         print("Sorry, could not set requested bot count\n");
 341                                 return;
 342                         }
 343                         else if(argv(1) == "load" && argc == 3)
 344                         {
 345                                 float fh, i;
 346                                 string s;
 347                                 fh = fopen(argv(2), FILE_READ);
 348                                 if(fh < 0)
 349                                 {
 350                                         print("cannot open the file\n");
 351                                         return;
 352                                 }
 353
 354                                 i = 0;
 355                                 while((s = fgets(fh)))
 356                                 {
 357                                         argc = tokenize_console(s);
 358
 359                                         if(argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
 360                                         {
 361                                                 if(argv(2) == "reset")
 362                                                 {
 363                                                         bot_resetqueues();
 364                                                 }
 365                                                 else if(argv(2) == "setbots")
 366                                                 {
 367                                                         cvar_settemp("bot_vs_human", "0");
 368                                                         cvar_settemp("minplayers", "0");
 369                                                         cvar_settemp("bot_number", "0");
 370                                                         bot_fixcount();
 371                                                         cvar_settemp("bot_number", argv(3));
 372                                                         if(!bot_fixcount())
 373                                                                 print("Sorry, could not set requested bot count\n");
 374                                                 }
 375                                                 else
 376                                                 {
 377                                                         // let's start at token 2 so we can skip sv_cmd bot_cmd
 378                                                         bot = find_bot_by_number(stof(argv(2)));
 379                                                         if(bot == world)
 380                                                                 bot = find_bot_by_name(argv(2));
 381                                                         if(bot)
 382                                                                 bot_queuecommand(bot, substring(s, argv_start_index(3), -1));
 383                                                 }
 384                                         }
 385                                         else
 386                                                 localcmd(strcat(s, "\n"));
 387
 388                                         ++i;
 389                                 }
 390                                 print(ftos(i), " commands read\n");
 391                                 fclose(fh);
 392                                 return;
 393                         }
 394                         else if(argv(1) == "help")
 395                         {
 396                                 if(argv(2))
 397                                         bot_cmdhelp(argv(2));
 398                                 else
 399                                         bot_list_commands();
 400                                 return;
 401                         }
 402                         else if(argc >= 3) // this comes last
 403                         {
 404                                 bot = find_bot_by_number(stof(argv(1)));
 405                                 if(bot == world)
 406                                         bot = find_bot_by_name(argv(1));
 407                                 if(bot)
 408                                 {
 409                                         print(strcat("Command '", substring(command, argv_start_index(2), -1), "' sent to bot ", bot.netname, "\n"));
 410                                         bot_queuecommand(bot, substring(command, argv_start_index(2), -1));
 411                                         return;
 412                                 }
 413                                 else
 414                                         print(strcat("Error: Can't find bot with the name or id '", argv(1),"' - Did you mistype the command?\n")); // don't return so that usage is shown
 415                         }
 416                 }
 417
 418                 default:
 419                         print("Incorrect parameters for ^2bot_cmd^7\n");
 420                 case CMD_REQUEST_USAGE:
 421                 {
 422                         print("\nUsage:^3 sv_cmd bot_cmd client command [argument]\n");
 423                         print("  'client' can be either the name or entity id of the bot\n");
 424                         print("  For full list of commands, see bot_cmd help [command].\n");
 425                         print("Examples: sv_cmd bot_cmd client cc \"say something\"\n");
 426                         print("          sv_cmd bot_cmd client presskey jump\n");
 427                         return;
 428                 }
 429         }
 430 }
 431
 432 void GameCommand_cointoss(float request, float argc)
 433 {
 434         switch(request)
 435         {
 436                 case CMD_REQUEST_COMMAND:
 437                 {
 438                         string result1 = (argv(2) ? strcat("^7", argv(1)) : "^1HEADS");
 439                         string result2 = (argv(2) ? strcat("^7", argv(2)) : "^4TAILS");
 440                         string choice = ((random() > 0.5) ? result1 : result2);
 441
 442                         Send_Notification(NOTIF_ALL, world, MSG_MULTI, MULTI_COINTOSS, choice);
 443
 444                         return;
 445                 }
 446
 447                 default:
 448                 case CMD_REQUEST_USAGE:
 449                 {
 450                         print("\nUsage:^3 sv_cmd cointoss [result1 result2]\n");
 451                         print("  Where 'result1' and 'result2' are user created options.\n");
 452                         return;
 453                 }
 454         }
 455 }
 456
 457 void GameCommand_database(float request, float argc)
 458 {
 459         switch(request)
 460         {
 461                 case CMD_REQUEST_COMMAND:
 462                 {
 463                         if(argc == 3)
 464                         {
 465                                 if(argv(1) == "save")
 466                                 {
 467                                         db_save(ServerProgsDB, argv(2));
 468                                         print(strcat("Copied serverprogs database to '", argv(2), "' in the data directory.\n"));
 469                                         return;
 470                                 }
 471                                 else if(argv(1) == "dump")
 472                                 {
 473                                         db_dump(ServerProgsDB, argv(2));
 474                                         print("DB dumped.\n"); // wtf does this do?
 475                                         return;
 476                                 }
 477                                 else if(argv(1) == "load")
 478                                 {
 479                                         db_close(ServerProgsDB);
 480                                         ServerProgsDB = db_load(argv(2));
 481                                         print(strcat("Loaded '", argv(2), "' as new serverprogs database.\n"));
 482                                         return;
 483                                 }
 484                         }
 485                 }
 486
 487                 default:
 488                         print("Incorrect parameters for ^2database^7\n");
 489                 case CMD_REQUEST_USAGE:
 490                 {
 491                         print("\nUsage:^3 sv_cmd database action filename\n");
 492                         print("  Where 'action' is the command to complete,\n");
 493                         print("  and 'filename' is what it acts upon.\n");
 494                         print("  Full list of commands here: \"save, dump, load.\"\n");
 495                         return;
 496                 }
 497         }
 498 }
 499
 500 void GameCommand_defer_clear(float request, float argc)
 501 {
 502         switch(request)
 503         {
 504                 case CMD_REQUEST_COMMAND:
 505                 {
 506                         entity client;
 507                         float accepted;
 508
 509                         if(argc >= 2)
 510                         {
 511                                 client = GetIndexedEntity(argc, 1);
 512                                 accepted = VerifyClientEntity(client, TRUE, FALSE);
 513
 514                                 if(accepted > 0)
 515                                 {
 516                                         stuffcmd(client, "defer clear\n");
 517                                         print("defer clear stuffed to ", client.netname, "\n");
 518                                 }
 519                                 else { print("defer_clear: ", GetClientErrorString(accepted, argv(1)), ".\n"); }
 520
 521                                 return;
 522                         }
 523                 }
 524
 525                 default:
 526                         print("Incorrect parameters for ^2defer_clear^7\n");
 527                 case CMD_REQUEST_USAGE:
 528                 {
 529                         print("\nUsage:^3 sv_cmd defer_clear client\n");
 530                         print("  'client' is the entity number or name of the player.\n");
 531                         print("See also: ^2defer_clear_all^7\n");
 532                         return;
 533                 }
 534         }
 535 }
 536
 537 void GameCommand_defer_clear_all(float request)
 538 {
 539         switch(request)
 540         {
 541                 case CMD_REQUEST_COMMAND:
 542                 {
 543                         entity client;
 544                         float i = 0;
 545                         float argc;
 546
 547                         FOR_EACH_CLIENT(client)
 548                         {
 549                                 argc = tokenize_console(strcat("defer_clear ", ftos(num_for_edict(client))));
 550                                 GameCommand_defer_clear(CMD_REQUEST_COMMAND, argc);
 551                                 ++i;
 552                         }
 553                         if(i) { print(strcat("Successfully stuffed defer clear to all clients (", ftos(i), ")\n")); } // should a message be added if no players were found?
 554                         return;
 555                 }
 556
 557                 default:
 558                 case CMD_REQUEST_USAGE:
 559                 {
 560                         print("\nUsage:^3 sv_cmd defer_clear_all\n");
 561                         print("  No arguments required.\n");
 562                         print("See also: ^2defer_clear^7\n");
 563                         return;
 564                 }
 565         }
 566 }
 567
 568 void GameCommand_delrec(float request, float argc)  // perhaps merge later with records and printstats and such?
 569 {
 570         switch(request)
 571         {
 572                 case CMD_REQUEST_COMMAND:
 573                 {
 574                         if(argv(1))
 575                         {
 576                                 if(argv(2))
 577                                         race_deleteTime(argv(2), stof(argv(1)));
 578                                 else
 579                                         race_deleteTime(GetMapname(), stof(argv(1)));
 580                                 return;
 581                         }
 582                 }
 583
 584                 default:
 585                         print("Incorrect parameters for ^2delrec^7\n");
 586                 case CMD_REQUEST_USAGE:
 587                 {
 588                         print("\nUsage:^3 sv_cmd delrec ranking [map]\n");
 589                         print("  'ranking' is which ranking level to clear up to, \n");
 590                         print("  it will clear all records up to nth place.\n");
 591                         print("  if 'map' is not provided it will use current map.\n");
 592                         return;
 593                 }
 594         }
 595 }
 596
 597 void GameCommand_effectindexdump(float request)
 598 {
 599         switch(request)
 600         {
 601                 case CMD_REQUEST_COMMAND:
 602                 {
 603                         float fh, d;
 604                         string s;
 605
 606                         d = db_create();
 607                         print("begin of effects list\n");
 608                         db_put(d, "TE_GUNSHOT", "1"); print("effect TE_GUNSHOT is ", ftos(particleeffectnum("TE_GUNSHOT")), "\n");
 609                         db_put(d, "TE_GUNSHOTQUAD", "1"); print("effect TE_GUNSHOTQUAD is ", ftos(particleeffectnum("TE_GUNSHOTQUAD")), "\n");
 610                         db_put(d, "TE_SPIKE", "1"); print("effect TE_SPIKE is ", ftos(particleeffectnum("TE_SPIKE")), "\n");
 611                         db_put(d, "TE_SPIKEQUAD", "1"); print("effect TE_SPIKEQUAD is ", ftos(particleeffectnum("TE_SPIKEQUAD")), "\n");
 612                         db_put(d, "TE_SUPERSPIKE", "1"); print("effect TE_SUPERSPIKE is ", ftos(particleeffectnum("TE_SUPERSPIKE")), "\n");
 613                         db_put(d, "TE_SUPERSPIKEQUAD", "1"); print("effect TE_SUPERSPIKEQUAD is ", ftos(particleeffectnum("TE_SUPERSPIKEQUAD")), "\n");
 614                         db_put(d, "TE_WIZSPIKE", "1"); print("effect TE_WIZSPIKE is ", ftos(particleeffectnum("TE_WIZSPIKE")), "\n");
 615                         db_put(d, "TE_KNIGHTSPIKE", "1"); print("effect TE_KNIGHTSPIKE is ", ftos(particleeffectnum("TE_KNIGHTSPIKE")), "\n");
 616                         db_put(d, "TE_EXPLOSION", "1"); print("effect TE_EXPLOSION is ", ftos(particleeffectnum("TE_EXPLOSION")), "\n");
 617                         db_put(d, "TE_EXPLOSIONQUAD", "1"); print("effect TE_EXPLOSIONQUAD is ", ftos(particleeffectnum("TE_EXPLOSIONQUAD")), "\n");
 618                         db_put(d, "TE_TAREXPLOSION", "1"); print("effect TE_TAREXPLOSION is ", ftos(particleeffectnum("TE_TAREXPLOSION")), "\n");
 619                         db_put(d, "TE_TELEPORT", "1"); print("effect TE_TELEPORT is ", ftos(particleeffectnum("TE_TELEPORT")), "\n");
 620                         db_put(d, "TE_LAVASPLASH", "1"); print("effect TE_LAVASPLASH is ", ftos(particleeffectnum("TE_LAVASPLASH")), "\n");
 621                         db_put(d, "TE_SMALLFLASH", "1"); print("effect TE_SMALLFLASH is ", ftos(particleeffectnum("TE_SMALLFLASH")), "\n");
 622                         db_put(d, "TE_FLAMEJET", "1"); print("effect TE_FLAMEJET is ", ftos(particleeffectnum("TE_FLAMEJET")), "\n");
 623                         db_put(d, "EF_FLAME", "1"); print("effect EF_FLAME is ", ftos(particleeffectnum("EF_FLAME")), "\n");
 624                         db_put(d, "TE_BLOOD", "1"); print("effect TE_BLOOD is ", ftos(particleeffectnum("TE_BLOOD")), "\n");
 625                         db_put(d, "TE_SPARK", "1"); print("effect TE_SPARK is ", ftos(particleeffectnum("TE_SPARK")), "\n");
 626                         db_put(d, "TE_PLASMABURN", "1"); print("effect TE_PLASMABURN is ", ftos(particleeffectnum("TE_PLASMABURN")), "\n");
 627                         db_put(d, "TE_TEI_G3", "1"); print("effect TE_TEI_G3 is ", ftos(particleeffectnum("TE_TEI_G3")), "\n");
 628                         db_put(d, "TE_TEI_SMOKE", "1"); print("effect TE_TEI_SMOKE is ", ftos(particleeffectnum("TE_TEI_SMOKE")), "\n");
 629                         db_put(d, "TE_TEI_BIGEXPLOSION", "1"); print("effect TE_TEI_BIGEXPLOSION is ", ftos(particleeffectnum("TE_TEI_BIGEXPLOSION")), "\n");
 630                         db_put(d, "TE_TEI_PLASMAHIT", "1"); print("effect TE_TEI_PLASMAHIT is ", ftos(particleeffectnum("TE_TEI_PLASMAHIT")), "\n");
 631                         db_put(d, "EF_STARDUST", "1"); print("effect EF_STARDUST is ", ftos(particleeffectnum("EF_STARDUST")), "\n");
 632                         db_put(d, "TR_ROCKET", "1"); print("effect TR_ROCKET is ", ftos(particleeffectnum("TR_ROCKET")), "\n");
 633                         db_put(d, "TR_GRENADE", "1"); print("effect TR_GRENADE is ", ftos(particleeffectnum("TR_GRENADE")), "\n");
 634                         db_put(d, "TR_BLOOD", "1"); print("effect TR_BLOOD is ", ftos(particleeffectnum("TR_BLOOD")), "\n");
 635                         db_put(d, "TR_WIZSPIKE", "1"); print("effect TR_WIZSPIKE is ", ftos(particleeffectnum("TR_WIZSPIKE")), "\n");
 636                         db_put(d, "TR_SLIGHTBLOOD", "1"); print("effect TR_SLIGHTBLOOD is ", ftos(particleeffectnum("TR_SLIGHTBLOOD")), "\n");
 637                         db_put(d, "TR_KNIGHTSPIKE", "1"); print("effect TR_KNIGHTSPIKE is ", ftos(particleeffectnum("TR_KNIGHTSPIKE")), "\n");
 638                         db_put(d, "TR_VORESPIKE", "1"); print("effect TR_VORESPIKE is ", ftos(particleeffectnum("TR_VORESPIKE")), "\n");
 639                         db_put(d, "TR_NEHAHRASMOKE", "1"); print("effect TR_NEHAHRASMOKE is ", ftos(particleeffectnum("TR_NEHAHRASMOKE")), "\n");
 640                         db_put(d, "TR_NEXUIZPLASMA", "1"); print("effect TR_NEXUIZPLASMA is ", ftos(particleeffectnum("TR_NEXUIZPLASMA")), "\n");
 641                         db_put(d, "TR_GLOWTRAIL", "1"); print("effect TR_GLOWTRAIL is ", ftos(particleeffectnum("TR_GLOWTRAIL")), "\n");
 642                         db_put(d, "TR_SEEKER", "1"); print("effect TR_SEEKER is ", ftos(particleeffectnum("TR_SEEKER")), "\n");
 643                         db_put(d, "SVC_PARTICLE", "1"); print("effect SVC_PARTICLE is ", ftos(particleeffectnum("SVC_PARTICLE")), "\n");
 644
 645                         fh = fopen("effectinfo.txt", FILE_READ);
 646                         while((s = fgets(fh)))
 647                         {
 648                                 tokenize_console(s);
 649                                 if(argv(0) == "effect")
 650                                 {
 651                                         if(db_get(d, argv(1)) != "1")
 652                                         {
 653                                                 if(particleeffectnum(argv(1)) >= 0)
 654                                                         print("effect ", argv(1), " is ", ftos(particleeffectnum(argv(1))), "\n");
 655                                                 db_put(d, argv(1), "1");
 656                                         }
 657                                 }
 658                         }
 659                         print("end of effects list\n");
 660
 661                         db_close(d);
 662                         return;
 663                 }
 664
 665                 default:
 666                 case CMD_REQUEST_USAGE:
 667                 {
 668                         print("\nUsage:^3 sv_cmd effectindexdump\n");
 669                         print("  No arguments required.\n");
 670                         return;
 671                 }
 672         }
 673 }
 674
 675 void GameCommand_extendmatchtime(float request)
 676 {
 677         switch(request)
 678         {
 679                 case CMD_REQUEST_COMMAND:
 680                 {
 681                         changematchtime(autocvar_timelimit_increment * 60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
 682                         return;
 683                 }
 684
 685                 default:
 686                 case CMD_REQUEST_USAGE:
 687                 {
 688                         print("\nUsage:^3 sv_cmd extendmatchtime\n");
 689                         print("  No arguments required.\n");
 690                         print("See also: ^2reducematchtime^7\n");
 691                         return;
 692                 }
 693         }
 694 }
 695
 696 void GameCommand_find(float request, float argc)  // is this even needed? We have prvm_edicts command and such ANYWAY
 697 {
 698         switch(request)
 699         {
 700                 case CMD_REQUEST_COMMAND:
 701                 {
 702                         entity client;
 703
 704                         for(client = world; (client = find(client, classname, argv(1))); )
 705                                 print(etos(client), "\n");
 706
 707                         return;
 708                 }
 709
 710                 default:
 711                         print("Incorrect parameters for ^2find^7\n");
 712                 case CMD_REQUEST_USAGE:
 713                 {
 714                         print("\nUsage:^3 sv_cmd find classname\n");
 715                         print("  Where 'classname' is the classname to search for.\n");
 716                         return;
 717                 }
 718         }
 719 }
 720
 721 void GameCommand_gametype(float request, float argc)
 722 {
 723         switch(request)
 724         {
 725                 case CMD_REQUEST_COMMAND:
 726                 {
 727                         if(argv(1) != "")
 728                         {
 729                                 string s = argv(1);
 730                                 float t = MapInfo_Type_FromString(s), tsave = MapInfo_CurrentGametype();
 731
 732                                 if(t)
 733                                 {
 734                                         MapInfo_SwitchGameType(t);
 735                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 736                                         if(MapInfo_count > 0)
 737                                         {
 738                                                 // update lsmaps in case the gametype changed, this way people can easily list maps for it
 739                                                 if(lsmaps_reply != "") { strunzone(lsmaps_reply); }
 740                                                 lsmaps_reply = strzone(getlsmaps());
 741                                                 bprint("Game type successfully switched to ", s, "\n");
 742                                         }
 743                                         else
 744                                         {
 745                                                 bprint("Cannot use this game type: no map for it found\n");
 746                                                 MapInfo_SwitchGameType(tsave);
 747                                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 748                                         }
 749                                 }
 750                                 else
 751                                         bprint("Game type switch to ", s, " failed: this type does not exist!\n");
 752
 753                                 return;
 754                         }
 755                 }
 756
 757                 default:
 758                         print("Incorrect parameters for ^2gametype^7\n");
 759                 case CMD_REQUEST_USAGE:
 760                 {
 761                         print("\nUsage:^3 sv_cmd gametype mode\n");
 762                         print("  Where 'mode' is the gametype mode to switch to.\n");
 763                         print("See also: ^2gotomap^7\n");
 764                         return;
 765                 }
 766         }
 767 }
 768
 769 void GameCommand_gettaginfo(float request, float argc)
 770 {
 771         switch(request)
 772         {
 773                 case CMD_REQUEST_COMMAND:
 774                 {
 775                         entity tmp_entity;
 776                         float i;
 777                         vector v;
 778
 779                         if(argc >= 4)
 780                         {
 781                                 tmp_entity = spawn();
 782                                 if(argv(1) == "w")
 783                                         setmodel(tmp_entity, (nextent(world)).weaponentity.model);
 784                                 else
 785                                 {
 786                                         precache_model(argv(1));
 787                                         setmodel(tmp_entity, argv(1));
 788                                 }
 789                                 tmp_entity.frame = stof(argv(2));
 790                                 if(substring(argv(3), 0, 1) == "#")
 791                                         i = stof(substring(argv(3), 1, -1));
 792                                 else
 793                                         i = gettagindex(tmp_entity, argv(3));
 794                                 if(i)
 795                                 {
 796                                         v = gettaginfo(tmp_entity, i);
 797                                         print("model ", tmp_entity.model, " frame ", ftos(tmp_entity.frame), " tag ", gettaginfo_name);
 798                                         print(" index ", ftos(i), " parent ", ftos(gettaginfo_parent), "\n");
 799                                         print(" vector = ", ftos(v_x), " ", ftos(v_y), " ", ftos(v_z), "\n");
 800                                         print(" offset = ", ftos(gettaginfo_offset_x), " ", ftos(gettaginfo_offset_y), " ", ftos(gettaginfo_offset_z), "\n");
 801                                         print(" forward = ", ftos(gettaginfo_forward_x), " ", ftos(gettaginfo_forward_y), " ", ftos(gettaginfo_forward_z), "\n");
 802                                         print(" right = ", ftos(gettaginfo_right_x), " ", ftos(gettaginfo_right_y), " ", ftos(gettaginfo_right_z), "\n");
 803                                         print(" up = ", ftos(gettaginfo_up_x), " ", ftos(gettaginfo_up_y), " ", ftos(gettaginfo_up_z), "\n");
 804                                         if(argc >= 6)
 805                                         {
 806                                                 v_y = -v_y;
 807                                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
 808                                         }
 809                                 }
 810                                 else
 811                                         print("bone not found\n");
 812
 813                                 remove(tmp_entity);
 814                                 return;
 815                         }
 816                 }
 817
 818                 default:
 819                         print("Incorrect parameters for ^2gettaginfo^7\n");
 820                 case CMD_REQUEST_USAGE:
 821                 {
 822                         print("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
 823                         print("See also: ^2bbox, trace^7\n");
 824                         return;
 825                 }
 826         }
 827 }
 828
 829 void GameCommand_animbench(float request, float argc)
 830 {
 831         switch(request)
 832         {
 833                 case CMD_REQUEST_COMMAND:
 834                 {
 835                         entity tmp_entity;
 836
 837                         if(argc >= 4)
 838                         {
 839                                 tmp_entity = spawn();
 840                                 if(argv(1) == "w")
 841                                         setmodel(tmp_entity, (nextent(world)).weaponentity.model);
 842                                 else
 843                                 {
 844                                         precache_model(argv(1));
 845                                         setmodel(tmp_entity, argv(1));
 846                                 }
 847                                 float f1 = stof(argv(2));
 848                                 float f2 = stof(argv(3));
 849                                 float t0;
 850                                 float t1 = 0;
 851                                 float t2 = 0;
 852                                 float n = 0;
 853
 854                                 while(t1 + t2 < 1)
 855                                 {
 856                                         tmp_entity.frame = f1;
 857                                         t0 = gettime(GETTIME_HIRES);
 858                                         getsurfacepoint(tmp_entity, 0, 0);
 859                                         t1 += gettime(GETTIME_HIRES) - t0;
 860                                         tmp_entity.frame = f2;
 861                                         t0 = gettime(GETTIME_HIRES);
 862                                         getsurfacepoint(tmp_entity, 0, 0);
 863                                         t2 += gettime(GETTIME_HIRES) - t0;
 864                                         n += 1;
 865                                 }
 866                                 print("model ", tmp_entity.model, " frame ", ftos(f1), " animtime ", ftos(n / t1), "/s\n");
 867                                 print("model ", tmp_entity.model, " frame ", ftos(f2), " animtime ", ftos(n / t2), "/s\n");
 868
 869                                 remove(tmp_entity);
 870                                 return;
 871                         }
 872                 }
 873
 874                 default:
 875                         print("Incorrect parameters for ^2gettaginfo^7\n");
 876                 case CMD_REQUEST_USAGE:
 877                 {
 878                         print("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
 879                         print("See also: ^2bbox, trace^7\n");
 880                         return;
 881                 }
 882         }
 883 }
 884
 885 void GameCommand_gotomap(float request, float argc)
 886 {
 887         switch(request)
 888         {
 889                 case CMD_REQUEST_COMMAND:
 890                 {
 891                         if(argv(1))
 892                         {
 893                                 print(GotoMap(argv(1)), "\n");
 894                                 return;
 895                         }
 896                 }
 897
 898                 default:
 899                         print("Incorrect parameters for ^2gotomap^7\n");
 900                 case CMD_REQUEST_USAGE:
 901                 {
 902                         print("\nUsage:^3 sv_cmd gotomap map\n");
 903                         print("  Where 'map' is the *.bsp file to change to.\n");
 904                         print("See also: ^2gametype^7\n");
 905                         return;
 906                 }
 907         }
 908 }
 909
 910 void GameCommand_lockteams(float request)
 911 {
 912         switch(request)
 913         {
 914                 case CMD_REQUEST_COMMAND:
 915                 {
 916                         if(teamplay)
 917                         {
 918                                 lockteams = 1;
 919                                 bprint("^1The teams are now locked.\n");
 920                         }
 921                         else
 922                         {
 923                                 bprint("lockteams command can only be used in a team-based gamemode.\n");
 924                         }
 925                         return;
 926                 }
 927
 928                 default:
 929                 case CMD_REQUEST_USAGE:
 930                 {
 931                         print("\nUsage:^3 sv_cmd lockteams\n");
 932                         print("  No arguments required.\n");
 933                         print("See also: ^2unlockteams^7\n");
 934                         return;
 935                 }
 936         }
 937 }
 938
 939 void GameCommand_make_mapinfo(float request)
 940 {
 941         switch(request)
 942         {
 943                 case CMD_REQUEST_COMMAND:
 944                 {
 945                         entity tmp_entity;
 946
 947                         tmp_entity = spawn();
 948                         tmp_entity.classname = "make_mapinfo";
 949                         tmp_entity.think = make_mapinfo_Think;
 950                         tmp_entity.nextthink = time;
 951                         MapInfo_Enumerate();
 952                         return;
 953                 }
 954
 955                 default:
 956                 case CMD_REQUEST_USAGE:
 957                 {
 958                         print("\nUsage:^3 sv_cmd make_mapinfo\n");
 959                         print("  No arguments required.\n");
 960                         print("See also: ^2radarmap^7\n");
 961                         return;
 962                 }
 963         }
 964 }
 965
 966 void GameCommand_moveplayer(float request, float argc)
 967 {
 968         switch(request)
 969         {
 970                 case CMD_REQUEST_COMMAND:
 971                 {
 972                         float accepted;
 973                         entity client;
 974
 975                         string targets = strreplace(",", " ", argv(1));
 976                         string original_targets = strreplace(" ", ", ", targets);
 977                         string destination = argv(2);
 978
 979                         string successful, t;
 980                         successful = string_null;
 981
 982                         // lets see if the target(s) even actually exist.
 983                         if((targets) && (destination))
 984                         {
 985                                 for(;targets;)
 986                                 {
 987                                         t = car(targets); targets = cdr(targets);
 988
 989                                         // Check to see if the player is a valid target
 990                                         client = GetFilteredEntity(t);
 991                                         accepted = VerifyClientEntity(client, FALSE, FALSE);
 992
 993                                         if not(accepted > 0)
 994                                         {
 995                                                 print("moveplayer: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
 996                                                 continue;
 997                                         }
 998
 999                                         // Where are we putting this player?
1000                                         if(destination == "spec" || destination == "spectator")
1001                                         {
1002                                                 if(!IS_SPEC(client) && !IS_OBSERVER(client))
1003                                                 {
1004                                                         self = client;
1005                                                         PutObserverInServer();
1006
1007                                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
1008                                                 }
1009                                                 else
1010                                                 {
1011                                                         print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already spectating.\n");
1012                                                 }
1013                                                 continue;
1014                                         }
1015                                         else
1016                                         {
1017                                                 if(!IS_SPEC(client) && !IS_OBSERVER(client))
1018                                                 {
1019                                                         if(teamplay)
1020                                                         {
1021                                                                 // set up
1022                                                                 float team_id;
1023                                                                 float save = client.team_forced;
1024                                                                 client.team_forced = 0;
1025
1026                                                                 // find the team to move the player to
1027                                                                 team_id = Team_ColorToTeam(destination);
1028                                                                 if(team_id == client.team) // already on the destination team
1029                                                                 {
1030                                                                         // keep the forcing undone
1031                                                                         print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already on the ", Team_ColoredFullName(client.team), (targets ? "^7, skipping to next player.\n" : "^7.\n"));
1032                                                                         continue;
1033                                                                 }
1034                                                                 else if(team_id == 0)  // auto team
1035                                                                 {
1036                                                                         team_id = Team_NumberToTeam(FindSmallestTeam(client, FALSE));
1037                                                                 }
1038                                                                 else
1039                                                                 {
1040                                                                         CheckAllowedTeams(client);
1041                                                                 }
1042                                                                 client.team_forced = save;
1043
1044                                                                 // Check to see if the destination team is even available
1045                                                                 switch(team_id)
1046                                                                 {
1047                                                                         case NUM_TEAM_1: if(c1 == -1) { print("Sorry, can't move player to red team if it doesn't exist.\n"); return; } break;
1048                                                                         case NUM_TEAM_2: if(c2 == -1) { print("Sorry, can't move player to blue team if it doesn't exist.\n"); return; } break;
1049                                                                         case NUM_TEAM_3: if(c3 == -1) { print("Sorry, can't move player to yellow team if it doesn't exist.\n"); return; } break;
1050                                                                         case NUM_TEAM_4: if(c4 == -1) { print("Sorry, can't move player to pink team if it doesn't exist.\n"); return; } break;
1051
1052                                                                         default: print("Sorry, can't move player here if team ", destination, " doesn't exist.\n"); return;
1053                                                                 }
1054
1055                                                                 // If so, lets continue and finally move the player
1056                                                                 client.team_forced = 0;
1057                                                                 MoveToTeam(client, team_id, 6);
1058                                                                 successful = strcat(successful, (successful ? ", " : ""), client.netname);
1059                                                                 print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") has been moved to the ", Team_ColoredFullName(team_id), "^7.\n");
1060                                                                 continue;
1061                                                         }
1062                                                         else
1063                                                         {
1064                                                                 print("Can't change teams when currently not playing a team game.\n");
1065                                                                 return;
1066                                                         }
1067                                                 }
1068                                                 else
1069                                                 {
1070                                                         print("Can't change teams if the player isn't in the game.\n"); // well technically we could, but should we allow that? :P
1071                                                         return;
1072                                                 }
1073                                         }
1074                                 }
1075
1076                                 if(successful)
1077                                         bprint("Successfully moved players ", successful, " to destination ", destination, ".\n");
1078                                 else
1079                                         print("No players given (", original_targets, ") are able to move.\n");
1080
1081                                 return; // still correct parameters so return to avoid usage print
1082                         }
1083                 }
1084
1085                 default:
1086                         print("Incorrect parameters for ^2moveplayer^7\n");
1087                 case CMD_REQUEST_USAGE:
1088                 {
1089                         print("\nUsage:^3 sv_cmd moveplayer clients destination\n");
1090                         print("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
1091                         print("  'destination' is what to send the player to, be it team or spectating\n");
1092                         print("  Full list of destinations here: \"spec, spectator, red, blue, yellow, pink, auto.\"\n");
1093                         print("Examples: sv_cmd moveplayer 1,3,5 red 3\n");
1094                         print("          sv_cmd moveplayer 2 spec \n");
1095                         print("See also: ^2allspec, shuffleteams^7\n");
1096                         return;
1097                 }
1098         }
1099 }
1100
1101 void GameCommand_nospectators(float request)
1102 {
1103         switch(request)
1104         {
1105                 case CMD_REQUEST_COMMAND:
1106                 {
1107                         blockSpectators = 1;
1108                         entity plr;
1109                         FOR_EACH_CLIENT(plr) //give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
1110                         {
1111                                 if(IS_SPEC(plr) || IS_OBSERVER(plr))
1112                                 {
1113                                         plr.spectatortime = time;
1114                                         Send_Notification(NOTIF_ONE_ONLY, plr, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1115                                 }
1116                         }
1117                         bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
1118                         return;
1119                 }
1120
1121                 default:
1122                 case CMD_REQUEST_USAGE:
1123                 {
1124                         print("\nUsage:^3 sv_cmd nospectators\n");
1125                         print("  No arguments required.\n");
1126                         return;
1127                 }
1128         }
1129 }
1130
1131 void GameCommand_playerdemo(float request, float argc)
1132 {
1133         switch(request)
1134         {
1135                 case CMD_REQUEST_COMMAND:
1136                 {
1137                         if(argv(2) && argv(3))
1138                         {
1139                                 entity client;
1140                                 float i, n, accepted;
1141
1142                                 switch(argv(1))
1143                                 {
1144                                         case "read":
1145                                         {
1146                                                 client = GetIndexedEntity(argc, 2);
1147                                                 accepted = VerifyClientEntity(client, FALSE, TRUE);
1148
1149                                                 if not(accepted > 0)
1150                                                 {
1151                                                         print("playerdemo: read: ", GetClientErrorString(accepted, argv(2)), ".\n");
1152                                                         return;
1153                                                 }
1154
1155                                                 self = client;
1156                                                 playerdemo_open_read(argv(next_token));
1157                                                 return;
1158                                         }
1159
1160                                         case "write":
1161                                         {
1162                                                 client = GetIndexedEntity(argc, 2);
1163                                                 accepted = VerifyClientEntity(client, FALSE, FALSE);
1164
1165                                                 if not(accepted > 0)
1166                                                 {
1167                                                         print("playerdemo: write: ", GetClientErrorString(accepted, argv(2)), ".\n");
1168                                                         return;
1169                                                 }
1170
1171                                                 self = client;
1172                                                 playerdemo_open_write(argv(next_token));
1173                                                 return;
1174                                         }
1175
1176                                         case "auto_read_and_write":
1177                                         {
1178                                                 n = GetFilteredNumber(argv(3));
1179                                                 cvar_set("bot_number", ftos(n));
1180
1181                                                 localcmd("wait; wait; wait\n");
1182                                                 for(i = 0; i < n; ++i) { localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", argv(2), ftos(i+1), "\n"); }
1183
1184                                                 localcmd("sv_cmd playerdemo write 1 ", ftos(n+1), "\n");
1185                                                 return;
1186                                         }
1187
1188                                         case "auto_read":
1189                                         {
1190                                                 n = GetFilteredNumber(argv(3));
1191                                                 cvar_set("bot_number", ftos(n));
1192
1193                                                 localcmd("wait; wait; wait\n");
1194                                                 for(i = 0; i < n; ++i) { localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", argv(2), ftos(i+1), "\n"); }
1195                                                 return;
1196                                         }
1197                                 }
1198                         }
1199                 }
1200
1201                 default:
1202                         print("Incorrect parameters for ^2playerdemo^7\n");
1203                 case CMD_REQUEST_USAGE:
1204                 {
1205                         print("\nUsage:^3 sv_cmd playerdemo command (entitynumber filename | entitynumber botnumber)\n");
1206                         print("  Full list of commands here: \"read, write, auto_read_and_write, auto_read.\"\n");
1207                         return;
1208                 }
1209         }
1210 }
1211
1212 void GameCommand_printstats(float request)
1213 {
1214         switch(request)
1215         {
1216                 case CMD_REQUEST_COMMAND:
1217                 {
1218                         DumpStats(FALSE);
1219                         print("stats dumped.\n");
1220                         return;
1221                 }
1222
1223                 default:
1224                 case CMD_REQUEST_USAGE:
1225                 {
1226                         print("\nUsage:^3 sv_cmd printstats\n");
1227                         print("  No arguments required.\n");
1228                         return;
1229                 }
1230         }
1231 }
1232
1233 void GameCommand_radarmap(float request, float argc)
1234 {
1235         switch(request)
1236         {
1237                 case CMD_REQUEST_COMMAND:
1238                 {
1239                         if(RadarMap_Make(argc))
1240                                 return;
1241                 }
1242
1243                 default:
1244                         print("Incorrect parameters for ^2radarmap^7\n");
1245                 case CMD_REQUEST_USAGE:
1246                 {
1247                         print("\nUsage:^3 sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]\n");
1248                         print("  The quality factor Q is roughly proportional to the time taken.\n");
1249                         print("  trace supports no quality factor; its result should look like --block with infinite quality factor.\n");
1250                         print("See also: ^2make_mapinfo^7\n");
1251                         return;
1252                 }
1253         }
1254 }
1255
1256 void GameCommand_reducematchtime(float request)
1257 {
1258         switch(request)
1259         {
1260                 case CMD_REQUEST_COMMAND:
1261                 {
1262                         changematchtime(autocvar_timelimit_decrement *-60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
1263                         return;
1264                 }
1265
1266                 default:
1267                 case CMD_REQUEST_USAGE:
1268                 {
1269                         print("\nUsage:^3 sv_cmd reducematchtime\n");
1270                         print("  No arguments required.\n");
1271                         print("See also: ^2extendmatchtime^7\n");
1272                         return;
1273                 }
1274         }
1275 }
1276
1277 void GameCommand_setbots(float request, float argc)
1278 {
1279         switch(request)
1280         {
1281                 case CMD_REQUEST_COMMAND:
1282                 {
1283                         if(argc >= 2)
1284                         {
1285                                 cvar_settemp("minplayers", "0");
1286                                 cvar_settemp("bot_number", argv(1));
1287                                 bot_fixcount();
1288                                 return;
1289                         }
1290                 }
1291
1292                 default:
1293                         print("Incorrect parameters for ^2setbots^7\n");
1294                 case CMD_REQUEST_USAGE:
1295                 {
1296                         print("\nUsage:^3 sv_cmd setbots botnumber\n");
1297                         print("  Where 'botnumber' is the amount of bots to set bot_number cvar to.\n");
1298                         print("See also: ^2bot_cmd^7\n");
1299                         return;
1300                 }
1301         }
1302 }
1303
1304 void GameCommand_shuffleteams(float request)
1305 {
1306         switch(request)
1307         {
1308                 case CMD_REQUEST_COMMAND:
1309                 {
1310                         if(teamplay)
1311                         {
1312                                 entity tmp_player;
1313                                 float i, x, z, t_teams, t_players, team_color;
1314
1315                                 // count the total amount of players and total amount of teams
1316                                 t_players = 0;
1317                                 t_teams = 0;
1318                                 FOR_EACH_PLAYER(tmp_player)
1319                                 {
1320                                         CheckAllowedTeams(tmp_player);
1321
1322                                         if(c1 >= 0) t_teams = max(1, t_teams);
1323                                         if(c2 >= 0) t_teams = max(2, t_teams);
1324                                         if(c3 >= 0) t_teams = max(3, t_teams);
1325                                         if(c4 >= 0) t_teams = max(4, t_teams);
1326
1327                                         ++t_players;
1328                                 }
1329
1330                                 // build a list of the players in a random order
1331                                 FOR_EACH_PLAYER(tmp_player)
1332                                 {
1333                                         for(;;)
1334                                         {
1335                                                 i = bound(1, floor(random() * maxclients) + 1, maxclients);
1336
1337                                                 if(shuffleteams_players[i])
1338                                                 {
1339                                                         continue; // a player is already assigned to this slot
1340                                                 }
1341                                                 else
1342                                                 {
1343                                                         shuffleteams_players[i] = num_for_edict(tmp_player);
1344                                                         break;
1345                                                 }
1346                                         }
1347                                 }
1348
1349                                 // finally, from the list made earlier, re-join the players in different order.
1350                                 for(i = 1; i <= t_teams; ++i)
1351                                 {
1352                                         // find out how many players to assign to this team
1353                                         x = (t_players / t_teams);
1354                                         x = ((i == 1) ? ceil(x) : floor(x));
1355
1356                                         team_color = Team_NumberToTeam(i);
1357
1358                                         // sort through the random list of players made earlier
1359                                         for(z = 1; z <= maxclients; ++z)
1360                                         {
1361                                                 if not(shuffleteams_teams[i] >= x)
1362                                                 {
1363                                                         if not(shuffleteams_players[z])
1364                                                                 continue; // not a player, move on to next random slot
1365
1366                                                         if(VerifyClientNumber(shuffleteams_players[z]))
1367                                                                 self = edict_num(shuffleteams_players[z]);
1368
1369                                                         if(self.team != team_color)
1370                                                                 MoveToTeam(self, team_color, 6);
1371
1372                                                         shuffleteams_players[z] = 0;
1373                                                         shuffleteams_teams[i] = shuffleteams_teams[i] + 1;
1374                                                 }
1375                                                 else
1376                                                 {
1377                                                         break; // move on to next team
1378                                                 }
1379                                         }
1380                                 }
1381
1382                                 bprint("Successfully shuffled the players around randomly.\n");
1383
1384                                 // clear the buffers now
1385                                 for (i=0; i<SHUFFLETEAMS_MAX_PLAYERS; ++i)
1386                                         shuffleteams_players[i] = 0;
1387
1388                                 for (i=0; i<SHUFFLETEAMS_MAX_TEAMS; ++i)
1389                                         shuffleteams_teams[i] = 0;
1390                         }
1391                         else
1392                         {
1393                                 print("Can't shuffle teams when currently not playing a team game.\n");
1394                         }
1395
1396                         return;
1397                 }
1398
1399                 default:
1400                 case CMD_REQUEST_USAGE:
1401                 {
1402                         print("\nUsage:^3 sv_cmd shuffleteams\n");
1403                         print("  No arguments required.\n");
1404                         print("See also: ^2moveplayer, allspec^7\n");
1405                         return;
1406                 }
1407         }
1408 }
1409
1410 void GameCommand_stuffto(float request, float argc)
1411 {
1412         // This... is a fairly dangerous and powerful command... - It allows any arguments to be sent to a client via rcon.
1413         // Because of this, it is disabled by default and must be enabled by the server owner when doing compilation. That way,
1414         // we can be certain they understand the risks of it... So to enable, compile server with -DSTUFFTO_ENABLED argument.
1415
1416         #ifdef STUFFTO_ENABLED
1417         #message "stuffto command enabled"
1418         switch(request)
1419         {
1420                 case CMD_REQUEST_COMMAND:
1421                 {
1422                         if(argv(2))
1423                         {
1424                                 entity client = GetIndexedEntity(argc, 1);
1425                                 float accepted = VerifyClientEntity(client, TRUE, FALSE);
1426
1427                                 if(accepted > 0)
1428                                 {
1429                                         stuffcmd(client, strcat("\n", argv(next_token), "\n"));
1430                                         print(strcat("Command: \"", argv(next_token), "\" sent to ", GetCallerName(client), " (", argv(1) ,").\n"));
1431                                 }
1432                                 else
1433                                         print("stuffto: ", GetClientErrorString(accepted, argv(1)), ".\n");
1434
1435                                 return;
1436                         }
1437                 }
1438
1439                 default:
1440                         print("Incorrect parameters for ^2stuffto^7\n");
1441                 case CMD_REQUEST_USAGE:
1442                 {
1443                         print("\nUsage:^3 sv_cmd stuffto client \"command\"\n");
1444                         print("  'client' is the entity number or name of the player,\n");
1445                         print("  and 'command' is the command to be sent to that player.\n");
1446                         return;
1447                 }
1448         }
1449         #else
1450         if(request)
1451         {
1452                 print("stuffto command is not enabled on this server.\n");
1453                 return;
1454         }
1455         #endif
1456 }
1457
1458 void GameCommand_trace(float request, float argc)
1459 {
1460         switch(request)
1461         {
1462                 case CMD_REQUEST_COMMAND:
1463                 {
1464                         entity e;
1465                         vector org, delta, start, end, p, q, q0, pos, vv, dv;
1466                         float i, f, safe, unsafe, dq, dqf;
1467
1468                         switch(argv(1))
1469                         {
1470                                 case "debug":
1471                                 {
1472                                         print("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.\n");
1473                                         for(;;)
1474                                         {
1475                                                 org = world.mins;
1476                                                 delta = world.maxs - world.mins;
1477
1478                                                 start_x = org_x + random() * delta_x;
1479                                                 start_y = org_y + random() * delta_y;
1480                                                 start_z = org_z + random() * delta_z;
1481
1482                                                 end_x = org_x + random() * delta_x;
1483                                                 end_y = org_y + random() * delta_y;
1484                                                 end_z = org_z + random() * delta_z;
1485
1486                                                 start = stov(vtos(start));
1487                                                 end = stov(vtos(end));
1488
1489                                                 tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
1490                                                 if(!trace_startsolid)
1491                                                 {
1492                                                         p = trace_endpos;
1493                                                         tracebox(p, PL_MIN, PL_MAX, p, MOVE_NOMONSTERS, world);
1494                                                         if(trace_startsolid || trace_fraction == 1)
1495                                                         {
1496                                                                 rint(42); // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
1497                                                                 tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
1498
1499                                                                 if(trace_startsolid)
1500                                                                 {
1501                                                                         // how much do we need to back off?
1502                                                                         safe = 1;
1503                                                                         unsafe = 0;
1504                                                                         for(;;)
1505                                                                         {
1506                                                                                 pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
1507                                                                                 tracebox(pos, PL_MIN, PL_MAX, pos, MOVE_NOMONSTERS, world);
1508                                                                                 if(trace_startsolid)
1509                                                                                 {
1510                                                                                         if((safe + unsafe) * 0.5 == unsafe)
1511                                                                                                 break;
1512                                                                                         unsafe = (safe + unsafe) * 0.5;
1513                                                                                 }
1514                                                                                 else
1515                                                                                 {
1516                                                                                         if((safe + unsafe) * 0.5 == safe)
1517                                                                                                 break;
1518                                                                                         safe = (safe + unsafe) * 0.5;
1519                                                                                 }
1520                                                                         }
1521
1522                                                                         print("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu\n");
1523                                                                         print("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu\n");
1524
1525                                                                         tracebox(p, PL_MIN + '0.1 0.1 0.1', PL_MAX - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, world);
1526                                                                         if(trace_startsolid)
1527                                                                                 print("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1528                                                                         else
1529                                                                                 print("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1530                                                                         break;
1531                                                                 }
1532
1533                                                                 q0 = p;
1534                                                                 dq = 0;
1535                                                                 dqf = 1;
1536                                                                 for(;;)
1537                                                                 {
1538                                                                         q = p + normalize(end - p) * (dq + dqf);
1539                                                                         if(q == q0)
1540                                                                                 break;
1541                                                                         tracebox(p, PL_MIN, PL_MAX, q, MOVE_NOMONSTERS, world);
1542                                                                         if(trace_startsolid)
1543                                                                                 error("THIS ONE cannot happen");
1544                                                                         if(trace_fraction > 0)
1545                                                                                 dq += dqf * trace_fraction;
1546                                                                         dqf *= 0.5;
1547                                                                         q0 = q;
1548                                                                 }
1549                                                                 if(dq > 0)
1550                                                                 {
1551                                                                         print("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1552                                                                         print("could go ", ftos(dq), " units further to ", vtos(q), "\n");
1553                                                                         break;
1554                                                                 }
1555                                                         }
1556                                                 }
1557                                         }
1558                                         return;
1559                                 }
1560
1561                                 case "debug2":
1562                                 {
1563                                         e = nextent(world);
1564                                         tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
1565                                         vv = trace_endpos;
1566                                         if(trace_fraction == 1)
1567                                         {
1568                                                 print("not above ground, aborting\n");
1569                                                 return;
1570                                         }
1571                                         f = 0;
1572                                         for(i = 0; i < 100000; ++i)
1573                                         {
1574                                                 dv = randomvec();
1575                                                 if(dv_z > 0)
1576                                                         dv = -1 * dv;
1577                                                 tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
1578                                                 if(trace_startsolid)
1579                                                         print("bug 1\n");
1580                                                 if(trace_fraction == 1)
1581                                                 if(dv_z < f)
1582                                                 {
1583                                                         print("bug 2: ", ftos(dv_x), " ", ftos(dv_y), " ", ftos(dv_z));
1584                                                         print(" (", ftos(asin(dv_z / vlen(dv)) * 180 / M_PI), " degrees)\n");
1585                                                         f = dv_z;
1586                                                 }
1587                                         }
1588                                         print("highest possible dist: ", ftos(f), "\n");
1589                                         return;
1590                                 }
1591
1592                                 case "walk":
1593                                 {
1594                                         if(argc == 4)
1595                                         {
1596                                                 e = nextent(world);
1597                                                 if(tracewalk(e, stov(argv(2)), e.mins, e.maxs, stov(argv(3)), MOVE_NORMAL))
1598                                                         print("can walk\n");
1599                                                 else
1600                                                         print("cannot walk\n");
1601                                                 return;
1602                                         }
1603                                 }
1604
1605                                 case "showline":
1606                                 {
1607                                         if(argc == 4)
1608                                         {
1609                                                 vv = stov(argv(2));
1610                                                 dv = stov(argv(3));
1611                                                 traceline(vv, dv, MOVE_NORMAL, world);
1612                                                 trailparticles(world, particleeffectnum("TR_NEXUIZPLASMA"), vv, trace_endpos);
1613                                                 trailparticles(world, particleeffectnum("TR_CRYLINKPLASMA"), trace_endpos, dv);
1614                                                 return;
1615                                         }
1616                                 }
1617
1618                                 // no default case, just go straight to invalid
1619                         }
1620                 }
1621
1622                 default:
1623                         print("Incorrect parameters for ^2trace^7\n");
1624                 case CMD_REQUEST_USAGE:
1625                 {
1626                         print("\nUsage:^3 sv_cmd trace command (startpos endpos)\n");
1627                         print("  Full list of commands here: \"debug, debug2, walk, showline.\"\n");
1628                         print("See also: ^2bbox, gettaginfo^7\n");
1629                         return;
1630                 }
1631         }
1632 }
1633
1634 void GameCommand_unlockteams(float request)
1635 {
1636         switch(request)
1637         {
1638                 case CMD_REQUEST_COMMAND:
1639                 {
1640                         if(teamplay)
1641                         {
1642                                 lockteams = 0;
1643                                 bprint("^1The teams are now unlocked.\n");
1644                         }
1645                         else
1646                         {
1647                                 bprint("unlockteams command can only be used in a team-based gamemode.\n");
1648                         }
1649                         return;
1650                 }
1651
1652                 default:
1653                 case CMD_REQUEST_USAGE:
1654                 {
1655                         print("\nUsage:^3 sv_cmd unlockteams\n");
1656                         print("  No arguments required.\n");
1657                         print("See also: ^2lockteams^7\n");
1658                         return;
1659                 }
1660         }
1661 }
1662
1663 void GameCommand_warp(float request, float argc)
1664 {
1665         switch (request)
1666         {
1667                 case CMD_REQUEST_COMMAND:
1668                 {
1669                         if(autocvar_g_campaign)
1670                         {
1671                                 if(argc >= 2)
1672                                 {
1673                                         CampaignLevelWarp(stof(argv(1)));
1674                                         print("Successfully warped to campaign level ", stof(argv(1)), ".\n");
1675                                 }
1676                                 else
1677                                 {
1678                                         CampaignLevelWarp(-1);
1679                                         print("Successfully warped to next campaign level.\n");
1680                                 }
1681                         }
1682                         else
1683                                 print("Not in campaign, can't level warp\n");
1684                         return;
1685                 }
1686
1687                 default:
1688                 case CMD_REQUEST_USAGE:
1689                 {
1690                         print("\nUsage:^3 sv_cmd warp [level]\n");
1691                         print("  'level' is the level to change campaign mode to.\n");
1692                         print("  if 'level' is not provided it will change to the next level.\n");
1693                         return;
1694                 }
1695         }
1696 }
1697
1698 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1699 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1700 void GameCommand_(float request)
1701 {
1702         switch(request)
1703         {
1704                 case CMD_REQUEST_COMMAND:
1705                 {
1706
1707                         return;
1708                 }
1709
1710                 default:
1711                 case CMD_REQUEST_USAGE:
1712                 {
1713                         print("\nUsage:^3 sv_cmd \n");
1714                         print("  No arguments required.\n");
1715                         return;
1716                 }
1717         }
1718 }
1719 */
1720
1721
1722 // ==================================
1723 //  Macro system for server commands
1724 // ==================================
1725
1726 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1727 #define SERVER_COMMANDS(request,arguments,command) \
1728         SERVER_COMMAND("adminmsg", GameCommand_adminmsg(request, arguments), "Send an admin message to a client directly") \
1729         SERVER_COMMAND("allready", GameCommand_allready(request), "Restart the server and reset the players") \
1730         SERVER_COMMAND("allspec", GameCommand_allspec(request, arguments), "Force all players to spectate") \
1731         SERVER_COMMAND("anticheat", GameCommand_anticheat(request, arguments), "Create an anticheat report for a client") \
1732         SERVER_COMMAND("animbench", GameCommand_animbench(request, arguments), "Benchmark model animation (LAGS)") \
1733         SERVER_COMMAND("bbox", GameCommand_bbox(request), "Print detailed information about world size") \
1734         SERVER_COMMAND("bot_cmd", GameCommand_bot_cmd(request, arguments, command), "Control and send commands to bots") \
1735         SERVER_COMMAND("cointoss", GameCommand_cointoss(request, arguments), "Flip a virtual coin and give random result") \
1736         SERVER_COMMAND("database", GameCommand_database(request, arguments), "Extra controls of the serverprogs database") \
1737         SERVER_COMMAND("defer_clear", GameCommand_defer_clear(request, arguments), "Clear all queued defer commands for a specific client") \
1738         SERVER_COMMAND("defer_clear_all", GameCommand_defer_clear_all(request), "Clear all queued defer commands for all clients") \
1739         SERVER_COMMAND("delrec", GameCommand_delrec(request, arguments), "Delete race time record for a map") \
1740         SERVER_COMMAND("effectindexdump", GameCommand_effectindexdump(request), "Dump list of effects from code and effectinfo.txt") \
1741         SERVER_COMMAND("extendmatchtime", GameCommand_extendmatchtime(request), "Increase the timelimit value incrementally") \
1742         SERVER_COMMAND("find", GameCommand_find(request, arguments), "Search through entities for matching classname") \
1743         SERVER_COMMAND("gametype", GameCommand_gametype(request, arguments), "Simple command to change the active gametype") \
1744         SERVER_COMMAND("gettaginfo", GameCommand_gettaginfo(request, arguments), "Get specific information about a weapon model") \
1745         SERVER_COMMAND("gotomap", GameCommand_gotomap(request, arguments), "Simple command to switch to another map") \
1746         SERVER_COMMAND("lockteams", GameCommand_lockteams(request), "Disable the ability for players to switch or enter teams") \
1747         SERVER_COMMAND("make_mapinfo", GameCommand_make_mapinfo(request), "Automatically rebuild mapinfo files") \
1748         SERVER_COMMAND("moveplayer", GameCommand_moveplayer(request, arguments), "Change the team/status of a player") \
1749         SERVER_COMMAND("nospectators", GameCommand_nospectators(request), "Automatically remove spectators from a match") \
1750         SERVER_COMMAND("playerdemo", GameCommand_playerdemo(request, arguments), "Control the ability to save demos of players") \
1751         SERVER_COMMAND("printstats", GameCommand_printstats(request), "Dump eventlog player stats and other score information") \
1752         SERVER_COMMAND("radarmap", GameCommand_radarmap(request, arguments), "Generate a radar image of the map") \
1753         SERVER_COMMAND("reducematchtime", GameCommand_reducematchtime(request), "Decrease the timelimit value incrementally") \
1754         SERVER_COMMAND("setbots", GameCommand_setbots(request, arguments), "Adjust how many bots are in the match") \
1755         SERVER_COMMAND("shuffleteams", GameCommand_shuffleteams(request), "Randomly move players to different teams") \
1756         SERVER_COMMAND("stuffto", GameCommand_stuffto(request, arguments), "Send a command to be executed on a client") \
1757         SERVER_COMMAND("trace", GameCommand_trace(request, arguments), "Various debugging tools with tracing") \
1758         SERVER_COMMAND("unlockteams", GameCommand_unlockteams(request), "Enable the ability for players to switch or enter teams") \
1759         SERVER_COMMAND("warp", GameCommand_warp(request, arguments), "Choose different level in campaign") \
1760         /* nothing */
1761
1762 void GameCommand_macro_help()
1763 {
1764         #define SERVER_COMMAND(name,function,description) \
1765                 { print("  ^2", name, "^7: ", description, "\n"); }
1766
1767         SERVER_COMMANDS(0, 0, "")
1768         #undef SERVER_COMMAND
1769
1770         return;
1771 }
1772
1773 float GameCommand_macro_command(float argc, string command)
1774 {
1775         #define SERVER_COMMAND(name,function,description) \
1776                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
1777
1778         SERVER_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
1779         #undef SERVER_COMMAND
1780
1781         return FALSE;
1782 }
1783
1784 float GameCommand_macro_usage(float argc)
1785 {
1786         #define SERVER_COMMAND(name,function,description) \
1787                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
1788
1789         SERVER_COMMANDS(CMD_REQUEST_USAGE, argc, "")
1790         #undef SERVER_COMMAND
1791
1792         return FALSE;
1793 }
1794
1795 void GameCommand_macro_write_aliases(float fh)
1796 {
1797         #define SERVER_COMMAND(name,function,description) \
1798                 { CMD_Write_Alias("qc_cmd_sv", name, description); }
1799
1800         SERVER_COMMANDS(0, 0, "")
1801         #undef SERVER_COMMAND
1802
1803         return;
1804 }
1805
1806
1807 // =========================================
1808 //  Main Function Called By Engine (sv_cmd)
1809 // =========================================
1810 // If this function exists, game code handles gamecommand instead of the engine code.
1811
1812 void GameCommand(string command)
1813 {
1814         float argc = tokenize_console(command);
1815
1816         // Guide for working with argc arguments by example:
1817         // argc:   1    - 2      - 3     - 4
1818         // argv:   0    - 1      - 2     - 3
1819         // cmd     vote - master - login - password
1820
1821         if(strtolower(argv(0)) == "help")
1822         {
1823                 if(argc == 1)
1824                 {
1825                         print("\nServer console commands:\n");
1826                         GameCommand_macro_help();
1827
1828                         print("\nBanning commands:\n");
1829                         BanCommand_macro_help();
1830
1831                         print("\nCommon networked commands:\n");
1832                         CommonCommand_macro_help(world);
1833
1834                         print("\nGeneric commands shared by all programs:\n");
1835                         GenericCommand_macro_help();
1836
1837                         print("\nUsage:^3 sv_cmd COMMAND...^7, where possible commands are listed above.\n");
1838                         print("For help about a specific command, type sv_cmd help COMMAND\n");
1839
1840                         return;
1841                 }
1842                 else if(BanCommand_macro_usage(argc)) // Instead of trying to call a command, we're going to see detailed information about it
1843                 {
1844                         return;
1845                 }
1846                 else if(CommonCommand_macro_usage(argc, world)) // same here, but for common commands instead
1847                 {
1848                         return;
1849                 }
1850                 else if(GenericCommand_macro_usage(argc)) // same here, but for generic commands instead
1851                 {
1852                         return;
1853                 }
1854                 else if(GameCommand_macro_usage(argc)) // finally try for normal commands too
1855                 {
1856                         return;
1857                 }
1858         }
1859         else if(BanCommand(command))
1860         {
1861                 return; // handled by server/command/ipban.qc
1862         }
1863         else if(CommonCommand_macro_command(argc, world, command))
1864         {
1865                 return; // handled by server/command/common.qc
1866         }
1867         else if(GenericCommand(command))
1868         {
1869                 return; // handled by common/command/generic.qc
1870         }
1871         else if(GameCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
1872         {
1873                 return; // handled by one of the above GameCommand_* functions
1874         }
1875
1876         // nothing above caught the command, must be invalid
1877         print(((command != "") ? strcat("Unknown server command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try sv_cmd help.\n");
1878
1879         return;
1880 }