qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  12 void WarpZone_crosshair_trace(entity pl)
  13 {
  14         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  15 }
  16
  17 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  18 void() spawnpoint_use;
  19 string GetMapname();
  20 string ColoredTeamName(float t);
  21
  22 string admin_name(void)
  23 {
  24         if(autocvar_sv_adminnick != "")
  25                 return autocvar_sv_adminnick;
  26         else
  27                 return "SERVER ADMIN";
  28 }
  29
  30 float DistributeEvenly_amount;
  31 float DistributeEvenly_totalweight;
  32 void DistributeEvenly_Init(float amount, float totalweight)
  33 {
  34     if (DistributeEvenly_amount)
  35     {
  36         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  37         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  38     }
  39     if (totalweight == 0)
  40         DistributeEvenly_amount = 0;
  41     else
  42         DistributeEvenly_amount = amount;
  43     DistributeEvenly_totalweight = totalweight;
  44 }
  45 float DistributeEvenly_Get(float weight)
  46 {
  47     float f;
  48     if (weight <= 0)
  49         return 0;
  50     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  51     DistributeEvenly_totalweight -= weight;
  52     DistributeEvenly_amount -= f;
  53     return f;
  54 }
  55
  56 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  57
  58
  59 string STR_PLAYER = "player";
  60 string STR_SPECTATOR = "spectator";
  61 string STR_OBSERVER = "observer";
  62
  63 #if 0
  64 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  65 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  66 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  67 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  68 #else
  69 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  70 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
  71 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  72 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
  73 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
  74 #endif
  75
  76 // copies a string to a tempstring (so one can strunzone it)
  77 string strcat1(string s) = #115; // FRIK_FILE
  78
  79 float logfile_open;
  80 float logfile;
  81
  82 string GetAdvancedDeathReports(entity enPlayer) // Extra fragmessage information
  83 {
  84         float nPlayerHealth = rint(enPlayer.health);
  85         float nPlayerArmor = rint(enPlayer.armorvalue);
  86         float nPlayerHandicap = enPlayer.cvar_cl_handicap;
  87         float nPlayerPing = rint(enPlayer.ping);
  88         string strPlayerPingColor;
  89         string strMessage;
  90
  91         if(nPlayerPing >= 150)
  92                 strPlayerPingColor = "^1";
  93         else
  94                 strPlayerPingColor = "^2";
  95
  96         if((autocvar_sv_fragmessage_information_stats) && (enPlayer.health >= 1))
  97                 strMessage = strcat(strMessage, "^7(Health ^1", ftos(nPlayerHealth), "^7 / Armor ^2", ftos(nPlayerArmor), "^7)");
  98
  99         if(autocvar_sv_fragmessage_information_ping) {
 100                 if(clienttype(enPlayer) == CLIENTTYPE_BOT) // Bots have no ping
 101                         strMessage = strcat(strMessage, " ^7(^2Bot");
 102                 else
 103                         strMessage = strcat(strMessage, " ^7(Ping ", strPlayerPingColor, ftos(nPlayerPing), "ms");
 104                 if(autocvar_sv_fragmessage_information_handicap)
 105                         if(autocvar_sv_fragmessage_information_handicap == 2)
 106                                 if(nPlayerHandicap <= 1)
 107                                         strMessage = strcat(strMessage, "^7 / Handicap ^2Off^7)");
 108                                 else
 109                                         strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 110                         else if not(nPlayerHandicap <= 1)
 111                                 strMessage = strcat(strMessage, "^7 / Handicap ^2", ftos(nPlayerHandicap), "^7)");
 112                 else
 113                         strMessage = strcat(strMessage, "^7)");
 114         } else if(autocvar_sv_fragmessage_information_handicap) {
 115                 if(autocvar_sv_fragmessage_information_handicap == 2)
 116                         if(nPlayerHandicap <= 1)
 117                                 strMessage = strcat(strMessage, "^7(Handicap ^2Off^7)");
 118                         else
 119                                 strMessage = strcat(strMessage, "^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 120                 else if(nPlayerHandicap > 1)
 121                         strMessage = strcat(strMessage, "^7(Handicap ^2", ftos(nPlayerHandicap), "^7)");
 122         }
 123
 124         if(strMessage) // add new line to the beginning if there is a message
 125                 strMessage = strcat("\n", strMessage);
 126
 127         return strMessage;
 128 }
 129 void bcenterprint(string s)
 130 {
 131     // TODO replace by MSG_ALL (would show it to spectators too, though)?
 132     entity head;
 133     FOR_EACH_PLAYER(head)
 134     if (clienttype(head) == CLIENTTYPE_REAL)
 135         centerprint(head, s);
 136 }
 137
 138 void GameLogEcho(string s)
 139 {
 140     string fn;
 141     float matches;
 142
 143     if (autocvar_sv_eventlog_files)
 144     {
 145         if (!logfile_open)
 146         {
 147             logfile_open = TRUE;
 148             matches = autocvar_sv_eventlog_files_counter + 1;
 149             cvar_set("sv_eventlog_files_counter", ftos(matches));
 150             fn = ftos(matches);
 151             if (strlen(fn) < 8)
 152                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 153             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 154             logfile = fopen(fn, FILE_APPEND);
 155             fputs(logfile, ":logversion:3\n");
 156         }
 157         if (logfile >= 0)
 158         {
 159             if (autocvar_sv_eventlog_files_timestamps)
 160                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 161             else
 162                 fputs(logfile, strcat(s, "\n"));
 163         }
 164     }
 165     if (autocvar_sv_eventlog_console)
 166     {
 167         print(s, "\n");
 168     }
 169 }
 170
 171 void GameLogInit()
 172 {
 173     logfile_open = 0;
 174     // will be opened later
 175 }
 176
 177 void GameLogClose()
 178 {
 179     if (logfile_open && logfile >= 0)
 180     {
 181         fclose(logfile);
 182         logfile = -1;
 183     }
 184 }
 185
 186 vector PL_VIEW_OFS;
 187 vector PL_MIN;
 188 vector PL_MAX;
 189 vector PL_HEAD;
 190 vector PL_CROUCH_VIEW_OFS;
 191 vector PL_CROUCH_MIN;
 192 vector PL_CROUCH_MAX;
 193
 194 float spawnpoint_nag;
 195 void relocate_spawnpoint()
 196 {
 197     PL_VIEW_OFS                             = stov(autocvar_sv_player_viewoffset);
 198     PL_MIN                                  = stov(autocvar_sv_player_mins);
 199     PL_MAX                                  = stov(autocvar_sv_player_maxs);
 200     PL_HEAD                                 = stov(autocvar_sv_player_headsize);
 201     PL_CROUCH_VIEW_OFS                      = stov(autocvar_sv_player_crouch_viewoffset);
 202     PL_CROUCH_MIN                           = stov(autocvar_sv_player_crouch_mins);
 203     PL_CROUCH_MAX                           = stov(autocvar_sv_player_crouch_maxs);
 204
 205     // nudge off the floor
 206     setorigin(self, self.origin + '0 0 1');
 207
 208     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 209     if (trace_startsolid)
 210     {
 211         vector o;
 212         o = self.origin;
 213         self.mins = PL_MIN;
 214         self.maxs = PL_MAX;
 215         if (!move_out_of_solid(self))
 216             objerror("could not get out of solid at all!");
 217         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 218         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 219         print(" ", ftos(self.origin_y - o_y));
 220         print(" ", ftos(self.origin_z - o_z), "'\n");
 221         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
 222         {
 223             if (!spawnpoint_nag)
 224                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 225             spawnpoint_nag = 1;
 226         }
 227         else
 228         {
 229             setorigin(self, o);
 230             self.mins = self.maxs = '0 0 0';
 231             objerror("player spawn point in solid, mapper sucks!\n");
 232             return;
 233         }
 234     }
 235
 236     self.use = spawnpoint_use;
 237     self.team_saved = self.team;
 238     if (!self.cnt)
 239         self.cnt = 1;
 240
 241     if (have_team_spawns != 0)
 242         if (self.team)
 243             have_team_spawns = 1;
 244     have_team_spawns_forteam[self.team] = 1;
 245
 246     if (autocvar_r_showbboxes)
 247     {
 248         // show where spawnpoints point at too
 249         makevectors(self.angles);
 250         entity e;
 251         e = spawn();
 252         e.classname = "info_player_foo";
 253         setorigin(e, self.origin + v_forward * 24);
 254         setsize(e, '-8 -8 -8', '8 8 8');
 255         e.solid = SOLID_TRIGGER;
 256     }
 257 }
 258
 259 #define strstr strstrofs
 260 /*
 261 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 262 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 263 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 264 // BE CONSTANT OR strzoneD!
 265 float strstr(string haystack, string needle, float offset)
 266 {
 267         float len, endpos;
 268         string found;
 269         len = strlen(needle);
 270         endpos = strlen(haystack) - len;
 271         while(offset <= endpos)
 272         {
 273                 found = substring(haystack, offset, len);
 274                 if(found == needle)
 275                         return offset;
 276                 offset = offset + 1;
 277         }
 278         return -1;
 279 }
 280 */
 281
 282 float NUM_NEAREST_ENTITIES = 4;
 283 entity nearest_entity[NUM_NEAREST_ENTITIES];
 284 float nearest_length[NUM_NEAREST_ENTITIES];
 285 entity findnearest(vector point, .string field, string value, vector axismod)
 286 {
 287     entity localhead;
 288     float i;
 289     float j;
 290     float len;
 291     vector dist;
 292
 293     float num_nearest;
 294     num_nearest = 0;
 295
 296     localhead = find(world, field, value);
 297     while (localhead)
 298     {
 299         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 300             dist = localhead.oldorigin;
 301         else
 302             dist = localhead.origin;
 303         dist = dist - point;
 304         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 305         len = vlen(dist);
 306
 307         for (i = 0; i < num_nearest; ++i)
 308         {
 309             if (len < nearest_length[i])
 310                 break;
 311         }
 312
 313         // now i tells us where to insert at
 314         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 315         if (i < NUM_NEAREST_ENTITIES)
 316         {
 317             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 318             {
 319                 nearest_length[j + 1] = nearest_length[j];
 320                 nearest_entity[j + 1] = nearest_entity[j];
 321             }
 322             nearest_length[i] = len;
 323             nearest_entity[i] = localhead;
 324             if (num_nearest < NUM_NEAREST_ENTITIES)
 325                 num_nearest = num_nearest + 1;
 326         }
 327
 328         localhead = find(localhead, field, value);
 329     }
 330
 331     // now use the first one from our list that we can see
 332     for (i = 0; i < num_nearest; ++i)
 333     {
 334         traceline(point, nearest_entity[i].origin, TRUE, world);
 335         if (trace_fraction == 1)
 336         {
 337             if (i != 0)
 338             {
 339                 dprint("Nearest point (");
 340                 dprint(nearest_entity[0].netname);
 341                 dprint(") is not visible, using a visible one.\n");
 342             }
 343             return nearest_entity[i];
 344         }
 345     }
 346
 347     if (num_nearest == 0)
 348         return world;
 349
 350     dprint("Not seeing any location point, using nearest as fallback.\n");
 351     /* DEBUGGING CODE:
 352     dprint("Candidates were: ");
 353     for(j = 0; j < num_nearest; ++j)
 354     {
 355         if(j != 0)
 356                 dprint(", ");
 357         dprint(nearest_entity[j].netname);
 358     }
 359     dprint("\n");
 360     */
 361
 362     return nearest_entity[0];
 363 }
 364
 365 void spawnfunc_target_location()
 366 {
 367     self.classname = "target_location";
 368     // location name in netname
 369     // eventually support: count, teamgame selectors, line of sight?
 370 };
 371
 372 void spawnfunc_info_location()
 373 {
 374     self.classname = "target_location";
 375     self.message = self.netname;
 376 };
 377
 378 string NearestLocation(vector p)
 379 {
 380     entity loc;
 381     string ret;
 382     ret = "somewhere";
 383     loc = findnearest(p, classname, "target_location", '1 1 1');
 384     if (loc)
 385     {
 386         ret = loc.message;
 387     }
 388     else
 389     {
 390         loc = findnearest(p, target, "###item###", '1 1 4');
 391         if (loc)
 392             ret = loc.netname;
 393     }
 394     return ret;
 395 }
 396
 397 string formatmessage(string msg)
 398 {
 399         float p, p1, p2;
 400         float n;
 401         vector cursor;
 402         entity cursor_ent;
 403         string escape;
 404         string replacement;
 405         p = 0;
 406         n = 7;
 407
 408         WarpZone_crosshair_trace(self);
 409         cursor = trace_endpos;
 410         cursor_ent = trace_ent;
 411
 412         while (1) {
 413                 if (n < 1)
 414                         break; // too many replacements
 415
 416                 n = n - 1;
 417                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 418                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 419
 420                 if (p1 < 0)
 421                         p1 = p2;
 422
 423                 if (p2 < 0)
 424                         p2 = p1;
 425
 426                 p = min(p1, p2);
 427
 428                 if (p < 0)
 429                         break;
 430
 431                 replacement = substring(msg, p, 2);
 432                 escape = substring(msg, p + 1, 1);
 433
 434                 if (escape == "%")
 435                         replacement = "%";
 436                 else if (escape == "\\")
 437                         replacement = "\\";
 438                 else if (escape == "n")
 439                         replacement = "\n";
 440                 else if (escape == "a")
 441                         replacement = ftos(floor(self.armorvalue));
 442                 else if (escape == "h")
 443                         replacement = ftos(floor(self.health));
 444                 else if (escape == "l")
 445                         replacement = NearestLocation(self.origin);
 446                 else if (escape == "y")
 447                         replacement = NearestLocation(cursor);
 448                 else if (escape == "d")
 449                         replacement = NearestLocation(self.death_origin);
 450                 else if (escape == "w") {
 451                         float wep;
 452                         wep = self.weapon;
 453                         if (!wep)
 454                                 wep = self.switchweapon;
 455                         if (!wep)
 456                                 wep = self.cnt;
 457                         replacement = W_Name(wep);
 458                 } else if (escape == "W") {
 459                         if (self.items & IT_SHELLS) replacement = "shells";
 460                         else if (self.items & IT_NAILS) replacement = "bullets";
 461                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 462                         else if (self.items & IT_CELLS) replacement = "cells";
 463                         else replacement = "batteries"; // ;)
 464                 } else if (escape == "x") {
 465                         replacement = cursor_ent.netname;
 466                         if (!replacement || !cursor_ent)
 467                                 replacement = "nothing";
 468                 } else if (escape == "s")
 469                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 470                 else if (escape == "S")
 471                         replacement = ftos(vlen(self.velocity));
 472
 473                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 474                 p = p + strlen(replacement);
 475         }
 476         return msg;
 477 }
 478
 479 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 480         return (value == 0) ? FALSE : TRUE;
 481 }
 482
 483 /*
 484 =============
 485 GetCvars
 486 =============
 487 Called with:
 488   0:  sends the request
 489   >0: receives a cvar from name=argv(f) value=argv(f+1)
 490 */
 491 void GetCvars_handleString(string thisname, float f, .string field, string name)
 492 {
 493         if (f < 0)
 494         {
 495                 if (self.field)
 496                         strunzone(self.field);
 497                 self.field = string_null;
 498         }
 499         else if (f > 0)
 500         {
 501                 if (thisname == name)
 502                 {
 503                         if (self.field)
 504                                 strunzone(self.field);
 505                         self.field = strzone(argv(f + 1));
 506                 }
 507         }
 508         else
 509                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 510 }
 511 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 512 {
 513         GetCvars_handleString(thisname, f, field, name);
 514         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 515                 if (thisname == name)
 516                 {
 517                         string s;
 518                         s = func(strcat1(self.field));
 519                         if (s != self.field)
 520                         {
 521                                 strunzone(self.field);
 522                                 self.field = strzone(s);
 523                         }
 524                 }
 525 }
 526 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 527 {
 528         if (f < 0)
 529         {
 530         }
 531         else if (f > 0)
 532         {
 533                 if (thisname == name)
 534                         self.field = stof(argv(f + 1));
 535         }
 536         else
 537                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 538 }
 539 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 540 {
 541         if (f < 0)
 542         {
 543         }
 544         else if (f > 0)
 545         {
 546                 if (thisname == name)
 547                 {
 548                         if(!self.field)
 549                         {
 550                                 self.field = stof(argv(f + 1));
 551                                 if(!self.field)
 552                                         self.field = -1;
 553                         }
 554                 }
 555         }
 556         else
 557         {
 558                 if(!self.field)
 559                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 560         }
 561 }
 562 float w_getbestweapon(entity e);
 563 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 564 {
 565         string o;
 566         o = W_FixWeaponOrder_ForceComplete(wo);
 567         if(self.weaponorder_byimpulse)
 568         {
 569                 strunzone(self.weaponorder_byimpulse);
 570                 self.weaponorder_byimpulse = string_null;
 571         }
 572         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 573         return o;
 574 }
 575 void GetCvars(float f)
 576 {
 577         string s;
 578
 579         if (f > 0)
 580                 s = strcat1(argv(f));
 581
 582         get_cvars_f = f;
 583         get_cvars_s = s;
 584         MUTATOR_CALLHOOK(GetCvars);
 585         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 586         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 587         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 588         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 589         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 590         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 591         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 592         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 593         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 594         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 595         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 596         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 597         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 598         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 599         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 600         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 601         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 602         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 603         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 604         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 605         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 606         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 607         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 608
 609         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 610         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 611
 612 #ifdef ALLOW_FORCEMODELS
 613         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
 614         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
 615 #endif
 616         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 617         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 618         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 619         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 620
 621         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 622         if (f > 0)
 623         {
 624                 if (s == "cl_weaponpriority")
 625                         self.switchweapon = w_getbestweapon(self);
 626                 if (s == "cl_allow_uidtracking")
 627                         PlayerStats_AddPlayer(self);
 628         }
 629 }
 630
 631 void backtrace(string msg)
 632 {
 633     float dev, war;
 634     dev = autocvar_developer;
 635     war = autocvar_prvm_backtraceforwarnings;
 636     cvar_set("developer", "1");
 637     cvar_set("prvm_backtraceforwarnings", "1");
 638     print("\n");
 639     print("--- CUT HERE ---\nWARNING: ");
 640     print(msg);
 641     print("\n");
 642     remove(world); // isn't there any better way to cause a backtrace?
 643     print("\n--- CUT UNTIL HERE ---\n");
 644     cvar_set("developer", ftos(dev));
 645     cvar_set("prvm_backtraceforwarnings", ftos(war));
 646 }
 647
 648 string Team_ColorCode(float teamid)
 649 {
 650     if (teamid == COLOR_TEAM1)
 651         return "^1";
 652     else if (teamid == COLOR_TEAM2)
 653         return "^4";
 654     else if (teamid == COLOR_TEAM3)
 655         return "^3";
 656     else if (teamid == COLOR_TEAM4)
 657         return "^6";
 658     else
 659         return "^7";
 660 }
 661
 662 string Team_ColorName(float t)
 663 {
 664     // fixme: Search for team entities and get their .netname's!
 665     if (t == COLOR_TEAM1)
 666         return "Red";
 667     if (t == COLOR_TEAM2)
 668         return "Blue";
 669     if (t == COLOR_TEAM3)
 670         return "Yellow";
 671     if (t == COLOR_TEAM4)
 672         return "Pink";
 673     return "Neutral";
 674 }
 675
 676 string Team_ColorNameLowerCase(float t)
 677 {
 678     // fixme: Search for team entities and get their .netname's!
 679     if (t == COLOR_TEAM1)
 680         return "red";
 681     if (t == COLOR_TEAM2)
 682         return "blue";
 683     if (t == COLOR_TEAM3)
 684         return "yellow";
 685     if (t == COLOR_TEAM4)
 686         return "pink";
 687     return "neutral";
 688 }
 689
 690 float ColourToNumber(string team_colour)
 691 {
 692         if (team_colour == "red")
 693                 return COLOR_TEAM1;
 694
 695         if (team_colour == "blue")
 696                 return COLOR_TEAM2;
 697
 698         if (team_colour == "yellow")
 699                 return COLOR_TEAM3;
 700
 701         if (team_colour == "pink")
 702                 return COLOR_TEAM4;
 703
 704         if (team_colour == "auto")
 705                 return 0;
 706
 707         return -1;
 708 }
 709
 710 float NumberToTeamNumber(float number)
 711 {
 712         if (number == 1)
 713                 return COLOR_TEAM1;
 714
 715         if (number == 2)
 716                 return COLOR_TEAM2;
 717
 718         if (number == 3)
 719                 return COLOR_TEAM3;
 720
 721         if (number == 4)
 722                 return COLOR_TEAM4;
 723
 724         return -1;
 725 }
 726
 727 // decolorizes and team colors the player name when needed
 728 string playername(entity p)
 729 {
 730     string t;
 731     if (teamplay && !intermission_running && p.classname == "player")
 732     {
 733         t = Team_ColorCode(p.team);
 734         return strcat(t, strdecolorize(p.netname));
 735     }
 736     else
 737         return p.netname;
 738 }
 739
 740 vector randompos(vector m1, vector m2)
 741 {
 742     local vector v;
 743     m2 = m2 - m1;
 744     v_x = m2_x * random() + m1_x;
 745     v_y = m2_y * random() + m1_y;
 746     v_z = m2_z * random() + m1_z;
 747     return  v;
 748 };
 749
 750 //#NO AUTOCVARS START
 751
 752 float g_pickup_shells;
 753 float g_pickup_shells_max;
 754 float g_pickup_nails;
 755 float g_pickup_nails_max;
 756 float g_pickup_rockets;
 757 float g_pickup_rockets_max;
 758 float g_pickup_cells;
 759 float g_pickup_cells_max;
 760 float g_pickup_fuel;
 761 float g_pickup_fuel_jetpack;
 762 float g_pickup_fuel_max;
 763 float g_pickup_armorsmall;
 764 float g_pickup_armorsmall_max;
 765 float g_pickup_armorsmall_anyway;
 766 float g_pickup_armormedium;
 767 float g_pickup_armormedium_max;
 768 float g_pickup_armormedium_anyway;
 769 float g_pickup_armorbig;
 770 float g_pickup_armorbig_max;
 771 float g_pickup_armorbig_anyway;
 772 float g_pickup_armorlarge;
 773 float g_pickup_armorlarge_max;
 774 float g_pickup_armorlarge_anyway;
 775 float g_pickup_healthsmall;
 776 float g_pickup_healthsmall_max;
 777 float g_pickup_healthsmall_anyway;
 778 float g_pickup_healthmedium;
 779 float g_pickup_healthmedium_max;
 780 float g_pickup_healthmedium_anyway;
 781 float g_pickup_healthlarge;
 782 float g_pickup_healthlarge_max;
 783 float g_pickup_healthlarge_anyway;
 784 float g_pickup_healthmega;
 785 float g_pickup_healthmega_max;
 786 float g_pickup_healthmega_anyway;
 787 float g_pickup_ammo_anyway;
 788 float g_pickup_weapons_anyway;
 789 float g_weaponarena;
 790 float g_weaponarena_random;
 791 float g_weaponarena_random_with_laser;
 792 string g_weaponarena_list;
 793 float g_weaponspeedfactor;
 794 float g_weaponratefactor;
 795 float g_weapondamagefactor;
 796 float g_weaponforcefactor;
 797 float g_weaponspreadfactor;
 798
 799 float start_weapons;
 800 float start_items;
 801 float start_ammo_shells;
 802 float start_ammo_nails;
 803 float start_ammo_rockets;
 804 float start_ammo_cells;
 805 float start_ammo_fuel;
 806 float start_health;
 807 float start_armorvalue;
 808 float warmup_start_weapons;
 809 float warmup_start_ammo_shells;
 810 float warmup_start_ammo_nails;
 811 float warmup_start_ammo_rockets;
 812 float warmup_start_ammo_cells;
 813 float warmup_start_ammo_fuel;
 814 float warmup_start_health;
 815 float warmup_start_armorvalue;
 816 float g_weapon_stay;
 817 float g_ghost_items;
 818
 819 entity get_weaponinfo(float w);
 820
 821 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 822 {
 823         var float i = weaponinfo.weapon;
 824
 825         if (!i)
 826                 return 0;
 827
 828         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 829
 830         if (t < 0) // "default" weapon selection
 831         {
 832                 if (g_lms || g_ca || allguns)
 833                         t = (weaponinfo.spawnflags & WEP_FLAG_NORMAL);
 834                 else if(t < -1)
 835                         t = 0;
 836                 else if (g_cts)
 837                         t = (i == WEP_SHOTGUN);
 838                 else if (g_nexball)
 839                         t = 0; // weapon is set a few lines later
 840                 else
 841                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 842                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 843                         t |= (i == WEP_HOOK);
 844         }
 845
 846         // we cannot disable porto in Nexball, we must force it
 847         if(g_nexball && i == WEP_PORTO)
 848                 t = 1;
 849
 850         return t;
 851 }
 852
 853 void readplayerstartcvars()
 854 {
 855         entity e;
 856         float i, j, t;
 857         string s;
 858
 859         // initialize starting values for players
 860         start_weapons = 0;
 861         start_items = 0;
 862         start_ammo_shells = 0;
 863         start_ammo_nails = 0;
 864         start_ammo_rockets = 0;
 865         start_ammo_cells = 0;
 866         start_health = cvar("g_balance_health_start");
 867         start_armorvalue = cvar("g_balance_armor_start");
 868
 869         g_weaponarena = 0;
 870         s = cvar_string("g_weaponarena");
 871         if (s == "0" || s == "")
 872         {
 873                 if(g_lms || g_ca)
 874                         s = "most";
 875         }
 876
 877         if (s == "0" || s == "")
 878         {
 879                 // no arena
 880         }
 881         else if (s == "off")
 882         {
 883                 // forcibly turn off weaponarena
 884         }
 885         else if (s == "all")
 886         {
 887                 g_weaponarena_list = "All Weapons";
 888                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 889                 {
 890                         e = get_weaponinfo(j);
 891                         g_weaponarena |= e.weapons;
 892                         weapon_action(e.weapon, WR_PRECACHE);
 893                 }
 894         }
 895         else if (s == "most")
 896         {
 897                 g_weaponarena_list = "Most Weapons";
 898                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 899                 {
 900                         e = get_weaponinfo(j);
 901                         if (e.spawnflags & WEP_FLAG_NORMAL)
 902                         {
 903                                 g_weaponarena |= e.weapons;
 904                                 weapon_action(e.weapon, WR_PRECACHE);
 905                         }
 906                 }
 907         }
 908         else if (s == "none")
 909         {
 910                 g_weaponarena_list = "No Weapons";
 911                 g_weaponarena = WEPBIT_ALL + 1; // this supports no single weapon bit!
 912         }
 913         else
 914         {
 915                 t = tokenize_console(s);
 916                 g_weaponarena_list = "";
 917                 for (i = 0; i < t; ++i)
 918                 {
 919                         s = argv(i);
 920                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 921                         {
 922                                 e = get_weaponinfo(j);
 923                                 if (e.netname == s)
 924                                 {
 925                                         g_weaponarena |= e.weapons;
 926                                         weapon_action(e.weapon, WR_PRECACHE);
 927                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 928                                         break;
 929                                 }
 930                         }
 931                         if (j > WEP_LAST)
 932                         {
 933                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 934                         }
 935                 }
 936                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 937         }
 938
 939         if(g_weaponarena)
 940                 g_weaponarena_random = cvar("g_weaponarena_random");
 941         else
 942                 g_weaponarena_random = 0;
 943         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 944
 945         if (g_weaponarena)
 946         {
 947                 start_weapons = g_weaponarena;
 948                 if(!(g_lms || g_ca))
 949                         start_items |= IT_UNLIMITED_AMMO;
 950         }
 951         else if (g_minstagib)
 952         {
 953                 start_health = 100;
 954                 start_armorvalue = 0;
 955                 start_weapons = WEPBIT_MINSTANEX;
 956                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
 957                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 958
 959                 if (g_minstagib_invis_alpha <= 0)
 960                         g_minstagib_invis_alpha = -1;
 961         }
 962         else
 963         {
 964                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 965                 {
 966                         e = get_weaponinfo(i);
 967                         if(want_weapon("g_start_weapon_", e, FALSE))
 968                                 start_weapons |= e.weapons;
 969                 }
 970         }
 971
 972         if(!cvar("g_use_ammunition"))
 973                 start_items |= IT_UNLIMITED_AMMO;
 974
 975         if(g_minstagib)
 976         {
 977                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 978                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 979         }
 980         else if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 981         {
 982                 start_ammo_rockets = 999;
 983                 start_ammo_shells = 999;
 984                 start_ammo_cells = 999;
 985                 start_ammo_nails = 999;
 986                 start_ammo_fuel = 999;
 987         }
 988         else
 989         {
 990                 if(g_lms || g_ca)
 991                 {
 992                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 993                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 994                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 995                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 996                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
 997                 }
 998                 else
 999                 {
1000                         start_ammo_shells = cvar("g_start_ammo_shells");
1001                         start_ammo_nails = cvar("g_start_ammo_nails");
1002                         start_ammo_rockets = cvar("g_start_ammo_rockets");
1003                         start_ammo_cells = cvar("g_start_ammo_cells");
1004                         start_ammo_fuel = cvar("g_start_ammo_fuel");
1005                 }
1006         }
1007
1008         if (g_lms || g_ca)
1009         {
1010                 start_health = cvar("g_lms_start_health");
1011                 start_armorvalue = cvar("g_lms_start_armor");
1012         }
1013
1014         if (inWarmupStage)
1015         {
1016                 warmup_start_ammo_shells = start_ammo_shells;
1017                 warmup_start_ammo_nails = start_ammo_nails;
1018                 warmup_start_ammo_rockets = start_ammo_rockets;
1019                 warmup_start_ammo_cells = start_ammo_cells;
1020                 warmup_start_ammo_fuel = start_ammo_fuel;
1021                 warmup_start_health = start_health;
1022                 warmup_start_armorvalue = start_armorvalue;
1023                 warmup_start_weapons = start_weapons;
1024
1025                 if (!g_weaponarena && !g_minstagib && !g_ca)
1026                 {
1027                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
1028                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
1029                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
1030                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
1031                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
1032                         warmup_start_health = cvar("g_warmup_start_health");
1033                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
1034                         warmup_start_weapons = 0;
1035                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1036                         {
1037                                 e = get_weaponinfo(i);
1038                                 if(want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns")))
1039                                         warmup_start_weapons |= e.weapons;
1040                         }
1041                 }
1042         }
1043
1044         if (g_jetpack || (g_grappling_hook && (start_weapons & WEPBIT_HOOK)))
1045         {
1046                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1047                 start_items |= IT_FUEL_REGEN;
1048                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1049                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1050         }
1051
1052         if (g_jetpack)
1053                 start_items |= IT_JETPACK;
1054
1055         if (g_weapon_stay == 2)
1056         {
1057                 if (!start_ammo_shells) start_ammo_shells = g_pickup_shells;
1058                 if (!start_ammo_nails) start_ammo_nails = g_pickup_nails;
1059                 if (!start_ammo_cells) start_ammo_cells = g_pickup_cells;
1060                 if (!start_ammo_rockets) start_ammo_rockets = g_pickup_rockets;
1061                 if (!start_ammo_fuel) start_ammo_fuel = g_pickup_fuel;
1062                 if (!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
1063                 if (!warmup_start_ammo_nails) warmup_start_ammo_nails = g_pickup_nails;
1064                 if (!warmup_start_ammo_cells) warmup_start_ammo_cells = g_pickup_cells;
1065                 if (!warmup_start_ammo_rockets) warmup_start_ammo_rockets = g_pickup_rockets;
1066                 if (!warmup_start_ammo_fuel) warmup_start_ammo_fuel = g_pickup_fuel;
1067         }
1068
1069         MUTATOR_CALLHOOK(SetStartItems);
1070
1071         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1072         {
1073                 e = get_weaponinfo(i);
1074                 if(e.weapons & (start_weapons | warmup_start_weapons))
1075                         weapon_action(e.weapon, WR_PRECACHE);
1076         }
1077
1078         start_ammo_shells = max(0, start_ammo_shells);
1079         start_ammo_nails = max(0, start_ammo_nails);
1080         start_ammo_cells = max(0, start_ammo_cells);
1081         start_ammo_rockets = max(0, start_ammo_rockets);
1082         start_ammo_fuel = max(0, start_ammo_fuel);
1083
1084         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1085         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1086         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1087         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1088         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1089 }
1090
1091 float g_bugrigs;
1092 float g_bugrigs_planar_movement;
1093 float g_bugrigs_planar_movement_car_jumping;
1094 float g_bugrigs_reverse_spinning;
1095 float g_bugrigs_reverse_speeding;
1096 float g_bugrigs_reverse_stopping;
1097 float g_bugrigs_air_steering;
1098 float g_bugrigs_angle_smoothing;
1099 float g_bugrigs_friction_floor;
1100 float g_bugrigs_friction_brake;
1101 float g_bugrigs_friction_air;
1102 float g_bugrigs_accel;
1103 float g_bugrigs_speed_ref;
1104 float g_bugrigs_speed_pow;
1105 float g_bugrigs_steer;
1106
1107 float g_touchexplode;
1108 float g_touchexplode_radius;
1109 float g_touchexplode_damage;
1110 float g_touchexplode_edgedamage;
1111 float g_touchexplode_force;
1112
1113 float sv_autotaunt;
1114 float sv_taunt;
1115
1116 float sv_pitch_min;
1117 float sv_pitch_max;
1118 float sv_pitch_fixyaw;
1119
1120 string GetGametype(); // g_world.qc
1121 void readlevelcvars(void)
1122 {
1123         // first load all the mutators
1124         if(cvar("g_invincible_projectiles"))
1125                 MUTATOR_ADD(mutator_invincibleprojectiles);
1126         if(cvar("g_nix"))
1127                 MUTATOR_ADD(mutator_nix);
1128         if(cvar("g_dodging"))
1129                 MUTATOR_ADD(mutator_dodging);
1130         if(cvar("g_rocket_flying"))
1131                 MUTATOR_ADD(mutator_rocketflying);
1132         if(cvar("g_vampire"))
1133                 MUTATOR_ADD(mutator_vampire);
1134
1135         if(cvar("sv_allow_fullbright"))
1136                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1137
1138     g_bugrigs = cvar("g_bugrigs");
1139     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1140     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1141     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1142     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1143     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1144     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1145     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1146     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1147     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1148     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1149     g_bugrigs_accel = cvar("g_bugrigs_accel");
1150     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1151     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1152     g_bugrigs_steer = cvar("g_bugrigs_steer");
1153
1154     g_touchexplode = cvar("g_touchexplode");
1155     g_touchexplode_radius = cvar("g_touchexplode_radius");
1156     g_touchexplode_damage = cvar("g_touchexplode_damage");
1157     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1158     g_touchexplode_force = cvar("g_touchexplode_force");
1159
1160 #ifdef ALLOW_FORCEMODELS
1161         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1162 #endif
1163         sv_loddistance1 = cvar("sv_loddistance1");
1164         sv_loddistance2 = cvar("sv_loddistance2");
1165
1166         if(sv_loddistance2 <= sv_loddistance1)
1167                 sv_loddistance2 = 1073741824; // enough to turn off LOD 2 reliably
1168
1169         sv_clones = cvar("sv_clones");
1170         sv_gentle = cvar("sv_gentle");
1171         sv_foginterval = cvar("sv_foginterval");
1172         g_cloaked = cvar("g_cloaked");
1173     if(g_cts)
1174         g_cloaked = 1; // always enable cloak in CTS
1175         g_jump_grunt = cvar("g_jump_grunt");
1176         g_footsteps = cvar("g_footsteps");
1177         g_grappling_hook = cvar("g_grappling_hook");
1178         g_jetpack = cvar("g_jetpack");
1179         g_midair = cvar("g_midair");
1180         g_minstagib = cvar("g_minstagib");
1181         g_norecoil = cvar("g_norecoil");
1182         g_bloodloss = cvar("g_bloodloss");
1183         sv_maxidle = cvar("sv_maxidle");
1184         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1185         g_ctf_reverse = cvar("g_ctf_reverse");
1186         sv_autotaunt = cvar("sv_autotaunt");
1187         sv_taunt = cvar("sv_taunt");
1188
1189         inWarmupStage = cvar("g_warmup");
1190         g_warmup_limit = cvar("g_warmup_limit");
1191         g_warmup_allguns = cvar("g_warmup_allguns");
1192         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1193
1194         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1195                 inWarmupStage = 0; // these modes cannot work together, sorry
1196
1197         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1198         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1199         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1200         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1201         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1202         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1203         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1204         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1205         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1206         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1207         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1208         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1209
1210         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1211         g_weaponratefactor = cvar("g_weaponratefactor");
1212         g_weapondamagefactor = cvar("g_weapondamagefactor");
1213         g_weaponforcefactor = cvar("g_weaponforcefactor");
1214         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1215
1216         g_pickup_shells = cvar("g_pickup_shells");
1217         g_pickup_shells_max = cvar("g_pickup_shells_max");
1218         g_pickup_nails = cvar("g_pickup_nails");
1219         g_pickup_nails_max = cvar("g_pickup_nails_max");
1220         g_pickup_rockets = cvar("g_pickup_rockets");
1221         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1222         g_pickup_cells = cvar("g_pickup_cells");
1223         g_pickup_cells_max = cvar("g_pickup_cells_max");
1224         g_pickup_fuel = cvar("g_pickup_fuel");
1225         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1226         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1227         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1228         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1229         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1230         g_pickup_armormedium = cvar("g_pickup_armormedium");
1231         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1232         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1233         g_pickup_armorbig = cvar("g_pickup_armorbig");
1234         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1235         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1236         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1237         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1238         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1239         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1240         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1241         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1242         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1243         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1244         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1245         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1246         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1247         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1248         g_pickup_healthmega = cvar("g_pickup_healthmega");
1249         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1250         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1251
1252         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1253         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1254
1255         g_pinata = cvar("g_pinata");
1256
1257     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1258     if(!g_weapon_stay)
1259         g_weapon_stay = cvar("g_weapon_stay");
1260
1261         g_ghost_items = cvar("g_ghost_items");
1262
1263         if(g_ghost_items >= 1)
1264                 g_ghost_items = 0.25; // default alpha value
1265
1266         if not(inWarmupStage && !g_ca)
1267                 game_starttime = cvar("g_start_delay");
1268
1269         sv_pitch_min = cvar("sv_pitch_min");
1270         sv_pitch_max = cvar("sv_pitch_max");
1271         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1272
1273         readplayerstartcvars();
1274 }
1275
1276 //#NO AUTOCVARS END
1277
1278 // Sound functions
1279 string precache_sound (string s) = #19;
1280 float precache_sound_index (string s) = #19;
1281
1282 #define SND_VOLUME      1
1283 #define SND_ATTENUATION 2
1284 #define SND_LARGEENTITY 8
1285 #define SND_LARGESOUND  16
1286
1287 float sound_allowed(float dest, entity e)
1288 {
1289     // sounds from world may always pass
1290     for (;;)
1291     {
1292         if (e.classname == "body")
1293             e = e.enemy;
1294         if (e.owner && e.owner != e)
1295             e = e.owner;
1296         else
1297             break;
1298     }
1299     // sounds to self may always pass
1300     if (dest == MSG_ONE)
1301         if (e == msg_entity)
1302             return TRUE;
1303     // sounds by players can be removed
1304     if (autocvar_bot_sound_monopoly)
1305         if (clienttype(e) == CLIENTTYPE_REAL)
1306             return FALSE;
1307     // anything else may pass
1308     return TRUE;
1309 }
1310
1311 #ifdef COMPAT_XON010_CHANNELS
1312 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1313 void sound(entity e, float chan, string samp, float vol, float atten)
1314 {
1315     if (!sound_allowed(MSG_BROADCAST, e))
1316         return;
1317     sound_builtin(e, chan, samp, vol, atten);
1318 }
1319 #else
1320 #undef sound
1321 void sound(entity e, float chan, string samp, float vol, float atten)
1322 {
1323     if (!sound_allowed(MSG_BROADCAST, e))
1324         return;
1325     sound7(e, chan, samp, vol, atten, 0, 0);
1326 }
1327 #endif
1328
1329 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1330 {
1331     float entno, idx;
1332
1333     if (!sound_allowed(dest, e))
1334         return;
1335
1336     entno = num_for_edict(e);
1337     idx = precache_sound_index(samp);
1338
1339     float sflags;
1340     sflags = 0;
1341
1342     atten = floor(atten * 64);
1343     vol = floor(vol * 255);
1344
1345     if (vol != 255)
1346         sflags |= SND_VOLUME;
1347     if (atten != 64)
1348         sflags |= SND_ATTENUATION;
1349     if (entno >= 8192 || chan < 0 || chan > 7)
1350         sflags |= SND_LARGEENTITY;
1351     if (idx >= 256)
1352         sflags |= SND_LARGESOUND;
1353
1354     WriteByte(dest, SVC_SOUND);
1355     WriteByte(dest, sflags);
1356     if (sflags & SND_VOLUME)
1357         WriteByte(dest, vol);
1358     if (sflags & SND_ATTENUATION)
1359         WriteByte(dest, atten);
1360     if (sflags & SND_LARGEENTITY)
1361     {
1362         WriteShort(dest, entno);
1363         WriteByte(dest, chan);
1364     }
1365     else
1366     {
1367         WriteShort(dest, entno * 8 + chan);
1368     }
1369     if (sflags & SND_LARGESOUND)
1370         WriteShort(dest, idx);
1371     else
1372         WriteByte(dest, idx);
1373
1374     WriteCoord(dest, o_x);
1375     WriteCoord(dest, o_y);
1376     WriteCoord(dest, o_z);
1377 }
1378 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1379 {
1380     vector o;
1381
1382     if (!sound_allowed(dest, e))
1383         return;
1384
1385     o = e.origin + 0.5 * (e.mins + e.maxs);
1386     soundtoat(dest, e, o, chan, samp, vol, atten);
1387 }
1388 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1389 {
1390     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1391 }
1392 void stopsoundto(float dest, entity e, float chan)
1393 {
1394     float entno;
1395
1396     if (!sound_allowed(dest, e))
1397         return;
1398
1399     entno = num_for_edict(e);
1400
1401     if (entno >= 8192 || chan < 0 || chan > 7)
1402     {
1403         float idx, sflags;
1404         idx = precache_sound_index("misc/null.wav");
1405         sflags = SND_LARGEENTITY;
1406         if (idx >= 256)
1407             sflags |= SND_LARGESOUND;
1408         WriteByte(dest, SVC_SOUND);
1409         WriteByte(dest, sflags);
1410         WriteShort(dest, entno);
1411         WriteByte(dest, chan);
1412         if (sflags & SND_LARGESOUND)
1413             WriteShort(dest, idx);
1414         else
1415             WriteByte(dest, idx);
1416         WriteCoord(dest, e.origin_x);
1417         WriteCoord(dest, e.origin_y);
1418         WriteCoord(dest, e.origin_z);
1419     }
1420     else
1421     {
1422         WriteByte(dest, SVC_STOPSOUND);
1423         WriteShort(dest, entno * 8 + chan);
1424     }
1425 }
1426 void stopsound(entity e, float chan)
1427 {
1428     if (!sound_allowed(MSG_BROADCAST, e))
1429         return;
1430
1431     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1432     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1433 }
1434
1435 void play2(entity e, string filename)
1436 {
1437     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1438     msg_entity = e;
1439     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1440 }
1441
1442 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1443 .float spamtime;
1444 float spamsound(entity e, float chan, string samp, float vol, float atten)
1445 {
1446     if (!sound_allowed(MSG_BROADCAST, e))
1447         return FALSE;
1448
1449     if (time > e.spamtime)
1450     {
1451         e.spamtime = time;
1452         sound(e, chan, samp, vol, atten);
1453         return TRUE;
1454     }
1455     return FALSE;
1456 }
1457
1458 void play2team(float t, string filename)
1459 {
1460     local entity head;
1461
1462     if (autocvar_bot_sound_monopoly)
1463         return;
1464
1465     FOR_EACH_REALPLAYER(head)
1466     {
1467         if (head.team == t)
1468             play2(head, filename);
1469     }
1470 }
1471
1472 void play2all(string samp)
1473 {
1474     if (autocvar_bot_sound_monopoly)
1475         return;
1476
1477     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1478 }
1479
1480 void PrecachePlayerSounds(string f);
1481 void precache_playermodel(string m)
1482 {
1483         float globhandle, i, n;
1484         string f;
1485
1486         if(substring(m, -9,5) == "_lod1")
1487                 return;
1488         if(substring(m, -9,5) == "_lod2")
1489                 return;
1490         precache_model(m);
1491         if(sv_loddistance1)
1492         {
1493                 f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1494                 if(fexists(f))
1495                         precache_model(f);
1496                 f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1497                 if(fexists(f))
1498                         precache_model(f);
1499         }
1500
1501         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1502         if (globhandle < 0)
1503                 return;
1504         n = search_getsize(globhandle);
1505         for (i = 0; i < n; ++i)
1506         {
1507                 //print(search_getfilename(globhandle, i), "\n");
1508                 f = search_getfilename(globhandle, i);
1509                 PrecachePlayerSounds(f);
1510         }
1511         search_end(globhandle);
1512 }
1513 void precache_all_playermodels(string pattern)
1514 {
1515         float globhandle, i, n;
1516         string f;
1517
1518         globhandle = search_begin(pattern, TRUE, FALSE);
1519         if (globhandle < 0)
1520                 return;
1521         n = search_getsize(globhandle);
1522         for (i = 0; i < n; ++i)
1523         {
1524                 //print(search_getfilename(globhandle, i), "\n");
1525                 f = search_getfilename(globhandle, i);
1526                 precache_playermodel(f);
1527         }
1528         search_end(globhandle);
1529 }
1530
1531 void precache()
1532 {
1533     // gamemode related things
1534     precache_model ("models/misc/chatbubble.spr");
1535     if (g_runematch)
1536     {
1537         precache_model ("models/runematch/curse.mdl");
1538         precache_model ("models/runematch/rune.mdl");
1539     }
1540
1541 #ifdef TTURRETS_ENABLED
1542     if (autocvar_g_turrets)
1543         turrets_precash();
1544 #endif
1545
1546     // Precache all player models if desired
1547     if (autocvar_sv_precacheplayermodels)
1548     {
1549         PrecachePlayerSounds("sound/player/default.sounds");
1550         precache_all_playermodels("models/player/*.zym");
1551         precache_all_playermodels("models/player/*.dpm");
1552         precache_all_playermodels("models/player/*.md3");
1553         precache_all_playermodels("models/player/*.psk");
1554         precache_all_playermodels("models/player/*.iqm");
1555     }
1556
1557     if (autocvar_sv_defaultcharacter)
1558     {
1559         string s;
1560         s = autocvar_sv_defaultplayermodel_red;
1561         if (s != "")
1562             precache_playermodel(s);
1563         s = autocvar_sv_defaultplayermodel_blue;
1564         if (s != "")
1565             precache_playermodel(s);
1566         s = autocvar_sv_defaultplayermodel_yellow;
1567         if (s != "")
1568             precache_playermodel(s);
1569         s = autocvar_sv_defaultplayermodel_pink;
1570         if (s != "")
1571             precache_playermodel(s);
1572         s = autocvar_sv_defaultplayermodel;
1573         if (s != "")
1574             precache_playermodel(s);
1575     }
1576
1577     if (g_footsteps)
1578     {
1579         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1580         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1581     }
1582
1583     // gore and miscellaneous sounds
1584     //precache_sound ("misc/h2ohit.wav");
1585     precache_model ("models/hook.md3");
1586     precache_sound ("misc/armorimpact.wav");
1587     precache_sound ("misc/bodyimpact1.wav");
1588     precache_sound ("misc/bodyimpact2.wav");
1589     precache_sound ("misc/gib.wav");
1590     precache_sound ("misc/gib_splat01.wav");
1591     precache_sound ("misc/gib_splat02.wav");
1592     precache_sound ("misc/gib_splat03.wav");
1593     precache_sound ("misc/gib_splat04.wav");
1594     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1595     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1596     precache_sound ("misc/null.wav");
1597     precache_sound ("misc/spawn.wav");
1598     precache_sound ("misc/talk.wav");
1599     precache_sound ("misc/teleport.wav");
1600     precache_sound ("misc/poweroff.wav");
1601     precache_sound ("player/lava.wav");
1602     precache_sound ("player/slime.wav");
1603
1604     if (g_jetpack)
1605         precache_sound ("misc/jetpack_fly.wav");
1606
1607     precache_model ("models/sprites/0.spr32");
1608     precache_model ("models/sprites/1.spr32");
1609     precache_model ("models/sprites/2.spr32");
1610     precache_model ("models/sprites/3.spr32");
1611     precache_model ("models/sprites/4.spr32");
1612     precache_model ("models/sprites/5.spr32");
1613     precache_model ("models/sprites/6.spr32");
1614     precache_model ("models/sprites/7.spr32");
1615     precache_model ("models/sprites/8.spr32");
1616     precache_model ("models/sprites/9.spr32");
1617     precache_model ("models/sprites/10.spr32");
1618
1619     // common weapon precaches
1620         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1621     precache_sound ("weapons/weapon_switch.wav");
1622     precache_sound ("weapons/weaponpickup.wav");
1623     precache_sound ("weapons/unavailable.wav");
1624     precache_sound ("weapons/dryfire.wav");
1625     if (g_grappling_hook)
1626     {
1627         precache_sound ("weapons/hook_fire.wav"); // hook
1628         precache_sound ("weapons/hook_impact.wav"); // hook
1629     }
1630
1631     if(autocvar_sv_precacheweapons)
1632     {
1633         //precache weapon models/sounds
1634         local float wep;
1635         wep = WEP_FIRST;
1636         while (wep <= WEP_LAST)
1637         {
1638             weapon_action(wep, WR_PRECACHE);
1639             wep = wep + 1;
1640         }
1641     }
1642
1643     precache_model("models/elaser.mdl");
1644     precache_model("models/laser.mdl");
1645     precache_model("models/ebomb.mdl");
1646
1647 #if 0
1648     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1649
1650     if (!self.noise && self.music) // quake 3 uses the music field
1651         self.noise = self.music;
1652
1653     // plays music for the level if there is any
1654     if (self.noise)
1655     {
1656         precache_sound (self.noise);
1657         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1658     }
1659 #endif
1660 }
1661
1662 // sorry, but using \ in macros breaks line numbers
1663 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1664 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1665 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1666
1667
1668 void Send_CSQC_Centerprint_Generic(entity e, float id, string s, float duration, float countdown_num)
1669 {
1670         if (clienttype(e) == CLIENTTYPE_REAL)
1671         {
1672                 msg_entity = e;
1673                 WRITESPECTATABLE_MSG_ONE({
1674                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1675                         WriteByte(MSG_ONE, TE_CSQC_CENTERPRINT_GENERIC);
1676                         WriteByte(MSG_ONE, id);
1677                         WriteString(MSG_ONE, s);
1678                         if (id != 0 && s != "")
1679                         {
1680                                 WriteByte(MSG_ONE, duration);
1681                                 WriteByte(MSG_ONE, countdown_num);
1682                         }
1683                 });
1684         }
1685 }
1686 void Send_CSQC_Centerprint_Generic_Expire(entity e, float id)
1687 {
1688         Send_CSQC_Centerprint_Generic(e, id, "", 1, 0);
1689 }
1690 // WARNING: this kills the trace globals
1691 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1692 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1693
1694 #define INITPRIO_FIRST              0
1695 #define INITPRIO_GAMETYPE           0
1696 #define INITPRIO_GAMETYPE_FALLBACK  1
1697 #define INITPRIO_FINDTARGET        10
1698 #define INITPRIO_DROPTOFLOOR       20
1699 #define INITPRIO_SETLOCATION       90
1700 #define INITPRIO_LINKDOORS         91
1701 #define INITPRIO_LAST              99
1702
1703 .void(void) initialize_entity;
1704 .float initialize_entity_order;
1705 .entity initialize_entity_next;
1706 entity initialize_entity_first;
1707
1708 void make_safe_for_remove(entity e)
1709 {
1710     if (e.initialize_entity)
1711     {
1712         entity ent, prev;
1713         for (ent = initialize_entity_first; ent; )
1714         {
1715             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1716             {
1717                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1718                 // skip it in linked list
1719                 if (prev)
1720                 {
1721                     prev.initialize_entity_next = ent.initialize_entity_next;
1722                     ent = prev.initialize_entity_next;
1723                 }
1724                 else
1725                 {
1726                     initialize_entity_first = ent.initialize_entity_next;
1727                     ent = initialize_entity_first;
1728                 }
1729             }
1730             else
1731             {
1732                 prev = ent;
1733                 ent = ent.initialize_entity_next;
1734             }
1735         }
1736     }
1737 }
1738
1739 void objerror(string s)
1740 {
1741     make_safe_for_remove(self);
1742     objerror_builtin(s);
1743 }
1744
1745 .float remove_except_protected_forbidden;
1746 void remove_except_protected(entity e)
1747 {
1748         if(e.remove_except_protected_forbidden)
1749                 error("not allowed to remove this at this point");
1750         remove_builtin(e);
1751 }
1752
1753 void remove_unsafely(entity e)
1754 {
1755     if(e.classname == "spike")
1756         error("Removing spikes is forbidden (crylink bug), please report");
1757     remove_builtin(e);
1758 }
1759
1760 void remove_safely(entity e)
1761 {
1762     make_safe_for_remove(e);
1763     remove_builtin(e);
1764 }
1765
1766 void InitializeEntity(entity e, void(void) func, float order)
1767 {
1768     entity prev, cur;
1769
1770     if (!e || e.initialize_entity)
1771     {
1772         // make a proxy initializer entity
1773         entity e_old;
1774         e_old = e;
1775         e = spawn();
1776         e.classname = "initialize_entity";
1777         e.enemy = e_old;
1778     }
1779
1780     e.initialize_entity = func;
1781     e.initialize_entity_order = order;
1782
1783     cur = initialize_entity_first;
1784     for (;;)
1785     {
1786         if (!cur || cur.initialize_entity_order > order)
1787         {
1788             // insert between prev and cur
1789             if (prev)
1790                 prev.initialize_entity_next = e;
1791             else
1792                 initialize_entity_first = e;
1793             e.initialize_entity_next = cur;
1794             return;
1795         }
1796         prev = cur;
1797         cur = cur.initialize_entity_next;
1798     }
1799 }
1800 void InitializeEntitiesRun()
1801 {
1802     entity startoflist;
1803     startoflist = initialize_entity_first;
1804     initialize_entity_first = world;
1805     remove = remove_except_protected;
1806     for (self = startoflist; self; self = self.initialize_entity_next)
1807     {
1808         self.remove_except_protected_forbidden = 1;
1809     }
1810     for (self = startoflist; self; )
1811     {
1812         entity e;
1813         var void(void) func;
1814         e = self.initialize_entity_next;
1815         func = self.initialize_entity;
1816         self.initialize_entity_order = 0;
1817         self.initialize_entity = func_null;
1818         self.initialize_entity_next = world;
1819         self.remove_except_protected_forbidden = 0;
1820         if (self.classname == "initialize_entity")
1821         {
1822             entity e_old;
1823             e_old = self.enemy;
1824             remove_builtin(self);
1825             self = e_old;
1826         }
1827         //dprint("Delayed initialization: ", self.classname, "\n");
1828         if(func != func_null)
1829             func();
1830         else
1831         {
1832             eprint(self);
1833             backtrace(strcat("Null function in: ", self.classname, "\n"));
1834         }
1835         self = e;
1836     }
1837     remove = remove_unsafely;
1838 }
1839
1840 .float uncustomizeentityforclient_set;
1841 .void(void) uncustomizeentityforclient;
1842 void(void) SUB_Nullpointer = #0;
1843 void UncustomizeEntitiesRun()
1844 {
1845     entity oldself;
1846     oldself = self;
1847     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1848         self.uncustomizeentityforclient();
1849     self = oldself;
1850 }
1851 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1852 {
1853     e.customizeentityforclient = customizer;
1854     e.uncustomizeentityforclient = uncustomizer;
1855     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1856 }
1857
1858 .float nottargeted;
1859 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1860
1861 void() SUB_Remove;
1862 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1863 {
1864     vector mi, ma;
1865
1866     if (e.classname == "")
1867         e.classname = "net_linked";
1868
1869     if (e.model == "" || self.modelindex == 0)
1870     {
1871         mi = e.mins;
1872         ma = e.maxs;
1873         setmodel(e, "null");
1874         setsize(e, mi, ma);
1875     }
1876
1877     e.SendEntity = sendfunc;
1878     e.SendFlags = 0xFFFFFF;
1879
1880     if (!docull)
1881         e.effects |= EF_NODEPTHTEST;
1882
1883     if (dt)
1884     {
1885         e.nextthink = time + dt;
1886         e.think = SUB_Remove;
1887     }
1888 }
1889
1890 void adaptor_think2touch()
1891 {
1892     entity o;
1893     o = other;
1894     other = world;
1895     self.touch();
1896     other = o;
1897 }
1898
1899 void adaptor_think2use()
1900 {
1901     entity o, a;
1902     o = other;
1903     a = activator;
1904     activator = world;
1905     other = world;
1906     self.use();
1907     other = o;
1908     activator = a;
1909 }
1910
1911 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1912 {
1913         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1914                 self.projectiledeathtype |= HITTYPE_SPLASH;
1915         adaptor_think2use();
1916 }
1917
1918 // deferred dropping
1919 void DropToFloor_Handler()
1920 {
1921     droptofloor_builtin();
1922     self.dropped_origin = self.origin;
1923 }
1924
1925 void droptofloor()
1926 {
1927     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1928 }
1929
1930
1931
1932 float trace_hits_box_a0, trace_hits_box_a1;
1933
1934 float trace_hits_box_1d(float end, float thmi, float thma)
1935 {
1936     if (end == 0)
1937     {
1938         // just check if x is in range
1939         if (0 < thmi)
1940             return FALSE;
1941         if (0 > thma)
1942             return FALSE;
1943     }
1944     else
1945     {
1946         // do the trace with respect to x
1947         // 0 -> end has to stay in thmi -> thma
1948         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1949         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1950         if (trace_hits_box_a0 > trace_hits_box_a1)
1951             return FALSE;
1952     }
1953     return TRUE;
1954 }
1955
1956 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1957 {
1958     end -= start;
1959     thmi -= start;
1960     thma -= start;
1961     // now it is a trace from 0 to end
1962
1963     trace_hits_box_a0 = 0;
1964     trace_hits_box_a1 = 1;
1965
1966     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1967         return FALSE;
1968     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1969         return FALSE;
1970     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1971         return FALSE;
1972
1973     return TRUE;
1974 }
1975
1976 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1977 {
1978     return trace_hits_box(start, end, thmi - ma, thma - mi);
1979 }
1980
1981 float SUB_NoImpactCheck()
1982 {
1983         // zero hitcontents = this is not the real impact, but either the
1984         // mirror-impact of something hitting the projectile instead of the
1985         // projectile hitting the something, or a touchareagrid one. Neither of
1986         // these stop the projectile from moving, so...
1987         if(trace_dphitcontents == 0)
1988         {
1989                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1990                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1991                 checkclient();
1992         }
1993     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1994         return 1;
1995     if (other == world && self.size != '0 0 0')
1996     {
1997         vector tic;
1998         tic = self.velocity * sys_frametime;
1999         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
2000         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
2001         if (trace_fraction >= 1)
2002         {
2003             dprint("Odd... did not hit...?\n");
2004         }
2005         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
2006         {
2007             dprint("Detected and prevented the sky-grapple bug.\n");
2008             return 1;
2009         }
2010     }
2011
2012     return 0;
2013 }
2014
2015 #define SUB_OwnerCheck() (other && (other == self.owner))
2016
2017 void RemoveGrapplingHook(entity pl);
2018 void W_Crylink_Dequeue(entity e);
2019 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
2020 {
2021         if(SUB_OwnerCheck())
2022                 return TRUE;
2023         if(SUB_NoImpactCheck())
2024         {
2025                 if(self.classname == "grapplinghook")
2026                         RemoveGrapplingHook(self.realowner);
2027                 else if(self.classname == "spike")
2028                 {
2029                         W_Crylink_Dequeue(self);
2030                         remove(self);
2031                 }
2032                 else
2033                         remove(self);
2034                 return TRUE;
2035         }
2036         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
2037                 UpdateCSQCProjectile(self);
2038         return FALSE;
2039 }
2040 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
2041
2042 float MAX_IPBAN_URIS           = 16;
2043
2044 float URI_GET_DISCARD          = 0;
2045 float URI_GET_IPBAN            = 1;
2046 float URI_GET_IPBAN_END        = 16;
2047 float URI_GET_PLAYERSTATS_SENT = 17;
2048
2049 void URI_Get_Callback(float id, float status, string data)
2050 {
2051     dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is:\n");
2052     dprint(data);
2053     dprint("\nEnd of data.\n");
2054
2055     if(url_URI_Get_Callback(id, status, data))
2056     {
2057         // handled
2058     }
2059     else if (id == URI_GET_DISCARD)
2060     {
2061         // discard
2062     }
2063     else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2064     {
2065         // online ban list
2066         OnlineBanList_URI_Get_Callback(id, status, data);
2067     }
2068     else if (id == URI_GET_PLAYERSTATS_SENT)
2069     {
2070         PlayerStats_Sent_URI_Get_Callback(id, status, data);
2071     }
2072     else
2073     {
2074         print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2075     }
2076 }
2077
2078 void print_to(entity e, string s)
2079 {
2080     if (e)
2081         sprint(e, strcat(s, "\n"));
2082     else
2083         print(s, "\n");
2084 }
2085
2086 string uid2name(string myuid) {
2087         string s;
2088         s = db_get(ServerProgsDB, strcat("uid2name", myuid));
2089
2090         if(s == "")
2091                 s = "^1Unregistered Player";
2092         return s;
2093 }
2094
2095 float race_readTime(string map, float pos)
2096 {
2097         string rr;
2098         if(g_cts)
2099                 rr = CTS_RECORD;
2100         else
2101                 rr = RACE_RECORD;
2102
2103         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
2104 }
2105
2106 string race_readUID(string map, float pos)
2107 {
2108         string rr;
2109         if(g_cts)
2110                 rr = CTS_RECORD;
2111         else
2112                 rr = RACE_RECORD;
2113
2114         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
2115 }
2116
2117 float race_readPos(string map, float t) {
2118         float i;
2119         for (i = 1; i <= RANKINGS_CNT; ++i)
2120                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
2121                         return i;
2122
2123         return 0; // pos is zero if unranked
2124 }
2125
2126 void race_writeTime(string map, float t, string myuid)
2127 {
2128         string rr;
2129         if(g_cts)
2130                 rr = CTS_RECORD;
2131         else
2132                 rr = RACE_RECORD;
2133
2134         float newpos;
2135         newpos = race_readPos(map, t);
2136
2137         float i, prevpos;
2138         for(i = 1; i <= RANKINGS_CNT; ++i)
2139         {
2140                 if(race_readUID(map, i) == myuid)
2141                         prevpos = i;
2142         }
2143         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
2144                 for (i = prevpos; i > newpos; --i) {
2145                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2146                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2147                 }
2148         } else { // player has no ranked record yet
2149                 for (i = RANKINGS_CNT; i > newpos; --i) {
2150                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2151                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2152                 }
2153         }
2154
2155         // store new time itself
2156         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2157         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2158 }
2159
2160 string race_readName(string map, float pos)
2161 {
2162         string rr;
2163         if(g_cts)
2164                 rr = CTS_RECORD;
2165         else
2166                 rr = RACE_RECORD;
2167
2168         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2169 }
2170
2171 string race_placeName(float pos) {
2172         if(floor((mod(pos, 100))/10) * 10 != 10) // examples: 12th, 111th, 213th will not execute this block
2173         {
2174                 if(mod(pos, 10) == 1)
2175                         return strcat(ftos(pos), "st");
2176                 else if(mod(pos, 10) == 2)
2177                         return strcat(ftos(pos), "nd");
2178                 else if(mod(pos, 10) == 3)
2179                         return strcat(ftos(pos), "rd");
2180                 else
2181                         return strcat(ftos(pos), "th");
2182         }
2183         else
2184                 return strcat(ftos(pos), "th");
2185 }
2186 string getrecords(float page) // 50 records per page
2187 {
2188     float rec;
2189     string h;
2190     float r;
2191     float i;
2192     string s;
2193
2194     rec = 0;
2195
2196     s = "";
2197
2198     if (g_ctf)
2199     {
2200         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2201         {
2202             if (MapInfo_Get_ByID(i))
2203             {
2204                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
2205                 if (r == 0)
2206                     continue;
2207                 // TODO: uid2name
2208                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
2209                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
2210                 ++rec;
2211             }
2212         }
2213     }
2214
2215     if (g_race)
2216     {
2217         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2218         {
2219             if (MapInfo_Get_ByID(i))
2220             {
2221                 r = race_readTime(MapInfo_Map_bspname, 1);
2222                 if (r == 0)
2223                     continue;
2224                 h = race_readName(MapInfo_Map_bspname, 1);
2225                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2226                 ++rec;
2227             }
2228         }
2229     }
2230
2231     if (g_cts)
2232     {
2233         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2234         {
2235             if (MapInfo_Get_ByID(i))
2236             {
2237                 r = race_readTime(MapInfo_Map_bspname, 1);
2238                 if (r == 0)
2239                     continue;
2240                 h = race_readName(MapInfo_Map_bspname, 1);
2241                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2242                 ++rec;
2243             }
2244         }
2245     }
2246
2247     MapInfo_ClearTemps();
2248
2249     if (s == "" && page == 0)
2250         return "No records are available on this server.\n";
2251     else
2252         return s;
2253 }
2254
2255 string getrankings()
2256 {
2257     string n;
2258     float t;
2259     float i;
2260     string s;
2261     string p;
2262     string map;
2263
2264     s = "";
2265
2266     map = GetMapname();
2267
2268     for (i = 1; i <= RANKINGS_CNT; ++i)
2269     {
2270         t = race_readTime(map, i);
2271         if (t == 0)
2272             continue;
2273         n = race_readName(map, i);
2274         p = race_placeName(i);
2275         s = strcat(s, strpad(8, p), " ", strpad(-8, TIME_ENCODED_TOSTRING(t)), " ", n, "\n");
2276     }
2277
2278     MapInfo_ClearTemps();
2279
2280     if (s == "")
2281         return strcat("No records are available for the map: ", map, "\n");
2282     else
2283         return strcat("Records for ", map, ":\n", s);
2284 }
2285
2286 #define LADDER_FIRSTPOINT 100
2287 #define LADDER_CNT 10
2288         // position X still gives LADDER_FIRSTPOINT/X points
2289 #define LADDER_SIZE 30
2290         // ladder shows the top X players
2291 string top_uids[LADDER_SIZE];
2292 float top_scores[LADDER_SIZE];
2293 string getladder()
2294 {
2295     float i, j, k, uidcnt;
2296     string s, temp_s;
2297
2298     s = "";
2299     temp_s = "";
2300
2301     string rr;
2302     if(g_cts)
2303         rr = CTS_RECORD;
2304     else
2305         rr = RACE_RECORD;
2306
2307     string myuid;
2308
2309     for (k = 0; k < MapInfo_count; ++k)
2310     {
2311         if (MapInfo_Get_ByID(k))
2312         {
2313                 for (i = 0; i <= LADDER_CNT; ++i) { // i = 0 because it is the speed award
2314                         if(i == 0) // speed award
2315                         {
2316                                 if(stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/speed"))) == 0)
2317                                         continue;
2318
2319                                 myuid = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/crypto_idfp"));
2320                         }
2321                         else // normal record, if it exists (else break)
2322                         {
2323                                 if(race_readTime(MapInfo_Map_bspname, i) == 0)
2324                                         continue;
2325
2326                                 myuid = race_readUID(MapInfo_Map_bspname, i);
2327                         }
2328
2329                         // string s contains:
2330                         // arg 0 = # of speed recs
2331                         // arg 1 = # of 1st place recs
2332                         // arg 2 = # of 2nd place recs
2333                         // ... etc
2334                         // LADDER_CNT+1 = total points
2335
2336                         temp_s = db_get(TemporaryDB, strcat("ladder", myuid));
2337                         if (temp_s == "")
2338                         {
2339                             db_put(TemporaryDB, strcat("uid", ftos(uidcnt)), myuid);
2340                             ++uidcnt;
2341                             for (j = 0; j <= LADDER_CNT + 1; ++j)
2342                             {
2343                                 if(j != LADDER_CNT + 1)
2344                                     temp_s = strcat(temp_s, "0 ");
2345                                 else
2346                                     temp_s = strcat(temp_s, "0");
2347                             }
2348                         }
2349
2350                         tokenize_console(temp_s);
2351                         s = "";
2352
2353                         if(i == 0) // speed award
2354                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2355                             {
2356                                 if(j == 0) // speed award
2357                                     s = strcat(s, ftos(stof(argv(j)) +1)); // add 1 to speed rec count and write
2358                                 else
2359                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2360                             }
2361                         else // record
2362                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2363                             {
2364                                 if(j == 0)
2365                                     s = strcat(s, argv(j)); // speed award, dont prefix with " "
2366                                 else if(j == i) // wanted rec!
2367                                     s = strcat(s, " ", ftos(stof(argv(j)) +1)); // update argv(j)
2368                                 else
2369                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2370                             }
2371
2372                         // total points are (by default) calculated like this:
2373                         // speedrec = floor(100 / 10) = 10 points
2374                         // 1st place = floor(100 / 1) = 100 points
2375                         // 2nd place = floor(100 / 2) = 50 points
2376                         // 3rd place = floor(100 / 3) = 33 points
2377                         // 4th place = floor(100 / 4) = 25 points
2378                         // 5th place = floor(100 / 5) = 20 points
2379                         // ... etc
2380
2381                         if(i == 0)
2382                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + LADDER_FIRSTPOINT / 10)); // speed award, add LADDER_FIRSTPOINT / 10 points
2383                         else
2384                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + floor(LADDER_FIRSTPOINT / i))); // record, add LADDER_FIRSTPOINT / i points
2385
2386                         db_put(TemporaryDB, strcat("ladder", myuid), s);
2387                 }
2388         }
2389     }
2390
2391     float thiscnt;
2392     string thisuid;
2393     for (i = 0; i <= uidcnt; ++i) // for each known uid
2394     {
2395         thisuid = db_get(TemporaryDB, strcat("uid", ftos(i)));
2396         temp_s = db_get(TemporaryDB, strcat("ladder", thisuid));
2397         tokenize_console(temp_s);
2398         thiscnt = stof(argv(LADDER_CNT+1));
2399
2400         if(thiscnt > top_scores[LADDER_SIZE-1])
2401         for (j = 0; j < LADDER_SIZE; ++j) // for each place in ladder
2402         {
2403             if(thiscnt > top_scores[j])
2404             {
2405                 for (k = LADDER_SIZE-1; k >= j; --k)
2406                 {
2407                     top_uids[k] = top_uids[k-1];
2408                     top_scores[k] = top_scores[k-1];
2409                 }
2410                 top_uids[j] = thisuid;
2411                 top_scores[j] = thiscnt;
2412                 break;
2413             }
2414         }
2415     }
2416
2417     s = "^3-----------------------\n\n";
2418
2419     s = strcat(s, "Pos ^3|");
2420     s = strcat(s, " ^7Total  ^3|");
2421     for (i = 1; i <= LADDER_CNT; ++i)
2422     {
2423         s = strcat(s, " ^7", race_placeName(i), " ^3|");
2424     }
2425     s = strcat(s, " ^7Speed awards ^3| ^7Name");
2426
2427     s = strcat(s, "\n^3----+--------");
2428     for (i = 1; i <= min(9, LADDER_CNT); ++i)
2429     {
2430         s = strcat(s, "+-----");
2431     }
2432 #if LADDER_CNT > 9
2433     for (i = 1; i <= LADDER_CNT - 9; ++i)
2434     {
2435         s = strcat(s, "+------");
2436     }
2437 #endif
2438
2439     s = strcat(s, "+--------------+--------------------\n");
2440
2441     for (i = 0; i < LADDER_SIZE; ++i)
2442     {
2443         temp_s = db_get(TemporaryDB, strcat("ladder", top_uids[i]));
2444         tokenize_console(temp_s);
2445         if (argv(LADDER_CNT+1) == "") // total is 0, skip
2446             continue;
2447         s = strcat(s, strpad(4, race_placeName(i+1)), "^3| ^7"); // pos
2448         s = strcat(s, strpad(7, argv(LADDER_CNT+1)), "^3| ^7"); // total
2449         for (j = 1; j <= min(9, LADDER_CNT); ++j)
2450         {
2451             s = strcat(s, strpad(4, argv(j)), "^3| ^7"); // 1st, 2nd, 3rd etc cnt
2452         }
2453 #if LADDER_CNT > 9
2454         for (j = 10; j <= LADDER_CNT; ++j)
2455         {
2456             s = strcat(s, strpad(4, argv(j)), " ^3| ^7"); // 1st, 2nd, 3rd etc cnt
2457         }
2458 #endif
2459
2460         s = strcat(s, strpad(13, argv(0)), "^3| ^7"); // speed award cnt
2461         s = strcat(s, uid2name(top_uids[i]), "\n"); // name
2462     }
2463
2464     MapInfo_ClearTemps();
2465
2466     if (s == "")
2467         return "No ladder on this server!\n";
2468     else
2469         return strcat("Top ", ftos(LADDER_SIZE), " ladder rankings:\n", s);
2470 }
2471
2472
2473 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2474 {
2475     float m, i;
2476     vector start, org, delta, end, enddown, mstart;
2477     entity sp;
2478
2479     m = e.dphitcontentsmask;
2480     e.dphitcontentsmask = goodcontents | badcontents;
2481
2482     org = world.mins;
2483     delta = world.maxs - world.mins;
2484
2485     for (i = 0; i < attempts; ++i)
2486     {
2487         start_x = org_x + random() * delta_x;
2488         start_y = org_y + random() * delta_y;
2489         start_z = org_z + random() * delta_z;
2490
2491         // rule 1: start inside world bounds, and outside
2492         // solid, and don't start from somewhere where you can
2493         // fall down to evil
2494         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2495         if (trace_fraction >= 1)
2496             continue;
2497         if (trace_startsolid)
2498             continue;
2499         if (trace_dphitcontents & badcontents)
2500             continue;
2501         if (trace_dphitq3surfaceflags & badsurfaceflags)
2502             continue;
2503
2504         // rule 2: if we are too high, lower the point
2505         if (trace_fraction * delta_z > maxaboveground)
2506             start = trace_endpos + '0 0 1' * maxaboveground;
2507         enddown = trace_endpos;
2508
2509         // rule 3: make sure we aren't outside the map. This only works
2510         // for somewhat well formed maps. A good rule of thumb is that
2511         // the map should have a convex outside hull.
2512         // these can be traceLINES as we already verified the starting box
2513         mstart = start + 0.5 * (e.mins + e.maxs);
2514         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2515         if (trace_fraction >= 1)
2516             continue;
2517         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2518         if (trace_fraction >= 1)
2519             continue;
2520         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2521         if (trace_fraction >= 1)
2522             continue;
2523         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2524         if (trace_fraction >= 1)
2525             continue;
2526         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2527         if (trace_fraction >= 1)
2528             continue;
2529
2530         // rule 4: we must "see" some spawnpoint
2531         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
2532                 if(checkpvs(mstart, sp))
2533                         break;
2534         if(!sp)
2535         {
2536                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
2537                         if(checkpvs(mstart, sp))
2538                                 break;
2539                 if(!sp)
2540                         continue;
2541         }
2542
2543         // find a random vector to "look at"
2544         end_x = org_x + random() * delta_x;
2545         end_y = org_y + random() * delta_y;
2546         end_z = org_z + random() * delta_z;
2547         end = start + normalize(end - start) * vlen(delta);
2548
2549         // rule 4: start TO end must not be too short
2550         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2551         if (trace_startsolid)
2552             continue;
2553         if (trace_fraction < minviewdistance / vlen(delta))
2554             continue;
2555
2556         // rule 5: don't want to look at sky
2557         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2558             continue;
2559
2560         // rule 6: we must not end up in trigger_hurt
2561         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2562             continue;
2563
2564         break;
2565     }
2566
2567     e.dphitcontentsmask = m;
2568
2569     if (i < attempts)
2570     {
2571         setorigin(e, start);
2572         e.angles = vectoangles(end - start);
2573         dprint("Needed ", ftos(i + 1), " attempts\n");
2574         return TRUE;
2575     }
2576     else
2577         return FALSE;
2578 }
2579
2580 float zcurveparticles_effectno;
2581 vector zcurveparticles_start;
2582 float zcurveparticles_spd;
2583
2584 void endzcurveparticles()
2585 {
2586         if(zcurveparticles_effectno)
2587         {
2588                 // terminator
2589                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2590         }
2591         zcurveparticles_effectno = 0;
2592 }
2593
2594 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2595 {
2596         spd = bound(0, floor(spd / 16), 32767);
2597         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2598         {
2599                 endzcurveparticles();
2600                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2601                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2602                 WriteShort(MSG_BROADCAST, effectno);
2603                 WriteCoord(MSG_BROADCAST, start_x);
2604                 WriteCoord(MSG_BROADCAST, start_y);
2605                 WriteCoord(MSG_BROADCAST, start_z);
2606                 zcurveparticles_effectno = effectno;
2607                 zcurveparticles_start = start;
2608         }
2609         else
2610                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2611         WriteCoord(MSG_BROADCAST, end_x);
2612         WriteCoord(MSG_BROADCAST, end_y);
2613         WriteCoord(MSG_BROADCAST, end_z);
2614         WriteCoord(MSG_BROADCAST, end_dz);
2615         zcurveparticles_spd = spd;
2616 }
2617
2618 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2619 {
2620         float end_dz;
2621         vector vecxy, velxy;
2622
2623         vecxy = end - start;
2624         vecxy_z = 0;
2625         velxy = vel;
2626         velxy_z = 0;
2627
2628         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2629         {
2630                 endzcurveparticles();
2631                 trailparticles(world, effectno, start, end);
2632                 return;
2633         }
2634
2635         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2636         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2637 }
2638
2639 void write_recordmarker(entity pl, float tstart, float dt)
2640 {
2641     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2642
2643     // also write a marker into demo files for demotc-race-record-extractor to find
2644     stuffcmd(pl,
2645              strcat(
2646                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2647                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2648 }
2649
2650 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2651 {
2652         switch(algn)
2653         {
2654                 default:
2655                 case 3: // right
2656                         break;
2657
2658                 case 4: // left
2659                         vecs_y = -vecs_y;
2660                         break;
2661
2662                 case 1:
2663                         if(allowcenter) // 2: allow center handedness
2664                         {
2665                                 // center
2666                                 vecs_y = 0;
2667                                 vecs_z -= 2;
2668                         }
2669                         else
2670                         {
2671                                 // right
2672                         }
2673                         break;
2674
2675                 case 2:
2676                         if(allowcenter) // 2: allow center handedness
2677                         {
2678                                 // center
2679                                 vecs_y = 0;
2680                                 vecs_z -= 2;
2681                         }
2682                         else
2683                         {
2684                                 // left
2685                                 vecs_y = -vecs_y;
2686                         }
2687                         break;
2688         }
2689         return vecs;
2690 }
2691
2692 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2693 {
2694         string s;
2695         vector v;
2696
2697         if (autocvar_g_shootfromeye)
2698         {
2699                 if (visual)
2700                 {
2701                         vecs_y = 0;
2702                         vecs_z -= 2;
2703                 }
2704                 else
2705                 {
2706                         vecs_y = 0;
2707                         vecs_z = 0;
2708                 }
2709         }
2710         else if (autocvar_g_shootfromcenter)
2711         {
2712                 vecs_y = 0;
2713                 vecs_z -= 2;
2714         }
2715         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2716         {
2717                 v = stov(s);
2718                 if (y_is_right)
2719                         v_y = -v_y;
2720                 if (v_x != 0)
2721                         vecs_x = v_x;
2722                 vecs_y = v_y;
2723                 vecs_z = v_z;
2724         }
2725         else if (autocvar_g_shootfromclient)
2726         {
2727                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2728         }
2729         return vecs;
2730 }
2731
2732 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2733 {
2734         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2735 }
2736
2737
2738 void attach_sameorigin(entity e, entity to, string tag)
2739 {
2740     vector org, t_forward, t_left, t_up, e_forward, e_up;
2741     vector org0, ang0;
2742     float tagscale;
2743
2744     ang0 = e.angles;
2745     org0 = e.origin;
2746
2747     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2748     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2749     t_forward = v_forward * tagscale;
2750     t_left = v_right * -tagscale;
2751     t_up = v_up * tagscale;
2752
2753     e.origin_x = org * t_forward;
2754     e.origin_y = org * t_left;
2755     e.origin_z = org * t_up;
2756
2757     // current forward and up directions
2758     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2759                 e.angles = AnglesTransform_FromVAngles(e.angles);
2760         else
2761                 e.angles = AnglesTransform_FromAngles(e.angles);
2762     fixedmakevectors(e.angles);
2763
2764     // untransform forward, up!
2765     e_forward_x = v_forward * t_forward;
2766     e_forward_y = v_forward * t_left;
2767     e_forward_z = v_forward * t_up;
2768     e_up_x = v_up * t_forward;
2769     e_up_y = v_up * t_left;
2770     e_up_z = v_up * t_up;
2771
2772     e.angles = fixedvectoangles2(e_forward, e_up);
2773     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2774                 e.angles = AnglesTransform_ToVAngles(e.angles);
2775         else
2776                 e.angles = AnglesTransform_ToAngles(e.angles);
2777
2778     setattachment(e, to, tag);
2779     setorigin(e, e.origin);
2780 }
2781
2782 void detach_sameorigin(entity e)
2783 {
2784     vector org;
2785     org = gettaginfo(e, 0);
2786     e.angles = fixedvectoangles2(v_forward, v_up);
2787     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2788                 e.angles = AnglesTransform_ToVAngles(e.angles);
2789         else
2790                 e.angles = AnglesTransform_ToAngles(e.angles);
2791     setorigin(e, org);
2792     setattachment(e, world, "");
2793     setorigin(e, e.origin);
2794 }
2795
2796 void follow_sameorigin(entity e, entity to)
2797 {
2798     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2799     e.aiment = to; // make the hole follow bmodel
2800     e.punchangle = to.angles; // the original angles of bmodel
2801     e.view_ofs = e.origin - to.origin; // relative origin
2802     e.v_angle = e.angles - to.angles; // relative angles
2803 }
2804
2805 void unfollow_sameorigin(entity e)
2806 {
2807     e.movetype = MOVETYPE_NONE;
2808 }
2809
2810 entity gettaginfo_relative_ent;
2811 vector gettaginfo_relative(entity e, float tag)
2812 {
2813     if (!gettaginfo_relative_ent)
2814     {
2815         gettaginfo_relative_ent = spawn();
2816         gettaginfo_relative_ent.effects = EF_NODRAW;
2817     }
2818     gettaginfo_relative_ent.model = e.model;
2819     gettaginfo_relative_ent.modelindex = e.modelindex;
2820     gettaginfo_relative_ent.frame = e.frame;
2821     return gettaginfo(gettaginfo_relative_ent, tag);
2822 }
2823
2824 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2825 {
2826     float p;
2827     p = pow(2, chan);
2828     if (pl.soundentity.cnt & p)
2829         return;
2830     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2831     pl.soundentity.cnt |= p;
2832 }
2833
2834 void SoundEntity_StopSound(entity pl, float chan)
2835 {
2836     float p;
2837     p = pow(2, chan);
2838     if (pl.soundentity.cnt & p)
2839     {
2840         stopsoundto(MSG_ALL, pl.soundentity, chan);
2841         pl.soundentity.cnt &~= p;
2842     }
2843 }
2844
2845 void SoundEntity_Attach(entity pl)
2846 {
2847     pl.soundentity = spawn();
2848     pl.soundentity.classname = "soundentity";
2849     pl.soundentity.owner = pl;
2850     setattachment(pl.soundentity, pl, "");
2851     setmodel(pl.soundentity, "null");
2852 }
2853
2854 void SoundEntity_Detach(entity pl)
2855 {
2856     float i;
2857     for (i = 0; i <= 7; ++i)
2858         SoundEntity_StopSound(pl, i);
2859 }
2860
2861
2862 float ParseCommandPlayerSlotTarget_firsttoken;
2863 entity GetCommandPlayerSlotTargetFromTokenizedCommand(float tokens, float idx) // idx = start index
2864 {
2865         string s;
2866         entity e, head;
2867         float n;
2868
2869         s = string_null;
2870
2871         ParseCommandPlayerSlotTarget_firsttoken = -1;
2872
2873         if (tokens > idx)
2874         {
2875                 if (substring(argv(idx), 0, 1) == "#")
2876                 {
2877                         s = substring(argv(idx), 1, -1);
2878                         ++idx;
2879                         if (s == "") if (tokens > idx)
2880                         {
2881                                 s = argv(idx);
2882                                 ++idx;
2883                         }
2884                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2885                         n = stof(s);
2886                         if (s == ftos(n) && n > 0 && n <= maxclients)
2887                         {
2888                                 e = edict_num(n);
2889                                 if (e.flags & FL_CLIENT)
2890                                         return e;
2891                         }
2892                 }
2893                 else
2894                 {
2895                         // it must be a nick name
2896                         s = argv(idx);
2897                         ++idx;
2898                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2899
2900                         n = 0;
2901                         FOR_EACH_CLIENT(head)
2902                                 if (head.netname == s)
2903                                 {
2904                                         e = head;
2905                                         ++n;
2906                                 }
2907                         if (n == 1)
2908                                 return e;
2909
2910                         s = strdecolorize(s);
2911                         n = 0;
2912                         FOR_EACH_CLIENT(head)
2913                                 if (strdecolorize(head.netname) == s)
2914                                 {
2915                                         e = head;
2916                                         ++n;
2917                                 }
2918                         if (n == 1)
2919                                 return e;
2920                 }
2921         }
2922
2923         return world;
2924 }
2925
2926 .float scale2;
2927
2928 float modeleffect_SendEntity(entity to, float sf)
2929 {
2930         float f;
2931         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2932
2933         f = 0;
2934         if(self.velocity != '0 0 0')
2935                 f |= 1;
2936         if(self.angles != '0 0 0')
2937                 f |= 2;
2938         if(self.avelocity != '0 0 0')
2939                 f |= 4;
2940
2941         WriteByte(MSG_ENTITY, f);
2942         WriteShort(MSG_ENTITY, self.modelindex);
2943         WriteByte(MSG_ENTITY, self.skin);
2944         WriteByte(MSG_ENTITY, self.frame);
2945         WriteCoord(MSG_ENTITY, self.origin_x);
2946         WriteCoord(MSG_ENTITY, self.origin_y);
2947         WriteCoord(MSG_ENTITY, self.origin_z);
2948         if(f & 1)
2949         {
2950                 WriteCoord(MSG_ENTITY, self.velocity_x);
2951                 WriteCoord(MSG_ENTITY, self.velocity_y);
2952                 WriteCoord(MSG_ENTITY, self.velocity_z);
2953         }
2954         if(f & 2)
2955         {
2956                 WriteCoord(MSG_ENTITY, self.angles_x);
2957                 WriteCoord(MSG_ENTITY, self.angles_y);
2958                 WriteCoord(MSG_ENTITY, self.angles_z);
2959         }
2960         if(f & 4)
2961         {
2962                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2963                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2964                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2965         }
2966         WriteShort(MSG_ENTITY, self.scale * 256.0);
2967         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2968         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2969         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2970         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2971
2972         return TRUE;
2973 }
2974
2975 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2976 {
2977         entity e;
2978         float sz;
2979         e = spawn();
2980         e.classname = "modeleffect";
2981         setmodel(e, m);
2982         e.frame = f;
2983         setorigin(e, o);
2984         e.velocity = v;
2985         e.angles = ang;
2986         e.avelocity = angv;
2987         e.alpha = a;
2988         e.teleport_time = t1;
2989         e.fade_time = t2;
2990         e.skin = s;
2991         if(s0 >= 0)
2992                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2993         else
2994                 e.scale = -s0;
2995         if(s2 >= 0)
2996                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2997         else
2998                 e.scale2 = -s2;
2999         sz = max(e.scale, e.scale2);
3000         setsize(e, e.mins * sz, e.maxs * sz);
3001         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
3002 }
3003
3004 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
3005 {
3006         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
3007 }
3008
3009 float randombit(float bits)
3010 {
3011         if not(bits & (bits-1)) // this ONLY holds for powers of two!
3012                 return bits;
3013
3014         float n, f, b, r;
3015
3016         r = random();
3017         b = 0;
3018         n = 0;
3019
3020         for(f = 1; f <= bits; f *= 2)
3021         {
3022                 if(bits & f)
3023                 {
3024                         ++n;
3025                         r *= n;
3026                         if(r <= 1)
3027                                 b = f;
3028                         else
3029                                 r = (r - 1) / (n - 1);
3030                 }
3031         }
3032
3033         return b;
3034 }
3035
3036 float randombits(float bits, float k, float error_return)
3037 {
3038         float r;
3039         r = 0;
3040         while(k > 0 && bits != r)
3041         {
3042                 r += randombit(bits - r);
3043                 --k;
3044         }
3045         if(error_return)
3046                 if(k > 0)
3047                         return -1; // all
3048         return r;
3049 }
3050
3051 void randombit_test(float bits, float iter)
3052 {
3053         while(iter > 0)
3054         {
3055                 print(ftos(randombit(bits)), "\n");
3056                 --iter;
3057         }
3058 }
3059
3060 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
3061 {
3062         if(halflifedist > 0)
3063                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
3064         else if(halflifedist < 0)
3065                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
3066         else
3067                 return 1;
3068 }
3069
3070
3071
3072
3073 #ifdef RELEASE
3074 #define cvar_string_normal cvar_string_builtin
3075 #define cvar_normal cvar_builtin
3076 #else
3077 string cvar_string_normal(string n)
3078 {
3079         if not(cvar_type(n) & 1)
3080                 backtrace(strcat("Attempt to access undefined cvar: ", n));
3081         return cvar_string_builtin(n);
3082 }
3083
3084 float cvar_normal(string n)
3085 {
3086         return stof(cvar_string_normal(n));
3087 }
3088 #endif
3089 #define cvar_set_normal cvar_set_builtin
3090
3091 void defer_think()
3092 {
3093     entity oself;
3094
3095     oself           = self;
3096     self            = self.owner;
3097     oself.think     = SUB_Remove;
3098     oself.nextthink = time;
3099
3100     oself.use();
3101 }
3102
3103 /*
3104     Execute func() after time + fdelay.
3105     self when func is executed = self when defer is called
3106 */
3107 void defer(float fdelay, void() func)
3108 {
3109     entity e;
3110
3111     e           = spawn();
3112     e.owner     = self;
3113     e.use       = func;
3114     e.think     = defer_think;
3115     e.nextthink = time + fdelay;
3116 }
3117
3118 .string aiment_classname;
3119 .float aiment_deadflag;
3120 void SetMovetypeFollow(entity ent, entity e)
3121 {
3122         // FIXME this may not be warpzone aware
3123         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
3124         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
3125         ent.aiment = e; // make the hole follow bmodel
3126         ent.punchangle = e.angles; // the original angles of bmodel
3127         ent.view_ofs = ent.origin - e.origin; // relative origin
3128         ent.v_angle = ent.angles - e.angles; // relative angles
3129         ent.aiment_classname = strzone(e.classname);
3130         ent.aiment_deadflag = e.deadflag;
3131 }
3132 void UnsetMovetypeFollow(entity ent)
3133 {
3134         ent.movetype = MOVETYPE_FLY;
3135         PROJECTILE_MAKETRIGGER(ent);
3136         ent.aiment = world;
3137 }
3138 float LostMovetypeFollow(entity ent)
3139 {
3140 /*
3141         if(ent.movetype != MOVETYPE_FOLLOW)
3142                 if(ent.aiment)
3143                         error("???");
3144 */
3145         if(ent.aiment)
3146         {
3147                 if(ent.aiment.classname != ent.aiment_classname)
3148                         return 1;
3149                 if(ent.aiment.deadflag != ent.aiment_deadflag)
3150                         return 1;
3151         }
3152         return 0;
3153 }
3154
3155 float isPushable(entity e)
3156 {
3157         if(e.iscreature)
3158                 return TRUE;
3159         switch(e.classname)
3160         {
3161                 case "body":
3162                 case "droppedweapon":
3163                 case "keepawayball":
3164                 case "nexball_basketball":
3165                 case "nexball_football":
3166                         return TRUE;
3167                 case "bullet": // antilagged bullets can't hit this either
3168                         return FALSE;
3169         }
3170         if (e.projectiledeathtype)
3171                 return TRUE;
3172         return FALSE;
3173 }