qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35 string ColoredTeamName(float t);
  36
  37 string admin_name(void)
  38 {
  39         if(autocvar_sv_adminnick != "")
  40                 return autocvar_sv_adminnick;
  41         else
  42                 return "SERVER ADMIN";
  43 }
  44
  45 float DistributeEvenly_amount;
  46 float DistributeEvenly_totalweight;
  47 void DistributeEvenly_Init(float amount, float totalweight)
  48 {
  49     if (DistributeEvenly_amount)
  50     {
  51         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  52         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  53     }
  54     if (totalweight == 0)
  55         DistributeEvenly_amount = 0;
  56     else
  57         DistributeEvenly_amount = amount;
  58     DistributeEvenly_totalweight = totalweight;
  59 }
  60 float DistributeEvenly_Get(float weight)
  61 {
  62     float f;
  63     if (weight <= 0)
  64         return 0;
  65     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  66     DistributeEvenly_totalweight -= weight;
  67     DistributeEvenly_amount -= f;
  68     return f;
  69 }
  70
  71 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  72
  73
  74 string STR_PLAYER = "player";
  75 string STR_SPECTATOR = "spectator";
  76 string STR_OBSERVER = "observer";
  77
  78 #if 0
  79 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  80 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  81 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  82 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  83 #else
  84 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  85 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
  86 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  87 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
  88 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
  89 #endif
  90
  91 // copies a string to a tempstring (so one can strunzone it)
  92 string strcat1(string s) = #115; // FRIK_FILE
  93
  94 float logfile_open;
  95 float logfile;
  96
  97 void bcenterprint(string s)
  98 {
  99     // TODO replace by MSG_ALL (would show it to spectators too, though)?
 100     entity head;
 101     FOR_EACH_PLAYER(head)
 102     if (clienttype(head) == CLIENTTYPE_REAL)
 103         centerprint(head, s);
 104 }
 105
 106 void GameLogEcho(string s)
 107 {
 108     string fn;
 109     float matches;
 110
 111     if (autocvar_sv_eventlog_files)
 112     {
 113         if (!logfile_open)
 114         {
 115             logfile_open = TRUE;
 116             matches = autocvar_sv_eventlog_files_counter + 1;
 117             cvar_set("sv_eventlog_files_counter", ftos(matches));
 118             fn = ftos(matches);
 119             if (strlen(fn) < 8)
 120                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 121             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 122             logfile = fopen(fn, FILE_APPEND);
 123             fputs(logfile, ":logversion:3\n");
 124         }
 125         if (logfile >= 0)
 126         {
 127             if (autocvar_sv_eventlog_files_timestamps)
 128                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 129             else
 130                 fputs(logfile, strcat(s, "\n"));
 131         }
 132     }
 133     if (autocvar_sv_eventlog_console)
 134     {
 135         print(s, "\n");
 136     }
 137 }
 138
 139 void GameLogInit()
 140 {
 141     logfile_open = 0;
 142     // will be opened later
 143 }
 144
 145 void GameLogClose()
 146 {
 147     if (logfile_open && logfile >= 0)
 148     {
 149         fclose(logfile);
 150         logfile = -1;
 151     }
 152 }
 153
 154 float spawnpoint_nag;
 155 void relocate_spawnpoint()
 156 {
 157     // nudge off the floor
 158     setorigin(self, self.origin + '0 0 1');
 159
 160     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 161     if (trace_startsolid)
 162     {
 163         vector o;
 164         o = self.origin;
 165         self.mins = PL_MIN;
 166         self.maxs = PL_MAX;
 167         if (!move_out_of_solid(self))
 168             objerror("could not get out of solid at all!");
 169         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 170         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 171         print(" ", ftos(self.origin_y - o_y));
 172         print(" ", ftos(self.origin_z - o_z), "'\n");
 173         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
 174         {
 175             if (!spawnpoint_nag)
 176                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 177             spawnpoint_nag = 1;
 178         }
 179         else
 180         {
 181             setorigin(self, o);
 182             self.mins = self.maxs = '0 0 0';
 183             objerror("player spawn point in solid, mapper sucks!\n");
 184             return;
 185         }
 186     }
 187
 188     self.use = spawnpoint_use;
 189     self.team_saved = self.team;
 190     if (!self.cnt)
 191         self.cnt = 1;
 192
 193     if (have_team_spawns != 0)
 194         if (self.team)
 195             have_team_spawns = 1;
 196     have_team_spawns_forteam[self.team] = 1;
 197
 198     if (autocvar_r_showbboxes)
 199     {
 200         // show where spawnpoints point at too
 201         makevectors(self.angles);
 202         entity e;
 203         e = spawn();
 204         e.classname = "info_player_foo";
 205         setorigin(e, self.origin + v_forward * 24);
 206         setsize(e, '-8 -8 -8', '8 8 8');
 207         e.solid = SOLID_TRIGGER;
 208     }
 209 }
 210
 211 #define strstr strstrofs
 212 /*
 213 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 214 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 215 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 216 // BE CONSTANT OR strzoneD!
 217 float strstr(string haystack, string needle, float offset)
 218 {
 219         float len, endpos;
 220         string found;
 221         len = strlen(needle);
 222         endpos = strlen(haystack) - len;
 223         while(offset <= endpos)
 224         {
 225                 found = substring(haystack, offset, len);
 226                 if(found == needle)
 227                         return offset;
 228                 offset = offset + 1;
 229         }
 230         return -1;
 231 }
 232 */
 233
 234 float NUM_NEAREST_ENTITIES = 4;
 235 entity nearest_entity[NUM_NEAREST_ENTITIES];
 236 float nearest_length[NUM_NEAREST_ENTITIES];
 237 entity findnearest(vector point, .string field, string value, vector axismod)
 238 {
 239     entity localhead;
 240     float i;
 241     float j;
 242     float len;
 243     vector dist;
 244
 245     float num_nearest;
 246     num_nearest = 0;
 247
 248     localhead = find(world, field, value);
 249     while (localhead)
 250     {
 251         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 252             dist = localhead.oldorigin;
 253         else
 254             dist = localhead.origin;
 255         dist = dist - point;
 256         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 257         len = vlen(dist);
 258
 259         for (i = 0; i < num_nearest; ++i)
 260         {
 261             if (len < nearest_length[i])
 262                 break;
 263         }
 264
 265         // now i tells us where to insert at
 266         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 267         if (i < NUM_NEAREST_ENTITIES)
 268         {
 269             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 270             {
 271                 nearest_length[j + 1] = nearest_length[j];
 272                 nearest_entity[j + 1] = nearest_entity[j];
 273             }
 274             nearest_length[i] = len;
 275             nearest_entity[i] = localhead;
 276             if (num_nearest < NUM_NEAREST_ENTITIES)
 277                 num_nearest = num_nearest + 1;
 278         }
 279
 280         localhead = find(localhead, field, value);
 281     }
 282
 283     // now use the first one from our list that we can see
 284     for (i = 0; i < num_nearest; ++i)
 285     {
 286         traceline(point, nearest_entity[i].origin, TRUE, world);
 287         if (trace_fraction == 1)
 288         {
 289             if (i != 0)
 290             {
 291                 dprint("Nearest point (");
 292                 dprint(nearest_entity[0].netname);
 293                 dprint(") is not visible, using a visible one.\n");
 294             }
 295             return nearest_entity[i];
 296         }
 297     }
 298
 299     if (num_nearest == 0)
 300         return world;
 301
 302     dprint("Not seeing any location point, using nearest as fallback.\n");
 303     /* DEBUGGING CODE:
 304     dprint("Candidates were: ");
 305     for(j = 0; j < num_nearest; ++j)
 306     {
 307         if(j != 0)
 308                 dprint(", ");
 309         dprint(nearest_entity[j].netname);
 310     }
 311     dprint("\n");
 312     */
 313
 314     return nearest_entity[0];
 315 }
 316
 317 void spawnfunc_target_location()
 318 {
 319     self.classname = "target_location";
 320     // location name in netname
 321     // eventually support: count, teamgame selectors, line of sight?
 322 }
 323
 324 void spawnfunc_info_location()
 325 {
 326     self.classname = "target_location";
 327     self.message = self.netname;
 328 }
 329
 330 string NearestLocation(vector p)
 331 {
 332     entity loc;
 333     string ret;
 334     ret = "somewhere";
 335     loc = findnearest(p, classname, "target_location", '1 1 1');
 336     if (loc)
 337     {
 338         ret = loc.message;
 339     }
 340     else
 341     {
 342         loc = findnearest(p, target, "###item###", '1 1 4');
 343         if (loc)
 344             ret = loc.netname;
 345     }
 346     return ret;
 347 }
 348
 349 string formatmessage(string msg)
 350 {
 351         float p, p1, p2;
 352         float n;
 353         vector cursor;
 354         entity cursor_ent;
 355         string escape;
 356         string replacement;
 357         p = 0;
 358         n = 7;
 359
 360         WarpZone_crosshair_trace(self);
 361         cursor = trace_endpos;
 362         cursor_ent = trace_ent;
 363
 364         while (1) {
 365                 if (n < 1)
 366                         break; // too many replacements
 367
 368                 n = n - 1;
 369                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 370                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 371
 372                 if (p1 < 0)
 373                         p1 = p2;
 374
 375                 if (p2 < 0)
 376                         p2 = p1;
 377
 378                 p = min(p1, p2);
 379
 380                 if (p < 0)
 381                         break;
 382
 383                 replacement = substring(msg, p, 2);
 384                 escape = substring(msg, p + 1, 1);
 385
 386                 if (escape == "%")
 387                         replacement = "%";
 388                 else if (escape == "\\")
 389                         replacement = "\\";
 390                 else if (escape == "n")
 391                         replacement = "\n";
 392                 else if (escape == "a")
 393                         replacement = ftos(floor(self.armorvalue));
 394                 else if (escape == "h")
 395                         replacement = ftos(floor(self.health));
 396                 else if (escape == "l")
 397                         replacement = NearestLocation(self.origin);
 398                 else if (escape == "y")
 399                         replacement = NearestLocation(cursor);
 400                 else if (escape == "d")
 401                         replacement = NearestLocation(self.death_origin);
 402                 else if (escape == "w") {
 403                         float wep;
 404                         wep = self.weapon;
 405                         if (!wep)
 406                                 wep = self.switchweapon;
 407                         if (!wep)
 408                                 wep = self.cnt;
 409                         replacement = W_Name(wep);
 410                 } else if (escape == "W") {
 411                         if (self.items & IT_SHELLS) replacement = "shells";
 412                         else if (self.items & IT_NAILS) replacement = "bullets";
 413                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 414                         else if (self.items & IT_CELLS) replacement = "cells";
 415                         else replacement = "batteries"; // ;)
 416                 } else if (escape == "x") {
 417                         replacement = cursor_ent.netname;
 418                         if (!replacement || !cursor_ent)
 419                                 replacement = "nothing";
 420                 } else if (escape == "s")
 421                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 422                 else if (escape == "S")
 423                         replacement = ftos(vlen(self.velocity));
 424
 425                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 426                 p = p + strlen(replacement);
 427         }
 428         return msg;
 429 }
 430
 431 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 432         return (value == 0) ? FALSE : TRUE;
 433 }
 434
 435 /*
 436 =============
 437 GetCvars
 438 =============
 439 Called with:
 440   0:  sends the request
 441   >0: receives a cvar from name=argv(f) value=argv(f+1)
 442 */
 443 void GetCvars_handleString(string thisname, float f, .string field, string name)
 444 {
 445         if (f < 0)
 446         {
 447                 if (self.field)
 448                         strunzone(self.field);
 449                 self.field = string_null;
 450         }
 451         else if (f > 0)
 452         {
 453                 if (thisname == name)
 454                 {
 455                         if (self.field)
 456                                 strunzone(self.field);
 457                         self.field = strzone(argv(f + 1));
 458                 }
 459         }
 460         else
 461                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 462 }
 463 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 464 {
 465         GetCvars_handleString(thisname, f, field, name);
 466         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 467                 if (thisname == name)
 468                 {
 469                         string s;
 470                         s = func(strcat1(self.field));
 471                         if (s != self.field)
 472                         {
 473                                 strunzone(self.field);
 474                                 self.field = strzone(s);
 475                         }
 476                 }
 477 }
 478 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 479 {
 480         if (f < 0)
 481         {
 482         }
 483         else if (f > 0)
 484         {
 485                 if (thisname == name)
 486                         self.field = stof(argv(f + 1));
 487         }
 488         else
 489                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 490 }
 491 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 492 {
 493         if (f < 0)
 494         {
 495         }
 496         else if (f > 0)
 497         {
 498                 if (thisname == name)
 499                 {
 500                         if(!self.field)
 501                         {
 502                                 self.field = stof(argv(f + 1));
 503                                 if(!self.field)
 504                                         self.field = -1;
 505                         }
 506                 }
 507         }
 508         else
 509         {
 510                 if(!self.field)
 511                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 512         }
 513 }
 514 float w_getbestweapon(entity e);
 515 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 516 {
 517         string o;
 518         o = W_FixWeaponOrder_ForceComplete(wo);
 519         if(self.weaponorder_byimpulse)
 520         {
 521                 strunzone(self.weaponorder_byimpulse);
 522                 self.weaponorder_byimpulse = string_null;
 523         }
 524         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 525         return o;
 526 }
 527 void GetCvars(float f)
 528 {
 529         string s;
 530
 531         if (f > 0)
 532                 s = strcat1(argv(f));
 533
 534         get_cvars_f = f;
 535         get_cvars_s = s;
 536         MUTATOR_CALLHOOK(GetCvars);
 537         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 538         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 539         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 540         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 541         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 542         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 543         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 544         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 545         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 546         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 547         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 548         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 549         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 550         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 551         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 552         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 553         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 554         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 555         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 556         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 557         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 558         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 559         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 560
 561         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 562         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 563
 564 #ifdef ALLOW_FORCEMODELS
 565         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
 566         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
 567 #endif
 568         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 569         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 570         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 571         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 572         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 573
 574         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 575         if (f > 0)
 576         {
 577                 if (s == "cl_weaponpriority")
 578                         self.switchweapon = w_getbestweapon(self);
 579                 if (s == "cl_allow_uidtracking")
 580                         PlayerStats_AddPlayer(self);
 581         }
 582 }
 583
 584 void backtrace(string msg)
 585 {
 586     float dev, war;
 587     dev = autocvar_developer;
 588     war = autocvar_prvm_backtraceforwarnings;
 589     cvar_set("developer", "1");
 590     cvar_set("prvm_backtraceforwarnings", "1");
 591     print("\n");
 592     print("--- CUT HERE ---\nWARNING: ");
 593     print(msg);
 594     print("\n");
 595     remove(world); // isn't there any better way to cause a backtrace?
 596     print("\n--- CUT UNTIL HERE ---\n");
 597     cvar_set("developer", ftos(dev));
 598     cvar_set("prvm_backtraceforwarnings", ftos(war));
 599 }
 600
 601 string Team_ColorCode(float teamid)
 602 {
 603     if (teamid == COLOR_TEAM1)
 604         return "^1";
 605     else if (teamid == COLOR_TEAM2)
 606         return "^4";
 607     else if (teamid == COLOR_TEAM3)
 608         return "^3";
 609     else if (teamid == COLOR_TEAM4)
 610         return "^6";
 611     else
 612         return "^7";
 613 }
 614
 615 string Team_ColorName(float t)
 616 {
 617     // fixme: Search for team entities and get their .netname's!
 618     if (t == COLOR_TEAM1)
 619         return "Red";
 620     if (t == COLOR_TEAM2)
 621         return "Blue";
 622     if (t == COLOR_TEAM3)
 623         return "Yellow";
 624     if (t == COLOR_TEAM4)
 625         return "Pink";
 626     return "Neutral";
 627 }
 628
 629 string Team_ColorNameLowerCase(float t)
 630 {
 631     // fixme: Search for team entities and get their .netname's!
 632     if (t == COLOR_TEAM1)
 633         return "red";
 634     if (t == COLOR_TEAM2)
 635         return "blue";
 636     if (t == COLOR_TEAM3)
 637         return "yellow";
 638     if (t == COLOR_TEAM4)
 639         return "pink";
 640     return "neutral";
 641 }
 642
 643 float ColourToNumber(string team_colour)
 644 {
 645         if (team_colour == "red")
 646                 return COLOR_TEAM1;
 647
 648         if (team_colour == "blue")
 649                 return COLOR_TEAM2;
 650
 651         if (team_colour == "yellow")
 652                 return COLOR_TEAM3;
 653
 654         if (team_colour == "pink")
 655                 return COLOR_TEAM4;
 656
 657         if (team_colour == "auto")
 658                 return 0;
 659
 660         return -1;
 661 }
 662
 663 float NumberToTeamNumber(float number)
 664 {
 665         if (number == 1)
 666                 return COLOR_TEAM1;
 667
 668         if (number == 2)
 669                 return COLOR_TEAM2;
 670
 671         if (number == 3)
 672                 return COLOR_TEAM3;
 673
 674         if (number == 4)
 675                 return COLOR_TEAM4;
 676
 677         return -1;
 678 }
 679
 680 // decolorizes and team colors the player name when needed
 681 string playername(entity p)
 682 {
 683     string t;
 684     if (teamplay && !intermission_running && p.classname == "player")
 685     {
 686         t = Team_ColorCode(p.team);
 687         return strcat(t, strdecolorize(p.netname));
 688     }
 689     else
 690         return p.netname;
 691 }
 692
 693 vector randompos(vector m1, vector m2)
 694 {
 695     vector v;
 696     m2 = m2 - m1;
 697     v_x = m2_x * random() + m1_x;
 698     v_y = m2_y * random() + m1_y;
 699     v_z = m2_z * random() + m1_z;
 700     return  v;
 701 }
 702
 703 //#NO AUTOCVARS START
 704
 705 float g_pickup_shells;
 706 float g_pickup_shells_max;
 707 float g_pickup_nails;
 708 float g_pickup_nails_max;
 709 float g_pickup_rockets;
 710 float g_pickup_rockets_max;
 711 float g_pickup_cells;
 712 float g_pickup_cells_max;
 713 float g_pickup_fuel;
 714 float g_pickup_fuel_jetpack;
 715 float g_pickup_fuel_max;
 716 float g_pickup_armorsmall;
 717 float g_pickup_armorsmall_max;
 718 float g_pickup_armorsmall_anyway;
 719 float g_pickup_armormedium;
 720 float g_pickup_armormedium_max;
 721 float g_pickup_armormedium_anyway;
 722 float g_pickup_armorbig;
 723 float g_pickup_armorbig_max;
 724 float g_pickup_armorbig_anyway;
 725 float g_pickup_armorlarge;
 726 float g_pickup_armorlarge_max;
 727 float g_pickup_armorlarge_anyway;
 728 float g_pickup_healthsmall;
 729 float g_pickup_healthsmall_max;
 730 float g_pickup_healthsmall_anyway;
 731 float g_pickup_healthmedium;
 732 float g_pickup_healthmedium_max;
 733 float g_pickup_healthmedium_anyway;
 734 float g_pickup_healthlarge;
 735 float g_pickup_healthlarge_max;
 736 float g_pickup_healthlarge_anyway;
 737 float g_pickup_healthmega;
 738 float g_pickup_healthmega_max;
 739 float g_pickup_healthmega_anyway;
 740 float g_pickup_ammo_anyway;
 741 float g_pickup_weapons_anyway;
 742 float g_weaponarena;
 743 float g_weaponarena_random;
 744 float g_weaponarena_random_with_laser;
 745 string g_weaponarena_list;
 746 float g_weaponspeedfactor;
 747 float g_weaponratefactor;
 748 float g_weapondamagefactor;
 749 float g_weaponforcefactor;
 750 float g_weaponspreadfactor;
 751
 752 float start_weapons;
 753 float start_items;
 754 float start_ammo_shells;
 755 float start_ammo_nails;
 756 float start_ammo_rockets;
 757 float start_ammo_cells;
 758 float start_ammo_fuel;
 759 float start_health;
 760 float start_armorvalue;
 761 float warmup_start_weapons;
 762 float warmup_start_ammo_shells;
 763 float warmup_start_ammo_nails;
 764 float warmup_start_ammo_rockets;
 765 float warmup_start_ammo_cells;
 766 float warmup_start_ammo_fuel;
 767 float warmup_start_health;
 768 float warmup_start_armorvalue;
 769 float g_weapon_stay;
 770 float g_ghost_items;
 771
 772 entity get_weaponinfo(float w);
 773
 774 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 775 {
 776         var float i = weaponinfo.weapon;
 777
 778         if (!i)
 779                 return 0;
 780
 781         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 782
 783         if (t < 0) // "default" weapon selection
 784         {
 785                 if (g_lms || g_ca || allguns)
 786                         t = (weaponinfo.spawnflags & WEP_FLAG_NORMAL);
 787                 else if(t < -1)
 788                         t = 0;
 789                 else if (g_cts)
 790                         t = (i == WEP_SHOTGUN);
 791                 else if (g_nexball)
 792                         t = 0; // weapon is set a few lines later
 793                 else
 794                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 795                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 796                         t |= (i == WEP_HOOK);
 797         }
 798
 799         return t;
 800 }
 801
 802 void readplayerstartcvars()
 803 {
 804         entity e;
 805         float i, j, t;
 806         string s;
 807
 808         // initialize starting values for players
 809         start_weapons = 0;
 810         start_items = 0;
 811         start_ammo_shells = 0;
 812         start_ammo_nails = 0;
 813         start_ammo_rockets = 0;
 814         start_ammo_cells = 0;
 815         start_health = cvar("g_balance_health_start");
 816         start_armorvalue = cvar("g_balance_armor_start");
 817
 818         g_weaponarena = 0;
 819         s = cvar_string("g_weaponarena");
 820         if (s == "0" || s == "")
 821         {
 822                 if(g_lms || g_ca)
 823                         s = "most";
 824         }
 825
 826         if (s == "0" || s == "")
 827         {
 828                 // no arena
 829         }
 830         else if (s == "off")
 831         {
 832                 // forcibly turn off weaponarena
 833         }
 834         else if (s == "all")
 835         {
 836                 g_weaponarena_list = "All Weapons";
 837                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 838                 {
 839                         e = get_weaponinfo(j);
 840                         g_weaponarena |= e.weapons;
 841                         weapon_action(e.weapon, WR_PRECACHE);
 842                 }
 843         }
 844         else if (s == "most")
 845         {
 846                 g_weaponarena_list = "Most Weapons";
 847                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 848                 {
 849                         e = get_weaponinfo(j);
 850                         if (e.spawnflags & WEP_FLAG_NORMAL)
 851                         {
 852                                 g_weaponarena |= e.weapons;
 853                                 weapon_action(e.weapon, WR_PRECACHE);
 854                         }
 855                 }
 856         }
 857         else if (s == "none")
 858         {
 859                 g_weaponarena_list = "No Weapons";
 860                 g_weaponarena = WEPBIT_ALL + 1; // this supports no single weapon bit!
 861         }
 862         else
 863         {
 864                 t = tokenize_console(s);
 865                 g_weaponarena_list = "";
 866                 for (i = 0; i < t; ++i)
 867                 {
 868                         s = argv(i);
 869                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 870                         {
 871                                 e = get_weaponinfo(j);
 872                                 if (e.netname == s)
 873                                 {
 874                                         g_weaponarena |= e.weapons;
 875                                         weapon_action(e.weapon, WR_PRECACHE);
 876                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 877                                         break;
 878                                 }
 879                         }
 880                         if (j > WEP_LAST)
 881                         {
 882                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 883                         }
 884                 }
 885                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 886         }
 887
 888         if(g_weaponarena)
 889                 g_weaponarena_random = cvar("g_weaponarena_random");
 890         else
 891                 g_weaponarena_random = 0;
 892         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 893
 894         if (g_weaponarena)
 895         {
 896                 g_minstagib = 0; // incompatible
 897                 g_pinata = 0; // incompatible
 898                 g_weapon_stay = 0; // incompatible
 899                 start_weapons = g_weaponarena;
 900                 if(!(g_lms || g_ca))
 901                         start_items |= IT_UNLIMITED_AMMO;
 902         }
 903         else if (g_minstagib)
 904         {
 905                 g_pinata = 0; // incompatible
 906                 g_weapon_stay = 0; // incompatible
 907                 g_bloodloss = 0; // incompatible
 908                 start_health = 100;
 909                 start_armorvalue = 0;
 910                 start_weapons = WEPBIT_MINSTANEX;
 911                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
 912                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 913                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
 914
 915                 if (g_minstagib_invis_alpha <= 0)
 916                         g_minstagib_invis_alpha = -1;
 917         }
 918         else
 919         {
 920                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 921                 {
 922                         e = get_weaponinfo(i);
 923                         if(want_weapon("g_start_weapon_", e, FALSE))
 924                                 start_weapons |= e.weapons;
 925                 }
 926         }
 927
 928         if(!cvar("g_use_ammunition"))
 929                 start_items |= IT_UNLIMITED_AMMO;
 930
 931         if(cvar("g_nexball"))
 932                 start_items |= IT_UNLIMITED_SUPERWEAPONS; // FIXME BAD BAD BAD BAD HACK, NEXBALL SHOULDN'T ABUSE PORTO'S WEAPON SLOT
 933
 934         if(g_minstagib)
 935         {
 936                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 937                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 938         }
 939         else if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 940         {
 941                 start_ammo_rockets = 999;
 942                 start_ammo_shells = 999;
 943                 start_ammo_cells = 999;
 944                 start_ammo_nails = 999;
 945                 start_ammo_fuel = 999;
 946         }
 947         else
 948         {
 949                 if(g_lms || g_ca)
 950                 {
 951                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 952                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 953                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 954                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 955                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
 956                 }
 957                 else
 958                 {
 959                         start_ammo_shells = cvar("g_start_ammo_shells");
 960                         start_ammo_nails = cvar("g_start_ammo_nails");
 961                         start_ammo_rockets = cvar("g_start_ammo_rockets");
 962                         start_ammo_cells = cvar("g_start_ammo_cells");
 963                         start_ammo_fuel = cvar("g_start_ammo_fuel");
 964                 }
 965         }
 966
 967         if (g_lms || g_ca)
 968         {
 969                 start_health = cvar("g_lms_start_health");
 970                 start_armorvalue = cvar("g_lms_start_armor");
 971         }
 972
 973         if (inWarmupStage)
 974         {
 975                 warmup_start_ammo_shells = start_ammo_shells;
 976                 warmup_start_ammo_nails = start_ammo_nails;
 977                 warmup_start_ammo_rockets = start_ammo_rockets;
 978                 warmup_start_ammo_cells = start_ammo_cells;
 979                 warmup_start_ammo_fuel = start_ammo_fuel;
 980                 warmup_start_health = start_health;
 981                 warmup_start_armorvalue = start_armorvalue;
 982                 warmup_start_weapons = start_weapons;
 983
 984                 if (!g_weaponarena && !g_minstagib && !g_ca)
 985                 {
 986                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 987                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 988                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 989                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 990                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 991                         warmup_start_health = cvar("g_warmup_start_health");
 992                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 993                         warmup_start_weapons = 0;
 994                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 995                         {
 996                                 e = get_weaponinfo(i);
 997                                 if(want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns")))
 998                                         warmup_start_weapons |= e.weapons;
 999                         }
1000                 }
1001         }
1002
1003         if (g_jetpack || (g_grappling_hook && (start_weapons & WEPBIT_HOOK)))
1004         {
1005                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1006                 start_items |= IT_FUEL_REGEN;
1007                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1008                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1009         }
1010
1011         if (g_jetpack)
1012                 start_items |= IT_JETPACK;
1013
1014         MUTATOR_CALLHOOK(SetStartItems);
1015
1016         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1017         {
1018                 e = get_weaponinfo(i);
1019                 if(e.weapons & (start_weapons | warmup_start_weapons))
1020                         weapon_action(e.weapon, WR_PRECACHE);
1021         }
1022
1023         start_ammo_shells = max(0, start_ammo_shells);
1024         start_ammo_nails = max(0, start_ammo_nails);
1025         start_ammo_cells = max(0, start_ammo_cells);
1026         start_ammo_rockets = max(0, start_ammo_rockets);
1027         start_ammo_fuel = max(0, start_ammo_fuel);
1028
1029         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1030         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1031         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1032         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1033         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1034 }
1035
1036 float g_bugrigs;
1037 float g_bugrigs_planar_movement;
1038 float g_bugrigs_planar_movement_car_jumping;
1039 float g_bugrigs_reverse_spinning;
1040 float g_bugrigs_reverse_speeding;
1041 float g_bugrigs_reverse_stopping;
1042 float g_bugrigs_air_steering;
1043 float g_bugrigs_angle_smoothing;
1044 float g_bugrigs_friction_floor;
1045 float g_bugrigs_friction_brake;
1046 float g_bugrigs_friction_air;
1047 float g_bugrigs_accel;
1048 float g_bugrigs_speed_ref;
1049 float g_bugrigs_speed_pow;
1050 float g_bugrigs_steer;
1051
1052 float g_touchexplode;
1053 float g_touchexplode_radius;
1054 float g_touchexplode_damage;
1055 float g_touchexplode_edgedamage;
1056 float g_touchexplode_force;
1057
1058 float sv_autotaunt;
1059 float sv_taunt;
1060
1061 float sv_pitch_min;
1062 float sv_pitch_max;
1063 float sv_pitch_fixyaw;
1064
1065 string GetGametype(); // g_world.qc
1066 void readlevelcvars(void)
1067 {
1068         // first load all the mutators
1069         if(cvar("g_invincible_projectiles"))
1070                 MUTATOR_ADD(mutator_invincibleprojectiles);
1071         if(cvar("g_nix"))
1072                 MUTATOR_ADD(mutator_nix);
1073         if(cvar("g_dodging"))
1074                 MUTATOR_ADD(mutator_dodging);
1075         if(cvar("g_rocket_flying"))
1076                 MUTATOR_ADD(mutator_rocketflying);
1077         if(cvar("g_vampire"))
1078                 MUTATOR_ADD(mutator_vampire);
1079         if(cvar("g_spawn_near_teammate"))
1080                 MUTATOR_ADD(mutator_spawn_near_teammate);
1081
1082         // is this a mutator? is this a mode?
1083         if(cvar("g_sandbox"))
1084                 MUTATOR_ADD(sandbox);
1085
1086         if(cvar("sv_allow_fullbright"))
1087                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1088
1089     g_bugrigs = cvar("g_bugrigs");
1090     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1091     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1092     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1093     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1094     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1095     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1096     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1097     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1098     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1099     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1100     g_bugrigs_accel = cvar("g_bugrigs_accel");
1101     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1102     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1103     g_bugrigs_steer = cvar("g_bugrigs_steer");
1104
1105     g_touchexplode = cvar("g_touchexplode");
1106     g_touchexplode_radius = cvar("g_touchexplode_radius");
1107     g_touchexplode_damage = cvar("g_touchexplode_damage");
1108     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1109     g_touchexplode_force = cvar("g_touchexplode_force");
1110
1111 #ifdef ALLOW_FORCEMODELS
1112         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1113 #endif
1114
1115         sv_clones = cvar("sv_clones");
1116         sv_gentle = cvar("sv_gentle");
1117         sv_foginterval = cvar("sv_foginterval");
1118         g_cloaked = cvar("g_cloaked");
1119     if(g_cts)
1120         g_cloaked = 1; // always enable cloak in CTS
1121         g_jump_grunt = cvar("g_jump_grunt");
1122         g_footsteps = cvar("g_footsteps");
1123         g_grappling_hook = cvar("g_grappling_hook");
1124         g_jetpack = cvar("g_jetpack");
1125         g_midair = cvar("g_midair");
1126         g_minstagib = cvar("g_minstagib");
1127         g_norecoil = cvar("g_norecoil");
1128         g_bloodloss = cvar("g_bloodloss");
1129         sv_maxidle = cvar("sv_maxidle");
1130         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1131         g_ctf_reverse = cvar("g_ctf_reverse");
1132         sv_autotaunt = cvar("sv_autotaunt");
1133         sv_taunt = cvar("sv_taunt");
1134
1135         inWarmupStage = cvar("g_warmup");
1136         g_warmup_limit = cvar("g_warmup_limit");
1137         g_warmup_allguns = cvar("g_warmup_allguns");
1138         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1139
1140         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1141                 inWarmupStage = 0; // these modes cannot work together, sorry
1142
1143         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1144         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
1145         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1146         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1147         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1148         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1149         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1150         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1151         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
1152         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1153         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1154         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1155         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1156         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1157
1158         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1159         g_weaponratefactor = cvar("g_weaponratefactor");
1160         g_weapondamagefactor = cvar("g_weapondamagefactor");
1161         g_weaponforcefactor = cvar("g_weaponforcefactor");
1162         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1163
1164         g_pickup_shells = cvar("g_pickup_shells");
1165         g_pickup_shells_max = cvar("g_pickup_shells_max");
1166         g_pickup_nails = cvar("g_pickup_nails");
1167         g_pickup_nails_max = cvar("g_pickup_nails_max");
1168         g_pickup_rockets = cvar("g_pickup_rockets");
1169         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1170         g_pickup_cells = cvar("g_pickup_cells");
1171         g_pickup_cells_max = cvar("g_pickup_cells_max");
1172         g_pickup_fuel = cvar("g_pickup_fuel");
1173         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1174         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1175         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1176         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1177         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1178         g_pickup_armormedium = cvar("g_pickup_armormedium");
1179         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1180         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1181         g_pickup_armorbig = cvar("g_pickup_armorbig");
1182         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1183         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1184         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1185         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1186         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1187         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1188         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1189         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1190         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1191         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1192         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1193         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1194         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1195         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1196         g_pickup_healthmega = cvar("g_pickup_healthmega");
1197         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1198         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1199
1200         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1201         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1202
1203         g_pinata = cvar("g_pinata");
1204
1205     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1206     if(!g_weapon_stay)
1207         g_weapon_stay = cvar("g_weapon_stay");
1208
1209         g_ghost_items = cvar("g_ghost_items");
1210
1211         if(g_ghost_items >= 1)
1212                 g_ghost_items = 0.25; // default alpha value
1213
1214         if not(inWarmupStage && !g_ca)
1215                 game_starttime = cvar("g_start_delay");
1216
1217         sv_pitch_min = cvar("sv_pitch_min");
1218         sv_pitch_max = cvar("sv_pitch_max");
1219         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1220
1221         readplayerstartcvars();
1222 }
1223
1224 //#NO AUTOCVARS END
1225
1226 // Sound functions
1227 string precache_sound (string s) = #19;
1228 float precache_sound_index (string s) = #19;
1229
1230 #define SND_VOLUME      1
1231 #define SND_ATTENUATION 2
1232 #define SND_LARGEENTITY 8
1233 #define SND_LARGESOUND  16
1234
1235 float sound_allowed(float dest, entity e)
1236 {
1237     // sounds from world may always pass
1238     for (;;)
1239     {
1240         if (e.classname == "body")
1241             e = e.enemy;
1242         else if (e.realowner && e.realowner != e)
1243             e = e.realowner;
1244         else if (e.owner && e.owner != e)
1245             e = e.owner;
1246         else
1247             break;
1248     }
1249     // sounds to self may always pass
1250     if (dest == MSG_ONE)
1251         if (e == msg_entity)
1252             return TRUE;
1253     // sounds by players can be removed
1254     if (autocvar_bot_sound_monopoly)
1255         if (clienttype(e) == CLIENTTYPE_REAL)
1256             return FALSE;
1257     // anything else may pass
1258     return TRUE;
1259 }
1260
1261 #ifdef COMPAT_XON010_CHANNELS
1262 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1263 void sound(entity e, float chan, string samp, float vol, float atten)
1264 {
1265     if (!sound_allowed(MSG_BROADCAST, e))
1266         return;
1267     builtin_sound(e, chan, samp, vol, atten);
1268 }
1269 #else
1270 #undef sound
1271 void sound(entity e, float chan, string samp, float vol, float atten)
1272 {
1273     if (!sound_allowed(MSG_BROADCAST, e))
1274         return;
1275     sound7(e, chan, samp, vol, atten, 0, 0);
1276 }
1277 #endif
1278
1279 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1280 {
1281     float entno, idx;
1282
1283     if (!sound_allowed(dest, e))
1284         return;
1285
1286     entno = num_for_edict(e);
1287     idx = precache_sound_index(samp);
1288
1289     float sflags;
1290     sflags = 0;
1291
1292     atten = floor(atten * 64);
1293     vol = floor(vol * 255);
1294
1295     if (vol != 255)
1296         sflags |= SND_VOLUME;
1297     if (atten != 64)
1298         sflags |= SND_ATTENUATION;
1299     if (entno >= 8192 || chan < 0 || chan > 7)
1300         sflags |= SND_LARGEENTITY;
1301     if (idx >= 256)
1302         sflags |= SND_LARGESOUND;
1303
1304     WriteByte(dest, SVC_SOUND);
1305     WriteByte(dest, sflags);
1306     if (sflags & SND_VOLUME)
1307         WriteByte(dest, vol);
1308     if (sflags & SND_ATTENUATION)
1309         WriteByte(dest, atten);
1310     if (sflags & SND_LARGEENTITY)
1311     {
1312         WriteShort(dest, entno);
1313         WriteByte(dest, chan);
1314     }
1315     else
1316     {
1317         WriteShort(dest, entno * 8 + chan);
1318     }
1319     if (sflags & SND_LARGESOUND)
1320         WriteShort(dest, idx);
1321     else
1322         WriteByte(dest, idx);
1323
1324     WriteCoord(dest, o_x);
1325     WriteCoord(dest, o_y);
1326     WriteCoord(dest, o_z);
1327 }
1328 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1329 {
1330     vector o;
1331
1332     if (!sound_allowed(dest, e))
1333         return;
1334
1335     o = e.origin + 0.5 * (e.mins + e.maxs);
1336     soundtoat(dest, e, o, chan, samp, vol, atten);
1337 }
1338 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1339 {
1340     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1341 }
1342 void stopsoundto(float dest, entity e, float chan)
1343 {
1344     float entno;
1345
1346     if (!sound_allowed(dest, e))
1347         return;
1348
1349     entno = num_for_edict(e);
1350
1351     if (entno >= 8192 || chan < 0 || chan > 7)
1352     {
1353         float idx, sflags;
1354         idx = precache_sound_index("misc/null.wav");
1355         sflags = SND_LARGEENTITY;
1356         if (idx >= 256)
1357             sflags |= SND_LARGESOUND;
1358         WriteByte(dest, SVC_SOUND);
1359         WriteByte(dest, sflags);
1360         WriteShort(dest, entno);
1361         WriteByte(dest, chan);
1362         if (sflags & SND_LARGESOUND)
1363             WriteShort(dest, idx);
1364         else
1365             WriteByte(dest, idx);
1366         WriteCoord(dest, e.origin_x);
1367         WriteCoord(dest, e.origin_y);
1368         WriteCoord(dest, e.origin_z);
1369     }
1370     else
1371     {
1372         WriteByte(dest, SVC_STOPSOUND);
1373         WriteShort(dest, entno * 8 + chan);
1374     }
1375 }
1376 void stopsound(entity e, float chan)
1377 {
1378     if (!sound_allowed(MSG_BROADCAST, e))
1379         return;
1380
1381     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1382     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1383 }
1384
1385 void play2(entity e, string filename)
1386 {
1387     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1388     msg_entity = e;
1389     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1390 }
1391
1392 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1393 .float spamtime;
1394 float spamsound(entity e, float chan, string samp, float vol, float atten)
1395 {
1396     if (!sound_allowed(MSG_BROADCAST, e))
1397         return FALSE;
1398
1399     if (time > e.spamtime)
1400     {
1401         e.spamtime = time;
1402         sound(e, chan, samp, vol, atten);
1403         return TRUE;
1404     }
1405     return FALSE;
1406 }
1407
1408 void play2team(float t, string filename)
1409 {
1410     entity head;
1411
1412     if (autocvar_bot_sound_monopoly)
1413         return;
1414
1415     FOR_EACH_REALPLAYER(head)
1416     {
1417         if (head.team == t)
1418             play2(head, filename);
1419     }
1420 }
1421
1422 void play2all(string samp)
1423 {
1424     if (autocvar_bot_sound_monopoly)
1425         return;
1426
1427     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1428 }
1429
1430 void PrecachePlayerSounds(string f);
1431 void precache_playermodel(string m)
1432 {
1433         float globhandle, i, n;
1434         string f;
1435
1436         if(substring(m, -9,5) == "_lod1")
1437                 return;
1438         if(substring(m, -9,5) == "_lod2")
1439                 return;
1440         precache_model(m);
1441         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1442         if(fexists(f))
1443                 precache_model(f);
1444         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1445         if(fexists(f))
1446                 precache_model(f);
1447
1448         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1449         if (globhandle < 0)
1450                 return;
1451         n = search_getsize(globhandle);
1452         for (i = 0; i < n; ++i)
1453         {
1454                 //print(search_getfilename(globhandle, i), "\n");
1455                 f = search_getfilename(globhandle, i);
1456                 PrecachePlayerSounds(f);
1457         }
1458         search_end(globhandle);
1459 }
1460 void precache_all_playermodels(string pattern)
1461 {
1462         float globhandle, i, n;
1463         string f;
1464
1465         globhandle = search_begin(pattern, TRUE, FALSE);
1466         if (globhandle < 0)
1467                 return;
1468         n = search_getsize(globhandle);
1469         for (i = 0; i < n; ++i)
1470         {
1471                 //print(search_getfilename(globhandle, i), "\n");
1472                 f = search_getfilename(globhandle, i);
1473                 precache_playermodel(f);
1474         }
1475         search_end(globhandle);
1476 }
1477
1478 void precache()
1479 {
1480     // gamemode related things
1481     precache_model ("models/misc/chatbubble.spr");
1482     if (g_runematch)
1483     {
1484         precache_model ("models/runematch/curse.mdl");
1485         precache_model ("models/runematch/rune.mdl");
1486     }
1487
1488 #ifdef TTURRETS_ENABLED
1489     if (autocvar_g_turrets)
1490         turrets_precash();
1491 #endif
1492
1493     // Precache all player models if desired
1494     if (autocvar_sv_precacheplayermodels)
1495     {
1496         PrecachePlayerSounds("sound/player/default.sounds");
1497         precache_all_playermodels("models/player/*.zym");
1498         precache_all_playermodels("models/player/*.dpm");
1499         precache_all_playermodels("models/player/*.md3");
1500         precache_all_playermodels("models/player/*.psk");
1501         precache_all_playermodels("models/player/*.iqm");
1502     }
1503
1504     if (autocvar_sv_defaultcharacter)
1505     {
1506         string s;
1507         s = autocvar_sv_defaultplayermodel_red;
1508         if (s != "")
1509             precache_playermodel(s);
1510         s = autocvar_sv_defaultplayermodel_blue;
1511         if (s != "")
1512             precache_playermodel(s);
1513         s = autocvar_sv_defaultplayermodel_yellow;
1514         if (s != "")
1515             precache_playermodel(s);
1516         s = autocvar_sv_defaultplayermodel_pink;
1517         if (s != "")
1518             precache_playermodel(s);
1519         s = autocvar_sv_defaultplayermodel;
1520         if (s != "")
1521             precache_playermodel(s);
1522     }
1523
1524     if (g_footsteps)
1525     {
1526         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1527         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1528     }
1529
1530     // gore and miscellaneous sounds
1531     //precache_sound ("misc/h2ohit.wav");
1532     precache_model ("models/hook.md3");
1533     precache_sound ("misc/armorimpact.wav");
1534     precache_sound ("misc/bodyimpact1.wav");
1535     precache_sound ("misc/bodyimpact2.wav");
1536     precache_sound ("misc/gib.wav");
1537     precache_sound ("misc/gib_splat01.wav");
1538     precache_sound ("misc/gib_splat02.wav");
1539     precache_sound ("misc/gib_splat03.wav");
1540     precache_sound ("misc/gib_splat04.wav");
1541     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1542     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1543     precache_sound ("misc/null.wav");
1544     precache_sound ("misc/spawn.wav");
1545     precache_sound ("misc/talk.wav");
1546     precache_sound ("misc/teleport.wav");
1547     precache_sound ("misc/poweroff.wav");
1548     precache_sound ("player/lava.wav");
1549     precache_sound ("player/slime.wav");
1550
1551     if (g_jetpack)
1552         precache_sound ("misc/jetpack_fly.wav");
1553
1554     precache_model ("models/sprites/0.spr32");
1555     precache_model ("models/sprites/1.spr32");
1556     precache_model ("models/sprites/2.spr32");
1557     precache_model ("models/sprites/3.spr32");
1558     precache_model ("models/sprites/4.spr32");
1559     precache_model ("models/sprites/5.spr32");
1560     precache_model ("models/sprites/6.spr32");
1561     precache_model ("models/sprites/7.spr32");
1562     precache_model ("models/sprites/8.spr32");
1563     precache_model ("models/sprites/9.spr32");
1564     precache_model ("models/sprites/10.spr32");
1565
1566     // common weapon precaches
1567         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1568     precache_sound ("weapons/weapon_switch.wav");
1569     precache_sound ("weapons/weaponpickup.wav");
1570     precache_sound ("weapons/unavailable.wav");
1571     precache_sound ("weapons/dryfire.wav");
1572     if (g_grappling_hook)
1573     {
1574         precache_sound ("weapons/hook_fire.wav"); // hook
1575         precache_sound ("weapons/hook_impact.wav"); // hook
1576     }
1577
1578     if(autocvar_sv_precacheweapons)
1579     {
1580         //precache weapon models/sounds
1581         float wep;
1582         wep = WEP_FIRST;
1583         while (wep <= WEP_LAST)
1584         {
1585             weapon_action(wep, WR_PRECACHE);
1586             wep = wep + 1;
1587         }
1588     }
1589
1590     precache_model("models/elaser.mdl");
1591     precache_model("models/laser.mdl");
1592     precache_model("models/ebomb.mdl");
1593
1594 #if 0
1595     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1596
1597     if (!self.noise && self.music) // quake 3 uses the music field
1598         self.noise = self.music;
1599
1600     // plays music for the level if there is any
1601     if (self.noise)
1602     {
1603         precache_sound (self.noise);
1604         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1605     }
1606 #endif
1607 }
1608
1609 // sorry, but using \ in macros breaks line numbers
1610 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1611 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1612 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1613
1614
1615 void Send_CSQC_Centerprint_Generic(entity e, float id, string s, float duration, float countdown_num)
1616 {
1617         if ((clienttype(e) == CLIENTTYPE_REAL) && (e.flags & FL_CLIENT))
1618         {
1619                 msg_entity = e;
1620                 WRITESPECTATABLE_MSG_ONE({
1621                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1622                         WriteByte(MSG_ONE, TE_CSQC_CENTERPRINT_GENERIC);
1623                         WriteByte(MSG_ONE, id);
1624                         WriteString(MSG_ONE, s);
1625                         if (id != 0 && s != "")
1626                         {
1627                                 WriteByte(MSG_ONE, duration);
1628                                 WriteByte(MSG_ONE, countdown_num);
1629                         }
1630                 });
1631         }
1632 }
1633 void Send_CSQC_Centerprint_Generic_Expire(entity e, float id)
1634 {
1635         Send_CSQC_Centerprint_Generic(e, id, "", 1, 0);
1636 }
1637 // WARNING: this kills the trace globals
1638 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1639 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1640
1641 #define INITPRIO_FIRST              0
1642 #define INITPRIO_GAMETYPE           0
1643 #define INITPRIO_GAMETYPE_FALLBACK  1
1644 #define INITPRIO_FINDTARGET        10
1645 #define INITPRIO_DROPTOFLOOR       20
1646 #define INITPRIO_SETLOCATION       90
1647 #define INITPRIO_LINKDOORS         91
1648 #define INITPRIO_LAST              99
1649
1650 .void(void) initialize_entity;
1651 .float initialize_entity_order;
1652 .entity initialize_entity_next;
1653 entity initialize_entity_first;
1654
1655 void make_safe_for_remove(entity e)
1656 {
1657     if (e.initialize_entity)
1658     {
1659         entity ent, prev;
1660         for (ent = initialize_entity_first; ent; )
1661         {
1662             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1663             {
1664                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1665                 // skip it in linked list
1666                 if (prev)
1667                 {
1668                     prev.initialize_entity_next = ent.initialize_entity_next;
1669                     ent = prev.initialize_entity_next;
1670                 }
1671                 else
1672                 {
1673                     initialize_entity_first = ent.initialize_entity_next;
1674                     ent = initialize_entity_first;
1675                 }
1676             }
1677             else
1678             {
1679                 prev = ent;
1680                 ent = ent.initialize_entity_next;
1681             }
1682         }
1683     }
1684 }
1685
1686 void objerror(string s)
1687 {
1688     make_safe_for_remove(self);
1689     builtin_objerror(s);
1690 }
1691
1692 .float remove_except_protected_forbidden;
1693 void remove_except_protected(entity e)
1694 {
1695         if(e.remove_except_protected_forbidden)
1696                 error("not allowed to remove this at this point");
1697         builtin_remove(e);
1698 }
1699
1700 void remove_unsafely(entity e)
1701 {
1702     if(e.classname == "spike")
1703         error("Removing spikes is forbidden (crylink bug), please report");
1704     builtin_remove(e);
1705 }
1706
1707 void remove_safely(entity e)
1708 {
1709     make_safe_for_remove(e);
1710     builtin_remove(e);
1711 }
1712
1713 void InitializeEntity(entity e, void(void) func, float order)
1714 {
1715     entity prev, cur;
1716
1717     if (!e || e.initialize_entity)
1718     {
1719         // make a proxy initializer entity
1720         entity e_old;
1721         e_old = e;
1722         e = spawn();
1723         e.classname = "initialize_entity";
1724         e.enemy = e_old;
1725     }
1726
1727     e.initialize_entity = func;
1728     e.initialize_entity_order = order;
1729
1730     cur = initialize_entity_first;
1731     for (;;)
1732     {
1733         if (!cur || cur.initialize_entity_order > order)
1734         {
1735             // insert between prev and cur
1736             if (prev)
1737                 prev.initialize_entity_next = e;
1738             else
1739                 initialize_entity_first = e;
1740             e.initialize_entity_next = cur;
1741             return;
1742         }
1743         prev = cur;
1744         cur = cur.initialize_entity_next;
1745     }
1746 }
1747 void InitializeEntitiesRun()
1748 {
1749     entity startoflist;
1750     startoflist = initialize_entity_first;
1751     initialize_entity_first = world;
1752     remove = remove_except_protected;
1753     for (self = startoflist; self; self = self.initialize_entity_next)
1754     {
1755         self.remove_except_protected_forbidden = 1;
1756     }
1757     for (self = startoflist; self; )
1758     {
1759         entity e;
1760         var void(void) func;
1761         e = self.initialize_entity_next;
1762         func = self.initialize_entity;
1763         self.initialize_entity_order = 0;
1764         self.initialize_entity = func_null;
1765         self.initialize_entity_next = world;
1766         self.remove_except_protected_forbidden = 0;
1767         if (self.classname == "initialize_entity")
1768         {
1769             entity e_old;
1770             e_old = self.enemy;
1771             builtin_remove(self);
1772             self = e_old;
1773         }
1774         //dprint("Delayed initialization: ", self.classname, "\n");
1775         if(func != func_null)
1776             func();
1777         else
1778         {
1779             eprint(self);
1780             backtrace(strcat("Null function in: ", self.classname, "\n"));
1781         }
1782         self = e;
1783     }
1784     remove = remove_unsafely;
1785 }
1786
1787 .float uncustomizeentityforclient_set;
1788 .void(void) uncustomizeentityforclient;
1789 void(void) SUB_Nullpointer = #0;
1790 void UncustomizeEntitiesRun()
1791 {
1792     entity oldself;
1793     oldself = self;
1794     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1795         self.uncustomizeentityforclient();
1796     self = oldself;
1797 }
1798 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1799 {
1800     e.customizeentityforclient = customizer;
1801     e.uncustomizeentityforclient = uncustomizer;
1802     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1803 }
1804
1805 .float nottargeted;
1806 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1807
1808 void() SUB_Remove;
1809 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1810 {
1811     vector mi, ma;
1812
1813     if (e.classname == "")
1814         e.classname = "net_linked";
1815
1816     if (e.model == "" || self.modelindex == 0)
1817     {
1818         mi = e.mins;
1819         ma = e.maxs;
1820         setmodel(e, "null");
1821         setsize(e, mi, ma);
1822     }
1823
1824     e.SendEntity = sendfunc;
1825     e.SendFlags = 0xFFFFFF;
1826
1827     if (!docull)
1828         e.effects |= EF_NODEPTHTEST;
1829
1830     if (dt)
1831     {
1832         e.nextthink = time + dt;
1833         e.think = SUB_Remove;
1834     }
1835 }
1836
1837 void adaptor_think2touch()
1838 {
1839     entity o;
1840     o = other;
1841     other = world;
1842     self.touch();
1843     other = o;
1844 }
1845
1846 void adaptor_think2use()
1847 {
1848     entity o, a;
1849     o = other;
1850     a = activator;
1851     activator = world;
1852     other = world;
1853     self.use();
1854     other = o;
1855     activator = a;
1856 }
1857
1858 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1859 {
1860         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1861                 self.projectiledeathtype |= HITTYPE_SPLASH;
1862         adaptor_think2use();
1863 }
1864
1865 // deferred dropping
1866 void DropToFloor_Handler()
1867 {
1868     builtin_droptofloor();
1869     self.dropped_origin = self.origin;
1870 }
1871
1872 void droptofloor()
1873 {
1874     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1875 }
1876
1877
1878
1879 float trace_hits_box_a0, trace_hits_box_a1;
1880
1881 float trace_hits_box_1d(float end, float thmi, float thma)
1882 {
1883     if (end == 0)
1884     {
1885         // just check if x is in range
1886         if (0 < thmi)
1887             return FALSE;
1888         if (0 > thma)
1889             return FALSE;
1890     }
1891     else
1892     {
1893         // do the trace with respect to x
1894         // 0 -> end has to stay in thmi -> thma
1895         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1896         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1897         if (trace_hits_box_a0 > trace_hits_box_a1)
1898             return FALSE;
1899     }
1900     return TRUE;
1901 }
1902
1903 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1904 {
1905     end -= start;
1906     thmi -= start;
1907     thma -= start;
1908     // now it is a trace from 0 to end
1909
1910     trace_hits_box_a0 = 0;
1911     trace_hits_box_a1 = 1;
1912
1913     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1914         return FALSE;
1915     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1916         return FALSE;
1917     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1918         return FALSE;
1919
1920     return TRUE;
1921 }
1922
1923 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1924 {
1925     return trace_hits_box(start, end, thmi - ma, thma - mi);
1926 }
1927
1928 float SUB_NoImpactCheck()
1929 {
1930         // zero hitcontents = this is not the real impact, but either the
1931         // mirror-impact of something hitting the projectile instead of the
1932         // projectile hitting the something, or a touchareagrid one. Neither of
1933         // these stop the projectile from moving, so...
1934         if(trace_dphitcontents == 0)
1935         {
1936                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1937                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1938                 checkclient();
1939         }
1940     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1941         return 1;
1942     if (other == world && self.size != '0 0 0')
1943     {
1944         vector tic;
1945         tic = self.velocity * sys_frametime;
1946         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1947         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1948         if (trace_fraction >= 1)
1949         {
1950             dprint("Odd... did not hit...?\n");
1951         }
1952         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1953         {
1954             dprint("Detected and prevented the sky-grapple bug.\n");
1955             return 1;
1956         }
1957     }
1958
1959     return 0;
1960 }
1961
1962 #define SUB_OwnerCheck() (other && (other == self.owner))
1963
1964 void RemoveGrapplingHook(entity pl);
1965 void W_Crylink_Dequeue(entity e);
1966 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1967 {
1968         if(SUB_OwnerCheck())
1969                 return TRUE;
1970         if(SUB_NoImpactCheck())
1971         {
1972                 if(self.classname == "grapplinghook")
1973                         RemoveGrapplingHook(self.realowner);
1974                 else if(self.classname == "spike")
1975                 {
1976                         W_Crylink_Dequeue(self);
1977                         remove(self);
1978                 }
1979                 else
1980                         remove(self);
1981                 return TRUE;
1982         }
1983         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1984                 UpdateCSQCProjectile(self);
1985         return FALSE;
1986 }
1987 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1988
1989 void URI_Get_Callback(float id, float status, string data)
1990 {
1991         if(url_URI_Get_Callback(id, status, data))
1992         {
1993                 // handled
1994         }
1995         else if (id == URI_GET_DISCARD)
1996         {
1997                 // discard
1998         }
1999         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
2000         {
2001                 // sv_cmd curl
2002                 Curl_URI_Get_Callback(id, status, data);
2003         }
2004         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2005         {
2006                 // online ban list
2007                 OnlineBanList_URI_Get_Callback(id, status, data);
2008         }
2009         else
2010         {
2011                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2012         }
2013 }
2014
2015 string uid2name(string myuid) {
2016         string s;
2017         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
2018
2019         // FIXME remove this later after 0.6 release
2020         // convert old style broken records to correct style
2021         if(s == "")
2022         {
2023                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
2024                 if(s != "")
2025                 {
2026                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
2027                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
2028                 }
2029         }
2030
2031         if(s == "")
2032                 s = "^1Unregistered Player";
2033         return s;
2034 }
2035
2036 float race_readTime(string map, float pos)
2037 {
2038         string rr;
2039         if(g_cts)
2040                 rr = CTS_RECORD;
2041         else
2042                 rr = RACE_RECORD;
2043
2044         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
2045 }
2046
2047 string race_readUID(string map, float pos)
2048 {
2049         string rr;
2050         if(g_cts)
2051                 rr = CTS_RECORD;
2052         else
2053                 rr = RACE_RECORD;
2054
2055         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
2056 }
2057
2058 float race_readPos(string map, float t) {
2059         float i;
2060         for (i = 1; i <= RANKINGS_CNT; ++i)
2061                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
2062                         return i;
2063
2064         return 0; // pos is zero if unranked
2065 }
2066
2067 void race_writeTime(string map, float t, string myuid)
2068 {
2069         string rr;
2070         if(g_cts)
2071                 rr = CTS_RECORD;
2072         else
2073                 rr = RACE_RECORD;
2074
2075         float newpos;
2076         newpos = race_readPos(map, t);
2077
2078         float i, prevpos;
2079         for(i = 1; i <= RANKINGS_CNT; ++i)
2080         {
2081                 if(race_readUID(map, i) == myuid)
2082                         prevpos = i;
2083         }
2084         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
2085                 for (i = prevpos; i > newpos; --i) {
2086                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2087                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2088                 }
2089         } else { // player has no ranked record yet
2090                 for (i = RANKINGS_CNT; i > newpos; --i) {
2091                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2092                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2093                 }
2094         }
2095
2096         // store new time itself
2097         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2098         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2099 }
2100
2101 string race_readName(string map, float pos)
2102 {
2103         string rr;
2104         if(g_cts)
2105                 rr = CTS_RECORD;
2106         else
2107                 rr = RACE_RECORD;
2108
2109         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2110 }
2111
2112 string race_placeName(float pos) {
2113         if(floor((mod(pos, 100))/10) * 10 != 10) // examples: 12th, 111th, 213th will not execute this block
2114         {
2115                 if(mod(pos, 10) == 1)
2116                         return strcat(ftos(pos), "st");
2117                 else if(mod(pos, 10) == 2)
2118                         return strcat(ftos(pos), "nd");
2119                 else if(mod(pos, 10) == 3)
2120                         return strcat(ftos(pos), "rd");
2121                 else
2122                         return strcat(ftos(pos), "th");
2123         }
2124         else
2125                 return strcat(ftos(pos), "th");
2126 }
2127
2128 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2129 {
2130     float m, i;
2131     vector start, org, delta, end, enddown, mstart;
2132     entity sp;
2133
2134     m = e.dphitcontentsmask;
2135     e.dphitcontentsmask = goodcontents | badcontents;
2136
2137     org = world.mins;
2138     delta = world.maxs - world.mins;
2139
2140     for (i = 0; i < attempts; ++i)
2141     {
2142         start_x = org_x + random() * delta_x;
2143         start_y = org_y + random() * delta_y;
2144         start_z = org_z + random() * delta_z;
2145
2146         // rule 1: start inside world bounds, and outside
2147         // solid, and don't start from somewhere where you can
2148         // fall down to evil
2149         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2150         if (trace_fraction >= 1)
2151             continue;
2152         if (trace_startsolid)
2153             continue;
2154         if (trace_dphitcontents & badcontents)
2155             continue;
2156         if (trace_dphitq3surfaceflags & badsurfaceflags)
2157             continue;
2158
2159         // rule 2: if we are too high, lower the point
2160         if (trace_fraction * delta_z > maxaboveground)
2161             start = trace_endpos + '0 0 1' * maxaboveground;
2162         enddown = trace_endpos;
2163
2164         // rule 3: make sure we aren't outside the map. This only works
2165         // for somewhat well formed maps. A good rule of thumb is that
2166         // the map should have a convex outside hull.
2167         // these can be traceLINES as we already verified the starting box
2168         mstart = start + 0.5 * (e.mins + e.maxs);
2169         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2170         if (trace_fraction >= 1)
2171             continue;
2172         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2173         if (trace_fraction >= 1)
2174             continue;
2175         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2176         if (trace_fraction >= 1)
2177             continue;
2178         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2179         if (trace_fraction >= 1)
2180             continue;
2181         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2182         if (trace_fraction >= 1)
2183             continue;
2184
2185         // rule 4: we must "see" some spawnpoint
2186         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
2187                 if(checkpvs(mstart, sp))
2188                         break;
2189         if(!sp)
2190         {
2191                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
2192                         if(checkpvs(mstart, sp))
2193                                 break;
2194                 if(!sp)
2195                         continue;
2196         }
2197
2198         // find a random vector to "look at"
2199         end_x = org_x + random() * delta_x;
2200         end_y = org_y + random() * delta_y;
2201         end_z = org_z + random() * delta_z;
2202         end = start + normalize(end - start) * vlen(delta);
2203
2204         // rule 4: start TO end must not be too short
2205         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2206         if (trace_startsolid)
2207             continue;
2208         if (trace_fraction < minviewdistance / vlen(delta))
2209             continue;
2210
2211         // rule 5: don't want to look at sky
2212         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2213             continue;
2214
2215         // rule 6: we must not end up in trigger_hurt
2216         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2217             continue;
2218
2219         break;
2220     }
2221
2222     e.dphitcontentsmask = m;
2223
2224     if (i < attempts)
2225     {
2226         setorigin(e, start);
2227         e.angles = vectoangles(end - start);
2228         dprint("Needed ", ftos(i + 1), " attempts\n");
2229         return TRUE;
2230     }
2231     else
2232         return FALSE;
2233 }
2234
2235 float zcurveparticles_effectno;
2236 vector zcurveparticles_start;
2237 float zcurveparticles_spd;
2238
2239 void endzcurveparticles()
2240 {
2241         if(zcurveparticles_effectno)
2242         {
2243                 // terminator
2244                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2245         }
2246         zcurveparticles_effectno = 0;
2247 }
2248
2249 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2250 {
2251         spd = bound(0, floor(spd / 16), 32767);
2252         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2253         {
2254                 endzcurveparticles();
2255                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2256                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2257                 WriteShort(MSG_BROADCAST, effectno);
2258                 WriteCoord(MSG_BROADCAST, start_x);
2259                 WriteCoord(MSG_BROADCAST, start_y);
2260                 WriteCoord(MSG_BROADCAST, start_z);
2261                 zcurveparticles_effectno = effectno;
2262                 zcurveparticles_start = start;
2263         }
2264         else
2265                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2266         WriteCoord(MSG_BROADCAST, end_x);
2267         WriteCoord(MSG_BROADCAST, end_y);
2268         WriteCoord(MSG_BROADCAST, end_z);
2269         WriteCoord(MSG_BROADCAST, end_dz);
2270         zcurveparticles_spd = spd;
2271 }
2272
2273 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2274 {
2275         float end_dz;
2276         vector vecxy, velxy;
2277
2278         vecxy = end - start;
2279         vecxy_z = 0;
2280         velxy = vel;
2281         velxy_z = 0;
2282
2283         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2284         {
2285                 endzcurveparticles();
2286                 trailparticles(world, effectno, start, end);
2287                 return;
2288         }
2289
2290         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2291         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2292 }
2293
2294 void write_recordmarker(entity pl, float tstart, float dt)
2295 {
2296     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2297
2298     // also write a marker into demo files for demotc-race-record-extractor to find
2299     stuffcmd(pl,
2300              strcat(
2301                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2302                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2303 }
2304
2305 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2306 {
2307         switch(algn)
2308         {
2309                 default:
2310                 case 3: // right
2311                         break;
2312
2313                 case 4: // left
2314                         vecs_y = -vecs_y;
2315                         break;
2316
2317                 case 1:
2318                         if(allowcenter) // 2: allow center handedness
2319                         {
2320                                 // center
2321                                 vecs_y = 0;
2322                                 vecs_z -= 2;
2323                         }
2324                         else
2325                         {
2326                                 // right
2327                         }
2328                         break;
2329
2330                 case 2:
2331                         if(allowcenter) // 2: allow center handedness
2332                         {
2333                                 // center
2334                                 vecs_y = 0;
2335                                 vecs_z -= 2;
2336                         }
2337                         else
2338                         {
2339                                 // left
2340                                 vecs_y = -vecs_y;
2341                         }
2342                         break;
2343         }
2344         return vecs;
2345 }
2346
2347 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2348 {
2349         string s;
2350         vector v;
2351
2352         if (autocvar_g_shootfromeye)
2353         {
2354                 if (visual)
2355                 {
2356                         vecs_y = 0;
2357                         vecs_z -= 2;
2358                 }
2359                 else
2360                 {
2361                         vecs_y = 0;
2362                         vecs_z = 0;
2363                 }
2364         }
2365         else if (autocvar_g_shootfromcenter)
2366         {
2367                 vecs_y = 0;
2368                 vecs_z -= 2;
2369         }
2370         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2371         {
2372                 v = stov(s);
2373                 if (y_is_right)
2374                         v_y = -v_y;
2375                 if (v_x != 0)
2376                         vecs_x = v_x;
2377                 vecs_y = v_y;
2378                 vecs_z = v_z;
2379         }
2380         else if (autocvar_g_shootfromclient)
2381         {
2382                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2383         }
2384         return vecs;
2385 }
2386
2387 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2388 {
2389         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2390 }
2391
2392
2393 void attach_sameorigin(entity e, entity to, string tag)
2394 {
2395     vector org, t_forward, t_left, t_up, e_forward, e_up;
2396     vector org0, ang0;
2397     float tagscale;
2398
2399     ang0 = e.angles;
2400     org0 = e.origin;
2401
2402     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2403     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2404     t_forward = v_forward * tagscale;
2405     t_left = v_right * -tagscale;
2406     t_up = v_up * tagscale;
2407
2408     e.origin_x = org * t_forward;
2409     e.origin_y = org * t_left;
2410     e.origin_z = org * t_up;
2411
2412     // current forward and up directions
2413     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2414                 e.angles = AnglesTransform_FromVAngles(e.angles);
2415         else
2416                 e.angles = AnglesTransform_FromAngles(e.angles);
2417     fixedmakevectors(e.angles);
2418
2419     // untransform forward, up!
2420     e_forward_x = v_forward * t_forward;
2421     e_forward_y = v_forward * t_left;
2422     e_forward_z = v_forward * t_up;
2423     e_up_x = v_up * t_forward;
2424     e_up_y = v_up * t_left;
2425     e_up_z = v_up * t_up;
2426
2427     e.angles = fixedvectoangles2(e_forward, e_up);
2428     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2429                 e.angles = AnglesTransform_ToVAngles(e.angles);
2430         else
2431                 e.angles = AnglesTransform_ToAngles(e.angles);
2432
2433     setattachment(e, to, tag);
2434     setorigin(e, e.origin);
2435 }
2436
2437 void detach_sameorigin(entity e)
2438 {
2439     vector org;
2440     org = gettaginfo(e, 0);
2441     e.angles = fixedvectoangles2(v_forward, v_up);
2442     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2443                 e.angles = AnglesTransform_ToVAngles(e.angles);
2444         else
2445                 e.angles = AnglesTransform_ToAngles(e.angles);
2446     setorigin(e, org);
2447     setattachment(e, world, "");
2448     setorigin(e, e.origin);
2449 }
2450
2451 void follow_sameorigin(entity e, entity to)
2452 {
2453     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2454     e.aiment = to; // make the hole follow bmodel
2455     e.punchangle = to.angles; // the original angles of bmodel
2456     e.view_ofs = e.origin - to.origin; // relative origin
2457     e.v_angle = e.angles - to.angles; // relative angles
2458 }
2459
2460 void unfollow_sameorigin(entity e)
2461 {
2462     e.movetype = MOVETYPE_NONE;
2463 }
2464
2465 entity gettaginfo_relative_ent;
2466 vector gettaginfo_relative(entity e, float tag)
2467 {
2468     if (!gettaginfo_relative_ent)
2469     {
2470         gettaginfo_relative_ent = spawn();
2471         gettaginfo_relative_ent.effects = EF_NODRAW;
2472     }
2473     gettaginfo_relative_ent.model = e.model;
2474     gettaginfo_relative_ent.modelindex = e.modelindex;
2475     gettaginfo_relative_ent.frame = e.frame;
2476     return gettaginfo(gettaginfo_relative_ent, tag);
2477 }
2478
2479 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2480 {
2481     float p;
2482     p = pow(2, chan);
2483     if (pl.soundentity.cnt & p)
2484         return;
2485     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2486     pl.soundentity.cnt |= p;
2487 }
2488
2489 void SoundEntity_StopSound(entity pl, float chan)
2490 {
2491     float p;
2492     p = pow(2, chan);
2493     if (pl.soundentity.cnt & p)
2494     {
2495         stopsoundto(MSG_ALL, pl.soundentity, chan);
2496         pl.soundentity.cnt &~= p;
2497     }
2498 }
2499
2500 void SoundEntity_Attach(entity pl)
2501 {
2502     pl.soundentity = spawn();
2503     pl.soundentity.classname = "soundentity";
2504     pl.soundentity.owner = pl;
2505     setattachment(pl.soundentity, pl, "");
2506     setmodel(pl.soundentity, "null");
2507 }
2508
2509 void SoundEntity_Detach(entity pl)
2510 {
2511     float i;
2512     for (i = 0; i <= 7; ++i)
2513         SoundEntity_StopSound(pl, i);
2514 }
2515
2516 .float scale2;
2517
2518 float modeleffect_SendEntity(entity to, float sf)
2519 {
2520         float f;
2521         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2522
2523         f = 0;
2524         if(self.velocity != '0 0 0')
2525                 f |= 1;
2526         if(self.angles != '0 0 0')
2527                 f |= 2;
2528         if(self.avelocity != '0 0 0')
2529                 f |= 4;
2530
2531         WriteByte(MSG_ENTITY, f);
2532         WriteShort(MSG_ENTITY, self.modelindex);
2533         WriteByte(MSG_ENTITY, self.skin);
2534         WriteByte(MSG_ENTITY, self.frame);
2535         WriteCoord(MSG_ENTITY, self.origin_x);
2536         WriteCoord(MSG_ENTITY, self.origin_y);
2537         WriteCoord(MSG_ENTITY, self.origin_z);
2538         if(f & 1)
2539         {
2540                 WriteCoord(MSG_ENTITY, self.velocity_x);
2541                 WriteCoord(MSG_ENTITY, self.velocity_y);
2542                 WriteCoord(MSG_ENTITY, self.velocity_z);
2543         }
2544         if(f & 2)
2545         {
2546                 WriteCoord(MSG_ENTITY, self.angles_x);
2547                 WriteCoord(MSG_ENTITY, self.angles_y);
2548                 WriteCoord(MSG_ENTITY, self.angles_z);
2549         }
2550         if(f & 4)
2551         {
2552                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2553                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2554                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2555         }
2556         WriteShort(MSG_ENTITY, self.scale * 256.0);
2557         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2558         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2559         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2560         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2561
2562         return TRUE;
2563 }
2564
2565 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2566 {
2567         entity e;
2568         float sz;
2569         e = spawn();
2570         e.classname = "modeleffect";
2571         setmodel(e, m);
2572         e.frame = f;
2573         setorigin(e, o);
2574         e.velocity = v;
2575         e.angles = ang;
2576         e.avelocity = angv;
2577         e.alpha = a;
2578         e.teleport_time = t1;
2579         e.fade_time = t2;
2580         e.skin = s;
2581         if(s0 >= 0)
2582                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2583         else
2584                 e.scale = -s0;
2585         if(s2 >= 0)
2586                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2587         else
2588                 e.scale2 = -s2;
2589         sz = max(e.scale, e.scale2);
2590         setsize(e, e.mins * sz, e.maxs * sz);
2591         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2592 }
2593
2594 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2595 {
2596         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2597 }
2598
2599 float randombit(float bits)
2600 {
2601         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2602                 return bits;
2603
2604         float n, f, b, r;
2605
2606         r = random();
2607         b = 0;
2608         n = 0;
2609
2610         for(f = 1; f <= bits; f *= 2)
2611         {
2612                 if(bits & f)
2613                 {
2614                         ++n;
2615                         r *= n;
2616                         if(r <= 1)
2617                                 b = f;
2618                         else
2619                                 r = (r - 1) / (n - 1);
2620                 }
2621         }
2622
2623         return b;
2624 }
2625
2626 float randombits(float bits, float k, float error_return)
2627 {
2628         float r;
2629         r = 0;
2630         while(k > 0 && bits != r)
2631         {
2632                 r += randombit(bits - r);
2633                 --k;
2634         }
2635         if(error_return)
2636                 if(k > 0)
2637                         return -1; // all
2638         return r;
2639 }
2640
2641 void randombit_test(float bits, float iter)
2642 {
2643         while(iter > 0)
2644         {
2645                 print(ftos(randombit(bits)), "\n");
2646                 --iter;
2647         }
2648 }
2649
2650 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2651 {
2652         if(halflifedist > 0)
2653                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2654         else if(halflifedist < 0)
2655                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2656         else
2657                 return 1;
2658 }
2659
2660
2661
2662
2663 #ifdef RELEASE
2664 #define cvar_string_normal builtin_cvar_string
2665 #define cvar_normal builtin_cvar
2666 #else
2667 string cvar_string_normal(string n)
2668 {
2669         if not(cvar_type(n) & 1)
2670                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2671         return builtin_cvar_string(n);
2672 }
2673
2674 float cvar_normal(string n)
2675 {
2676         return stof(cvar_string_normal(n));
2677 }
2678 #endif
2679 #define cvar_set_normal builtin_cvar_set
2680
2681 void defer_think()
2682 {
2683     entity oself;
2684
2685     oself           = self;
2686     self            = self.owner;
2687     oself.think     = SUB_Remove;
2688     oself.nextthink = time;
2689
2690     oself.use();
2691 }
2692
2693 /*
2694     Execute func() after time + fdelay.
2695     self when func is executed = self when defer is called
2696 */
2697 void defer(float fdelay, void() func)
2698 {
2699     entity e;
2700
2701     e           = spawn();
2702     e.owner     = self;
2703     e.use       = func;
2704     e.think     = defer_think;
2705     e.nextthink = time + fdelay;
2706 }
2707
2708 .string aiment_classname;
2709 .float aiment_deadflag;
2710 void SetMovetypeFollow(entity ent, entity e)
2711 {
2712         // FIXME this may not be warpzone aware
2713         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2714         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2715         ent.aiment = e; // make the hole follow bmodel
2716         ent.punchangle = e.angles; // the original angles of bmodel
2717         ent.view_ofs = ent.origin - e.origin; // relative origin
2718         ent.v_angle = ent.angles - e.angles; // relative angles
2719         ent.aiment_classname = strzone(e.classname);
2720         ent.aiment_deadflag = e.deadflag;
2721 }
2722 void UnsetMovetypeFollow(entity ent)
2723 {
2724         ent.movetype = MOVETYPE_FLY;
2725         PROJECTILE_MAKETRIGGER(ent);
2726         ent.aiment = world;
2727 }
2728 float LostMovetypeFollow(entity ent)
2729 {
2730 /*
2731         if(ent.movetype != MOVETYPE_FOLLOW)
2732                 if(ent.aiment)
2733                         error("???");
2734 */
2735         if(ent.aiment)
2736         {
2737                 if(ent.aiment.classname != ent.aiment_classname)
2738                         return 1;
2739                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2740                         return 1;
2741         }
2742         return 0;
2743 }
2744
2745 float isPushable(entity e)
2746 {
2747         if(e.iscreature)
2748                 return TRUE;
2749         switch(e.classname)
2750         {
2751                 case "body":
2752                 case "droppedweapon":
2753                 case "keepawayball":
2754                 case "nexball_basketball":
2755                 case "nexball_football":
2756                         return TRUE;
2757                 case "bullet": // antilagged bullets can't hit this either
2758                         return FALSE;
2759         }
2760         if (e.projectiledeathtype)
2761                 return TRUE;
2762         return FALSE;
2763 }