qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50 float headshot;
  51 float damage_headshotbonus; // bonus multiplier for head shots, set to 0 after use
  52
  53 .float dmg_team;
  54 .float teamkill_complain;
  55 .float teamkill_soundtime;
  56 .entity teamkill_soundsource;
  57 .entity pusher;
  58 .float taunt_soundtime;
  59
  60
  61 float IsDifferentTeam(entity a, entity b)
  62 {
  63         if(teamplay)
  64         {
  65                 if(a.team == b.team)
  66                         return 0;
  67         }
  68         else
  69         {
  70                 if(a == b)
  71                         return 0;
  72         }
  73         return 1;
  74 }
  75
  76 float IsFlying(entity a)
  77 {
  78         if(a.flags & FL_ONGROUND)
  79                 return 0;
  80         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  81                 return 0;
  82         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  83         if(trace_fraction < 1)
  84                 return 0;
  85         return 1;
  86 }
  87
  88 vector GetHeadshotMins(entity targ)
  89 {
  90         return '-0.5 0 0' * PL_HEAD_x + '0 -0.5 0' * PL_HEAD_y + '0 0 1' * (targ.maxs_z - PL_HEAD_z);
  91 }
  92 vector GetHeadshotMaxs(entity targ)
  93 {
  94         return '0.5 0 0' * PL_HEAD_x + '0 0.5 0' * PL_HEAD_y + '0 0 1' * targ.maxs_z;
  95 }
  96
  97 void UpdateFrags(entity player, float f)
  98 {
  99         PlayerTeamScore_AddScore(player, f);
 100 }
 101
 102 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
 103 void W_SwitchWeapon_Force(entity e, float w);
 104 entity GiveFrags_randomweapons;
 105 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
 106 {
 107         // TODO route through PlayerScores instead
 108         if(gameover) return;
 109
 110         if(f < 0)
 111         {
 112                 if(targ == attacker)
 113                 {
 114                         // suicide
 115                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 116                 }
 117                 else
 118                 {
 119                         // teamkill
 120                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 121                 }
 122         }
 123         else
 124         {
 125                 // regular frag
 126                 PlayerScore_Add(attacker, SP_KILLS, 1);
 127                 if(targ.playerid)
 128                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 129         }
 130
 131         PlayerScore_Add(targ, SP_DEATHS, 1);
 132
 133         if(g_arena || g_ca)
 134                 if(autocvar_g_arena_roundbased)
 135                         return;
 136
 137         if(targ != attacker) // not for suicides
 138         if(g_weaponarena_random)
 139         {
 140                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 141                 float culprit;
 142                 culprit = DEATH_WEAPONOF(deathtype);
 143                 if(!culprit || !WEPSET_CONTAINS_EW(attacker, culprit))
 144                         culprit = attacker.weapon;
 145
 146                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 147                 {
 148                         // no exchange
 149                 }
 150                 else
 151                 {
 152                         if(!GiveFrags_randomweapons)
 153                         {
 154                                 GiveFrags_randomweapons = spawn();
 155                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 156                         }
 157
 158                         if(inWarmupStage)
 159                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
 160                         else
 161                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
 162
 163                         // all others (including the culprit): remove
 164                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
 165                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
 166
 167                         // among the remaining ones, choose one by random
 168                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 169
 170                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
 171                         {
 172                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
 173                                 WEPSET_ANDNOT_EW(attacker, culprit);
 174                         }
 175                 }
 176
 177                 // after a frag, choose another random weapon set
 178                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
 179                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 180         }
 181
 182         // FIXME fix the mess this is (we have REAL points now!)
 183         entity oldself;
 184         oldself = self;
 185         self = attacker;
 186         frag_attacker = attacker;
 187         frag_target = targ;
 188         frag_score = f;
 189         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 190         {
 191                 f = frag_score;
 192                 self = oldself;
 193         }
 194         else
 195         {
 196                 self = oldself;
 197                 if(g_runematch)
 198                 {
 199                         f = RunematchHandleFrags(attacker, targ, f);
 200                 }
 201                 else if(g_lms)
 202                 {
 203                         // remove a life
 204                         float tl;
 205                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 206                         if(tl < lms_lowest_lives)
 207                                 lms_lowest_lives = tl;
 208                         if(tl <= 0)
 209                         {
 210                                 if(!lms_next_place)
 211                                         lms_next_place = player_count;
 212                                 else
 213                                         lms_next_place = min(lms_next_place, player_count);
 214                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 215                                 --lms_next_place;
 216                         }
 217                         f = 0;
 218                 }
 219         }
 220
 221         attacker.totalfrags += f;
 222
 223         if(f)
 224                 UpdateFrags(attacker, f);
 225 }
 226
 227 string Obituary_ExtraFragInfo(entity player) // Extra fragmessage information
 228 {
 229         string health_output;
 230         string ping_output;
 231         string handicap_output;
 232         string output;
 233
 234         if(autocvar_sv_fraginfo && ((autocvar_sv_fraginfo == 2) || inWarmupStage))
 235         {
 236                 // health/armor of attacker (person who killed you)
 237                 if(autocvar_sv_fraginfo_stats && (player.health >= 1))
 238                         health_output = strcat("^7(Health ^1", ftos(rint(player.health)), "^7 / Armor ^2", ftos(rint(player.armorvalue)), "^7)");
 239
 240                 // ping display
 241                 if(autocvar_sv_fraginfo_ping)
 242                         ping_output = ((clienttype(player) == CLIENTTYPE_BOT) ? "^2Bot" : strcat("Ping ", ((player.ping >= 150) ? "^1" : "^2"), ftos(rint(player.ping)), "ms"));
 243
 244                 // handicap display
 245                 if(autocvar_sv_fraginfo_handicap)
 246                 {
 247                         if(autocvar_sv_fraginfo_handicap == 2)
 248                                 handicap_output = strcat(output, strcat("Handicap ^2", ((player.cvar_cl_handicap <= 1) ? "Off" : ftos(rint(player.cvar_cl_handicap)))));
 249                         else if(player.cvar_cl_handicap) // with _handicap 1, only show this if there actually is a handicap enabled.
 250                                 handicap_output = strcat("Handicap ^2", ftos(rint(player.cvar_cl_handicap)));
 251                 }
 252
 253                 // format the string
 254                 output = strcat(health_output, (health_output ? ((ping_output || handicap_output) ? " ^7(" : "") : ((ping_output || handicap_output) ? "^7(" : "")),
 255                         ping_output, (handicap_output ? "^7 / " : ""),
 256                         handicap_output, ((ping_output || handicap_output) ? "^7)" : ""));
 257
 258                 // add new line to the beginning if there is a message
 259                 if(output) { output = strcat("\n", output); }
 260         }
 261
 262         return output;
 263 }
 264
 265 string AppendItemcodes(string s, entity player)
 266 {
 267         float w;
 268         w = player.weapon;
 269         //if(w == 0)
 270         //      w = player.switchweapon;
 271         if(w == 0)
 272                 w = player.cnt; // previous weapon!
 273         s = strcat(s, ftos(w));
 274         if(time < player.strength_finished)
 275                 s = strcat(s, "S");
 276         if(time < player.invincible_finished)
 277                 s = strcat(s, "I");
 278         if(player.flagcarried != world)
 279                 s = strcat(s, "F");
 280         if(player.BUTTON_CHAT)
 281                 s = strcat(s, "T");
 282         if(player.kh_next)
 283                 s = strcat(s, "K");
 284         if(player.runes)
 285                 s = strcat(s, "|", ftos(player.runes));
 286         return s;
 287 }
 288
 289 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 290 {
 291         string s;
 292         if(!autocvar_sv_eventlog)
 293                 return;
 294         s = strcat(":kill:", mode);
 295         s = strcat(s, ":", ftos(killer.playerid));
 296         s = strcat(s, ":", ftos(killed.playerid));
 297         s = strcat(s, ":type=", ftos(deathtype));
 298         s = strcat(s, ":items=");
 299         s = AppendItemcodes(s, killer);
 300         if(killed != killer)
 301         {
 302                 s = strcat(s, ":victimitems=");
 303                 s = AppendItemcodes(s, killed);
 304         }
 305         GameLogEcho(s);
 306 }
 307
 308 void Send_KillNotification (string s1, string s2, string s3, float msg, float type)
 309 {
 310         WriteByte(MSG_ALL, SVC_TEMPENTITY);
 311         WriteByte(MSG_ALL, TE_CSQC_KILLNOTIFY);
 312         WriteString(MSG_ALL, s1);
 313         WriteString(MSG_ALL, s2);
 314         WriteString(MSG_ALL, s3);
 315         WriteShort(MSG_ALL, msg);
 316         WriteByte(MSG_ALL, type);
 317 }
 318
 319 // Function is used to send a generic centerprint whose content CSQC gets to decide (gentle version or not in the below cases)
 320 void Send_CSQC_KillCenterprint(entity e, string s1, string s2, float msg, float type)
 321 {
 322         if (clienttype(e) == CLIENTTYPE_REAL)
 323         {
 324                 msg_entity = e;
 325                 WRITESPECTATABLE_MSG_ONE({
 326                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 327                         WriteByte(MSG_ONE, TE_CSQC_KILLCENTERPRINT);
 328                         WriteString(MSG_ONE, s1);
 329                         WriteString(MSG_ONE, s2);
 330                         WriteShort(MSG_ONE, msg);
 331                         WriteByte(MSG_ONE, type);
 332                 });
 333         }
 334 }
 335
 336 void Obituary (entity attacker, entity inflictor, entity targ, float deathtype)
 337 {
 338         string  s, a, msg;
 339         float w, type;
 340
 341         if (targ.classname == "player")
 342         {
 343                 s = targ.netname;
 344                 a = attacker.netname;
 345
 346                 if (targ == attacker) // suicides
 347                 {
 348                         if (deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 349                                 msg = ColoredTeamName(targ.team); // TODO: check if needed?
 350             if(!g_cts) // no "killed your own dumb self" message in CTS
 351                 Send_CSQC_KillCenterprint(targ, msg, "", deathtype, MSG_SUICIDE);
 352
 353                         if(deathtype != DEATH_TEAMCHANGE && deathtype != DEATH_QUIET)
 354                         {
 355                                 LogDeath("suicide", deathtype, targ, targ);
 356                                 GiveFrags(attacker, targ, -1, deathtype);
 357                         }
 358
 359                         if (targ.killcount > 2)
 360                                 msg = ftos(targ.killcount);
 361                         if(teamplay && deathtype == DEATH_MIRRORDAMAGE)
 362                         {
 363                                 if(attacker.team == COLOR_TEAM1)
 364                                         deathtype = KILL_TEAM_RED;
 365                                 else
 366                                         deathtype = KILL_TEAM_BLUE;
 367                         }
 368
 369                         Send_KillNotification(s, msg, ftos(w), deathtype, MSG_SUICIDE);
 370                 }
 371                 else if (attacker.classname == "player")
 372                 {
 373                         if(!IsDifferentTeam(attacker, targ))
 374                         {
 375                                 if(attacker.team == COLOR_TEAM1)
 376                                         type = KILL_TEAM_RED;
 377                                 else
 378                                         type = KILL_TEAM_BLUE;
 379
 380                                 GiveFrags(attacker, targ, -1, deathtype);
 381
 382                                 Send_CSQC_KillCenterprint(attacker, s, "", type, MSG_KILL);
 383
 384                                 if (targ.killcount > 2) {
 385                                         msg = ftos(targ.killcount);
 386                                 }
 387
 388                                 if (attacker.killcount > 2) {
 389                                         msg = ftos(attacker.killcount);
 390                                         type = KILL_TEAM_SPREE;
 391                                 }
 392                                 Send_KillNotification(a, s, msg, type, MSG_KILL);
 393
 394                                 attacker.killcount = 0;
 395
 396                                 LogDeath("tk", deathtype, attacker, targ);
 397                         }
 398                         else
 399                         {
 400                                 if (!checkrules_firstblood)
 401                                 {
 402                                         checkrules_firstblood = TRUE;
 403                                         Send_KillNotification(a, "", "", KILL_FIRST_BLOOD, MSG_KILL);
 404                                         // TODO: make these print a newline if they dont
 405                                         Send_CSQC_KillCenterprint(attacker, "", "", KILL_FIRST_BLOOD, MSG_KILL);
 406                                         Send_CSQC_KillCenterprint(targ, "", "", KILL_FIRST_VICTIM, MSG_KILL);
 407                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 408                                         PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 409                                 }
 410
 411                                 if(targ.BUTTON_CHAT) {
 412                                         Send_CSQC_KillCenterprint(attacker, s, Obituary_ExtraFragInfo(targ), KILL_TYPEFRAG, MSG_KILL);
 413                                         Send_CSQC_KillCenterprint(targ, a, Obituary_ExtraFragInfo(attacker), KILL_TYPEFRAGGED, MSG_KILL);
 414                                 } else {
 415                                         Send_CSQC_KillCenterprint(attacker, s, Obituary_ExtraFragInfo(targ), KILL_FRAG, MSG_KILL);
 416                                         Send_CSQC_KillCenterprint(targ, a, Obituary_ExtraFragInfo(attacker), KILL_FRAGGED, MSG_KILL);
 417                                 }
 418
 419                                 attacker.taunt_soundtime = time + 1;
 420
 421                                 // TODO: fix this?
 422                                 if (deathtype == DEATH_CUSTOM)
 423                                         msg = deathmessage;
 424                                 else
 425                                         msg = inflictor.message2;
 426
 427                                 if(strstrofs(msg, "%", 0) < 0)
 428                                         msg = strcat("%s ", msg, " by %s");
 429
 430                                 Send_KillNotification(a, s, msg, deathtype, MSG_KILL);
 431
 432                                 GiveFrags(attacker, targ, 1, deathtype);
 433
 434                                 if (targ.killcount > 2) {
 435                                         Send_KillNotification(s, ftos(targ.killcount), a, KILL_END_SPREE, MSG_SPREE);
 436                                 }
 437
 438                                 attacker.killcount = attacker.killcount + 1;
 439
 440                                 if (attacker.killcount > 2) {
 441                                         Send_KillNotification(a, ftos(attacker.killcount), "", KILL_SPREE, MSG_SPREE);
 442                                 }
 443                                 else if (attacker.killcount == 3)
 444                                 {
 445                                         Send_KillNotification(a, "", "", KILL_SPREE_3, MSG_SPREE);
 446                                         AnnounceTo(attacker, "03kills");
 447                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_3, 1);
 448                                 }
 449                                 else if (attacker.killcount == 5)
 450                                 {
 451                                         Send_KillNotification(a, "", "", KILL_SPREE_5, MSG_SPREE);
 452                                         AnnounceTo(attacker, "05kills");
 453                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_5, 1);
 454                                 }
 455                                 else if (attacker.killcount == 10)
 456                                 {
 457                                         Send_KillNotification(a, "", "", KILL_SPREE_10, MSG_SPREE);
 458                                         AnnounceTo(attacker, "10kills");
 459                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_10, 1);
 460                                 }
 461                                 else if (attacker.killcount == 15)
 462                                 {
 463                                         Send_KillNotification(a, "", "", KILL_SPREE_15, MSG_SPREE);
 464                                         AnnounceTo(attacker, "15kills");
 465                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_15, 1);
 466                                 }
 467                                 else if (attacker.killcount == 20)
 468                                 {
 469                                         Send_KillNotification(a, "", "", KILL_SPREE_20, MSG_SPREE);
 470                                         AnnounceTo(attacker, "20kills");
 471                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_20, 1);
 472                                 }
 473                                 else if (attacker.killcount == 25)
 474                                 {
 475                                         Send_KillNotification(a, "", "", KILL_SPREE_25, MSG_SPREE);
 476                                         AnnounceTo(attacker, "25kills");
 477                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_25, 1);
 478                                 }
 479                                 else if (attacker.killcount == 30)
 480                                 {
 481                                         Send_KillNotification(a, "", "", KILL_SPREE_30, MSG_SPREE);
 482                                         AnnounceTo(attacker, "30kills");
 483                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_30, 1);
 484                                 }
 485                                 LogDeath("frag", deathtype, attacker, targ);
 486                         }
 487                 }
 488                 else
 489                 {
 490                         Send_CSQC_KillCenterprint(targ, "", "", deathtype, MSG_KILL_ACTION);
 491                         if (deathtype == DEATH_HURTTRIGGER && inflictor.message != "")
 492                                 msg = inflictor.message;
 493                         else if (deathtype == DEATH_CUSTOM)
 494                                 msg = deathmessage;
 495                         if(strstrofs(msg, "%", 0) < 0)
 496                                 msg = strcat("%s ", msg);
 497
 498                         GiveFrags(targ, targ, -1, deathtype);
 499                         if(PlayerScore_Add(targ, SP_SCORE, 0) == -5) {
 500                                 AnnounceTo(targ, "botlike");
 501                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 502                         }
 503                         Send_KillNotification(s, msg, "", deathtype, MSG_KILL_ACTION);
 504
 505                         if (targ.killcount > 2)
 506                                 Send_KillNotification(s, ftos(targ.killcount), "", 0, MSG_KILL_ACTION_SPREE);
 507
 508                         LogDeath("accident", deathtype, targ, targ);
 509                 }
 510
 511                 targ.death_origin = targ.origin;
 512                 if(targ != attacker)
 513                         targ.killer_origin = attacker.origin;
 514
 515                 // FIXME: this should go in PutClientInServer
 516                 if (targ.killcount)
 517                         targ.killcount = 0;
 518         }
 519 }
 520
 521 // these are updated by each Damage call for use in button triggering and such
 522 entity damage_targ;
 523 entity damage_inflictor;
 524 entity damage_attacker;
 525
 526 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 527 {
 528         float mirrordamage;
 529         float mirrorforce;
 530         float teamdamage0;
 531         entity attacker_save;
 532         mirrordamage = 0;
 533         mirrorforce = 0;
 534
 535         if (gameover || targ.killcount == -666)
 536                 return;
 537
 538         entity oldself;
 539         oldself = self;
 540         self = targ;
 541         damage_targ = targ;
 542         damage_inflictor = inflictor;
 543         damage_attacker = attacker;
 544                 attacker_save = attacker;
 545
 546         if(targ.classname == "player")
 547                 if(targ.hook)
 548                         if(targ.hook.aiment)
 549                                 if(targ.hook.aiment == attacker)
 550                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 551
 552         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 553         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 554         {
 555                 if(targ.classname == "player")
 556                         if not(IsDifferentTeam(targ, attacker))
 557                         {
 558                                 self = oldself;
 559                                 return;
 560                         }
 561         }
 562
 563         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE || deathtype == DEATH_QUIET)
 564         {
 565                 // These are ALWAYS lethal
 566                 // No damage modification here
 567                 // Instead, prepare the victim for his death...
 568                 targ.armorvalue = 0;
 569                 targ.spawnshieldtime = 0;
 570                 targ.health = 0.9; // this is < 1
 571                 targ.flags -= targ.flags & FL_GODMODE;
 572                 damage = 100000;
 573         }
 574         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 575         {
 576                 // no processing
 577         }
 578         else
 579         {
 580                 /*
 581                 skill based bot damage? gtfo. (tZork)
 582                 if (targ.classname == "player")
 583                 if (attacker.classname == "player")
 584                 if (!targ.isbot)
 585                 if (attacker.isbot)
 586                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 587         */
 588
 589                 // nullify damage if teamplay is on
 590                 if(deathtype != DEATH_TELEFRAG)
 591                 if(attacker.classname == "player")
 592                 {
 593                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 594                         {
 595                                 damage = 0;
 596                                 force = '0 0 0';
 597                         }
 598                         else if(!IsDifferentTeam(attacker, targ))
 599                         {
 600                                 if(autocvar_teamplay_mode == 1)
 601                                         damage = 0;
 602                                 else if(attacker != targ)
 603                                 {
 604                                         if(autocvar_teamplay_mode == 3)
 605                                                 damage = 0;
 606                                         else if(autocvar_teamplay_mode == 4)
 607                                         {
 608                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 609                                                 {
 610                                                         teamdamage0 = max(attacker.dmg_team, autocvar_g_teamdamage_threshold);
 611                                                         attacker.dmg_team = attacker.dmg_team + damage;
 612                                                         if(attacker.dmg_team > teamdamage0 && !g_ca)
 613                                                                 mirrordamage = autocvar_g_mirrordamage * (attacker.dmg_team - teamdamage0);
 614                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 615                                                         if(g_minstagib)
 616                                                         {
 617                                                                 if(autocvar_g_friendlyfire == 0)
 618                                                                         damage = 0;
 619                                                         }
 620                                                         else if(g_ca)
 621                                                                 damage = 0;
 622                                                         else
 623                                                                 damage = autocvar_g_friendlyfire * damage;
 624                                                         // mirrordamage will be used LATER
 625
 626                                                         if(autocvar_g_mirrordamage_virtual)
 627                                                         {
 628                                                                 vector v;
 629                                                                 v = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 630                                                                 v_z = 0; // fteqcc sucks
 631                                                                 attacker.dmg_take += v_x;
 632                                                                 attacker.dmg_save += v_y;
 633                                                                 attacker.dmg_inflictor = inflictor;
 634                                                                 mirrordamage = 0;
 635                                                                 mirrorforce = 0;
 636                                                         }
 637
 638                                                         if(autocvar_g_friendlyfire_virtual)
 639                                                         {
 640                                                                 vector v;
 641                                                                 v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 642                                                                 v_z = 0; // fteqcc sucks
 643                                                                 targ.dmg_take += v_x;
 644                                                                 targ.dmg_save += v_y;
 645                                                                 targ.dmg_inflictor = inflictor;
 646                                                                 damage = 0;
 647                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 648                                                                         force = '0 0 0';
 649                                                         }
 650                                                 }
 651                                                 else
 652                                                         damage = 0;
 653                                         }
 654                                 }
 655                         }
 656                 }
 657
 658                 if(targ.classname == "player")
 659                 if(attacker.classname == "player")
 660                 if(attacker != targ)
 661                 {
 662                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 663                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 664                 }
 665
 666                 if(targ.classname == "player")
 667                 if (g_minstagib)
 668                 {
 669                         if ((deathtype == DEATH_FALL)  ||
 670                                 (deathtype == DEATH_DROWN) ||
 671                                 (deathtype == DEATH_SLIME) ||
 672                                 (deathtype == DEATH_LAVA)  ||
 673                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 674                         {
 675                                 self = oldself;
 676                                 return;
 677                         }
 678                         if(damage > 0)
 679                             damage = 10000;
 680                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 681                         {
 682                                 targ.armorvalue -= 1;
 683                                 centerprint(targ, strcat("^3Remaining extra lives: ",ftos(targ.armorvalue)));
 684                                 damage = 0;
 685                                 targ.hitsound += 1;
 686                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 687                         }
 688                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 689                         {
 690                                 damage = 0;
 691                                 mirrordamage = 0;
 692                                 if (targ != attacker)
 693                                 {
 694                                         if ((targ.health >= 1) && (targ.classname == "player"))
 695                                                 centerprint(attacker, "Secondary fire inflicts no damage!");
 696                                         force = '0 0 0';
 697                                         // keep mirrorforce
 698                                         attacker = targ;
 699                                 }
 700                         }
 701                 }
 702
 703                 if not(DEATH_ISSPECIAL(deathtype))
 704                 {
 705                         damage *= g_weapondamagefactor;
 706                         mirrordamage *= g_weapondamagefactor;
 707                         force = force * g_weaponforcefactor;
 708                         mirrorforce *= g_weaponforcefactor;
 709                 }
 710
 711                 // should this be changed at all? If so, in what way?
 712                 frag_attacker = attacker;
 713                 frag_target = targ;
 714                 frag_damage = damage;
 715                 frag_force = force;
 716         frag_deathtype = deathtype;
 717                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 718                 damage = frag_damage;
 719                 force = frag_force;
 720
 721                 // apply strength multiplier
 722                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 723                 {
 724                         if(targ == attacker)
 725                         {
 726                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 727                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
 728                         }
 729                         else
 730                         {
 731                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
 732                                 force = force * autocvar_g_balance_powerup_strength_force;
 733                         }
 734                 }
 735
 736                 // apply invincibility multiplier
 737                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 738                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 739
 740                 if (targ == attacker)
 741                 {
 742                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 743                                 damage = 0;
 744                         else
 745                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 746                 }
 747
 748                 if(g_runematch)
 749                 {
 750                         // apply strength rune
 751                         if (attacker.runes & RUNE_STRENGTH)
 752                         {
 753                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 754                                 {
 755                                         damage = damage * autocvar_g_balance_rune_strength_combo_damage;
 756                                         force = force * autocvar_g_balance_rune_strength_combo_force;
 757                                 }
 758                                 else
 759                                 {
 760                                         damage = damage * autocvar_g_balance_rune_strength_damage;
 761                                         force = force * autocvar_g_balance_rune_strength_force;
 762                                 }
 763                         }
 764                         else if (attacker.runes & CURSE_WEAK)
 765                         {
 766                                 damage = damage * autocvar_g_balance_curse_weak_damage;
 767                                 force = force * autocvar_g_balance_curse_weak_force;
 768                         }
 769
 770                         // apply defense rune
 771                         if (targ.runes & RUNE_DEFENSE)
 772                         {
 773                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 774                                         damage = damage * autocvar_g_balance_rune_defense_combo_takedamage;
 775                                 else
 776                                         damage = damage * autocvar_g_balance_rune_defense_takedamage;
 777                         }
 778                         else if (targ.runes & CURSE_VULNER)
 779                                 damage = damage * autocvar_g_balance_curse_vulner_takedamage;
 780                 }
 781
 782                 // count the damage
 783                 if(attacker)
 784                 if(!targ.deadflag)
 785                 if(targ.takedamage == DAMAGE_AIM)
 786                 if(targ != attacker)
 787                 {
 788                         if(damage_headshotbonus > 0)
 789                         {
 790                                 if(targ.classname == "player")
 791                                 {
 792                                         // HEAD SHOT:
 793                                         // find height of hit on player axis
 794                                         // if above view_ofs and below maxs, and also in the middle half of the bbox, it is head shot
 795                                         vector headmins, headmaxs, org;
 796                                         org = antilag_takebackorigin(targ, time - ANTILAG_LATENCY(attacker));
 797                                         headmins = org + GetHeadshotMins(targ);
 798                                         headmaxs = org + GetHeadshotMaxs(targ);
 799                                         if(trace_hits_box(railgun_start, railgun_end, headmins, headmaxs))
 800                                         {
 801                                                 deathtype |= HITTYPE_HEADSHOT;
 802                                         }
 803                                 }
 804                                 else if(targ.classname == "turret_head")
 805                                 {
 806                                         deathtype |= HITTYPE_HEADSHOT;
 807                                 }
 808                                 if(deathtype & HITTYPE_HEADSHOT)
 809                                         damage *= 1 + damage_headshotbonus;
 810                         }
 811
 812                         entity victim;
 813                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 814                                 victim = targ.owner;
 815                         else
 816                                 victim = targ;
 817
 818                         if(victim.classname == "player" || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 819                         {
 820                                 if(IsDifferentTeam(victim, attacker))
 821                                 {
 822                                         if(damage > 0)
 823                                         {
 824                                                 if(deathtype != DEATH_FIRE)
 825                                                 {
 826                                                         if(victim.BUTTON_CHAT)
 827                                                                 attacker.typehitsound += 1;
 828                                                         else
 829                                                                 attacker.hitsound += 1;
 830                                                 }
 831
 832                                                 damage_goodhits += 1;
 833                                                 damage_gooddamage += damage;
 834
 835                                                 if not(DEATH_ISSPECIAL(deathtype))
 836                                                 {
 837                                                         if(targ.classname == "player") // don't do this for vehicles
 838                                                         if(!g_minstagib)
 839                                                         if(IsFlying(victim))
 840                                                                 yoda = 1;
 841
 842                                                         if(g_minstagib)
 843                                                         if(victim.items & IT_STRENGTH)
 844                                                                 yoda = 1;
 845
 846                                                         if(deathtype & HITTYPE_HEADSHOT)
 847                                                                 headshot = 1;
 848                                                 }
 849                                                 if(g_ca)
 850                                                         PlayerScore_Add(attacker, SP_SCORE, damage * autocvar_g_ca_damage2score_multiplier);
 851                                         }
 852                                 }
 853                                 else
 854                                 {
 855                                         if(deathtype != DEATH_FIRE)
 856                                         {
 857                                                 attacker.typehitsound += 1;
 858                                         }
 859                                         if(mirrordamage > 0)
 860                                                 if(time > attacker.teamkill_complain)
 861                                                 {
 862                                                         attacker.teamkill_complain = time + 5;
 863                                                         attacker.teamkill_soundtime = time + 0.4;
 864                                                         attacker.teamkill_soundsource = targ;
 865                                                 }
 866                                 }
 867                         }
 868                 }
 869         }
 870
 871         // apply push
 872         if (self.damageforcescale)
 873         if (vlen(force))
 874         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 875         {
 876                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 877                 if(self.movetype == MOVETYPE_PHYSICS)
 878                 {
 879                         entity farcent;
 880                         farcent = spawn();
 881                         farcent.classname = "farce";
 882                         farcent.enemy = self;
 883                         farcent.movedir = farce * 10;
 884                         if(self.mass)
 885                                 farcent.movedir = farcent.movedir * self.mass;
 886                         farcent.origin = hitloc;
 887                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 888                         farcent.nextthink = time + 0.1;
 889                         farcent.think = SUB_Remove;
 890                 }
 891                 else
 892                         self.velocity = self.velocity + farce;
 893                 self.flags &~= FL_ONGROUND;
 894                 UpdateCSQCProjectile(self);
 895         }
 896         // apply damage
 897         if (damage != 0 || (self.damageforcescale && vlen(force)))
 898         if (self.event_damage)
 899                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 900         self = oldself;
 901
 902         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 903         {
 904                 if(g_runematch)
 905                 {
 906                         if (attacker.runes & RUNE_VAMPIRE)
 907                         {
 908                         // apply vampire rune
 909                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 910                                 {
 911                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb;
 912                                         attacker.health = bound(
 913                                                 autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 40
 914                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb,
 915                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 916                                 }
 917                                 else
 918                                 {
 919                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_absorb;
 920                                         attacker.health = bound(
 921                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
 922                                                                                         // empathy won't let you gain health in the same way...
 923                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_absorb,
 924                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 925                                         }
 926                         }
 927                         // apply empathy curse
 928                         else if (attacker.runes & CURSE_EMPATHY)
 929                         {
 930                                 attacker.health = bound(
 931                                         autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 20
 932                                         attacker.health + damage * autocvar_g_balance_curse_empathy_takedamage,
 933                                         attacker.health);
 934                         }
 935                 }
 936         }
 937
 938         // apply mirror damage if any
 939         if(mirrordamage > 0 || mirrorforce > 0)
 940         {
 941                 attacker = attacker_save;
 942                 if(g_minstagib)
 943                 if(mirrordamage > 0)
 944                 {
 945                         // just lose extra LIVES, don't kill the player for mirror damage
 946                         if(attacker.armorvalue > 0)
 947                         {
 948                                 attacker.armorvalue = attacker.armorvalue - 1;
 949                                 centerprint(attacker, strcat("^3Remaining extra lives: ",ftos(attacker.armorvalue)));
 950                                 attacker.hitsound += 1;
 951                         }
 952                         mirrordamage = 0;
 953                 }
 954
 955                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 956                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 957         }
 958 }
 959
 960 float RadiusDamage_running;
 961 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 962 // Returns total damage applies to creatures
 963 {
 964         entity  targ;
 965         float   finaldmg;
 966         float   power;
 967         vector  blastorigin;
 968         vector  force;
 969         vector  diff;
 970         vector  center;
 971         vector  nearest;
 972         float   total_damage_to_creatures;
 973         entity  next;
 974         float   tfloordmg;
 975         float   tfloorforce;
 976
 977         float stat_damagedone;
 978
 979         if(RadiusDamage_running)
 980         {
 981                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
 982                 return 0;
 983         }
 984
 985         RadiusDamage_running = 1;
 986
 987         tfloordmg = autocvar_g_throughfloor_damage;
 988         tfloorforce = autocvar_g_throughfloor_force;
 989
 990         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
 991         total_damage_to_creatures = 0;
 992
 993         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 994         if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 995         {
 996                 force = inflictor.velocity;
 997                 if(vlen(force) == 0)
 998                         force = '0 0 -1';
 999                 else
1000                         force = normalize(force);
1001                 if(forceintensity >= 0)
1002                         Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
1003                 else
1004                         Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
1005         }
1006
1007         stat_damagedone = 0;
1008
1009         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
1010         while (targ)
1011         {
1012                 next = targ.chain;
1013                 if (targ != inflictor)
1014                         if (ignore != targ) if(targ.takedamage)
1015                         {
1016                                 // LordHavoc: measure distance to nearest point on target (not origin)
1017                                 // (this guarentees 100% damage on a touch impact)
1018                                 nearest = targ.WarpZone_findradius_nearest;
1019                                 diff = targ.WarpZone_findradius_dist;
1020                                 // round up a little on the damage to ensure full damage on impacts
1021                                 // and turn the distance into a fraction of the radius
1022                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
1023                                 //bprint(" ");
1024                                 //bprint(ftos(power));
1025                                 //if (targ == attacker)
1026                                 //      print(ftos(power), "\n");
1027                                 if (power > 0)
1028                                 {
1029                                         if (power > 1)
1030                                                 power = 1;
1031                                         finaldmg = coredamage * power + edgedamage * (1 - power);
1032                                         if (finaldmg > 0)
1033                                         {
1034                                                 float a;
1035                                                 float c;
1036                                                 float hits;
1037                                                 float total;
1038                                                 float hitratio;
1039                                                 vector hitloc;
1040                                                 vector myblastorigin;
1041                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
1042                                                 center = targ.origin + (targ.mins + targ.maxs) * 0.5;
1043                                                 // if it's a player, use the view origin as reference
1044                                                 if (targ.classname == "player")
1045                                                         center = targ.origin + targ.view_ofs;
1046                                                 force = normalize(center - myblastorigin);
1047                                                 force = force * (finaldmg / coredamage) * forceintensity;
1048                                                 // test line of sight to multiple positions on box,
1049                                                 // and do damage if any of them hit
1050                                                 hits = 0;
1051                                                 if (targ.classname == "player")
1052                                                         total = ceil(bound(1, finaldmg, 50));
1053                                                 else
1054                                                         total = ceil(bound(1, finaldmg/10, 5));
1055                                                 hitloc = nearest;
1056                                                 c = 0;
1057                                                 while (c < total)
1058                                                 {
1059                                                         //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1060                                                         WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1061                                                         if (trace_fraction == 1 || trace_ent == targ)
1062                                                         {
1063                                                                 hits = hits + 1;
1064                                                                 if (hits > 1)
1065                                                                         hitloc = hitloc + nearest;
1066                                                                 else
1067                                                                         hitloc = nearest;
1068                                                         }
1069                                                         nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1070                                                         nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1071                                                         nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1072                                                         c = c + 1;
1073                                                 }
1074                                                 nearest = hitloc * (1 / max(1, hits));
1075                                                 hitratio = (hits / total);
1076                                                 a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1077                                                 finaldmg = finaldmg * a;
1078                                                 a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1079                                                 force = force * a;
1080
1081                                                 // laser force adjustments :P
1082                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1083                                                 {
1084                             if (targ == attacker)
1085                             {
1086                                 vector vel;
1087
1088                                 float force_zscale;
1089                                 float force_velocitybiasramp;
1090                                 float force_velocitybias;
1091
1092                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1093                                 if(deathtype & HITTYPE_SECONDARY)
1094                                 {
1095                                     force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1096                                     force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1097                                 }
1098                                 else
1099                                 {
1100                                     force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1101                                     force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1102                                 }
1103
1104                                 vel = targ.velocity;
1105                                 vel_z = 0;
1106                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1107                                 force =
1108                                     vlen(force)
1109                                     *
1110                                     normalize(normalize(force) + vel);
1111
1112                                 force_z *= force_zscale;
1113                             }
1114                             else
1115                             {
1116                                 if(deathtype & HITTYPE_SECONDARY)
1117                                 {
1118                                     force *= autocvar_g_balance_laser_secondary_force_other_scale;
1119                                 }
1120                                 else
1121                                 {
1122                                     force *= autocvar_g_balance_laser_primary_force_other_scale;
1123                                 }
1124                             }
1125                                                 }
1126
1127                                                 //if (targ == attacker)
1128                                                 //{
1129                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1130                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1131                                                 //      print(" (", ftos(a), ")\n");
1132                                                 //}
1133                                                 if(hits || tfloordmg || tfloorforce)
1134                                                 {
1135                                                         if(targ.iscreature)
1136                                                         {
1137                                                                 total_damage_to_creatures += finaldmg;
1138
1139                                                                 if(accuracy_isgooddamage(attacker, targ))
1140                                                                         stat_damagedone += finaldmg;
1141                                                         }
1142
1143                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1144                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1145                                                         else
1146                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1147                                                 }
1148                                         }
1149                                 }
1150                         }
1151                 targ = next;
1152         }
1153
1154         RadiusDamage_running = 0;
1155
1156         if(!DEATH_ISSPECIAL(deathtype))
1157                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1158
1159         return total_damage_to_creatures;
1160 }
1161
1162 .float fire_damagepersec;
1163 .float fire_endtime;
1164 .float fire_deathtype;
1165 .entity fire_owner;
1166 .float fire_hitsound;
1167 .entity fire_burner;
1168
1169 void fireburner_think();
1170
1171 float Fire_IsBurning(entity e)
1172 {
1173         return (time < e.fire_endtime);
1174 }
1175
1176 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1177 {
1178         float dps;
1179         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1180
1181         if(e.classname == "player")
1182         {
1183                 if(e.deadflag)
1184                         return -1;
1185         }
1186         else
1187         {
1188                 if(!e.fire_burner)
1189                 {
1190                         // print("adding a fire burner to ", e.classname, "\n");
1191                         e.fire_burner = spawn();
1192                         e.fire_burner.classname = "fireburner";
1193                         e.fire_burner.think = fireburner_think;
1194                         e.fire_burner.nextthink = time;
1195                         e.fire_burner.owner = e;
1196                 }
1197         }
1198
1199         t = max(t, 0.1);
1200         dps = d / t;
1201         if(Fire_IsBurning(e))
1202         {
1203                 mintime = e.fire_endtime - time;
1204                 maxtime = max(mintime, t);
1205
1206                 mindps = e.fire_damagepersec;
1207                 maxdps = max(mindps, dps);
1208
1209                 if(maxtime > mintime || maxdps > mindps)
1210                 {
1211                         mindamage = mindps * mintime;
1212                         maxdamage = mindamage + d;
1213
1214                         // interval [mintime, maxtime] * [mindps, maxdps]
1215                         // intersected with
1216                         // [mindamage, maxdamage]
1217                         // maximum of this!
1218
1219                         if(maxdamage >= maxtime * maxdps)
1220                         {
1221                                 totaltime = maxtime;
1222                                 totaldamage = maxtime * maxdps;
1223
1224                                 // this branch increases totaldamage if either t > mintime, or dps > mindps
1225                         }
1226                         else
1227                         {
1228                                 // maxdamage is inside the interval!
1229                                 // first, try to use mindps; only if this fails, increase dps as needed
1230                                 totaltime = min(maxdamage / mindps, maxtime); // maxdamage / mindps >= mindamage / mindps = mintime
1231                                 totaldamage = maxdamage;
1232                                 // can totaldamage / totaltime be >= maxdps?
1233                                 // max(mindps, maxdamage / maxtime) >= maxdps?
1234                                 // we know maxdamage < maxtime * maxdps
1235                                 // so it cannot be
1236
1237                                 // this branch ALWAYS increases totaldamage, but requires maxdamage < maxtime * maxdps
1238                         }
1239
1240                         // total conditions for increasing:
1241                         //     maxtime > mintime OR maxdps > mindps OR maxtime * maxdps > maxdamage
1242                         // however:
1243                         //     if maxtime = mintime, maxdps = mindps
1244                         // then:
1245                         //     maxdamage = mindamage + d
1246                         //     mindamage = mindps * mintime = maxdps * maxtime < maxdamage!
1247                         // so the last condition is not needed
1248
1249                         e.fire_damagepersec = totaldamage / totaltime;
1250                         e.fire_endtime = time + totaltime;
1251                         if(totaldamage > 1.2 * mindamage)
1252                         {
1253                                 e.fire_deathtype = dt;
1254                                 if(e.fire_owner != o)
1255                                 {
1256                                         e.fire_owner = o;
1257                                         e.fire_hitsound = FALSE;
1258                                 }
1259                         }
1260                         if(accuracy_isgooddamage(o, e))
1261                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1262                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1263                 }
1264                 else
1265                         return 0;
1266         }
1267         else
1268         {
1269                 e.fire_damagepersec = dps;
1270                 e.fire_endtime = time + t;
1271                 e.fire_deathtype = dt;
1272                 e.fire_owner = o;
1273                 e.fire_hitsound = FALSE;
1274                 if(accuracy_isgooddamage(o, e))
1275                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1276                 return d;
1277         }
1278 }
1279
1280 void Fire_ApplyDamage(entity e)
1281 {
1282         float t, d, hi, ty;
1283         entity o;
1284
1285         if not(Fire_IsBurning(e))
1286                 return;
1287
1288         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1289         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1290                 o = e.fire_owner;
1291
1292         // water and slime stop fire
1293         if(e.waterlevel)
1294         if(e.watertype != CONTENT_LAVA)
1295                 e.fire_endtime = 0;
1296
1297         // ice stops fire
1298         if(e.freezetag_frozen)
1299                 e.fire_endtime = 0;
1300
1301         t = min(frametime, e.fire_endtime - time);
1302         d = e.fire_damagepersec * t;
1303
1304         hi = e.fire_owner.hitsound;
1305         ty = e.fire_owner.typehitsound;
1306         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1307         if(e.fire_hitsound && e.fire_owner)
1308         {
1309                 e.fire_owner.hitsound = hi;
1310                 e.fire_owner.typehitsound = ty;
1311         }
1312         e.fire_hitsound = TRUE;
1313
1314         if not(IS_INDEPENDENT_PLAYER(e))
1315         FOR_EACH_PLAYER(other) if(e != other)
1316         {
1317                 if(other.classname == "player")
1318                 if(other.deadflag == DEAD_NO)
1319                 if not(IS_INDEPENDENT_PLAYER(other))
1320                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1321                 {
1322                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1323                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1324                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1325                 }
1326         }
1327 }
1328
1329 void Fire_ApplyEffect(entity e)
1330 {
1331         if(Fire_IsBurning(e))
1332                 e.effects |= EF_FLAME;
1333         else
1334                 e.effects &~= EF_FLAME;
1335 }
1336
1337 void fireburner_think()
1338 {
1339         // for players, this is done in the regular loop
1340         if(wasfreed(self.owner))
1341         {
1342                 remove(self);
1343                 return;
1344         }
1345         Fire_ApplyEffect(self.owner);
1346         if(!Fire_IsBurning(self.owner))
1347         {
1348                 self.owner.fire_burner = world;
1349                 remove(self);
1350                 return;
1351         }
1352         Fire_ApplyDamage(self.owner);
1353         self.nextthink = time;
1354 }