qcsrc/server/mutators/gamemode_ca.qc

   1 float total_players;
   2 float redalive, bluealive, yellowalive, pinkalive;
   3 .float redalive_stat, bluealive_stat, yellowalive_stat, pinkalive_stat;
   4 float ca_teams;
   5 float allowed_to_spawn;
   6
   7 void CA_count_alive_players()
   8 {
   9         entity e;
  10         total_players = redalive = bluealive = yellowalive = pinkalive = 0;
  11         FOR_EACH_PLAYER(e) {
  12                 if(e.team == NUM_TEAM_1)
  13                 {
  14                         ++total_players;
  15                         if (e.health >= 1) ++redalive;
  16                 }
  17                 else if(e.team == NUM_TEAM_2)
  18                 {
  19                         ++total_players;
  20                         if (e.health >= 1) ++bluealive;
  21                 }
  22                 else if(e.team == NUM_TEAM_3)
  23                 {
  24                         ++total_players;
  25                         if (e.health >= 1) ++yellowalive;
  26                 }
  27                 else if(e.team == NUM_TEAM_4)
  28                 {
  29                         ++total_players;
  30                         if (e.health >= 1) ++pinkalive;
  31                 }
  32         }
  33         FOR_EACH_REALCLIENT(e) {
  34                 e.redalive_stat = redalive;
  35                 e.bluealive_stat = bluealive;
  36                 e.yellowalive_stat = yellowalive;
  37                 e.pinkalive_stat = pinkalive;
  38         }
  39 }
  40
  41 float CA_GetWinnerTeam()
  42 {
  43         float winner_team = 0;
  44         if(redalive >= 1)
  45                 winner_team = NUM_TEAM_1;
  46         if(bluealive >= 1)
  47         {
  48                 if(winner_team) return 0;
  49                 winner_team = NUM_TEAM_2;
  50         }
  51         if(yellowalive >= 1)
  52         {
  53                 if(winner_team) return 0;
  54                 winner_team = NUM_TEAM_3;
  55         }
  56         if(pinkalive >= 1)
  57         {
  58                 if(winner_team) return 0;
  59                 winner_team = NUM_TEAM_4;
  60         }
  61         if(winner_team)
  62                 return winner_team;
  63         return -1; // no player left
  64 }
  65
  66 #define CA_ALIVE_TEAMS() ((redalive > 0) + (bluealive > 0) + (yellowalive > 0) + (pinkalive > 0))
  67 #define CA_ALIVE_TEAMS_OK() (CA_ALIVE_TEAMS() == ca_teams)
  68 float CA_CheckWinner()
  69 {
  70         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
  71         {
  72                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_OVER);
  73                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_OVER);
  74                 allowed_to_spawn = FALSE;
  75                 round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
  76                 return 1;
  77         }
  78
  79         CA_count_alive_players();
  80         if(CA_ALIVE_TEAMS() > 1)
  81                 return 0;
  82
  83         float winner_team = CA_GetWinnerTeam();
  84         if(winner_team > 0)
  85         {
  86                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, APP_TEAM_NUM_4(winner_team, CENTER_ROUND_TEAM_WIN_));
  87                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM_4(winner_team, INFO_ROUND_TEAM_WIN_));
  88                 TeamScore_AddToTeam(winner_team, ST_CA_ROUNDS, +1);
  89         }
  90         else if(winner_team == -1)
  91         {
  92                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_TIED);
  93                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_TIED);
  94         }
  95
  96         allowed_to_spawn = FALSE;
  97         round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
  98         return 1;
  99 }
 100
 101 void CA_RoundStart()
 102 {
 103         if(warmup_stage)
 104                 allowed_to_spawn = TRUE;
 105         else
 106                 allowed_to_spawn = FALSE;
 107 }
 108
 109 float prev_missing_teams_mask;
 110 float CA_CheckTeams()
 111 {
 112         allowed_to_spawn = TRUE;
 113         CA_count_alive_players();
 114         if(CA_ALIVE_TEAMS_OK())
 115         {
 116                 if(prev_missing_teams_mask > 0)
 117                         Kill_Notification(NOTIF_ALL, world, MSG_CENTER_CPID, CPID_MISSING_TEAMS);
 118                 prev_missing_teams_mask = -1;
 119                 return 1;
 120         }
 121         float missing_teams_mask = (!redalive) + (!bluealive) * 2;
 122         if(ca_teams >= 3) missing_teams_mask += (!yellowalive) * 4;
 123         if(ca_teams >= 4) missing_teams_mask += (!pinkalive) * 8;
 124         if(prev_missing_teams_mask != missing_teams_mask)
 125         {
 126                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
 127                 prev_missing_teams_mask = missing_teams_mask;
 128         }
 129         return 0;
 130 }
 131
 132 MUTATOR_HOOKFUNCTION(ca_PlayerSpawn)
 133 {
 134         self.caplayer = 1;
 135         return 1;
 136 }
 137
 138 MUTATOR_HOOKFUNCTION(ca_PutClientInServer)
 139 {
 140         if(!allowed_to_spawn)
 141         if(IS_PLAYER(self)) // this is true even when player is trying to join
 142         {
 143                 self.classname = "observer";
 144                 if(self.jointime != time) //not when connecting
 145                 if(!self.caplayer)
 146                 {
 147                         self.caplayer = 0.5;
 148                         if(IS_REAL_CLIENT(self))
 149                                 sprint(self, "You will join the game in the next round.\n");
 150                 }
 151         }
 152         return 1;
 153 }
 154
 155 MUTATOR_HOOKFUNCTION(ca_reset_map_players)
 156 {
 157         FOR_EACH_CLIENT(self)
 158         {
 159                 self.killcount = 0;
 160                 if(!self.caplayer && IS_BOT_CLIENT(self))
 161                 {
 162                         self.team = -1;
 163                         self.caplayer = 1;
 164                 }
 165                 if(self.caplayer)
 166                 {
 167                         self.classname = "player";
 168                         self.caplayer = 1;
 169                         PutClientInServer();
 170                 }
 171         }
 172         return 1;
 173 }
 174
 175 MUTATOR_HOOKFUNCTION(ca_ClientConnect)
 176 {
 177         self.classname = "observer";
 178         return 1;
 179 }
 180
 181 MUTATOR_HOOKFUNCTION(ca_reset_map_global)
 182 {
 183         allowed_to_spawn = TRUE;
 184         return 1;
 185 }
 186
 187 MUTATOR_HOOKFUNCTION(ca_GetTeamCount)
 188 {
 189         ret_float = ca_teams;
 190         return 0;
 191 }
 192
 193 MUTATOR_HOOKFUNCTION(ca_PlayerDies)
 194 {
 195         if(!allowed_to_spawn)
 196                 self.respawn_flags =  RESPAWN_SILENT;
 197         return 1;
 198 }
 199
 200 MUTATOR_HOOKFUNCTION(ca_ForbidPlayerScore_Clear)
 201 {
 202         return 1;
 203 }
 204
 205 MUTATOR_HOOKFUNCTION(ca_MakePlayerObserver)
 206 {
 207         if(self.killindicator_teamchange == -2)
 208                 self.caplayer = 0;
 209         if(self.caplayer)
 210                 self.frags = FRAGS_LMS_LOSER;
 211         return 1;
 212 }
 213
 214 MUTATOR_HOOKFUNCTION(ca_ForbidThrowCurrentWeapon)
 215 {
 216         return 1;
 217 }
 218
 219 MUTATOR_HOOKFUNCTION(ca_GiveFragsForKill)
 220 {
 221         frag_score = 0; // score will be given to the winner team when the round ends
 222         return 1;
 223 }
 224
 225 MUTATOR_HOOKFUNCTION(ca_SetStartItems)
 226 {
 227         start_items &= ~IT_UNLIMITED_AMMO;
 228         start_health       = warmup_start_health       = cvar("g_lms_start_health");
 229         start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
 230         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
 231         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
 232         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 233         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
 234         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
 235
 236         return 0;
 237 }
 238
 239 MUTATOR_HOOKFUNCTION(ca_PlayerDamage)
 240 {
 241         if(IS_PLAYER(frag_target))
 242         if(frag_target.deadflag == DEAD_NO)
 243         if(frag_target == frag_attacker || SAME_TEAM(frag_target, frag_attacker) || frag_deathtype == DEATH_FALL)
 244                 frag_damage = 0;
 245
 246         frag_mirrordamage = 0;
 247
 248         return FALSE;
 249 }
 250
 251 MUTATOR_HOOKFUNCTION(ca_FilterItem)
 252 {
 253         if(autocvar_g_powerups <= 0)
 254         if(self.flags & FL_POWERUP)
 255                 return TRUE;
 256
 257         if(autocvar_g_pickup_items <= 0)
 258                 return TRUE;
 259
 260         return FALSE;
 261 }
 262
 263 MUTATOR_HOOKFUNCTION(ca_PlayerDamage_SplitHealthArmor)
 264 {
 265         float excess = max(0, frag_damage - damage_take - damage_save);
 266
 267         if(frag_target != frag_attacker && IS_PLAYER(frag_attacker))
 268                 PlayerTeamScore_Add(frag_attacker, SP_SCORE, ST_SCORE, (frag_damage - excess) * autocvar_g_ca_damage2score_multiplier);
 269
 270         return FALSE;
 271 }
 272
 273 MUTATOR_HOOKFUNCTION(ca_PlayerRegen)
 274 {
 275         // no regeneration in CA
 276         return TRUE;
 277 }
 278
 279 void ca_Initialize()
 280 {
 281         allowed_to_spawn = TRUE;
 282
 283         ca_teams = autocvar_g_ca_teams_override;
 284         if(ca_teams < 2)
 285                 ca_teams = autocvar_g_ca_teams;
 286         ca_teams = bound(2, ca_teams, 4);
 287         ret_float = ca_teams;
 288         ScoreRules_ca(ca_teams);
 289
 290         round_handler_Spawn(CA_CheckTeams, CA_CheckWinner, CA_RoundStart);
 291         round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
 292
 293         addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 294         addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 295         addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 296         addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 297 }
 298
 299 MUTATOR_DEFINITION(gamemode_ca)
 300 {
 301         MUTATOR_HOOK(PlayerSpawn, ca_PlayerSpawn, CBC_ORDER_ANY);
 302         MUTATOR_HOOK(PutClientInServer, ca_PutClientInServer, CBC_ORDER_ANY);
 303         MUTATOR_HOOK(MakePlayerObserver, ca_MakePlayerObserver, CBC_ORDER_ANY);
 304         MUTATOR_HOOK(ClientConnect, ca_ClientConnect, CBC_ORDER_ANY);
 305         MUTATOR_HOOK(reset_map_global, ca_reset_map_global, CBC_ORDER_ANY);
 306         MUTATOR_HOOK(reset_map_players, ca_reset_map_players, CBC_ORDER_ANY);
 307         MUTATOR_HOOK(GetTeamCount, ca_GetTeamCount, CBC_ORDER_EXCLUSIVE);
 308         MUTATOR_HOOK(PlayerDies, ca_PlayerDies, CBC_ORDER_ANY);
 309         MUTATOR_HOOK(ForbidPlayerScore_Clear, ca_ForbidPlayerScore_Clear, CBC_ORDER_ANY);
 310         MUTATOR_HOOK(ForbidThrowCurrentWeapon, ca_ForbidThrowCurrentWeapon, CBC_ORDER_ANY);
 311         MUTATOR_HOOK(GiveFragsForKill, ca_GiveFragsForKill, CBC_ORDER_FIRST);
 312         MUTATOR_HOOK(SetStartItems, ca_SetStartItems, CBC_ORDER_ANY);
 313         MUTATOR_HOOK(PlayerDamage_Calculate, ca_PlayerDamage, CBC_ORDER_ANY);
 314         MUTATOR_HOOK(FilterItem, ca_FilterItem, CBC_ORDER_ANY);
 315         MUTATOR_HOOK(PlayerDamage_SplitHealthArmor, ca_PlayerDamage_SplitHealthArmor, CBC_ORDER_ANY);
 316         MUTATOR_HOOK(PlayerRegen, ca_PlayerRegen, CBC_ORDER_ANY);
 317
 318         MUTATOR_ONADD
 319         {
 320                 if(time > 1) // game loads at time 1
 321                         error("This is a game type and it cannot be added at runtime.");
 322                 ca_Initialize();
 323         }
 324
 325         MUTATOR_ONREMOVE
 326         {
 327                 print("This is a game type and it cannot be removed at runtime.");
 328                 return -1;
 329         }
 330
 331         return 0;
 332 }