qcsrc/server/mutators/gamemode_keyhunt.qc

   1 #define FOR_EACH_KH_KEY(v) for(v = kh_worldkeylist; v; v = v.kh_worldkeynext )
   2
   3 // #define KH_PLAYER_USE_ATTACHMENT
   4 // #define KH_PLAYER_USE_CARRIEDMODEL
   5
   6 #ifdef KH_PLAYER_USE_ATTACHMENT
   7 vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
   8 vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
   9 vector KH_PLAYER_ATTACHMENT = '0 0 0';
  10 vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  11 string KH_PLAYER_ATTACHMENT_BONE = "";
  12 #else
  13 float KH_KEY_ZSHIFT = 22;
  14 float KH_KEY_XYDIST = 24;
  15 float KH_KEY_XYSPEED = 45;
  16 #endif
  17 float KH_KEY_WP_ZSHIFT = 20;
  18
  19 vector KH_KEY_MIN = '-10 -10 -46';
  20 vector KH_KEY_MAX = '10 10 3';
  21 float KH_KEY_BRIGHTNESS = 2;
  22
  23 float kh_no_radar_circles;
  24
  25 // kh_state
  26 //     bits  0- 4: team of key 1, or 0 for no such key, or 30 for dropped, or 31 for self
  27 //     bits  5- 9: team of key 2, or 0 for no such key, or 30 for dropped, or 31 for self
  28 //     bits 10-14: team of key 3, or 0 for no such key, or 30 for dropped, or 31 for self
  29 //     bits 15-19: team of key 4, or 0 for no such key, or 30 for dropped, or 31 for self
  30 .float kh_state;
  31 .float siren_time;  //  time delay the siren
  32 //.float stuff_time;  //  time delay to stuffcmd a cvar
  33
  34 float kh_keystatus[17];
  35 //kh_keystatus[0] = status of dropped keys, kh_keystatus[1 - 16] = player #
  36 //replace 17 with cvar("maxplayers") or similar !!!!!!!!!
  37 //for(i = 0; i < maxplayers; ++i)
  38 //      kh_keystatus[i] = "0";
  39
  40 float kh_Team_ByID(float t)
  41 {
  42         if(t == 0) return FL_TEAM_1;
  43         if(t == 1) return FL_TEAM_2;
  44         if(t == 2) return FL_TEAM_3;
  45         if(t == 3) return FL_TEAM_4;
  46         return 0;
  47 }
  48
  49 entity kh_worldkeylist;
  50 .entity kh_worldkeynext;
  51 entity kh_controller;
  52 float kh_tracking_enabled;
  53 float kh_teams;
  54 float kh_interferemsg_time, kh_interferemsg_team;
  55 .entity kh_next, kh_prev; // linked list
  56 .float kh_droptime;
  57 .float kh_dropperteam;
  58 .entity kh_previous_owner;
  59 .float kh_previous_owner_playerid;
  60 .float kh_cp_duration;
  61
  62 string kh_sound_capture = "kh/capture.wav";
  63 string kh_sound_destroy = "kh/destroy.wav";
  64 string kh_sound_drop = "kh/drop.wav";
  65 string kh_sound_collect = "kh/collect.wav";
  66 string kh_sound_alarm = "kh/alarm.wav";  // the new siren/alarm
  67
  68 float kh_key_dropped, kh_key_carried;
  69
  70 float kh_KeyCarrier_waypointsprite_visible_for_player(entity e)  // runs all the time
  71 {
  72         if(e.classname != "player" || self.team != e.team)
  73                 if(!kh_tracking_enabled)
  74                         return FALSE;
  75
  76         return TRUE;
  77 }
  78
  79 float kh_Key_waypointsprite_visible_for_player(entity e) // ??
  80 {
  81         if(!kh_tracking_enabled)
  82                 return FALSE;
  83         if(!self.owner)
  84                 return TRUE;
  85         if(!self.owner.owner)
  86                 return TRUE;
  87         return FALSE;  // draw only when key is not owned
  88 }
  89
  90 void kh_update_state()
  91 {
  92         entity player;
  93         entity key;
  94         float s;
  95         float f;
  96
  97         s = 0;
  98         FOR_EACH_KH_KEY(key)
  99         {
 100                 if(key.owner)
 101                         f = key.team;
 102                 else
 103                         f = 30;
 104                 s |= pow(32, key.count) * f;
 105         }
 106
 107         FOR_EACH_CLIENT(player)
 108         {
 109                 player.kh_state = s;
 110         }
 111
 112         FOR_EACH_KH_KEY(key)
 113         {
 114                 if(key.owner)
 115                         key.owner.kh_state |= pow(32, key.count) * 31;
 116         }
 117         //print(ftos((nextent(world)).kh_state), "\n");
 118 }
 119
 120
 121
 122
 123 var kh_Think_t kh_Controller_Thinkfunc;
 124 void kh_Controller_SetThink(float t, kh_Think_t func)  // runs occasionaly
 125 {
 126         kh_Controller_Thinkfunc = func;
 127         kh_controller.cnt = ceil(t);
 128         if(t == 0)
 129                 kh_controller.nextthink = time; // force
 130 }
 131 void kh_WaitForPlayers();
 132 void kh_Controller_Think()  // called a lot
 133 {
 134         if(intermission_running)
 135                 return;
 136         if(self.cnt > 0)
 137         { if(self.think != kh_WaitForPlayers) { self.cnt -= 1; } }
 138         else if(self.cnt == 0)
 139         {
 140                 self.cnt -= 1;
 141                 kh_Controller_Thinkfunc();
 142         }
 143         self.nextthink = time + 1;
 144 }
 145
 146 // frags f: take from cvar * f
 147 // frags 0: no frags
 148 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)  // update the score when a key is captured
 149 {
 150         string s;
 151         if(intermission_running)
 152                 return;
 153
 154         if(frags_player)
 155                 UpdateFrags(player, frags_player);
 156
 157         if(key && key.owner && frags_owner)
 158                 UpdateFrags(key.owner, frags_owner);
 159
 160         if(!autocvar_sv_eventlog)  //output extra info to the console or text file
 161                 return;
 162
 163         s = strcat(":keyhunt:", what, ":", ftos(player.playerid), ":", ftos(frags_player));
 164
 165         if(key && key.owner)
 166                 s = strcat(s, ":", ftos(key.owner.playerid));
 167         else
 168                 s = strcat(s, ":0");
 169
 170         s = strcat(s, ":", ftos(frags_owner), ":");
 171
 172         if(key)
 173                 s = strcat(s, key.netname);
 174
 175         GameLogEcho(s);
 176 }
 177
 178 vector kh_AttachedOrigin(entity e)  // runs when a team captures the flag, it can run 2 or 3 times.
 179 {
 180         if(e.tag_entity)
 181         {
 182                 makevectors(e.tag_entity.angles);
 183                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 184         }
 185         else
 186                 return e.origin;
 187 }
 188
 189 void kh_Key_Attach(entity key)  // runs when a player picks up a key and several times when a key is assigned to a player at the start of a round
 190 {
 191 #ifdef KH_PLAYER_USE_ATTACHMENT
 192         entity first;
 193         first = key.owner.kh_next;
 194         if(key == first)
 195         {
 196                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 197                 if(key.kh_next)
 198                 {
 199                         setattachment(key.kh_next, key, "");
 200                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 201                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 202                         key.kh_next.angles = '0 0 0';
 203                 }
 204                 else
 205                         setorigin(key, KH_PLAYER_ATTACHMENT);
 206                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 207         }
 208         else
 209         {
 210                 setattachment(key, key.kh_prev, "");
 211                 if(key.kh_next)
 212                         setattachment(key.kh_next, key, "");
 213                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 214                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 215                 key.angles = '0 0 0';
 216         }
 217 #else
 218         setattachment(key, key.owner, "");
 219         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT);  // fixing x, y in think
 220         key.angles_y -= key.owner.angles_y;
 221 #endif
 222         key.flags = 0;
 223         key.solid = SOLID_NOT;
 224         key.movetype = MOVETYPE_NONE;
 225         key.team = key.owner.team;
 226         key.nextthink = time;
 227         key.damageforcescale = 0;
 228         key.takedamage = DAMAGE_NO;
 229         key.modelindex = kh_key_carried;
 230 }
 231
 232 void kh_Key_Detach(entity key) // runs every time a key is dropped or lost. Runs several times times when all the keys are captured
 233 {
 234 #ifdef KH_PLAYER_USE_ATTACHMENT
 235         entity first;
 236         first = key.owner.kh_next;
 237         if(key == first)
 238         {
 239                 if(key.kh_next)
 240                 {
 241                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 242                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 243                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 244                 }
 245         }
 246         else
 247         {
 248                 if(key.kh_next)
 249                         setattachment(key.kh_next, key.kh_prev, "");
 250                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 251         }
 252         // in any case:
 253         setattachment(key, world, "");
 254         setorigin(key, key.owner.origin + '0 0 1' * (PL_MIN_z - KH_KEY_MIN_z));
 255         key.angles = key.owner.angles;
 256 #else
 257         setorigin(key, key.owner.origin + key.origin_z * '0 0 1');
 258         setattachment(key, world, "");
 259         key.angles_y += key.owner.angles_y;
 260 #endif
 261         key.flags = FL_ITEM;
 262         key.solid = SOLID_TRIGGER;
 263         key.movetype = MOVETYPE_TOSS;
 264         key.pain_finished = time + autocvar_g_balance_keyhunt_delay_return;
 265         key.damageforcescale = autocvar_g_balance_keyhunt_damageforcescale;
 266         key.takedamage = DAMAGE_YES;
 267         // let key.team stay
 268         key.modelindex = kh_key_dropped;
 269         key.kh_previous_owner = key.owner;
 270         key.kh_previous_owner_playerid = key.owner.playerid;
 271 }
 272
 273 void kh_Key_AssignTo(entity key, entity player)  // runs every time a key is picked up or assigned. Runs prior to kh_key_attach
 274 {
 275         entity k;
 276         float ownerteam0, ownerteam;
 277         if(key.owner == player)
 278                 return;
 279
 280         ownerteam0 = kh_Key_AllOwnedByWhichTeam();
 281
 282         if(key.owner)
 283         {
 284                 kh_Key_Detach(key);
 285
 286                 // remove from linked list
 287                 if(key.kh_next)
 288                         key.kh_next.kh_prev = key.kh_prev;
 289                 key.kh_prev.kh_next = key.kh_next;
 290                 key.kh_next = world;
 291                 key.kh_prev = world;
 292
 293                 if(key.owner.kh_next == world)
 294                 {
 295                         // No longer a key carrier
 296                         if(!kh_no_radar_circles)
 297                                 WaypointSprite_Ping(key.owner.waypointsprite_attachedforcarrier);
 298                         WaypointSprite_DetachCarrier(key.owner);
 299                 }
 300         }
 301
 302         key.owner = player;
 303
 304         if(player)
 305         {
 306                 // insert into linked list
 307                 key.kh_next = player.kh_next;
 308                 key.kh_prev = player;
 309                 player.kh_next = key;
 310                 if(key.kh_next)
 311                         key.kh_next.kh_prev = key;
 312
 313                 float i;
 314                 i = kh_keystatus[key.owner.playerid];
 315                         if(key.netname == "^1red key")
 316                                 i += 1;
 317                         if(key.netname == "^4blue key")
 318                                 i += 2;
 319                         if(key.netname == "^3yellow key")
 320                                 i += 4;
 321                         if(key.netname == "^6pink key")
 322                                 i += 8;
 323                 kh_keystatus[key.owner.playerid] = i;
 324
 325                 kh_Key_Attach(key);
 326
 327                 if(key.kh_next == world)
 328                 {
 329                         // player is now a key carrier
 330                         WaypointSprite_AttachCarrier("", player, RADARICON_FLAGCARRIER, colormapPaletteColor(player.team - 1, 0));
 331                         player.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_KeyCarrier_waypointsprite_visible_for_player;
 332                         WaypointSprite_UpdateRule(player.waypointsprite_attachedforcarrier, player.team, SPRITERULE_TEAMPLAY);
 333                         if(player.team == FL_TEAM_1)
 334                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-red", "keycarrier-friend", "keycarrier-red");
 335                         else if(player.team == FL_TEAM_2)
 336                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-blue", "keycarrier-friend", "keycarrier-blue");
 337                         else if(player.team == FL_TEAM_3)
 338                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-yellow", "keycarrier-friend", "keycarrier-yellow");
 339                         else if(player.team == FL_TEAM_4)
 340                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-pink", "keycarrier-friend", "keycarrier-pink");
 341                         if(!kh_no_radar_circles)
 342                                 WaypointSprite_Ping(player.waypointsprite_attachedforcarrier);
 343                 }
 344         }
 345
 346         // moved that here, also update if there's no player
 347         kh_update_state();
 348
 349         key.pusher = world;
 350
 351         ownerteam = kh_Key_AllOwnedByWhichTeam();
 352         if(ownerteam != ownerteam0)
 353         {
 354                 if(ownerteam != -1)
 355                 {
 356                         kh_interferemsg_time = time + 0.2;
 357                         kh_interferemsg_team = player.team;
 358
 359                         // audit all key carrier sprites, update them to RUN HERE
 360                         FOR_EACH_KH_KEY(k)
 361                         {
 362                                 if(k.owner)
 363                                         WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, k.owner.waypointsprite_attachedforcarrier.model1, "keycarrier-finish", k.owner.waypointsprite_attachedforcarrier.model3);
 364                         }
 365                 }
 366                 else
 367                 {
 368                         kh_interferemsg_time = 0;
 369
 370                         // audit all key carrier sprites, update them to RUN HERE
 371                         FOR_EACH_KH_KEY(k)
 372                         {
 373                                 if(k.owner)
 374                                         WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, k.owner.waypointsprite_attachedforcarrier.model1, "keycarrier-friend", k.owner.waypointsprite_attachedforcarrier.model3);
 375                         }
 376                 }
 377         }
 378 }
 379
 380 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 381 {
 382         if(self.owner)
 383                 return;
 384         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 385         {
 386                 // touching lava, or hurt trigger
 387                 // what shall we do?
 388                 // immediately return is bad
 389                 // maybe start a shorter countdown?
 390         }
 391         if(vlen(force) <= 0)
 392                 return;
 393         if(time > self.pushltime)
 394                 if(attacker.classname == "player")
 395                         self.team = attacker.team;
 396 }
 397
 398 void kh_Key_Collect(entity key, entity player)  //a player picks up a dropped key
 399 {
 400         sound(player, CH_TRIGGER, kh_sound_collect, VOL_BASE, ATTN_NORM);
 401
 402         if(key.kh_dropperteam != player.team)
 403         {
 404                 kh_Scores_Event(player, key, "collect", autocvar_g_balance_keyhunt_score_collect, 0);
 405                 PlayerScore_Add(player, SP_KH_PICKUPS, 1);
 406         }
 407         key.kh_dropperteam = 0;
 408
 409         backtrace("keyhunt pickup\n");
 410         Send_Notification(NOTIF_ANY, world, MSG_INFO, APP_TEAM_ENT_4(key, INFO_KEYHUNT_PICKUP_), player.netname);
 411
 412         kh_Key_AssignTo(key, player); // this also updates .kh_state
 413 }
 414
 415 void kh_Key_Touch()  // runs many, many times when a key has been dropped and can be picked up
 416 {
 417         if(intermission_running)
 418                 return;
 419
 420         if(self.owner) // already carried
 421                 return;
 422
 423         if(ITEM_TOUCH_NEEDKILL())
 424         {
 425                 // touching sky, or nodrop
 426                 // what shall we do?
 427                 // immediately return is bad
 428                 // maybe start a shorter countdown?
 429         }
 430
 431         if(other.classname != "player")
 432                 return;
 433         if(other.deadflag != DEAD_NO)
 434                 return;
 435         if(other == self.enemy)
 436                 if(time < self.kh_droptime + autocvar_g_balance_keyhunt_delay_collect)
 437                         return;  // you just dropped it!
 438         kh_Key_Collect(self, other);
 439 }
 440
 441 void kh_Key_Remove(entity key)  // runs after when all the keys have been collected or when a key has been dropped for more than X seconds
 442 {
 443         entity o;
 444         o = key.owner;
 445         kh_Key_AssignTo(key, world);
 446         if(o) // it was attached
 447                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 448         else // it was dropped
 449                 WaypointSprite_DetachCarrier(key);
 450
 451         // remove key from key list
 452         if (kh_worldkeylist == key)
 453                 kh_worldkeylist = kh_worldkeylist.kh_worldkeynext;
 454         else
 455         {
 456                 o = kh_worldkeylist;
 457                 while (o)
 458                 {
 459                         if (o.kh_worldkeynext == key)
 460                         {
 461                                 o.kh_worldkeynext = o.kh_worldkeynext.kh_worldkeynext;
 462                                 break;
 463                         }
 464                         o = o.kh_worldkeynext;
 465                 }
 466         }
 467
 468         remove(key);
 469
 470         kh_update_state();
 471 }
 472
 473 void kh_FinishRound()  // runs when a team captures the keys
 474 {
 475         // prepare next round
 476         kh_interferemsg_time = 0;
 477         entity key;
 478
 479         kh_no_radar_circles = TRUE;
 480         FOR_EACH_KH_KEY(key)
 481                 kh_Key_Remove(key);
 482         kh_no_radar_circles = FALSE;
 483
 484         Send_Notification(NOTIF_ANY, world, MSG_CENTER, CENTER_ARENA_ROUNDSTART, autocvar_g_balance_keyhunt_delay_round);
 485         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, kh_StartRound);
 486 }
 487
 488 void kh_WinnerTeam(float teem)  // runs when a team wins // Samual: Teem?.... TEEM?!?! what the fuck is wrong with you people
 489 {
 490         // all key carriers get some points
 491         vector firstorigin, lastorigin, midpoint;
 492         float first;
 493         entity key;
 494         float score;
 495         score = (kh_teams - 1) * autocvar_g_balance_keyhunt_score_capture;
 496         DistributeEvenly_Init(score, kh_teams);
 497         // twice the score for 3 team games, three times the score for 4 team games!
 498         // note: for a win by destroying the key, this should NOT be applied
 499         FOR_EACH_KH_KEY(key)
 500         {
 501                 float f;
 502                 f = DistributeEvenly_Get(1);
 503                 kh_Scores_Event(key.owner, key, "capture", f, 0);
 504                 PlayerTeamScore_Add(key.owner, SP_KH_CAPS, ST_KH_CAPS, 1);
 505         }
 506
 507         first = TRUE;
 508         string keyowner = "";
 509         FOR_EACH_KH_KEY(key)
 510                 if(key.owner.kh_next == key)
 511                 {
 512                         if(!first)
 513                                 keyowner = strcat(keyowner, ", ");
 514                         keyowner = key.owner.netname;
 515                         first = FALSE;
 516                 }
 517
 518         backtrace("keyhunt capture\n");
 519         Send_Notification(NOTIF_ANY, world, MSG_INFO, APP_TEAM_NUM_4(teem, INFO_KEYHUNT_CAPTURE_), keyowner);
 520
 521         first = TRUE;
 522         midpoint = '0 0 0';
 523         firstorigin = '0 0 0';
 524         lastorigin = '0 0 0';
 525         FOR_EACH_KH_KEY(key)
 526         {
 527                 vector thisorigin;
 528
 529                 thisorigin = kh_AttachedOrigin(key);
 530                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 531                 midpoint += thisorigin;
 532
 533                 if(!first)
 534                         te_lightning2(world, lastorigin, thisorigin);
 535                 lastorigin = thisorigin;
 536                 if(first)
 537                         firstorigin = thisorigin;
 538                 first = FALSE;
 539         }
 540         if(kh_teams > 2)
 541         {
 542                 te_lightning2(world, lastorigin, firstorigin);
 543         }
 544         midpoint = midpoint * (1 / kh_teams);
 545         te_customflash(midpoint, 1000, 1, Team_ColorRGB(teem) * 0.5 + '0.5 0.5 0.5');  // make the color >=0.5 in each component
 546
 547         play2all(kh_sound_capture);
 548         kh_FinishRound();
 549 }
 550
 551 void kh_LoserTeam(float teem, entity lostkey)  // runs when a player pushes a flag carrier off the map
 552 {
 553         entity player, key, attacker;
 554         float players;
 555         float keys;
 556         float f;
 557
 558         attacker = world;
 559         if(lostkey.pusher)
 560                 if(lostkey.pusher.team != teem)
 561                         if(lostkey.pusher.classname == "player")
 562                                 attacker = lostkey.pusher;
 563
 564         players = keys = 0;
 565
 566         if(attacker)
 567         {
 568                 if(lostkey.kh_previous_owner)
 569                         kh_Scores_Event(lostkey.kh_previous_owner, world, "pushed", 0, -autocvar_g_balance_keyhunt_score_push);
 570                         // don't actually GIVE him the -nn points, just log
 571                 kh_Scores_Event(attacker, world, "push", autocvar_g_balance_keyhunt_score_push, 0);
 572                 PlayerScore_Add(attacker, SP_KH_PUSHES, 1);
 573                 //centerprint(attacker, "Your push is the best!"); // does this really need to exist?
 574         }
 575         else
 576         {
 577                 float of, fragsleft, i, j, thisteam;
 578                 of = autocvar_g_balance_keyhunt_score_destroyed_ownfactor;
 579
 580                 FOR_EACH_PLAYER(player)
 581                         if(player.team != teem)
 582                                 ++players;
 583
 584                 FOR_EACH_KH_KEY(key)
 585                         if(key.owner && key.team != teem)
 586                                 ++keys;
 587
 588                 if(lostkey.kh_previous_owner)
 589                         kh_Scores_Event(lostkey.kh_previous_owner, world, "destroyed", 0, -autocvar_g_balance_keyhunt_score_destroyed);
 590                         // don't actually GIVE him the -nn points, just log
 591
 592                 if(lostkey.kh_previous_owner.playerid == lostkey.kh_previous_owner_playerid)
 593                         PlayerScore_Add(lostkey.kh_previous_owner, SP_KH_DESTROYS, 1);
 594
 595                 DistributeEvenly_Init(autocvar_g_balance_keyhunt_score_destroyed, keys * of + players);
 596
 597                 FOR_EACH_KH_KEY(key)
 598                         if(key.owner && key.team != teem)
 599                         {
 600                                 f = DistributeEvenly_Get(of);
 601                                 kh_Scores_Event(key.owner, world, "destroyed_holdingkey", f, 0);
 602                         }
 603
 604                 fragsleft = DistributeEvenly_Get(players);
 605
 606                 // Now distribute these among all other teams...
 607                 j = kh_teams - 1;
 608                 for(i = 0; i < kh_teams; ++i)
 609                 {
 610                         thisteam = kh_Team_ByID(i);
 611                         if(thisteam == teem) // bad boy, no cookie - this WILL happen
 612                                 continue;
 613
 614                         players = 0;
 615                         FOR_EACH_PLAYER(player)
 616                                 if(player.team == thisteam)
 617                                         ++players;
 618
 619                         DistributeEvenly_Init(fragsleft, j);
 620                         fragsleft = DistributeEvenly_Get(j - 1);
 621                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 622
 623                         FOR_EACH_PLAYER(player)
 624                                 if(player.team == thisteam)
 625                                 {
 626                                         f = DistributeEvenly_Get(1);
 627                                         kh_Scores_Event(player, world, "destroyed", f, 0);
 628                                 }
 629
 630                         --j;
 631                 }
 632         }
 633
 634         backtrace("keyhunt lost\n");
 635         Send_Notification(NOTIF_ANY, world, MSG_INFO, APP_TEAM_ENT_4(lostkey, INFO_KEYHUNT_LOST_), lostkey.kh_previous_owner.netname);
 636
 637         play2all(kh_sound_destroy);
 638         te_tarexplosion(lostkey.origin);
 639
 640         kh_FinishRound();
 641 }
 642
 643 void kh_Key_Think()  // runs all the time
 644 {
 645         entity head;
 646         //entity player;  // needed by FOR_EACH_PLAYER
 647
 648         if(intermission_running)
 649                 return;
 650
 651         if(self.owner)
 652         {
 653 #ifndef KH_PLAYER_USE_ATTACHMENT
 654                 makevectors('0 1 0' * (self.cnt + mod(time, 360) * KH_KEY_XYSPEED));
 655                 setorigin(self, v_forward * KH_KEY_XYDIST + '0 0 1' * self.origin_z);
 656 #endif
 657         }
 658
 659         // if in nodrop or time over, end the round
 660         if(!self.owner)
 661                 if(time > self.pain_finished)
 662                         kh_LoserTeam(self.team, self);
 663
 664         if(self.owner)
 665         if(kh_Key_AllOwnedByWhichTeam() != -1)
 666         {
 667                 if(self.siren_time < time)
 668                 {
 669                         sound(self.owner, CH_TRIGGER, kh_sound_alarm, VOL_BASE, ATTN_NORM);  // play a simple alarm
 670                         self.siren_time = time + 2.5;  // repeat every 2.5 seconds
 671                 }
 672
 673                 entity key;
 674                 vector p;
 675                 p = self.owner.origin;
 676                 FOR_EACH_KH_KEY(key)
 677                         if(vlen(key.owner.origin - p) > autocvar_g_balance_keyhunt_maxdist)
 678                                 goto not_winning;
 679                 kh_WinnerTeam(self.team);
 680 :not_winning
 681         }
 682
 683         if(kh_interferemsg_time && time > kh_interferemsg_time)
 684         {
 685                 kh_interferemsg_time = 0;
 686                 FOR_EACH_PLAYER(head)
 687                 {
 688                         if(head.team == kh_interferemsg_team)
 689                                 if(head.kh_next)
 690                                         Send_Notification(NOTIF_ONE, head, MSG_CENTER, CENTER_KEYHUNT_MEET);
 691                                 else
 692                                         Send_Notification(NOTIF_ONE, head, MSG_CENTER, CENTER_KEYHUNT_HELP);
 693                         else
 694                                 Send_Notification(NOTIF_ONE, head, MSG_CENTER, APP_TEAM_NUM_4(kh_interferemsg_team, CENTER_KEYHUNT_INTERFERE_));
 695                 }
 696         }
 697
 698         self.nextthink = time + 0.05;
 699 }
 700
 701 void key_reset()
 702 {
 703         kh_Key_AssignTo(self, world);
 704         kh_Key_Remove(self);
 705 }
 706
 707 string STR_ITEM_KH_KEY = "item_kh_key";
 708 void kh_Key_Spawn(entity initial_owner, float angle, float i)  // runs every time a new flag is created, ie after all the keys have been collected
 709 {
 710         entity key;
 711         key = spawn();
 712         key.count = i;
 713         key.classname = STR_ITEM_KH_KEY;
 714         key.touch = kh_Key_Touch;
 715         key.think = kh_Key_Think;
 716         key.nextthink = time;
 717         key.items = IT_KEY1 | IT_KEY2;
 718         key.cnt = angle;
 719         key.angles = '0 360 0' * random();
 720         key.event_damage = kh_Key_Damage;
 721         key.takedamage = DAMAGE_YES;
 722         key.modelindex = kh_key_dropped;
 723         key.model = "key";
 724         key.kh_dropperteam = 0;
 725         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 726         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 727         key.colormod = Team_ColorRGB(initial_owner.team) * KH_KEY_BRIGHTNESS;
 728         key.reset = key_reset;
 729
 730         switch(initial_owner.team)
 731         {
 732                 case FL_TEAM_1:
 733                         key.netname = "^1red key";
 734                         break;
 735                 case FL_TEAM_2:
 736                         key.netname = "^4blue key";
 737                         break;
 738                 case FL_TEAM_3:
 739                         key.netname = "^3yellow key";
 740                         break;
 741                 case FL_TEAM_4:
 742                         key.netname = "^6pink key";
 743                         break;
 744                 default:
 745                         key.netname = "NETGIER key";
 746                         break;
 747         }
 748
 749         // link into key list
 750         key.kh_worldkeynext = kh_worldkeylist;
 751         kh_worldkeylist = key;
 752
 753         Send_Notification(NOTIF_ONE, initial_owner, MSG_CENTER, APP_TEAM_NUM_4(initial_owner.team, CENTER_KEYHUNT_START_));
 754
 755         WaypointSprite_Spawn("key-dropped", 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, world, key.team, key, waypointsprite_attachedforcarrier, FALSE, RADARICON_FLAG, '0 1 1');
 756         key.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_Key_waypointsprite_visible_for_player;
 757
 758         kh_Key_AssignTo(key, initial_owner);
 759 }
 760
 761 // -1 when no team completely owns all keys yet
 762 float kh_Key_AllOwnedByWhichTeam()  // constantly called. check to see if all the keys are owned by the same team
 763 {
 764         entity key;
 765         float teem;
 766         float keys;
 767
 768         teem = -1;
 769         keys = kh_teams;
 770         FOR_EACH_KH_KEY(key)
 771         {
 772                 if(!key.owner)
 773                         return -1;
 774                 if(teem == -1)
 775                         teem = key.team;
 776                 else if(teem != key.team)
 777                         return -1;
 778                 --keys;
 779         }
 780         if(keys != 0)
 781                 return -1;
 782         return teem;
 783 }
 784
 785 void kh_Key_DropOne(entity key)
 786 {
 787         // prevent collecting this one for some time
 788         entity player;
 789         player = key.owner;
 790
 791         key.kh_droptime = time;
 792         key.enemy = player;
 793
 794         kh_Scores_Event(player, key, "dropkey", 0, 0);
 795         PlayerScore_Add(player, SP_KH_LOSSES, 1);
 796         Send_Notification(NOTIF_ANY, world, MSG_INFO, APP_TEAM_ENT_4(key, INFO_KEYHUNT_DROP_), player.netname);
 797
 798         kh_Key_AssignTo(key, world);
 799         makevectors(player.v_angle);
 800         key.velocity = W_CalculateProjectileVelocity(player.velocity, autocvar_g_balance_keyhunt_throwvelocity * v_forward, FALSE);
 801         key.pusher = world;
 802         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 803         key.kh_dropperteam = key.team;
 804
 805         sound(player, CH_TRIGGER, kh_sound_drop, VOL_BASE, ATTN_NORM);
 806 }
 807
 808 void kh_Key_DropAll(entity player, float suicide) // runs whenever a player dies
 809 {
 810         entity key;
 811         entity mypusher;
 812         if(player.kh_next)
 813         {
 814                 mypusher = world;
 815                 if(player.pusher)
 816                         if(time < player.pushltime)
 817                                 mypusher = player.pusher;
 818                 while((key = player.kh_next))
 819                 {
 820                         kh_Scores_Event(player, key, "losekey", 0, 0);
 821                         PlayerScore_Add(player, SP_KH_LOSSES, 1);
 822                         Send_Notification(NOTIF_ANY, world, MSG_INFO, APP_TEAM_ENT_4(key, INFO_KEYHUNT_LOST_), player.netname);
 823                         kh_Key_AssignTo(key, world);
 824                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 825                         key.velocity = W_CalculateProjectileVelocity(player.velocity, autocvar_g_balance_keyhunt_dropvelocity * v_forward, FALSE);
 826                         key.pusher = mypusher;
 827                         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 828                         if(suicide)
 829                                 key.kh_dropperteam = player.team;
 830                 }
 831                 sound(player, CH_TRIGGER, kh_sound_drop, VOL_BASE, ATTN_NORM);
 832         }
 833 }
 834
 835 float kh_CheckPlayers(float num)
 836 {
 837         if(num < kh_teams)
 838         {
 839                 float t_team = kh_Team_ByID(num);
 840                 float players = 0;
 841                 entity tmp_player;
 842                 FOR_EACH_PLAYER(tmp_player)
 843                         if(tmp_player.deadflag == DEAD_NO)
 844                                 if(!tmp_player.BUTTON_CHAT)
 845                                         if(tmp_player.team == t_team)
 846                                                 ++players;
 847
 848                 if not(players) { return t_team; }
 849         }
 850         return 0;
 851 }
 852
 853 void kh_WaitForPlayers()  // delay start of the round until enough players are present
 854 {
 855         if(time < game_starttime)
 856         {
 857                 kh_Controller_SetThink(game_starttime - time + 0.1, kh_WaitForPlayers);
 858                 return;
 859         }
 860
 861         float p1 = kh_CheckPlayers(0), p2 = kh_CheckPlayers(1), p3 = kh_CheckPlayers(2), p4 = kh_CheckPlayers(3);
 862         if not(p1 || p2 || p3 || p4)
 863         {
 864                 Send_Notification(NOTIF_ANY, world, MSG_CENTER, CENTER_ARENA_ROUNDSTART, autocvar_g_balance_keyhunt_delay_round);
 865                 kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, kh_StartRound);
 866         }
 867         else
 868         {
 869                 Send_Notification(NOTIF_ANY, world, MSG_CENTER, CENTER_KEYHUNT_WAIT, p1, p2, p3, p4);
 870                 kh_Controller_SetThink(1, kh_WaitForPlayers);
 871         }
 872 }
 873
 874 void kh_EnableTrackingDevice()  // runs after each round
 875 {
 876         Kill_Notification(NOTIF_ANY, world, MSG_CENTER, CENTER_KEYHUNT_HELP);
 877
 878         kh_tracking_enabled = TRUE;
 879 }
 880
 881 void kh_StartRound()  // runs at the start of each round
 882 {
 883         float i, players, teem;
 884         entity player;
 885
 886         if(time < game_starttime)
 887         {
 888                 kh_Controller_SetThink(game_starttime - time + 0.1, kh_WaitForPlayers);
 889                 return;
 890         }
 891
 892         float p1 = kh_CheckPlayers(0), p2 = kh_CheckPlayers(1), p3 = kh_CheckPlayers(2), p4 = kh_CheckPlayers(3);
 893         if(p1 || p2 || p3 || p4)
 894         {
 895                 kh_Controller_SetThink(1, kh_WaitForPlayers);
 896                 Send_Notification(NOTIF_ANY, world, MSG_CENTER, CENTER_KEYHUNT_WAIT, p1, p2, p3, p4);
 897                 return;
 898         }
 899
 900         Kill_Notification(NOTIF_ANY, world, MSG_CENTER, CENTER_KEYHUNT_HELP);
 901
 902         for(i = 0; i < kh_teams; ++i)
 903         {
 904                 teem = kh_Team_ByID(i);
 905                 players = 0;
 906                 entity my_player = world;
 907                 FOR_EACH_PLAYER(player)
 908                         if(player.deadflag == DEAD_NO)
 909                                 if(!player.BUTTON_CHAT)
 910                                         if(player.team == teem)
 911                                         {
 912                                                 ++players;
 913                                                 if(random() * players <= 1)
 914                                                         my_player = player;
 915                                         }
 916                 kh_Key_Spawn(my_player, 360 * i / kh_teams, i);
 917         }
 918
 919         kh_tracking_enabled = FALSE;
 920         Send_Notification(NOTIF_ANY, world, MSG_CENTER, CENTER_KEYHUNT_SCAN, autocvar_g_balance_keyhunt_delay_tracking);
 921         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_tracking, kh_EnableTrackingDevice);
 922 }
 923
 924 float kh_HandleFrags(entity attacker, entity targ, float f)  // adds to the player score
 925 {
 926         if(attacker == targ)
 927                 return f;
 928
 929         if(targ.kh_next)
 930         {
 931                 if(attacker.team == targ.team)
 932                 {
 933                         entity k;
 934                         float nk;
 935                         nk = 0;
 936                         for(k = targ.kh_next; k != world; k = k.kh_next)
 937                                 ++nk;
 938                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * autocvar_g_balance_keyhunt_score_collect, 0);
 939                 }
 940                 else
 941                 {
 942                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", autocvar_g_balance_keyhunt_score_carrierfrag-1, 0);
 943                         PlayerScore_Add(attacker, SP_KH_KCKILLS, 1);
 944                         // the frag gets added later
 945                 }
 946         }
 947
 948         return f;
 949 }
 950
 951 void kh_Initialize()  // sets up th KH environment
 952 {
 953         precache_sound(kh_sound_capture);
 954         precache_sound(kh_sound_destroy);
 955         precache_sound(kh_sound_drop);
 956         precache_sound(kh_sound_collect);
 957         precache_sound(kh_sound_alarm);  // the new siren
 958
 959 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 960         precache_model("models/keyhunt/key-carried.md3");
 961 #endif
 962         precache_model("models/keyhunt/key.md3");
 963
 964         // setup variables
 965         kh_teams = autocvar_g_keyhunt_teams_override;
 966         if(kh_teams < 2)
 967                 kh_teams = autocvar_g_keyhunt_teams;
 968         kh_teams = bound(2, kh_teams, 4);
 969
 970         // make a KH entity for controlling the game
 971         kh_controller = spawn();
 972         kh_controller.think = kh_Controller_Think;
 973         kh_Controller_SetThink(0, kh_WaitForPlayers);
 974
 975         setmodel(kh_controller, "models/keyhunt/key.md3");
 976         kh_key_dropped = kh_controller.modelindex;
 977         /*
 978         dprint(vtos(kh_controller.mins));
 979         dprint(vtos(kh_controller.maxs));
 980         dprint("\n");
 981         */
 982 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 983         setmodel(kh_controller, "models/keyhunt/key-carried.md3");
 984         kh_key_carried = kh_controller.modelindex;
 985 #else
 986         kh_key_carried = kh_key_dropped;
 987 #endif
 988
 989         kh_controller.model = "";
 990         kh_controller.modelindex = 0;
 991
 992         addstat(STAT_KH_KEYS, AS_INT, kh_state);
 993
 994         ScoreRules_kh(kh_teams);
 995 }
 996
 997 void kh_finalize()
 998 {
 999         // to be called before intermission
1000         kh_FinishRound();
1001         remove(kh_controller);
1002         kh_controller = world;
1003 }
1004
1005 // register this as a mutator
1006
1007 MUTATOR_HOOKFUNCTION(kh_Key_DropAll)
1008 {
1009         kh_Key_DropAll(self, TRUE);
1010         return 0;
1011 }
1012
1013 MUTATOR_HOOKFUNCTION(kh_PlayerDies)
1014 {
1015         if(self == other)
1016                 kh_Key_DropAll(self, TRUE);
1017         else if(other.classname == "player")
1018                 kh_Key_DropAll(self, FALSE);
1019         else
1020                 kh_Key_DropAll(self, TRUE);
1021         return 0;
1022 }
1023
1024 MUTATOR_HOOKFUNCTION(kh_GiveFragsForKill)
1025 {
1026         frag_score = kh_HandleFrags(frag_attacker, frag_target, frag_score);
1027         return 0;
1028 }
1029
1030 MUTATOR_HOOKFUNCTION(kh_finalize)
1031 {
1032         kh_finalize();
1033         return 0;
1034 }
1035
1036 MUTATOR_HOOKFUNCTION(kh_GetTeamCount)
1037 {
1038         ret_float = kh_teams;
1039         return 0;
1040 }
1041
1042 MUTATOR_HOOKFUNCTION(kh_SpectateCopy)
1043 {
1044         self.kh_state = other.kh_state;
1045         return 0;
1046 }
1047
1048 MUTATOR_HOOKFUNCTION(kh_PlayerUseKey)
1049 {
1050         if(MUTATOR_RETURNVALUE == 0)
1051         {
1052                 entity k;
1053                 k = self.kh_next;
1054                 if(k)
1055                 {
1056                         kh_Key_DropOne(k);
1057                         return 1;
1058                 }
1059         }
1060         return 0;
1061 }
1062
1063 MUTATOR_DEFINITION(gamemode_keyhunt)
1064 {
1065         MUTATOR_HOOK(MakePlayerObserver, kh_Key_DropAll, CBC_ORDER_ANY);
1066         MUTATOR_HOOK(ClientDisconnect, kh_Key_DropAll, CBC_ORDER_ANY);
1067         MUTATOR_HOOK(PlayerDies, kh_PlayerDies, CBC_ORDER_ANY);
1068         MUTATOR_HOOK(GiveFragsForKill, kh_GiveFragsForKill, CBC_ORDER_FIRST);
1069         MUTATOR_HOOK(MatchEnd, kh_finalize, CBC_ORDER_ANY);
1070         MUTATOR_HOOK(GetTeamCount, kh_GetTeamCount, CBC_ORDER_EXCLUSIVE);
1071         MUTATOR_HOOK(SpectateCopy, kh_SpectateCopy, CBC_ORDER_ANY);
1072         MUTATOR_HOOK(PlayerUseKey, kh_PlayerUseKey, CBC_ORDER_ANY);
1073
1074         MUTATOR_ONADD
1075         {
1076                 if(time > 1) // game loads at time 1
1077                         error("This is a game type and it cannot be added at runtime.");
1078                 kh_Initialize();
1079         }
1080
1081         MUTATOR_ONROLLBACK_OR_REMOVE
1082         {
1083                 // we actually cannot roll back kh_Initialize here
1084                 // BUT: we don't need to! If this gets called, adding always
1085                 // succeeds.
1086         }
1087
1088         MUTATOR_ONREMOVE
1089         {
1090                 print("This is a game type and it cannot be removed at runtime.");
1091                 return -1;
1092         }
1093
1094         return 0;
1095 }