qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50 float headshot;
  51 float damage_headshotbonus; // bonus multiplier for head shots, set to 0 after use
  52
  53 .float dmg_team;
  54 .float teamkill_complain;
  55 .float teamkill_soundtime;
  56 .entity teamkill_soundsource;
  57 .entity pusher;
  58 .float istypefrag;
  59 .float taunt_soundtime;
  60
  61
  62 float IsDifferentTeam(entity a, entity b)
  63 {
  64         if(teamplay)
  65         {
  66                 if(a.team == b.team)
  67                         return 0;
  68         }
  69         else
  70         {
  71                 if(a == b)
  72                         return 0;
  73         }
  74         return 1;
  75 }
  76
  77 float IsFlying(entity a)
  78 {
  79         if(a.flags & FL_ONGROUND)
  80                 return 0;
  81         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  82                 return 0;
  83         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  84         if(trace_fraction < 1)
  85                 return 0;
  86         return 1;
  87 }
  88
  89 vector GetHeadshotMins(entity targ)
  90 {
  91         return '-0.5 0 0' * PL_HEAD_x + '0 -0.5 0' * PL_HEAD_y + '0 0 1' * (targ.maxs_z - PL_HEAD_z);
  92 }
  93 vector GetHeadshotMaxs(entity targ)
  94 {
  95         return '0.5 0 0' * PL_HEAD_x + '0 0.5 0' * PL_HEAD_y + '0 0 1' * targ.maxs_z;
  96 }
  97
  98 void UpdateFrags(entity player, float f)
  99 {
 100         PlayerTeamScore_AddScore(player, f);
 101 }
 102
 103 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
 104 void W_SwitchWeapon_Force(entity e, float w);
 105 entity GiveFrags_randomweapons;
 106 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
 107 {
 108         // TODO route through PlayerScores instead
 109         if(gameover) return;
 110
 111         if(f < 0)
 112         {
 113                 if(targ == attacker)
 114                 {
 115                         // suicide
 116                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 117                 }
 118                 else
 119                 {
 120                         // teamkill
 121                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 122                 }
 123         }
 124         else
 125         {
 126                 // regular frag
 127                 PlayerScore_Add(attacker, SP_KILLS, 1);
 128                 if(targ.playerid)
 129                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 130         }
 131
 132         PlayerScore_Add(targ, SP_DEATHS, 1);
 133
 134         if(g_arena || g_ca)
 135                 if(autocvar_g_arena_roundbased)
 136                         return;
 137
 138         if(targ != attacker) // not for suicides
 139         if(g_weaponarena_random)
 140         {
 141                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 142                 float culprit;
 143                 culprit = DEATH_WEAPONOF(deathtype);
 144                 if(!culprit)
 145                         culprit = attacker.weapon;
 146                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
 147                         culprit = attacker.weapon;
 148
 149                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 150                 {
 151                         // no exchange
 152                 }
 153                 else
 154                 {
 155                         if(!GiveFrags_randomweapons)
 156                         {
 157                                 GiveFrags_randomweapons = spawn();
 158                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 159                         }
 160
 161                         if(inWarmupStage)
 162                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
 163                         else
 164                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
 165
 166                         // all others (including the culprit): remove
 167                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
 168                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
 169
 170                         // among the remaining ones, choose one by random
 171                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 172
 173                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
 174                         {
 175                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
 176                                 WEPSET_ANDNOT_EW(attacker, culprit);
 177                         }
 178                 }
 179
 180                 // after a frag, choose another random weapon set
 181                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
 182                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 183         }
 184
 185         // FIXME fix the mess this is (we have REAL points now!)
 186         entity oldself;
 187         oldself = self;
 188         self = attacker;
 189         frag_attacker = attacker;
 190         frag_target = targ;
 191         frag_score = f;
 192         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 193         {
 194                 f = frag_score;
 195                 self = oldself;
 196         }
 197         else
 198         {
 199                 self = oldself;
 200                 if(g_runematch)
 201                 {
 202                         f = RunematchHandleFrags(attacker, targ, f);
 203                 }
 204                 else if(g_lms)
 205                 {
 206                         // remove a life
 207                         float tl;
 208                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 209                         if(tl < lms_lowest_lives)
 210                                 lms_lowest_lives = tl;
 211                         if(tl <= 0)
 212                         {
 213                                 if(!lms_next_place)
 214                                         lms_next_place = player_count;
 215                                 else
 216                                         lms_next_place = min(lms_next_place, player_count);
 217                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 218                                 --lms_next_place;
 219                         }
 220                         f = 0;
 221                 }
 222         }
 223
 224         attacker.totalfrags += f;
 225
 226         if(f)
 227                 UpdateFrags(attacker, f);
 228 }
 229
 230 string Obituary_ExtraFragInfo(entity player) // Extra fragmessage information
 231 {
 232         string health_output = string_null;
 233         string ping_output = string_null;
 234         string handicap_output = string_null;
 235         string output = string_null;
 236
 237         if(autocvar_sv_fraginfo && ((autocvar_sv_fraginfo == 2) || inWarmupStage))
 238         {
 239                 // health/armor of attacker (person who killed you)
 240                 if(autocvar_sv_fraginfo_stats && (player.health >= 1))
 241                         health_output = strcat("^7(Health ^1", ftos(rint(player.health)), "^7 / Armor ^2", ftos(rint(player.armorvalue)), "^7)");
 242
 243                 // ping display
 244                 if(autocvar_sv_fraginfo_ping)
 245                         ping_output = ((clienttype(player) == CLIENTTYPE_BOT) ? "^2Bot" : strcat("Ping ", ((player.ping >= 150) ? "^1" : "^2"), ftos(rint(player.ping)), "ms"));
 246
 247                 // handicap display
 248                 if(autocvar_sv_fraginfo_handicap)
 249                 {
 250                         if(autocvar_sv_fraginfo_handicap == 2)
 251                                 handicap_output = strcat(output, strcat("Handicap ^2", ((player.cvar_cl_handicap <= 1) ? "Off" : ftos(rint(player.cvar_cl_handicap)))));
 252                         else if(player.cvar_cl_handicap) // with _handicap 1, only show this if there actually is a handicap enabled.
 253                                 handicap_output = strcat("Handicap ^2", ftos(rint(player.cvar_cl_handicap)));
 254                 }
 255
 256                 // format the string
 257                 output = strcat(health_output, (health_output ? ((ping_output || handicap_output) ? " ^7(" : "") : ((ping_output || handicap_output) ? "^7(" : "")),
 258                         ping_output, (handicap_output ? "^7 / " : ""),
 259                         handicap_output, ((ping_output || handicap_output) ? "^7)" : ""));
 260
 261                 // add new line to the beginning if there is a message
 262                 if(output) { output = strcat("\n", output); }
 263         }
 264
 265         return output;
 266 }
 267
 268 string AppendItemcodes(string s, entity player)
 269 {
 270         float w;
 271         w = player.weapon;
 272         //if(w == 0)
 273         //      w = player.switchweapon;
 274         if(w == 0)
 275                 w = player.cnt; // previous weapon!
 276         s = strcat(s, ftos(w));
 277         if(time < player.strength_finished)
 278                 s = strcat(s, "S");
 279         if(time < player.invincible_finished)
 280                 s = strcat(s, "I");
 281         if(player.flagcarried != world)
 282                 s = strcat(s, "F");
 283         if(player.BUTTON_CHAT)
 284                 s = strcat(s, "T");
 285         if(player.kh_next)
 286                 s = strcat(s, "K");
 287         if(player.runes)
 288                 s = strcat(s, "|", ftos(player.runes));
 289         return s;
 290 }
 291
 292 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 293 {
 294         string s;
 295         if(!autocvar_sv_eventlog)
 296                 return;
 297         s = strcat(":kill:", mode);
 298         s = strcat(s, ":", ftos(killer.playerid));
 299         s = strcat(s, ":", ftos(killed.playerid));
 300         s = strcat(s, ":type=", ftos(deathtype));
 301         s = strcat(s, ":items=");
 302         s = AppendItemcodes(s, killer);
 303         if(killed != killer)
 304         {
 305                 s = strcat(s, ":victimitems=");
 306                 s = AppendItemcodes(s, killed);
 307         }
 308         GameLogEcho(s);
 309 }
 310
 311 void Obituary_Notification(entity notif_target, string s1, string s2, string s3, float deathtype)
 312 {
 313         #define DEATHTYPE(name,type,notification,first,last) \
 314                 { if((deathtype == max(0, name)) && max(0, type) && max(0, notification)) { Send_Notification(type, notif_target, notification, s1, s2, s3); return; } }
 315
 316         DEATHTYPES
 317         backtrace("Unhandled deathtype. Please notify Samual!\n");
 318 }
 319
 320 void Obituary (entity attacker, entity inflictor, entity targ, float deathtype)
 321 {
 322         string  s, a, msg;
 323         float w, type;
 324
 325         string s1, s2, s3;
 326
 327         if (targ.classname == "player")
 328         {
 329                 s = targ.netname;
 330                 a = attacker.netname;
 331
 332                 if (targ == attacker) // suicides
 333                 {
 334                         s1 = ((deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE) ? ColoredTeamName(targ.team) : "");
 335
 336                         // no "killed your own dumb self" message in CTS
 337             if(!g_cts) { Obituary_Notification(targ, s1, "", "", deathtype); }
 338
 339                         if(deathtype != DEATH_TEAMCHANGE && deathtype != DEATH_QUIET)
 340                         {
 341                                 LogDeath("suicide", deathtype, targ, targ);
 342                                 GiveFrags(attacker, targ, -1, deathtype);
 343                         }
 344
 345                         s1 = targ.netname;
 346                         s2 = ((targ.killcount > 2) ? ftos(targ.killcount) : "");
 347
 348                         //if(teamplay && deathtype == DEATH_MIRRORDAMAGE)
 349                         //      { deathtype = ((attacker.team == COLOR_TEAM1) ? KILL_TEAM_SUICIDE_RED : KILL_TEAM_SUICIDE_BLUE); }
 350
 351                         Obituary_Notification(world, s1, s2, "", deathtype);
 352                         //Send_KillNotification(s, s2, ftos(w), deathtype, MSG_SUICIDE);
 353                 }
 354                 else if (attacker.classname == "player")
 355                 {
 356                         if(!IsDifferentTeam(attacker, targ))
 357                         {
 358                                 //type = ((attacker.team == COLOR_TEAM1) ? KILL_TEAM_FRAG_RED : KILL_TEAM_FRAG_BLUE);
 359
 360                                 GiveFrags(attacker, targ, -1, deathtype);
 361
 362                                 //Send_CSQC_KillCenterprint(attacker, s, "", type);
 363
 364                                 if (targ.killcount > 2)
 365                                         msg = ftos(targ.killcount);
 366                                 else
 367                                         msg = "";
 368
 369                                 if (attacker.killcount > 2) {
 370                                         msg = ftos(attacker.killcount);
 371                                         type = KILL_TEAM_SPREE;
 372                                 }
 373                                 Send_KillNotification(a, s, msg, type, MSG_KILL);
 374
 375                                 attacker.killcount = 0;
 376
 377                                 LogDeath("tk", deathtype, attacker, targ);
 378                         }
 379                         else
 380                         {
 381                                 if (!checkrules_firstblood)
 382                                 {
 383                                         checkrules_firstblood = TRUE;
 384                                         Send_KillNotification(a, "", "", KILL_FIRST_BLOOD, MSG_KILL);
 385                                         // TODO: make these print a newline if they dont
 386                                         Send_CSQC_KillCenterprint(attacker, "", "", KILL_FIRST_BLOOD, MSG_KILL);
 387                                         Send_CSQC_KillCenterprint(targ, "", "", KILL_FIRST_VICTIM, MSG_KILL);
 388                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 389                                         PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 390                                 }
 391
 392                                 if(targ.istypefrag) {
 393                                         Send_CSQC_KillCenterprint(attacker, s, Obituary_ExtraFragInfo(targ), KILL_TYPEFRAG, MSG_KILL);
 394                                         Send_CSQC_KillCenterprint(targ, a, Obituary_ExtraFragInfo(attacker), KILL_TYPEFRAGGED, MSG_KILL);
 395                                 } else {
 396                                         Send_CSQC_KillCenterprint(attacker, s, Obituary_ExtraFragInfo(targ), KILL_FRAG, MSG_KILL);
 397                                         Send_CSQC_KillCenterprint(targ, a, Obituary_ExtraFragInfo(attacker), KILL_FRAGGED, MSG_KILL);
 398                                 }
 399
 400                                 attacker.taunt_soundtime = time + 1;
 401
 402                                 if (deathtype == DEATH_HURTTRIGGER && inflictor.message2 != "")
 403                                         msg = inflictor.message2;
 404                                 else if (deathtype == DEATH_CUSTOM)
 405                                         msg = deathmessage;
 406                                 else
 407                                         msg = "";
 408
 409                                 if(strstrofs(msg, "%", 0) < 0)
 410                                         msg = strcat("%s ", msg, " by %s");
 411
 412                                 Send_KillNotification(a, s, msg, deathtype, MSG_KILL);
 413
 414                                 GiveFrags(attacker, targ, 1, deathtype);
 415
 416                                 if (targ.killcount > 2) {
 417                                         Send_KillNotification(s, ftos(targ.killcount), a, KILL_END_SPREE, MSG_SPREE);
 418                                 }
 419
 420                                 attacker.killcount = attacker.killcount + 1;
 421
 422                                 if (attacker.killcount == 3)
 423                                 {
 424                                         Send_KillNotification(a, "", "", KILL_SPREE_3, MSG_SPREE);
 425                                         AnnounceTo(attacker, "03kills");
 426                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_3, 1);
 427                                 }
 428                                 else if (attacker.killcount == 5)
 429                                 {
 430                                         Send_KillNotification(a, "", "", KILL_SPREE_5, MSG_SPREE);
 431                                         AnnounceTo(attacker, "05kills");
 432                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_5, 1);
 433                                 }
 434                                 else if (attacker.killcount == 10)
 435                                 {
 436                                         Send_KillNotification(a, "", "", KILL_SPREE_10, MSG_SPREE);
 437                                         AnnounceTo(attacker, "10kills");
 438                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_10, 1);
 439                                 }
 440                                 else if (attacker.killcount == 15)
 441                                 {
 442                                         Send_KillNotification(a, "", "", KILL_SPREE_15, MSG_SPREE);
 443                                         AnnounceTo(attacker, "15kills");
 444                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_15, 1);
 445                                 }
 446                                 else if (attacker.killcount == 20)
 447                                 {
 448                                         Send_KillNotification(a, "", "", KILL_SPREE_20, MSG_SPREE);
 449                                         AnnounceTo(attacker, "20kills");
 450                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_20, 1);
 451                                 }
 452                                 else if (attacker.killcount == 25)
 453                                 {
 454                                         Send_KillNotification(a, "", "", KILL_SPREE_25, MSG_SPREE);
 455                                         AnnounceTo(attacker, "25kills");
 456                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_25, 1);
 457                                 }
 458                                 else if (attacker.killcount == 30)
 459                                 {
 460                                         Send_KillNotification(a, "", "", KILL_SPREE_30, MSG_SPREE);
 461                                         AnnounceTo(attacker, "30kills");
 462                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_30, 1);
 463                                 }
 464                                 else if (attacker.killcount > 2) {
 465                                         Send_KillNotification(a, ftos(attacker.killcount), "", KILL_SPREE, MSG_SPREE);
 466                                 }
 467                                 LogDeath("frag", deathtype, attacker, targ);
 468                         }
 469                 }
 470                 else
 471                 {
 472                         Send_CSQC_KillCenterprint(targ, "", "", deathtype, MSG_KILL_ACTION);
 473                         if (deathtype == DEATH_HURTTRIGGER && inflictor.message != "")
 474                                 msg = inflictor.message;
 475                         else if (deathtype == DEATH_CUSTOM)
 476                                 msg = deathmessage;
 477                         else
 478                                 msg = "";
 479                         if(strstrofs(msg, "%", 0) < 0)
 480                                 msg = strcat("%s ", msg);
 481
 482                         GiveFrags(targ, targ, -1, deathtype);
 483                         if(PlayerScore_Add(targ, SP_SCORE, 0) == -5) {
 484                                 AnnounceTo(targ, "botlike");
 485                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 486                         }
 487                         Send_KillNotification(s, msg, "", deathtype, MSG_KILL_ACTION);
 488
 489                         if (targ.killcount > 2)
 490                                 Send_KillNotification(s, ftos(targ.killcount), "", 0, MSG_KILL_ACTION_SPREE);
 491
 492                         LogDeath("accident", deathtype, targ, targ);
 493                 }
 494
 495                 targ.death_origin = targ.origin;
 496                 if(targ != attacker)
 497                         targ.killer_origin = attacker.origin;
 498
 499                 // FIXME: this should go in PutClientInServer
 500                 if (targ.killcount)
 501                         targ.killcount = 0;
 502         }
 503 }
 504
 505 // these are updated by each Damage call for use in button triggering and such
 506 entity damage_targ;
 507 entity damage_inflictor;
 508 entity damage_attacker;
 509
 510 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 511 {
 512         float mirrordamage;
 513         float mirrorforce;
 514         float teamdamage0;
 515         entity attacker_save;
 516         mirrordamage = 0;
 517         mirrorforce = 0;
 518
 519         if (gameover || targ.killcount == -666)
 520                 return;
 521
 522         entity oldself;
 523         oldself = self;
 524         self = targ;
 525         damage_targ = targ;
 526         damage_inflictor = inflictor;
 527         damage_attacker = attacker;
 528                 attacker_save = attacker;
 529
 530         if(targ.classname == "player")
 531                 if(targ.hook)
 532                         if(targ.hook.aiment)
 533                                 if(targ.hook.aiment == attacker)
 534                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 535
 536         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 537         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 538         {
 539                 if(targ.classname == "player")
 540                         if not(IsDifferentTeam(targ, attacker))
 541                         {
 542                                 self = oldself;
 543                                 return;
 544                         }
 545         }
 546
 547         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE || deathtype == DEATH_QUIET)
 548         {
 549                 // These are ALWAYS lethal
 550                 // No damage modification here
 551                 // Instead, prepare the victim for his death...
 552                 targ.armorvalue = 0;
 553                 targ.spawnshieldtime = 0;
 554                 targ.health = 0.9; // this is < 1
 555                 targ.flags -= targ.flags & FL_GODMODE;
 556                 damage = 100000;
 557         }
 558         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 559         {
 560                 // no processing
 561         }
 562         else
 563         {
 564                 /*
 565                 skill based bot damage? gtfo. (tZork)
 566                 if (targ.classname == "player")
 567                 if (attacker.classname == "player")
 568                 if (!targ.isbot)
 569                 if (attacker.isbot)
 570                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 571         */
 572
 573                 // nullify damage if teamplay is on
 574                 if(deathtype != DEATH_TELEFRAG)
 575                 if(attacker.classname == "player")
 576                 {
 577                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 578                         {
 579                                 damage = 0;
 580                                 force = '0 0 0';
 581                         }
 582                         else if(!IsDifferentTeam(attacker, targ))
 583                         {
 584                                 if(autocvar_teamplay_mode == 1)
 585                                         damage = 0;
 586                                 else if(attacker != targ)
 587                                 {
 588                                         if(autocvar_teamplay_mode == 3)
 589                                                 damage = 0;
 590                                         else if(autocvar_teamplay_mode == 4)
 591                                         {
 592                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 593                                                 {
 594                                                         teamdamage0 = max(attacker.dmg_team, autocvar_g_teamdamage_threshold);
 595                                                         attacker.dmg_team = attacker.dmg_team + damage;
 596                                                         if(attacker.dmg_team > teamdamage0 && !g_ca)
 597                                                                 mirrordamage = autocvar_g_mirrordamage * (attacker.dmg_team - teamdamage0);
 598                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 599                                                         if(g_minstagib)
 600                                                         {
 601                                                                 if(autocvar_g_friendlyfire == 0)
 602                                                                         damage = 0;
 603                                                         }
 604                                                         else if(g_ca)
 605                                                                 damage = 0;
 606                                                         else
 607                                                                 damage = autocvar_g_friendlyfire * damage;
 608                                                         // mirrordamage will be used LATER
 609
 610                                                         if(autocvar_g_mirrordamage_virtual)
 611                                                         {
 612                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 613                                                                 attacker.dmg_take += v_x;
 614                                                                 attacker.dmg_save += v_y;
 615                                                                 attacker.dmg_inflictor = inflictor;
 616                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 617                                                                 mirrorforce = 0;
 618                                                         }
 619
 620                                                         if(autocvar_g_friendlyfire_virtual)
 621                                                         {
 622                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 623                                                                 targ.dmg_take += v_x;
 624                                                                 targ.dmg_save += v_y;
 625                                                                 targ.dmg_inflictor = inflictor;
 626                                                                 damage = 0;
 627                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 628                                                                         force = '0 0 0';
 629                                                         }
 630                                                 }
 631                                                 else
 632                                                         damage = 0;
 633                                         }
 634                                 }
 635                         }
 636                 }
 637
 638                 if(targ.classname == "player")
 639                 if(attacker.classname == "player")
 640                 if(attacker != targ)
 641                 {
 642                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 643                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 644                 }
 645
 646                 if(targ.classname == "player")
 647                 if (g_minstagib)
 648                 {
 649                         if ((deathtype == DEATH_FALL)  ||
 650                                 (deathtype == DEATH_DROWN) ||
 651                                 (deathtype == DEATH_SLIME) ||
 652                                 (deathtype == DEATH_LAVA)  ||
 653                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 654                         {
 655                                 self = oldself;
 656                                 return;
 657                         }
 658                         if(damage > 0)
 659                             damage = 10000;
 660                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 661                         {
 662                                 targ.armorvalue -= 1;
 663                                 centerprint(targ, strcat("^3Remaining extra lives: ",ftos(targ.armorvalue)));
 664                                 damage = 0;
 665                                 targ.hitsound += 1;
 666                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 667                         }
 668                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 669                         {
 670                                 damage = 0;
 671                                 mirrordamage = 0;
 672                                 if (targ != attacker)
 673                                 {
 674                                         if ((targ.health >= 1) && (targ.classname == "player"))
 675                                                 centerprint(attacker, "Secondary fire inflicts no damage!");
 676                                         force = '0 0 0';
 677                                         // keep mirrorforce
 678                                         attacker = targ;
 679                                 }
 680                         }
 681                 }
 682
 683                 if not(DEATH_ISSPECIAL(deathtype))
 684                 {
 685                         damage *= g_weapondamagefactor;
 686                         mirrordamage *= g_weapondamagefactor;
 687                         force = force * g_weaponforcefactor;
 688                         mirrorforce *= g_weaponforcefactor;
 689                 }
 690
 691                 // should this be changed at all? If so, in what way?
 692                 frag_attacker = attacker;
 693                 frag_target = targ;
 694                 frag_damage = damage;
 695                 frag_force = force;
 696         frag_deathtype = deathtype;
 697                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 698                 damage = frag_damage;
 699                 force = frag_force;
 700
 701                 // apply strength multiplier
 702                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 703                 {
 704                         if(targ == attacker)
 705                         {
 706                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 707                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
 708                         }
 709                         else
 710                         {
 711                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
 712                                 force = force * autocvar_g_balance_powerup_strength_force;
 713                         }
 714                 }
 715
 716                 // apply invincibility multiplier
 717                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 718                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 719
 720                 if (targ == attacker)
 721                 {
 722                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 723                                 damage = 0;
 724                         else
 725                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 726                 }
 727
 728                 if(g_runematch)
 729                 {
 730                         // apply strength rune
 731                         if (attacker.runes & RUNE_STRENGTH)
 732                         {
 733                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 734                                 {
 735                                         damage = damage * autocvar_g_balance_rune_strength_combo_damage;
 736                                         force = force * autocvar_g_balance_rune_strength_combo_force;
 737                                 }
 738                                 else
 739                                 {
 740                                         damage = damage * autocvar_g_balance_rune_strength_damage;
 741                                         force = force * autocvar_g_balance_rune_strength_force;
 742                                 }
 743                         }
 744                         else if (attacker.runes & CURSE_WEAK)
 745                         {
 746                                 damage = damage * autocvar_g_balance_curse_weak_damage;
 747                                 force = force * autocvar_g_balance_curse_weak_force;
 748                         }
 749
 750                         // apply defense rune
 751                         if (targ.runes & RUNE_DEFENSE)
 752                         {
 753                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 754                                         damage = damage * autocvar_g_balance_rune_defense_combo_takedamage;
 755                                 else
 756                                         damage = damage * autocvar_g_balance_rune_defense_takedamage;
 757                         }
 758                         else if (targ.runes & CURSE_VULNER)
 759                                 damage = damage * autocvar_g_balance_curse_vulner_takedamage;
 760                 }
 761
 762                 // count the damage
 763                 if(attacker)
 764                 if(!targ.deadflag)
 765                 if(targ.takedamage == DAMAGE_AIM)
 766                 if(targ != attacker)
 767                 {
 768                         if(damage_headshotbonus)
 769                         {
 770                                 if(targ.classname == "player")
 771                                 {
 772                                         // HEAD SHOT:
 773                                         // find height of hit on player axis
 774                                         // if above view_ofs and below maxs, and also in the middle half of the bbox, it is head shot
 775                                         vector headmins, headmaxs, org;
 776                                         org = antilag_takebackorigin(targ, time - ANTILAG_LATENCY(attacker));
 777                                         headmins = org + GetHeadshotMins(targ);
 778                                         headmaxs = org + GetHeadshotMaxs(targ);
 779                                         if(trace_hits_box(railgun_start, railgun_end, headmins, headmaxs))
 780                                         {
 781                                                 deathtype |= HITTYPE_HEADSHOT;
 782                                         }
 783                                 }
 784                                 else if(targ.classname == "turret_head")
 785                                 {
 786                                         deathtype |= HITTYPE_HEADSHOT;
 787                                 }
 788                                 if(deathtype & HITTYPE_HEADSHOT)
 789                                         if(damage_headshotbonus > 0)
 790                                                 damage *= 1 + damage_headshotbonus;
 791                         }
 792
 793                         entity victim;
 794                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 795                                 victim = targ.owner;
 796                         else
 797                                 victim = targ;
 798
 799                         if(victim.classname == "player" || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 800                         {
 801                                 if(IsDifferentTeam(victim, attacker))
 802                                 {
 803                                         if(damage > 0)
 804                                         {
 805                                                 if(deathtype != DEATH_FIRE)
 806                                                 {
 807                                                         if(victim.BUTTON_CHAT)
 808                                                                 attacker.typehitsound += 1;
 809                                                         else
 810                                                                 attacker.hitsound += 1;
 811                                                 }
 812
 813                                                 damage_goodhits += 1;
 814                                                 damage_gooddamage += damage;
 815
 816                                                 if not(DEATH_ISSPECIAL(deathtype))
 817                                                 {
 818                                                         if(targ.classname == "player") // don't do this for vehicles
 819                                                         if(!g_minstagib)
 820                                                         if(IsFlying(victim))
 821                                                                 yoda = 1;
 822
 823                                                         if(g_minstagib)
 824                                                         if(victim.items & IT_STRENGTH)
 825                                                                 yoda = 1;
 826
 827                                                         if(deathtype & HITTYPE_HEADSHOT)
 828                                                                 headshot = 1;
 829                                                 }
 830                                                 if(g_ca)
 831                                                         PlayerScore_Add(attacker, SP_SCORE, damage * autocvar_g_ca_damage2score_multiplier);
 832                                         }
 833                                 }
 834                                 else
 835                                 {
 836                                         if(deathtype != DEATH_FIRE)
 837                                         {
 838                                                 attacker.typehitsound += 1;
 839                                         }
 840                                         if(mirrordamage > 0)
 841                                                 if(time > attacker.teamkill_complain)
 842                                                 {
 843                                                         attacker.teamkill_complain = time + 5;
 844                                                         attacker.teamkill_soundtime = time + 0.4;
 845                                                         attacker.teamkill_soundsource = targ;
 846                                                 }
 847                                 }
 848                         }
 849                 }
 850         }
 851
 852         // apply push
 853         if (self.damageforcescale)
 854         if (vlen(force))
 855         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 856         {
 857                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 858                 if(self.movetype == MOVETYPE_PHYSICS)
 859                 {
 860                         entity farcent;
 861                         farcent = spawn();
 862                         farcent.classname = "farce";
 863                         farcent.enemy = self;
 864                         farcent.movedir = farce * 10;
 865                         if(self.mass)
 866                                 farcent.movedir = farcent.movedir * self.mass;
 867                         farcent.origin = hitloc;
 868                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 869                         farcent.nextthink = time + 0.1;
 870                         farcent.think = SUB_Remove;
 871                 }
 872                 else
 873                         self.velocity = self.velocity + farce;
 874                 self.flags &~= FL_ONGROUND;
 875                 UpdateCSQCProjectile(self);
 876         }
 877         // apply damage
 878         if (damage != 0 || (self.damageforcescale && vlen(force)))
 879         if (self.event_damage)
 880                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 881         self = oldself;
 882
 883         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 884         {
 885                 if(g_runematch)
 886                 {
 887                         if (attacker.runes & RUNE_VAMPIRE)
 888                         {
 889                         // apply vampire rune
 890                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 891                                 {
 892                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb;
 893                                         attacker.health = bound(
 894                                                 autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 40
 895                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb,
 896                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 897                                 }
 898                                 else
 899                                 {
 900                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_absorb;
 901                                         attacker.health = bound(
 902                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
 903                                                                                         // empathy won't let you gain health in the same way...
 904                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_absorb,
 905                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 906                                         }
 907                         }
 908                         // apply empathy curse
 909                         else if (attacker.runes & CURSE_EMPATHY)
 910                         {
 911                                 attacker.health = bound(
 912                                         autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 20
 913                                         attacker.health + damage * autocvar_g_balance_curse_empathy_takedamage,
 914                                         attacker.health);
 915                         }
 916                 }
 917         }
 918
 919         // apply mirror damage if any
 920         if(mirrordamage > 0 || mirrorforce > 0)
 921         {
 922                 attacker = attacker_save;
 923                 if(g_minstagib)
 924                 if(mirrordamage > 0)
 925                 {
 926                         // just lose extra LIVES, don't kill the player for mirror damage
 927                         if(attacker.armorvalue > 0)
 928                         {
 929                                 attacker.armorvalue = attacker.armorvalue - 1;
 930                                 centerprint(attacker, strcat("^3Remaining extra lives: ",ftos(attacker.armorvalue)));
 931                                 attacker.hitsound += 1;
 932                         }
 933                         mirrordamage = 0;
 934                 }
 935
 936                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 937                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 938         }
 939 }
 940
 941 float RadiusDamage_running;
 942 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 943         // Returns total damage applies to creatures
 944 {
 945         entity  targ;
 946         vector  blastorigin;
 947         vector  force;
 948         float   total_damage_to_creatures;
 949         entity  next;
 950         float   tfloordmg;
 951         float   tfloorforce;
 952
 953         float stat_damagedone;
 954
 955         if(RadiusDamage_running)
 956         {
 957                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
 958                 return 0;
 959         }
 960
 961         RadiusDamage_running = 1;
 962
 963         tfloordmg = autocvar_g_throughfloor_damage;
 964         tfloorforce = autocvar_g_throughfloor_force;
 965
 966         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
 967         total_damage_to_creatures = 0;
 968
 969         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 970                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 971                 {
 972                         force = inflictor.velocity;
 973                         if(vlen(force) == 0)
 974                                 force = '0 0 -1';
 975                         else
 976                                 force = normalize(force);
 977                         if(forceintensity >= 0)
 978                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
 979                         else
 980                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
 981                 }
 982
 983         stat_damagedone = 0;
 984
 985         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
 986         while (targ)
 987         {
 988                 next = targ.chain;
 989                 if (targ != inflictor)
 990                         if (ignore != targ) if(targ.takedamage)
 991                         {
 992                                 vector nearest;
 993                                 vector diff;
 994                                 float power;
 995
 996                                 // LordHavoc: measure distance to nearest point on target (not origin)
 997                                 // (this guarentees 100% damage on a touch impact)
 998                                 nearest = targ.WarpZone_findradius_nearest;
 999                                 diff = targ.WarpZone_findradius_dist;
1000                                 // round up a little on the damage to ensure full damage on impacts
1001                                 // and turn the distance into a fraction of the radius
1002                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
1003                                 //bprint(" ");
1004                                 //bprint(ftos(power));
1005                                 //if (targ == attacker)
1006                                 //      print(ftos(power), "\n");
1007                                 if (power > 0)
1008                                 {
1009                                         float finaldmg;
1010                                         if (power > 1)
1011                                                 power = 1;
1012                                         finaldmg = coredamage * power + edgedamage * (1 - power);
1013                                         if (finaldmg > 0)
1014                                         {
1015                                                 float a;
1016                                                 float c;
1017                                                 vector hitloc;
1018                                                 vector myblastorigin;
1019                                                 vector center;
1020
1021                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
1022
1023                                                 // if it's a player, use the view origin as reference
1024                                                 center = CENTER_OR_VIEWOFS(targ);
1025
1026                                                 force = normalize(center - myblastorigin);
1027                                                 force = force * (finaldmg / coredamage) * forceintensity;
1028                                                 hitloc = nearest;
1029
1030                                                 if(targ != directhitentity)
1031                                                 {
1032                                                         float hits;
1033                                                         float total;
1034                                                         float hitratio;
1035                                                         float mininv_f, mininv_d;
1036
1037                                                         // test line of sight to multiple positions on box,
1038                                                         // and do damage if any of them hit
1039                                                         hits = 0;
1040
1041                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
1042                                                         // so for a given max stddev:
1043                                                         // n = (1 / (2 * max stddev of hitratio))^2
1044
1045                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
1046                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
1047
1048                                                         if(autocvar_g_throughfloor_debug)
1049                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
1050
1051                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
1052
1053                                                         if(autocvar_g_throughfloor_debug)
1054                                                                 print(sprintf(" steps=%f", total));
1055
1056                                                         if (targ.classname == "player")
1057                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
1058                                                         else
1059                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
1060
1061                                                         if(autocvar_g_throughfloor_debug)
1062                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
1063
1064                                                         for(c = 0; c < total; ++c)
1065                                                         {
1066                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1067                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1068                                                                 if (trace_fraction == 1 || trace_ent == targ)
1069                                                                 {
1070                                                                         ++hits;
1071                                                                         if (hits > 1)
1072                                                                                 hitloc = hitloc + nearest;
1073                                                                         else
1074                                                                                 hitloc = nearest;
1075                                                                 }
1076                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1077                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1078                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1079                                                         }
1080
1081                                                         nearest = hitloc * (1 / max(1, hits));
1082                                                         hitratio = (hits / total);
1083                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1084                                                         finaldmg = finaldmg * a;
1085                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1086                                                         force = force * a;
1087
1088                                                         if(autocvar_g_throughfloor_debug)
1089                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
1090                                                 }
1091
1092                                                 // laser force adjustments :P
1093                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1094                                                 {
1095                                                         if (targ == attacker)
1096                                                         {
1097                                                                 vector vel;
1098
1099                                                                 float force_zscale;
1100                                                                 float force_velocitybiasramp;
1101                                                                 float force_velocitybias;
1102
1103                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1104                                                                 if(deathtype & HITTYPE_SECONDARY)
1105                                                                 {
1106                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1107                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1108                                                                 }
1109                                                                 else
1110                                                                 {
1111                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1112                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1113                                                                 }
1114
1115                                                                 vel = targ.velocity;
1116                                                                 vel_z = 0;
1117                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1118                                                                 force =
1119                                                                         vlen(force)
1120                                                                         *
1121                                                                         normalize(normalize(force) + vel);
1122
1123                                                                 force_z *= force_zscale;
1124                                                         }
1125                                                         else
1126                                                         {
1127                                                                 if(deathtype & HITTYPE_SECONDARY)
1128                                                                 {
1129                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1130                                                                 }
1131                                                                 else
1132                                                                 {
1133                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1134                                                                 }
1135                                                         }
1136                                                 }
1137
1138                                                 //if (targ == attacker)
1139                                                 //{
1140                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1141                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1142                                                 //      print(" (", ftos(a), ")\n");
1143                                                 //}
1144                                                 if(finaldmg || vlen(force))
1145                                                 {
1146                                                         if(targ.iscreature)
1147                                                         {
1148                                                                 total_damage_to_creatures += finaldmg;
1149
1150                                                                 if(accuracy_isgooddamage(attacker, targ))
1151                                                                         stat_damagedone += finaldmg;
1152                                                         }
1153
1154                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1155                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1156                                                         else
1157                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1158                                                 }
1159                                         }
1160                                 }
1161                         }
1162                 targ = next;
1163         }
1164
1165         RadiusDamage_running = 0;
1166
1167         if(!DEATH_ISSPECIAL(deathtype))
1168                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1169
1170         return total_damage_to_creatures;
1171 }
1172
1173 .float fire_damagepersec;
1174 .float fire_endtime;
1175 .float fire_deathtype;
1176 .entity fire_owner;
1177 .float fire_hitsound;
1178 .entity fire_burner;
1179
1180 void fireburner_think();
1181
1182 float Fire_IsBurning(entity e)
1183 {
1184         return (time < e.fire_endtime);
1185 }
1186
1187 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1188 {
1189         float dps;
1190         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1191
1192         if(e.classname == "player")
1193         {
1194                 if(e.deadflag)
1195                         return -1;
1196         }
1197         else
1198         {
1199                 if(!e.fire_burner)
1200                 {
1201                         // print("adding a fire burner to ", e.classname, "\n");
1202                         e.fire_burner = spawn();
1203                         e.fire_burner.classname = "fireburner";
1204                         e.fire_burner.think = fireburner_think;
1205                         e.fire_burner.nextthink = time;
1206                         e.fire_burner.owner = e;
1207                 }
1208         }
1209
1210         t = max(t, 0.1);
1211         dps = d / t;
1212         if(Fire_IsBurning(e))
1213         {
1214                 mintime = e.fire_endtime - time;
1215                 maxtime = max(mintime, t);
1216
1217                 mindps = e.fire_damagepersec;
1218                 maxdps = max(mindps, dps);
1219
1220                 if(maxtime > mintime || maxdps > mindps)
1221                 {
1222                         // Constraints:
1223
1224                         // damage we have right now
1225                         mindamage = mindps * mintime;
1226
1227                         // damage we want to get
1228                         maxdamage = mindamage + d;
1229
1230                         // but we can't exceed maxtime * maxdps!
1231                         totaldamage = min(maxdamage, maxtime * maxdps);
1232
1233                         // LEMMA:
1234                         // Look at:
1235                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1236                         // We see:
1237                         // totaldamage <= maxtime * maxdps
1238                         // ==> totaldamage / maxdps <= maxtime.
1239                         // We also see:
1240                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1241                         //                     >= min(mintime, maxtime)
1242                         // ==> totaldamage / maxdps >= mintime.
1243
1244                         /*
1245                         // how long do we damage then?
1246                         // at least as long as before
1247                         // but, never exceed maxdps
1248                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1249                         */
1250
1251                         // alternate:
1252                         // at most as long as maximum allowed
1253                         // but, never below mindps
1254                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1255
1256                         // assuming t > mintime, dps > mindps:
1257                         // we get d = t * dps = maxtime * maxdps
1258                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1259                         // totaldamage / maxdps = maxtime
1260                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1261                         // FROM THIS:
1262                         // a) totaltime = max(mintime, maxtime) = maxtime
1263                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1264
1265                         // assuming t <= mintime:
1266                         // we get maxtime = mintime
1267                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1268                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1269
1270                         // assuming dps <= mindps:
1271                         // we get mindps = maxdps.
1272                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1273                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1274                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1275
1276                         e.fire_damagepersec = totaldamage / totaltime;
1277                         e.fire_endtime = time + totaltime;
1278                         if(totaldamage > 1.2 * mindamage)
1279                         {
1280                                 e.fire_deathtype = dt;
1281                                 if(e.fire_owner != o)
1282                                 {
1283                                         e.fire_owner = o;
1284                                         e.fire_hitsound = FALSE;
1285                                 }
1286                         }
1287                         if(accuracy_isgooddamage(o, e))
1288                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1289                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1290                 }
1291                 else
1292                         return 0;
1293         }
1294         else
1295         {
1296                 e.fire_damagepersec = dps;
1297                 e.fire_endtime = time + t;
1298                 e.fire_deathtype = dt;
1299                 e.fire_owner = o;
1300                 e.fire_hitsound = FALSE;
1301                 if(accuracy_isgooddamage(o, e))
1302                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1303                 return d;
1304         }
1305 }
1306
1307 void Fire_ApplyDamage(entity e)
1308 {
1309         float t, d, hi, ty;
1310         entity o;
1311
1312         if not(Fire_IsBurning(e))
1313                 return;
1314
1315         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1316         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1317                 o = e.fire_owner;
1318
1319         // water and slime stop fire
1320         if(e.waterlevel)
1321         if(e.watertype != CONTENT_LAVA)
1322                 e.fire_endtime = 0;
1323
1324         // ice stops fire
1325         if(e.freezetag_frozen)
1326                 e.fire_endtime = 0;
1327
1328         t = min(frametime, e.fire_endtime - time);
1329         d = e.fire_damagepersec * t;
1330
1331         hi = e.fire_owner.hitsound;
1332         ty = e.fire_owner.typehitsound;
1333         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1334         if(e.fire_hitsound && e.fire_owner)
1335         {
1336                 e.fire_owner.hitsound = hi;
1337                 e.fire_owner.typehitsound = ty;
1338         }
1339         e.fire_hitsound = TRUE;
1340
1341         if not(IS_INDEPENDENT_PLAYER(e))
1342         FOR_EACH_PLAYER(other) if(e != other)
1343         {
1344                 if(other.classname == "player")
1345                 if(other.deadflag == DEAD_NO)
1346                 if not(IS_INDEPENDENT_PLAYER(other))
1347                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1348                 {
1349                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1350                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1351                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1352                 }
1353         }
1354 }
1355
1356 void Fire_ApplyEffect(entity e)
1357 {
1358         if(Fire_IsBurning(e))
1359                 e.effects |= EF_FLAME;
1360         else
1361                 e.effects &~= EF_FLAME;
1362 }
1363
1364 void fireburner_think()
1365 {
1366         // for players, this is done in the regular loop
1367         if(wasfreed(self.owner))
1368         {
1369                 remove(self);
1370                 return;
1371         }
1372         Fire_ApplyEffect(self.owner);
1373         if(!Fire_IsBurning(self.owner))
1374         {
1375                 self.owner.fire_burner = world;
1376                 remove(self);
1377                 return;
1378         }
1379         Fire_ApplyDamage(self.owner);
1380         self.nextthink = time;
1381 }