qcsrc/server/mutators/gamemode_invasion.qc

   1 void invasion_spawnpoint()
   2 {
   3         if not(g_invasion) { remove(self); return; }
   4
   5         self.classname = "invasion_spawnpoint";
   6 }
   7
   8 float invasion_PickMonster(float have_shamblers)
   9 {
  10         if(autocvar_g_invasion_zombies_only)
  11                 return MONSTER_ZOMBIE;
  12
  13         float i;
  14
  15         RandomSelection_Init();
  16
  17         for(i = MONSTER_FIRST + 1; i < MONSTER_LAST; ++i)
  18         {
  19                 if(i == MONSTER_STINGRAY || i == MONSTER_WYVERN || (i == MONSTER_SHAMBLER && have_shamblers >= 1))
  20                         continue; // flying/swimming monsters not yet supported
  21
  22                 RandomSelection_Add(world, i, "", 1, 1);
  23         }
  24
  25         return RandomSelection_chosen_float;
  26 }
  27
  28 entity invasion_PickSpawn()
  29 {
  30         entity e;
  31
  32         RandomSelection_Init();
  33
  34         for(e = world;(e = find(e, classname, "invasion_spawnpoint")); )
  35                 RandomSelection_Add(e, 0, string_null, 1, 1);
  36
  37         return RandomSelection_chosen_ent;
  38 }
  39
  40 void invasion_SpawnChosenMonster(float mon)
  41 {
  42         entity spawn_point, monster;
  43
  44         spawn_point = invasion_PickSpawn();
  45
  46         if(spawn_point == world)
  47         {
  48                 dprint("Warning: couldn't find any invasion_spawnpoint spawnpoints, no monsters will spawn!\n");
  49                 return;
  50         }
  51
  52         monster = spawnmonster("", mon, spawn_point, spawn_point, spawn_point.origin, FALSE, 2);
  53 }
  54
  55 void invasion_SpawnMonsters(float have_shamblers)
  56 {
  57         float chosen_monster = invasion_PickMonster(have_shamblers);
  58
  59         invasion_SpawnChosenMonster(chosen_monster);
  60 }
  61
  62 float Invasion_CheckWinner()
  63 {
  64         entity head;
  65         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
  66         {
  67                 FOR_EACH_MONSTER(head)
  68                 {
  69                         WaypointSprite_Kill(head.sprite);
  70                         if(head.weaponentity) remove(head.weaponentity);
  71                         if(head.iceblock) remove(head.iceblock);
  72                         remove(head);
  73                 }
  74
  75                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_OVER);
  76                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_OVER);
  77                 round_handler_Init(5, autocvar_g_invasion_warmup, autocvar_g_invasion_round_timelimit);
  78                 return 1;
  79         }
  80
  81         float total_alive_monsters = 0, shamblers = 0;
  82
  83         FOR_EACH_MONSTER(head) if(head.health > 0)
  84         {
  85                 if(head.monsterid == MONSTER_SHAMBLER)
  86                         ++shamblers;
  87                 ++total_alive_monsters;
  88         }
  89
  90         if((total_alive_monsters + numkilled) < maxspawned && maxcurrent < 10) // 10 at a time should be plenty
  91         {
  92                 if(time >= last_check)
  93                 {
  94                         invasion_SpawnMonsters(shamblers);
  95                         last_check = time + 2;
  96                 }
  97
  98                 return 0;
  99         }
 100
 101         if(numspawned < 1 || numkilled < maxspawned)
 102                 return 0; // nothing has spawned yet, or there are still alive monsters
 103
 104         if(roundcnt >= maxrounds)
 105         {
 106                 NextLevel();
 107                 return 1;
 108         }
 109
 110         entity winner = world;
 111         float winning_score = 0;
 112
 113         FOR_EACH_PLAYER(head)
 114         {
 115                 float cs = PlayerScore_Add(head, SP_KILLS, 0);
 116                 if(cs > winning_score)
 117                 {
 118                         winning_score = cs;
 119                         winner = head;
 120                 }
 121         }
 122
 123         if(winner)
 124         {
 125                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_PLAYER_WIN, winner.netname);
 126                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_PLAYER_WIN, winner.netname);
 127         }
 128
 129         round_handler_Init(5, autocvar_g_invasion_warmup, autocvar_g_invasion_round_timelimit);
 130
 131         return 1;
 132 }
 133
 134 float Invasion_CheckPlayers()
 135 {
 136         return TRUE;
 137 }
 138
 139 void Invasion_RoundStart()
 140 {
 141         entity e;
 142         float numplayers = 0;
 143         FOR_EACH_PLAYER(e)
 144         {
 145                 e.player_blocked = 0;
 146                 ++numplayers;
 147         }
 148
 149         roundcnt += 1;
 150
 151         maxcurrent = 0;
 152         numspawned = 0;
 153         numkilled = 0;
 154
 155         if(roundcnt > 1)
 156                 maxspawned = rint(autocvar_g_invasion_monster_count * (roundcnt * 0.5));
 157         else
 158                 maxspawned = autocvar_g_invasion_monster_count;
 159
 160         monster_skill += 0.1 * numplayers;
 161 }
 162
 163 MUTATOR_HOOKFUNCTION(invasion_MonsterDies)
 164 {
 165         numkilled += 1;
 166         maxcurrent -= 1;
 167
 168         if(IS_PLAYER(frag_attacker))
 169                 PlayerScore_Add(frag_attacker, SP_KILLS, +1);
 170
 171         return FALSE;
 172 }
 173
 174 MUTATOR_HOOKFUNCTION(invasion_MonsterSpawn)
 175 {
 176         if(self.realowner == world)
 177         {
 178                 WaypointSprite_Kill(self.sprite);
 179                 if(self.weaponentity) remove(self.weaponentity);
 180                 if(self.iceblock) remove(self.iceblock);
 181                 remove(self);
 182                 return FALSE;
 183         }
 184
 185         numspawned += 1;
 186         maxcurrent += 1;
 187
 188         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
 189
 190         return FALSE;
 191 }
 192
 193 MUTATOR_HOOKFUNCTION(invasion_PlayerThink)
 194 {
 195         monsters_total = maxspawned; // TODO: make sure numspawned never exceeds maxspawned
 196         monsters_killed = numkilled;
 197
 198         return FALSE;
 199 }
 200
 201 MUTATOR_HOOKFUNCTION(invasion_PlayerSpawn)
 202 {
 203         self.bot_attack = FALSE;
 204         return FALSE;
 205 }
 206
 207 MUTATOR_HOOKFUNCTION(invasion_PlayerDamage)
 208 {
 209         if(IS_PLAYER(frag_attacker) && IS_PLAYER(frag_target) && frag_attacker != frag_target)
 210         {
 211                 frag_damage = 0;
 212                 frag_force = '0 0 0';
 213         }
 214
 215         if(frag_attacker.flags & FL_MONSTER && frag_target.flags & FL_MONSTER && frag_attacker != frag_target)
 216                 frag_damage = 0;
 217
 218         return FALSE;
 219 }
 220
 221 MUTATOR_HOOKFUNCTION(invasion_PlayerCommand)
 222 {
 223         if(MUTATOR_RETURNVALUE) // command was already handled?
 224                 return FALSE;
 225
 226         if(cmd_name == "debuginvasion")
 227         {
 228                 sprint(self, strcat("maxspawned = ", ftos(maxspawned), "\n"));
 229                 sprint(self, strcat("numspawned = ", ftos(numspawned), "\n"));
 230                 sprint(self, strcat("numkilled = ", ftos(numkilled), "\n"));
 231                 sprint(self, strcat("roundcnt = ", ftos(roundcnt), "\n"));
 232                 sprint(self, strcat("monsters_total = ", ftos(monsters_total), "\n"));
 233                 sprint(self, strcat("monsters_killed = ", ftos(monsters_killed), "\n"));
 234                 sprint(self, strcat("monster_skill = ", ftos(monster_skill), "\n"));
 235
 236                 return TRUE;
 237         }
 238
 239         return FALSE;
 240 }
 241
 242 MUTATOR_HOOKFUNCTION(invasion_SetStartItems)
 243 {
 244         start_armorvalue = 100;
 245
 246         return FALSE;
 247 }
 248
 249 void invasion_ScoreRules()
 250 {
 251         ScoreRules_basics(0, 0, 0, FALSE);
 252         ScoreInfo_SetLabel_PlayerScore(SP_KILLS, "frags", SFL_SORT_PRIO_PRIMARY);
 253         ScoreRules_basics_end();
 254 }
 255
 256 void invasion_Initialize()
 257 {
 258         independent_players = 1; // to disable extra useless scores
 259
 260         invasion_ScoreRules();
 261
 262         independent_players = 0;
 263
 264         round_handler_Spawn(Invasion_CheckPlayers, Invasion_CheckWinner, Invasion_RoundStart);
 265         round_handler_Init(5, autocvar_g_invasion_warmup, autocvar_g_invasion_round_timelimit);
 266
 267         allowed_to_spawn = TRUE;
 268
 269         monster_skill = 0.5;
 270
 271         roundcnt = 0;
 272 }
 273
 274 MUTATOR_DEFINITION(gamemode_invasion)
 275 {
 276         MUTATOR_HOOK(MonsterDies, invasion_MonsterDies, CBC_ORDER_ANY);
 277         MUTATOR_HOOK(MonsterSpawn, invasion_MonsterSpawn, CBC_ORDER_ANY);
 278         MUTATOR_HOOK(PlayerPreThink, invasion_PlayerThink, CBC_ORDER_ANY);
 279         MUTATOR_HOOK(PlayerSpawn, invasion_PlayerSpawn, CBC_ORDER_ANY);
 280         MUTATOR_HOOK(PlayerDamage_Calculate, invasion_PlayerDamage, CBC_ORDER_ANY);
 281         MUTATOR_HOOK(SV_ParseClientCommand, invasion_PlayerCommand, CBC_ORDER_ANY);
 282         MUTATOR_HOOK(SetStartItems, invasion_SetStartItems, CBC_ORDER_ANY);
 283
 284         MUTATOR_ONADD
 285         {
 286                 if(time > 1) // game loads at time 1
 287                         error("This is a game type and it cannot be added at runtime.");
 288                 invasion_Initialize();
 289
 290                 cvar_settemp("g_monsters", "1");
 291         }
 292
 293         MUTATOR_ONROLLBACK_OR_REMOVE
 294         {
 295                 // we actually cannot roll back invasion_Initialize here
 296                 // BUT: we don't need to! If this gets called, adding always
 297                 // succeeds.
 298         }
 299
 300         MUTATOR_ONREMOVE
 301         {
 302                 print("This is a game type and it cannot be removed at runtime.");
 303                 return -1;
 304         }
 305
 306         return 0;
 307 }