qcsrc/server/monsters/lib/monsters.qc

   1 // TODO: clean up this file?
   2
   3 void() spawnfunc_item_minst_cells;
   4
   5 void M_Item_Touch ()
   6 {
   7         if(self && IS_PLAYER(other) && other.deadflag == DEAD_NO)
   8         {
   9                 Item_Touch();
  10                 self.think = SUB_Remove;
  11                 self.nextthink = time + 0.1;
  12         }
  13 }
  14
  15 void monster_item_spawn()
  16 {
  17         self.monster_delayedattack();
  18
  19         self.gravity = 1;
  20         self.velocity = randomvec() * 175 + '0 0 325';
  21         self.touch = M_Item_Touch;
  22
  23         SUB_SetFade(self, time + autocvar_g_monsters_drop_time, 1);
  24 }
  25
  26 void Monster_DropItem (string itype, string itemsize)
  27 {
  28         vector org = self.origin + ((self.mins + self.maxs) * 0.5);
  29         entity e = spawn();
  30
  31         setorigin(e, org);
  32
  33         switch(itype)
  34         {
  35                 case "armor":
  36                 {
  37                         switch(itemsize)
  38                         {
  39                                 case "mega": e.monster_delayedattack = spawnfunc_item_armor_large; break;
  40                                 case "large": e.monster_delayedattack = spawnfunc_item_armor_big; break;
  41                                 case "medium": e.monster_delayedattack = spawnfunc_item_armor_medium; break;
  42                                 case "small": e.monster_delayedattack = spawnfunc_item_armor_small; break;
  43                         }
  44                         break; // break here?
  45                 }
  46                 case "health":
  47                 {
  48                         switch(itemsize)
  49                         {
  50                                 case "mega": e.monster_delayedattack = spawnfunc_item_health_mega; break;
  51                                 case "large": e.monster_delayedattack = spawnfunc_item_health_large; break;
  52                                 case "medium": e.monster_delayedattack = spawnfunc_item_health_medium; break;
  53                                 case "small": e.monster_delayedattack = spawnfunc_item_health_small; break;
  54                         }
  55                         break; // break here?
  56                 }
  57                 case "ammo":
  58                 {
  59                         switch(itemsize)
  60                         {
  61                                 case "shells": e.monster_delayedattack = spawnfunc_item_shells; break;
  62                                 case "cells": e.monster_delayedattack = spawnfunc_item_cells; break;
  63                                 case "rockets": e.monster_delayedattack = spawnfunc_item_rockets; break;
  64                                 case "bullets":
  65                                 case "nails": e.monster_delayedattack = spawnfunc_item_bullets; break;
  66                         }
  67                         break;
  68                 }
  69         }
  70
  71         if(g_minstagib)
  72                 e.monster_delayedattack = spawnfunc_item_minst_cells;
  73
  74         e.think = monster_item_spawn;
  75         e.nextthink = time + 0.1;
  76 }
  77
  78 void monsters_setframe(float _frame)
  79 {
  80         if(self.frame == _frame)
  81                 return;
  82
  83         self.anim_start_time = time;
  84         self.frame = _frame;
  85         self.SendFlags |= MSF_ANIM;
  86 }
  87
  88 float monster_isvalidtarget (entity targ, entity ent)
  89 {
  90         if(!targ || !ent)
  91                 return FALSE; // someone doesn't exist
  92
  93         if(time < game_starttime)
  94                 return FALSE; // monsters do nothing before the match has started
  95
  96         WarpZone_TraceLine(ent.origin, targ.origin, MOVE_NORMAL, ent);
  97
  98         if(vlen(targ.origin - ent.origin) >= ent.target_range)
  99                 return FALSE; // enemy is too far away
 100
 101         if not(targ.vehicle_flags & VHF_ISVEHICLE)
 102         if(trace_ent != targ)
 103                 return FALSE; // we can't see the enemy
 104
 105         if(targ.takedamage == DAMAGE_NO)
 106                 return FALSE; // enemy can't be damaged
 107
 108         if(targ.items & IT_INVISIBILITY)
 109                 return FALSE; // enemy is invisible
 110
 111         if(substring(targ.classname, 0, 10) == "onslaught_")
 112                 return FALSE; // don't attack onslaught targets
 113
 114         if(IS_SPEC(targ) || IS_OBSERVER(targ))
 115                 return FALSE; // enemy is a spectator
 116
 117         if not(targ.vehicle_flags & VHF_ISVEHICLE) // vehicles dont count as alive?
 118         if(targ.deadflag != DEAD_NO || ent.deadflag != DEAD_NO || targ.health <= 0 || ent.health <= 0)
 119                 return FALSE; // enemy/self is dead
 120
 121         if(targ.monster_owner == ent || ent.monster_owner == targ)
 122                 return FALSE; // enemy owns us, or we own them
 123
 124         if not(targ.vehicle_flags & VHF_ISVEHICLE)
 125         if(targ.flags & FL_NOTARGET)
 126                 return FALSE; // enemy can't be targetted
 127
 128         if not(autocvar_g_monsters_typefrag)
 129         if(targ.BUTTON_CHAT)
 130                 return FALSE; // no typefragging!
 131
 132         if not(IsDifferentTeam(targ, ent))
 133                 return FALSE; // enemy is on our team
 134
 135         if(autocvar_g_monsters_target_infront)
 136         if(ent.enemy != targ)
 137         {
 138                 float dot;
 139
 140                 makevectors (ent.angles);
 141                 dot = normalize (targ.origin - ent.origin) * v_forward;
 142
 143                 if(dot <= 0.3)
 144                         return FALSE;
 145         }
 146
 147         return TRUE;
 148 }
 149
 150 entity FindTarget (entity ent)
 151 {
 152         if(MUTATOR_CALLHOOK(MonsterFindTarget)) { return ent.enemy; } // Handled by a mutator
 153         entity e;
 154
 155         for(e = world; (e = findflags(e, monster_attack, TRUE)); )
 156         if(monster_isvalidtarget(e, ent))
 157                 return e;
 158
 159         return world;
 160 }
 161
 162 void MonsterTouch ()
 163 {
 164         if(other == world)
 165                 return;
 166
 167         if(self.enemy != other)
 168         if not(other.flags & FL_MONSTER)
 169         if(monster_isvalidtarget(other, self))
 170                 self.enemy = other;
 171 }
 172
 173 void monster_sound(string msound, float sound_delay, float delaytoo)
 174 {
 175         if(delaytoo && time < self.msound_delay)
 176                 return; // too early
 177
 178         if(msound == "")
 179                 return; // sound doesn't exist
 180
 181         sound(self, CHAN_AUTO, msound, VOL_BASE, ATTN_NORM);
 182
 183         self.msound_delay = time + sound_delay;
 184 }
 185
 186 void monster_precachesounds(entity e)
 187 {
 188         precache_sound(e.msound_idle);
 189         precache_sound(e.msound_death);
 190         precache_sound(e.msound_attack_melee);
 191         precache_sound(e.msound_attack_ranged);
 192         precache_sound(e.msound_sight);
 193         precache_sound(e.msound_pain);
 194 }
 195
 196 void monster_setupsounds(string mon)
 197 {
 198         if(self.msound_idle == "") self.msound_idle = strzone(strcat("monsters/", mon, "_idle.wav"));
 199         if(self.msound_death == "") self.msound_death = strzone(strcat("monsters/", mon, "_death.wav"));
 200         if(self.msound_pain == "") self.msound_pain = strzone(strcat("monsters/", mon, "_pain.wav"));
 201         if(self.msound_attack_melee == "") self.msound_attack_melee = strzone(strcat("monsters/", mon, "_melee.wav"));
 202         if(self.msound_attack_ranged == "") self.msound_attack_ranged = strzone(strcat("monsters/", mon, "_attack.wav"));
 203         if(self.msound_sight == "") self.msound_sight = strzone(strcat("monsters/", mon, "_sight.wav"));
 204 }
 205
 206 void monster_melee (entity targ, float damg, float er, float deathtype, float dostop)
 207 {
 208         float dot, rdmg = damg * random();
 209
 210         if (self.health <= 0)
 211                 return;
 212         if (targ == world)
 213                 return;
 214
 215         if(dostop)
 216         {
 217                 self.velocity_x = 0;
 218                 self.velocity_y = 0;
 219                 self.state = MONSTER_STATE_ATTACK_MELEE;
 220                 self.SendFlags |= MSF_MOVE;
 221         }
 222
 223         makevectors (self.angles);
 224         dot = normalize (targ.origin - self.origin) * v_forward;
 225
 226         if(dot > er)
 227                 Damage(targ, self, self, rdmg * monster_skill, deathtype, targ.origin, normalize(targ.origin - self.origin));
 228 }
 229
 230 void Monster_CheckDropCvars (string mon)
 231 {
 232         if not(self.candrop)
 233                 return; // forced off
 234
 235         string dropitem;
 236         string dropsize;
 237
 238         dropitem = cvar_string(strcat("g_monster_", mon, "_drop"));
 239         dropsize = cvar_string(strcat("g_monster_", mon, "_drop_size"));
 240
 241         monster_dropitem = dropitem;
 242         monster_dropsize = dropsize;
 243         MUTATOR_CALLHOOK(MonsterDropItem);
 244         dropitem = monster_dropitem;
 245         dropsize = monster_dropsize;
 246
 247         if(autocvar_g_monsters_forcedrop)
 248                 Monster_DropItem(autocvar_g_monsters_drop_type, autocvar_g_monsters_drop_size);
 249         else if(dropitem != "")
 250                 Monster_DropItem(dropitem, dropsize);
 251         else
 252                 Monster_DropItem("armor", "medium");
 253 }
 254
 255 void Monster_CheckMinibossFlag ()
 256 {
 257         if(MUTATOR_CALLHOOK(MonsterCheckBossFlag))
 258                 return;
 259
 260         float chance = random() * 100;
 261
 262         // g_monsters_miniboss_chance cvar or spawnflags 64 causes a monster to be a miniboss
 263         if ((self.spawnflags & MONSTERFLAG_MINIBOSS) || (chance < autocvar_g_monsters_miniboss_chance))
 264         {
 265                 self.health += autocvar_g_monsters_miniboss_healthboost;
 266                 self.flags |= MONSTERFLAG_MINIBOSS;
 267                 if not(self.weapon)
 268                         self.weapon = WEP_NEX;
 269         }
 270 }
 271
 272 float Monster_CanRespawn(entity ent)
 273 {
 274         other = ent;
 275         if(MUTATOR_CALLHOOK(MonsterRespawn))
 276                 return TRUE; // enabled by a mutator
 277
 278         if(ent.spawnflags & MONSTERFLAG_NORESPAWN)
 279                 return FALSE;
 280
 281         if not(autocvar_g_monsters_respawn)
 282                 return FALSE;
 283
 284         return TRUE;
 285 }
 286
 287 void Monster_Fade ()
 288 {
 289         if(Monster_CanRespawn(self))
 290         {
 291                 self.monster_respawned = TRUE;
 292                 self.think = self.monster_spawnfunc;
 293                 self.nextthink = time + self.respawntime;
 294                 self.deadflag = DEAD_RESPAWNING;
 295                 if(self.spawnflags & MONSTER_RESPAWN_DEATHPOINT)
 296                 {
 297                         self.pos1 = self.origin;
 298                         self.pos2 = self.angles;
 299                 }
 300                 self.event_damage = func_null;
 301                 self.takedamage = DAMAGE_NO;
 302                 setorigin(self, self.pos1);
 303                 self.angles = self.pos2;
 304                 self.health = self.max_health; // TODO: check if resetting to max_health is wise here
 305
 306                 self.SendFlags |= MSF_MOVE;
 307                 self.SendFlags |= MSF_STATUS;
 308
 309                 return;
 310         }
 311         SUB_SetFade(self, time + 3, 1);
 312 }
 313
 314 float Monster_CanJump (vector vel)
 315 {
 316         if(self.state)
 317                 return FALSE; // already attacking
 318         if not(self.flags & FL_ONGROUND)
 319                 return FALSE; // not on the ground
 320         if(self.health <= 0)
 321                 return FALSE; // called when dead?
 322         if(time < self.attack_finished_single)
 323                 return FALSE; // still attacking
 324
 325         vector old = self.velocity;
 326
 327         self.velocity = vel;
 328         tracetoss(self, self);
 329         self.velocity = old;
 330         if (trace_ent != self.enemy)
 331                 return FALSE;
 332
 333         return TRUE;
 334 }
 335
 336 float monster_leap (float anm, void() touchfunc, vector vel, float anim_finished)
 337 {
 338         if(!Monster_CanJump(vel))
 339                 return FALSE;
 340
 341         monsters_setframe(anm);
 342         self.state = MONSTER_STATE_ATTACK_LEAP;
 343         self.touch = touchfunc;
 344         self.origin_z += 1;
 345         self.velocity = vel;
 346         self.flags &~= FL_ONGROUND;
 347
 348         self.attack_finished_single = time + anim_finished;
 349
 350         return TRUE;
 351 }
 352
 353 void monster_checkattack(entity e, entity targ)
 354 {
 355         if(e == world)
 356                 return;
 357         if(targ == world)
 358         {
 359                 e.monster_delayedattack = func_null;
 360                 e.delay = -1;
 361                 return;
 362         }
 363
 364         if not(e.monster_attackfunc)
 365                 return;
 366
 367         if(e.monster_delayedattack && e.delay != -1)
 368         {
 369                 if(time < e.delay)
 370                         return;
 371
 372                 e.monster_delayedattack();
 373
 374                 return;
 375         }
 376
 377         if(time < e.attack_finished_single)
 378                 return;
 379
 380         if(vlen(targ.origin - e.origin) <= e.attack_range)
 381         if(e.monster_attackfunc(MONSTER_ATTACK_MELEE))
 382         {
 383                 monster_sound(e.msound_attack_melee, 0, FALSE);
 384                 return;
 385         }
 386
 387         if(e.monster_attackfunc(MONSTER_ATTACK_RANGED))
 388         {
 389                 monster_sound(e.msound_attack_ranged, 0, FALSE);
 390                 return;
 391         }
 392 }
 393
 394 void monster_makevectors(entity e)
 395 {
 396         vector v;
 397
 398         v = e.origin + (e.mins + e.maxs) * 0.5;
 399         self.v_angle = vectoangles(v - (self.origin + self.view_ofs));
 400         self.v_angle_x = -self.v_angle_x;
 401
 402         makevectors(self.v_angle);
 403 }
 404
 405 void monster_use ()
 406 {
 407         if (self.enemy)
 408                 return;
 409         if (self.health <= 0)
 410                 return;
 411
 412         if(!monster_isvalidtarget(activator, self))
 413                 return;
 414
 415         self.enemy = activator;
 416 }
 417
 418 float trace_path(vector from, vector to)
 419 {
 420         vector dir = normalize(to - from) * 15, offset = '0 0 0';
 421         float trace1 = trace_fraction;
 422
 423         offset_x = dir_y;
 424         offset_y = -dir_x;
 425         traceline (from+offset, to+offset, TRUE, self);
 426
 427         traceline(from-offset, to-offset, TRUE, self);
 428
 429         return ((trace1 < trace_fraction) ? trace1 : trace_fraction);
 430 }
 431
 432 .float last_trace;
 433 vector monster_pickmovetarget(entity targ)
 434 {
 435         // enemy is always preferred target
 436         if(self.enemy)
 437         {
 438                 self.monster_movestate = MONSTER_MOVE_ENEMY;
 439                 self.last_trace = time + 0.1;
 440                 return self.enemy.origin;
 441         }
 442
 443         switch(self.monster_moveflags)
 444         {
 445                 case MONSTER_MOVE_OWNER:
 446                 {
 447                         self.monster_movestate = MONSTER_MOVE_OWNER;
 448                         self.last_trace = time + 0.3;
 449                         if(self.monster_owner && self.monster_owner.classname != "td_spawnpoint")
 450                                 return self.monster_owner.origin;
 451                 }
 452                 case MONSTER_MOVE_SPAWNLOC:
 453                 {
 454                         self.monster_movestate = MONSTER_MOVE_SPAWNLOC;
 455                         self.last_trace = time + 2;
 456                         return self.pos1;
 457                 }
 458                 case MONSTER_MOVE_NOMOVE:
 459                 {
 460                         self.monster_movestate = MONSTER_MOVE_NOMOVE;
 461                         self.last_trace = time + 2;
 462                         return self.origin;
 463                 }
 464                 default:
 465                 case MONSTER_MOVE_WANDER:
 466                 {
 467                         vector pos;
 468                         self.monster_movestate = MONSTER_MOVE_WANDER;
 469                         self.last_trace = time + 2;
 470
 471                         self.angles_y = random() * 500;
 472                         makevectors(self.angles);
 473                         pos = self.origin + v_forward * 600;
 474
 475                         if(self.flags & FL_FLY || self.flags & FL_SWIM)
 476                         {
 477                                 pos_z = random() * 200;
 478                                 if(random() >= 0.5)
 479                                         pos_z *= -1;
 480                         }
 481
 482                         if(targ)
 483                         {
 484                                 self.last_trace = time + 0.5;
 485                                 pos = targ.origin;
 486                         }
 487
 488                         return pos;
 489                 }
 490         }
 491 }
 492
 493 void monster_move(float runspeed, float walkspeed, float stopspeed, float manim_run, float manim_walk, float manim_idle)
 494 {
 495         if(self.target2)
 496                 self.goalentity = find(world, targetname, self.target2);
 497
 498         entity targ;
 499
 500         if(self.frozen)
 501         {
 502                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
 503                 self.health = max(1, self.max_health * self.revive_progress);
 504
 505                 if(self.sprite) WaypointSprite_UpdateHealth(self.sprite, self.health);
 506
 507                 movelib_beak_simple(stopspeed);
 508
 509                 self.velocity = '0 0 0';
 510                 self.enemy = world;
 511                 self.nextthink = time + 0.1;
 512
 513                 if(self.revive_progress >= 1)
 514                         Unfreeze(self); // wait for next think before attacking
 515
 516                 self.SendFlags |= MSF_MOVE;
 517
 518                 return; // no moving while frozen
 519         }
 520
 521         if(self.flags & FL_SWIM)
 522         {
 523                 if(self.waterlevel < WATERLEVEL_WETFEET)
 524                 {
 525                         if(time >= self.last_trace)
 526                         {
 527                                 self.last_trace = time + 0.4;
 528
 529                                 Damage (self, world, world, 2, DEATH_DROWN, self.origin, '0 0 0');
 530                                 self.angles = '90 90 0';
 531                                 if(random() < 0.5)
 532                                 {
 533                                         self.velocity_y += random() * 50;
 534                                         self.velocity_x -= random() * 50;
 535                                 }
 536                                 else
 537                                 {
 538                                         self.velocity_y -= random() * 50;
 539                                         self.velocity_x += random() * 50;
 540                                 }
 541                                 self.velocity_z += random() * 150;
 542                         }
 543
 544
 545                         self.movetype = MOVETYPE_BOUNCE;
 546                         //self.velocity_z = -200;
 547
 548                         self.SendFlags |= MSF_MOVE | MSF_ANG;
 549
 550                         return;
 551                 }
 552                 else
 553                 {
 554                         self.angles = '0 0 0';
 555                         self.movetype = MOVETYPE_WALK;
 556                 }
 557         }
 558
 559         targ = self.goalentity;
 560
 561         monster_target = targ;
 562         monster_speed_run = runspeed;
 563         monster_speed_walk = walkspeed;
 564
 565         if(MUTATOR_CALLHOOK(MonsterMove) || gameover || (round_handler_IsActive() && !round_handler_IsRoundStarted()) || time < game_starttime || (autocvar_g_campaign && !campaign_bots_may_start) || time < self.spawn_time)
 566         {
 567                 runspeed = walkspeed = 0;
 568                 if(time >= self.spawn_time)
 569                         monsters_setframe(manim_idle);
 570                 movelib_beak_simple(stopspeed);
 571                 self.SendFlags |= MSF_MOVE;
 572                 return;
 573         }
 574
 575         targ = monster_target;
 576         runspeed = monster_speed_run;
 577         walkspeed = monster_speed_walk;
 578
 579         if(IsDifferentTeam(self.monster_owner, self))
 580                 self.monster_owner = world;
 581
 582         if not(monster_isvalidtarget(self.enemy, self))
 583                 self.enemy = world; // check enemy each think frame?
 584
 585         if not(self.enemy)
 586         {
 587                 self.enemy = FindTarget(self);
 588                 if(self.enemy)
 589                         monster_sound(self.msound_sight, 0, FALSE);
 590         }
 591
 592         if(self.state == MONSTER_STATE_ATTACK_MELEE && time >= self.attack_finished_single)
 593                 self.state = 0;
 594
 595         if(self.state != MONSTER_STATE_ATTACK_MELEE) // don't move if set
 596         if(time >= self.last_trace || self.enemy) // update enemy instantly
 597                 self.moveto = monster_pickmovetarget(targ);
 598
 599         if not(self.enemy)
 600                 monster_sound(self.msound_idle, 5, TRUE);
 601
 602         vector angles_face = vectoangles(self.moveto - self.origin);
 603         vector owner_face = vectoangles(self.monster_owner.origin - self.origin);
 604         vector enemy_face = vectoangles(self.enemy.origin - self.origin);
 605
 606         if(!(self.flags & FL_FLY || self.flags & FL_SWIM))
 607                 self.moveto_z = self.origin_z;
 608
 609         if(self.state != MONSTER_STATE_ATTACK_LEAP)
 610                 self.angles_y = angles_face_y;
 611
 612         if(self.state == MONSTER_STATE_ATTACK_LEAP && (self.flags & FL_ONGROUND))
 613         {
 614                 self.state = 0;
 615                 self.touch = MonsterTouch;
 616         }
 617
 618         v_forward = normalize(self.moveto - self.origin);
 619
 620         float l = vlen(self.moveto - self.origin);
 621         float t1 = trace_path(self.origin+'0 0 10', self.moveto+'0 0 10');
 622         float t2 = trace_path(self.origin-'0 0 15', self.moveto-'0 0 15');
 623
 624         if(t1*l-t2*l>50 && (t1*l > 100 || t1 > 0.8))
 625         if(self.flags & FL_ONGROUND)
 626                 movelib_jump_simple(100);
 627
 628         if(vlen(self.origin - self.moveto) > 64)
 629         {
 630                 if(self.flags & FL_FLY || self.flags & FL_SWIM)
 631                         movelib_move_simple(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 632                 else
 633                         movelib_move_simple_gravity(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 634                 if(time > self.pain_finished)
 635                 if(time > self.attack_finished_single)
 636                         monsters_setframe((self.enemy) ? manim_run : manim_walk);
 637         }
 638         else
 639         {
 640                 if(targ.target)
 641                         self.target2 = targ.target;
 642                 else if(targ.target2)
 643                         self.target2 = targ.target2;
 644                 else
 645                 {
 646                         movelib_beak_simple(stopspeed);
 647                         if(time > self.attack_finished_single)
 648                         if(time > self.pain_finished)
 649                         if (vlen(self.velocity) <= 30)
 650                         {
 651                                 monsters_setframe(manim_idle);
 652                                 if(self.enemy)
 653                                         self.angles_y = enemy_face_y;
 654                                 else
 655                                         self.angles_y = ((self.monster_owner) ? owner_face_y : self.pos2_y); // reset looking angle now?
 656                         }
 657                 }
 658         }
 659
 660         if(self.enemy)
 661                 monster_checkattack(self, self.enemy);
 662
 663         self.SendFlags |= MSF_ANG;
 664         self.SendFlags |= MSF_MOVE;
 665 }
 666
 667 void monster_dead_think()
 668 {
 669         self.think = monster_dead_think;
 670         self.nextthink = time + 0.3; // don't need to update so often now
 671
 672         self.deadflag = DEAD_DEAD;
 673
 674         if(time >= self.ltime)
 675         {
 676                 Monster_Fade();
 677                 return;
 678         }
 679
 680         self.SendFlags |= MSF_MOVE; // keep up to date on the monster's location
 681 }
 682
 683 void monsters_setstatus()
 684 {
 685         self.stat_monsters_total = monsters_total;
 686         self.stat_monsters_killed = monsters_killed;
 687 }
 688
 689 void Monster_Appear()
 690 {
 691         self.enemy = activator;
 692         self.spawnflags &~= MONSTERFLAG_APPEAR;
 693         self.monster_spawnfunc();
 694 }
 695
 696 float Monster_CheckAppearFlags(entity ent)
 697 {
 698         if not(ent.spawnflags & MONSTERFLAG_APPEAR)
 699                 return FALSE;
 700
 701         ent.think = func_null;
 702         ent.nextthink = 0;
 703         ent.use = Monster_Appear;
 704         ent.flags = FL_MONSTER; // set so this monster can get butchered
 705
 706         return TRUE;
 707 }
 708
 709 void monsters_reset()
 710 {
 711         setorigin(self, self.pos1);
 712         self.angles = self.pos2;
 713
 714         self.health = self.max_health;
 715         self.velocity = '0 0 0';
 716         self.enemy = world;
 717         self.goalentity = world;
 718         self.attack_finished_single = 0;
 719         self.moveto = self.origin;
 720
 721         WaypointSprite_UpdateHealth(self.sprite, self.health);
 722 }
 723
 724 float monster_send(entity to, float sf)
 725 {
 726         WriteByte(MSG_ENTITY, ENT_CLIENT_MONSTER);
 727         WriteByte(MSG_ENTITY, sf);
 728         if(sf & MSF_SETUP)
 729         {
 730             WriteByte(MSG_ENTITY, self.monsterid);
 731
 732             WriteCoord(MSG_ENTITY, self.origin_x);
 733             WriteCoord(MSG_ENTITY, self.origin_y);
 734             WriteCoord(MSG_ENTITY, self.origin_z);
 735
 736             WriteAngle(MSG_ENTITY, self.angles_x);
 737             WriteAngle(MSG_ENTITY, self.angles_y);
 738
 739                 WriteByte(MSG_ENTITY, self.skin);
 740                 WriteByte(MSG_ENTITY, self.team);
 741     }
 742
 743     if(sf & MSF_ANG)
 744     {
 745         WriteShort(MSG_ENTITY, rint(self.angles_x));
 746         WriteShort(MSG_ENTITY, rint(self.angles_y));
 747     }
 748
 749     if(sf & MSF_MOVE)
 750     {
 751         WriteShort(MSG_ENTITY, rint(self.origin_x));
 752         WriteShort(MSG_ENTITY, rint(self.origin_y));
 753         WriteShort(MSG_ENTITY, rint(self.origin_z));
 754
 755         WriteShort(MSG_ENTITY, rint(self.velocity_x));
 756         WriteShort(MSG_ENTITY, rint(self.velocity_y));
 757         WriteShort(MSG_ENTITY, rint(self.velocity_z));
 758
 759         WriteShort(MSG_ENTITY, rint(self.angles_y));
 760     }
 761
 762     if(sf & MSF_ANIM)
 763     {
 764         WriteCoord(MSG_ENTITY, self.anim_start_time);
 765         WriteByte(MSG_ENTITY, self.frame);
 766     }
 767
 768     if(sf & MSF_STATUS)
 769     {
 770                 WriteByte(MSG_ENTITY, self.skin);
 771
 772         WriteByte(MSG_ENTITY, self.team);
 773
 774                 WriteByte(MSG_ENTITY, self.deadflag);
 775
 776         if(self.health <= 0)
 777             WriteByte(MSG_ENTITY, 0);
 778         else
 779             WriteByte(MSG_ENTITY, ceil((self.health / self.max_health) * 255));
 780     }
 781
 782         return TRUE;
 783 }
 784
 785 void monster_link(void() spawnproc)
 786 {
 787     Net_LinkEntity(self, TRUE, 0, monster_send);
 788     self.think      = spawnproc;
 789     self.nextthink  = time;
 790 }
 791
 792 void monsters_corpse_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 793 {
 794         self.health -= damage;
 795
 796         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 797
 798         if(self.health <= -100) // 100 health until gone?
 799         {
 800                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 801
 802                 self.think = SUB_Remove;
 803                 self.nextthink = time + 0.1;
 804         }
 805 }
 806
 807 void monsters_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 808 {
 809         if(self.frozen && deathtype != DEATH_KILL)
 810                 return;
 811
 812         if(time < self.pain_finished && deathtype != DEATH_KILL)
 813                 return;
 814
 815         if(time < self.spawnshieldtime)
 816                 return;
 817
 818         if((ignore_turrets && !(attacker.turrcaps_flags & TFL_TURRCAPS_ISTURRET)) || !ignore_turrets)
 819         if(monster_isvalidtarget(attacker, self))
 820                 self.enemy = attacker;
 821
 822         if(deathtype != DEATH_KILL)
 823                 damage *= self.armorvalue;
 824
 825         if(self.weaponentity && self.weaponentity.classname == "shield")
 826                 self.weaponentity.health -= damage;
 827
 828         self.health -= damage;
 829
 830         if(self.sprite)
 831                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 832
 833         self.dmg_time = time;
 834
 835         if(sound_allowed(MSG_BROADCAST, attacker) && deathtype != DEATH_DROWN)
 836                 spamsound (self, CH_PAIN, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);  // FIXME: PLACEHOLDER
 837
 838         self.velocity += force * self.damageforcescale;
 839
 840         if(deathtype != DEATH_DROWN)
 841         {
 842                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 843                 if (damage > 50)
 844                         Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 845                 if (damage > 100)
 846                         Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 847         }
 848
 849         if(self.health <= 0)
 850         {
 851                 if(self.sprite)
 852                 {
 853                         // Update one more time to avoid waypoint fading without emptying healthbar
 854                         WaypointSprite_UpdateHealth(self.sprite, 0);
 855                 }
 856
 857                 if(deathtype == DEATH_KILL)
 858                         self.candrop = FALSE; // killed by mobkill command
 859
 860                 // TODO: fix this?
 861                 activator = attacker;
 862                 other = self.enemy;
 863                 SUB_UseTargets();
 864                 self.target2 = self.oldtarget2; // reset to original target on death, incase we respawn
 865
 866                 self.monster_die();
 867
 868                 frag_attacker = attacker;
 869                 frag_target = self;
 870                 MUTATOR_CALLHOOK(MonsterDies);
 871
 872                 if(self.health <= -100) // check if we're already gibbed
 873                 {
 874                         Violence_GibSplash(self, 1, 0.5, attacker);
 875
 876                         self.think = SUB_Remove;
 877                         self.nextthink = time + 0.1;
 878                 }
 879         }
 880
 881         self.SendFlags |= MSF_STATUS;
 882 }
 883
 884 // used to hook into monster post death functions without a mutator
 885 void monster_hook_death()
 886 {
 887         WaypointSprite_Kill(self.sprite);
 888
 889         if(self.weaponentity)
 890         {
 891                 remove(self.weaponentity);
 892                 self.weaponentity = world;
 893         }
 894
 895         monster_sound(self.msound_death, 0, FALSE);
 896
 897         if(!(self.spawnflags & MONSTERFLAG_SPAWNED) && !self.monster_respawned)
 898                 monsters_killed += 1;
 899
 900         if(self.candrop && self.weapon)
 901                 W_ThrowNewWeapon(self, self.weapon, 0, self.origin, randomvec() * 150 + '0 0 325');
 902
 903         if(IS_CLIENT(self.realowner))
 904                 self.realowner.monstercount -= 1;
 905
 906         self.event_damage       = monsters_corpse_damage;
 907         self.solid                      = SOLID_CORPSE;
 908         self.takedamage         = DAMAGE_AIM;
 909         self.enemy                      = world;
 910         self.movetype           = MOVETYPE_TOSS;
 911         self.moveto                     = self.origin;
 912         self.touch                      = MonsterTouch; // reset incase monster was pouncing
 913
 914         if not(self.flags & FL_FLY)
 915                 self.velocity = '0 0 0';
 916
 917         self.SendFlags |= MSF_MOVE;
 918
 919         totalspawned -= 1;
 920 }
 921
 922 // used to hook into monster post spawn functions without a mutator
 923 void monster_hook_spawn()
 924 {
 925         if not(self.monster_respawned)
 926                 Monster_CheckMinibossFlag();
 927
 928         self.max_health = self.health;
 929         self.pain_finished = self.nextthink;
 930         self.anim_start_time = time;
 931
 932         if not(self.noalign)
 933         {
 934                 setorigin(self, self.origin + '0 0 20');
 935                 tracebox(self.origin + '0 0 100', self.mins, self.maxs, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
 936                 setorigin(self, trace_endpos);
 937         }
 938
 939         if not(self.monster_respawned)
 940                 self.skin = rint(random() * 4);
 941
 942         self.pos1 = self.origin;
 943
 944         monster_precachesounds(self);
 945
 946         if(teamplay)
 947                 self.monster_attack = TRUE; // we can have monster enemies in team games
 948
 949         if(autocvar_g_monsters_healthbars)
 950         {
 951                 WaypointSprite_Spawn(strzone(strdecolorize(self.netname)), 0, 600, self, '0 0 1' * (self.maxs_z + 15), world, 0, self, sprite, FALSE, RADARICON_DANGER, ((self.team) ? Team_ColorRGB(self.team) : '1 0 0'));
 952                 WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 953                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 954         }
 955
 956         monster_sound(self.msound_spawn, 0, FALSE);
 957
 958         MUTATOR_CALLHOOK(MonsterSpawn);
 959
 960         self.SendFlags = MSF_SETUP;
 961 }
 962
 963 float monster_initialize(string  net_name, float mon_id,
 964                                                  vector  min_s,
 965                                                  vector  max_s,
 966                                                  float   nodrop,
 967                                                  void() dieproc,
 968                                                  void() spawnproc)
 969 {
 970         if not(autocvar_g_monsters)
 971                 return FALSE;
 972
 973         // support for quake style removing monsters based on skill
 974         if(monster_skill <= autocvar_g_monsters_skill_easy && (self.spawnflags & MONSTERSKILL_NOTEASY)) { return FALSE; }
 975         if(monster_skill == autocvar_g_monsters_skill_normal && (self.spawnflags & MONSTERSKILL_NOTMEDIUM)) { return FALSE; }
 976         if(monster_skill == autocvar_g_monsters_skill_hard && (self.spawnflags & MONSTERSKILL_NOTHARD)) { return FALSE; }
 977         if(monster_skill == autocvar_g_monsters_skill_insane && (self.spawnflags & MONSTERSKILL_NOTINSANE)) { return FALSE; }
 978         if(monster_skill >= autocvar_g_monsters_skill_nightmare && (self.spawnflags & MONSTERSKILL_NOTNIGHTMARE)) { return FALSE; }
 979
 980         if(self.netname == "")
 981                 self.netname = ((net_name == "") ? self.classname : net_name);
 982
 983         if(self.team && !teamplay)
 984                 self.team = 0;
 985
 986         self.flags = FL_MONSTER;
 987
 988         if not(self.spawnflags & MONSTERFLAG_SPAWNED) // naturally spawned monster
 989         if not(self.monster_respawned)
 990                 monsters_total += 1;
 991
 992         setsize(self, min_s, max_s);
 993         self.takedamage                 = DAMAGE_AIM;
 994         self.bot_attack                 = TRUE;
 995         self.iscreature                 = TRUE;
 996         self.teleportable               = TRUE;
 997         self.damagedbycontents  = TRUE;
 998         self.monsterid                  = mon_id;
 999         self.damageforcescale   = 0.003;
1000         self.monster_die                = dieproc;
1001         self.event_damage               = monsters_damage;
1002         self.touch                              = MonsterTouch;
1003         self.use                                = monster_use;
1004         self.solid                              = SOLID_BBOX;
1005         self.scale                              = 1;
1006         self.movetype                   = MOVETYPE_WALK;
1007         self.delay                              = -1; // used in attack delay code
1008         self.spawnshieldtime    = time + autocvar_g_monsters_spawnshieldtime;
1009         monsters_spawned           += 1;
1010         self.enemy                              = world;
1011         self.velocity                   = '0 0 0';
1012         self.moveto                             = self.origin;
1013         self.pos2                               = self.angles;
1014         self.reset                              = monsters_reset;
1015         self.candrop                    = TRUE;
1016         self.view_ofs                   = '0 0 1' * (self.maxs_z * 0.5);
1017         self.oldtarget2                 = self.target2;
1018         self.deadflag                   = DEAD_NO; // UNDEAD
1019         self.noalign                    = nodrop;
1020         self.spawn_time                 = time;
1021         self.dphitcontentsmask  = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
1022
1023         if not(self.attack_range)
1024                 self.attack_range = 120;
1025
1026         if not(self.ticrate)
1027                 self.ticrate = autocvar_g_monsters_think_delay;
1028
1029         self.ticrate = bound(sys_frametime, self.ticrate, 60);
1030
1031         if not(self.armorvalue)
1032                 self.armorvalue = 1; // multiplier
1033
1034         if not(self.target_range)
1035                 self.target_range = autocvar_g_monsters_target_range;
1036
1037         if not(self.respawntime)
1038                 self.respawntime = autocvar_g_monsters_respawn_delay;
1039
1040         if not(self.monster_moveflags)
1041                 self.monster_moveflags = MONSTER_MOVE_WANDER;
1042
1043         monster_link(spawnproc);
1044
1045         return TRUE;
1046 }