qcsrc/server/mutators/gamemode_keepaway.qc

   1 void ka_SpawnBall(void);
   2 void ka_TouchEvent(void);
   3 void ka_RespawnBall(void);
   4 void ka_DropEvent(entity);
   5
   6 void ka_Initialize()
   7 {
   8         if(!g_keepaway)
   9                 return;
  10
  11         precache_sound("keepaway/pickedup.wav");
  12         precache_sound("keepaway/dropped.wav");
  13
  14         ScoreRules_keepaway();
  15
  16         entity e;
  17         e = spawn();
  18         e.think = ka_SpawnBall;
  19         e.nextthink = time;
  20 }
  21
  22 void ka_SpawnBall() // self = the ball
  23 {
  24         if(!g_keepaway) {
  25                 remove(self);
  26                 return;
  27         }
  28         if (!self.model) {
  29                 self.model = "models/orbs/orbblue.md3";
  30                 self.scale = 1;
  31         }
  32
  33         precache_model(self.model);
  34         setmodel(self, self.model);
  35         setsize(self, BALL_MINS, BALL_MAXS);
  36         ball_scale = self.scale;
  37         self.classname = "keepawayball";
  38         self.damageforcescale = cvar("g_keepawayball_damageforcescale");
  39         self.takedamage = DAMAGE_YES;
  40         self.effects = self.effects | EF_FULLBRIGHT;
  41         self.movetype = MOVETYPE_BOUNCE;
  42         self.touch = ka_TouchEvent;
  43         self.think = ka_RespawnBall;
  44         self.nextthink = time;
  45         self.flags = FL_ITEM;
  46         //self.reset = ka_Reset;
  47         self.owner = world;
  48
  49         WaypointSprite_Spawn("ka-ball", 0, 0, self, '0 0 64', world, self.team, self, waypointsprite_attachedforcarrier, FALSE);
  50         WaypointSprite_UpdateTeamRadar(self.waypointsprite_attachedforcarrier, RADARICON_FLAGCARRIER, '0 1 1');
  51 }
  52
  53 void ka_RespawnBall()
  54 {
  55         if(MoveToRandomMapLocation(self, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, 10, 1024, 256))
  56         {
  57                 makevectors(self.angles);
  58                 self.movetype = MOVETYPE_BOUNCE;
  59                 self.velocity = '0 0 200';
  60                 self.angles = '0 0 0';
  61                 self.solid = SOLID_TRIGGER;
  62                 //self.touch = ka_TouchEvent;
  63                 self.think = ka_RespawnBall;
  64                 self.nextthink = time + cvar("g_keepawayball_respawntime");
  65         }
  66         else
  67         {
  68                 // sorry, can't spawn, better luck next frame
  69                 self.think = ka_RespawnBall;
  70                 self.nextthink = time;
  71         }
  72 }
  73
  74 void ka_TouchEvent()
  75 {
  76         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  77         {
  78                 self.think = ka_SpawnBall;
  79                 self.nextthink = time;
  80                 return;
  81         }
  82         if(other.classname != "player" || other.health < 1) { return; }
  83         if(!self) { return; }
  84         if(self.wait > time) { return; }
  85
  86         self.owner = other;
  87         other.ballcarried = self;
  88         setattachment(self, other, "");
  89         setorigin(self, BALL_ATTACHORG);
  90
  91         self.velocity = '0 0 0';
  92         self.movetype = MOVETYPE_NONE;
  93         self.touch = SUB_Null;
  94         self.alpha = 0.01;
  95         self.think = SUB_Null;
  96         self.nextthink = 0;
  97         self.glow_color = cvar("g_keepawayball_trail_color");
  98         self.glow_trail = TRUE;
  99         self.takedamage = DAMAGE_NO;
 100
 101         other.effects |= 8;
 102         other.alpha = 0.6;
 103
 104         bprint(other.netname, "^7 has picked up the ball!\n");
 105         WriteByte(MSG_BROADCAST, SVC_CENTERPRINT);
 106         WriteString(MSG_BROADCAST, strcat("\n\n", other.netname, "^7 has picked up the ball!\n"));
 107         sound(self.owner, CHAN_AUTO, "keepaway/pickedup.wav", VOL_BASE, ATTN_NONE);
 108
 109         PlayerScore_Add(other, SP_KEEPAWAY_PICKUPS, 1);
 110
 111         WaypointSprite_AttachCarrier("ka-ballcarrier", other);
 112         WaypointSprite_UpdateRule(other.waypointsprite_attachedforcarrier, 0, SPRITERULE_DEFAULT);
 113         WaypointSprite_UpdateTeamRadar(other.waypointsprite_attachedforcarrier, RADARICON_FLAGCARRIER, '1 0 0');
 114         WaypointSprite_Ping(other.waypointsprite_attachedforcarrier);
 115         WaypointSprite_Kill(self.waypointsprite_attachedforcarrier);
 116 }
 117
 118 void ka_DropEvent(entity plyr)
 119 {
 120         entity ball;
 121         ball = plyr.ballcarried;
 122
 123         if(!ball) { return; }
 124
 125         setattachment(ball, world, "");
 126         ball.movetype = MOVETYPE_BOUNCE;
 127         ball.solid = SOLID_TRIGGER;
 128         ball.wait = time + 1;
 129         ball.think = ka_SpawnBall;
 130         ball.nextthink = time + cvar("g_keepawayball_respawntime");
 131         ball.touch = ka_TouchEvent;
 132         ball.takedamage = DAMAGE_YES;
 133         plyr.effects = EF_LOWPRECISION;
 134         plyr.alpha = 1.0;
 135         ball.alpha = 1.0;
 136         setorigin(ball, plyr.origin + '0 0 10');
 137         ball.velocity = '0 0 200' + '0 100 0'*crandom() + '100 0 0'*crandom();
 138         ball.owner.ballcarried = world;
 139         ball.owner = world;
 140
 141         bprint(plyr.netname, "^7 has dropped the ball!\n");
 142         WriteByte(MSG_BROADCAST, SVC_CENTERPRINT);
 143         WriteString(MSG_BROADCAST, strcat("\n\n", plyr.netname, "^7 has dropped the ball!\n"));
 144         sound(other, CHAN_AUTO, "keepaway/dropped.wav", VOL_BASE, ATTN_NONE);
 145
 146         PlayerScore_Add(plyr, SP_KEEPAWAY_DROPS, 1);
 147
 148         WaypointSprite_Spawn("ka-ball", 0, 0, ball, '0 0 64', world, ball.team, ball, waypointsprite_attachedforcarrier, FALSE);
 149         WaypointSprite_UpdateRule(ball.waypointsprite_attachedforcarrier, 0, SPRITERULE_DEFAULT);
 150         WaypointSprite_UpdateTeamRadar(ball.waypointsprite_attachedforcarrier, RADARICON_FLAGCARRIER, '0 1 1');
 151         WaypointSprite_Ping(ball.waypointsprite_attachedforcarrier);
 152         WaypointSprite_Kill(plyr.waypointsprite_attachedforcarrier);
 153 }
 154
 155 MUTATOR_HOOKFUNCTION(ka_RemovePlayer)
 156 {
 157         if(self.ballcarried) { ka_DropEvent(self); }
 158         return 1;
 159 }
 160
 161 MUTATOR_HOOKFUNCTION(ka_Scoring)
 162 {
 163         if((frag_attacker != frag_target) && (frag_attacker.classname == "player"))
 164         {
 165                 if(frag_target.ballcarried) { // get amount of times killing carrier
 166                         PlayerScore_Add(frag_attacker, SP_KEEPAWAY_CARRIERKILLS, 1);
 167                         if(cvar("g_keepaway_bckillscore"))
 168                                 PlayerScore_Add(frag_attacker, SP_KEEPAWAY_SCORE, 1);
 169                 }
 170                 else if(!frag_attacker.ballcarried)
 171                         if(cvar("g_keepaway_noncarrier_warn"))
 172                                 centerprint_atprio(frag_attacker, (CENTERPRIO_SPAM + 5), "Killing people while you don't have the ball gives no points!");
 173
 174                 if(frag_attacker.ballcarried) // get kills as carrier
 175                         PlayerScore_Add(frag_attacker, SP_KEEPAWAY_SCORE, 1);
 176         }
 177
 178         if(self.ballcarried) { ka_DropEvent(self); }
 179         return 1;
 180 }
 181
 182 MUTATOR_HOOKFUNCTION(ka_GiveFragsForKill)
 183 {
 184         frag_score = 0; // no frags counted in keepaway
 185         return 1;
 186 }
 187
 188 MUTATOR_HOOKFUNCTION(ka_PlayerPreThink)
 189 {
 190         self.items &~= IT_KEY1;
 191
 192         if(self.ballcarried) {
 193                 self.items |= IT_KEY1;
 194         }
 195         return 1;
 196 }
 197
 198 MUTATOR_DEFINITION(gamemode_keepaway)
 199 {
 200         MUTATOR_HOOK(MakePlayerObserver, ka_RemovePlayer, CBC_ORDER_ANY);
 201         MUTATOR_HOOK(ClientDisconnect, ka_RemovePlayer, CBC_ORDER_ANY);
 202         MUTATOR_HOOK(PlayerDies, ka_Scoring, CBC_ORDER_ANY);
 203         MUTATOR_HOOK(GiveFragsForKill, ka_GiveFragsForKill, CBC_ORDER_FIRST);
 204         MUTATOR_HOOK(PlayerPreThink, ka_PlayerPreThink, CBC_ORDER_FIRST);
 205
 206         MUTATOR_ONADD
 207         {
 208                 if(time > 1) // game loads at time 1
 209                         error("This is a game type and it cannot be added at runtime.");
 210                 g_keepaway = 1;
 211                 ka_Initialize();
 212         }
 213
 214         MUTATOR_ONREMOVE
 215         {
 216                 g_keepaway = 0;
 217                 error("This is a game type and it cannot be removed at runtime.");
 218         }
 219
 220         return 0;
 221 }