qcsrc/server/miscfunctions.qc

   1 #if defined(CSQC)
   2 #elif defined(MENUQC)
   3 #elif defined(SVQC)
   4         #include "miscfunctions.qh"
   5         #include "../dpdefs/progsdefs.qh"
   6     #include "../dpdefs/dpextensions.qh"
   7     #include "../common/playerstats.qh"
   8     #include "../warpzonelib/anglestransform.qh"
   9     #include "../warpzonelib/server.qh"
  10     #include "../common/constants.qh"
  11     #include "../common/teams.qh"
  12     #include "../common/util.qh"
  13     #include "../common/urllib.qh"
  14     #include "../common/command/generic.qh"
  15     #include "../common/weapons/weapons.qh"
  16     #include "weapons/accuracy.qh"
  17     #include "weapons/csqcprojectile.qh"
  18     #include "weapons/selection.qh"
  19     #include "t_items.qh"
  20     #include "autocvars.qh"
  21     #include "constants.qh"
  22     #include "defs.qh"
  23     #include "../common/notifications.qh"
  24     #include "../common/deathtypes.qh"
  25     #include "mutators/mutators_include.qh"
  26     #include "tturrets/include/turrets_early.qh"
  27     #include "../common/mapinfo.qh"
  28     #include "command/common.qh"
  29     #include "../csqcmodellib/sv_model.qh"
  30     #include "ipban.qh"
  31 #endif
  32
  33 void crosshair_trace(entity pl)
  34 {
  35         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  36 }
  37 void crosshair_trace_plusvisibletriggers(entity pl)
  38 {
  39         entity first;
  40         entity e;
  41         first = findchainfloat(solid, SOLID_TRIGGER);
  42
  43         for (e = first; e; e = e.chain)
  44                 if (e.model != "")
  45                         e.solid = SOLID_BSP;
  46
  47         crosshair_trace(pl);
  48
  49         for (e = first; e; e = e.chain)
  50                 e.solid = SOLID_TRIGGER;
  51 }
  52 void WarpZone_crosshair_trace(entity pl)
  53 {
  54         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  55 }
  56
  57
  58 string admin_name(void)
  59 {
  60         if(autocvar_sv_adminnick != "")
  61                 return autocvar_sv_adminnick;
  62         else
  63                 return "SERVER ADMIN";
  64 }
  65
  66 void DistributeEvenly_Init(float amount, float totalweight)
  67 {
  68     if (DistributeEvenly_amount)
  69     {
  70         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  71         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  72     }
  73     if (totalweight == 0)
  74         DistributeEvenly_amount = 0;
  75     else
  76         DistributeEvenly_amount = amount;
  77     DistributeEvenly_totalweight = totalweight;
  78 }
  79 float DistributeEvenly_Get(float weight)
  80 {
  81     float f;
  82     if (weight <= 0)
  83         return 0;
  84     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  85     DistributeEvenly_totalweight -= weight;
  86     DistributeEvenly_amount -= f;
  87     return f;
  88 }
  89 float DistributeEvenly_GetRandomized(float weight)
  90 {
  91     float f;
  92     if (weight <= 0)
  93         return 0;
  94     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  95     DistributeEvenly_totalweight -= weight;
  96     DistributeEvenly_amount -= f;
  97     return f;
  98 }
  99
 100
 101 void GameLogEcho(string s)
 102 {
 103     string fn;
 104     float matches;
 105
 106     if (autocvar_sv_eventlog_files)
 107     {
 108         if (!logfile_open)
 109         {
 110             logfile_open = true;
 111             matches = autocvar_sv_eventlog_files_counter + 1;
 112             cvar_set("sv_eventlog_files_counter", ftos(matches));
 113             fn = ftos(matches);
 114             if (strlen(fn) < 8)
 115                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 116             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 117             logfile = fopen(fn, FILE_APPEND);
 118             fputs(logfile, ":logversion:3\n");
 119         }
 120         if (logfile >= 0)
 121         {
 122             if (autocvar_sv_eventlog_files_timestamps)
 123                 fputs(logfile, strcat(":time:", strftime(true, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 124             else
 125                 fputs(logfile, strcat(s, "\n"));
 126         }
 127     }
 128     if (autocvar_sv_eventlog_console)
 129     {
 130         print(s, "\n");
 131     }
 132 }
 133
 134 void GameLogInit()
 135 {
 136     logfile_open = 0;
 137     // will be opened later
 138 }
 139
 140 void GameLogClose()
 141 {
 142     if (logfile_open && logfile >= 0)
 143     {
 144         fclose(logfile);
 145         logfile = -1;
 146     }
 147 }
 148
 149 entity findnearest(vector point, .string field, string value, vector axismod)
 150 {
 151     entity localhead;
 152     float i;
 153     float j;
 154     float len;
 155     vector dist;
 156
 157     float num_nearest;
 158     num_nearest = 0;
 159
 160     localhead = find(world, field, value);
 161     while (localhead)
 162     {
 163         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 164             dist = localhead.oldorigin;
 165         else
 166             dist = localhead.origin;
 167         dist = dist - point;
 168         dist = dist.x * axismod.x * '1 0 0' + dist.y * axismod.y * '0 1 0' + dist.z * axismod.z * '0 0 1';
 169         len = vlen(dist);
 170
 171         for (i = 0; i < num_nearest; ++i)
 172         {
 173             if (len < nearest_length[i])
 174                 break;
 175         }
 176
 177         // now i tells us where to insert at
 178         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 179         if (i < NUM_NEAREST_ENTITIES)
 180         {
 181             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 182             {
 183                 nearest_length[j + 1] = nearest_length[j];
 184                 nearest_entity[j + 1] = nearest_entity[j];
 185             }
 186             nearest_length[i] = len;
 187             nearest_entity[i] = localhead;
 188             if (num_nearest < NUM_NEAREST_ENTITIES)
 189                 num_nearest = num_nearest + 1;
 190         }
 191
 192         localhead = find(localhead, field, value);
 193     }
 194
 195     // now use the first one from our list that we can see
 196     for (i = 0; i < num_nearest; ++i)
 197     {
 198         traceline(point, nearest_entity[i].origin, true, world);
 199         if (trace_fraction == 1)
 200         {
 201             if (i != 0)
 202             {
 203                 dprint("Nearest point (");
 204                 dprint(nearest_entity[0].netname);
 205                 dprint(") is not visible, using a visible one.\n");
 206             }
 207             return nearest_entity[i];
 208         }
 209     }
 210
 211     if (num_nearest == 0)
 212         return world;
 213
 214     dprint("Not seeing any location point, using nearest as fallback.\n");
 215     /* DEBUGGING CODE:
 216     dprint("Candidates were: ");
 217     for(j = 0; j < num_nearest; ++j)
 218     {
 219         if(j != 0)
 220                 dprint(", ");
 221         dprint(nearest_entity[j].netname);
 222     }
 223     dprint("\n");
 224     */
 225
 226     return nearest_entity[0];
 227 }
 228
 229 void spawnfunc_target_location()
 230 {
 231     self.classname = "target_location";
 232     // location name in netname
 233     // eventually support: count, teamgame selectors, line of sight?
 234 }
 235
 236 void spawnfunc_info_location()
 237 {
 238     self.classname = "target_location";
 239     self.message = self.netname;
 240 }
 241
 242 string NearestLocation(vector p)
 243 {
 244     entity loc;
 245     string ret;
 246     ret = "somewhere";
 247     loc = findnearest(p, classname, "target_location", '1 1 1');
 248     if (loc)
 249     {
 250         ret = loc.message;
 251     }
 252     else
 253     {
 254         loc = findnearest(p, target, "###item###", '1 1 4');
 255         if (loc)
 256             ret = loc.netname;
 257     }
 258     return ret;
 259 }
 260
 261 string formatmessage(string msg)
 262 {
 263         float p, p1, p2;
 264         float n;
 265         vector cursor;
 266         entity cursor_ent;
 267         string escape;
 268         string replacement;
 269         p = 0;
 270         n = 7;
 271
 272         WarpZone_crosshair_trace(self);
 273         cursor = trace_endpos;
 274         cursor_ent = trace_ent;
 275
 276         while (1) {
 277                 if (n < 1)
 278                         break; // too many replacements
 279
 280                 n = n - 1;
 281                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 282                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 283
 284                 if (p1 < 0)
 285                         p1 = p2;
 286
 287                 if (p2 < 0)
 288                         p2 = p1;
 289
 290                 p = min(p1, p2);
 291
 292                 if (p < 0)
 293                         break;
 294
 295                 replacement = substring(msg, p, 2);
 296                 escape = substring(msg, p + 1, 1);
 297
 298                 if (escape == "%")
 299                         replacement = "%";
 300                 else if (escape == "\\")
 301                         replacement = "\\";
 302                 else if (escape == "n")
 303                         replacement = "\n";
 304                 else if (escape == "a")
 305                         replacement = ftos(floor(self.armorvalue));
 306                 else if (escape == "h")
 307                         replacement = ftos(floor(self.health));
 308                 else if (escape == "l")
 309                         replacement = NearestLocation(self.origin);
 310                 else if (escape == "y")
 311                         replacement = NearestLocation(cursor);
 312                 else if (escape == "d")
 313                         replacement = NearestLocation(self.death_origin);
 314                 else if (escape == "w") {
 315                         float wep;
 316                         wep = self.weapon;
 317                         if (!wep)
 318                                 wep = self.switchweapon;
 319                         if (!wep)
 320                                 wep = self.cnt;
 321                         replacement = WEP_NAME(wep);
 322                 } else if (escape == "W") {
 323                         if (self.items & IT_SHELLS) replacement = "shells";
 324                         else if (self.items & IT_NAILS) replacement = "bullets";
 325                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 326                         else if (self.items & IT_CELLS) replacement = "cells";
 327                         else if (self.items & IT_PLASMA) replacement = "plasma";
 328                         else replacement = "batteries"; // ;)
 329                 } else if (escape == "x") {
 330                         replacement = cursor_ent.netname;
 331                         if (replacement == "" || !cursor_ent)
 332                                 replacement = "nothing";
 333                 } else if (escape == "s")
 334                         replacement = ftos(vlen(self.velocity - self.velocity.z * '0 0 1'));
 335                 else if (escape == "S")
 336                         replacement = ftos(vlen(self.velocity));
 337
 338                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 339                 p = p + strlen(replacement);
 340         }
 341         return msg;
 342 }
 343
 344 float boolean(float value) { // if value is 0 return false (0), otherwise return true (1)
 345         return (value == 0) ? false : true;
 346 }
 347
 348 /*
 349 =============
 350 GetCvars
 351 =============
 352 Called with:
 353   0:  sends the request
 354   >0: receives a cvar from name=argv(f) value=argv(f+1)
 355 */
 356 void GetCvars_handleString(string thisname, float f, .string field, string name)
 357 {
 358         if (f < 0)
 359         {
 360                 if (self.field)
 361                         strunzone(self.field);
 362                 self.field = string_null;
 363         }
 364         else if (f > 0)
 365         {
 366                 if (thisname == name)
 367                 {
 368                         if (self.field)
 369                                 strunzone(self.field);
 370                         self.field = strzone(argv(f + 1));
 371                 }
 372         }
 373         else
 374                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 375 }
 376 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 377 {
 378         GetCvars_handleString(thisname, f, field, name);
 379         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 380                 if (thisname == name)
 381                 {
 382                         string s;
 383                         s = func(strcat1(self.field));
 384                         if (s != self.field)
 385                         {
 386                                 strunzone(self.field);
 387                                 self.field = strzone(s);
 388                         }
 389                 }
 390 }
 391 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 392 {
 393         if (f < 0)
 394         {
 395         }
 396         else if (f > 0)
 397         {
 398                 if (thisname == name)
 399                         self.field = stof(argv(f + 1));
 400         }
 401         else
 402                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 403 }
 404 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 405 {
 406         if (f < 0)
 407         {
 408         }
 409         else if (f > 0)
 410         {
 411                 if (thisname == name)
 412                 {
 413                         if(!self.field)
 414                         {
 415                                 self.field = stof(argv(f + 1));
 416                                 if(!self.field)
 417                                         self.field = -1;
 418                         }
 419                 }
 420         }
 421         else
 422         {
 423                 if(!self.field)
 424                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 425         }
 426 }
 427 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 428 {
 429         string o;
 430         o = W_FixWeaponOrder_ForceComplete(wo);
 431         if(self.weaponorder_byimpulse)
 432         {
 433                 strunzone(self.weaponorder_byimpulse);
 434                 self.weaponorder_byimpulse = string_null;
 435         }
 436         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 437         return o;
 438 }
 439 void GetCvars(float f)
 440 {
 441         string s = string_null;
 442
 443         if (f > 0)
 444                 s = strcat1(argv(f));
 445
 446         get_cvars_f = f;
 447         get_cvars_s = s;
 448
 449         MUTATOR_CALLHOOK(GetCvars);
 450
 451         Notification_GetCvars();
 452
 453         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 454         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 455         GetCvars_handleFloat(s, f, cvar_cl_jetpack_jump, "cl_jetpack_jump");
 456         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 457         GetCvars_handleString(s, f, cvar_cl_physics, "cl_physics");
 458         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 459         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 460         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 461         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 462         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 463         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 464         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 465         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 466         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 467         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 468         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 469         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 470         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 471         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 472         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 473         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 474         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 475         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 476         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 477         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 478
 479         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 480         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 481
 482         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 483         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 484         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 485         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 486         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 487
 488         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 489         if (f > 0)
 490         {
 491                 if (s == "cl_weaponpriority")
 492                         self.switchweapon = w_getbestweapon(self);
 493                 if (s == "cl_allow_uidtracking")
 494                         PlayerStats_GameReport_AddPlayer(self);
 495         }
 496 }
 497
 498 // decolorizes and team colors the player name when needed
 499 string playername(entity p)
 500 {
 501     string t;
 502     if (teamplay && !intermission_running && IS_PLAYER(p))
 503     {
 504         t = Team_ColorCode(p.team);
 505         return strcat(t, strdecolorize(p.netname));
 506     }
 507     else
 508         return p.netname;
 509 }
 510
 511 vector randompos(vector m1, vector m2)
 512 {
 513     vector v;
 514     m2 = m2 - m1;
 515     v.x = m2_x * random() + m1_x;
 516     v.y = m2_y * random() + m1_y;
 517     v.z = m2_z * random() + m1_z;
 518     return  v;
 519 }
 520
 521 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO: what still needs done?
 522 {
 523         int i = weaponinfo.weapon;
 524         int d = 0;
 525
 526         if (!i)
 527                 return 0;
 528
 529         if (g_lms || g_ca || allguns)
 530         {
 531                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 532                         d = true;
 533                 else
 534                         d = false;
 535         }
 536         else if (g_cts)
 537                 d = (i == WEP_SHOTGUN);
 538         else if (g_nexball)
 539                 d = 0; // weapon is set a few lines later
 540         else
 541                 d = !(!weaponinfo.weaponstart);
 542
 543         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 544                 d |= (i == WEP_HOOK);
 545         if(!g_cts && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 546                 d = 0;
 547
 548         float t = weaponinfo.weaponstartoverride;
 549
 550         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 551
 552         // bit order in t:
 553         // 1: want or not
 554         // 2: is default?
 555         // 4: is set by default?
 556         if(t < 0)
 557                 t = 4 | (3 * d);
 558         else
 559                 t |= (2 * d);
 560
 561         return t;
 562 }
 563
 564 void readplayerstartcvars()
 565 {
 566         entity e;
 567         float i, j, t;
 568         string s;
 569
 570         // initialize starting values for players
 571         start_weapons = '0 0 0';
 572         start_weapons_default = '0 0 0';
 573         start_weapons_defaultmask = '0 0 0';
 574         start_items = 0;
 575         start_ammo_shells = 0;
 576         start_ammo_nails = 0;
 577         start_ammo_rockets = 0;
 578         start_ammo_cells = 0;
 579         start_ammo_plasma = 0;
 580         start_health = cvar("g_balance_health_start");
 581         start_armorvalue = cvar("g_balance_armor_start");
 582
 583         g_weaponarena = 0;
 584         g_weaponarena_weapons = '0 0 0';
 585
 586         s = cvar_string("g_weaponarena");
 587         if (s == "0" || s == "")
 588         {
 589                 if(g_ca)
 590                         s = "most";
 591         }
 592
 593         if (s == "0" || s == "")
 594         {
 595                 // no arena
 596         }
 597         else if (s == "off")
 598         {
 599                 // forcibly turn off weaponarena
 600         }
 601         else if (s == "all" || s == "1")
 602         {
 603                 g_weaponarena = 1;
 604                 g_weaponarena_list = "All Weapons";
 605                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 606                 {
 607                         e = get_weaponinfo(j);
 608                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 609                                 g_weaponarena_weapons |= WepSet_FromWeapon(j);
 610                 }
 611         }
 612         else if (s == "most")
 613         {
 614                 g_weaponarena = 1;
 615                 g_weaponarena_list = "Most Weapons";
 616                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 617                 {
 618                         e = get_weaponinfo(j);
 619                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 620                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 621                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 622                 }
 623         }
 624         else if (s == "none")
 625         {
 626                 g_weaponarena = 1;
 627                 g_weaponarena_list = "No Weapons";
 628         }
 629         else
 630         {
 631                 g_weaponarena = 1;
 632                 t = tokenize_console(s);
 633                 g_weaponarena_list = "";
 634                 for (i = 0; i < t; ++i)
 635                 {
 636                         s = argv(i);
 637                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 638                         {
 639                                 e = get_weaponinfo(j);
 640                                 if (e.netname == s)
 641                                 {
 642                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 643                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 644                                         break;
 645                                 }
 646                         }
 647                         if (j > WEP_LAST)
 648                         {
 649                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 650                         }
 651                 }
 652                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 653         }
 654
 655         if(g_weaponarena)
 656                 g_weaponarena_random = cvar("g_weaponarena_random");
 657         else
 658                 g_weaponarena_random = 0;
 659         g_weaponarena_random_with_blaster = cvar("g_weaponarena_random_with_blaster");
 660
 661         if (g_weaponarena)
 662         {
 663                 g_weapon_stay = 0; // incompatible
 664                 start_weapons = g_weaponarena_weapons;
 665                 start_items |= IT_UNLIMITED_AMMO;
 666         }
 667         else
 668         {
 669                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 670                 {
 671                         e = get_weaponinfo(i);
 672                         int w = want_weapon(e, false);
 673                         if(w & 1)
 674                                 start_weapons |= WepSet_FromWeapon(i);
 675                         if(w & 2)
 676                                 start_weapons_default |= WepSet_FromWeapon(i);
 677                         if(w & 4)
 678                                 start_weapons_defaultmask |= WepSet_FromWeapon(i);
 679                 }
 680         }
 681
 682         if(!cvar("g_use_ammunition"))
 683                 start_items |= IT_UNLIMITED_AMMO;
 684
 685         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 686         {
 687                 start_ammo_shells = 999;
 688                 start_ammo_nails = 999;
 689                 start_ammo_rockets = 999;
 690                 start_ammo_cells = 999;
 691                 start_ammo_plasma = 999;
 692                 start_ammo_fuel = 999;
 693         }
 694         else
 695         {
 696                 start_ammo_shells = cvar("g_start_ammo_shells");
 697                 start_ammo_nails = cvar("g_start_ammo_nails");
 698                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 699                 start_ammo_cells = cvar("g_start_ammo_cells");
 700                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 701                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 702         }
 703
 704         if (warmup_stage)
 705         {
 706                 warmup_start_ammo_shells = start_ammo_shells;
 707                 warmup_start_ammo_nails = start_ammo_nails;
 708                 warmup_start_ammo_rockets = start_ammo_rockets;
 709                 warmup_start_ammo_cells = start_ammo_cells;
 710                 warmup_start_ammo_plasma = start_ammo_plasma;
 711                 warmup_start_ammo_fuel = start_ammo_fuel;
 712                 warmup_start_health = start_health;
 713                 warmup_start_armorvalue = start_armorvalue;
 714                 warmup_start_weapons = start_weapons;
 715                 warmup_start_weapons_default = start_weapons_default;
 716                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 717
 718                 if (!g_weaponarena && !g_ca)
 719                 {
 720                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 721                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 722                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 723                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 724                         warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
 725                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 726                         warmup_start_health = cvar("g_warmup_start_health");
 727                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 728                         warmup_start_weapons = '0 0 0';
 729                         warmup_start_weapons_default = '0 0 0';
 730                         warmup_start_weapons_defaultmask = '0 0 0';
 731                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 732                         {
 733                                 e = get_weaponinfo(i);
 734                                 int w = want_weapon(e, g_warmup_allguns);
 735                                 if(w & 1)
 736                                         warmup_start_weapons |= WepSet_FromWeapon(i);
 737                                 if(w & 2)
 738                                         warmup_start_weapons_default |= WepSet_FromWeapon(i);
 739                                 if(w & 4)
 740                                         warmup_start_weapons_defaultmask |= WepSet_FromWeapon(i);
 741                         }
 742                 }
 743         }
 744
 745         if (g_jetpack)
 746                 start_items |= IT_JETPACK;
 747
 748         MUTATOR_CALLHOOK(SetStartItems);
 749
 750         if ((start_items & IT_JETPACK) || (g_grappling_hook && (start_weapons & WEPSET_HOOK)))
 751         {
 752                 start_items |= IT_FUEL_REGEN;
 753                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 754                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 755         }
 756
 757         WepSet precache_weapons = start_weapons;
 758         if (g_warmup_allguns != 1)
 759                 precache_weapons |= warmup_start_weapons;
 760         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 761         {
 762                 e = get_weaponinfo(i);
 763                 if(precache_weapons & WepSet_FromWeapon(i))
 764                         WEP_ACTION(i, WR_INIT);
 765         }
 766
 767         start_ammo_shells = max(0, start_ammo_shells);
 768         start_ammo_nails = max(0, start_ammo_nails);
 769         start_ammo_rockets = max(0, start_ammo_rockets);
 770         start_ammo_cells = max(0, start_ammo_cells);
 771         start_ammo_plasma = max(0, start_ammo_plasma);
 772         start_ammo_fuel = max(0, start_ammo_fuel);
 773
 774         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 775         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 776         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 777         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 778         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 779         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 780 }
 781
 782 float sound_allowed(float _dest, entity e)
 783 {
 784     // sounds from world may always pass
 785     for (;;)
 786     {
 787         if (e.classname == "body")
 788             e = e.enemy;
 789         else if (e.realowner && e.realowner != e)
 790             e = e.realowner;
 791         else if (e.owner && e.owner != e)
 792             e = e.owner;
 793         else
 794             break;
 795     }
 796     // sounds to self may always pass
 797     if (_dest == MSG_ONE)
 798         if (e == msg_entity)
 799             return true;
 800     // sounds by players can be removed
 801     if (autocvar_bot_sound_monopoly)
 802         if (IS_REAL_CLIENT(e))
 803             return false;
 804     // anything else may pass
 805     return true;
 806 }
 807
 808 #undef sound
 809 void sound(entity e, float chan, string samp, float vol, float _atten)
 810 {
 811     if (!sound_allowed(MSG_BROADCAST, e))
 812         return;
 813     sound7(e, chan, samp, vol, _atten, 0, 0);
 814 }
 815
 816 void soundtoat(float _dest, entity e, vector o, float chan, string samp, float vol, float _atten)
 817 {
 818     float entno, idx;
 819
 820     if (!sound_allowed(_dest, e))
 821         return;
 822
 823     entno = num_for_edict(e);
 824     idx = precache_sound_index(samp);
 825
 826     float sflags;
 827     sflags = 0;
 828
 829     _atten = floor(_atten * 64);
 830     vol = floor(vol * 255);
 831
 832     if (vol != 255)
 833         sflags |= SND_VOLUME;
 834     if (_atten != 64)
 835         sflags |= SND_ATTENUATION;
 836     if (entno >= 8192 || chan < 0 || chan > 7)
 837         sflags |= SND_LARGEENTITY;
 838     if (idx >= 256)
 839         sflags |= SND_LARGESOUND;
 840
 841     WriteByte(_dest, SVC_SOUND);
 842     WriteByte(_dest, sflags);
 843     if (sflags & SND_VOLUME)
 844         WriteByte(_dest, vol);
 845     if (sflags & SND_ATTENUATION)
 846         WriteByte(_dest, _atten);
 847     if (sflags & SND_LARGEENTITY)
 848     {
 849         WriteShort(_dest, entno);
 850         WriteByte(_dest, chan);
 851     }
 852     else
 853     {
 854         WriteShort(_dest, entno * 8 + chan);
 855     }
 856     if (sflags & SND_LARGESOUND)
 857         WriteShort(_dest, idx);
 858     else
 859         WriteByte(_dest, idx);
 860
 861     WriteCoord(_dest, o.x);
 862     WriteCoord(_dest, o.y);
 863     WriteCoord(_dest, o.z);
 864 }
 865 void soundto(float _dest, entity e, float chan, string samp, float vol, float _atten)
 866 {
 867     vector o;
 868
 869     if (!sound_allowed(_dest, e))
 870         return;
 871
 872     o = e.origin + 0.5 * (e.mins + e.maxs);
 873     soundtoat(_dest, e, o, chan, samp, vol, _atten);
 874 }
 875 void soundat(entity e, vector o, float chan, string samp, float vol, float _atten)
 876 {
 877     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, _atten);
 878 }
 879 void stopsoundto(float _dest, entity e, float chan)
 880 {
 881     float entno;
 882
 883     if (!sound_allowed(_dest, e))
 884         return;
 885
 886     entno = num_for_edict(e);
 887
 888     if (entno >= 8192 || chan < 0 || chan > 7)
 889     {
 890         float idx, sflags;
 891         idx = precache_sound_index("misc/null.wav");
 892         sflags = SND_LARGEENTITY;
 893         if (idx >= 256)
 894             sflags |= SND_LARGESOUND;
 895         WriteByte(_dest, SVC_SOUND);
 896         WriteByte(_dest, sflags);
 897         WriteShort(_dest, entno);
 898         WriteByte(_dest, chan);
 899         if (sflags & SND_LARGESOUND)
 900             WriteShort(_dest, idx);
 901         else
 902             WriteByte(_dest, idx);
 903         WriteCoord(_dest, e.origin.x);
 904         WriteCoord(_dest, e.origin.y);
 905         WriteCoord(_dest, e.origin.z);
 906     }
 907     else
 908     {
 909         WriteByte(_dest, SVC_STOPSOUND);
 910         WriteShort(_dest, entno * 8 + chan);
 911     }
 912 }
 913 void stopsound(entity e, float chan)
 914 {
 915     if (!sound_allowed(MSG_BROADCAST, e))
 916         return;
 917
 918     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
 919     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
 920 }
 921
 922 void play2(entity e, string filename)
 923 {
 924     //stuffcmd(e, strcat("play2 ", filename, "\n"));
 925     msg_entity = e;
 926     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTEN_NONE);
 927 }
 928
 929 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
 930 .float spamtime;
 931 float spamsound(entity e, float chan, string samp, float vol, float _atten)
 932 {
 933     if (!sound_allowed(MSG_BROADCAST, e))
 934         return false;
 935
 936     if (time > e.spamtime)
 937     {
 938         e.spamtime = time;
 939         sound(e, chan, samp, vol, _atten);
 940         return true;
 941     }
 942     return false;
 943 }
 944
 945 void play2team(float t, string filename)
 946 {
 947     entity head;
 948
 949     if (autocvar_bot_sound_monopoly)
 950         return;
 951
 952     FOR_EACH_REALPLAYER(head)
 953     {
 954         if (head.team == t)
 955             play2(head, filename);
 956     }
 957 }
 958
 959 void play2all(string samp)
 960 {
 961     if (autocvar_bot_sound_monopoly)
 962         return;
 963
 964     sound(world, CH_INFO, samp, VOL_BASE, ATTEN_NONE);
 965 }
 966
 967 void PrecachePlayerSounds(string f);
 968 void precache_playermodel(string m)
 969 {
 970         float globhandle, i, n;
 971         string f;
 972
 973         if(substring(m, -9,5) == "_lod1")
 974                 return;
 975         if(substring(m, -9,5) == "_lod2")
 976                 return;
 977         precache_model(m);
 978         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
 979         if(fexists(f))
 980                 precache_model(f);
 981         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
 982         if(fexists(f))
 983                 precache_model(f);
 984
 985         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
 986         if (globhandle < 0)
 987                 return;
 988         n = search_getsize(globhandle);
 989         for (i = 0; i < n; ++i)
 990         {
 991                 //print(search_getfilename(globhandle, i), "\n");
 992                 f = search_getfilename(globhandle, i);
 993                 PrecachePlayerSounds(f);
 994         }
 995         search_end(globhandle);
 996 }
 997 void precache_all_playermodels(string pattern)
 998 {
 999         float globhandle, i, n;
1000         string f;
1001
1002         globhandle = search_begin(pattern, true, false);
1003         if (globhandle < 0)
1004                 return;
1005         n = search_getsize(globhandle);
1006         for (i = 0; i < n; ++i)
1007         {
1008                 //print(search_getfilename(globhandle, i), "\n");
1009                 f = search_getfilename(globhandle, i);
1010                 precache_playermodel(f);
1011         }
1012         search_end(globhandle);
1013 }
1014
1015 void precache()
1016 {
1017     // gamemode related things
1018     precache_model ("models/misc/chatbubble.spr");
1019         precache_model("models/ice/ice.md3");
1020
1021 #ifdef TTURRETS_ENABLED
1022     if (autocvar_g_turrets)
1023         turrets_precash();
1024 #endif
1025
1026     // Precache all player models if desired
1027     if (autocvar_sv_precacheplayermodels)
1028     {
1029         PrecachePlayerSounds("sound/player/default.sounds");
1030         precache_all_playermodels("models/player/*.zym");
1031         precache_all_playermodels("models/player/*.dpm");
1032         precache_all_playermodels("models/player/*.md3");
1033         precache_all_playermodels("models/player/*.psk");
1034         precache_all_playermodels("models/player/*.iqm");
1035     }
1036
1037     if (autocvar_sv_defaultcharacter)
1038     {
1039         string s;
1040         s = autocvar_sv_defaultplayermodel_red;
1041         if (s != "")
1042             precache_playermodel(s);
1043         s = autocvar_sv_defaultplayermodel_blue;
1044         if (s != "")
1045             precache_playermodel(s);
1046         s = autocvar_sv_defaultplayermodel_yellow;
1047         if (s != "")
1048             precache_playermodel(s);
1049         s = autocvar_sv_defaultplayermodel_pink;
1050         if (s != "")
1051             precache_playermodel(s);
1052         s = autocvar_sv_defaultplayermodel;
1053         if (s != "")
1054             precache_playermodel(s);
1055     }
1056
1057     if (g_footsteps)
1058     {
1059         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1060         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1061     }
1062
1063     // gore and miscellaneous sounds
1064     //precache_sound ("misc/h2ohit.wav");
1065     precache_model ("models/hook.md3");
1066     precache_sound ("misc/armorimpact.wav");
1067     precache_sound ("misc/bodyimpact1.wav");
1068     precache_sound ("misc/bodyimpact2.wav");
1069     precache_sound ("misc/gib.wav");
1070     precache_sound ("misc/gib_splat01.wav");
1071     precache_sound ("misc/gib_splat02.wav");
1072     precache_sound ("misc/gib_splat03.wav");
1073     precache_sound ("misc/gib_splat04.wav");
1074     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1075     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1076     precache_sound ("misc/null.wav");
1077     precache_sound ("misc/spawn.wav");
1078     precache_sound ("misc/talk.wav");
1079     precache_sound ("misc/teleport.wav");
1080     precache_sound ("misc/poweroff.wav");
1081     precache_sound ("player/lava.wav");
1082     precache_sound ("player/slime.wav");
1083
1084     precache_model ("models/sprites/0.spr32");
1085     precache_model ("models/sprites/1.spr32");
1086     precache_model ("models/sprites/2.spr32");
1087     precache_model ("models/sprites/3.spr32");
1088     precache_model ("models/sprites/4.spr32");
1089     precache_model ("models/sprites/5.spr32");
1090     precache_model ("models/sprites/6.spr32");
1091     precache_model ("models/sprites/7.spr32");
1092     precache_model ("models/sprites/8.spr32");
1093     precache_model ("models/sprites/9.spr32");
1094     precache_model ("models/sprites/10.spr32");
1095
1096     // common weapon precaches
1097         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1098     precache_sound ("weapons/weapon_switch.wav");
1099     precache_sound ("weapons/weaponpickup.wav");
1100     precache_sound ("weapons/unavailable.wav");
1101     precache_sound ("weapons/dryfire.wav");
1102     if (g_grappling_hook)
1103     {
1104         precache_sound ("weapons/hook_fire.wav"); // hook
1105         precache_sound ("weapons/hook_impact.wav"); // hook
1106     }
1107
1108     precache_model("models/elaser.mdl");
1109     precache_model("models/laser.mdl");
1110     precache_model("models/ebomb.mdl");
1111
1112 #if 0
1113     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1114
1115     if (!self.noise && self.music) // quake 3 uses the music field
1116         self.noise = self.music;
1117
1118     // plays music for the level if there is any
1119     if (self.noise)
1120     {
1121         precache_sound (self.noise);
1122         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTEN_NONE);
1123     }
1124 #endif
1125
1126 #include "precache-for-csqc.inc"
1127 }
1128
1129
1130 void make_safe_for_remove(entity e)
1131 {
1132     if (e.initialize_entity)
1133     {
1134         entity ent, prev = world;
1135         for (ent = initialize_entity_first; ent; )
1136         {
1137             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1138             {
1139                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1140                 // skip it in linked list
1141                 if (prev)
1142                 {
1143                     prev.initialize_entity_next = ent.initialize_entity_next;
1144                     ent = prev.initialize_entity_next;
1145                 }
1146                 else
1147                 {
1148                     initialize_entity_first = ent.initialize_entity_next;
1149                     ent = initialize_entity_first;
1150                 }
1151             }
1152             else
1153             {
1154                 prev = ent;
1155                 ent = ent.initialize_entity_next;
1156             }
1157         }
1158     }
1159 }
1160
1161 void objerror(string s)
1162 {
1163     make_safe_for_remove(self);
1164     builtin_objerror(s);
1165 }
1166
1167 .float remove_except_protected_forbidden;
1168 void remove_except_protected(entity e)
1169 {
1170         if(e.remove_except_protected_forbidden)
1171                 error("not allowed to remove this at this point");
1172         builtin_remove(e);
1173 }
1174
1175 void remove_unsafely(entity e)
1176 {
1177     if(e.classname == "spike")
1178         error("Removing spikes is forbidden (crylink bug), please report");
1179     builtin_remove(e);
1180 }
1181
1182 void remove_safely(entity e)
1183 {
1184     make_safe_for_remove(e);
1185     builtin_remove(e);
1186 }
1187
1188 void InitializeEntity(entity e, void(void) func, float order)
1189 {
1190     entity prev, cur;
1191
1192     if (!e || e.initialize_entity)
1193     {
1194         // make a proxy initializer entity
1195         entity e_old;
1196         e_old = e;
1197         e = spawn();
1198         e.classname = "initialize_entity";
1199         e.enemy = e_old;
1200     }
1201
1202     e.initialize_entity = func;
1203     e.initialize_entity_order = order;
1204
1205     cur = initialize_entity_first;
1206     prev = world;
1207     for (;;)
1208     {
1209         if (!cur || cur.initialize_entity_order > order)
1210         {
1211             // insert between prev and cur
1212             if (prev)
1213                 prev.initialize_entity_next = e;
1214             else
1215                 initialize_entity_first = e;
1216             e.initialize_entity_next = cur;
1217             return;
1218         }
1219         prev = cur;
1220         cur = cur.initialize_entity_next;
1221     }
1222 }
1223 void InitializeEntitiesRun()
1224 {
1225     entity startoflist;
1226     startoflist = initialize_entity_first;
1227     initialize_entity_first = world;
1228     remove = remove_except_protected;
1229     for (self = startoflist; self; self = self.initialize_entity_next)
1230     {
1231         self.remove_except_protected_forbidden = 1;
1232     }
1233     for (self = startoflist; self; )
1234     {
1235         entity e;
1236         var void(void) func;
1237         e = self.initialize_entity_next;
1238         func = self.initialize_entity;
1239         self.initialize_entity_order = 0;
1240         self.initialize_entity = func_null;
1241         self.initialize_entity_next = world;
1242         self.remove_except_protected_forbidden = 0;
1243         if (self.classname == "initialize_entity")
1244         {
1245             entity e_old;
1246             e_old = self.enemy;
1247             builtin_remove(self);
1248             self = e_old;
1249         }
1250         //dprint("Delayed initialization: ", self.classname, "\n");
1251         if(func)
1252             func();
1253         else
1254         {
1255             eprint(self);
1256             backtrace(strcat("Null function in: ", self.classname, "\n"));
1257         }
1258         self = e;
1259     }
1260     remove = remove_unsafely;
1261 }
1262
1263 void UncustomizeEntitiesRun()
1264 {
1265     entity oldself;
1266     oldself = self;
1267     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1268         self.uncustomizeentityforclient();
1269     self = oldself;
1270 }
1271 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1272 {
1273     e.customizeentityforclient = customizer;
1274     e.uncustomizeentityforclient = uncustomizer;
1275     e.uncustomizeentityforclient_set = !!uncustomizer;
1276 }
1277
1278
1279 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1280 {
1281     vector mi, ma;
1282
1283     if (e.classname == "")
1284         e.classname = "net_linked";
1285
1286     if (e.model == "" || self.modelindex == 0)
1287     {
1288         mi = e.mins;
1289         ma = e.maxs;
1290         setmodel(e, "null");
1291         setsize(e, mi, ma);
1292     }
1293
1294     e.SendEntity = sendfunc;
1295     e.SendFlags = 0xFFFFFF;
1296
1297     if (!docull)
1298         e.effects |= EF_NODEPTHTEST;
1299
1300     if (dt)
1301     {
1302         e.nextthink = time + dt;
1303         e.think = SUB_Remove;
1304     }
1305 }
1306
1307
1308 entity eliminatedPlayers;
1309 .float(entity) isEliminated;
1310 float EliminatedPlayers_SendEntity(entity to, float sendflags)
1311 {
1312         float i, f, b;
1313         entity e;
1314         WriteByte(MSG_ENTITY, ENT_CLIENT_ELIMINATEDPLAYERS);
1315         WriteByte(MSG_ENTITY, sendflags);
1316
1317         if(sendflags & 1)
1318         {
1319                 for(i = 1; i <= maxclients; i += 8)
1320                 {
1321                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
1322                         {
1323                                 if(eliminatedPlayers.isEliminated(e))
1324                                         f |= b;
1325                         }
1326                         WriteByte(MSG_ENTITY, f);
1327                 }
1328         }
1329
1330         return true;
1331 }
1332
1333 void EliminatedPlayers_Init(float(entity) isEliminated_func)
1334 {
1335         if(eliminatedPlayers)
1336         {
1337                 backtrace("Can't spawn eliminatedPlayers again!");
1338                 return;
1339         }
1340         Net_LinkEntity(eliminatedPlayers = spawn(), false, 0, EliminatedPlayers_SendEntity);
1341         eliminatedPlayers.isEliminated = isEliminated_func;
1342 }
1343
1344
1345 void adaptor_think2touch()
1346 {
1347     entity o;
1348     o = other;
1349     other = world;
1350     self.touch();
1351     other = o;
1352 }
1353
1354 void adaptor_think2use()
1355 {
1356     entity o, a;
1357     o = other;
1358     a = activator;
1359     activator = world;
1360     other = world;
1361     self.use();
1362     other = o;
1363     activator = a;
1364 }
1365
1366 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1367 {
1368         if(!(self.flags & FL_ONGROUND)) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1369                 self.projectiledeathtype |= HITTYPE_SPLASH;
1370         adaptor_think2use();
1371 }
1372
1373 // deferred dropping
1374 void DropToFloor_Handler()
1375 {
1376     builtin_droptofloor();
1377     self.dropped_origin = self.origin;
1378 }
1379
1380 void droptofloor()
1381 {
1382     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1383 }
1384
1385
1386
1387 float trace_hits_box_a0, trace_hits_box_a1;
1388
1389 float trace_hits_box_1d(float end, float thmi, float thma)
1390 {
1391     if (end == 0)
1392     {
1393         // just check if x is in range
1394         if (0 < thmi)
1395             return false;
1396         if (0 > thma)
1397             return false;
1398     }
1399     else
1400     {
1401         // do the trace with respect to x
1402         // 0 -> end has to stay in thmi -> thma
1403         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1404         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1405         if (trace_hits_box_a0 > trace_hits_box_a1)
1406             return false;
1407     }
1408     return true;
1409 }
1410
1411 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1412 {
1413     end -= start;
1414     thmi -= start;
1415     thma -= start;
1416     // now it is a trace from 0 to end
1417
1418     trace_hits_box_a0 = 0;
1419     trace_hits_box_a1 = 1;
1420
1421     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
1422         return false;
1423     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
1424         return false;
1425     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
1426         return false;
1427
1428     return true;
1429 }
1430
1431 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1432 {
1433     return trace_hits_box(start, end, thmi - ma, thma - mi);
1434 }
1435
1436 float SUB_NoImpactCheck()
1437 {
1438         // zero hitcontents = this is not the real impact, but either the
1439         // mirror-impact of something hitting the projectile instead of the
1440         // projectile hitting the something, or a touchareagrid one. Neither of
1441         // these stop the projectile from moving, so...
1442         if(trace_dphitcontents == 0)
1443         {
1444                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1445                 dprintf("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n", num_for_edict(self), self.classname, vtos(self.origin));
1446                 checkclient();
1447         }
1448     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1449         return 1;
1450     if (other == world && self.size != '0 0 0')
1451     {
1452         vector tic;
1453         tic = self.velocity * sys_frametime;
1454         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1455         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1456         if (trace_fraction >= 1)
1457         {
1458             dprint("Odd... did not hit...?\n");
1459         }
1460         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1461         {
1462             dprint("Detected and prevented the sky-grapple bug.\n");
1463             return 1;
1464         }
1465     }
1466
1467     return 0;
1468 }
1469
1470 #define SUB_OwnerCheck() (other && (other == self.owner))
1471
1472 void RemoveGrapplingHook(entity pl);
1473 void W_Crylink_Dequeue(entity e);
1474 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1475 {
1476         if(SUB_OwnerCheck())
1477                 return true;
1478         if(SUB_NoImpactCheck())
1479         {
1480                 if(self.classname == "nade")
1481                         return false; // no checks here
1482                 else if(self.classname == "grapplinghook")
1483                         RemoveGrapplingHook(self.realowner);
1484                 else if(self.classname == "spike")
1485                 {
1486                         W_Crylink_Dequeue(self);
1487                         remove(self);
1488                 }
1489                 else
1490                         remove(self);
1491                 return true;
1492         }
1493         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1494                 UpdateCSQCProjectile(self);
1495         return false;
1496 }
1497
1498
1499 void URI_Get_Callback(float id, float status, string data)
1500 {
1501         if(url_URI_Get_Callback(id, status, data))
1502         {
1503                 // handled
1504         }
1505         else if (id == URI_GET_DISCARD)
1506         {
1507                 // discard
1508         }
1509         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1510         {
1511                 // sv_cmd curl
1512                 Curl_URI_Get_Callback(id, status, data);
1513         }
1514         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1515         {
1516                 // online ban list
1517                 OnlineBanList_URI_Get_Callback(id, status, data);
1518         }
1519         else
1520         {
1521                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1522         }
1523 }
1524
1525 string uid2name(string myuid) {
1526         string s;
1527         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1528
1529         // FIXME remove this later after 0.6 release
1530         // convert old style broken records to correct style
1531         if(s == "")
1532         {
1533                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1534                 if(s != "")
1535                 {
1536                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1537                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1538                 }
1539         }
1540
1541         if(s == "")
1542                 s = "^1Unregistered Player";
1543         return s;
1544 }
1545
1546 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1547 {
1548     float m, i;
1549     vector start, org, delta, end, enddown, mstart;
1550     entity sp;
1551
1552     m = e.dphitcontentsmask;
1553     e.dphitcontentsmask = goodcontents | badcontents;
1554
1555     org = world.mins;
1556     delta = world.maxs - world.mins;
1557
1558     start = end = org;
1559
1560     for (i = 0; i < attempts; ++i)
1561     {
1562         start.x = org.x + random() * delta.x;
1563         start.y = org.y + random() * delta.y;
1564         start.z = org.z + random() * delta.z;
1565
1566         // rule 1: start inside world bounds, and outside
1567         // solid, and don't start from somewhere where you can
1568         // fall down to evil
1569         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1570         if (trace_fraction >= 1)
1571             continue;
1572         if (trace_startsolid)
1573             continue;
1574         if (trace_dphitcontents & badcontents)
1575             continue;
1576         if (trace_dphitq3surfaceflags & badsurfaceflags)
1577             continue;
1578
1579         // rule 2: if we are too high, lower the point
1580         if (trace_fraction * delta.z > maxaboveground)
1581             start = trace_endpos + '0 0 1' * maxaboveground;
1582         enddown = trace_endpos;
1583
1584         // rule 3: make sure we aren't outside the map. This only works
1585         // for somewhat well formed maps. A good rule of thumb is that
1586         // the map should have a convex outside hull.
1587         // these can be traceLINES as we already verified the starting box
1588         mstart = start + 0.5 * (e.mins + e.maxs);
1589         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1590         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1591             continue;
1592         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1593         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1594             continue;
1595         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1596         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1597             continue;
1598         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1599         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1600             continue;
1601         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1602         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1603             continue;
1604
1605         // rule 4: we must "see" some spawnpoint or item
1606         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
1607                 if(checkpvs(mstart, sp))
1608                         if((traceline(mstart, sp.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1609                                 break;
1610         if(!sp)
1611         {
1612                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
1613                         if(checkpvs(mstart, sp))
1614                                 if((traceline(mstart, sp.origin + (sp.mins + sp.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1615                                         break;
1616                 if(!sp)
1617                         continue;
1618         }
1619
1620         // find a random vector to "look at"
1621         end.x = org.x + random() * delta.x;
1622         end.y = org.y + random() * delta.y;
1623         end.z = org.z + random() * delta.z;
1624         end = start + normalize(end - start) * vlen(delta);
1625
1626         // rule 4: start TO end must not be too short
1627         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1628         if (trace_startsolid)
1629             continue;
1630         if (trace_fraction < minviewdistance / vlen(delta))
1631             continue;
1632
1633         // rule 5: don't want to look at sky
1634         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1635             continue;
1636
1637         // rule 6: we must not end up in trigger_hurt
1638         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1639             continue;
1640
1641         break;
1642     }
1643
1644     e.dphitcontentsmask = m;
1645
1646     if (i < attempts)
1647     {
1648         setorigin(e, start);
1649         e.angles = vectoangles(end - start);
1650         dprint("Needed ", ftos(i + 1), " attempts\n");
1651         return true;
1652     }
1653     else
1654         return false;
1655 }
1656
1657 void write_recordmarker(entity pl, float tstart, float dt)
1658 {
1659     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1660
1661     // also write a marker into demo files for demotc-race-record-extractor to find
1662     stuffcmd(pl,
1663              strcat(
1664                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1665                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1666 }
1667
1668 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
1669 {
1670         switch(algn)
1671         {
1672                 default:
1673                 case 3: // right
1674                         break;
1675
1676                 case 4: // left
1677                         vecs.y = -vecs.y;
1678                         break;
1679
1680                 case 1:
1681                         if(allowcenter) // 2: allow center handedness
1682                         {
1683                                 // center
1684                                 vecs.y = 0;
1685                                 vecs.z -= 2;
1686                         }
1687                         else
1688                         {
1689                                 // right
1690                         }
1691                         break;
1692
1693                 case 2:
1694                         if(allowcenter) // 2: allow center handedness
1695                         {
1696                                 // center
1697                                 vecs.y = 0;
1698                                 vecs.z -= 2;
1699                         }
1700                         else
1701                         {
1702                                 // left
1703                                 vecs.y = -vecs.y;
1704                         }
1705                         break;
1706         }
1707         return vecs;
1708 }
1709
1710 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
1711 {
1712         string s;
1713         vector v;
1714
1715         if (autocvar_g_shootfromeye)
1716         {
1717                 if (visual)
1718                 {
1719                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
1720                         else { vecs.y = 0; vecs.z -= 2; }
1721                 }
1722                 else
1723                 {
1724                         vecs.y = 0;
1725                         vecs.z = 0;
1726                 }
1727         }
1728         else if (autocvar_g_shootfromcenter)
1729         {
1730                 vecs.y = 0;
1731                 vecs.z -= 2;
1732         }
1733         else if ((s = autocvar_g_shootfromfixedorigin) != "")
1734         {
1735                 v = stov(s);
1736                 if (y_is_right)
1737                         v.y = -v.y;
1738                 if (v.x != 0)
1739                         vecs.x = v.x;
1740                 vecs.y = v.y;
1741                 vecs.z = v.z;
1742         }
1743         else if (autocvar_g_shootfromclient)
1744         {
1745                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
1746         }
1747         return vecs;
1748 }
1749
1750 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
1751 {
1752         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
1753 }
1754
1755
1756 void attach_sameorigin(entity e, entity to, string tag)
1757 {
1758     vector org, t_forward, t_left, t_up, e_forward, e_up;
1759     float tagscale;
1760
1761     org = e.origin - gettaginfo(to, gettagindex(to, tag));
1762     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
1763     t_forward = v_forward * tagscale;
1764     t_left = v_right * -tagscale;
1765     t_up = v_up * tagscale;
1766
1767     e.origin_x = org * t_forward;
1768     e.origin_y = org * t_left;
1769     e.origin_z = org * t_up;
1770
1771     // current forward and up directions
1772     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1773                 e.angles = AnglesTransform_FromVAngles(e.angles);
1774         else
1775                 e.angles = AnglesTransform_FromAngles(e.angles);
1776     fixedmakevectors(e.angles);
1777
1778     // untransform forward, up!
1779     e_forward.x = v_forward * t_forward;
1780     e_forward.y = v_forward * t_left;
1781     e_forward.z = v_forward * t_up;
1782     e_up.x = v_up * t_forward;
1783     e_up.y = v_up * t_left;
1784     e_up.z = v_up * t_up;
1785
1786     e.angles = fixedvectoangles2(e_forward, e_up);
1787     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1788                 e.angles = AnglesTransform_ToVAngles(e.angles);
1789         else
1790                 e.angles = AnglesTransform_ToAngles(e.angles);
1791
1792     setattachment(e, to, tag);
1793     setorigin(e, e.origin);
1794 }
1795
1796 void detach_sameorigin(entity e)
1797 {
1798     vector org;
1799     org = gettaginfo(e, 0);
1800     e.angles = fixedvectoangles2(v_forward, v_up);
1801     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1802                 e.angles = AnglesTransform_ToVAngles(e.angles);
1803         else
1804                 e.angles = AnglesTransform_ToAngles(e.angles);
1805     setorigin(e, org);
1806     setattachment(e, world, "");
1807     setorigin(e, e.origin);
1808 }
1809
1810 void follow_sameorigin(entity e, entity to)
1811 {
1812     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
1813     e.aiment = to; // make the hole follow bmodel
1814     e.punchangle = to.angles; // the original angles of bmodel
1815     e.view_ofs = e.origin - to.origin; // relative origin
1816     e.v_angle = e.angles - to.angles; // relative angles
1817 }
1818
1819 void unfollow_sameorigin(entity e)
1820 {
1821     e.movetype = MOVETYPE_NONE;
1822 }
1823
1824 entity gettaginfo_relative_ent;
1825 vector gettaginfo_relative(entity e, float tag)
1826 {
1827     if (!gettaginfo_relative_ent)
1828     {
1829         gettaginfo_relative_ent = spawn();
1830         gettaginfo_relative_ent.effects = EF_NODRAW;
1831     }
1832     gettaginfo_relative_ent.model = e.model;
1833     gettaginfo_relative_ent.modelindex = e.modelindex;
1834     gettaginfo_relative_ent.frame = e.frame;
1835     return gettaginfo(gettaginfo_relative_ent, tag);
1836 }
1837
1838 .float scale2;
1839
1840 float modeleffect_SendEntity(entity to, float sf)
1841 {
1842         float f;
1843         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
1844
1845         f = 0;
1846         if(self.velocity != '0 0 0')
1847                 f |= 1;
1848         if(self.angles != '0 0 0')
1849                 f |= 2;
1850         if(self.avelocity != '0 0 0')
1851                 f |= 4;
1852
1853         WriteByte(MSG_ENTITY, f);
1854         WriteShort(MSG_ENTITY, self.modelindex);
1855         WriteByte(MSG_ENTITY, self.skin);
1856         WriteByte(MSG_ENTITY, self.frame);
1857         WriteCoord(MSG_ENTITY, self.origin.x);
1858         WriteCoord(MSG_ENTITY, self.origin.y);
1859         WriteCoord(MSG_ENTITY, self.origin.z);
1860         if(f & 1)
1861         {
1862                 WriteCoord(MSG_ENTITY, self.velocity.x);
1863                 WriteCoord(MSG_ENTITY, self.velocity.y);
1864                 WriteCoord(MSG_ENTITY, self.velocity.z);
1865         }
1866         if(f & 2)
1867         {
1868                 WriteCoord(MSG_ENTITY, self.angles.x);
1869                 WriteCoord(MSG_ENTITY, self.angles.y);
1870                 WriteCoord(MSG_ENTITY, self.angles.z);
1871         }
1872         if(f & 4)
1873         {
1874                 WriteCoord(MSG_ENTITY, self.avelocity.x);
1875                 WriteCoord(MSG_ENTITY, self.avelocity.y);
1876                 WriteCoord(MSG_ENTITY, self.avelocity.z);
1877         }
1878         WriteShort(MSG_ENTITY, self.scale * 256.0);
1879         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
1880         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
1881         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
1882         WriteByte(MSG_ENTITY, self.alpha * 255.0);
1883
1884         return true;
1885 }
1886
1887 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
1888 {
1889         entity e;
1890         float sz;
1891         e = spawn();
1892         e.classname = "modeleffect";
1893         setmodel(e, m);
1894         e.frame = f;
1895         setorigin(e, o);
1896         e.velocity = v;
1897         e.angles = ang;
1898         e.avelocity = angv;
1899         e.alpha = a;
1900         e.teleport_time = t1;
1901         e.fade_time = t2;
1902         e.skin = s;
1903         if(s0 >= 0)
1904                 e.scale = s0 / max6(-e.mins.x, -e.mins.y, -e.mins.z, e.maxs.x, e.maxs.y, e.maxs.z);
1905         else
1906                 e.scale = -s0;
1907         if(s2 >= 0)
1908                 e.scale2 = s2 / max6(-e.mins.x, -e.mins.y, -e.mins.z, e.maxs.x, e.maxs.y, e.maxs.z);
1909         else
1910                 e.scale2 = -s2;
1911         sz = max(e.scale, e.scale2);
1912         setsize(e, e.mins * sz, e.maxs * sz);
1913         Net_LinkEntity(e, false, 0.1, modeleffect_SendEntity);
1914 }
1915
1916 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
1917 {
1918         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
1919 }
1920
1921 float randombit(float bits)
1922 {
1923         if(!(bits & (bits-1))) // this ONLY holds for powers of two!
1924                 return bits;
1925
1926         float n, f, b, r;
1927
1928         r = random();
1929         b = 0;
1930         n = 0;
1931
1932         for(f = 1; f <= bits; f *= 2)
1933         {
1934                 if(bits & f)
1935                 {
1936                         ++n;
1937                         r *= n;
1938                         if(r <= 1)
1939                                 b = f;
1940                         else
1941                                 r = (r - 1) / (n - 1);
1942                 }
1943         }
1944
1945         return b;
1946 }
1947
1948 float randombits(float bits, float k, float error_return)
1949 {
1950         float r;
1951         r = 0;
1952         while(k > 0 && bits != r)
1953         {
1954                 r += randombit(bits - r);
1955                 --k;
1956         }
1957         if(error_return)
1958                 if(k > 0)
1959                         return -1; // all
1960         return r;
1961 }
1962
1963 void randombit_test(float bits, float iter)
1964 {
1965         while(iter > 0)
1966         {
1967                 print(ftos(randombit(bits)), "\n");
1968                 --iter;
1969         }
1970 }
1971
1972 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
1973 {
1974         if(halflifedist > 0)
1975                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
1976         else if(halflifedist < 0)
1977                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
1978         else
1979                 return 1;
1980 }
1981
1982
1983 void defer_think()
1984 {
1985     entity oself;
1986
1987     oself           = self;
1988     self            = self.owner;
1989     oself.think     = SUB_Remove;
1990     oself.nextthink = time;
1991
1992     oself.use();
1993 }
1994
1995 /*
1996     Execute func() after time + fdelay.
1997     self when func is executed = self when defer is called
1998 */
1999 void defer(float fdelay, void() func)
2000 {
2001     entity e;
2002
2003     e           = spawn();
2004     e.owner     = self;
2005     e.use       = func;
2006     e.think     = defer_think;
2007     e.nextthink = time + fdelay;
2008 }
2009
2010 .string aiment_classname;
2011 .float aiment_deadflag;
2012 void SetMovetypeFollow(entity ent, entity e)
2013 {
2014         // FIXME this may not be warpzone aware
2015         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2016         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2017         ent.aiment = e; // make the hole follow bmodel
2018         ent.punchangle = e.angles; // the original angles of bmodel
2019         ent.view_ofs = ent.origin - e.origin; // relative origin
2020         ent.v_angle = ent.angles - e.angles; // relative angles
2021         ent.aiment_classname = strzone(e.classname);
2022         ent.aiment_deadflag = e.deadflag;
2023 }
2024 void UnsetMovetypeFollow(entity ent)
2025 {
2026         ent.movetype = MOVETYPE_FLY;
2027         PROJECTILE_MAKETRIGGER(ent);
2028         ent.aiment = world;
2029 }
2030 float LostMovetypeFollow(entity ent)
2031 {
2032 /*
2033         if(ent.movetype != MOVETYPE_FOLLOW)
2034                 if(ent.aiment)
2035                         error("???");
2036 */
2037         if(ent.aiment)
2038         {
2039                 if(ent.aiment.classname != ent.aiment_classname)
2040                         return 1;
2041                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2042                         return 1;
2043         }
2044         return 0;
2045 }
2046
2047 float isPushable(entity e)
2048 {
2049         if(e.iscreature)
2050                 return true;
2051         if(e.pushable)
2052                 return true;
2053         switch(e.classname)
2054         {
2055                 case "body":
2056                 case "droppedweapon":
2057                 case "keepawayball":
2058                 case "nexball_basketball":
2059                 case "nexball_football":
2060                         return true;
2061                 case "bullet": // antilagged bullets can't hit this either
2062                         return false;
2063         }
2064         if (e.projectiledeathtype)
2065                 return true;
2066         return false;
2067 }