qcsrc/server/mutators/gamemode_freezetag.qc

   1 void freezetag_Initialize()
   2 {
   3         precache_model("models/ice/ice.md3");
   4         warmup = time + autocvar_g_start_delay + autocvar_g_freezetag_warmup;
   5         ScoreRules_freezetag();
   6 }
   7
   8 void freezetag_CheckWinner()
   9 {
  10         if(time <= game_starttime) // game didn't even start yet! nobody can win in that case.
  11                 return;
  12
  13         if(next_round || (time > warmup - autocvar_g_freezetag_warmup && time < warmup))
  14                 return; // already waiting for next round to start
  15
  16         if((redalive >= 1 && bluealive >= 1) // counted in arena.qc
  17                 || (redalive >= 1 && yellowalive >= 1)
  18                 || (redalive >= 1 && pinkalive >= 1)
  19                 || (bluealive >= 1 && yellowalive >= 1)
  20                 || (bluealive >= 1 && pinkalive >= 1)
  21                 || (yellowalive >= 1 && pinkalive >= 1))
  22                 return; // we still have active players on two or more teams, nobody won yet
  23
  24         entity e, winner;
  25         string teamname;
  26
  27         FOR_EACH_PLAYER(e)
  28         {
  29                 if(e.freezetag_frozen == 0 && e.classname == "player" && e.health >= 1) // here's one player from the winning team... good
  30                 {
  31                         winner = e;
  32                         break; // break, we found the winner
  33                 }
  34         }
  35
  36         if(winner != world) // just in case a winner wasn't found
  37         {
  38                 TeamScore_AddToTeam(winner.team, ST_SCORE, +1);
  39                 if(winner.team == COLOR_TEAM1)
  40                         teamname = "^1Red Team";
  41                 else if(winner.team == COLOR_TEAM2)
  42                         teamname = "^4Blue Team";
  43                 else if(winner.team == COLOR_TEAM3)
  44                         teamname = "^3Yellow Team";
  45                 else
  46                         teamname = "^6Pink Team";
  47                 FOR_EACH_PLAYER(e) {
  48                         centerprint(e, strcat(teamname, "^5 wins the round, all other teams were frozen.\n"));
  49                 }
  50                 bprint(teamname, "^5 wins the round since all the other teams were frozen.\n");
  51         }
  52
  53         next_round = time + 5;
  54 }
  55
  56 // this is needed to allow the player to turn his view around (fixangle can't
  57 // be used to freeze his view, as that also changes the angles), while not
  58 // turning that ice object with the player
  59 void freezetag_Ice_Think()
  60 {
  61         setorigin(self, self.owner.origin - '0 0 16');
  62         self.nextthink = time;
  63 }
  64
  65 void freezetag_Freeze(entity attacker)
  66 {
  67         self.freezetag_frozen = 1;
  68
  69         entity ice;
  70         ice = spawn();
  71         ice.owner = self;
  72         ice.classname = "freezetag_ice";
  73         ice.think = freezetag_Ice_Think;
  74         ice.nextthink = time;
  75         ice.frame = floor(random() * 21); // ice model has 20 different looking frames
  76         setmodel(ice, "models/ice/ice.md3");
  77
  78         entity oldself;
  79         oldself = self;
  80         self = ice;
  81         freezetag_Ice_Think();
  82         self = oldself;
  83
  84         // add waypoint
  85         WaypointSprite_Spawn("freezetag_frozen", 0, 0, self, '0 0 64', world, self.team, self, waypointsprite_attached, TRUE);
  86         if(self.waypointsprite_attached)
  87         {
  88                 WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_WAYPOINT, '0.25 0.90 1');
  89         }
  90
  91         if(attacker == self)
  92         {
  93                 // you froze your own dumb self
  94                 // counted as "suicide" already
  95                 PlayerScore_Add(self, SP_SCORE, -1);
  96         }
  97         else if(attacker.classname == "player")
  98         {
  99                 // got frozen by an enemy
 100                 // counted as "kill" and "death" already
 101                 PlayerScore_Add(self, SP_SCORE, -1);
 102                 PlayerScore_Add(attacker, SP_SCORE, +1);
 103         }
 104         else
 105         {
 106                 // nothing - got frozen by the game type rules themselves
 107         }
 108 }
 109
 110 void freezetag_Unfreeze(entity attacker)
 111 {
 112         self.freezetag_frozen = 0;
 113
 114         if(attacker.classname == "player")
 115         {
 116                 PlayerScore_Add(attacker, SP_FREEZETAG_REVIVALS, +1);
 117                 PlayerScore_Add(attacker, SP_SCORE, +1);
 118         }
 119
 120         // remove the ice block
 121         entity ice;
 122         for(ice = world; (ice = find(ice, classname, "freezetag_ice")); ) if(ice.owner == self)
 123         {
 124                 remove(ice);
 125                 break;
 126         }
 127
 128         // remove waypoint
 129         if(self.waypointsprite_attached)
 130                 WaypointSprite_Kill(self.waypointsprite_attached);
 131 }
 132
 133 MUTATOR_HOOKFUNCTION(freezetag_RemovePlayer)
 134 {
 135         if(self.freezetag_frozen == 0)
 136         {
 137                 if(self.team == COLOR_TEAM1)
 138                         --redalive;
 139                 else if(self.team == COLOR_TEAM2)
 140                         --bluealive;
 141                 else if(self.team == COLOR_TEAM3)
 142                         --yellowalive;
 143                 else if(self.team == COLOR_TEAM4)
 144                         --pinkalive;
 145                 --totalalive;
 146         }
 147
 148         if(totalspawned > 2) // only check for winners if we had more than two players (one of them left, don't let the other player win just because of that)
 149                 freezetag_CheckWinner();
 150
 151         freezetag_Unfreeze(world);
 152
 153         return 1;
 154 }
 155
 156 MUTATOR_HOOKFUNCTION(freezetag_PlayerDies)
 157 {
 158         if(self.freezetag_frozen == 0)
 159         {
 160                 if(self.team == COLOR_TEAM1)
 161                         --redalive;
 162                 else if(self.team == COLOR_TEAM2)
 163                         --bluealive;
 164                 else if(self.team == COLOR_TEAM3)
 165                         --yellowalive;
 166                 else if(self.team == COLOR_TEAM4)
 167                         --pinkalive;
 168                 --totalalive;
 169
 170         freezetag_Freeze(frag_attacker);
 171         }
 172
 173     if(frag_attacker.classname == STR_PLAYER)
 174         centerprint(frag_attacker, strcat("^2You froze ^7", frag_target.netname, ".\n"));
 175
 176         if(frag_attacker == frag_target || frag_attacker == world)
 177         {
 178         if(frag_target.classname == STR_PLAYER)
 179             centerprint(frag_target, "^1You froze yourself.\n");
 180                 bprint("^7", frag_target.netname, "^1 froze himself.\n");
 181         }
 182         else
 183         {
 184         if(frag_target.classname == STR_PLAYER)
 185             centerprint(frag_target, strcat("^1You were frozen by ^7", frag_attacker.netname, ".\n"));
 186                 bprint("^7", frag_target.netname, "^1 was frozen by ^7", frag_attacker.netname, ".\n");
 187         }
 188
 189         frag_target.health = autocvar_g_balance_health_start; // "respawn" the player :P
 190
 191         freezetag_CheckWinner();
 192
 193         return 1;
 194 }
 195
 196 MUTATOR_HOOKFUNCTION(freezetag_PlayerSpawn)
 197 {
 198     freezetag_Unfreeze(world); // start by making sure that all ice blocks are removed
 199
 200         if(totalspawned == 1 && time > game_starttime) // only one player active on server, start a new match immediately
 201         if(!next_round && warmup && (time < warmup - autocvar_g_freezetag_warmup || time > warmup)) // not awaiting next round
 202         {
 203                 next_round = time;
 204                 return 1;
 205         }
 206         if(warmup && time > warmup) // spawn too late, freeze player
 207         {
 208                 centerprint(self, "^1You spawned after the round started, you'll spawn as frozen.\n");
 209                 freezetag_Freeze(world);
 210         }
 211
 212         return 1;
 213 }
 214
 215 MUTATOR_HOOKFUNCTION(freezetag_GiveFragsForKill)
 216 {
 217         frag_score = 0; // no frags counted in Freeze Tag
 218         return 1;
 219 }
 220
 221 MUTATOR_HOOKFUNCTION(freezetag_PlayerPreThink)
 222 {
 223     vector revive_extra_size;
 224     revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
 225
 226     float teammate_nearby;
 227     FOR_EACH_PLAYER(other) if(self != other)
 228     {
 229         if(other.freezetag_frozen == 0)
 230         {
 231             if(other.team == self.team)
 232             {
 233                 teammate_nearby = boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax);
 234                 if(teammate_nearby)
 235                     break;
 236             }
 237         }
 238     }
 239
 240     if(teammate_nearby && self.freezetag_frozen == 1) // OK, there is at least one teammate reviving us
 241     {
 242         if(self.freezetag_beginrevive_time == -9999) // initialize values if this is the first frame of revival
 243         {
 244             self.freezetag_beginrevive_time = time;
 245             self.freezetag_revive_progress = 0;
 246         }
 247         else
 248         {
 249             self.freezetag_revive_progress = (time - self.freezetag_beginrevive_time) / autocvar_g_freezetag_revive_time;
 250             if(time - self.freezetag_beginrevive_time >= autocvar_g_freezetag_revive_time)
 251             {
 252                 freezetag_Unfreeze(self);
 253
 254                 centerprint(self, strcat("^5You were revived by ^7", other.netname, ".\n"));
 255                 centerprint(other, strcat("^5You revived ^7", self.netname, ".\n"));
 256                 bprint("^7", other.netname, "^5 revived ^7", self.netname, ".\n");
 257
 258                 self.freezetag_beginrevive_time = -9999;
 259                 self.freezetag_revive_progress = 0;
 260             }
 261         }
 262         // now find EVERY teammate within reviving radius, set their revive_progress values correct
 263         FOR_EACH_PLAYER(other) if(self != other)
 264         {
 265             if(other.freezetag_frozen == 0)
 266             {
 267                 if(other.team == self.team)
 268                 {
 269                     teammate_nearby = boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax);
 270                     if(teammate_nearby)
 271                         other.freezetag_revive_progress = self.freezetag_revive_progress;
 272                 }
 273             }
 274         }
 275     }
 276     else if(!teammate_nearby) // only if no teammate is nearby will we reset
 277     {
 278         self.freezetag_beginrevive_time = -9999;
 279         self.freezetag_revive_progress = 0;
 280     }
 281
 282         return 1;
 283 }
 284
 285 MUTATOR_HOOKFUNCTION(freezetag_PlayerPhysics)
 286 {
 287         if(self.freezetag_frozen)
 288         {
 289                 self.movement = '0 0 0';
 290                 self.disableclientprediction = 1;
 291         }
 292         return 1;
 293 }
 294
 295 MUTATOR_HOOKFUNCTION(freezetag_PlayerDamage_Calculate)
 296 {
 297     if(g_freezetag)
 298     {
 299         if(frag_target.freezetag_frozen == 1 && frag_deathtype != DEATH_HURTTRIGGER)
 300         {
 301             frag_damage = 0;
 302             frag_force = frag_force * autocvar_g_freezetag_frozen_force;
 303         }
 304     }
 305     return 1;
 306 }
 307
 308 MUTATOR_DEFINITION(gamemode_freezetag)
 309 {
 310         MUTATOR_HOOK(MakePlayerObserver, freezetag_RemovePlayer, CBC_ORDER_ANY);
 311         MUTATOR_HOOK(ClientDisconnect, freezetag_RemovePlayer, CBC_ORDER_ANY);
 312         MUTATOR_HOOK(PlayerDies, freezetag_PlayerDies, CBC_ORDER_ANY);
 313         MUTATOR_HOOK(PlayerSpawn, freezetag_PlayerSpawn, CBC_ORDER_ANY);
 314         MUTATOR_HOOK(GiveFragsForKill, freezetag_GiveFragsForKill, CBC_ORDER_FIRST);
 315         MUTATOR_HOOK(PlayerPreThink, freezetag_PlayerPreThink, CBC_ORDER_FIRST);
 316         MUTATOR_HOOK(PlayerPhysics, freezetag_PlayerPhysics, CBC_ORDER_FIRST);
 317         MUTATOR_HOOK(PlayerDamage_Calculate, freezetag_PlayerDamage_Calculate, CBC_ORDER_ANY);
 318
 319         MUTATOR_ONADD
 320         {
 321                 if(time > 1) // game loads at time 1
 322                         error("This is a game type and it cannot be added at runtime.");
 323                 g_freezetag = 1;
 324                 freezetag_Initialize();
 325         }
 326
 327         MUTATOR_ONREMOVE
 328         {
 329                 g_freezetag = 0;
 330                 error("This is a game type and it cannot be removed at runtime.");
 331         }
 332
 333         return 0;
 334 }