qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35 string ColoredTeamName(float t);
  36
  37 string admin_name(void)
  38 {
  39         if(autocvar_sv_adminnick != "")
  40                 return autocvar_sv_adminnick;
  41         else
  42                 return "SERVER ADMIN";
  43 }
  44
  45 float DistributeEvenly_amount;
  46 float DistributeEvenly_totalweight;
  47 void DistributeEvenly_Init(float amount, float totalweight)
  48 {
  49     if (DistributeEvenly_amount)
  50     {
  51         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  52         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  53     }
  54     if (totalweight == 0)
  55         DistributeEvenly_amount = 0;
  56     else
  57         DistributeEvenly_amount = amount;
  58     DistributeEvenly_totalweight = totalweight;
  59 }
  60 float DistributeEvenly_Get(float weight)
  61 {
  62     float f;
  63     if (weight <= 0)
  64         return 0;
  65     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  66     DistributeEvenly_totalweight -= weight;
  67     DistributeEvenly_amount -= f;
  68     return f;
  69 }
  70
  71 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  72
  73
  74 string STR_PLAYER = "player";
  75 string STR_SPECTATOR = "spectator";
  76 string STR_OBSERVER = "observer";
  77
  78 #if 0
  79 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  80 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  81 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  82 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  83 #else
  84 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  85 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
  86 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  87 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
  88 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
  89 #endif
  90
  91 // copies a string to a tempstring (so one can strunzone it)
  92 string strcat1(string s) = #115; // FRIK_FILE
  93
  94 float logfile_open;
  95 float logfile;
  96
  97 void bcenterprint(string s)
  98 {
  99     // TODO replace by MSG_ALL (would show it to spectators too, though)?
 100     entity head;
 101     FOR_EACH_PLAYER(head)
 102     if (clienttype(head) == CLIENTTYPE_REAL)
 103         centerprint(head, s);
 104 }
 105
 106 void GameLogEcho(string s)
 107 {
 108     string fn;
 109     float matches;
 110
 111     if (autocvar_sv_eventlog_files)
 112     {
 113         if (!logfile_open)
 114         {
 115             logfile_open = TRUE;
 116             matches = autocvar_sv_eventlog_files_counter + 1;
 117             cvar_set("sv_eventlog_files_counter", ftos(matches));
 118             fn = ftos(matches);
 119             if (strlen(fn) < 8)
 120                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 121             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 122             logfile = fopen(fn, FILE_APPEND);
 123             fputs(logfile, ":logversion:3\n");
 124         }
 125         if (logfile >= 0)
 126         {
 127             if (autocvar_sv_eventlog_files_timestamps)
 128                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 129             else
 130                 fputs(logfile, strcat(s, "\n"));
 131         }
 132     }
 133     if (autocvar_sv_eventlog_console)
 134     {
 135         print(s, "\n");
 136     }
 137 }
 138
 139 void GameLogInit()
 140 {
 141     logfile_open = 0;
 142     // will be opened later
 143 }
 144
 145 void GameLogClose()
 146 {
 147     if (logfile_open && logfile >= 0)
 148     {
 149         fclose(logfile);
 150         logfile = -1;
 151     }
 152 }
 153
 154 float spawnpoint_nag;
 155 void relocate_spawnpoint()
 156 {
 157     // nudge off the floor
 158     setorigin(self, self.origin + '0 0 1');
 159
 160     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 161     if (trace_startsolid)
 162     {
 163         vector o;
 164         o = self.origin;
 165         self.mins = PL_MIN;
 166         self.maxs = PL_MAX;
 167         if (!move_out_of_solid(self))
 168             objerror("could not get out of solid at all!");
 169         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 170         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 171         print(" ", ftos(self.origin_y - o_y));
 172         print(" ", ftos(self.origin_z - o_z), "'\n");
 173         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
 174         {
 175             if (!spawnpoint_nag)
 176                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 177             spawnpoint_nag = 1;
 178         }
 179         else
 180         {
 181             setorigin(self, o);
 182             self.mins = self.maxs = '0 0 0';
 183             objerror("player spawn point in solid, mapper sucks!\n");
 184             return;
 185         }
 186     }
 187
 188     self.use = spawnpoint_use;
 189     self.team_saved = self.team;
 190     if (!self.cnt)
 191         self.cnt = 1;
 192
 193     if (have_team_spawns != 0)
 194         if (self.team)
 195             have_team_spawns = 1;
 196     have_team_spawns_forteam[self.team] = 1;
 197
 198     if (autocvar_r_showbboxes)
 199     {
 200         // show where spawnpoints point at too
 201         makevectors(self.angles);
 202         entity e;
 203         e = spawn();
 204         e.classname = "info_player_foo";
 205         setorigin(e, self.origin + v_forward * 24);
 206         setsize(e, '-8 -8 -8', '8 8 8');
 207         e.solid = SOLID_TRIGGER;
 208     }
 209 }
 210
 211 #define strstr strstrofs
 212 /*
 213 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 214 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 215 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 216 // BE CONSTANT OR strzoneD!
 217 float strstr(string haystack, string needle, float offset)
 218 {
 219         float len, endpos;
 220         string found;
 221         len = strlen(needle);
 222         endpos = strlen(haystack) - len;
 223         while(offset <= endpos)
 224         {
 225                 found = substring(haystack, offset, len);
 226                 if(found == needle)
 227                         return offset;
 228                 offset = offset + 1;
 229         }
 230         return -1;
 231 }
 232 */
 233
 234 float NUM_NEAREST_ENTITIES = 4;
 235 entity nearest_entity[NUM_NEAREST_ENTITIES];
 236 float nearest_length[NUM_NEAREST_ENTITIES];
 237 entity findnearest(vector point, .string field, string value, vector axismod)
 238 {
 239     entity localhead;
 240     float i;
 241     float j;
 242     float len;
 243     vector dist;
 244
 245     float num_nearest;
 246     num_nearest = 0;
 247
 248     localhead = find(world, field, value);
 249     while (localhead)
 250     {
 251         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 252             dist = localhead.oldorigin;
 253         else
 254             dist = localhead.origin;
 255         dist = dist - point;
 256         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 257         len = vlen(dist);
 258
 259         for (i = 0; i < num_nearest; ++i)
 260         {
 261             if (len < nearest_length[i])
 262                 break;
 263         }
 264
 265         // now i tells us where to insert at
 266         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 267         if (i < NUM_NEAREST_ENTITIES)
 268         {
 269             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 270             {
 271                 nearest_length[j + 1] = nearest_length[j];
 272                 nearest_entity[j + 1] = nearest_entity[j];
 273             }
 274             nearest_length[i] = len;
 275             nearest_entity[i] = localhead;
 276             if (num_nearest < NUM_NEAREST_ENTITIES)
 277                 num_nearest = num_nearest + 1;
 278         }
 279
 280         localhead = find(localhead, field, value);
 281     }
 282
 283     // now use the first one from our list that we can see
 284     for (i = 0; i < num_nearest; ++i)
 285     {
 286         traceline(point, nearest_entity[i].origin, TRUE, world);
 287         if (trace_fraction == 1)
 288         {
 289             if (i != 0)
 290             {
 291                 dprint("Nearest point (");
 292                 dprint(nearest_entity[0].netname);
 293                 dprint(") is not visible, using a visible one.\n");
 294             }
 295             return nearest_entity[i];
 296         }
 297     }
 298
 299     if (num_nearest == 0)
 300         return world;
 301
 302     dprint("Not seeing any location point, using nearest as fallback.\n");
 303     /* DEBUGGING CODE:
 304     dprint("Candidates were: ");
 305     for(j = 0; j < num_nearest; ++j)
 306     {
 307         if(j != 0)
 308                 dprint(", ");
 309         dprint(nearest_entity[j].netname);
 310     }
 311     dprint("\n");
 312     */
 313
 314     return nearest_entity[0];
 315 }
 316
 317 void spawnfunc_target_location()
 318 {
 319     self.classname = "target_location";
 320     // location name in netname
 321     // eventually support: count, teamgame selectors, line of sight?
 322 }
 323
 324 void spawnfunc_info_location()
 325 {
 326     self.classname = "target_location";
 327     self.message = self.netname;
 328 }
 329
 330 string NearestLocation(vector p)
 331 {
 332     entity loc;
 333     string ret;
 334     ret = "somewhere";
 335     loc = findnearest(p, classname, "target_location", '1 1 1');
 336     if (loc)
 337     {
 338         ret = loc.message;
 339     }
 340     else
 341     {
 342         loc = findnearest(p, target, "###item###", '1 1 4');
 343         if (loc)
 344             ret = loc.netname;
 345     }
 346     return ret;
 347 }
 348
 349 string formatmessage(string msg)
 350 {
 351         float p, p1, p2;
 352         float n;
 353         vector cursor;
 354         entity cursor_ent;
 355         string escape;
 356         string replacement;
 357         p = 0;
 358         n = 7;
 359
 360         WarpZone_crosshair_trace(self);
 361         cursor = trace_endpos;
 362         cursor_ent = trace_ent;
 363
 364         while (1) {
 365                 if (n < 1)
 366                         break; // too many replacements
 367
 368                 n = n - 1;
 369                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 370                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 371
 372                 if (p1 < 0)
 373                         p1 = p2;
 374
 375                 if (p2 < 0)
 376                         p2 = p1;
 377
 378                 p = min(p1, p2);
 379
 380                 if (p < 0)
 381                         break;
 382
 383                 replacement = substring(msg, p, 2);
 384                 escape = substring(msg, p + 1, 1);
 385
 386                 if (escape == "%")
 387                         replacement = "%";
 388                 else if (escape == "\\")
 389                         replacement = "\\";
 390                 else if (escape == "n")
 391                         replacement = "\n";
 392                 else if (escape == "a")
 393                         replacement = ftos(floor(self.armorvalue));
 394                 else if (escape == "h")
 395                         replacement = ftos(floor(self.health));
 396                 else if (escape == "l")
 397                         replacement = NearestLocation(self.origin);
 398                 else if (escape == "y")
 399                         replacement = NearestLocation(cursor);
 400                 else if (escape == "d")
 401                         replacement = NearestLocation(self.death_origin);
 402                 else if (escape == "w") {
 403                         float wep;
 404                         wep = self.weapon;
 405                         if (!wep)
 406                                 wep = self.switchweapon;
 407                         if (!wep)
 408                                 wep = self.cnt;
 409                         replacement = W_Name(wep);
 410                 } else if (escape == "W") {
 411                         if (self.items & IT_SHELLS) replacement = "shells";
 412                         else if (self.items & IT_NAILS) replacement = "bullets";
 413                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 414                         else if (self.items & IT_CELLS) replacement = "cells";
 415                         else replacement = "batteries"; // ;)
 416                 } else if (escape == "x") {
 417                         replacement = cursor_ent.netname;
 418                         if (!replacement || !cursor_ent)
 419                                 replacement = "nothing";
 420                 } else if (escape == "s")
 421                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 422                 else if (escape == "S")
 423                         replacement = ftos(vlen(self.velocity));
 424
 425                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 426                 p = p + strlen(replacement);
 427         }
 428         return msg;
 429 }
 430
 431 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 432         return (value == 0) ? FALSE : TRUE;
 433 }
 434
 435 /*
 436 =============
 437 GetCvars
 438 =============
 439 Called with:
 440   0:  sends the request
 441   >0: receives a cvar from name=argv(f) value=argv(f+1)
 442 */
 443 void GetCvars_handleString(string thisname, float f, .string field, string name)
 444 {
 445         if (f < 0)
 446         {
 447                 if (self.field)
 448                         strunzone(self.field);
 449                 self.field = string_null;
 450         }
 451         else if (f > 0)
 452         {
 453                 if (thisname == name)
 454                 {
 455                         if (self.field)
 456                                 strunzone(self.field);
 457                         self.field = strzone(argv(f + 1));
 458                 }
 459         }
 460         else
 461                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 462 }
 463 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 464 {
 465         GetCvars_handleString(thisname, f, field, name);
 466         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 467                 if (thisname == name)
 468                 {
 469                         string s;
 470                         s = func(strcat1(self.field));
 471                         if (s != self.field)
 472                         {
 473                                 strunzone(self.field);
 474                                 self.field = strzone(s);
 475                         }
 476                 }
 477 }
 478 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 479 {
 480         if (f < 0)
 481         {
 482         }
 483         else if (f > 0)
 484         {
 485                 if (thisname == name)
 486                         self.field = stof(argv(f + 1));
 487         }
 488         else
 489                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 490 }
 491 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 492 {
 493         if (f < 0)
 494         {
 495         }
 496         else if (f > 0)
 497         {
 498                 if (thisname == name)
 499                 {
 500                         if(!self.field)
 501                         {
 502                                 self.field = stof(argv(f + 1));
 503                                 if(!self.field)
 504                                         self.field = -1;
 505                         }
 506                 }
 507         }
 508         else
 509         {
 510                 if(!self.field)
 511                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 512         }
 513 }
 514 float w_getbestweapon(entity e);
 515 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 516 {
 517         string o;
 518         o = W_FixWeaponOrder_ForceComplete(wo);
 519         if(self.weaponorder_byimpulse)
 520         {
 521                 strunzone(self.weaponorder_byimpulse);
 522                 self.weaponorder_byimpulse = string_null;
 523         }
 524         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 525         return o;
 526 }
 527 void GetCvars(float f)
 528 {
 529         string s;
 530
 531         if (f > 0)
 532                 s = strcat1(argv(f));
 533
 534         get_cvars_f = f;
 535         get_cvars_s = s;
 536         MUTATOR_CALLHOOK(GetCvars);
 537         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 538         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 539         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 540         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 541         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 542         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 543         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 544         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 545         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 546         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 547         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 548         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 549         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 550         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 551         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 552         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 553         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 554         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 555         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 556         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 557         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 558         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 559         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 560
 561         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 562         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 563
 564 #ifdef ALLOW_FORCEMODELS
 565         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
 566         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
 567 #endif
 568         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 569         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 570         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 571         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 572         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 573
 574         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 575         if (f > 0)
 576         {
 577                 if (s == "cl_weaponpriority")
 578                         self.switchweapon = w_getbestweapon(self);
 579                 if (s == "cl_allow_uidtracking")
 580                         PlayerStats_AddPlayer(self);
 581         }
 582 }
 583
 584 void backtrace(string msg)
 585 {
 586     float dev, war;
 587     dev = autocvar_developer;
 588     war = autocvar_prvm_backtraceforwarnings;
 589     cvar_set("developer", "1");
 590     cvar_set("prvm_backtraceforwarnings", "1");
 591     print("\n");
 592     print("--- CUT HERE ---\nWARNING: ");
 593     print(msg);
 594     print("\n");
 595     remove(world); // isn't there any better way to cause a backtrace?
 596     print("\n--- CUT UNTIL HERE ---\n");
 597     cvar_set("developer", ftos(dev));
 598     cvar_set("prvm_backtraceforwarnings", ftos(war));
 599 }
 600
 601 string Team_ColorCode(float teamid)
 602 {
 603     if (teamid == COLOR_TEAM1)
 604         return "^1";
 605     else if (teamid == COLOR_TEAM2)
 606         return "^4";
 607     else if (teamid == COLOR_TEAM3)
 608         return "^3";
 609     else if (teamid == COLOR_TEAM4)
 610         return "^6";
 611     else
 612         return "^7";
 613 }
 614
 615 string Team_ColorName(float t)
 616 {
 617     // fixme: Search for team entities and get their .netname's!
 618     if (t == COLOR_TEAM1)
 619         return "Red";
 620     if (t == COLOR_TEAM2)
 621         return "Blue";
 622     if (t == COLOR_TEAM3)
 623         return "Yellow";
 624     if (t == COLOR_TEAM4)
 625         return "Pink";
 626     return "Neutral";
 627 }
 628
 629 string Team_ColorNameLowerCase(float t)
 630 {
 631     // fixme: Search for team entities and get their .netname's!
 632     if (t == COLOR_TEAM1)
 633         return "red";
 634     if (t == COLOR_TEAM2)
 635         return "blue";
 636     if (t == COLOR_TEAM3)
 637         return "yellow";
 638     if (t == COLOR_TEAM4)
 639         return "pink";
 640     return "neutral";
 641 }
 642
 643 float ColourToNumber(string team_colour)
 644 {
 645         if (team_colour == "red")
 646                 return COLOR_TEAM1;
 647
 648         if (team_colour == "blue")
 649                 return COLOR_TEAM2;
 650
 651         if (team_colour == "yellow")
 652                 return COLOR_TEAM3;
 653
 654         if (team_colour == "pink")
 655                 return COLOR_TEAM4;
 656
 657         if (team_colour == "auto")
 658                 return 0;
 659
 660         return -1;
 661 }
 662
 663 float NumberToTeamNumber(float number)
 664 {
 665         if (number == 1)
 666                 return COLOR_TEAM1;
 667
 668         if (number == 2)
 669                 return COLOR_TEAM2;
 670
 671         if (number == 3)
 672                 return COLOR_TEAM3;
 673
 674         if (number == 4)
 675                 return COLOR_TEAM4;
 676
 677         return -1;
 678 }
 679
 680 // decolorizes and team colors the player name when needed
 681 string playername(entity p)
 682 {
 683     string t;
 684     if (teamplay && !intermission_running && p.classname == "player")
 685     {
 686         t = Team_ColorCode(p.team);
 687         return strcat(t, strdecolorize(p.netname));
 688     }
 689     else
 690         return p.netname;
 691 }
 692
 693 vector randompos(vector m1, vector m2)
 694 {
 695     vector v;
 696     m2 = m2 - m1;
 697     v_x = m2_x * random() + m1_x;
 698     v_y = m2_y * random() + m1_y;
 699     v_z = m2_z * random() + m1_z;
 700     return  v;
 701 }
 702
 703 //#NO AUTOCVARS START
 704
 705 float g_pickup_shells;
 706 float g_pickup_shells_max;
 707 float g_pickup_nails;
 708 float g_pickup_nails_max;
 709 float g_pickup_rockets;
 710 float g_pickup_rockets_max;
 711 float g_pickup_cells;
 712 float g_pickup_cells_max;
 713 float g_pickup_fuel;
 714 float g_pickup_fuel_jetpack;
 715 float g_pickup_fuel_max;
 716 float g_pickup_armorsmall;
 717 float g_pickup_armorsmall_max;
 718 float g_pickup_armorsmall_anyway;
 719 float g_pickup_armormedium;
 720 float g_pickup_armormedium_max;
 721 float g_pickup_armormedium_anyway;
 722 float g_pickup_armorbig;
 723 float g_pickup_armorbig_max;
 724 float g_pickup_armorbig_anyway;
 725 float g_pickup_armorlarge;
 726 float g_pickup_armorlarge_max;
 727 float g_pickup_armorlarge_anyway;
 728 float g_pickup_healthsmall;
 729 float g_pickup_healthsmall_max;
 730 float g_pickup_healthsmall_anyway;
 731 float g_pickup_healthmedium;
 732 float g_pickup_healthmedium_max;
 733 float g_pickup_healthmedium_anyway;
 734 float g_pickup_healthlarge;
 735 float g_pickup_healthlarge_max;
 736 float g_pickup_healthlarge_anyway;
 737 float g_pickup_healthmega;
 738 float g_pickup_healthmega_max;
 739 float g_pickup_healthmega_anyway;
 740 float g_pickup_ammo_anyway;
 741 float g_pickup_weapons_anyway;
 742 float g_weaponarena;
 743 WEPSET_DECLARE_A(g_weaponarena_weapons);
 744 float g_weaponarena_random;
 745 float g_weaponarena_random_with_laser;
 746 string g_weaponarena_list;
 747 float g_weaponspeedfactor;
 748 float g_weaponratefactor;
 749 float g_weapondamagefactor;
 750 float g_weaponforcefactor;
 751 float g_weaponspreadfactor;
 752
 753 WEPSET_DECLARE_A(start_weapons);
 754 WEPSET_DECLARE_A(start_weapons_default);
 755 WEPSET_DECLARE_A(start_weapons_defaultmask);
 756 float start_items;
 757 float start_ammo_shells;
 758 float start_ammo_nails;
 759 float start_ammo_rockets;
 760 float start_ammo_cells;
 761 float start_ammo_fuel;
 762 float start_health;
 763 float start_armorvalue;
 764 WEPSET_DECLARE_A(warmup_start_weapons);
 765 WEPSET_DECLARE_A(warmup_start_weapons_default);
 766 WEPSET_DECLARE_A(warmup_start_weapons_defaultmask);
 767 float warmup_start_ammo_shells;
 768 float warmup_start_ammo_nails;
 769 float warmup_start_ammo_rockets;
 770 float warmup_start_ammo_cells;
 771 float warmup_start_ammo_fuel;
 772 float warmup_start_health;
 773 float warmup_start_armorvalue;
 774 float g_weapon_stay;
 775 float g_ghost_items;
 776
 777 entity get_weaponinfo(float w);
 778
 779 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 780 {
 781         var float i = weaponinfo.weapon;
 782         var float d = 0;
 783
 784         if (!i)
 785                 return 0;
 786
 787         if (g_lms || g_ca || allguns)
 788                 d = (weaponinfo.spawnflags & WEP_FLAG_NORMAL);
 789         else if (g_cts)
 790                 d = (i == WEP_SHOTGUN);
 791         else if (g_nexball)
 792                 d = 0; // weapon is set a few lines later
 793         else
 794                 d = (i == WEP_LASER || i == WEP_SHOTGUN);
 795         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 796                 d |= (i == WEP_HOOK);
 797         if(weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED) // never default mutator blocked guns
 798                 d = 0;
 799
 800         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 801
 802         // bit order in t:
 803         // 1: want or not
 804         // 2: is default?
 805         // 4: is set by default?
 806         if(t < 0)
 807                 t = 4 | (3 * d);
 808         else
 809                 t |= (2 * d);
 810
 811         return t;
 812 }
 813
 814 void readplayerstartcvars()
 815 {
 816         entity e;
 817         float i, j, t;
 818         string s;
 819
 820         // initialize starting values for players
 821         WEPSET_CLEAR_A(start_weapons);
 822         WEPSET_CLEAR_A(start_weapons_default);
 823         WEPSET_CLEAR_A(start_weapons_defaultmask);
 824         start_items = 0;
 825         start_ammo_shells = 0;
 826         start_ammo_nails = 0;
 827         start_ammo_rockets = 0;
 828         start_ammo_cells = 0;
 829         start_health = cvar("g_balance_health_start");
 830         start_armorvalue = cvar("g_balance_armor_start");
 831
 832         g_weaponarena = 0;
 833         WEPSET_CLEAR_A(g_weaponarena_weapons);
 834
 835         s = cvar_string("g_weaponarena");
 836         if (s == "0" || s == "")
 837         {
 838                 if(g_lms || g_ca)
 839                         s = "most";
 840         }
 841
 842         if (s == "0" || s == "")
 843         {
 844                 // no arena
 845         }
 846         else if (s == "off")
 847         {
 848                 // forcibly turn off weaponarena
 849         }
 850         else if (s == "all")
 851         {
 852                 g_weaponarena = 1;
 853                 g_weaponarena_list = "All Weapons";
 854                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 855                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 856                                 WEPSET_OR_AW(g_weaponarena_weapons, j);
 857         }
 858         else if (s == "most")
 859         {
 860                 g_weaponarena = 1;
 861                 g_weaponarena_list = "Most Weapons";
 862                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 863                 {
 864                         e = get_weaponinfo(j);
 865                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 866                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 867                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 868                 }
 869         }
 870         else if (s == "none")
 871         {
 872                 g_weaponarena = 1;
 873                 g_weaponarena_list = "No Weapons";
 874         }
 875         else
 876         {
 877                 g_weaponarena = 1;
 878                 t = tokenize_console(s);
 879                 g_weaponarena_list = "";
 880                 for (i = 0; i < t; ++i)
 881                 {
 882                         s = argv(i);
 883                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 884                         {
 885                                 e = get_weaponinfo(j);
 886                                 if (e.netname == s)
 887                                 {
 888                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 889                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 890                                         break;
 891                                 }
 892                         }
 893                         if (j > WEP_LAST)
 894                         {
 895                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 896                         }
 897                 }
 898                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 899         }
 900
 901         if(g_weaponarena)
 902                 g_weaponarena_random = cvar("g_weaponarena_random");
 903         else
 904                 g_weaponarena_random = 0;
 905         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 906
 907         if (g_weaponarena)
 908         {
 909                 g_minstagib = 0; // incompatible
 910                 g_pinata = 0; // incompatible
 911                 g_weapon_stay = 0; // incompatible
 912                 WEPSET_COPY_AA(start_weapons, g_weaponarena_weapons);
 913                 if(!(g_lms || g_ca))
 914                         start_items |= IT_UNLIMITED_AMMO;
 915         }
 916         else if (g_minstagib)
 917         {
 918                 g_pinata = 0; // incompatible
 919                 g_weapon_stay = 0; // incompatible
 920                 g_bloodloss = 0; // incompatible
 921                 start_health = 100;
 922                 start_armorvalue = 0;
 923                 WEPSET_COPY_AW(start_weapons, WEP_MINSTANEX);
 924                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 925                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
 926
 927                 if (g_minstagib_invis_alpha <= 0)
 928                         g_minstagib_invis_alpha = -1;
 929         }
 930         else
 931         {
 932                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 933                 {
 934                         e = get_weaponinfo(i);
 935                         float w = want_weapon("g_start_weapon_", e, FALSE);
 936                         if(w & 1)
 937                                 WEPSET_OR_AW(start_weapons, i);
 938                         if(w & 2)
 939                                 WEPSET_OR_AW(start_weapons_default, i);
 940                         if(w & 4)
 941                                 WEPSET_OR_AW(start_weapons_defaultmask, i);
 942                 }
 943         }
 944
 945         if(!cvar("g_use_ammunition"))
 946                 start_items |= IT_UNLIMITED_AMMO;
 947
 948         if(cvar("g_nexball"))
 949                 start_items |= IT_UNLIMITED_SUPERWEAPONS; // FIXME BAD BAD BAD BAD HACK, NEXBALL SHOULDN'T ABUSE PORTO'S WEAPON SLOT
 950
 951         if(g_minstagib)
 952         {
 953                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 954                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 955         }
 956         else if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 957         {
 958                 start_ammo_rockets = 999;
 959                 start_ammo_shells = 999;
 960                 start_ammo_cells = 999;
 961                 start_ammo_nails = 999;
 962                 start_ammo_fuel = 999;
 963         }
 964         else
 965         {
 966                 if(g_lms || g_ca)
 967                 {
 968                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 969                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 970                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 971                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 972                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
 973                 }
 974                 else
 975                 {
 976                         start_ammo_shells = cvar("g_start_ammo_shells");
 977                         start_ammo_nails = cvar("g_start_ammo_nails");
 978                         start_ammo_rockets = cvar("g_start_ammo_rockets");
 979                         start_ammo_cells = cvar("g_start_ammo_cells");
 980                         start_ammo_fuel = cvar("g_start_ammo_fuel");
 981                 }
 982         }
 983
 984         if (g_lms || g_ca)
 985         {
 986                 start_health = cvar("g_lms_start_health");
 987                 start_armorvalue = cvar("g_lms_start_armor");
 988         }
 989
 990         if (inWarmupStage)
 991         {
 992                 warmup_start_ammo_shells = start_ammo_shells;
 993                 warmup_start_ammo_nails = start_ammo_nails;
 994                 warmup_start_ammo_rockets = start_ammo_rockets;
 995                 warmup_start_ammo_cells = start_ammo_cells;
 996                 warmup_start_ammo_fuel = start_ammo_fuel;
 997                 warmup_start_health = start_health;
 998                 warmup_start_armorvalue = start_armorvalue;
 999                 WEPSET_COPY_AA(warmup_start_weapons, start_weapons);
1000                 WEPSET_COPY_AA(warmup_start_weapons_default, start_weapons_default);
1001                 WEPSET_COPY_AA(warmup_start_weapons_defaultmask, start_weapons_defaultmask);
1002
1003                 if (!g_weaponarena && !g_minstagib && !g_ca)
1004                 {
1005                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
1006                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
1007                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
1008                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
1009                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
1010                         warmup_start_health = cvar("g_warmup_start_health");
1011                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
1012                         WEPSET_CLEAR_A(warmup_start_weapons);
1013                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1014                         {
1015                                 e = get_weaponinfo(i);
1016                                 float w = want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns"));
1017                                 if(w & 1)
1018                                         WEPSET_OR_AW(warmup_start_weapons, i);
1019                                 if(w & 2)
1020                                         WEPSET_OR_AW(warmup_start_weapons_default, i);
1021                                 if(w & 4)
1022                                         WEPSET_OR_AW(warmup_start_weapons_defaultmask, i);
1023                         }
1024                 }
1025         }
1026
1027         if (g_jetpack)
1028                 start_items |= IT_JETPACK;
1029
1030         MUTATOR_CALLHOOK(SetStartItems);
1031
1032         if ((start_items & IT_JETPACK) || (g_grappling_hook && WEPSET_CONTAINS_AW(start_weapons, WEP_HOOK)))
1033         {
1034                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1035                 start_items |= IT_FUEL_REGEN;
1036                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1037                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1038         }
1039
1040         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1041         {
1042                 e = get_weaponinfo(i);
1043                 if(WEPSET_CONTAINS_AW(start_weapons, i) || WEPSET_CONTAINS_AW(warmup_start_weapons, i))
1044                         weapon_action(i, WR_PRECACHE);
1045         }
1046
1047         start_ammo_shells = max(0, start_ammo_shells);
1048         start_ammo_nails = max(0, start_ammo_nails);
1049         start_ammo_cells = max(0, start_ammo_cells);
1050         start_ammo_rockets = max(0, start_ammo_rockets);
1051         start_ammo_fuel = max(0, start_ammo_fuel);
1052
1053         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1054         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1055         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1056         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1057         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1058 }
1059
1060 float g_bugrigs;
1061 float g_bugrigs_planar_movement;
1062 float g_bugrigs_planar_movement_car_jumping;
1063 float g_bugrigs_reverse_spinning;
1064 float g_bugrigs_reverse_speeding;
1065 float g_bugrigs_reverse_stopping;
1066 float g_bugrigs_air_steering;
1067 float g_bugrigs_angle_smoothing;
1068 float g_bugrigs_friction_floor;
1069 float g_bugrigs_friction_brake;
1070 float g_bugrigs_friction_air;
1071 float g_bugrigs_accel;
1072 float g_bugrigs_speed_ref;
1073 float g_bugrigs_speed_pow;
1074 float g_bugrigs_steer;
1075
1076 float g_touchexplode;
1077 float g_touchexplode_radius;
1078 float g_touchexplode_damage;
1079 float g_touchexplode_edgedamage;
1080 float g_touchexplode_force;
1081
1082 float sv_autotaunt;
1083 float sv_taunt;
1084
1085 float sv_pitch_min;
1086 float sv_pitch_max;
1087 float sv_pitch_fixyaw;
1088
1089 string GetGametype(); // g_world.qc
1090 void readlevelcvars(void)
1091 {
1092         g_minstagib = cvar("g_minstagib");
1093
1094         // load ALL the mutators
1095         if(cvar("g_dodging"))
1096                 MUTATOR_ADD(mutator_dodging);
1097         if(cvar("g_spawn_near_teammate"))
1098                 MUTATOR_ADD(mutator_spawn_near_teammate);
1099         if(!g_minstagib)
1100         {
1101                 if(cvar("g_invincible_projectiles"))
1102                         MUTATOR_ADD(mutator_invincibleprojectiles);
1103                 if(cvar("g_new_toys"))
1104                         MUTATOR_ADD(mutator_new_toys);
1105                 if(cvar("g_nix"))
1106                         MUTATOR_ADD(mutator_nix);
1107                 if(cvar("g_rocket_flying"))
1108                         MUTATOR_ADD(mutator_rocketflying);
1109                 if(cvar("g_vampire"))
1110                         MUTATOR_ADD(mutator_vampire);
1111         }
1112
1113         // is this a mutator? is this a mode?
1114         if(cvar("g_sandbox"))
1115                 MUTATOR_ADD(sandbox);
1116
1117         if(cvar("sv_allow_fullbright"))
1118                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1119
1120     g_bugrigs = cvar("g_bugrigs");
1121     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1122     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1123     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1124     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1125     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1126     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1127     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1128     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1129     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1130     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1131     g_bugrigs_accel = cvar("g_bugrigs_accel");
1132     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1133     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1134     g_bugrigs_steer = cvar("g_bugrigs_steer");
1135
1136     g_touchexplode = cvar("g_touchexplode");
1137     g_touchexplode_radius = cvar("g_touchexplode_radius");
1138     g_touchexplode_damage = cvar("g_touchexplode_damage");
1139     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1140     g_touchexplode_force = cvar("g_touchexplode_force");
1141
1142 #ifdef ALLOW_FORCEMODELS
1143         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1144 #endif
1145
1146         sv_clones = cvar("sv_clones");
1147         sv_gentle = cvar("sv_gentle");
1148         sv_foginterval = cvar("sv_foginterval");
1149         g_cloaked = cvar("g_cloaked");
1150     if(g_cts)
1151         g_cloaked = 1; // always enable cloak in CTS
1152         g_jump_grunt = cvar("g_jump_grunt");
1153         g_footsteps = cvar("g_footsteps");
1154         g_grappling_hook = cvar("g_grappling_hook");
1155         g_jetpack = cvar("g_jetpack");
1156         g_midair = cvar("g_midair");
1157         g_norecoil = cvar("g_norecoil");
1158         g_bloodloss = cvar("g_bloodloss");
1159         sv_maxidle = cvar("sv_maxidle");
1160         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1161         g_ctf_reverse = cvar("g_ctf_reverse");
1162         sv_autotaunt = cvar("sv_autotaunt");
1163         sv_taunt = cvar("sv_taunt");
1164
1165         inWarmupStage = cvar("g_warmup");
1166         g_warmup_limit = cvar("g_warmup_limit");
1167         g_warmup_allguns = cvar("g_warmup_allguns");
1168         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1169
1170         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1171                 inWarmupStage = 0; // these modes cannot work together, sorry
1172
1173         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1174         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
1175         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1176         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1177         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1178         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1179         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1180         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1181         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
1182         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1183         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1184         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1185         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1186         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1187
1188         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1189         g_weaponratefactor = cvar("g_weaponratefactor");
1190         g_weapondamagefactor = cvar("g_weapondamagefactor");
1191         g_weaponforcefactor = cvar("g_weaponforcefactor");
1192         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1193
1194         g_pickup_shells = cvar("g_pickup_shells");
1195         g_pickup_shells_max = cvar("g_pickup_shells_max");
1196         g_pickup_nails = cvar("g_pickup_nails");
1197         g_pickup_nails_max = cvar("g_pickup_nails_max");
1198         g_pickup_rockets = cvar("g_pickup_rockets");
1199         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1200         g_pickup_cells = cvar("g_pickup_cells");
1201         g_pickup_cells_max = cvar("g_pickup_cells_max");
1202         g_pickup_fuel = cvar("g_pickup_fuel");
1203         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1204         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1205         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1206         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1207         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1208         g_pickup_armormedium = cvar("g_pickup_armormedium");
1209         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1210         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1211         g_pickup_armorbig = cvar("g_pickup_armorbig");
1212         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1213         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1214         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1215         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1216         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1217         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1218         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1219         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1220         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1221         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1222         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1223         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1224         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1225         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1226         g_pickup_healthmega = cvar("g_pickup_healthmega");
1227         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1228         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1229
1230         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1231         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1232
1233         g_pinata = cvar("g_pinata");
1234
1235     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1236     if(!g_weapon_stay)
1237         g_weapon_stay = cvar("g_weapon_stay");
1238
1239         g_ghost_items = cvar("g_ghost_items");
1240
1241         if(g_ghost_items >= 1)
1242                 g_ghost_items = 0.25; // default alpha value
1243
1244         if not(inWarmupStage && !g_ca)
1245                 game_starttime = cvar("g_start_delay");
1246
1247         sv_pitch_min = cvar("sv_pitch_min");
1248         sv_pitch_max = cvar("sv_pitch_max");
1249         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1250
1251         readplayerstartcvars();
1252 }
1253
1254 //#NO AUTOCVARS END
1255
1256 // Sound functions
1257 string precache_sound (string s) = #19;
1258 float precache_sound_index (string s) = #19;
1259
1260 #define SND_VOLUME      1
1261 #define SND_ATTENUATION 2
1262 #define SND_LARGEENTITY 8
1263 #define SND_LARGESOUND  16
1264
1265 float sound_allowed(float dest, entity e)
1266 {
1267     // sounds from world may always pass
1268     for (;;)
1269     {
1270         if (e.classname == "body")
1271             e = e.enemy;
1272         else if (e.realowner && e.realowner != e)
1273             e = e.realowner;
1274         else if (e.owner && e.owner != e)
1275             e = e.owner;
1276         else
1277             break;
1278     }
1279     // sounds to self may always pass
1280     if (dest == MSG_ONE)
1281         if (e == msg_entity)
1282             return TRUE;
1283     // sounds by players can be removed
1284     if (autocvar_bot_sound_monopoly)
1285         if (clienttype(e) == CLIENTTYPE_REAL)
1286             return FALSE;
1287     // anything else may pass
1288     return TRUE;
1289 }
1290
1291 #ifdef COMPAT_XON010_CHANNELS
1292 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1293 void sound(entity e, float chan, string samp, float vol, float atten)
1294 {
1295     if (!sound_allowed(MSG_BROADCAST, e))
1296         return;
1297     builtin_sound(e, chan, samp, vol, atten);
1298 }
1299 #else
1300 #undef sound
1301 void sound(entity e, float chan, string samp, float vol, float atten)
1302 {
1303     if (!sound_allowed(MSG_BROADCAST, e))
1304         return;
1305     sound7(e, chan, samp, vol, atten, 0, 0);
1306 }
1307 #endif
1308
1309 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1310 {
1311     float entno, idx;
1312
1313     if (!sound_allowed(dest, e))
1314         return;
1315
1316     entno = num_for_edict(e);
1317     idx = precache_sound_index(samp);
1318
1319     float sflags;
1320     sflags = 0;
1321
1322     atten = floor(atten * 64);
1323     vol = floor(vol * 255);
1324
1325     if (vol != 255)
1326         sflags |= SND_VOLUME;
1327     if (atten != 64)
1328         sflags |= SND_ATTENUATION;
1329     if (entno >= 8192 || chan < 0 || chan > 7)
1330         sflags |= SND_LARGEENTITY;
1331     if (idx >= 256)
1332         sflags |= SND_LARGESOUND;
1333
1334     WriteByte(dest, SVC_SOUND);
1335     WriteByte(dest, sflags);
1336     if (sflags & SND_VOLUME)
1337         WriteByte(dest, vol);
1338     if (sflags & SND_ATTENUATION)
1339         WriteByte(dest, atten);
1340     if (sflags & SND_LARGEENTITY)
1341     {
1342         WriteShort(dest, entno);
1343         WriteByte(dest, chan);
1344     }
1345     else
1346     {
1347         WriteShort(dest, entno * 8 + chan);
1348     }
1349     if (sflags & SND_LARGESOUND)
1350         WriteShort(dest, idx);
1351     else
1352         WriteByte(dest, idx);
1353
1354     WriteCoord(dest, o_x);
1355     WriteCoord(dest, o_y);
1356     WriteCoord(dest, o_z);
1357 }
1358 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1359 {
1360     vector o;
1361
1362     if (!sound_allowed(dest, e))
1363         return;
1364
1365     o = e.origin + 0.5 * (e.mins + e.maxs);
1366     soundtoat(dest, e, o, chan, samp, vol, atten);
1367 }
1368 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1369 {
1370     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1371 }
1372 void stopsoundto(float dest, entity e, float chan)
1373 {
1374     float entno;
1375
1376     if (!sound_allowed(dest, e))
1377         return;
1378
1379     entno = num_for_edict(e);
1380
1381     if (entno >= 8192 || chan < 0 || chan > 7)
1382     {
1383         float idx, sflags;
1384         idx = precache_sound_index("misc/null.wav");
1385         sflags = SND_LARGEENTITY;
1386         if (idx >= 256)
1387             sflags |= SND_LARGESOUND;
1388         WriteByte(dest, SVC_SOUND);
1389         WriteByte(dest, sflags);
1390         WriteShort(dest, entno);
1391         WriteByte(dest, chan);
1392         if (sflags & SND_LARGESOUND)
1393             WriteShort(dest, idx);
1394         else
1395             WriteByte(dest, idx);
1396         WriteCoord(dest, e.origin_x);
1397         WriteCoord(dest, e.origin_y);
1398         WriteCoord(dest, e.origin_z);
1399     }
1400     else
1401     {
1402         WriteByte(dest, SVC_STOPSOUND);
1403         WriteShort(dest, entno * 8 + chan);
1404     }
1405 }
1406 void stopsound(entity e, float chan)
1407 {
1408     if (!sound_allowed(MSG_BROADCAST, e))
1409         return;
1410
1411     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1412     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1413 }
1414
1415 void play2(entity e, string filename)
1416 {
1417     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1418     msg_entity = e;
1419     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1420 }
1421
1422 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1423 .float spamtime;
1424 float spamsound(entity e, float chan, string samp, float vol, float atten)
1425 {
1426     if (!sound_allowed(MSG_BROADCAST, e))
1427         return FALSE;
1428
1429     if (time > e.spamtime)
1430     {
1431         e.spamtime = time;
1432         sound(e, chan, samp, vol, atten);
1433         return TRUE;
1434     }
1435     return FALSE;
1436 }
1437
1438 void play2team(float t, string filename)
1439 {
1440     entity head;
1441
1442     if (autocvar_bot_sound_monopoly)
1443         return;
1444
1445     FOR_EACH_REALPLAYER(head)
1446     {
1447         if (head.team == t)
1448             play2(head, filename);
1449     }
1450 }
1451
1452 void play2all(string samp)
1453 {
1454     if (autocvar_bot_sound_monopoly)
1455         return;
1456
1457     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1458 }
1459
1460 void PrecachePlayerSounds(string f);
1461 void precache_playermodel(string m)
1462 {
1463         float globhandle, i, n;
1464         string f;
1465
1466         if(substring(m, -9,5) == "_lod1")
1467                 return;
1468         if(substring(m, -9,5) == "_lod2")
1469                 return;
1470         precache_model(m);
1471         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1472         if(fexists(f))
1473                 precache_model(f);
1474         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1475         if(fexists(f))
1476                 precache_model(f);
1477
1478         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1479         if (globhandle < 0)
1480                 return;
1481         n = search_getsize(globhandle);
1482         for (i = 0; i < n; ++i)
1483         {
1484                 //print(search_getfilename(globhandle, i), "\n");
1485                 f = search_getfilename(globhandle, i);
1486                 PrecachePlayerSounds(f);
1487         }
1488         search_end(globhandle);
1489 }
1490 void precache_all_playermodels(string pattern)
1491 {
1492         float globhandle, i, n;
1493         string f;
1494
1495         globhandle = search_begin(pattern, TRUE, FALSE);
1496         if (globhandle < 0)
1497                 return;
1498         n = search_getsize(globhandle);
1499         for (i = 0; i < n; ++i)
1500         {
1501                 //print(search_getfilename(globhandle, i), "\n");
1502                 f = search_getfilename(globhandle, i);
1503                 precache_playermodel(f);
1504         }
1505         search_end(globhandle);
1506 }
1507
1508 void precache()
1509 {
1510     // gamemode related things
1511     precache_model ("models/misc/chatbubble.spr");
1512     if (g_runematch)
1513     {
1514         precache_model ("models/runematch/curse.mdl");
1515         precache_model ("models/runematch/rune.mdl");
1516     }
1517
1518 #ifdef TTURRETS_ENABLED
1519     if (autocvar_g_turrets)
1520         turrets_precash();
1521 #endif
1522
1523     // Precache all player models if desired
1524     if (autocvar_sv_precacheplayermodels)
1525     {
1526         PrecachePlayerSounds("sound/player/default.sounds");
1527         precache_all_playermodels("models/player/*.zym");
1528         precache_all_playermodels("models/player/*.dpm");
1529         precache_all_playermodels("models/player/*.md3");
1530         precache_all_playermodels("models/player/*.psk");
1531         precache_all_playermodels("models/player/*.iqm");
1532     }
1533
1534     if (autocvar_sv_defaultcharacter)
1535     {
1536         string s;
1537         s = autocvar_sv_defaultplayermodel_red;
1538         if (s != "")
1539             precache_playermodel(s);
1540         s = autocvar_sv_defaultplayermodel_blue;
1541         if (s != "")
1542             precache_playermodel(s);
1543         s = autocvar_sv_defaultplayermodel_yellow;
1544         if (s != "")
1545             precache_playermodel(s);
1546         s = autocvar_sv_defaultplayermodel_pink;
1547         if (s != "")
1548             precache_playermodel(s);
1549         s = autocvar_sv_defaultplayermodel;
1550         if (s != "")
1551             precache_playermodel(s);
1552     }
1553
1554     if (g_footsteps)
1555     {
1556         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1557         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1558     }
1559
1560     // gore and miscellaneous sounds
1561     //precache_sound ("misc/h2ohit.wav");
1562     precache_model ("models/hook.md3");
1563     precache_sound ("misc/armorimpact.wav");
1564     precache_sound ("misc/bodyimpact1.wav");
1565     precache_sound ("misc/bodyimpact2.wav");
1566     precache_sound ("misc/gib.wav");
1567     precache_sound ("misc/gib_splat01.wav");
1568     precache_sound ("misc/gib_splat02.wav");
1569     precache_sound ("misc/gib_splat03.wav");
1570     precache_sound ("misc/gib_splat04.wav");
1571     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1572     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1573     precache_sound ("misc/null.wav");
1574     precache_sound ("misc/spawn.wav");
1575     precache_sound ("misc/talk.wav");
1576     precache_sound ("misc/teleport.wav");
1577     precache_sound ("misc/poweroff.wav");
1578     precache_sound ("player/lava.wav");
1579     precache_sound ("player/slime.wav");
1580
1581     if (g_jetpack)
1582         precache_sound ("misc/jetpack_fly.wav");
1583
1584     precache_model ("models/sprites/0.spr32");
1585     precache_model ("models/sprites/1.spr32");
1586     precache_model ("models/sprites/2.spr32");
1587     precache_model ("models/sprites/3.spr32");
1588     precache_model ("models/sprites/4.spr32");
1589     precache_model ("models/sprites/5.spr32");
1590     precache_model ("models/sprites/6.spr32");
1591     precache_model ("models/sprites/7.spr32");
1592     precache_model ("models/sprites/8.spr32");
1593     precache_model ("models/sprites/9.spr32");
1594     precache_model ("models/sprites/10.spr32");
1595
1596     // common weapon precaches
1597         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1598     precache_sound ("weapons/weapon_switch.wav");
1599     precache_sound ("weapons/weaponpickup.wav");
1600     precache_sound ("weapons/unavailable.wav");
1601     precache_sound ("weapons/dryfire.wav");
1602     if (g_grappling_hook)
1603     {
1604         precache_sound ("weapons/hook_fire.wav"); // hook
1605         precache_sound ("weapons/hook_impact.wav"); // hook
1606     }
1607
1608     if(autocvar_sv_precacheweapons)
1609     {
1610         //precache weapon models/sounds
1611         float wep;
1612         wep = WEP_FIRST;
1613         while (wep <= WEP_LAST)
1614         {
1615             weapon_action(wep, WR_PRECACHE);
1616             wep = wep + 1;
1617         }
1618     }
1619
1620     precache_model("models/elaser.mdl");
1621     precache_model("models/laser.mdl");
1622     precache_model("models/ebomb.mdl");
1623
1624 #if 0
1625     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1626
1627     if (!self.noise && self.music) // quake 3 uses the music field
1628         self.noise = self.music;
1629
1630     // plays music for the level if there is any
1631     if (self.noise)
1632     {
1633         precache_sound (self.noise);
1634         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1635     }
1636 #endif
1637 }
1638
1639 // sorry, but using \ in macros breaks line numbers
1640 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1641 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1642 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1643
1644
1645 void Send_CSQC_Centerprint_Generic(entity e, float id, string s, float duration, float countdown_num)
1646 {
1647         if ((clienttype(e) == CLIENTTYPE_REAL) && (e.flags & FL_CLIENT))
1648         {
1649                 msg_entity = e;
1650                 WRITESPECTATABLE_MSG_ONE({
1651                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1652                         WriteByte(MSG_ONE, TE_CSQC_CENTERPRINT_GENERIC);
1653                         WriteByte(MSG_ONE, id);
1654                         WriteString(MSG_ONE, s);
1655                         if (id != 0 && s != "")
1656                         {
1657                                 WriteByte(MSG_ONE, duration);
1658                                 WriteByte(MSG_ONE, countdown_num);
1659                         }
1660                 });
1661         }
1662 }
1663 void Send_CSQC_Centerprint_Generic_Expire(entity e, float id)
1664 {
1665         Send_CSQC_Centerprint_Generic(e, id, "", 1, 0);
1666 }
1667 // WARNING: this kills the trace globals
1668 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1669 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1670
1671 #define INITPRIO_FIRST              0
1672 #define INITPRIO_GAMETYPE           0
1673 #define INITPRIO_GAMETYPE_FALLBACK  1
1674 #define INITPRIO_FINDTARGET        10
1675 #define INITPRIO_DROPTOFLOOR       20
1676 #define INITPRIO_SETLOCATION       90
1677 #define INITPRIO_LINKDOORS         91
1678 #define INITPRIO_LAST              99
1679
1680 .void(void) initialize_entity;
1681 .float initialize_entity_order;
1682 .entity initialize_entity_next;
1683 entity initialize_entity_first;
1684
1685 void make_safe_for_remove(entity e)
1686 {
1687     if (e.initialize_entity)
1688     {
1689         entity ent, prev;
1690         for (ent = initialize_entity_first; ent; )
1691         {
1692             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1693             {
1694                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1695                 // skip it in linked list
1696                 if (prev)
1697                 {
1698                     prev.initialize_entity_next = ent.initialize_entity_next;
1699                     ent = prev.initialize_entity_next;
1700                 }
1701                 else
1702                 {
1703                     initialize_entity_first = ent.initialize_entity_next;
1704                     ent = initialize_entity_first;
1705                 }
1706             }
1707             else
1708             {
1709                 prev = ent;
1710                 ent = ent.initialize_entity_next;
1711             }
1712         }
1713     }
1714 }
1715
1716 void objerror(string s)
1717 {
1718     make_safe_for_remove(self);
1719     builtin_objerror(s);
1720 }
1721
1722 .float remove_except_protected_forbidden;
1723 void remove_except_protected(entity e)
1724 {
1725         if(e.remove_except_protected_forbidden)
1726                 error("not allowed to remove this at this point");
1727         builtin_remove(e);
1728 }
1729
1730 void remove_unsafely(entity e)
1731 {
1732     if(e.classname == "spike")
1733         error("Removing spikes is forbidden (crylink bug), please report");
1734     builtin_remove(e);
1735 }
1736
1737 void remove_safely(entity e)
1738 {
1739     make_safe_for_remove(e);
1740     builtin_remove(e);
1741 }
1742
1743 void InitializeEntity(entity e, void(void) func, float order)
1744 {
1745     entity prev, cur;
1746
1747     if (!e || e.initialize_entity)
1748     {
1749         // make a proxy initializer entity
1750         entity e_old;
1751         e_old = e;
1752         e = spawn();
1753         e.classname = "initialize_entity";
1754         e.enemy = e_old;
1755     }
1756
1757     e.initialize_entity = func;
1758     e.initialize_entity_order = order;
1759
1760     cur = initialize_entity_first;
1761     for (;;)
1762     {
1763         if (!cur || cur.initialize_entity_order > order)
1764         {
1765             // insert between prev and cur
1766             if (prev)
1767                 prev.initialize_entity_next = e;
1768             else
1769                 initialize_entity_first = e;
1770             e.initialize_entity_next = cur;
1771             return;
1772         }
1773         prev = cur;
1774         cur = cur.initialize_entity_next;
1775     }
1776 }
1777 void InitializeEntitiesRun()
1778 {
1779     entity startoflist;
1780     startoflist = initialize_entity_first;
1781     initialize_entity_first = world;
1782     remove = remove_except_protected;
1783     for (self = startoflist; self; self = self.initialize_entity_next)
1784     {
1785         self.remove_except_protected_forbidden = 1;
1786     }
1787     for (self = startoflist; self; )
1788     {
1789         entity e;
1790         var void(void) func;
1791         e = self.initialize_entity_next;
1792         func = self.initialize_entity;
1793         self.initialize_entity_order = 0;
1794         self.initialize_entity = func_null;
1795         self.initialize_entity_next = world;
1796         self.remove_except_protected_forbidden = 0;
1797         if (self.classname == "initialize_entity")
1798         {
1799             entity e_old;
1800             e_old = self.enemy;
1801             builtin_remove(self);
1802             self = e_old;
1803         }
1804         //dprint("Delayed initialization: ", self.classname, "\n");
1805         if(func != func_null)
1806             func();
1807         else
1808         {
1809             eprint(self);
1810             backtrace(strcat("Null function in: ", self.classname, "\n"));
1811         }
1812         self = e;
1813     }
1814     remove = remove_unsafely;
1815 }
1816
1817 .float uncustomizeentityforclient_set;
1818 .void(void) uncustomizeentityforclient;
1819 void(void) SUB_Nullpointer = #0;
1820 void UncustomizeEntitiesRun()
1821 {
1822     entity oldself;
1823     oldself = self;
1824     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1825         self.uncustomizeentityforclient();
1826     self = oldself;
1827 }
1828 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1829 {
1830     e.customizeentityforclient = customizer;
1831     e.uncustomizeentityforclient = uncustomizer;
1832     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1833 }
1834
1835 .float nottargeted;
1836 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1837
1838 void() SUB_Remove;
1839 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1840 {
1841     vector mi, ma;
1842
1843     if (e.classname == "")
1844         e.classname = "net_linked";
1845
1846     if (e.model == "" || self.modelindex == 0)
1847     {
1848         mi = e.mins;
1849         ma = e.maxs;
1850         setmodel(e, "null");
1851         setsize(e, mi, ma);
1852     }
1853
1854     e.SendEntity = sendfunc;
1855     e.SendFlags = 0xFFFFFF;
1856
1857     if (!docull)
1858         e.effects |= EF_NODEPTHTEST;
1859
1860     if (dt)
1861     {
1862         e.nextthink = time + dt;
1863         e.think = SUB_Remove;
1864     }
1865 }
1866
1867 void adaptor_think2touch()
1868 {
1869     entity o;
1870     o = other;
1871     other = world;
1872     self.touch();
1873     other = o;
1874 }
1875
1876 void adaptor_think2use()
1877 {
1878     entity o, a;
1879     o = other;
1880     a = activator;
1881     activator = world;
1882     other = world;
1883     self.use();
1884     other = o;
1885     activator = a;
1886 }
1887
1888 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1889 {
1890         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1891                 self.projectiledeathtype |= HITTYPE_SPLASH;
1892         adaptor_think2use();
1893 }
1894
1895 // deferred dropping
1896 void DropToFloor_Handler()
1897 {
1898     builtin_droptofloor();
1899     self.dropped_origin = self.origin;
1900 }
1901
1902 void droptofloor()
1903 {
1904     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1905 }
1906
1907
1908
1909 float trace_hits_box_a0, trace_hits_box_a1;
1910
1911 float trace_hits_box_1d(float end, float thmi, float thma)
1912 {
1913     if (end == 0)
1914     {
1915         // just check if x is in range
1916         if (0 < thmi)
1917             return FALSE;
1918         if (0 > thma)
1919             return FALSE;
1920     }
1921     else
1922     {
1923         // do the trace with respect to x
1924         // 0 -> end has to stay in thmi -> thma
1925         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1926         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1927         if (trace_hits_box_a0 > trace_hits_box_a1)
1928             return FALSE;
1929     }
1930     return TRUE;
1931 }
1932
1933 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1934 {
1935     end -= start;
1936     thmi -= start;
1937     thma -= start;
1938     // now it is a trace from 0 to end
1939
1940     trace_hits_box_a0 = 0;
1941     trace_hits_box_a1 = 1;
1942
1943     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1944         return FALSE;
1945     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1946         return FALSE;
1947     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1948         return FALSE;
1949
1950     return TRUE;
1951 }
1952
1953 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1954 {
1955     return trace_hits_box(start, end, thmi - ma, thma - mi);
1956 }
1957
1958 float SUB_NoImpactCheck()
1959 {
1960         // zero hitcontents = this is not the real impact, but either the
1961         // mirror-impact of something hitting the projectile instead of the
1962         // projectile hitting the something, or a touchareagrid one. Neither of
1963         // these stop the projectile from moving, so...
1964         if(trace_dphitcontents == 0)
1965         {
1966                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1967                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1968                 checkclient();
1969         }
1970     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1971         return 1;
1972     if (other == world && self.size != '0 0 0')
1973     {
1974         vector tic;
1975         tic = self.velocity * sys_frametime;
1976         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1977         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1978         if (trace_fraction >= 1)
1979         {
1980             dprint("Odd... did not hit...?\n");
1981         }
1982         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1983         {
1984             dprint("Detected and prevented the sky-grapple bug.\n");
1985             return 1;
1986         }
1987     }
1988
1989     return 0;
1990 }
1991
1992 #define SUB_OwnerCheck() (other && (other == self.owner))
1993
1994 void RemoveGrapplingHook(entity pl);
1995 void W_Crylink_Dequeue(entity e);
1996 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1997 {
1998         if(SUB_OwnerCheck())
1999                 return TRUE;
2000         if(SUB_NoImpactCheck())
2001         {
2002                 if(self.classname == "grapplinghook")
2003                         RemoveGrapplingHook(self.realowner);
2004                 else if(self.classname == "spike")
2005                 {
2006                         W_Crylink_Dequeue(self);
2007                         remove(self);
2008                 }
2009                 else
2010                         remove(self);
2011                 return TRUE;
2012         }
2013         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
2014                 UpdateCSQCProjectile(self);
2015         return FALSE;
2016 }
2017 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
2018
2019 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
2020 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
2021
2022 void URI_Get_Callback(float id, float status, string data)
2023 {
2024         if(url_URI_Get_Callback(id, status, data))
2025         {
2026                 // handled
2027         }
2028         else if (id == URI_GET_DISCARD)
2029         {
2030                 // discard
2031         }
2032         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
2033         {
2034                 // sv_cmd curl
2035                 Curl_URI_Get_Callback(id, status, data);
2036         }
2037         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2038         {
2039                 // online ban list
2040                 OnlineBanList_URI_Get_Callback(id, status, data);
2041         }
2042         else
2043         {
2044                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2045         }
2046 }
2047
2048 string uid2name(string myuid) {
2049         string s;
2050         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
2051
2052         // FIXME remove this later after 0.6 release
2053         // convert old style broken records to correct style
2054         if(s == "")
2055         {
2056                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
2057                 if(s != "")
2058                 {
2059                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
2060                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
2061                 }
2062         }
2063
2064         if(s == "")
2065                 s = "^1Unregistered Player";
2066         return s;
2067 }
2068
2069 float race_readTime(string map, float pos)
2070 {
2071         string rr;
2072         if(g_cts)
2073                 rr = CTS_RECORD;
2074         else
2075                 rr = RACE_RECORD;
2076
2077         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
2078 }
2079
2080 string race_readUID(string map, float pos)
2081 {
2082         string rr;
2083         if(g_cts)
2084                 rr = CTS_RECORD;
2085         else
2086                 rr = RACE_RECORD;
2087
2088         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
2089 }
2090
2091 float race_readPos(string map, float t) {
2092         float i;
2093         for (i = 1; i <= RANKINGS_CNT; ++i)
2094                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
2095                         return i;
2096
2097         return 0; // pos is zero if unranked
2098 }
2099
2100 void race_writeTime(string map, float t, string myuid)
2101 {
2102         string rr;
2103         if(g_cts)
2104                 rr = CTS_RECORD;
2105         else
2106                 rr = RACE_RECORD;
2107
2108         float newpos;
2109         newpos = race_readPos(map, t);
2110
2111         float i, prevpos;
2112         for(i = 1; i <= RANKINGS_CNT; ++i)
2113         {
2114                 if(race_readUID(map, i) == myuid)
2115                         prevpos = i;
2116         }
2117         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
2118                 for (i = prevpos; i > newpos; --i) {
2119                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2120                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2121                 }
2122         } else { // player has no ranked record yet
2123                 for (i = RANKINGS_CNT; i > newpos; --i) {
2124                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2125                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2126                 }
2127         }
2128
2129         // store new time itself
2130         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2131         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2132 }
2133
2134 string race_readName(string map, float pos)
2135 {
2136         string rr;
2137         if(g_cts)
2138                 rr = CTS_RECORD;
2139         else
2140                 rr = RACE_RECORD;
2141
2142         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2143 }
2144
2145 string race_placeName(float pos) {
2146         if(floor((mod(pos, 100))/10) * 10 != 10) // examples: 12th, 111th, 213th will not execute this block
2147         {
2148                 if(mod(pos, 10) == 1)
2149                         return strcat(ftos(pos), "st");
2150                 else if(mod(pos, 10) == 2)
2151                         return strcat(ftos(pos), "nd");
2152                 else if(mod(pos, 10) == 3)
2153                         return strcat(ftos(pos), "rd");
2154                 else
2155                         return strcat(ftos(pos), "th");
2156         }
2157         else
2158                 return strcat(ftos(pos), "th");
2159 }
2160
2161 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2162 {
2163     float m, i;
2164     vector start, org, delta, end, enddown, mstart;
2165     entity sp;
2166
2167     m = e.dphitcontentsmask;
2168     e.dphitcontentsmask = goodcontents | badcontents;
2169
2170     org = world.mins;
2171     delta = world.maxs - world.mins;
2172
2173     for (i = 0; i < attempts; ++i)
2174     {
2175         start_x = org_x + random() * delta_x;
2176         start_y = org_y + random() * delta_y;
2177         start_z = org_z + random() * delta_z;
2178
2179         // rule 1: start inside world bounds, and outside
2180         // solid, and don't start from somewhere where you can
2181         // fall down to evil
2182         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2183         if (trace_fraction >= 1)
2184             continue;
2185         if (trace_startsolid)
2186             continue;
2187         if (trace_dphitcontents & badcontents)
2188             continue;
2189         if (trace_dphitq3surfaceflags & badsurfaceflags)
2190             continue;
2191
2192         // rule 2: if we are too high, lower the point
2193         if (trace_fraction * delta_z > maxaboveground)
2194             start = trace_endpos + '0 0 1' * maxaboveground;
2195         enddown = trace_endpos;
2196
2197         // rule 3: make sure we aren't outside the map. This only works
2198         // for somewhat well formed maps. A good rule of thumb is that
2199         // the map should have a convex outside hull.
2200         // these can be traceLINES as we already verified the starting box
2201         mstart = start + 0.5 * (e.mins + e.maxs);
2202         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2203         if (trace_fraction >= 1)
2204             continue;
2205         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2206         if (trace_fraction >= 1)
2207             continue;
2208         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2209         if (trace_fraction >= 1)
2210             continue;
2211         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2212         if (trace_fraction >= 1)
2213             continue;
2214         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2215         if (trace_fraction >= 1)
2216             continue;
2217
2218         // rule 4: we must "see" some spawnpoint
2219         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
2220                 if(checkpvs(mstart, sp))
2221                         break;
2222         if(!sp)
2223         {
2224                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
2225                         if(checkpvs(mstart, sp))
2226                                 break;
2227                 if(!sp)
2228                         continue;
2229         }
2230
2231         // find a random vector to "look at"
2232         end_x = org_x + random() * delta_x;
2233         end_y = org_y + random() * delta_y;
2234         end_z = org_z + random() * delta_z;
2235         end = start + normalize(end - start) * vlen(delta);
2236
2237         // rule 4: start TO end must not be too short
2238         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2239         if (trace_startsolid)
2240             continue;
2241         if (trace_fraction < minviewdistance / vlen(delta))
2242             continue;
2243
2244         // rule 5: don't want to look at sky
2245         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2246             continue;
2247
2248         // rule 6: we must not end up in trigger_hurt
2249         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2250             continue;
2251
2252         break;
2253     }
2254
2255     e.dphitcontentsmask = m;
2256
2257     if (i < attempts)
2258     {
2259         setorigin(e, start);
2260         e.angles = vectoangles(end - start);
2261         dprint("Needed ", ftos(i + 1), " attempts\n");
2262         return TRUE;
2263     }
2264     else
2265         return FALSE;
2266 }
2267
2268 float zcurveparticles_effectno;
2269 vector zcurveparticles_start;
2270 float zcurveparticles_spd;
2271
2272 void endzcurveparticles()
2273 {
2274         if(zcurveparticles_effectno)
2275         {
2276                 // terminator
2277                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2278         }
2279         zcurveparticles_effectno = 0;
2280 }
2281
2282 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2283 {
2284         spd = bound(0, floor(spd / 16), 32767);
2285         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2286         {
2287                 endzcurveparticles();
2288                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2289                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2290                 WriteShort(MSG_BROADCAST, effectno);
2291                 WriteCoord(MSG_BROADCAST, start_x);
2292                 WriteCoord(MSG_BROADCAST, start_y);
2293                 WriteCoord(MSG_BROADCAST, start_z);
2294                 zcurveparticles_effectno = effectno;
2295                 zcurveparticles_start = start;
2296         }
2297         else
2298                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2299         WriteCoord(MSG_BROADCAST, end_x);
2300         WriteCoord(MSG_BROADCAST, end_y);
2301         WriteCoord(MSG_BROADCAST, end_z);
2302         WriteCoord(MSG_BROADCAST, end_dz);
2303         zcurveparticles_spd = spd;
2304 }
2305
2306 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2307 {
2308         float end_dz;
2309         vector vecxy, velxy;
2310
2311         vecxy = end - start;
2312         vecxy_z = 0;
2313         velxy = vel;
2314         velxy_z = 0;
2315
2316         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2317         {
2318                 endzcurveparticles();
2319                 trailparticles(world, effectno, start, end);
2320                 return;
2321         }
2322
2323         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2324         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2325 }
2326
2327 void write_recordmarker(entity pl, float tstart, float dt)
2328 {
2329     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2330
2331     // also write a marker into demo files for demotc-race-record-extractor to find
2332     stuffcmd(pl,
2333              strcat(
2334                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2335                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2336 }
2337
2338 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2339 {
2340         switch(algn)
2341         {
2342                 default:
2343                 case 3: // right
2344                         break;
2345
2346                 case 4: // left
2347                         vecs_y = -vecs_y;
2348                         break;
2349
2350                 case 1:
2351                         if(allowcenter) // 2: allow center handedness
2352                         {
2353                                 // center
2354                                 vecs_y = 0;
2355                                 vecs_z -= 2;
2356                         }
2357                         else
2358                         {
2359                                 // right
2360                         }
2361                         break;
2362
2363                 case 2:
2364                         if(allowcenter) // 2: allow center handedness
2365                         {
2366                                 // center
2367                                 vecs_y = 0;
2368                                 vecs_z -= 2;
2369                         }
2370                         else
2371                         {
2372                                 // left
2373                                 vecs_y = -vecs_y;
2374                         }
2375                         break;
2376         }
2377         return vecs;
2378 }
2379
2380 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2381 {
2382         string s;
2383         vector v;
2384
2385         if (autocvar_g_shootfromeye)
2386         {
2387                 if (visual)
2388                 {
2389                         vecs_y = 0;
2390                         vecs_z -= 2;
2391                 }
2392                 else
2393                 {
2394                         vecs_y = 0;
2395                         vecs_z = 0;
2396                 }
2397         }
2398         else if (autocvar_g_shootfromcenter)
2399         {
2400                 vecs_y = 0;
2401                 vecs_z -= 2;
2402         }
2403         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2404         {
2405                 v = stov(s);
2406                 if (y_is_right)
2407                         v_y = -v_y;
2408                 if (v_x != 0)
2409                         vecs_x = v_x;
2410                 vecs_y = v_y;
2411                 vecs_z = v_z;
2412         }
2413         else if (autocvar_g_shootfromclient)
2414         {
2415                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2416         }
2417         return vecs;
2418 }
2419
2420 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2421 {
2422         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2423 }
2424
2425
2426 void attach_sameorigin(entity e, entity to, string tag)
2427 {
2428     vector org, t_forward, t_left, t_up, e_forward, e_up;
2429     vector org0, ang0;
2430     float tagscale;
2431
2432     ang0 = e.angles;
2433     org0 = e.origin;
2434
2435     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2436     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2437     t_forward = v_forward * tagscale;
2438     t_left = v_right * -tagscale;
2439     t_up = v_up * tagscale;
2440
2441     e.origin_x = org * t_forward;
2442     e.origin_y = org * t_left;
2443     e.origin_z = org * t_up;
2444
2445     // current forward and up directions
2446     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2447                 e.angles = AnglesTransform_FromVAngles(e.angles);
2448         else
2449                 e.angles = AnglesTransform_FromAngles(e.angles);
2450     fixedmakevectors(e.angles);
2451
2452     // untransform forward, up!
2453     e_forward_x = v_forward * t_forward;
2454     e_forward_y = v_forward * t_left;
2455     e_forward_z = v_forward * t_up;
2456     e_up_x = v_up * t_forward;
2457     e_up_y = v_up * t_left;
2458     e_up_z = v_up * t_up;
2459
2460     e.angles = fixedvectoangles2(e_forward, e_up);
2461     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2462                 e.angles = AnglesTransform_ToVAngles(e.angles);
2463         else
2464                 e.angles = AnglesTransform_ToAngles(e.angles);
2465
2466     setattachment(e, to, tag);
2467     setorigin(e, e.origin);
2468 }
2469
2470 void detach_sameorigin(entity e)
2471 {
2472     vector org;
2473     org = gettaginfo(e, 0);
2474     e.angles = fixedvectoangles2(v_forward, v_up);
2475     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2476                 e.angles = AnglesTransform_ToVAngles(e.angles);
2477         else
2478                 e.angles = AnglesTransform_ToAngles(e.angles);
2479     setorigin(e, org);
2480     setattachment(e, world, "");
2481     setorigin(e, e.origin);
2482 }
2483
2484 void follow_sameorigin(entity e, entity to)
2485 {
2486     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2487     e.aiment = to; // make the hole follow bmodel
2488     e.punchangle = to.angles; // the original angles of bmodel
2489     e.view_ofs = e.origin - to.origin; // relative origin
2490     e.v_angle = e.angles - to.angles; // relative angles
2491 }
2492
2493 void unfollow_sameorigin(entity e)
2494 {
2495     e.movetype = MOVETYPE_NONE;
2496 }
2497
2498 entity gettaginfo_relative_ent;
2499 vector gettaginfo_relative(entity e, float tag)
2500 {
2501     if (!gettaginfo_relative_ent)
2502     {
2503         gettaginfo_relative_ent = spawn();
2504         gettaginfo_relative_ent.effects = EF_NODRAW;
2505     }
2506     gettaginfo_relative_ent.model = e.model;
2507     gettaginfo_relative_ent.modelindex = e.modelindex;
2508     gettaginfo_relative_ent.frame = e.frame;
2509     return gettaginfo(gettaginfo_relative_ent, tag);
2510 }
2511
2512 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2513 {
2514     float p;
2515     p = pow(2, chan);
2516     if (pl.soundentity.cnt & p)
2517         return;
2518     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2519     pl.soundentity.cnt |= p;
2520 }
2521
2522 void SoundEntity_StopSound(entity pl, float chan)
2523 {
2524     float p;
2525     p = pow(2, chan);
2526     if (pl.soundentity.cnt & p)
2527     {
2528         stopsoundto(MSG_ALL, pl.soundentity, chan);
2529         pl.soundentity.cnt &~= p;
2530     }
2531 }
2532
2533 void SoundEntity_Attach(entity pl)
2534 {
2535     pl.soundentity = spawn();
2536     pl.soundentity.classname = "soundentity";
2537     pl.soundentity.owner = pl;
2538     setattachment(pl.soundentity, pl, "");
2539     setmodel(pl.soundentity, "null");
2540 }
2541
2542 void SoundEntity_Detach(entity pl)
2543 {
2544     float i;
2545     for (i = 0; i <= 7; ++i)
2546         SoundEntity_StopSound(pl, i);
2547 }
2548
2549 .float scale2;
2550
2551 float modeleffect_SendEntity(entity to, float sf)
2552 {
2553         float f;
2554         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2555
2556         f = 0;
2557         if(self.velocity != '0 0 0')
2558                 f |= 1;
2559         if(self.angles != '0 0 0')
2560                 f |= 2;
2561         if(self.avelocity != '0 0 0')
2562                 f |= 4;
2563
2564         WriteByte(MSG_ENTITY, f);
2565         WriteShort(MSG_ENTITY, self.modelindex);
2566         WriteByte(MSG_ENTITY, self.skin);
2567         WriteByte(MSG_ENTITY, self.frame);
2568         WriteCoord(MSG_ENTITY, self.origin_x);
2569         WriteCoord(MSG_ENTITY, self.origin_y);
2570         WriteCoord(MSG_ENTITY, self.origin_z);
2571         if(f & 1)
2572         {
2573                 WriteCoord(MSG_ENTITY, self.velocity_x);
2574                 WriteCoord(MSG_ENTITY, self.velocity_y);
2575                 WriteCoord(MSG_ENTITY, self.velocity_z);
2576         }
2577         if(f & 2)
2578         {
2579                 WriteCoord(MSG_ENTITY, self.angles_x);
2580                 WriteCoord(MSG_ENTITY, self.angles_y);
2581                 WriteCoord(MSG_ENTITY, self.angles_z);
2582         }
2583         if(f & 4)
2584         {
2585                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2586                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2587                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2588         }
2589         WriteShort(MSG_ENTITY, self.scale * 256.0);
2590         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2591         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2592         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2593         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2594
2595         return TRUE;
2596 }
2597
2598 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2599 {
2600         entity e;
2601         float sz;
2602         e = spawn();
2603         e.classname = "modeleffect";
2604         setmodel(e, m);
2605         e.frame = f;
2606         setorigin(e, o);
2607         e.velocity = v;
2608         e.angles = ang;
2609         e.avelocity = angv;
2610         e.alpha = a;
2611         e.teleport_time = t1;
2612         e.fade_time = t2;
2613         e.skin = s;
2614         if(s0 >= 0)
2615                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2616         else
2617                 e.scale = -s0;
2618         if(s2 >= 0)
2619                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2620         else
2621                 e.scale2 = -s2;
2622         sz = max(e.scale, e.scale2);
2623         setsize(e, e.mins * sz, e.maxs * sz);
2624         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2625 }
2626
2627 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2628 {
2629         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2630 }
2631
2632 float randombit(float bits)
2633 {
2634         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2635                 return bits;
2636
2637         float n, f, b, r;
2638
2639         r = random();
2640         b = 0;
2641         n = 0;
2642
2643         for(f = 1; f <= bits; f *= 2)
2644         {
2645                 if(bits & f)
2646                 {
2647                         ++n;
2648                         r *= n;
2649                         if(r <= 1)
2650                                 b = f;
2651                         else
2652                                 r = (r - 1) / (n - 1);
2653                 }
2654         }
2655
2656         return b;
2657 }
2658
2659 float randombits(float bits, float k, float error_return)
2660 {
2661         float r;
2662         r = 0;
2663         while(k > 0 && bits != r)
2664         {
2665                 r += randombit(bits - r);
2666                 --k;
2667         }
2668         if(error_return)
2669                 if(k > 0)
2670                         return -1; // all
2671         return r;
2672 }
2673
2674 void randombit_test(float bits, float iter)
2675 {
2676         while(iter > 0)
2677         {
2678                 print(ftos(randombit(bits)), "\n");
2679                 --iter;
2680         }
2681 }
2682
2683 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2684 {
2685         if(halflifedist > 0)
2686                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2687         else if(halflifedist < 0)
2688                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2689         else
2690                 return 1;
2691 }
2692
2693
2694
2695
2696 #ifdef RELEASE
2697 #define cvar_string_normal builtin_cvar_string
2698 #define cvar_normal builtin_cvar
2699 #else
2700 string cvar_string_normal(string n)
2701 {
2702         if not(cvar_type(n) & 1)
2703                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2704         return builtin_cvar_string(n);
2705 }
2706
2707 float cvar_normal(string n)
2708 {
2709         return stof(cvar_string_normal(n));
2710 }
2711 #endif
2712 #define cvar_set_normal builtin_cvar_set
2713
2714 void defer_think()
2715 {
2716     entity oself;
2717
2718     oself           = self;
2719     self            = self.owner;
2720     oself.think     = SUB_Remove;
2721     oself.nextthink = time;
2722
2723     oself.use();
2724 }
2725
2726 /*
2727     Execute func() after time + fdelay.
2728     self when func is executed = self when defer is called
2729 */
2730 void defer(float fdelay, void() func)
2731 {
2732     entity e;
2733
2734     e           = spawn();
2735     e.owner     = self;
2736     e.use       = func;
2737     e.think     = defer_think;
2738     e.nextthink = time + fdelay;
2739 }
2740
2741 .string aiment_classname;
2742 .float aiment_deadflag;
2743 void SetMovetypeFollow(entity ent, entity e)
2744 {
2745         // FIXME this may not be warpzone aware
2746         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2747         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2748         ent.aiment = e; // make the hole follow bmodel
2749         ent.punchangle = e.angles; // the original angles of bmodel
2750         ent.view_ofs = ent.origin - e.origin; // relative origin
2751         ent.v_angle = ent.angles - e.angles; // relative angles
2752         ent.aiment_classname = strzone(e.classname);
2753         ent.aiment_deadflag = e.deadflag;
2754 }
2755 void UnsetMovetypeFollow(entity ent)
2756 {
2757         ent.movetype = MOVETYPE_FLY;
2758         PROJECTILE_MAKETRIGGER(ent);
2759         ent.aiment = world;
2760 }
2761 float LostMovetypeFollow(entity ent)
2762 {
2763 /*
2764         if(ent.movetype != MOVETYPE_FOLLOW)
2765                 if(ent.aiment)
2766                         error("???");
2767 */
2768         if(ent.aiment)
2769         {
2770                 if(ent.aiment.classname != ent.aiment_classname)
2771                         return 1;
2772                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2773                         return 1;
2774         }
2775         return 0;
2776 }
2777
2778 float isPushable(entity e)
2779 {
2780         if(e.iscreature)
2781                 return TRUE;
2782         switch(e.classname)
2783         {
2784                 case "body":
2785                 case "droppedweapon":
2786                 case "keepawayball":
2787                 case "nexball_basketball":
2788                 case "nexball_football":
2789                         return TRUE;
2790                 case "bullet": // antilagged bullets can't hit this either
2791                         return FALSE;
2792         }
2793         if (e.projectiledeathtype)
2794                 return TRUE;
2795         return FALSE;
2796 }