qcsrc/server/item_key.qc

   1 /*
   2 TODO:
   3 - add an unlock sound (here to trigger_keylock and to func_door)
   4 - display available keys on the HUD
   5 - make more tests
   6 - think about adding NOT_EASY/NOT_NORMAL/NOT_HARD for Q1 compatibility
   7 - should keys have a trigger?
   8 */
   9
  10 float item_keys_usekey(entity l, entity p) {
  11         float valid = l.itemkeys & p.itemkeys;
  12
  13         if not(valid) {
  14                 // other has none of the needed keys
  15                 return FALSE;
  16         } else if (l.itemkeys == valid) {
  17                 // ALL needed keys were given
  18                 l.itemkeys = 0;
  19                 return TRUE;
  20         } else {
  21                 // only some of the needed keys were given
  22                 l.itemkeys &~= valid;
  23                 return TRUE;
  24         }
  25 }
  26
  27 string item_keys_keylist(float keylist) {
  28         float base, l;
  29         string n;
  30
  31         // no keys
  32         if not(keylist)
  33                 return "";
  34
  35         // one key
  36         if ((keylist & (keylist-1)) != 0)
  37                 return strcat("the ", item_keys_names[lowestbit(keylist)]);
  38
  39         n = "";
  40         base = 0;
  41         while (keylist) {
  42                 l = lowestbit(keylist);
  43                 if (n)
  44                         n = strcat(n, ", the ", item_keys_names[base + l]);
  45                 else
  46                         n = strcat("the ", item_keys_names[base + l]);
  47
  48                 keylist = bitshift(keylist,  -(l + 1));
  49                 base+= l + 1;
  50         }
  51
  52         return n;
  53 }
  54
  55
  56 /*
  57 ================================
  58 item_key
  59 ================================
  60 */
  61
  62 /**
  63  * Key touch handler.
  64  */
  65 void item_key_touch(void) {
  66         if (other.classname != "player")
  67                 return;
  68
  69         // player already picked up this key
  70         if (other.itemkeys & self.itemkeys)
  71                 return;
  72
  73         other.itemkeys |= self.itemkeys;
  74         play2(other, self.noise);
  75
  76         centerprint(other, self.message);
  77 };
  78
  79 /**
  80  * Spawn a key with given model, key code and color.
  81  */
  82 void spawn_item_key() {
  83         precache_model(self.model);
  84
  85         if (self.spawnflags & 1) // FLOATING
  86                 self.noalign = 1;
  87
  88         if (self.noalign)
  89                 self.movetype = MOVETYPE_NONE;
  90         else
  91                 self.movetype = MOVETYPE_TOSS;
  92
  93         precache_sound(self.noise);
  94
  95         self.mdl = self.model;
  96         self.effects = EF_LOWPRECISION;
  97         setmodel(self, self.model);
  98         //setsize(self, '-16 -16 -24', '16 16 32');
  99         setorigin(self, self.origin + '0 0 32');
 100         setsize(self, '-16 -16 -56', '16 16 0');
 101         self.modelflags |= MF_ROTATE;
 102         self.solid = SOLID_TRIGGER;
 103
 104         if (!self.noalign)
 105         {
 106                 // first nudge it off the floor a little bit to avoid math errors
 107                 setorigin(self, self.origin + '0 0 1');
 108                 // note droptofloor returns FALSE if stuck/or would fall too far
 109                 droptofloor();
 110         }
 111
 112         self.touch = item_key_touch;
 113 };
 114
 115
 116 /*QUAKED item_key (0 .5 .8) (-16 -16 -24) (16 16 32) FLOATING
 117 A key entity.
 118 The itemkeys should contain one of the following key IDs:
 119 1 - GOLD key -
 120 2 - SILVER key
 121 4 - BRONZE key
 122 8 - RED keycard
 123 16 - BLUE keycard
 124 32 - GREEN keycard
 125 Custom keys:
 126 ... - last key is 1<<23
 127 Keys with bigger Id than 32 don't have a default netname and model, if you use one of them, you MUST provide those.
 128 -----------KEYS------------
 129 colormod: color of the key (default: '.9 .9 .9').
 130 itemkeys: a key Id.
 131 message: message to print when player picks up this key.
 132 model: custom key model to use.
 133 netname: the display name of the key.
 134 noise: custom sound to play when player picks up the key.
 135 -------- SPAWNFLAGS --------
 136 FLOATING: the item will float in air, instead of aligning to the floor by falling
 137 ---------NOTES----------
 138 This is the only correct way to put keys on the map!
 139
 140 itemkeys MUST always have exactly one bit set.
 141 */
 142 void spawnfunc_item_key() {
 143         local string _model, _netname;
 144         local vector _colormod;
 145
 146         // reject this entity if more than one key was set!
 147         if (self.itemkeys>0 && (self.itemkeys & (self.itemkeys-1)) != 0) {
 148                 objerror("item_key.itemkeys must contain only 1 bit set specifying the key it represents!");
 149                 remove(self);
 150                 return;
 151         }
 152
 153         // find default netname and colormod
 154         switch(self.itemkeys) {
 155         case 1:
 156                 _netname = "GOLD key";
 157                 _colormod = '1 .9 0';
 158                 break;
 159
 160         case 2:
 161                 _netname = "SILVER key";
 162                 _colormod = '.9 .9 .9';
 163                 break;
 164
 165         case 4:
 166                 _netname = "BRONZE key";
 167                 _colormod = '.6 .25 0';
 168                 break;
 169
 170         case 8:
 171                 _netname = "RED keycard";
 172                 _colormod = '.9 0 0';
 173                 break;
 174
 175         case 16:
 176                 _netname = "BLUE keycard";
 177                 _colormod = '0 0 .9';
 178                 break;
 179
 180         case 32:
 181                 _netname = "GREEN keycard";
 182                 _colormod = '0 .9 0';
 183                 break;
 184
 185         default:
 186                 _netname = "FLUFFY PINK keycard";
 187                 _colormod = '1 1 1';
 188
 189                 if (!self.netname) {
 190                         objerror("item_key doesn't have a default name for this key and a custom one was not specified!");
 191                         remove(self);
 192                         return;
 193                 }
 194                 break;
 195
 196         }
 197
 198         // find default model
 199         if (self.itemkeys <= ITEM_KEY_BIT(2)) {
 200                 _model = "models/keys/key.md3";
 201         } else if (self.itemkeys >= ITEM_KEY_BIT(3) && self.itemkeys <= ITEM_KEY_BIT(5)) {
 202                 _model = "models/keys/key.md3"; // FIXME: replace it by a keycard model!
 203         } else if (!self.model) {
 204                 objerror("item_key doesn't have a default model for this key and a custom one was not specified!");
 205                 remove(self);
 206                 return;
 207         }
 208
 209         // set defailt netname
 210         if (!self.netname)
 211                 self.netname = _netname;
 212
 213         // set default colormod
 214         if (!self.colormod)
 215                 self.colormod = _colormod;
 216
 217         // set default model
 218         if (!self.model)
 219                 self.model = _model;
 220
 221         // set default pickup message
 222         if (!self.message)
 223                 self.message = strzone(strcat("You've picked up the ", self.netname, "!"));
 224
 225         if (!self.noise)
 226                 self.noise = "misc/itempickup.wav";
 227
 228         // save the name for later
 229         item_keys_names[lowestbit(self.itemkeys)] = self.netname;
 230
 231         // put the key on the map
 232         spawn_item_key();
 233 }
 234
 235 /*QUAKED item_key1 (0 .5 .8) (-16 -16 -24) (16 16 32) FLOATING
 236 SILVER key.
 237 -----------KEYS------------
 238 colormod: color of the key (default: '.9 .9 .9').
 239 message: message to print when player picks up this key.
 240 model: custom model to use.
 241 noise: custom sound to play when player picks up the key.
 242 -------- SPAWNFLAGS --------
 243 FLOATING: the item will float in air, instead of aligning to the floor by falling
 244 ---------NOTES----------
 245 Don't use this entity on new maps! Use item_key instead.
 246 */
 247 void spawnfunc_item_key1(void) {
 248         self.classname = "item_key";
 249         self.itemkeys = ITEM_KEY_BIT(1);
 250         spawnfunc_item_key();
 251 };
 252
 253 /*QUAKED item_key2 (0 .5 .8) (-16 -16 -24) (16 16 32) FLOATING
 254 GOLD key.
 255 -----------KEYS------------
 256 colormod: color of the key (default: '1 .9 0').
 257 message: message to print when player picks up this key.
 258 model: custom model to use.
 259 noise: custom sound to play when player picks up the key.
 260 -------- SPAWNFLAGS --------
 261 FLOATING: the item will float in air, instead of aligning to the floor by falling
 262 ---------NOTES----------
 263 Don't use this entity on new maps! Use item_key instead.
 264 */
 265 void spawnfunc_item_key2(void) {
 266         self.classname = "item_key";
 267         self.itemkeys = ITEM_KEY_BIT(0);
 268         spawnfunc_item_key();
 269 };
 270
 271
 272 /*
 273 ================================
 274 trigger_keylock
 275 ================================
 276 */
 277
 278 /**
 279  * trigger givent targets
 280  */
 281 void trigger_keylock_trigger(string s) {
 282         local entity t, stemp, otemp, atemp;
 283
 284         stemp = self;
 285         otemp = other;
 286         atemp = activator;
 287
 288
 289         for(t = world; (t = find(t, targetname, s)); )
 290                 if (t.use) {
 291                         self = t;
 292                         other = stemp;
 293                         activator = atemp;
 294                         self.use();
 295                 }
 296
 297         self = stemp;
 298         other = otemp;
 299         activator = atemp;
 300 };
 301
 302 /**
 303  * kill killtarget of trigger keylock.
 304  */
 305 void trigger_keylock_kill(string s) {
 306         local entity t;
 307         for(t = world; (t = find(t, targetname, s)); )
 308                 remove(t);
 309 };
 310
 311 void trigger_keylock_touch(void) {
 312         local float key_used, started_delay;
 313
 314         key_used = FALSE;
 315         started_delay = FALSE;
 316
 317         // only player may trigger the lock
 318         if (other.classname != "player")
 319                 return;
 320
 321
 322         // check silver key
 323         if (self.itemkeys)
 324                 key_used = item_keys_usekey(self, other);
 325
 326         activator = other;
 327
 328         if (self.itemkeys) {
 329                 // at least one of the keys is missing
 330                 if (key_used) {
 331                         // one or more keys were given, but others are still missing!
 332                         play2(other, self.noise1);
 333                         centerprint(other, strcat("You also need ", item_keys_keylist(self.itemkeys), "!"));
 334                         other.key_door_messagetime = time + 2;
 335                 } else if (other.key_door_messagetime <= time) {
 336                         // no keys were given
 337                         play2(other, self.noise2);
 338                         centerprint(other, strcat("You need ", item_keys_keylist(self.itemkeys), "!"));
 339                         other.key_door_messagetime = time + 2;
 340                 }
 341
 342                 // trigger target2
 343                 if (self.delay <= time || started_delay == TRUE)
 344                 if (self.target2) {
 345                         trigger_keylock_trigger(self.target2);
 346                         started_delay = TRUE;
 347                         self.delay = time + self.wait;
 348                 }
 349         } else {
 350                 // all keys were given!
 351                 play2(other, self.noise);
 352                 centerprint(other, self.message);
 353
 354                 if (self.target)
 355                         trigger_keylock_trigger(self.target);
 356
 357                 if (self.killtarget)
 358                         trigger_keylock_kill(self.killtarget);
 359
 360                 remove(self);
 361         }
 362
 363 };
 364
 365 /*QUAKED trigger_keylock (.0 .5 .8) ?
 366 Keylock trigger.  Must target other entities.
 367 This trigger will trigger target entities when all required keys are provided.
 368 -------- KEYS --------
 369 itemkeys: A bit field with key IDs that are needed to open this lock.
 370 sounds: 1 to play misc/secret.wav, 2 to play misc/talk.wav, 3 to play misc/trigger1.wav (3 is default)
 371 target: trigger all entities with this targetname when triggered and all keys have been given to it, then remove this trigger
 372 target2: trigger all entities with this targetname when triggered without giving it all the required keys.
 373 killtarget: remove all entities with this targetname when triggered with all the needed keys.
 374 message: print this message to the player who activated the trigger when all needed keys have been given.
 375 message2: print this message to the player who activated the trigger when not all of the needed keys have been given.
 376 noise: sound to play when lock gets unlocked (default: see sounds)
 377 noise1: sound to play when only some of the needed key were used but not all (default: misc/decreasevalue.wav)
 378 noise2: sound to play when a key is missing (default: misc/talk.wav)
 379 wait: prevent triggering again for this amount of time (default: 5) - applies to target2, target3, target4.
 380 ---------NOTES----------
 381 If spawned without any key specified in itemkeys, this trigger will display an error and remove itself.
 382 message2 and noise2 will be resent to the player every 2 seconds while he is in the trigger zone.
 383 */
 384 void spawnfunc_trigger_keylock(void) {
 385         if (!self.itemkeys) {
 386                 remove(self);
 387                 return;
 388         }
 389
 390         // set unlocked message
 391         if (!self.message)
 392                 self.message = "Unlocked!";
 393
 394         // set default unlock noise
 395         if (!self.noise) {
 396                 if (self.sounds == 1)
 397                         self.noise = "misc/secret.wav";
 398                 else if (self.sounds == 2)
 399                         self.noise = "misc/talk.wav";
 400                 else //if (self.sounds == 3) {
 401                         self.noise = "misc/trigger1.wav";
 402         }
 403
 404         // set default use key sound
 405         if (!self.noise1)
 406                 self.noise1 = "misc/decreasevalue.wav";
 407
 408         // set closed sourd
 409         if (!self.noise2)
 410                 self.noise2 = "misc/talk.wav";
 411
 412         // delay between triggering message2 and trigger2
 413         if (!self.wait)
 414                 self.wait = 5;
 415
 416         // precache sounds
 417         precache_sound(self.noise);
 418         precache_sound(self.noise1);
 419         precache_sound(self.noise2);
 420
 421         EXACTTRIGGER_INIT;
 422
 423         self.touch = trigger_keylock_touch;
 424 };
 425
 426