qcsrc/server/mapvoting.qc

   1 #include "mapvoting.qh"
   2
   3 #include <common/constants.qh>
   4 #include <common/mapinfo.qh>
   5 #include <common/net_linked.qh>
   6 #include <common/playerstats.qh>
   7 #include <common/state.qh>
   8 #include <common/stats.qh>
   9 #include <common/util.qh>
  10 #include <common/weapons/_all.qh>
  11 #include <server/client.qh>
  12 #include <server/command/cmd.qh>
  13 #include <server/command/getreplies.qh>
  14 #include <server/gamelog.qh>
  15 #include <server/world.qh>
  16
  17 // definitions
  18
  19 float mapvote_nextthink;
  20 float mapvote_keeptwotime;
  21 float mapvote_timeout;
  22 const int MAPVOTE_SCREENSHOT_DIRS_COUNT = 4;
  23 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
  24 int mapvote_screenshot_dirs_count;
  25
  26 int mapvote_count;
  27 int mapvote_count_real;
  28 string mapvote_maps[MAPVOTE_COUNT];
  29 int mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
  30 string mapvote_maps_pakfile[MAPVOTE_COUNT];
  31 bool mapvote_maps_suggested[MAPVOTE_COUNT];
  32 string mapvote_suggestions[MAPVOTE_COUNT];
  33 int mapvote_suggestion_ptr;
  34 int mapvote_voters;
  35 int mapvote_selections[MAPVOTE_COUNT];
  36 int mapvote_maps_flags[MAPVOTE_COUNT];
  37 bool mapvote_run;
  38 bool mapvote_detail;
  39 bool mapvote_abstain;
  40 .int mapvote;
  41
  42 entity mapvote_ent;
  43
  44 /**
  45  * Returns the gamtype ID from its name, if type_name isn't a real gametype it
  46  * checks for sv_vote_gametype_(type_name)_type
  47  */
  48 Gametype GameTypeVote_Type_FromString(string type_name)
  49 {
  50         Gametype type = MapInfo_Type_FromString(type_name, false, false);
  51         if (type == NULL)
  52                 type = MapInfo_Type_FromString(cvar_string(
  53                         strcat("sv_vote_gametype_",type_name,"_type")), false, false);
  54         return type;
  55 }
  56
  57 int GameTypeVote_AvailabilityStatus(string type_name)
  58 {
  59         int flag = GTV_FORBIDDEN;
  60
  61         Gametype type = MapInfo_Type_FromString(type_name, false, false);
  62         if ( type == NULL )
  63         {
  64                 type = MapInfo_Type_FromString(cvar_string(
  65                         strcat("sv_vote_gametype_",type_name,"_type")), false, false);
  66                 flag |= GTV_CUSTOM;
  67         }
  68
  69         if( type == NULL )
  70                 return flag;
  71
  72         if ( autocvar_nextmap != "" )
  73         {
  74                 if ( !MapInfo_Get_ByName(autocvar_nextmap, false, NULL) )
  75                         return flag;
  76                 if (!(MapInfo_Map_supportedGametypes & type.m_flags))
  77                         return flag;
  78         }
  79
  80         return flag | GTV_AVAILABLE;
  81 }
  82
  83 int GameTypeVote_GetMask()
  84 {
  85         int n, j, gametype_mask;
  86         n = tokenizebyseparator(autocvar_sv_vote_gametype_options, " ");
  87         n = min(MAPVOTE_COUNT, n);
  88         gametype_mask = 0;
  89         for(j = 0; j < n; ++j)
  90                 gametype_mask |= GameTypeVote_Type_FromString(argv(j)).m_flags;
  91
  92         if (gametype_mask == 0)
  93                 gametype_mask |= MapInfo_CurrentGametype().m_flags;
  94
  95         return gametype_mask;
  96 }
  97
  98 string GameTypeVote_MapInfo_FixName(string m)
  99 {
 100         if ( autocvar_sv_vote_gametype )
 101         {
 102                 MapInfo_Enumerate();
 103                 _MapInfo_FilterGametype(GameTypeVote_GetMask(), 0, MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 104         }
 105         return MapInfo_FixName(m);
 106 }
 107
 108 void MapVote_ClearAllVotes()
 109 {
 110         FOREACH_CLIENT(true, { it.mapvote = 0; });
 111 }
 112
 113 void MapVote_UnzoneStrings()
 114 {
 115         for(int j = 0; j < mapvote_count; ++j)
 116         {
 117                 strfree(mapvote_maps[j]);
 118                 strfree(mapvote_maps_pakfile[j]);
 119         }
 120 }
 121
 122 string MapVote_Suggest(entity this, string m)
 123 {
 124         int i;
 125         if(m == "")
 126                 return "That's not how to use this command.";
 127         if(!autocvar_g_maplist_votable_suggestions)
 128                 return "Suggestions are not accepted on this server.";
 129         if(mapvote_initialized)
 130         if(!gametypevote)
 131                 return "Can't suggest - voting is already in progress!";
 132         m = GameTypeVote_MapInfo_FixName(m);
 133         if (!m)
 134                 return "The map you suggested is not available on this server.";
 135         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
 136                 if(Map_IsRecent(m))
 137                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
 138
 139         if (!autocvar_sv_vote_gametype)
 140         if(!MapInfo_CheckMap(m))
 141                 return "The map you suggested does not support the current game mode.";
 142         for(i = 0; i < mapvote_suggestion_ptr; ++i)
 143                 if(mapvote_suggestions[i] == m)
 144                         return "This map was already suggested.";
 145         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
 146         {
 147                 i = floor(random() * mapvote_suggestion_ptr);
 148         }
 149         else
 150         {
 151                 i = mapvote_suggestion_ptr;
 152                 mapvote_suggestion_ptr += 1;
 153         }
 154         if(mapvote_suggestions[i] != "")
 155                 strunzone(mapvote_suggestions[i]);
 156         mapvote_suggestions[i] = strzone(m);
 157         if(autocvar_sv_eventlog)
 158                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(this.playerid)));
 159         return strcat("Suggestion of ", m, " accepted.");
 160 }
 161
 162 void MapVote_AddVotable(string nextMap, bool isSuggestion)
 163 {
 164         int j, i, o;
 165         string pakfile, mapfile;
 166
 167         if(nextMap == "")
 168                 return;
 169         for(j = 0; j < mapvote_count; ++j)
 170                 if(mapvote_maps[j] == nextMap)
 171                         return;
 172         // suggestions might be no longer valid/allowed after gametype switch!
 173         if(isSuggestion)
 174                 if(!MapInfo_CheckMap(nextMap))
 175                         return;
 176         mapvote_maps[mapvote_count] = strzone(nextMap);
 177         mapvote_maps_suggested[mapvote_count] = isSuggestion;
 178
 179         pakfile = string_null;
 180         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
 181         {
 182                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", nextMap);
 183                 pakfile = whichpack(strcat(mapfile, ".tga"));
 184                 if(pakfile == "")
 185                         pakfile = whichpack(strcat(mapfile, ".jpg"));
 186                 if(pakfile == "")
 187                         pakfile = whichpack(strcat(mapfile, ".png"));
 188                 if(pakfile != "")
 189                         break;
 190         }
 191         if(i >= mapvote_screenshot_dirs_count)
 192                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
 193         for(o = strstrofs(pakfile, "/", 0)+1; o > 0; o = strstrofs(pakfile, "/", 0)+1)
 194                 pakfile = substring(pakfile, o, -1);
 195
 196         mapvote_maps_screenshot_dir[mapvote_count] = i;
 197         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
 198         mapvote_maps_flags[mapvote_count] = GTV_AVAILABLE;
 199
 200         mapvote_count += 1;
 201 }
 202
 203 void MapVote_AddVotableMaps(int nmax, int smax)
 204 {
 205         int available_maps = Maplist_Init();
 206         int max_attempts = available_maps;
 207         if (available_maps >= 2)
 208                 max_attempts = min(available_maps * 5, 100);
 209
 210         if (smax && mapvote_suggestion_ptr)
 211                 for(int i = 0; i < max_attempts && mapvote_count < smax; ++i)
 212                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], true);
 213
 214         for (int i = 0; i < max_attempts && mapvote_count < nmax; ++i)
 215                 MapVote_AddVotable(GetNextMap(), false);
 216 }
 217
 218 bool GameTypeVote_SetGametype(Gametype type);
 219
 220 // gametype_name can be the name of a custom gametype based on Gametype type
 221 void GameTypeVote_ApplyGameType(Gametype type, string gametype_name)
 222 {
 223         if (gametype_name == "")
 224                 gametype_name = MapInfo_Type_ToString(type);
 225
 226         localcmd("sv_vote_gametype_hook_all\n");
 227         localcmd("sv_vote_gametype_hook_", gametype_name, "\n");
 228
 229         if (!GameTypeVote_SetGametype(type))
 230                 LOG_TRACE("Selected gametype is not supported by any map");
 231 }
 232
 233 string voted_gametype_string;
 234 Gametype voted_gametype;
 235 Gametype match_gametype;
 236 void MapVote_Init()
 237 {
 238         int nmax, smax;
 239
 240         MapVote_ClearAllVotes();
 241         MapVote_UnzoneStrings();
 242
 243         mapvote_count = 0;
 244         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
 245         mapvote_abstain = boolean(autocvar_g_maplist_votable_abstain);
 246
 247         if(mapvote_abstain)
 248                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
 249         else
 250                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
 251         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
 252
 253         // we need this for AddVotable, as that cycles through the screenshot dirs
 254         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
 255         if(mapvote_screenshot_dirs_count == 0)
 256                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
 257         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
 258         for(int i = 0; i < mapvote_screenshot_dirs_count; ++i)
 259                 mapvote_screenshot_dirs[i] = strzone(argv(i));
 260
 261         MapVote_AddVotableMaps(nmax, smax);
 262
 263         mapvote_count_real = mapvote_count;
 264         if(mapvote_abstain)
 265                 MapVote_AddVotable("don't care", false);
 266
 267         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
 268
 269         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
 270         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
 271         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
 272                 mapvote_keeptwotime = 0;
 273
 274         MapVote_Spawn();
 275
 276         // If match_gametype is set it means voted_gametype has just been applied (on game type vote end).
 277         // In this case apply back match_gametype here so that the "restart" command, if called,
 278         // properly restarts the map applying the current game type.
 279         // Applying voted_gametype before map vote start is needed to properly initialize map vote.
 280         if (match_gametype)
 281                 GameTypeVote_ApplyGameType(match_gametype, gametype_custom_string);
 282 }
 283
 284 void MapVote_SendPicture(entity to, int id)
 285 {
 286         msg_entity = to;
 287         WriteHeader(MSG_ONE, TE_CSQC_PICTURE);
 288         WriteByte(MSG_ONE, id);
 289         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
 290 }
 291
 292
 293 void MapVote_WriteMask()
 294 {
 295         if ( mapvote_count < 24 )
 296         {
 297                 int mask = 0;
 298                 for(int j = 0; j < mapvote_count; ++j)
 299                 {
 300                         if(mapvote_maps_flags[j] & GTV_AVAILABLE)
 301                                 mask |= BIT(j);
 302                 }
 303
 304                 if(mapvote_count < 8)
 305                         WriteByte(MSG_ENTITY, mask);
 306                 else if (mapvote_count < 16)
 307                         WriteShort(MSG_ENTITY,mask);
 308                 else
 309                         WriteLong(MSG_ENTITY, mask);
 310         }
 311         else
 312         {
 313                 for (int j = 0; j < mapvote_count; ++j)
 314                         WriteByte(MSG_ENTITY, mapvote_maps_flags[j]);
 315         }
 316 }
 317
 318 /*
 319  * Sends a single map vote option to the client
 320  */
 321 void MapVote_SendOption(int i)
 322 {
 323         // abstain
 324         if(mapvote_abstain && i == mapvote_count - 1)
 325         {
 326                 WriteString(MSG_ENTITY, ""); // abstain needs no text
 327                 WriteString(MSG_ENTITY, ""); // abstain needs no pack
 328                 WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
 329         }
 330         else
 331         {
 332                 WriteString(MSG_ENTITY, mapvote_maps[i]);
 333                 WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
 334                 WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
 335         }
 336 }
 337
 338 /*
 339  * Sends a single gametype vote option to the client
 340  */
 341 void GameTypeVote_SendOption(int i)
 342 {
 343         // abstain
 344         if(mapvote_abstain && i == mapvote_count - 1)
 345         {
 346                 WriteString(MSG_ENTITY, ""); // abstain needs no text
 347                 WriteByte(MSG_ENTITY, GTV_AVAILABLE);
 348         }
 349         else
 350         {
 351                 string type_name = mapvote_maps[i];
 352                 WriteString(MSG_ENTITY, type_name);
 353                 WriteByte(MSG_ENTITY, mapvote_maps_flags[i]);
 354                 if ( mapvote_maps_flags[i] & GTV_CUSTOM )
 355                 {
 356                         WriteString(MSG_ENTITY, cvar_string(
 357                                 strcat("sv_vote_gametype_",type_name,"_name")));
 358                         WriteString(MSG_ENTITY, cvar_string(
 359                                 strcat("sv_vote_gametype_",type_name,"_description")));
 360                         WriteString(MSG_ENTITY, cvar_string(
 361                                 strcat("sv_vote_gametype_",type_name,"_type")));
 362                 }
 363         }
 364 }
 365
 366 int mapvote_winner;
 367 float mapvote_winner_time;
 368 bool MapVote_SendEntity(entity this, entity to, int sf)
 369 {
 370         int i;
 371
 372         if(sf & 1)
 373                 sf &= ~2; // if we send 1, we don't need to also send 2
 374
 375         if (!mapvote_winner_time)
 376                 sf &= ~8; // no winner yet
 377
 378         WriteHeader(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
 379         WriteByte(MSG_ENTITY, sf);
 380
 381         if(sf & 1)
 382         {
 383                 // flag 1 == initialization
 384                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
 385                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
 386                 WriteString(MSG_ENTITY, "");
 387                 WriteByte(MSG_ENTITY, mapvote_count);
 388                 WriteByte(MSG_ENTITY, mapvote_abstain);
 389                 WriteByte(MSG_ENTITY, mapvote_detail);
 390                 WriteCoord(MSG_ENTITY, mapvote_timeout);
 391
 392                 if ( gametypevote )
 393                 {
 394                         // gametype vote
 395                         WriteByte(MSG_ENTITY, BIT(0)); // gametypevote_flags
 396                         WriteString(MSG_ENTITY, autocvar_nextmap);
 397                 }
 398                 else if ( autocvar_sv_vote_gametype )
 399                 {
 400                         // map vote but gametype has been chosen via voting screen
 401                         WriteByte(MSG_ENTITY, BIT(1)); // gametypevote_flags
 402                         string voted_gametype_name;
 403                         if (voted_gametype_string == MapInfo_Type_ToString(voted_gametype))
 404                                 voted_gametype_name = MapInfo_Type_ToText(voted_gametype);
 405                         else
 406                                 voted_gametype_name = cvar_string(strcat("sv_vote_gametype_", voted_gametype_string, "_name"));
 407                         WriteString(MSG_ENTITY, voted_gametype_name);
 408                 }
 409                 else
 410                         WriteByte(MSG_ENTITY, 0); // map vote
 411
 412                 MapVote_WriteMask();
 413
 414                 // Send data for the vote options
 415                 for(i = 0; i < mapvote_count; ++i)
 416                 {
 417                         if(gametypevote)
 418                                 GameTypeVote_SendOption(i);
 419                         else
 420                                 MapVote_SendOption(i);
 421                 }
 422         }
 423
 424         if(sf & 2)
 425         {
 426                 // flag 2 == update of mask
 427                 MapVote_WriteMask();
 428         }
 429
 430         if(sf & 4)
 431         {
 432                 if(mapvote_detail)
 433                         for(i = 0; i < mapvote_count; ++i)
 434                                 if ( mapvote_maps_flags[i] & GTV_AVAILABLE )
 435                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
 436
 437                 WriteByte(MSG_ENTITY, to.mapvote);
 438         }
 439
 440         if(sf & 8)
 441         {
 442                 WriteByte(MSG_ENTITY, mapvote_winner + 1);
 443         }
 444
 445         return true;
 446 }
 447
 448 void MapVote_Spawn()
 449 {
 450         Net_LinkEntity(mapvote_ent = new(mapvote_ent), false, 0, MapVote_SendEntity);
 451 }
 452
 453 void MapVote_TouchMask()
 454 {
 455         mapvote_ent.SendFlags |= 2;
 456 }
 457
 458 void MapVote_TouchVotes(entity voter)
 459 {
 460         mapvote_ent.SendFlags |= 4;
 461 }
 462
 463 void MapVote_Winner(int mappos)
 464 {
 465         mapvote_ent.SendFlags |= 8;
 466         mapvote_winner_time = time;
 467         mapvote_winner = mappos;
 468 }
 469
 470 bool MapVote_Finished(int mappos)
 471 {
 472         if(alreadychangedlevel)
 473                 return false;
 474
 475         string result;
 476         int i;
 477         int didntvote;
 478
 479         if(autocvar_sv_eventlog)
 480         {
 481                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
 482                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
 483                 didntvote = mapvote_voters;
 484                 for(i = 0; i < mapvote_count; ++i)
 485                         if(mapvote_maps_flags[i] & GTV_AVAILABLE )
 486                         {
 487                                 didntvote -= mapvote_selections[i];
 488                                 if(i != mappos)
 489                                 {
 490                                         result = strcat(result, ":", mapvote_maps[i]);
 491                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
 492                                 }
 493                         }
 494                 result = strcat(result, ":didn't vote:", ftos(didntvote));
 495
 496                 GameLogEcho(result);
 497                 if(mapvote_maps_suggested[mappos])
 498                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
 499         }
 500
 501         FOREACH_CLIENT(IS_REAL_CLIENT(it), { FixClientCvars(it); });
 502
 503         if(gametypevote)
 504         {
 505                 if ( GameTypeVote_Finished(mappos) )
 506                 {
 507                         gametypevote = false;
 508                         if(autocvar_nextmap != "")
 509                         {
 510                                 Map_Goto_SetStr(autocvar_nextmap);
 511                                 Map_Goto(0);
 512                                 alreadychangedlevel = true;
 513                                 strfree(voted_gametype_string);
 514                                 return true;
 515                         }
 516                         else
 517                                 MapVote_Init();
 518                 }
 519                 return false;
 520         }
 521
 522         MapVote_Winner(mappos);
 523         alreadychangedlevel = true;
 524
 525         return true;
 526 }
 527
 528 void MapVote_CheckRules_1()
 529 {
 530         for (int i = 0; i < mapvote_count; ++i)
 531                 if (mapvote_maps_flags[i] & GTV_AVAILABLE)
 532                 {
 533                         //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
 534                         mapvote_selections[i] = 0;
 535                 }
 536
 537         mapvote_voters = 0;
 538         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 539                 ++mapvote_voters;
 540                 if (it.mapvote)
 541                 {
 542                         int idx = it.mapvote - 1;
 543                         //dprint("Player ", it.netname, " vote = ", ftos(idx), "\n");
 544                         ++mapvote_selections[idx];
 545                 }
 546         });
 547 }
 548
 549 bool MapVote_CheckRules_2()
 550 {
 551         int i;
 552         int firstPlace, secondPlace, currentPlace;
 553         int firstPlaceVotes, secondPlaceVotes, currentVotes;
 554         int mapvote_voters_real;
 555         string result;
 556
 557         if(mapvote_count_real == 1)
 558                 return MapVote_Finished(0);
 559
 560         mapvote_voters_real = mapvote_voters;
 561         if(mapvote_abstain)
 562                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
 563
 564         RandomSelection_Init();
 565         currentPlace = 0;
 566         currentVotes = -1;
 567         for(i = 0; i < mapvote_count_real; ++i)
 568                 if ( mapvote_maps_flags[i] & GTV_AVAILABLE )
 569                 {
 570                         RandomSelection_AddFloat(i, 1, mapvote_selections[i]);
 571                         if ( gametypevote && mapvote_maps[i] == MapInfo_Type_ToString(MapInfo_CurrentGametype()) )
 572                         {
 573                                 currentVotes = mapvote_selections[i];
 574                                 currentPlace = i;
 575                         }
 576                 }
 577         firstPlaceVotes = RandomSelection_best_priority;
 578         if (gametypevote && autocvar_sv_vote_gametype_default_current && firstPlaceVotes == 0)
 579                 firstPlace = currentPlace;
 580         else
 581                 firstPlace = RandomSelection_chosen_float;
 582
 583         //dprint("First place: ", ftos(firstPlace), "\n");
 584         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
 585
 586         RandomSelection_Init();
 587         for(i = 0; i < mapvote_count_real; ++i)
 588                 if(i != firstPlace)
 589                 if ( mapvote_maps_flags[i] & GTV_AVAILABLE )
 590                         RandomSelection_AddFloat(i, 1, mapvote_selections[i]);
 591         secondPlace = RandomSelection_chosen_float;
 592         secondPlaceVotes = RandomSelection_best_priority;
 593         //dprint("Second place: ", ftos(secondPlace), "\n");
 594         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
 595
 596         if(firstPlace == -1)
 597                 error("No first place in map vote... WTF?");
 598
 599         if(secondPlace == -1 || time > mapvote_timeout
 600                 || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes
 601                 || mapvote_selections[mapvote_count - 1] == mapvote_voters)
 602         {
 603                 return MapVote_Finished(firstPlace);
 604         }
 605
 606         if(mapvote_keeptwotime)
 607                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
 608                 {
 609                         MapVote_TouchMask();
 610                         mapvote_keeptwotime = 0;
 611                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
 612                         result = strcat(result, ":", ftos(firstPlaceVotes));
 613                         result = strcat(result, ":", mapvote_maps[secondPlace]);
 614                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
 615                         int didntvote = mapvote_voters;
 616                         for(i = 0; i < mapvote_count; ++i)
 617                         {
 618                                 didntvote -= mapvote_selections[i];
 619                                 if(i != firstPlace)
 620                                         if(i != secondPlace)
 621                                         {
 622                                                 result = strcat(result, ":", mapvote_maps[i]);
 623                                                 result = strcat(result, ":", ftos(mapvote_selections[i]));
 624                                                 if(i < mapvote_count_real)
 625                                                 {
 626                                                         mapvote_maps_flags[i] &= ~GTV_AVAILABLE;
 627                                                 }
 628                                         }
 629                         }
 630                         result = strcat(result, ":didn't vote:", ftos(didntvote));
 631                         if(autocvar_sv_eventlog)
 632                                 GameLogEcho(result);
 633                 }
 634
 635         return false;
 636 }
 637
 638 void MapVote_Tick()
 639 {
 640         MapVote_CheckRules_1(); // count
 641         if(MapVote_CheckRules_2()) // decide
 642                 return;
 643
 644         int totalvotes = 0;
 645         FOREACH_CLIENT(true, {
 646                 if(!IS_REAL_CLIENT(it))
 647                 {
 648                         // apply the same special health value to bots too for consistency's sake
 649                         if(GetResource(it, RES_HEALTH) != 2342)
 650                                 SetResourceExplicit(it, RES_HEALTH, 2342);
 651                         continue;
 652                 }
 653                 // hide scoreboard again
 654                 if(GetResource(it, RES_HEALTH) != 2342)
 655                 {
 656                         SetResourceExplicit(it, RES_HEALTH, 2342); // health in the voting phase
 657                         CS(it).impulse = 0;
 658
 659                         msg_entity = it;
 660                         WriteByte(MSG_ONE, SVC_FINALE);
 661                         WriteString(MSG_ONE, "");
 662                 }
 663
 664                 // clear possibly invalid votes
 665                 if ( !(mapvote_maps_flags[it.mapvote-1] & GTV_AVAILABLE) )
 666                         it.mapvote = 0;
 667                 // use impulses as new vote
 668                 if(CS(it).impulse >= 1 && CS(it).impulse <= mapvote_count)
 669                         if( mapvote_maps_flags[CS(it).impulse - 1] & GTV_AVAILABLE )
 670                         {
 671                                 it.mapvote = CS(it).impulse;
 672                                 MapVote_TouchVotes(it);
 673                         }
 674                 CS(it).impulse = 0;
 675
 676                 if(it.mapvote)
 677                         ++totalvotes;
 678         });
 679
 680         MapVote_CheckRules_1(); // just count
 681 }
 682
 683 void MapVote_Start()
 684 {
 685         // if mapvote is already running, don't do this initialization again
 686         if(mapvote_run) { return; }
 687
 688         // don't start mapvote until after playerstats gamereport is sent
 689         if(PlayerStats_GameReport_DelayMapVote) { return; }
 690
 691         MapInfo_Enumerate();
 692         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
 693                 mapvote_run = true;
 694 }
 695
 696 void MapVote_Think()
 697 {
 698         if(!mapvote_run)
 699                 return;
 700
 701         if (mapvote_winner_time)
 702         {
 703                 if (time > mapvote_winner_time + 1)
 704                 {
 705                         if (voted_gametype)
 706                         {
 707                                 // clear match_gametype so that GameTypeVote_ApplyGameType
 708                                 // prints the game type switch message
 709                                 match_gametype = NULL;
 710                                 GameTypeVote_ApplyGameType(voted_gametype, voted_gametype_string);
 711                         }
 712
 713                         Map_Goto_SetStr(mapvote_maps[mapvote_winner]);
 714                         Map_Goto(0);
 715                         strfree(voted_gametype_string);
 716                 }
 717                 return;
 718         }
 719
 720         if(alreadychangedlevel)
 721                 return;
 722
 723         if(time < mapvote_nextthink)
 724                 return;
 725         //dprint("tick\n");
 726
 727         mapvote_nextthink = time + 0.5;
 728         if (mapvote_nextthink > mapvote_timeout - 0.1) // make sure there's no delay when map vote times out
 729                 mapvote_nextthink = mapvote_timeout + 0.001;
 730
 731         if(!mapvote_initialized)
 732         {
 733                 if(autocvar_rescan_pending == 1)
 734                 {
 735                         cvar_set("rescan_pending", "2");
 736                         localcmd("fs_rescan\nrescan_pending 3\n");
 737                         return;
 738                 }
 739                 else if(autocvar_rescan_pending == 2)
 740                 {
 741                         return;
 742                 }
 743                 else if(autocvar_rescan_pending == 3)
 744                 {
 745                         // now build missing mapinfo files
 746                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
 747                                 return;
 748
 749                         // we're done, start the timer
 750                         cvar_set("rescan_pending", "0");
 751                 }
 752
 753                 mapvote_initialized = true;
 754                 if(DoNextMapOverride(0))
 755                         return;
 756                 if(!autocvar_g_maplist_votable || player_count <= 0)
 757                 {
 758                         GotoNextMap(0);
 759                         return;
 760                 }
 761
 762                 if(autocvar_sv_vote_gametype) { GameTypeVote_Start(); }
 763                 else if(autocvar_nextmap == "") { MapVote_Init(); }
 764         }
 765
 766         MapVote_Tick();
 767 }
 768
 769 bool GameTypeVote_SetGametype(Gametype type)
 770 {
 771         if (MapInfo_CurrentGametype() == type)
 772                 return true;
 773
 774         Gametype tsave = MapInfo_CurrentGametype();
 775
 776         MapInfo_SwitchGameType(type);
 777
 778         MapInfo_Enumerate();
 779         MapInfo_FilterGametype(type, MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 780         if(MapInfo_count > 0)
 781         {
 782                 // update lsmaps in case the gametype changed, this way people can easily list maps for it
 783                 if(lsmaps_reply != "") { strunzone(lsmaps_reply); }
 784                 lsmaps_reply = strzone(getlsmaps());
 785
 786                 if (!match_gametype) // don't show this msg if we are temporarily switching game type
 787                         bprint("Game type successfully switched to ", MapInfo_Type_ToString(type), "\n");
 788         }
 789         else
 790         {
 791                 bprint("Cannot use this game type: no map for it found\n");
 792                 MapInfo_SwitchGameType(tsave);
 793                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 794                 return false;
 795         }
 796
 797         cvar_set("g_maplist", MapInfo_ListAllowedMaps(type, MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()) );
 798
 799         return true;
 800 }
 801
 802 bool gametypevote_finished;
 803 bool GameTypeVote_Finished(int pos)
 804 {
 805         if(!gametypevote || gametypevote_finished)
 806                 return false;
 807
 808         match_gametype = MapInfo_CurrentGametype();
 809         voted_gametype = GameTypeVote_Type_FromString(mapvote_maps[pos]);
 810         strcpy(voted_gametype_string, mapvote_maps[pos]);
 811
 812         GameTypeVote_ApplyGameType(voted_gametype, voted_gametype_string);
 813
 814         // save to a cvar so it can be applied back when gametype is temporary
 815         // changed on gametype vote end of the next game
 816         if (mapvote_maps_flags[pos] & GTV_CUSTOM)
 817                 cvar_set("_sv_vote_gametype_custom", voted_gametype_string);
 818
 819         gametypevote_finished = true;
 820
 821         return true;
 822 }
 823
 824 bool GameTypeVote_AddVotable(string nextMode)
 825 {
 826         if ( nextMode == "" || GameTypeVote_Type_FromString(nextMode) == NULL )
 827                 return false;
 828
 829         for(int j = 0; j < mapvote_count; ++j)
 830                 if(mapvote_maps[j] == nextMode)
 831                         return false;
 832
 833         mapvote_maps[mapvote_count] = strzone(nextMode);
 834         mapvote_maps_suggested[mapvote_count] = false;
 835
 836         mapvote_maps_screenshot_dir[mapvote_count] = 0;
 837         mapvote_maps_pakfile[mapvote_count] = strzone("");
 838         mapvote_maps_flags[mapvote_count] = GameTypeVote_AvailabilityStatus(nextMode);
 839
 840         mapvote_count += 1;
 841
 842         return true;
 843
 844 }
 845
 846 bool GameTypeVote_Start()
 847 {
 848         MapVote_ClearAllVotes();
 849         MapVote_UnzoneStrings();
 850
 851         mapvote_count = 0;
 852         mapvote_timeout = time + autocvar_sv_vote_gametype_timeout;
 853         mapvote_abstain = false;
 854         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
 855
 856         int n = tokenizebyseparator(autocvar_sv_vote_gametype_options, " ");
 857         n = min(MAPVOTE_COUNT, n);
 858
 859         int really_available, which_available;
 860         really_available = 0;
 861         which_available = -1;
 862         for(int j = 0; j < n; ++j)
 863         {
 864                 if ( GameTypeVote_AddVotable(argv(j)) )
 865                 if ( mapvote_maps_flags[j] & GTV_AVAILABLE )
 866                 {
 867                         really_available++;
 868                         which_available = j;
 869                 }
 870         }
 871
 872         mapvote_count_real = mapvote_count;
 873
 874         gametypevote = true;
 875
 876         if ( really_available == 0 )
 877         {
 878                 if ( mapvote_count > 0 )
 879                         strunzone(mapvote_maps[0]);
 880                 mapvote_maps[0] = strzone(MapInfo_Type_ToString(MapInfo_CurrentGametype()));
 881                 //GameTypeVote_Finished(0);
 882                 MapVote_Finished(0);
 883                 return false;
 884         }
 885         if ( really_available == 1 )
 886         {
 887                 //GameTypeVote_Finished(which_available);
 888                 MapVote_Finished(which_available);
 889                 return false;
 890         }
 891
 892         mapvote_count_real = mapvote_count;
 893
 894         mapvote_keeptwotime = time + autocvar_sv_vote_gametype_keeptwotime;
 895         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
 896                 mapvote_keeptwotime = 0;
 897
 898         MapVote_Spawn();
 899
 900         return true;
 901 }