qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50 float headshot;
  51 float damage_headshotbonus; // bonus multiplier for head shots, set to 0 after use
  52
  53 .float dmg_team;
  54 .float teamkill_complain;
  55 .float teamkill_soundtime;
  56 .entity teamkill_soundsource;
  57 .entity pusher;
  58 .float istypefrag;
  59 .float taunt_soundtime;
  60
  61
  62 float IsDifferentTeam(entity a, entity b)
  63 {
  64         if(teamplay)
  65         {
  66                 if(a.team == b.team)
  67                         return 0;
  68         }
  69         else
  70         {
  71                 if(a == b)
  72                         return 0;
  73         }
  74         return 1;
  75 }
  76
  77 float IsFlying(entity a)
  78 {
  79         if(a.flags & FL_ONGROUND)
  80                 return 0;
  81         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  82                 return 0;
  83         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  84         if(trace_fraction < 1)
  85                 return 0;
  86         return 1;
  87 }
  88
  89 vector GetHeadshotMins(entity targ)
  90 {
  91         return '-0.5 0 0' * PL_HEAD_x + '0 -0.5 0' * PL_HEAD_y + '0 0 1' * (targ.maxs_z - PL_HEAD_z);
  92 }
  93 vector GetHeadshotMaxs(entity targ)
  94 {
  95         return '0.5 0 0' * PL_HEAD_x + '0 0.5 0' * PL_HEAD_y + '0 0 1' * targ.maxs_z;
  96 }
  97
  98 void UpdateFrags(entity player, float f)
  99 {
 100         PlayerTeamScore_AddScore(player, f);
 101 }
 102
 103 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
 104 void W_SwitchWeapon_Force(entity e, float w);
 105 entity GiveFrags_randomweapons;
 106 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
 107 {
 108         // TODO route through PlayerScores instead
 109         if(gameover) return;
 110
 111         if(f < 0)
 112         {
 113                 if(targ == attacker)
 114                 {
 115                         // suicide
 116                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 117                 }
 118                 else
 119                 {
 120                         // teamkill
 121                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 122                 }
 123         }
 124         else
 125         {
 126                 // regular frag
 127                 PlayerScore_Add(attacker, SP_KILLS, 1);
 128                 if(targ.playerid)
 129                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 130         }
 131
 132         PlayerScore_Add(targ, SP_DEATHS, 1);
 133
 134         if(g_arena || g_ca)
 135                 if(autocvar_g_arena_roundbased)
 136                         return;
 137
 138         if(targ != attacker) // not for suicides
 139         if(g_weaponarena_random)
 140         {
 141                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 142                 float culprit;
 143                 culprit = DEATH_WEAPONOF(deathtype);
 144                 if(!culprit)
 145                         culprit = attacker.weapon;
 146                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
 147                         culprit = attacker.weapon;
 148
 149                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 150                 {
 151                         // no exchange
 152                 }
 153                 else
 154                 {
 155                         if(!GiveFrags_randomweapons)
 156                         {
 157                                 GiveFrags_randomweapons = spawn();
 158                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 159                         }
 160
 161                         if(inWarmupStage)
 162                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
 163                         else
 164                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
 165
 166                         // all others (including the culprit): remove
 167                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
 168                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
 169
 170                         // among the remaining ones, choose one by random
 171                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 172
 173                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
 174                         {
 175                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
 176                                 WEPSET_ANDNOT_EW(attacker, culprit);
 177                         }
 178                 }
 179
 180                 // after a frag, choose another random weapon set
 181                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
 182                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 183         }
 184
 185         // FIXME fix the mess this is (we have REAL points now!)
 186         entity oldself;
 187         oldself = self;
 188         self = attacker;
 189         frag_attacker = attacker;
 190         frag_target = targ;
 191         frag_score = f;
 192         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 193         {
 194                 f = frag_score;
 195                 self = oldself;
 196         }
 197         else
 198         {
 199                 self = oldself;
 200                 if(g_runematch)
 201                 {
 202                         f = RunematchHandleFrags(attacker, targ, f);
 203                 }
 204                 else if(g_lms)
 205                 {
 206                         // remove a life
 207                         float tl;
 208                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 209                         if(tl < lms_lowest_lives)
 210                                 lms_lowest_lives = tl;
 211                         if(tl <= 0)
 212                         {
 213                                 if(!lms_next_place)
 214                                         lms_next_place = player_count;
 215                                 else
 216                                         lms_next_place = min(lms_next_place, player_count);
 217                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 218                                 --lms_next_place;
 219                         }
 220                         f = 0;
 221                 }
 222         }
 223
 224         attacker.totalfrags += f;
 225
 226         if(f)
 227                 UpdateFrags(attacker, f);
 228 }
 229
 230 string Obituary_ExtraFragInfo(entity player) // Extra fragmessage information
 231 {
 232         string health_output = string_null;
 233         string ping_output = string_null;
 234         string handicap_output = string_null;
 235         string output = string_null;
 236
 237         if(autocvar_sv_fraginfo && ((autocvar_sv_fraginfo == 2) || inWarmupStage))
 238         {
 239                 // health/armor of attacker (person who killed you)
 240                 if(autocvar_sv_fraginfo_stats && (player.health >= 1))
 241                         health_output = strcat("^7(Health ^1", ftos(rint(player.health)), "^7 / Armor ^2", ftos(rint(player.armorvalue)), "^7)");
 242
 243                 // ping display
 244                 if(autocvar_sv_fraginfo_ping)
 245                         ping_output = ((clienttype(player) == CLIENTTYPE_BOT) ? "^2Bot" : strcat("Ping ", ((player.ping >= 150) ? "^1" : "^2"), ftos(rint(player.ping)), "ms"));
 246
 247                 // handicap display
 248                 if(autocvar_sv_fraginfo_handicap)
 249                 {
 250                         if(autocvar_sv_fraginfo_handicap == 2)
 251                                 handicap_output = strcat(output, strcat("Handicap ^2", ((player.cvar_cl_handicap <= 1) ? "Off" : ftos(rint(player.cvar_cl_handicap)))));
 252                         else if(player.cvar_cl_handicap) // with _handicap 1, only show this if there actually is a handicap enabled.
 253                                 handicap_output = strcat("Handicap ^2", ftos(rint(player.cvar_cl_handicap)));
 254                 }
 255
 256                 // format the string
 257                 output = strcat(health_output, (health_output ? ((ping_output || handicap_output) ? " ^7(" : "") : ((ping_output || handicap_output) ? "^7(" : "")),
 258                         ping_output, (handicap_output ? "^7 / " : ""),
 259                         handicap_output, ((ping_output || handicap_output) ? "^7)" : ""));
 260
 261                 // add new line to the beginning if there is a message
 262                 if(output) { output = strcat("\n", output); }
 263         }
 264
 265         return output;
 266 }
 267
 268 string AppendItemcodes(string s, entity player)
 269 {
 270         float w;
 271         w = player.weapon;
 272         //if(w == 0)
 273         //      w = player.switchweapon;
 274         if(w == 0)
 275                 w = player.cnt; // previous weapon!
 276         s = strcat(s, ftos(w));
 277         if(time < player.strength_finished)
 278                 s = strcat(s, "S");
 279         if(time < player.invincible_finished)
 280                 s = strcat(s, "I");
 281         if(player.flagcarried != world)
 282                 s = strcat(s, "F");
 283         if(player.BUTTON_CHAT)
 284                 s = strcat(s, "T");
 285         if(player.kh_next)
 286                 s = strcat(s, "K");
 287         if(player.runes)
 288                 s = strcat(s, "|", ftos(player.runes));
 289         return s;
 290 }
 291
 292 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 293 {
 294         string s;
 295         if(!autocvar_sv_eventlog)
 296                 return;
 297         s = strcat(":kill:", mode);
 298         s = strcat(s, ":", ftos(killer.playerid));
 299         s = strcat(s, ":", ftos(killed.playerid));
 300         s = strcat(s, ":type=", Deathtype_Name(deathtype));
 301         s = strcat(s, ":items=");
 302         s = AppendItemcodes(s, killer);
 303         if(killed != killer)
 304         {
 305                 s = strcat(s, ":victimitems=");
 306                 s = AppendItemcodes(s, killed);
 307         }
 308         GameLogEcho(s);
 309 }
 310
 311 void Obituary_SpecialDeath(entity notif_target, float murder, float deathtype, string s1, string s2, float f1, float f2, float f3)
 312 {
 313         float handled, hits;
 314         if(DEATH_ISSPECIAL(deathtype))
 315         {
 316                 #define DEATHTYPE(name,msg_death,msg_death_by,position) \
 317                         { if(deathtype == max(0, name)) \
 318                         { \
 319                                 #if msg_death != NO_MSG \
 320                                         if not(murder) \
 321                                         { \
 322                                                 Send_Notification(notif_target, MSG_ONE, MSG_DEATH, msg_death, s1, s2, f1, f2, f3); \
 323                                                 Send_Notification_ToAll(notif_target, TRUE, MSG_INFO, INFO_##msg_death, s1, s2, f1, f2, f3); \
 324                                                 ++handled; \
 325                                         } \
 326                                 #endif \
 327                                 #if msg_death_by != NO_MSG \
 328                                         if(murder) \
 329                                         { \
 330                                                 Send_Notification(notif_target, MSG_ONE, MSG_DEATH, msg_death_by, s1, s2, f1, f2, f3); \
 331                                                 Send_Notification_ToAll(notif_target, TRUE, MSG_INFO, INFO_##msg_death_by, s1, s2, f1, f2, f3); \
 332                                                 ++handled; \
 333                                         } \
 334                                 #endif \
 335                                 ++hits; \
 336                         } }
 337
 338                 DEATHTYPES
 339                 #undef DEATHTYPE
 340
 341                 if not(hits)
 342                 {
 343                         backtrace("Unhandled deathtype. Please notify Samual!\n");
 344                         //return;
 345                 }
 346                 if not(handled)
 347                 {
 348                         print(sprintf("Obituary_SpecialDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification!\n", Deathtype_Name(deathtype), deathtype));
 349                         return;
 350                 }
 351         }
 352 }
 353
 354 void Obituary_WeaponDeath(entity notif_target, float deathtype, string s1, string s2, float f1, float f2, float f3)
 355 {
 356         float handled, hits;
 357         if(DEATH_ISSPECIAL(deathtype))
 358         {
 359                 #define DEATHTYPE(name,msg_death,msg_death_by,position) \
 360                         { if(deathtype == max(0, name)) \
 361                         { \
 362                                 ++hits; \
 363                         } }
 364
 365                 DEATHTYPES
 366                 #undef DEATHTYPE
 367
 368                 if not(hits)
 369                 {
 370                         backtrace("Unhandled deathtype. Please notify Samual!\n");
 371                         //return;
 372                 }
 373                 if not(handled)
 374                 {
 375                         print(sprintf("Obituary_SpecialDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification!\n", Deathtype_Name(deathtype), deathtype));
 376                         return;
 377                 }
 378         }
 379 }
 380
 381 .float FRAG_VERBOSE;
 382
 383 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
 384 {
 385         // Sanity check
 386         if not(targ.classname == STR_PLAYER) { backtrace("Obituary called on non-player?!\n"); return; }
 387
 388         // Declarations
 389         string  s, a, msg;
 390         float w, type;
 391
 392         string s1 = NO_STR_ARG, s2 = NO_STR_ARG;
 393         float f1 = NO_FL_ARG, f2 = NO_FL_ARG, f3 = NO_FL_ARG;
 394         float notif_firstblood;
 395
 396
 397         dprint(sprintf("Obituary(): Deathtype = %s (%d), Attacker = %s, Inflictor = %s, Target = %s...\n", Deathtype_Name(deathtype), deathtype, attacker.netname, inflictor.netname, targ.netname));
 398
 399
 400         // =======
 401         // SUICIDE
 402         // =======
 403         if(targ == attacker)
 404         {
 405                 if(DEATH_ISSPECIAL(deathtype))
 406                 {
 407                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 408                         {
 409                                 s1 = targ.netname;
 410                                 f1 = targ.team;
 411                         }
 412                         else
 413                         {
 414                                 switch(deathtype)
 415                                 {
 416                                         case DEATH_MIRRORDAMAGE:
 417                                         {
 418                                                 s1 = targ.netname;
 419                                                 f1 = targ.team;
 420                                                 //f2 = targ.killcount;
 421                                                 break;
 422                                         }
 423
 424                                         default:
 425                                         {
 426                                                 s1 = targ.netname;
 427                                                 s2 = NO_STR_ARG;
 428                                                 f1 = f2 = f3 = NO_FL_ARG;
 429                                                 break;
 430                                         }
 431                                 }
 432                                 LogDeath("suicide", deathtype, targ, targ);
 433                                 GiveFrags(attacker, targ, -1, deathtype);
 434                         }
 435                         Obituary_SpecialDeath(targ, FALSE, deathtype, s1, s2, f1, f2, NO_FL_ARG);
 436                 }
 437                 else if(DEATH_WEAPONOF(deathtype))
 438                 {
 439                         print("SUICIDE: death was a weapon!\n");
 440                 }
 441                 else
 442                 {
 443                         backtrace("SUICIDE: what the hell happened here?\n");
 444                 }
 445         }
 446
 447
 448         // ======
 449         // MURDER
 450         // ======
 451         else if(attacker.classname == "player")
 452         {
 453                 s1 = attacker.netname;
 454                 s2 = targ.netname;
 455
 456                 attacker.FRAG_VERBOSE = TRUE;
 457                 targ.FRAG_VERBOSE = TRUE;
 458
 459                 if(!IsDifferentTeam(attacker, targ))
 460                 {
 461                         LogDeath("tk", deathtype, attacker, targ);
 462                         GiveFrags(attacker, targ, -1, deathtype);
 463
 464                         attacker.killcount = 0;
 465
 466                         Send_Notification(attacker, MSG_ONE, MSG_DEATH, DEATH_TEAMKILL_FRAG, s2, NO_STR_ARG, NO_FL_ARG, NO_FL_ARG, NO_FL_ARG);
 467                         Send_Notification(targ, MSG_ONE, MSG_DEATH, DEATH_TEAMKILL_FRAGGED, s1, NO_STR_ARG, NO_FL_ARG, NO_FL_ARG, NO_FL_ARG);
 468                         Send_Notification(world, MSG_ALL, MSG_INFO, APP_TEAM_NUM_4(targ.team, INFO_DEATH_TEAMKILL_), s2, s1, targ.killcount, NO_FL_ARG, NO_FL_ARG);
 469
 470                         // In this case, the death message will ALWAYS be "foo was betrayed by bar"
 471                         // No need for specific death/weapon messages...
 472                         //if(DEATH_WEAPONOF(deathtype)) { print("Currently unhandled...\n"); }
 473                         //else { Obituary_SpecialDeath(targ, TRUE, deathtype, s2, s1, NO_FL_ARG, NO_FL_ARG, NO_FL_ARG); }
 474                 }
 475                 else
 476                 {
 477                         LogDeath("frag", deathtype, attacker, targ);
 478                         GiveFrags(attacker, targ, 1, deathtype);
 479
 480                         attacker.taunt_soundtime = time + 1;
 481                         attacker.killcount = attacker.killcount + 1;
 482                         if(targ.killcount > 2) { Send_KillNotification(s, ftos(targ.killcount), a, KILL_END_SPREE, MSG_SPREE); }
 483
 484                         #define ADD_ACHIEVEMENT_CASE(numa,numb) \
 485                                 case numa: \
 486                                 { \
 487                                         AnnounceTo(attacker, strcat(#numb, "kills")); \
 488                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##numa, 1); \
 489                                         break; \
 490                                 }
 491                         switch(attacker.killcount)
 492                         {
 493                                 ADD_ACHIEVEMENT_CASE(3, 03)
 494                                 ADD_ACHIEVEMENT_CASE(5, 05)
 495                                 ADD_ACHIEVEMENT_CASE(10, 10)
 496                                 ADD_ACHIEVEMENT_CASE(15, 15)
 497                                 ADD_ACHIEVEMENT_CASE(20, 20)
 498                                 ADD_ACHIEVEMENT_CASE(25, 25)
 499                                 ADD_ACHIEVEMENT_CASE(30, 30)
 500                                 default: break;
 501                         }
 502                         #undef ADD_ACHIEVEMENT_CASE
 503
 504                         if(!checkrules_firstblood)
 505                         {
 506                                 checkrules_firstblood = TRUE;
 507                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
 508                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 509                                 PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 510                         }
 511
 512                         if(notif_firstblood) // first blood, no kill sprees yet
 513                         {
 514                                 if(targ.istypefrag)
 515                                 {
 516                                         Send_Notification(attacker, MSG_ONE, MSG_DEATH, (attacker.FRAG_VERBOSE ? DEATH_MURDER_TYPEFRAG_FIRST_VERBOSE : DEATH_MURDER_TYPEFRAG_FIRST),
 517                                                 s2, s1, (attacker.FRAG_VERBOSE ? ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping) : NO_FL_ARG), NO_FL_ARG, NO_FL_ARG);
 518
 519                                         Send_Notification(targ, MSG_ONE, MSG_DEATH, (targ.FRAG_VERBOSE ? DEATH_MURDER_TYPEFRAGGED_FIRST_VERBOSE : DEATH_MURDER_TYPEFRAGGED_FIRST),
 520                                                 s1, NO_STR_ARG, (targ.FRAG_VERBOSE ? attacker.health : NO_FL_ARG), (targ.FRAG_VERBOSE ? attacker.armorvalue : NO_FL_ARG), (targ.FRAG_VERBOSE ? ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping) : NO_FL_ARG));
 521                                 }
 522                                 else
 523                                 {
 524                                         Send_Notification(attacker, MSG_ONE, MSG_DEATH, (attacker.FRAG_VERBOSE ? DEATH_MURDER_FRAG_FIRST_VERBOSE : DEATH_MURDER_FRAG_FIRST),
 525                                                 s2, s1, (attacker.FRAG_VERBOSE ? ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping) : NO_FL_ARG), NO_FL_ARG, NO_FL_ARG);
 526
 527                                         Send_Notification(targ, MSG_ONE, MSG_DEATH, (targ.FRAG_VERBOSE ? DEATH_MURDER_FRAGGED_FIRST_VERBOSE : DEATH_MURDER_FRAGGED_FIRST),
 528                                                 s1, NO_STR_ARG, (targ.FRAG_VERBOSE ? attacker.health : NO_FL_ARG), (targ.FRAG_VERBOSE ? attacker.armorvalue : NO_FL_ARG), (targ.FRAG_VERBOSE ? ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping) : NO_FL_ARG));
 529                                 }
 530                                 //Send_Notification(world, MSG_INFO, INFO_DEATH_FRAG_FIRSTBLOOD, s1, s2, attacker.team, NO_FL_ARG, NO_FL_ARG);
 531                         }
 532                         else // normal frags, kill sprees listed
 533                         {
 534                                 if(targ.istypefrag)
 535                                 {
 536                                         Send_Notification(attacker, MSG_ONE, MSG_DEATH, (attacker.FRAG_VERBOSE ? DEATH_MURDER_TYPEFRAG_VERBOSE : DEATH_MURDER_TYPEFRAG),
 537                                                 s2, NO_STR_ARG, attacker.killcount, (attacker.FRAG_VERBOSE ? ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping) : NO_FL_ARG), NO_FL_ARG);
 538
 539                                         Send_Notification(targ, MSG_ONE, MSG_DEATH, (targ.FRAG_VERBOSE ? DEATH_MURDER_TYPEFRAGGED_VERBOSE : DEATH_MURDER_TYPEFRAGGED),
 540                                                 s1, NO_STR_ARG, (targ.FRAG_VERBOSE ? attacker.health : NO_FL_ARG), (targ.FRAG_VERBOSE ? attacker.armorvalue : NO_FL_ARG), (targ.FRAG_VERBOSE ? ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping) : NO_FL_ARG));
 541                                 }
 542                                 else
 543                                 {
 544                                         Send_Notification(attacker, MSG_ONE, MSG_DEATH, (attacker.FRAG_VERBOSE ? DEATH_MURDER_FRAG_VERBOSE : DEATH_MURDER_FRAG),
 545                                                 s2, NO_STR_ARG, attacker.killcount, (attacker.FRAG_VERBOSE ? ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping) : NO_FL_ARG), NO_FL_ARG);
 546
 547                                         Send_Notification(targ, MSG_ONE, MSG_DEATH, (targ.FRAG_VERBOSE ? DEATH_MURDER_FRAGGED_VERBOSE : DEATH_MURDER_FRAGGED),
 548                                                 s1, NO_STR_ARG, (targ.FRAG_VERBOSE ? attacker.health : NO_FL_ARG), (targ.FRAG_VERBOSE ? attacker.armorvalue : NO_FL_ARG), (targ.FRAG_VERBOSE ? ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping) : NO_FL_ARG));
 549                                 }
 550
 551                                 // Send_Notification(world, MSG_WEAPON, 50, s1, s2, attacker.killcount, targ.killcount, Obituary_Score_Position);
 552                                 if(DEATH_WEAPONOF(deathtype)) { print("Currently unhandled...\n"); }
 553                                 else { Obituary_SpecialDeath(targ, TRUE, deathtype, s2, s1, NO_FL_ARG, NO_FL_ARG, NO_FL_ARG); }
 554                         }
 555                 }
 556         }
 557
 558         // =============
 559         // ACCIDENT/TRAP
 560         // =============
 561         else
 562         {
 563                 switch(deathtype)
 564                 {
 565                         // For now, we're just forcing HURTTRIGGER to behave as "DEATH_VOID" and giving it no special options...
 566                         // Later on you will only be able to make custom messages using DEATH_CUSTOM,
 567                         // and there will be a REAL DEATH_VOID implementation which mappers will use.
 568                         /*case DEATH_HURTTRIGGER:
 569                         {
 570                                 s1 = targ.netname;
 571                                 s2 = inflictor.message;
 572                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 573                                 break;
 574                         }*/
 575
 576                         case DEATH_CUSTOM:
 577                         {
 578                                 s1 = targ.netname;
 579                                 s2 = deathmessage;
 580                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 581                                 break;
 582                         }
 583
 584                         default:
 585                         {
 586                                 s1 = targ.netname;
 587                                 s2 = NO_STR_ARG;
 588                                 f1 = f2 = f3 = NO_FL_ARG;
 589                                 break;
 590                         }
 591                 }
 592
 593                 // log and score the death
 594                 LogDeath("accident", deathtype, targ, targ);
 595                 GiveFrags(targ, targ, -1, deathtype);
 596
 597                 // achieve failure
 598                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5)
 599                 {
 600                         AnnounceTo(targ, "botlike");
 601                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 602                 }
 603
 604                 // tell everyone about it
 605                 Obituary_SpecialDeath(targ, FALSE, deathtype, s1, s2, f1, f2, NO_FL_ARG);
 606         }
 607
 608         // Set final information for the death
 609         targ.death_origin = targ.origin;
 610         if(targ != attacker) { targ.killer_origin = attacker.origin; }
 611         if(targ.killcount) { targ.killcount = 0; }
 612 }
 613
 614 // these are updated by each Damage call for use in button triggering and such
 615 entity damage_targ;
 616 entity damage_inflictor;
 617 entity damage_attacker;
 618
 619 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 620 {
 621         float mirrordamage;
 622         float mirrorforce;
 623         float teamdamage0;
 624         entity attacker_save;
 625         mirrordamage = 0;
 626         mirrorforce = 0;
 627
 628         if (gameover || targ.killcount == -666)
 629                 return;
 630
 631         entity oldself;
 632         oldself = self;
 633         self = targ;
 634         damage_targ = targ;
 635         damage_inflictor = inflictor;
 636         damage_attacker = attacker;
 637                 attacker_save = attacker;
 638
 639         if(targ.classname == "player")
 640                 if(targ.hook)
 641                         if(targ.hook.aiment)
 642                                 if(targ.hook.aiment == attacker)
 643                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 644
 645         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 646         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 647         {
 648                 if(targ.classname == "player")
 649                         if not(IsDifferentTeam(targ, attacker))
 650                         {
 651                                 self = oldself;
 652                                 return;
 653                         }
 654         }
 655
 656         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 657         {
 658                 // These are ALWAYS lethal
 659                 // No damage modification here
 660                 // Instead, prepare the victim for his death...
 661                 targ.armorvalue = 0;
 662                 targ.spawnshieldtime = 0;
 663                 targ.health = 0.9; // this is < 1
 664                 targ.flags -= targ.flags & FL_GODMODE;
 665                 damage = 100000;
 666         }
 667         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 668         {
 669                 // no processing
 670         }
 671         else
 672         {
 673                 /*
 674                 skill based bot damage? gtfo. (tZork)
 675                 if (targ.classname == "player")
 676                 if (attacker.classname == "player")
 677                 if (!targ.isbot)
 678                 if (attacker.isbot)
 679                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 680         */
 681
 682                 // nullify damage if teamplay is on
 683                 if(deathtype != DEATH_TELEFRAG)
 684                 if(attacker.classname == "player")
 685                 {
 686                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 687                         {
 688                                 damage = 0;
 689                                 force = '0 0 0';
 690                         }
 691                         else if(!IsDifferentTeam(attacker, targ))
 692                         {
 693                                 if(autocvar_teamplay_mode == 1)
 694                                         damage = 0;
 695                                 else if(attacker != targ)
 696                                 {
 697                                         if(autocvar_teamplay_mode == 3)
 698                                                 damage = 0;
 699                                         else if(autocvar_teamplay_mode == 4)
 700                                         {
 701                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 702                                                 {
 703                                                         teamdamage0 = max(attacker.dmg_team, autocvar_g_teamdamage_threshold);
 704                                                         attacker.dmg_team = attacker.dmg_team + damage;
 705                                                         if(attacker.dmg_team > teamdamage0 && !g_ca)
 706                                                                 mirrordamage = autocvar_g_mirrordamage * (attacker.dmg_team - teamdamage0);
 707                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 708                                                         if(g_minstagib)
 709                                                         {
 710                                                                 if(autocvar_g_friendlyfire == 0)
 711                                                                         damage = 0;
 712                                                         }
 713                                                         else if(g_ca)
 714                                                                 damage = 0;
 715                                                         else
 716                                                                 damage = autocvar_g_friendlyfire * damage;
 717                                                         // mirrordamage will be used LATER
 718
 719                                                         if(autocvar_g_mirrordamage_virtual)
 720                                                         {
 721                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 722                                                                 attacker.dmg_take += v_x;
 723                                                                 attacker.dmg_save += v_y;
 724                                                                 attacker.dmg_inflictor = inflictor;
 725                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 726                                                                 mirrorforce = 0;
 727                                                         }
 728
 729                                                         if(autocvar_g_friendlyfire_virtual)
 730                                                         {
 731                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 732                                                                 targ.dmg_take += v_x;
 733                                                                 targ.dmg_save += v_y;
 734                                                                 targ.dmg_inflictor = inflictor;
 735                                                                 damage = 0;
 736                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 737                                                                         force = '0 0 0';
 738                                                         }
 739                                                 }
 740                                                 else
 741                                                         damage = 0;
 742                                         }
 743                                 }
 744                         }
 745                 }
 746
 747                 if(targ.classname == "player")
 748                 if(attacker.classname == "player")
 749                 if(attacker != targ)
 750                 {
 751                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 752                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 753                 }
 754
 755                 if(targ.classname == "player")
 756                 if (g_minstagib)
 757                 {
 758                         if ((deathtype == DEATH_FALL)  ||
 759                                 (deathtype == DEATH_DROWN) ||
 760                                 (deathtype == DEATH_SLIME) ||
 761                                 (deathtype == DEATH_LAVA)  ||
 762                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 763                         {
 764                                 self = oldself;
 765                                 return;
 766                         }
 767                         if(damage > 0)
 768                             damage = 10000;
 769                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 770                         {
 771                                 targ.armorvalue -= 1;
 772                                 centerprint(targ, strcat("^3Remaining extra lives: ",ftos(targ.armorvalue)));
 773                                 damage = 0;
 774                                 targ.hitsound += 1;
 775                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 776                         }
 777                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 778                         {
 779                                 damage = 0;
 780                                 mirrordamage = 0;
 781                                 if (targ != attacker)
 782                                 {
 783                                         if ((targ.health >= 1) && (targ.classname == "player"))
 784                                                 centerprint(attacker, "Secondary fire inflicts no damage!");
 785                                         force = '0 0 0';
 786                                         // keep mirrorforce
 787                                         attacker = targ;
 788                                 }
 789                         }
 790                 }
 791
 792                 if not(DEATH_ISSPECIAL(deathtype))
 793                 {
 794                         damage *= g_weapondamagefactor;
 795                         mirrordamage *= g_weapondamagefactor;
 796                         force = force * g_weaponforcefactor;
 797                         mirrorforce *= g_weaponforcefactor;
 798                 }
 799
 800                 // should this be changed at all? If so, in what way?
 801                 frag_attacker = attacker;
 802                 frag_target = targ;
 803                 frag_damage = damage;
 804                 frag_force = force;
 805         frag_deathtype = deathtype;
 806                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 807                 damage = frag_damage;
 808                 force = frag_force;
 809
 810                 // apply strength multiplier
 811                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 812                 {
 813                         if(targ == attacker)
 814                         {
 815                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 816                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
 817                         }
 818                         else
 819                         {
 820                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
 821                                 force = force * autocvar_g_balance_powerup_strength_force;
 822                         }
 823                 }
 824
 825                 // apply invincibility multiplier
 826                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 827                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 828
 829                 if (targ == attacker)
 830                 {
 831                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 832                                 damage = 0;
 833                         else
 834                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 835                 }
 836
 837                 if(g_runematch)
 838                 {
 839                         // apply strength rune
 840                         if (attacker.runes & RUNE_STRENGTH)
 841                         {
 842                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 843                                 {
 844                                         damage = damage * autocvar_g_balance_rune_strength_combo_damage;
 845                                         force = force * autocvar_g_balance_rune_strength_combo_force;
 846                                 }
 847                                 else
 848                                 {
 849                                         damage = damage * autocvar_g_balance_rune_strength_damage;
 850                                         force = force * autocvar_g_balance_rune_strength_force;
 851                                 }
 852                         }
 853                         else if (attacker.runes & CURSE_WEAK)
 854                         {
 855                                 damage = damage * autocvar_g_balance_curse_weak_damage;
 856                                 force = force * autocvar_g_balance_curse_weak_force;
 857                         }
 858
 859                         // apply defense rune
 860                         if (targ.runes & RUNE_DEFENSE)
 861                         {
 862                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 863                                         damage = damage * autocvar_g_balance_rune_defense_combo_takedamage;
 864                                 else
 865                                         damage = damage * autocvar_g_balance_rune_defense_takedamage;
 866                         }
 867                         else if (targ.runes & CURSE_VULNER)
 868                                 damage = damage * autocvar_g_balance_curse_vulner_takedamage;
 869                 }
 870
 871                 // count the damage
 872                 if(attacker)
 873                 if(!targ.deadflag)
 874                 if(targ.takedamage == DAMAGE_AIM)
 875                 if(targ != attacker)
 876                 {
 877                         if(damage_headshotbonus)
 878                         {
 879                                 if(targ.classname == "player")
 880                                 {
 881                                         // HEAD SHOT:
 882                                         // find height of hit on player axis
 883                                         // if above view_ofs and below maxs, and also in the middle half of the bbox, it is head shot
 884                                         vector headmins, headmaxs, org;
 885                                         org = antilag_takebackorigin(targ, time - ANTILAG_LATENCY(attacker));
 886                                         headmins = org + GetHeadshotMins(targ);
 887                                         headmaxs = org + GetHeadshotMaxs(targ);
 888                                         if(trace_hits_box(railgun_start, railgun_end, headmins, headmaxs))
 889                                         {
 890                                                 deathtype |= HITTYPE_HEADSHOT;
 891                                         }
 892                                 }
 893                                 else if(targ.classname == "turret_head")
 894                                 {
 895                                         deathtype |= HITTYPE_HEADSHOT;
 896                                 }
 897                                 if(deathtype & HITTYPE_HEADSHOT)
 898                                         if(damage_headshotbonus > 0)
 899                                                 damage *= 1 + damage_headshotbonus;
 900                         }
 901
 902                         entity victim;
 903                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 904                                 victim = targ.owner;
 905                         else
 906                                 victim = targ;
 907
 908                         if(victim.classname == "player" || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 909                         {
 910                                 if(IsDifferentTeam(victim, attacker))
 911                                 {
 912                                         if(damage > 0)
 913                                         {
 914                                                 if(deathtype != DEATH_FIRE)
 915                                                 {
 916                                                         if(victim.BUTTON_CHAT)
 917                                                                 attacker.typehitsound += 1;
 918                                                         else
 919                                                                 attacker.hitsound += 1;
 920                                                 }
 921
 922                                                 damage_goodhits += 1;
 923                                                 damage_gooddamage += damage;
 924
 925                                                 if not(DEATH_ISSPECIAL(deathtype))
 926                                                 {
 927                                                         if(targ.classname == "player") // don't do this for vehicles
 928                                                         if(!g_minstagib)
 929                                                         if(IsFlying(victim))
 930                                                                 yoda = 1;
 931
 932                                                         if(g_minstagib)
 933                                                         if(victim.items & IT_STRENGTH)
 934                                                                 yoda = 1;
 935
 936                                                         if(deathtype & HITTYPE_HEADSHOT)
 937                                                                 headshot = 1;
 938                                                 }
 939                                         }
 940                                 }
 941                                 else
 942                                 {
 943                                         if(deathtype != DEATH_FIRE)
 944                                         {
 945                                                 attacker.typehitsound += 1;
 946                                         }
 947                                         if(mirrordamage > 0)
 948                                                 if(time > attacker.teamkill_complain)
 949                                                 {
 950                                                         attacker.teamkill_complain = time + 5;
 951                                                         attacker.teamkill_soundtime = time + 0.4;
 952                                                         attacker.teamkill_soundsource = targ;
 953                                                 }
 954                                 }
 955                         }
 956                 }
 957         }
 958
 959         // apply push
 960         if (self.damageforcescale)
 961         if (vlen(force))
 962         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 963         {
 964                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 965                 if(self.movetype == MOVETYPE_PHYSICS)
 966                 {
 967                         entity farcent;
 968                         farcent = spawn();
 969                         farcent.classname = "farce";
 970                         farcent.enemy = self;
 971                         farcent.movedir = farce * 10;
 972                         if(self.mass)
 973                                 farcent.movedir = farcent.movedir * self.mass;
 974                         farcent.origin = hitloc;
 975                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 976                         farcent.nextthink = time + 0.1;
 977                         farcent.think = SUB_Remove;
 978                 }
 979                 else
 980                         self.velocity = self.velocity + farce;
 981                 self.flags &~= FL_ONGROUND;
 982                 UpdateCSQCProjectile(self);
 983         }
 984         // apply damage
 985         if (damage != 0 || (self.damageforcescale && vlen(force)))
 986         if (self.event_damage)
 987                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 988         self = oldself;
 989
 990         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 991         {
 992                 if(g_runematch)
 993                 {
 994                         if (attacker.runes & RUNE_VAMPIRE)
 995                         {
 996                         // apply vampire rune
 997                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 998                                 {
 999                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb;
1000                                         attacker.health = bound(
1001                                                 autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 40
1002                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb,
1003                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
1004                                 }
1005                                 else
1006                                 {
1007                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_absorb;
1008                                         attacker.health = bound(
1009                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
1010                                                                                         // empathy won't let you gain health in the same way...
1011                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_absorb,
1012                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
1013                                         }
1014                         }
1015                         // apply empathy curse
1016                         else if (attacker.runes & CURSE_EMPATHY)
1017                         {
1018                                 attacker.health = bound(
1019                                         autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 20
1020                                         attacker.health + damage * autocvar_g_balance_curse_empathy_takedamage,
1021                                         attacker.health);
1022                         }
1023                 }
1024         }
1025
1026         // apply mirror damage if any
1027         if(mirrordamage > 0 || mirrorforce > 0)
1028         {
1029                 attacker = attacker_save;
1030                 if(g_minstagib)
1031                 if(mirrordamage > 0)
1032                 {
1033                         // just lose extra LIVES, don't kill the player for mirror damage
1034                         if(attacker.armorvalue > 0)
1035                         {
1036                                 attacker.armorvalue = attacker.armorvalue - 1;
1037                                 centerprint(attacker, strcat("^3Remaining extra lives: ",ftos(attacker.armorvalue)));
1038                                 attacker.hitsound += 1;
1039                         }
1040                         mirrordamage = 0;
1041                 }
1042
1043                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
1044                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
1045         }
1046 }
1047
1048 float RadiusDamage_running;
1049 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
1050         // Returns total damage applies to creatures
1051 {
1052         entity  targ;
1053         vector  blastorigin;
1054         vector  force;
1055         float   total_damage_to_creatures;
1056         entity  next;
1057         float   tfloordmg;
1058         float   tfloorforce;
1059
1060         float stat_damagedone;
1061
1062         if(RadiusDamage_running)
1063         {
1064                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
1065                 return 0;
1066         }
1067
1068         RadiusDamage_running = 1;
1069
1070         tfloordmg = autocvar_g_throughfloor_damage;
1071         tfloorforce = autocvar_g_throughfloor_force;
1072
1073         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
1074         total_damage_to_creatures = 0;
1075
1076         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
1077                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
1078                 {
1079                         force = inflictor.velocity;
1080                         if(vlen(force) == 0)
1081                                 force = '0 0 -1';
1082                         else
1083                                 force = normalize(force);
1084                         if(forceintensity >= 0)
1085                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
1086                         else
1087                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
1088                 }
1089
1090         stat_damagedone = 0;
1091
1092         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
1093         while (targ)
1094         {
1095                 next = targ.chain;
1096                 if (targ != inflictor)
1097                         if (ignore != targ) if(targ.takedamage)
1098                         {
1099                                 vector nearest;
1100                                 vector diff;
1101                                 float power;
1102
1103                                 // LordHavoc: measure distance to nearest point on target (not origin)
1104                                 // (this guarentees 100% damage on a touch impact)
1105                                 nearest = targ.WarpZone_findradius_nearest;
1106                                 diff = targ.WarpZone_findradius_dist;
1107                                 // round up a little on the damage to ensure full damage on impacts
1108                                 // and turn the distance into a fraction of the radius
1109                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
1110                                 //bprint(" ");
1111                                 //bprint(ftos(power));
1112                                 //if (targ == attacker)
1113                                 //      print(ftos(power), "\n");
1114                                 if (power > 0)
1115                                 {
1116                                         float finaldmg;
1117                                         if (power > 1)
1118                                                 power = 1;
1119                                         finaldmg = coredamage * power + edgedamage * (1 - power);
1120                                         if (finaldmg > 0)
1121                                         {
1122                                                 float a;
1123                                                 float c;
1124                                                 vector hitloc;
1125                                                 vector myblastorigin;
1126                                                 vector center;
1127
1128                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
1129
1130                                                 // if it's a player, use the view origin as reference
1131                                                 center = CENTER_OR_VIEWOFS(targ);
1132
1133                                                 force = normalize(center - myblastorigin);
1134                                                 force = force * (finaldmg / coredamage) * forceintensity;
1135                                                 hitloc = nearest;
1136
1137                                                 if(targ != directhitentity)
1138                                                 {
1139                                                         float hits;
1140                                                         float total;
1141                                                         float hitratio;
1142                                                         float mininv_f, mininv_d;
1143
1144                                                         // test line of sight to multiple positions on box,
1145                                                         // and do damage if any of them hit
1146                                                         hits = 0;
1147
1148                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
1149                                                         // so for a given max stddev:
1150                                                         // n = (1 / (2 * max stddev of hitratio))^2
1151
1152                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
1153                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
1154
1155                                                         if(autocvar_g_throughfloor_debug)
1156                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
1157
1158                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
1159
1160                                                         if(autocvar_g_throughfloor_debug)
1161                                                                 print(sprintf(" steps=%f", total));
1162
1163                                                         if (targ.classname == "player")
1164                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
1165                                                         else
1166                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
1167
1168                                                         if(autocvar_g_throughfloor_debug)
1169                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
1170
1171                                                         for(c = 0; c < total; ++c)
1172                                                         {
1173                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1174                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1175                                                                 if (trace_fraction == 1 || trace_ent == targ)
1176                                                                 {
1177                                                                         ++hits;
1178                                                                         if (hits > 1)
1179                                                                                 hitloc = hitloc + nearest;
1180                                                                         else
1181                                                                                 hitloc = nearest;
1182                                                                 }
1183                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1184                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1185                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1186                                                         }
1187
1188                                                         nearest = hitloc * (1 / max(1, hits));
1189                                                         hitratio = (hits / total);
1190                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1191                                                         finaldmg = finaldmg * a;
1192                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1193                                                         force = force * a;
1194
1195                                                         if(autocvar_g_throughfloor_debug)
1196                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
1197                                                 }
1198
1199                                                 // laser force adjustments :P
1200                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1201                                                 {
1202                                                         if (targ == attacker)
1203                                                         {
1204                                                                 vector vel;
1205
1206                                                                 float force_zscale;
1207                                                                 float force_velocitybiasramp;
1208                                                                 float force_velocitybias;
1209
1210                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1211                                                                 if(deathtype & HITTYPE_SECONDARY)
1212                                                                 {
1213                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1214                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1215                                                                 }
1216                                                                 else
1217                                                                 {
1218                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1219                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1220                                                                 }
1221
1222                                                                 vel = targ.velocity;
1223                                                                 vel_z = 0;
1224                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1225                                                                 force =
1226                                                                         vlen(force)
1227                                                                         *
1228                                                                         normalize(normalize(force) + vel);
1229
1230                                                                 force_z *= force_zscale;
1231                                                         }
1232                                                         else
1233                                                         {
1234                                                                 if(deathtype & HITTYPE_SECONDARY)
1235                                                                 {
1236                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1237                                                                 }
1238                                                                 else
1239                                                                 {
1240                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1241                                                                 }
1242                                                         }
1243                                                 }
1244
1245                                                 //if (targ == attacker)
1246                                                 //{
1247                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1248                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1249                                                 //      print(" (", ftos(a), ")\n");
1250                                                 //}
1251                                                 if(finaldmg || vlen(force))
1252                                                 {
1253                                                         if(targ.iscreature)
1254                                                         {
1255                                                                 total_damage_to_creatures += finaldmg;
1256
1257                                                                 if(accuracy_isgooddamage(attacker, targ))
1258                                                                         stat_damagedone += finaldmg;
1259                                                         }
1260
1261                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1262                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1263                                                         else
1264                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1265                                                 }
1266                                         }
1267                                 }
1268                         }
1269                 targ = next;
1270         }
1271
1272         RadiusDamage_running = 0;
1273
1274         if(!DEATH_ISSPECIAL(deathtype))
1275                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1276
1277         return total_damage_to_creatures;
1278 }
1279
1280 .float fire_damagepersec;
1281 .float fire_endtime;
1282 .float fire_deathtype;
1283 .entity fire_owner;
1284 .float fire_hitsound;
1285 .entity fire_burner;
1286
1287 void fireburner_think();
1288
1289 float Fire_IsBurning(entity e)
1290 {
1291         return (time < e.fire_endtime);
1292 }
1293
1294 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1295 {
1296         float dps;
1297         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1298
1299         if(e.classname == "player")
1300         {
1301                 if(e.deadflag)
1302                         return -1;
1303         }
1304         else
1305         {
1306                 if(!e.fire_burner)
1307                 {
1308                         // print("adding a fire burner to ", e.classname, "\n");
1309                         e.fire_burner = spawn();
1310                         e.fire_burner.classname = "fireburner";
1311                         e.fire_burner.think = fireburner_think;
1312                         e.fire_burner.nextthink = time;
1313                         e.fire_burner.owner = e;
1314                 }
1315         }
1316
1317         t = max(t, 0.1);
1318         dps = d / t;
1319         if(Fire_IsBurning(e))
1320         {
1321                 mintime = e.fire_endtime - time;
1322                 maxtime = max(mintime, t);
1323
1324                 mindps = e.fire_damagepersec;
1325                 maxdps = max(mindps, dps);
1326
1327                 if(maxtime > mintime || maxdps > mindps)
1328                 {
1329                         // Constraints:
1330
1331                         // damage we have right now
1332                         mindamage = mindps * mintime;
1333
1334                         // damage we want to get
1335                         maxdamage = mindamage + d;
1336
1337                         // but we can't exceed maxtime * maxdps!
1338                         totaldamage = min(maxdamage, maxtime * maxdps);
1339
1340                         // LEMMA:
1341                         // Look at:
1342                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1343                         // We see:
1344                         // totaldamage <= maxtime * maxdps
1345                         // ==> totaldamage / maxdps <= maxtime.
1346                         // We also see:
1347                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1348                         //                     >= min(mintime, maxtime)
1349                         // ==> totaldamage / maxdps >= mintime.
1350
1351                         /*
1352                         // how long do we damage then?
1353                         // at least as long as before
1354                         // but, never exceed maxdps
1355                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1356                         */
1357
1358                         // alternate:
1359                         // at most as long as maximum allowed
1360                         // but, never below mindps
1361                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1362
1363                         // assuming t > mintime, dps > mindps:
1364                         // we get d = t * dps = maxtime * maxdps
1365                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1366                         // totaldamage / maxdps = maxtime
1367                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1368                         // FROM THIS:
1369                         // a) totaltime = max(mintime, maxtime) = maxtime
1370                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1371
1372                         // assuming t <= mintime:
1373                         // we get maxtime = mintime
1374                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1375                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1376
1377                         // assuming dps <= mindps:
1378                         // we get mindps = maxdps.
1379                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1380                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1381                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1382
1383                         e.fire_damagepersec = totaldamage / totaltime;
1384                         e.fire_endtime = time + totaltime;
1385                         if(totaldamage > 1.2 * mindamage)
1386                         {
1387                                 e.fire_deathtype = dt;
1388                                 if(e.fire_owner != o)
1389                                 {
1390                                         e.fire_owner = o;
1391                                         e.fire_hitsound = FALSE;
1392                                 }
1393                         }
1394                         if(accuracy_isgooddamage(o, e))
1395                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1396                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1397                 }
1398                 else
1399                         return 0;
1400         }
1401         else
1402         {
1403                 e.fire_damagepersec = dps;
1404                 e.fire_endtime = time + t;
1405                 e.fire_deathtype = dt;
1406                 e.fire_owner = o;
1407                 e.fire_hitsound = FALSE;
1408                 if(accuracy_isgooddamage(o, e))
1409                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1410                 return d;
1411         }
1412 }
1413
1414 void Fire_ApplyDamage(entity e)
1415 {
1416         float t, d, hi, ty;
1417         entity o;
1418
1419         if not(Fire_IsBurning(e))
1420                 return;
1421
1422         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1423         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1424                 o = e.fire_owner;
1425
1426         // water and slime stop fire
1427         if(e.waterlevel)
1428         if(e.watertype != CONTENT_LAVA)
1429                 e.fire_endtime = 0;
1430
1431         // ice stops fire
1432         if(e.freezetag_frozen)
1433                 e.fire_endtime = 0;
1434
1435         t = min(frametime, e.fire_endtime - time);
1436         d = e.fire_damagepersec * t;
1437
1438         hi = e.fire_owner.hitsound;
1439         ty = e.fire_owner.typehitsound;
1440         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1441         if(e.fire_hitsound && e.fire_owner)
1442         {
1443                 e.fire_owner.hitsound = hi;
1444                 e.fire_owner.typehitsound = ty;
1445         }
1446         e.fire_hitsound = TRUE;
1447
1448         if not(IS_INDEPENDENT_PLAYER(e))
1449         FOR_EACH_PLAYER(other) if(e != other)
1450         {
1451                 if(other.classname == "player")
1452                 if(other.deadflag == DEAD_NO)
1453                 if not(IS_INDEPENDENT_PLAYER(other))
1454                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1455                 {
1456                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1457                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1458                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1459                 }
1460         }
1461 }
1462
1463 void Fire_ApplyEffect(entity e)
1464 {
1465         if(Fire_IsBurning(e))
1466                 e.effects |= EF_FLAME;
1467         else
1468                 e.effects &~= EF_FLAME;
1469 }
1470
1471 void fireburner_think()
1472 {
1473         // for players, this is done in the regular loop
1474         if(wasfreed(self.owner))
1475         {
1476                 remove(self);
1477                 return;
1478         }
1479         Fire_ApplyEffect(self.owner);
1480         if(!Fire_IsBurning(self.owner))
1481         {
1482                 self.owner.fire_burner = world;
1483                 remove(self);
1484                 return;
1485         }
1486         Fire_ApplyDamage(self.owner);
1487         self.nextthink = time;
1488 }