qcsrc/server/monsters/monster/spider.qc

   1 // cvars
   2 float autocvar_g_monster_spider;
   3 float autocvar_g_monster_spider_stopspeed;
   4 float autocvar_g_monster_spider_attack_leap_delay;
   5 float autocvar_g_monster_spider_attack_stand_damage;
   6 float autocvar_g_monster_spider_attack_stand_delay;
   7 float autocvar_g_monster_spider_health;
   8 float autocvar_g_monster_spider_speed_walk;
   9 float autocvar_g_monster_spider_speed_run;
  10 float autocvar_g_monster_spider_attack_type;
  11
  12 // spider animations
  13 #define spider_anim_idle                        0
  14 #define spider_anim_walk                        1
  15 #define spider_anim_attack                      2
  16 #define spider_anim_attack2                     3
  17
  18 const vector SPIDER_MIN                          = '-18 -18 -25';
  19 const vector SPIDER_MAX                          = '18 18 30';
  20
  21 .float spider_type; // used to switch between fire & ice attacks
  22 const float SPIDER_TYPE_ICE             = 0;
  23 const float SPIDER_TYPE_FIRE    = 1;
  24
  25 void spider_spawn();
  26 void spawnfunc_monster_spider();
  27 void spider_think();
  28
  29 void spider_die ()
  30 {
  31         Monster_CheckDropCvars ("spider");
  32
  33         self.angles += '180 0 0';
  34         self.solid                      = SOLID_NOT;
  35         self.takedamage         = DAMAGE_NO;
  36         self.event_damage   = func_null;
  37         self.enemy                      = world;
  38         self.movetype           = MOVETYPE_TOSS;
  39         self.think                      = Monster_Fade;
  40         self.nextthink          = time + 2.1;
  41         self.frame                      = spider_anim_attack;
  42
  43         monster_hook_death(); // for post-death mods
  44 }
  45
  46 /**
  47  * Performe a standing attack on self.enemy.
  48  */
  49 void spider_attack_standing()
  50 {
  51         float dot = 0, bigdmg = autocvar_g_monster_spider_attack_stand_damage * self.scale;
  52
  53         self.velocity_x = 0;
  54         self.velocity_y = 0;
  55
  56         makevectors (self.angles);
  57         dot = normalize (self.enemy.origin - self.origin) * v_forward;
  58         if(dot > 0.3)
  59                 Damage(self.enemy, self, self, bigdmg * monster_skill, DEATH_MONSTER_SPIDER, self.origin, '0 0 0');
  60
  61         if(random() < 0.50)
  62                 self.frame = spider_anim_attack;
  63         else
  64                 self.frame = spider_anim_attack2;
  65
  66         self.attack_finished_single = time + autocvar_g_monster_spider_attack_stand_delay;
  67 }
  68
  69 void spider_web_explode ()
  70 {
  71         RadiusDamage (self, self.realowner, 0, 0, 1, world, 0, self.projectiledeathtype, other);
  72         remove (self);
  73 }
  74
  75 void spider_web_touch ()
  76 {
  77         PROJECTILE_TOUCH;
  78         if (other.takedamage == DAMAGE_AIM)
  79                 Freeze(other, 0.3);
  80
  81         spider_web_explode();
  82 }
  83
  84 void spider_shootweb()
  85 {
  86         // clone of the electro secondary attack, with less bouncing
  87         entity proj = world;
  88
  89         makevectors(self.angles);
  90
  91         W_SetupShot_ProjectileSize (self, '0 0 -4', '0 0 -4', FALSE, 2, "weapons/electro_fire2.wav", CH_WEAPON_A, 0);
  92
  93         w_shotdir = v_forward; // no TrueAim for grenades please
  94
  95         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  96
  97         proj = spawn ();
  98         proj.classname = "plasma";
  99         proj.owner = proj.realowner = self;
 100         proj.use = spider_web_touch;
 101         proj.think = adaptor_think2use_hittype_splash;
 102         proj.bot_dodge = TRUE;
 103         proj.bot_dodgerating = 0;
 104         proj.nextthink = time + autocvar_g_balance_electro_secondary_lifetime;
 105         PROJECTILE_MAKETRIGGER(proj);
 106         proj.projectiledeathtype = WEP_ELECTRO | HITTYPE_SECONDARY;
 107         setorigin(proj, w_shotorg);
 108
 109         //proj.glow_size = 50;
 110         //proj.glow_color = 45;
 111         proj.movetype = MOVETYPE_BOUNCE;
 112         W_SETUPPROJECTILEVELOCITY_UP(proj, g_balance_electro_secondary);
 113         proj.touch = spider_web_touch;
 114         setsize(proj, '0 0 -4', '0 0 -4');
 115         proj.takedamage = DAMAGE_YES;
 116         proj.damageforcescale = 0;
 117         proj.health = 500;
 118         proj.event_damage = W_Plasma_Damage;
 119         proj.flags = FL_PROJECTILE;
 120         proj.damagedbycontents = TRUE;
 121
 122         proj.bouncefactor = 0.3;
 123         proj.bouncestop = 0.05;
 124         proj.missile_flags = MIF_SPLASH | MIF_ARC;
 125
 126         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO, FALSE); // no culling, it has sound
 127
 128         other = proj; MUTATOR_CALLHOOK(EditProjectile);
 129 }
 130
 131 void spider_attack_leap()
 132 {
 133         vector angles_face = vectoangles(self.enemy.origin - self.origin);
 134
 135         // face the enemy
 136         self.frame = spider_anim_attack2;
 137         self.angles_y = angles_face_y ;
 138         self.attack_finished_single = time + autocvar_g_monster_spider_attack_leap_delay;
 139
 140         makevectors(self.angles);
 141
 142         switch(self.spider_type)
 143         {
 144                 default:
 145                 case SPIDER_TYPE_ICE:
 146                         spider_shootweb(); break; // must... remember... breaks!
 147                 case SPIDER_TYPE_FIRE:
 148                         W_Fireball_Attack2(); break;
 149         }
 150 }
 151
 152 float spider_attack_ranged()
 153 {
 154         if(self.enemy.frozen || self.enemy.freezetag_frozen)
 155                 return FALSE;
 156
 157         spider_attack_leap();
 158         return TRUE;
 159 }
 160
 161 void spider_think()
 162 {
 163         self.think = spider_think;
 164         self.nextthink = time + 0.1;
 165
 166         monster_move(autocvar_g_monster_spider_speed_run, autocvar_g_monster_spider_speed_walk, autocvar_g_monster_spider_stopspeed, spider_anim_walk, spider_anim_walk, spider_anim_idle);
 167 }
 168
 169 /**
 170  * Spawn the spider.
 171  */
 172 void spider_spawn()
 173 {
 174         if not(self.health)
 175                 self.health = autocvar_g_monster_spider_health * self.scale;
 176
 177         self.classname                  = "monster_spider";
 178         self.nextthink                  = time + random() * 0.5 + 0.1;
 179         self.frame                              = spider_anim_idle;
 180         self.checkattack                = GenericCheckAttack;
 181         self.attack_melee               = spider_attack_standing;
 182         self.attack_ranged              = spider_attack_ranged;
 183         self.think                              = spider_think;
 184         self.sprite_height      = 40 * self.scale;
 185
 186         monster_hook_spawn(); // for post-spawn mods
 187 }
 188
 189 /*QUAKED monster_spider (1 0 0) (-18 -18 -25) (18 18 47)
 190 Spider, 60 health points.
 191 -------- KEYS --------
 192 -------- SPAWNFLAGS --------
 193 MONSTERFLAG_APPEAR: monster will spawn when triggered.
 194 ---------NOTES----------
 195 -------- MODEL FOR RADIANT ONLY - DO NOT SET THIS AS A KEY --------
 196 modeldisabled="models/monsters/spider.dpm"
 197 */
 198 void spawnfunc_monster_spider()
 199 {
 200         if not(autocvar_g_monster_spider) { remove(self); return; }
 201
 202         self.monster_spawnfunc = spawnfunc_monster_spider;
 203         self.classname = "monster_spider";
 204         if(!self.spider_type)
 205                 self.spider_type = autocvar_g_monster_spider_attack_type;
 206
 207         if(self.spawnflags & MONSTERFLAG_APPEAR)
 208         {
 209                 self.think = func_null;
 210                 self.nextthink = -1;
 211                 self.use = Monster_Appear;
 212                 return;
 213         }
 214
 215         if not (monster_initialize(
 216                          "Spider",
 217                          "models/monsters/spider.dpm",
 218                          SPIDER_MIN, SPIDER_MAX,
 219                          FALSE,
 220                          spider_die, spider_spawn))
 221         {
 222                 remove(self);
 223                 return;
 224         }
 225 }