qcsrc/server/mutators/gamemode_freezetag.qc

   1 void freezetag_Initialize()
   2 {
   3         precache_model("models/ice/ice.md3");
   4         warmup = max(time, game_starttime) + autocvar_g_freezetag_warmup;
   5         ScoreRules_freezetag();
   6 }
   7
   8 void freezetag_CheckWinner()
   9 {
  10         if(time <= game_starttime) // game didn't even start yet! nobody can win in that case.
  11                 return;
  12
  13         if(next_round || (time > warmup - autocvar_g_freezetag_warmup && time < warmup))
  14                 return; // already waiting for next round to start
  15
  16         if((redalive >= 1 && bluealive >= 1)
  17                 || (redalive >= 1 && yellowalive >= 1)
  18                 || (redalive >= 1 && pinkalive >= 1)
  19                 || (bluealive >= 1 && yellowalive >= 1)
  20                 || (bluealive >= 1 && pinkalive >= 1)
  21                 || (yellowalive >= 1 && pinkalive >= 1))
  22                 return; // we still have active players on two or more teams, nobody won yet
  23
  24         entity e, winner;
  25         string teamname;
  26         winner = world;
  27
  28         FOR_EACH_PLAYER(e)
  29         {
  30                 if(e.freezetag_frozen == 0 && e.health >= 1) // here's one player from the winning team... good
  31                 {
  32                         winner = e;
  33                         break; // break, we found the winner
  34                 }
  35         }
  36
  37         if(winner != world) // just in case a winner wasn't found
  38         {
  39                 if(winner.team == COLOR_TEAM1)
  40                         teamname = "^1Red Team";
  41                 else if(winner.team == COLOR_TEAM2)
  42                         teamname = "^4Blue Team";
  43                 else if(winner.team == COLOR_TEAM3)
  44                         teamname = "^3Yellow Team";
  45                 else
  46                         teamname = "^6Pink Team";
  47                 FOR_EACH_PLAYER(e) {
  48                         centerprint(e, strcat(teamname, "^5 wins the round, all other teams were frozen.\n"));
  49                 }
  50                 bprint(teamname, "^5 wins the round since all the other teams were frozen.\n");
  51                 TeamScore_AddToTeam(winner.team, ST_SCORE, +1);
  52         }
  53
  54         redalive = bluealive = yellowalive = pinkalive = 0;
  55         next_round = time + 5;
  56 }
  57
  58 // this is needed to allow the player to turn his view around (fixangle can't
  59 // be used to freeze his view, as that also changes the angles), while not
  60 // turning that ice object with the player
  61 void freezetag_Ice_Think()
  62 {
  63         setorigin(self, self.owner.origin - '0 0 16');
  64         self.nextthink = time;
  65 }
  66
  67 void freezetag_update_alive_stats()
  68 {
  69         entity e;
  70         FOR_EACH_REALCLIENT(e) {
  71                 e.redalive_stat = redalive;
  72                 e.bluealive_stat = bluealive;
  73                 e.yellowalive_stat = yellowalive;
  74                 e.pinkalive_stat = pinkalive;
  75         }
  76 }
  77
  78 void freezetag_add_alive()
  79 {
  80         if(self.team == COLOR_TEAM1) ++redalive;
  81         else if(self.team == COLOR_TEAM2) ++bluealive;
  82         else if(self.team == COLOR_TEAM3) ++yellowalive;
  83         else if(self.team == COLOR_TEAM4) ++pinkalive;
  84         freezetag_update_alive_stats();
  85 }
  86
  87 void freezetag_remove_alive()
  88 {
  89         if(self.team == COLOR_TEAM1) --redalive;
  90         else if(self.team == COLOR_TEAM2) --bluealive;
  91         else if(self.team == COLOR_TEAM3) --yellowalive;
  92         else if(self.team == COLOR_TEAM4) --pinkalive;
  93         freezetag_update_alive_stats();
  94 }
  95
  96 void freezetag_Freeze(entity attacker)
  97 {
  98         if(self.freezetag_frozen)
  99                 return;
 100         self.freezetag_frozen = 1;
 101         self.freezetag_revive_progress = 0;
 102         self.health = 1;
 103
 104         entity ice;
 105         ice = spawn();
 106         ice.owner = self;
 107         ice.classname = "freezetag_ice";
 108         ice.think = freezetag_Ice_Think;
 109         ice.nextthink = time;
 110         ice.frame = floor(random() * 21); // ice model has 20 different looking frames
 111         setmodel(ice, "models/ice/ice.md3");
 112
 113         entity oldself;
 114         oldself = self;
 115         self = ice;
 116         freezetag_Ice_Think();
 117         self = oldself;
 118
 119         RemoveGrapplingHook(self);
 120
 121         // add waypoint
 122         WaypointSprite_Spawn("freezetag_frozen", 0, 0, self, '0 0 64', world, self.team, self, waypointsprite_attached, TRUE, RADARICON_WAYPOINT, '0.25 0.90 1');
 123
 124         if(attacker == self)
 125         {
 126                 // you froze your own dumb self
 127                 // counted as "suicide" already
 128                 PlayerScore_Add(self, SP_SCORE, -1);
 129         }
 130         else if(attacker.classname == "player")
 131         {
 132                 // got frozen by an enemy
 133                 // counted as "kill" and "death" already
 134                 PlayerScore_Add(self, SP_SCORE, -1);
 135                 PlayerScore_Add(attacker, SP_SCORE, +1);
 136         }
 137         else
 138         {
 139                 // nothing - got frozen by the game type rules themselves
 140         }
 141 }
 142
 143 void freezetag_Unfreeze(entity attacker)
 144 {
 145         self.freezetag_frozen = 0;
 146         self.freezetag_revive_progress = 0;
 147         self.health = autocvar_g_balance_health_start;
 148
 149         // remove the ice block
 150         entity ice;
 151         for(ice = world; (ice = find(ice, classname, "freezetag_ice")); ) if(ice.owner == self)
 152         {
 153                 remove(ice);
 154                 break;
 155         }
 156
 157         // remove waypoint
 158         if(self.waypointsprite_attached)
 159                 WaypointSprite_Kill(self.waypointsprite_attached);
 160 }
 161
 162
 163 // ================
 164 // Bot player logic
 165 // ================
 166
 167 void() havocbot_role_ft_freeing;
 168 void() havocbot_role_ft_offense;
 169
 170 void havocbot_goalrating_freeplayers(float ratingscale, vector org, float sradius)
 171 {
 172         entity head;
 173         float distance;
 174
 175         FOR_EACH_PLAYER(head)
 176         {
 177                 if ((head != self) && (head.team == self.team))
 178                 {
 179                         if (head.freezetag_frozen)
 180                         {
 181                                 distance = vlen(head.origin - org);
 182                                 if (distance > sradius)
 183                                         continue;
 184                                 navigation_routerating(head, ratingscale, 2000);
 185                         }
 186                         else
 187                         {
 188                                 // If teamate is not frozen still seek them out as fight better
 189                                 // in a group.
 190                                 navigation_routerating(head, ratingscale/3, 2000);
 191                         }
 192                 }
 193         }
 194 }
 195
 196 void havocbot_role_ft_offense()
 197 {
 198         entity head;
 199         float unfrozen;
 200
 201         if(self.deadflag != DEAD_NO)
 202                 return;
 203
 204         if (!self.havocbot_role_timeout)
 205                 self.havocbot_role_timeout = time + random() * 10 + 20;
 206
 207         // Count how many players on team are unfrozen.
 208         unfrozen = 0;
 209         FOR_EACH_PLAYER(head)
 210         {
 211                 if ((head.team == self.team) && (!head.freezetag_frozen))
 212                         unfrozen++;
 213         }
 214
 215         // If only one left on team or if role has timed out then start trying to free players.
 216         if (((unfrozen == 0) && (!self.freezetag_frozen)) || (time > self.havocbot_role_timeout))
 217         {
 218                 dprint("changing role to freeing\n");
 219                 self.havocbot_role = havocbot_role_ft_freeing;
 220                 self.havocbot_role_timeout = 0;
 221                 return;
 222         }
 223
 224         if (time > self.bot_strategytime)
 225         {
 226                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 227
 228                 navigation_goalrating_start();
 229                 havocbot_goalrating_items(10000, self.origin, 10000);
 230                 havocbot_goalrating_enemyplayers(20000, self.origin, 10000);
 231                 havocbot_goalrating_freeplayers(9000, self.origin, 10000);
 232                 //havocbot_goalrating_waypoints(1, self.origin, 1000);
 233                 navigation_goalrating_end();
 234         }
 235 }
 236
 237 void havocbot_role_ft_freeing()
 238 {
 239         if(self.deadflag != DEAD_NO)
 240                 return;
 241
 242         if (!self.havocbot_role_timeout)
 243                 self.havocbot_role_timeout = time + random() * 10 + 20;
 244
 245         if (time > self.havocbot_role_timeout)
 246         {
 247                 dprint("changing role to offense\n");
 248                 self.havocbot_role = havocbot_role_ft_offense;
 249                 self.havocbot_role_timeout = 0;
 250                 return;
 251         }
 252
 253         if (time > self.bot_strategytime)
 254         {
 255                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 256
 257                 navigation_goalrating_start();
 258                 havocbot_goalrating_items(8000, self.origin, 10000);
 259                 havocbot_goalrating_enemyplayers(10000, self.origin, 10000);
 260                 havocbot_goalrating_freeplayers(20000, self.origin, 10000);
 261                 //havocbot_goalrating_waypoints(1, self.origin, 1000);
 262                 navigation_goalrating_end();
 263         }
 264 }
 265
 266
 267 // ==============
 268 // Hook Functions
 269 // ==============
 270
 271 MUTATOR_HOOKFUNCTION(freezetag_RemovePlayer)
 272 {
 273         if(self.freezetag_frozen == 0 && self.health >= 1)
 274                 freezetag_remove_alive();
 275
 276         freezetag_Unfreeze(world);
 277
 278         if(total_players > 2) // only check for winners if we had more than two players (one of them left, don't let the other player win just because of that)
 279                 freezetag_CheckWinner();
 280
 281         return 1;
 282 }
 283
 284 MUTATOR_HOOKFUNCTION(freezetag_PlayerDies)
 285 {
 286         if(self.freezetag_frozen == 0)
 287         {
 288                 freezetag_Freeze(frag_attacker);
 289                 freezetag_remove_alive();
 290         }
 291
 292         if(frag_attacker == frag_target || frag_attacker == world)
 293         {
 294                 if(frag_target.classname == STR_PLAYER)
 295                         centerprint(frag_target, "^1You froze yourself.\n");
 296                 bprint("^7", frag_target.netname, "^1 froze himself.\n");
 297         }
 298         else
 299         {
 300                 if(frag_target.classname == STR_PLAYER)
 301                         centerprint(frag_target, strcat("^1You were frozen by ^7", frag_attacker.netname, ".\n"));
 302                 if(frag_attacker.classname == STR_PLAYER)
 303                         centerprint(frag_attacker, strcat("^2You froze ^7", frag_target.netname, ".\n"));
 304                 bprint("^7", frag_target.netname, "^1 was frozen by ^7", frag_attacker.netname, ".\n");
 305         }
 306
 307         frag_target.health = 1; // "respawn" the player :P
 308
 309         freezetag_CheckWinner();
 310
 311         return 1;
 312 }
 313
 314 MUTATOR_HOOKFUNCTION(freezetag_PlayerSpawn)
 315 {
 316         freezetag_add_alive();
 317         if(time <= game_starttime || total_players == 0)
 318                 return 1;
 319
 320         freezetag_Unfreeze(world); // start by making sure that all ice blocks are removed
 321
 322         if(total_players == 1) // only one player active on server, start a new match immediately
 323         if(!next_round && warmup && (time < warmup - autocvar_g_freezetag_warmup || time > warmup)) // not awaiting next round
 324         {
 325                 redalive = bluealive = yellowalive = pinkalive = 0;
 326                 next_round = time;
 327                 return 1;
 328         }
 329
 330         if(warmup && time > warmup) // spawn too late, freeze player
 331         {
 332                 centerprint(self, "^1You spawned after the round started, you'll spawn as frozen.\n");
 333                 freezetag_Freeze(world);
 334                 freezetag_remove_alive();
 335         }
 336
 337         return 1;
 338 }
 339
 340 MUTATOR_HOOKFUNCTION(freezetag_GiveFragsForKill)
 341 {
 342         frag_score = 0; // no frags counted in Freeze Tag
 343         return 1;
 344 }
 345
 346 MUTATOR_HOOKFUNCTION(freezetag_PlayerPreThink)
 347 {
 348         float n;
 349         vector revive_extra_size;
 350
 351         if(next_round || (time > warmup - autocvar_g_freezetag_warmup && time < warmup))
 352                 return 1; // already waiting for next round to start
 353
 354         revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
 355
 356         entity o;
 357         o = world;
 358         n = 0;
 359         FOR_EACH_PLAYER(other) if(self != other)
 360         {
 361                 if(other.freezetag_frozen == 0)
 362                 {
 363                         if(other.team == self.team)
 364                         {
 365                                 if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 366                                 {
 367                                         if(!o)
 368                                                 o = other;
 369                                         ++n;
 370                                 }
 371                         }
 372                 }
 373         }
 374
 375         if(n && self.freezetag_frozen) // OK, there is at least one teammate reviving us
 376         {
 377                 self.freezetag_revive_progress = bound(0, self.freezetag_revive_progress + frametime * autocvar_g_freezetag_revive_speed, 1);
 378                 self.health = max(1, self.freezetag_revive_progress * autocvar_g_balance_health_start);
 379
 380                 if(self.freezetag_revive_progress >= 1)
 381                 {
 382                         freezetag_Unfreeze(self);
 383                         freezetag_add_alive();
 384
 385                         // EVERY team mate nearby gets a point (even if multiple!)
 386                         FOR_EACH_PLAYER(other) if(self != other)
 387                         {
 388                                 if(other.freezetag_frozen == 0)
 389                                 {
 390                                         if(other.team == self.team)
 391                                         {
 392                                                 if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 393                                                 {
 394                                                         PlayerScore_Add(other, SP_FREEZETAG_REVIVALS, +1);
 395                                                         PlayerScore_Add(other, SP_SCORE, +1);
 396                                                 }
 397                                         }
 398                                 }
 399                         }
 400
 401                         if(n > 1)
 402                                 centerprint(self, strcat("^5You were revived by ^7", o.netname, "^5 et al.\n"));
 403                         else
 404                                 centerprint(self, strcat("^5You were revived by ^7", o.netname, "^5.\n"));
 405                         centerprint(o, strcat("^5You revived ^7", self.netname, "^5.\n"));
 406                         if(n > 1)
 407                                 bprint("^7", o.netname, "^5 et al revived ^7", self.netname, "^5.\n");
 408                         else
 409                                 bprint("^7", o.netname, "^5 revived ^7", self.netname, "^5.\n");
 410                 }
 411
 412                 // now find EVERY teammate within reviving radius, set their revive_progress values correct
 413                 FOR_EACH_PLAYER(other) if(self != other)
 414                 {
 415                         if(other.freezetag_frozen == 0)
 416                         {
 417                                 if(other.team == self.team)
 418                                 {
 419                                         if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 420                                                 other.freezetag_revive_progress = self.freezetag_revive_progress;
 421                                 }
 422                         }
 423                 }
 424         }
 425         else if(!n && self.freezetag_frozen) // only if no teammate is nearby will we reset
 426         {
 427                 self.freezetag_revive_progress = bound(0, self.freezetag_revive_progress - frametime * autocvar_g_freezetag_revive_clearspeed, 1);
 428                 self.health = max(1, self.freezetag_revive_progress * autocvar_g_balance_health_start);
 429         }
 430         else if(!n)
 431         {
 432                 self.freezetag_revive_progress = 0; // thawing nobody
 433         }
 434
 435         return 1;
 436 }
 437
 438 MUTATOR_HOOKFUNCTION(freezetag_PlayerPhysics)
 439 {
 440         if(self.freezetag_frozen)
 441         {
 442                 self.movement = '0 0 0';
 443                 self.disableclientprediction = 1;
 444         }
 445         return 1;
 446 }
 447
 448 MUTATOR_HOOKFUNCTION(freezetag_PlayerDamage_Calculate)
 449 {
 450     if(g_freezetag)
 451     {
 452         if(frag_target.freezetag_frozen == 1 && frag_deathtype != DEATH_HURTTRIGGER)
 453         {
 454             frag_damage = 0;
 455             frag_force = frag_force * autocvar_g_freezetag_frozen_force;
 456         }
 457     }
 458     return 1;
 459 }
 460
 461 MUTATOR_HOOKFUNCTION(freezetag_ForbidThrowCurrentWeapon)
 462 {
 463         if (self.freezetag_frozen)
 464                 return 1;
 465         return 0;
 466 }
 467
 468 MUTATOR_HOOKFUNCTION(freezetag_BotRoles)
 469 {
 470         if not(self.deadflag)
 471         {
 472                 if (random() < 0.5)
 473                         self.havocbot_role = havocbot_role_ft_freeing;
 474                 else
 475                         self.havocbot_role = havocbot_role_ft_offense;
 476         }
 477
 478         return TRUE;
 479 }
 480
 481 MUTATOR_DEFINITION(gamemode_freezetag)
 482 {
 483         MUTATOR_HOOK(MakePlayerObserver, freezetag_RemovePlayer, CBC_ORDER_ANY);
 484         MUTATOR_HOOK(ClientDisconnect, freezetag_RemovePlayer, CBC_ORDER_ANY);
 485         MUTATOR_HOOK(PlayerDies, freezetag_PlayerDies, CBC_ORDER_ANY);
 486         MUTATOR_HOOK(PlayerSpawn, freezetag_PlayerSpawn, CBC_ORDER_ANY);
 487         MUTATOR_HOOK(GiveFragsForKill, freezetag_GiveFragsForKill, CBC_ORDER_FIRST);
 488         MUTATOR_HOOK(PlayerPreThink, freezetag_PlayerPreThink, CBC_ORDER_FIRST);
 489         MUTATOR_HOOK(PlayerPhysics, freezetag_PlayerPhysics, CBC_ORDER_FIRST);
 490         MUTATOR_HOOK(PlayerDamage_Calculate, freezetag_PlayerDamage_Calculate, CBC_ORDER_ANY);
 491         MUTATOR_HOOK(ForbidThrowCurrentWeapon, freezetag_ForbidThrowCurrentWeapon, CBC_ORDER_FIRST); //first, last or any? dunno.
 492         MUTATOR_HOOK(HavocBot_ChooseRule, freezetag_BotRoles, CBC_ORDER_ANY);
 493
 494         MUTATOR_ONADD
 495         {
 496                 if(time > 1) // game loads at time 1
 497                         error("This is a game type and it cannot be added at runtime.");
 498                 freezetag_Initialize();
 499         }
 500
 501         MUTATOR_ONREMOVE
 502         {
 503                 error("This is a game type and it cannot be removed at runtime.");
 504         }
 505
 506         return 0;
 507 }