qcsrc/server/monsters/monster/knight.qc

   1 const vector KNIGHT_MIN = '-20 -20 -32';
   2 const vector KNIGHT_MAX = '20 20 41';
   3
   4 string KNIGHT_MODEL = "models/monsters/hknight.mdl";
   5
   6 #ifdef SVQC
   7 float autocvar_g_monster_knight;
   8 float autocvar_g_monster_knight_health;
   9 float autocvar_g_monster_knight_melee_damage;
  10 float autocvar_g_monster_knight_inferno_damage;
  11 float autocvar_g_monster_knight_inferno_damagetime;
  12 float autocvar_g_monster_knight_inferno_chance;
  13 float autocvar_g_monster_knight_speed_walk;
  14 float autocvar_g_monster_knight_speed_run;
  15 float autocvar_g_monster_knight_fireball_damage;
  16 float autocvar_g_monster_knight_fireball_force;
  17 float autocvar_g_monster_knight_fireball_radius;
  18 float autocvar_g_monster_knight_fireball_chance;
  19 float autocvar_g_monster_knight_fireball_edgedamage;
  20 float autocvar_g_monster_knight_spike_chance;
  21 float autocvar_g_monster_knight_spike_force;
  22 float autocvar_g_monster_knight_spike_radius;
  23 float autocvar_g_monster_knight_spike_edgedamage;
  24 float autocvar_g_monster_knight_spike_damage;
  25 float autocvar_g_monster_knight_jump_chance;
  26 float autocvar_g_monster_knight_jump_damage;
  27 float autocvar_g_monster_knight_jump_dist;
  28
  29 const float knight_anim_stand   = 0;
  30 const float knight_anim_walk    = 1;
  31 const float knight_anim_run     = 2;
  32 const float knight_anim_pain    = 3;
  33 const float knight_anim_death1  = 4;
  34 const float knight_anim_death2  = 5;
  35 const float knight_anim_charge1 = 6;
  36 const float knight_anim_magic1  = 7;
  37 const float knight_anim_magic2  = 8;
  38 const float knight_anim_charge2 = 9;
  39 const float knight_anim_slice   = 10;
  40 const float knight_anim_smash   = 11;
  41 const float knight_anim_wattack = 12;
  42 const float knight_anim_magic3  = 13;
  43
  44 .float knight_cycles;
  45
  46 void knight_think()
  47 {
  48         self.think = knight_think;
  49         self.nextthink = time + self.ticrate;
  50
  51         monster_move(autocvar_g_monster_knight_speed_run, autocvar_g_monster_knight_speed_walk, 100, knight_anim_run, knight_anim_walk, knight_anim_stand);
  52 }
  53
  54 void knight_inferno()
  55 {
  56         if not(self.enemy)
  57                 return;
  58
  59         traceline((self.absmin + self.absmax) * 0.5, (self.enemy.absmin + self.enemy.absmax) * 0.5, TRUE, world);
  60         if (trace_fraction != 1)
  61                 return; // not visible
  62
  63         self.enemy.effects |= EF_MUZZLEFLASH;
  64         sound(self.enemy, CHAN_AUTO, "player/lava.wav", 1, ATTN_NORM);
  65
  66         if(vlen(self.enemy.origin - self.origin) <= 2000)
  67                 Fire_AddDamage(self.enemy, self, autocvar_g_monster_knight_inferno_damage * monster_skill, autocvar_g_monster_knight_inferno_damagetime, DEATH_MONSTER_KNIGHT_INFERNO);
  68 }
  69
  70 void knight_fireball_explode()
  71 {
  72         entity e;
  73         if(self)
  74         {
  75                 pointparticles(particleeffectnum("fireball_explode"), self.origin, '0 0 0', 1);
  76
  77                 RadiusDamage(self, self.realowner, autocvar_g_monster_knight_fireball_damage, autocvar_g_monster_knight_fireball_edgedamage, autocvar_g_monster_knight_fireball_force, world, autocvar_g_monster_knight_fireball_radius, self.projectiledeathtype, world);
  78
  79                 for(e = world; (e = findfloat(e, takedamage, DAMAGE_AIM)); ) if(vlen(e.origin - self.origin) <= autocvar_g_monster_knight_fireball_radius)
  80                         Fire_AddDamage(e, self, 5 * monster_skill, autocvar_g_monster_knight_inferno_damagetime, self.projectiledeathtype);
  81
  82                 remove(self);
  83         }
  84 }
  85
  86 void knight_fireball_touch()
  87 {
  88         PROJECTILE_TOUCH;
  89
  90         knight_fireball_explode();
  91 }
  92
  93 void knight_fireball()
  94 {
  95         entity missile = spawn();
  96         vector dir = normalize((self.enemy.origin + '0 0 10') - self.origin);
  97
  98         monster_makevectors(self.enemy);
  99
 100         self.effects |= EF_MUZZLEFLASH;
 101         sound(self, CHAN_WEAPON, "weapons/fireball2.wav", 1, ATTN_NORM);
 102
 103         missile.owner = missile.realowner = self;
 104         missile.solid = SOLID_TRIGGER;
 105         missile.movetype = MOVETYPE_FLYMISSILE;
 106         missile.projectiledeathtype = DEATH_MONSTER_KNIGHT_FBALL;
 107         setsize(missile, '-6 -6 -6', '6 6 6');
 108         setorigin(missile, self.origin + self.view_ofs + v_forward * 14);
 109         missile.flags = FL_PROJECTILE;
 110         missile.velocity = dir * 400;
 111         missile.avelocity = '300 300 300';
 112         missile.nextthink = time + 5;
 113         missile.think = knight_fireball_explode;
 114         missile.enemy = self.enemy;
 115         missile.touch = knight_fireball_touch;
 116         CSQCProjectile(missile, TRUE, PROJECTILE_FIREMINE, TRUE);
 117 }
 118
 119 void knight_spike_explode()
 120 {
 121         if(self)
 122         {
 123                 pointparticles(particleeffectnum("TE_WIZSPIKE"), self.origin, '0 0 0', 1);
 124
 125                 RadiusDamage (self, self.realowner, autocvar_g_monster_knight_spike_damage, autocvar_g_monster_knight_spike_edgedamage, autocvar_g_monster_knight_spike_force, world, autocvar_g_monster_knight_spike_radius, DEATH_MONSTER_KNIGHT_SPIKE, other);
 126                 remove(self);
 127         }
 128 }
 129
 130 void knight_spike_touch()
 131 {
 132         PROJECTILE_TOUCH;
 133
 134         knight_spike_explode();
 135 }
 136
 137 void knight_spike()
 138 {
 139         entity missile;
 140         vector dir = normalize((self.enemy.origin + '0 0 10') - self.origin);
 141
 142         self.effects |= EF_MUZZLEFLASH;
 143
 144         missile = spawn ();
 145         missile.owner = missile.realowner = self;
 146         missile.solid = SOLID_TRIGGER;
 147         missile.movetype = MOVETYPE_FLYMISSILE;
 148         setsize (missile, '0 0 0', '0 0 0');
 149         setorigin(missile, self.origin + '0 0 10' + v_forward * 14);
 150         missile.scale = self.scale;
 151         missile.flags = FL_PROJECTILE;
 152         missile.velocity = dir * 400;
 153         missile.avelocity = '300 300 300';
 154         missile.nextthink = time + 5;
 155         missile.think = knight_spike_explode;
 156         missile.enemy = self.enemy;
 157         missile.touch = knight_spike_touch;
 158         CSQCProjectile(missile, TRUE, PROJECTILE_CRYLINK, TRUE);
 159 }
 160
 161 void knight_spikes()
 162 {
 163         self.knight_cycles += 1;
 164         knight_spike();
 165
 166         if(self.knight_cycles <= 7)
 167                 defer(0.1, knight_spikes);
 168 }
 169
 170 float knight_attack_ranged()
 171 {
 172         if not(self.flags & FL_ONGROUND)
 173                 return FALSE;
 174
 175         self.knight_cycles = 0;
 176
 177         RandomSelection_Init();
 178         RandomSelection_Add(world, 1, "", autocvar_g_monster_knight_fireball_chance, 1);
 179         RandomSelection_Add(world, 2, "", autocvar_g_monster_knight_inferno_chance, 1);
 180         RandomSelection_Add(world, 3, "", autocvar_g_monster_knight_spike_chance, 1);
 181         if(self.health >= 100) RandomSelection_Add(world, 4, "", ((vlen(self.enemy.origin - self.origin) > autocvar_g_monster_knight_jump_dist) ? 1 : autocvar_g_monster_knight_jump_chance), 1);
 182
 183         switch(RandomSelection_chosen_float)
 184         {
 185                 case 1:
 186                 {
 187                         monsters_setframe(knight_anim_magic2);
 188                         self.attack_finished_single = time + 2;
 189                         defer(0.4, knight_fireball);
 190
 191                         return TRUE;
 192                 }
 193                 case 2:
 194                 {
 195                         self.attack_finished_single = time + 3;
 196                         defer(0.5, knight_inferno);
 197                         return TRUE;
 198                 }
 199                 case 3:
 200                 {
 201                         monsters_setframe(knight_anim_magic3);
 202                         self.attack_finished_single = time + 3;
 203                         defer(0.4, knight_spikes);
 204
 205                         return TRUE;
 206                 }
 207                 case 4:
 208                 {
 209                         float er = vlen(self.enemy.origin - self.origin);
 210
 211                         if(er >= 400 && er < 1200)
 212                         if(findtrajectorywithleading(self.origin, self.mins, self.maxs, self.enemy, 1000, 0, 10, 0, self))
 213                         {
 214                                 self.velocity = findtrajectory_velocity;
 215                                 Damage(self.enemy, self, self, autocvar_g_monster_knight_jump_damage * monster_skill, DEATH_MONSTER_KNIGHT_CRUSH, self.enemy.origin, normalize(self.enemy.origin - self.origin));
 216                                 self.attack_finished_single = time + 2;
 217                                 return TRUE;
 218                         }
 219                         return FALSE;
 220                 }
 221         }
 222
 223         return FALSE;
 224 }
 225
 226 float knight_attack(float attack_type)
 227 {
 228         switch(attack_type)
 229         {
 230                 case MONSTER_ATTACK_MELEE:
 231                 {
 232                         float anim;
 233                         if(random() < 0.3)
 234                                 anim = knight_anim_slice;
 235                         else if(random() < 0.6)
 236                                 anim = knight_anim_smash;
 237                         else
 238                                 anim = knight_anim_wattack;
 239
 240                         monsters_setframe(anim);
 241                         self.attack_finished_single = time + 0.7;
 242                         monster_melee(self.enemy, autocvar_g_monster_knight_melee_damage, 0.3, DEATH_MONSTER_KNIGHT_MELEE, TRUE);
 243
 244                         return TRUE;
 245                 }
 246                 case MONSTER_ATTACK_RANGED:
 247                 {
 248                         if(knight_attack_ranged())
 249                                 return TRUE;
 250                 }
 251         }
 252
 253         return FALSE;
 254 }
 255
 256 void knight_die()
 257 {
 258         float chance = random();
 259         Monster_CheckDropCvars ("knight");
 260
 261         self.think = monster_dead_think;
 262         self.nextthink = time + self.ticrate;
 263         self.ltime = time + 5;
 264         monsters_setframe((random() > 0.5) ? knight_anim_death1 : knight_anim_death2);
 265
 266         if(chance < 0.10 || self.flags & MONSTERFLAG_MINIBOSS)
 267         if(self.candrop)
 268         {
 269                 self.superweapons_finished = time + autocvar_g_balance_superweapons_time + 5; // give the player a few seconds to find the weapon
 270                 self.weapon = WEP_FIREBALL;
 271         }
 272
 273         monster_hook_death(); // for post-death mods
 274 }
 275
 276 void knight_spawn()
 277 {
 278         if not(self.health)
 279                 self.health = autocvar_g_monster_knight_health;
 280
 281         self.damageforcescale   = 0.003;
 282         self.classname                  = "monster_knight";
 283         self.monster_attackfunc = knight_attack;
 284         self.nextthink                  = time + random() * 0.5 + 0.1;
 285         self.think                              = knight_think;
 286
 287         monsters_setframe(knight_anim_stand);
 288
 289         monster_setupsounds("knight");
 290
 291         monster_hook_spawn(); // for post-spawn mods
 292 }
 293
 294 void spawnfunc_monster_knight()
 295 {
 296         if not(autocvar_g_monster_knight) { remove(self); return; }
 297
 298         self.monster_spawnfunc = spawnfunc_monster_knight;
 299
 300         if(Monster_CheckAppearFlags(self))
 301                 return;
 302
 303         self.scale = 1.3;
 304
 305         if not (monster_initialize(
 306                          "Knight", MONSTER_KNIGHT,
 307                          KNIGHT_MIN, KNIGHT_MAX,
 308                          FALSE,
 309                          knight_die, knight_spawn))
 310         {
 311                 remove(self);
 312                 return;
 313         }
 314 }
 315
 316 // compatibility with old spawns
 317 void spawnfunc_monster_hell_knight() { spawnfunc_monster_knight(); }
 318
 319 #endif // SVQC