qcsrc/server/mutators/gamemode_keyhunt.qc

   1 #define FOR_EACH_KH_KEY(v) for(v = kh_worldkeylist; v; v = v.kh_worldkeynext )
   2
   3 // #define KH_PLAYER_USE_ATTACHMENT
   4 // #define KH_PLAYER_USE_CARRIEDMODEL
   5
   6 #ifdef KH_PLAYER_USE_ATTACHMENT
   7 const vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
   8 const vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
   9 const vector KH_PLAYER_ATTACHMENT = '0 0 0';
  10 const vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  11 const string KH_PLAYER_ATTACHMENT_BONE = "";
  12 #else
  13 const float KH_KEY_ZSHIFT = 22;
  14 const float KH_KEY_XYDIST = 24;
  15 const float KH_KEY_XYSPEED = 45;
  16 #endif
  17 const float KH_KEY_WP_ZSHIFT = 20;
  18
  19 const vector KH_KEY_MIN = '-10 -10 -46';
  20 const vector KH_KEY_MAX = '10 10 3';
  21 const float KH_KEY_BRIGHTNESS = 2;
  22
  23 float kh_no_radar_circles;
  24
  25 // kh_state
  26 //     bits  0- 4: team of key 1, or 0 for no such key, or 30 for dropped, or 31 for self
  27 //     bits  5- 9: team of key 2, or 0 for no such key, or 30 for dropped, or 31 for self
  28 //     bits 10-14: team of key 3, or 0 for no such key, or 30 for dropped, or 31 for self
  29 //     bits 15-19: team of key 4, or 0 for no such key, or 30 for dropped, or 31 for self
  30 .float kh_state;
  31 .float siren_time;  //  time delay the siren
  32 //.float stuff_time;  //  time delay to stuffcmd a cvar
  33
  34 float kh_keystatus[17];
  35 //kh_keystatus[0] = status of dropped keys, kh_keystatus[1 - 16] = player #
  36 //replace 17 with cvar("maxplayers") or similar !!!!!!!!!
  37 //for(i = 0; i < maxplayers; ++i)
  38 //      kh_keystatus[i] = "0";
  39
  40 float kh_Team_ByID(float t)
  41 {
  42         if(t == 0) return NUM_TEAM_1;
  43         if(t == 1) return NUM_TEAM_2;
  44         if(t == 2) return NUM_TEAM_3;
  45         if(t == 3) return NUM_TEAM_4;
  46         return 0;
  47 }
  48
  49 entity kh_worldkeylist;
  50 .entity kh_worldkeynext;
  51 entity kh_controller;
  52 float kh_tracking_enabled;
  53 float kh_teams;
  54 float kh_interferemsg_time, kh_interferemsg_team;
  55 .entity kh_next, kh_prev; // linked list
  56 .float kh_droptime;
  57 .float kh_dropperteam;
  58 .entity kh_previous_owner;
  59 .float kh_previous_owner_playerid;
  60 .float kh_cp_duration;
  61
  62 string kh_sound_capture = "kh/capture.wav";
  63 string kh_sound_destroy = "kh/destroy.wav";
  64 string kh_sound_drop = "kh/drop.wav";
  65 string kh_sound_collect = "kh/collect.wav";
  66 string kh_sound_alarm = "kh/alarm.wav";  // the new siren/alarm
  67
  68 float kh_key_dropped, kh_key_carried;
  69
  70 float kh_KeyCarrier_waypointsprite_visible_for_player(entity e)  // runs all the time
  71 {
  72         if(!IS_PLAYER(e) || self.team != e.team)
  73                 if(!kh_tracking_enabled)
  74                         return FALSE;
  75
  76         return TRUE;
  77 }
  78
  79 float kh_Key_waypointsprite_visible_for_player(entity e) // ??
  80 {
  81         if(!kh_tracking_enabled)
  82                 return FALSE;
  83         if(!self.owner)
  84                 return TRUE;
  85         if(!self.owner.owner)
  86                 return TRUE;
  87         return FALSE;  // draw only when key is not owned
  88 }
  89
  90 void kh_update_state()
  91 {
  92         entity player;
  93         entity key;
  94         float s;
  95         float f;
  96
  97         s = 0;
  98         FOR_EACH_KH_KEY(key)
  99         {
 100                 if(key.owner)
 101                         f = key.team;
 102                 else
 103                         f = 30;
 104                 s |= pow(32, key.count) * f;
 105         }
 106
 107         FOR_EACH_CLIENT(player)
 108         {
 109                 player.kh_state = s;
 110         }
 111
 112         FOR_EACH_KH_KEY(key)
 113         {
 114                 if(key.owner)
 115                         key.owner.kh_state |= pow(32, key.count) * 31;
 116         }
 117         //print(ftos((nextent(world)).kh_state), "\n");
 118 }
 119
 120
 121
 122
 123 var kh_Think_t kh_Controller_Thinkfunc;
 124 void kh_Controller_SetThink(float t, kh_Think_t func)  // runs occasionaly
 125 {
 126         kh_Controller_Thinkfunc = func;
 127         kh_controller.cnt = ceil(t);
 128         if(t == 0)
 129                 kh_controller.nextthink = time; // force
 130 }
 131 void kh_WaitForPlayers();
 132 void kh_Controller_Think()  // called a lot
 133 {
 134         if(intermission_running)
 135                 return;
 136         if(self.cnt > 0)
 137         { if(self.think != kh_WaitForPlayers) { self.cnt -= 1; } }
 138         else if(self.cnt == 0)
 139         {
 140                 self.cnt -= 1;
 141                 kh_Controller_Thinkfunc();
 142         }
 143         self.nextthink = time + 1;
 144 }
 145
 146 // frags f: take from cvar * f
 147 // frags 0: no frags
 148 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)  // update the score when a key is captured
 149 {
 150         string s;
 151         if(intermission_running)
 152                 return;
 153
 154         if(frags_player)
 155                 UpdateFrags(player, frags_player);
 156
 157         if(key && key.owner && frags_owner)
 158                 UpdateFrags(key.owner, frags_owner);
 159
 160         if(!autocvar_sv_eventlog)  //output extra info to the console or text file
 161                 return;
 162
 163         s = strcat(":keyhunt:", what, ":", ftos(player.playerid), ":", ftos(frags_player));
 164
 165         if(key && key.owner)
 166                 s = strcat(s, ":", ftos(key.owner.playerid));
 167         else
 168                 s = strcat(s, ":0");
 169
 170         s = strcat(s, ":", ftos(frags_owner), ":");
 171
 172         if(key)
 173                 s = strcat(s, key.netname);
 174
 175         GameLogEcho(s);
 176 }
 177
 178 vector kh_AttachedOrigin(entity e)  // runs when a team captures the flag, it can run 2 or 3 times.
 179 {
 180         if(e.tag_entity)
 181         {
 182                 makevectors(e.tag_entity.angles);
 183                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 184         }
 185         else
 186                 return e.origin;
 187 }
 188
 189 void kh_Key_Attach(entity key)  // runs when a player picks up a key and several times when a key is assigned to a player at the start of a round
 190 {
 191 #ifdef KH_PLAYER_USE_ATTACHMENT
 192         entity first;
 193         first = key.owner.kh_next;
 194         if(key == first)
 195         {
 196                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 197                 if(key.kh_next)
 198                 {
 199                         setattachment(key.kh_next, key, "");
 200                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 201                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 202                         key.kh_next.angles = '0 0 0';
 203                 }
 204                 else
 205                         setorigin(key, KH_PLAYER_ATTACHMENT);
 206                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 207         }
 208         else
 209         {
 210                 setattachment(key, key.kh_prev, "");
 211                 if(key.kh_next)
 212                         setattachment(key.kh_next, key, "");
 213                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 214                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 215                 key.angles = '0 0 0';
 216         }
 217 #else
 218         setattachment(key, key.owner, "");
 219         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT);  // fixing x, y in think
 220         key.angles_y -= key.owner.angles_y;
 221 #endif
 222         key.flags = 0;
 223         key.solid = SOLID_NOT;
 224         key.movetype = MOVETYPE_NONE;
 225         key.team = key.owner.team;
 226         key.nextthink = time;
 227         key.damageforcescale = 0;
 228         key.takedamage = DAMAGE_NO;
 229         key.modelindex = kh_key_carried;
 230 }
 231
 232 void kh_Key_Detach(entity key) // runs every time a key is dropped or lost. Runs several times times when all the keys are captured
 233 {
 234 #ifdef KH_PLAYER_USE_ATTACHMENT
 235         entity first;
 236         first = key.owner.kh_next;
 237         if(key == first)
 238         {
 239                 if(key.kh_next)
 240                 {
 241                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 242                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 243                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 244                 }
 245         }
 246         else
 247         {
 248                 if(key.kh_next)
 249                         setattachment(key.kh_next, key.kh_prev, "");
 250                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 251         }
 252         // in any case:
 253         setattachment(key, world, "");
 254         setorigin(key, key.owner.origin + '0 0 1' * (PL_MIN_z - KH_KEY_MIN_z));
 255         key.angles = key.owner.angles;
 256 #else
 257         setorigin(key, key.owner.origin + key.origin_z * '0 0 1');
 258         setattachment(key, world, "");
 259         key.angles_y += key.owner.angles_y;
 260 #endif
 261         key.flags = FL_ITEM;
 262         key.solid = SOLID_TRIGGER;
 263         key.movetype = MOVETYPE_TOSS;
 264         key.pain_finished = time + autocvar_g_balance_keyhunt_delay_return;
 265         key.damageforcescale = autocvar_g_balance_keyhunt_damageforcescale;
 266         key.takedamage = DAMAGE_YES;
 267         // let key.team stay
 268         key.modelindex = kh_key_dropped;
 269         key.kh_previous_owner = key.owner;
 270         key.kh_previous_owner_playerid = key.owner.playerid;
 271 }
 272
 273 void kh_Key_AssignTo(entity key, entity player)  // runs every time a key is picked up or assigned. Runs prior to kh_key_attach
 274 {
 275         entity k;
 276         float ownerteam0, ownerteam;
 277         if(key.owner == player)
 278                 return;
 279
 280         ownerteam0 = kh_Key_AllOwnedByWhichTeam();
 281
 282         if(key.owner)
 283         {
 284                 kh_Key_Detach(key);
 285
 286                 // remove from linked list
 287                 if(key.kh_next)
 288                         key.kh_next.kh_prev = key.kh_prev;
 289                 key.kh_prev.kh_next = key.kh_next;
 290                 key.kh_next = world;
 291                 key.kh_prev = world;
 292
 293                 if(key.owner.kh_next == world)
 294                 {
 295                         // No longer a key carrier
 296                         if(!kh_no_radar_circles)
 297                                 WaypointSprite_Ping(key.owner.waypointsprite_attachedforcarrier);
 298                         WaypointSprite_DetachCarrier(key.owner);
 299                 }
 300         }
 301
 302         key.owner = player;
 303
 304         if(player)
 305         {
 306                 // insert into linked list
 307                 key.kh_next = player.kh_next;
 308                 key.kh_prev = player;
 309                 player.kh_next = key;
 310                 if(key.kh_next)
 311                         key.kh_next.kh_prev = key;
 312
 313                 float i;
 314                 i = kh_keystatus[key.owner.playerid];
 315                         if(key.netname == "^1red key")
 316                                 i += 1;
 317                         if(key.netname == "^4blue key")
 318                                 i += 2;
 319                         if(key.netname == "^3yellow key")
 320                                 i += 4;
 321                         if(key.netname == "^6pink key")
 322                                 i += 8;
 323                 kh_keystatus[key.owner.playerid] = i;
 324
 325                 kh_Key_Attach(key);
 326
 327                 if(key.kh_next == world)
 328                 {
 329                         // player is now a key carrier
 330                         WaypointSprite_AttachCarrier("", player, RADARICON_FLAGCARRIER, colormapPaletteColor(player.team - 1, 0));
 331                         player.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_KeyCarrier_waypointsprite_visible_for_player;
 332                         WaypointSprite_UpdateRule(player.waypointsprite_attachedforcarrier, player.team, SPRITERULE_TEAMPLAY);
 333                         if(player.team == NUM_TEAM_1)
 334                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-red", "keycarrier-friend", "keycarrier-red");
 335                         else if(player.team == NUM_TEAM_2)
 336                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-blue", "keycarrier-friend", "keycarrier-blue");
 337                         else if(player.team == NUM_TEAM_3)
 338                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-yellow", "keycarrier-friend", "keycarrier-yellow");
 339                         else if(player.team == NUM_TEAM_4)
 340                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-pink", "keycarrier-friend", "keycarrier-pink");
 341                         if(!kh_no_radar_circles)
 342                                 WaypointSprite_Ping(player.waypointsprite_attachedforcarrier);
 343                 }
 344         }
 345
 346         // moved that here, also update if there's no player
 347         kh_update_state();
 348
 349         key.pusher = world;
 350
 351         ownerteam = kh_Key_AllOwnedByWhichTeam();
 352         if(ownerteam != ownerteam0)
 353         {
 354                 if(ownerteam != -1)
 355                 {
 356                         kh_interferemsg_time = time + 0.2;
 357                         kh_interferemsg_team = player.team;
 358
 359                         // audit all key carrier sprites, update them to RUN HERE
 360                         FOR_EACH_KH_KEY(k)
 361                         {
 362                                 if(k.owner)
 363                                         WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, k.owner.waypointsprite_attachedforcarrier.model1, "keycarrier-finish", k.owner.waypointsprite_attachedforcarrier.model3);
 364                         }
 365                 }
 366                 else
 367                 {
 368                         kh_interferemsg_time = 0;
 369
 370                         // audit all key carrier sprites, update them to RUN HERE
 371                         FOR_EACH_KH_KEY(k)
 372                         {
 373                                 if(k.owner)
 374                                         WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, k.owner.waypointsprite_attachedforcarrier.model1, "keycarrier-friend", k.owner.waypointsprite_attachedforcarrier.model3);
 375                         }
 376                 }
 377         }
 378 }
 379
 380 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 381 {
 382         if(self.owner)
 383                 return;
 384         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 385         {
 386                 // touching lava, or hurt trigger
 387                 // what shall we do?
 388                 // immediately return is bad
 389                 // maybe start a shorter countdown?
 390         }
 391         if(vlen(force) <= 0)
 392                 return;
 393         if(time > self.pushltime)
 394                 if(IS_PLAYER(attacker))
 395                         self.team = attacker.team;
 396 }
 397
 398 void kh_Key_Collect(entity key, entity player)  //a player picks up a dropped key
 399 {
 400         sound(player, CH_TRIGGER, kh_sound_collect, VOL_BASE, ATTEN_NORM);
 401
 402         if(key.kh_dropperteam != player.team)
 403         {
 404                 kh_Scores_Event(player, key, "collect", autocvar_g_balance_keyhunt_score_collect, 0);
 405                 PlayerScore_Add(player, SP_KH_PICKUPS, 1);
 406         }
 407         key.kh_dropperteam = 0;
 408         Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(key, INFO_KEYHUNT_PICKUP_), player.netname);
 409
 410         kh_Key_AssignTo(key, player); // this also updates .kh_state
 411 }
 412
 413 void kh_Key_Touch()  // runs many, many times when a key has been dropped and can be picked up
 414 {
 415         if(intermission_running)
 416                 return;
 417
 418         if(self.owner) // already carried
 419                 return;
 420
 421         if(ITEM_TOUCH_NEEDKILL())
 422         {
 423                 // touching sky, or nodrop
 424                 // what shall we do?
 425                 // immediately return is bad
 426                 // maybe start a shorter countdown?
 427         }
 428
 429         if (!IS_PLAYER(other))
 430                 return;
 431         if(other.deadflag != DEAD_NO)
 432                 return;
 433         if(other == self.enemy)
 434                 if(time < self.kh_droptime + autocvar_g_balance_keyhunt_delay_collect)
 435                         return;  // you just dropped it!
 436         kh_Key_Collect(self, other);
 437 }
 438
 439 void kh_Key_Remove(entity key)  // runs after when all the keys have been collected or when a key has been dropped for more than X seconds
 440 {
 441         entity o;
 442         o = key.owner;
 443         kh_Key_AssignTo(key, world);
 444         if(o) // it was attached
 445                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 446         else // it was dropped
 447                 WaypointSprite_DetachCarrier(key);
 448
 449         // remove key from key list
 450         if (kh_worldkeylist == key)
 451                 kh_worldkeylist = kh_worldkeylist.kh_worldkeynext;
 452         else
 453         {
 454                 o = kh_worldkeylist;
 455                 while (o)
 456                 {
 457                         if (o.kh_worldkeynext == key)
 458                         {
 459                                 o.kh_worldkeynext = o.kh_worldkeynext.kh_worldkeynext;
 460                                 break;
 461                         }
 462                         o = o.kh_worldkeynext;
 463                 }
 464         }
 465
 466         remove(key);
 467
 468         kh_update_state();
 469 }
 470
 471 void kh_FinishRound()  // runs when a team captures the keys
 472 {
 473         // prepare next round
 474         kh_interferemsg_time = 0;
 475         entity key;
 476
 477         kh_no_radar_circles = TRUE;
 478         FOR_EACH_KH_KEY(key)
 479                 kh_Key_Remove(key);
 480         kh_no_radar_circles = FALSE;
 481
 482         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_KEYHUNT_ROUNDSTART, autocvar_g_balance_keyhunt_delay_round);
 483         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, kh_StartRound);
 484 }
 485
 486 void kh_WinnerTeam(float teem)  // runs when a team wins // Samual: Teem?.... TEEM?!?! what the fuck is wrong with you people
 487 {
 488         // all key carriers get some points
 489         vector firstorigin, lastorigin, midpoint;
 490         float first;
 491         entity key;
 492         float score;
 493         score = (kh_teams - 1) * autocvar_g_balance_keyhunt_score_capture;
 494         DistributeEvenly_Init(score, kh_teams);
 495         // twice the score for 3 team games, three times the score for 4 team games!
 496         // note: for a win by destroying the key, this should NOT be applied
 497         FOR_EACH_KH_KEY(key)
 498         {
 499                 float f;
 500                 f = DistributeEvenly_Get(1);
 501                 kh_Scores_Event(key.owner, key, "capture", f, 0);
 502                 PlayerTeamScore_Add(key.owner, SP_KH_CAPS, ST_KH_CAPS, 1);
 503                 nades_GiveBonus(key.owner, autocvar_g_nades_bonus_score_high);
 504         }
 505
 506         first = TRUE;
 507         string keyowner = "";
 508         FOR_EACH_KH_KEY(key)
 509                 if(key.owner.kh_next == key)
 510                 {
 511                         if(!first)
 512                                 keyowner = strcat(keyowner, ", ");
 513                         keyowner = key.owner.netname;
 514                         first = FALSE;
 515                 }
 516
 517         Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM_4(teem, INFO_KEYHUNT_CAPTURE_), keyowner);
 518
 519         first = TRUE;
 520         midpoint = '0 0 0';
 521         firstorigin = '0 0 0';
 522         lastorigin = '0 0 0';
 523         FOR_EACH_KH_KEY(key)
 524         {
 525                 vector thisorigin;
 526
 527                 thisorigin = kh_AttachedOrigin(key);
 528                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 529                 midpoint += thisorigin;
 530
 531                 if(!first)
 532                         te_lightning2(world, lastorigin, thisorigin);
 533                 lastorigin = thisorigin;
 534                 if(first)
 535                         firstorigin = thisorigin;
 536                 first = FALSE;
 537         }
 538         if(kh_teams > 2)
 539         {
 540                 te_lightning2(world, lastorigin, firstorigin);
 541         }
 542         midpoint = midpoint * (1 / kh_teams);
 543         te_customflash(midpoint, 1000, 1, Team_ColorRGB(teem) * 0.5 + '0.5 0.5 0.5');  // make the color >=0.5 in each component
 544
 545         play2all(kh_sound_capture);
 546         kh_FinishRound();
 547 }
 548
 549 void kh_LoserTeam(float teem, entity lostkey)  // runs when a player pushes a flag carrier off the map
 550 {
 551         entity player, key, attacker;
 552         float players;
 553         float keys;
 554         float f;
 555
 556         attacker = world;
 557         if(lostkey.pusher)
 558                 if(lostkey.pusher.team != teem)
 559                         if(IS_PLAYER(lostkey.pusher))
 560                                 attacker = lostkey.pusher;
 561
 562         players = keys = 0;
 563
 564         if(attacker)
 565         {
 566                 if(lostkey.kh_previous_owner)
 567                         kh_Scores_Event(lostkey.kh_previous_owner, world, "pushed", 0, -autocvar_g_balance_keyhunt_score_push);
 568                         // don't actually GIVE him the -nn points, just log
 569                 kh_Scores_Event(attacker, world, "push", autocvar_g_balance_keyhunt_score_push, 0);
 570                 PlayerScore_Add(attacker, SP_KH_PUSHES, 1);
 571                 //centerprint(attacker, "Your push is the best!"); // does this really need to exist?
 572         }
 573         else
 574         {
 575                 float of, fragsleft, i, j, thisteam;
 576                 of = autocvar_g_balance_keyhunt_score_destroyed_ownfactor;
 577
 578                 FOR_EACH_PLAYER(player)
 579                         if(player.team != teem)
 580                                 ++players;
 581
 582                 FOR_EACH_KH_KEY(key)
 583                         if(key.owner && key.team != teem)
 584                                 ++keys;
 585
 586                 if(lostkey.kh_previous_owner)
 587                         kh_Scores_Event(lostkey.kh_previous_owner, world, "destroyed", 0, -autocvar_g_balance_keyhunt_score_destroyed);
 588                         // don't actually GIVE him the -nn points, just log
 589
 590                 if(lostkey.kh_previous_owner.playerid == lostkey.kh_previous_owner_playerid)
 591                         PlayerScore_Add(lostkey.kh_previous_owner, SP_KH_DESTROYS, 1);
 592
 593                 DistributeEvenly_Init(autocvar_g_balance_keyhunt_score_destroyed, keys * of + players);
 594
 595                 FOR_EACH_KH_KEY(key)
 596                         if(key.owner && key.team != teem)
 597                         {
 598                                 f = DistributeEvenly_Get(of);
 599                                 kh_Scores_Event(key.owner, world, "destroyed_holdingkey", f, 0);
 600                         }
 601
 602                 fragsleft = DistributeEvenly_Get(players);
 603
 604                 // Now distribute these among all other teams...
 605                 j = kh_teams - 1;
 606                 for(i = 0; i < kh_teams; ++i)
 607                 {
 608                         thisteam = kh_Team_ByID(i);
 609                         if(thisteam == teem) // bad boy, no cookie - this WILL happen
 610                                 continue;
 611
 612                         players = 0;
 613                         FOR_EACH_PLAYER(player)
 614                                 if(player.team == thisteam)
 615                                         ++players;
 616
 617                         DistributeEvenly_Init(fragsleft, j);
 618                         fragsleft = DistributeEvenly_Get(j - 1);
 619                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 620
 621                         FOR_EACH_PLAYER(player)
 622                                 if(player.team == thisteam)
 623                                 {
 624                                         f = DistributeEvenly_Get(1);
 625                                         kh_Scores_Event(player, world, "destroyed", f, 0);
 626                                 }
 627
 628                         --j;
 629                 }
 630         }
 631
 632         Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(lostkey, INFO_KEYHUNT_LOST_), lostkey.kh_previous_owner.netname);
 633
 634         play2all(kh_sound_destroy);
 635         te_tarexplosion(lostkey.origin);
 636
 637         kh_FinishRound();
 638 }
 639
 640 void kh_Key_Think()  // runs all the time
 641 {
 642         entity head;
 643         //entity player;  // needed by FOR_EACH_PLAYER
 644
 645         if(intermission_running)
 646                 return;
 647
 648         if(self.owner)
 649         {
 650 #ifndef KH_PLAYER_USE_ATTACHMENT
 651                 makevectors('0 1 0' * (self.cnt + mod(time, 360) * KH_KEY_XYSPEED));
 652                 setorigin(self, v_forward * KH_KEY_XYDIST + '0 0 1' * self.origin_z);
 653 #endif
 654         }
 655
 656         // if in nodrop or time over, end the round
 657         if(!self.owner)
 658                 if(time > self.pain_finished)
 659                         kh_LoserTeam(self.team, self);
 660
 661         if(self.owner)
 662         if(kh_Key_AllOwnedByWhichTeam() != -1)
 663         {
 664                 if(self.siren_time < time)
 665                 {
 666                         sound(self.owner, CH_TRIGGER, kh_sound_alarm, VOL_BASE, ATTEN_NORM);  // play a simple alarm
 667                         self.siren_time = time + 2.5;  // repeat every 2.5 seconds
 668                 }
 669
 670                 entity key;
 671                 vector p;
 672                 p = self.owner.origin;
 673                 FOR_EACH_KH_KEY(key)
 674                         if(vlen(key.owner.origin - p) > autocvar_g_balance_keyhunt_maxdist)
 675                                 goto not_winning;
 676                 kh_WinnerTeam(self.team);
 677 :not_winning
 678         }
 679
 680         if(kh_interferemsg_time && time > kh_interferemsg_time)
 681         {
 682                 kh_interferemsg_time = 0;
 683                 FOR_EACH_PLAYER(head)
 684                 {
 685                         if(head.team == kh_interferemsg_team)
 686                                 if(head.kh_next)
 687                                         Send_Notification(NOTIF_ONE, head, MSG_CENTER, CENTER_KEYHUNT_MEET);
 688                                 else
 689                                         Send_Notification(NOTIF_ONE, head, MSG_CENTER, CENTER_KEYHUNT_HELP);
 690                         else
 691                                 Send_Notification(NOTIF_ONE, head, MSG_CENTER, APP_TEAM_NUM_4(kh_interferemsg_team, CENTER_KEYHUNT_INTERFERE_));
 692                 }
 693         }
 694
 695         self.nextthink = time + 0.05;
 696 }
 697
 698 void key_reset()
 699 {
 700         kh_Key_AssignTo(self, world);
 701         kh_Key_Remove(self);
 702 }
 703
 704 const string STR_ITEM_KH_KEY = "item_kh_key";
 705 void kh_Key_Spawn(entity initial_owner, float angle, float i)  // runs every time a new flag is created, ie after all the keys have been collected
 706 {
 707         entity key;
 708         key = spawn();
 709         key.count = i;
 710         key.classname = STR_ITEM_KH_KEY;
 711         key.touch = kh_Key_Touch;
 712         key.think = kh_Key_Think;
 713         key.nextthink = time;
 714         key.items = IT_KEY1 | IT_KEY2;
 715         key.cnt = angle;
 716         key.angles = '0 360 0' * random();
 717         key.event_damage = kh_Key_Damage;
 718         key.takedamage = DAMAGE_YES;
 719         key.modelindex = kh_key_dropped;
 720         key.model = "key";
 721         key.kh_dropperteam = 0;
 722         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 723         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 724         key.colormod = Team_ColorRGB(initial_owner.team) * KH_KEY_BRIGHTNESS;
 725         key.reset = key_reset;
 726
 727         switch(initial_owner.team)
 728         {
 729                 case NUM_TEAM_1:
 730                         key.netname = "^1red key";
 731                         break;
 732                 case NUM_TEAM_2:
 733                         key.netname = "^4blue key";
 734                         break;
 735                 case NUM_TEAM_3:
 736                         key.netname = "^3yellow key";
 737                         break;
 738                 case NUM_TEAM_4:
 739                         key.netname = "^6pink key";
 740                         break;
 741                 default:
 742                         key.netname = "NETGIER key";
 743                         break;
 744         }
 745
 746         // link into key list
 747         key.kh_worldkeynext = kh_worldkeylist;
 748         kh_worldkeylist = key;
 749
 750         Send_Notification(NOTIF_ONE, initial_owner, MSG_CENTER, APP_TEAM_NUM_4(initial_owner.team, CENTER_KEYHUNT_START_));
 751
 752         WaypointSprite_Spawn("key-dropped", 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, world, key.team, key, waypointsprite_attachedforcarrier, FALSE, RADARICON_FLAG, '0 1 1');
 753         key.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_Key_waypointsprite_visible_for_player;
 754
 755         kh_Key_AssignTo(key, initial_owner);
 756 }
 757
 758 // -1 when no team completely owns all keys yet
 759 float kh_Key_AllOwnedByWhichTeam()  // constantly called. check to see if all the keys are owned by the same team
 760 {
 761         entity key;
 762         float teem;
 763         float keys;
 764
 765         teem = -1;
 766         keys = kh_teams;
 767         FOR_EACH_KH_KEY(key)
 768         {
 769                 if(!key.owner)
 770                         return -1;
 771                 if(teem == -1)
 772                         teem = key.team;
 773                 else if(teem != key.team)
 774                         return -1;
 775                 --keys;
 776         }
 777         if(keys != 0)
 778                 return -1;
 779         return teem;
 780 }
 781
 782 void kh_Key_DropOne(entity key)
 783 {
 784         // prevent collecting this one for some time
 785         entity player;
 786         player = key.owner;
 787
 788         key.kh_droptime = time;
 789         key.enemy = player;
 790
 791         kh_Scores_Event(player, key, "dropkey", 0, 0);
 792         PlayerScore_Add(player, SP_KH_LOSSES, 1);
 793         Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(key, INFO_KEYHUNT_DROP_), player.netname);
 794
 795         kh_Key_AssignTo(key, world);
 796         makevectors(player.v_angle);
 797         key.velocity = W_CalculateProjectileVelocity(player.velocity, autocvar_g_balance_keyhunt_throwvelocity * v_forward, FALSE);
 798         key.pusher = world;
 799         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 800         key.kh_dropperteam = key.team;
 801
 802         sound(player, CH_TRIGGER, kh_sound_drop, VOL_BASE, ATTEN_NORM);
 803 }
 804
 805 void kh_Key_DropAll(entity player, float suicide) // runs whenever a player dies
 806 {
 807         entity key;
 808         entity mypusher;
 809         if(player.kh_next)
 810         {
 811                 mypusher = world;
 812                 if(player.pusher)
 813                         if(time < player.pushltime)
 814                                 mypusher = player.pusher;
 815                 while((key = player.kh_next))
 816                 {
 817                         kh_Scores_Event(player, key, "losekey", 0, 0);
 818                         PlayerScore_Add(player, SP_KH_LOSSES, 1);
 819                         Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(key, INFO_KEYHUNT_LOST_), player.netname);
 820                         kh_Key_AssignTo(key, world);
 821                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 822                         key.velocity = W_CalculateProjectileVelocity(player.velocity, autocvar_g_balance_keyhunt_dropvelocity * v_forward, FALSE);
 823                         key.pusher = mypusher;
 824                         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 825                         if(suicide)
 826                                 key.kh_dropperteam = player.team;
 827                 }
 828                 sound(player, CH_TRIGGER, kh_sound_drop, VOL_BASE, ATTEN_NORM);
 829         }
 830 }
 831
 832 float kh_CheckPlayers(float num)
 833 {
 834         if(num < kh_teams)
 835         {
 836                 float t_team = kh_Team_ByID(num);
 837                 float players = 0;
 838                 entity tmp_player;
 839                 FOR_EACH_PLAYER(tmp_player)
 840                         if(tmp_player.deadflag == DEAD_NO)
 841                                 if(!tmp_player.BUTTON_CHAT)
 842                                         if(tmp_player.team == t_team)
 843                                                 ++players;
 844
 845                 if (!players) { return t_team; }
 846         }
 847         return 0;
 848 }
 849
 850 void kh_WaitForPlayers()  // delay start of the round until enough players are present
 851 {
 852         if(time < game_starttime)
 853         {
 854                 kh_Controller_SetThink(game_starttime - time + 0.1, kh_WaitForPlayers);
 855                 return;
 856         }
 857
 858         float p1 = kh_CheckPlayers(0), p2 = kh_CheckPlayers(1), p3 = kh_CheckPlayers(2), p4 = kh_CheckPlayers(3);
 859         if (!(p1 || p2 || p3 || p4))
 860         {
 861                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_KEYHUNT_ROUNDSTART, autocvar_g_balance_keyhunt_delay_round);
 862                 kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, kh_StartRound);
 863         }
 864         else
 865         {
 866                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_KEYHUNT_WAIT, p1, p2, p3, p4);
 867                 kh_Controller_SetThink(1, kh_WaitForPlayers);
 868         }
 869 }
 870
 871 void kh_EnableTrackingDevice()  // runs after each round
 872 {
 873         Kill_Notification(NOTIF_ALL, world, MSG_CENTER_CPID, CPID_KEYHUNT);
 874         Kill_Notification(NOTIF_ALL, world, MSG_CENTER_CPID, CPID_KEYHUNT_OTHER);
 875
 876         kh_tracking_enabled = TRUE;
 877 }
 878
 879 void kh_StartRound()  // runs at the start of each round
 880 {
 881         float i, players, teem;
 882         entity player;
 883
 884         if(time < game_starttime)
 885         {
 886                 kh_Controller_SetThink(game_starttime - time + 0.1, kh_WaitForPlayers);
 887                 return;
 888         }
 889
 890         float p1 = kh_CheckPlayers(0), p2 = kh_CheckPlayers(1), p3 = kh_CheckPlayers(2), p4 = kh_CheckPlayers(3);
 891         if(p1 || p2 || p3 || p4)
 892         {
 893                 kh_Controller_SetThink(1, kh_WaitForPlayers);
 894                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_KEYHUNT_WAIT, p1, p2, p3, p4);
 895                 return;
 896         }
 897
 898         Kill_Notification(NOTIF_ALL, world, MSG_CENTER_CPID, CPID_KEYHUNT);
 899         Kill_Notification(NOTIF_ALL, world, MSG_CENTER_CPID, CPID_KEYHUNT_OTHER);
 900
 901         for(i = 0; i < kh_teams; ++i)
 902         {
 903                 teem = kh_Team_ByID(i);
 904                 players = 0;
 905                 entity my_player = world;
 906                 FOR_EACH_PLAYER(player)
 907                         if(player.deadflag == DEAD_NO)
 908                                 if(!player.BUTTON_CHAT)
 909                                         if(player.team == teem)
 910                                         {
 911                                                 ++players;
 912                                                 if(random() * players <= 1)
 913                                                         my_player = player;
 914                                         }
 915                 kh_Key_Spawn(my_player, 360 * i / kh_teams, i);
 916         }
 917
 918         kh_tracking_enabled = FALSE;
 919         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_KEYHUNT_SCAN, autocvar_g_balance_keyhunt_delay_tracking);
 920         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_tracking, kh_EnableTrackingDevice);
 921 }
 922
 923 float kh_HandleFrags(entity attacker, entity targ, float f)  // adds to the player score
 924 {
 925         if(attacker == targ)
 926                 return f;
 927
 928         if(targ.kh_next)
 929         {
 930                 if(attacker.team == targ.team)
 931                 {
 932                         entity k;
 933                         float nk;
 934                         nk = 0;
 935                         for(k = targ.kh_next; k != world; k = k.kh_next)
 936                                 ++nk;
 937                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * autocvar_g_balance_keyhunt_score_collect, 0);
 938                 }
 939                 else
 940                 {
 941                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", autocvar_g_balance_keyhunt_score_carrierfrag-1, 0);
 942                         PlayerScore_Add(attacker, SP_KH_KCKILLS, 1);
 943                         // the frag gets added later
 944                 }
 945         }
 946
 947         return f;
 948 }
 949
 950 void kh_Initialize()  // sets up th KH environment
 951 {
 952         precache_sound(kh_sound_capture);
 953         precache_sound(kh_sound_destroy);
 954         precache_sound(kh_sound_drop);
 955         precache_sound(kh_sound_collect);
 956         precache_sound(kh_sound_alarm);  // the new siren
 957
 958 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 959         precache_model("models/keyhunt/key-carried.md3");
 960 #endif
 961         precache_model("models/keyhunt/key.md3");
 962
 963         // setup variables
 964         kh_teams = autocvar_g_keyhunt_teams_override;
 965         if(kh_teams < 2)
 966                 kh_teams = autocvar_g_keyhunt_teams;
 967         kh_teams = bound(2, kh_teams, 4);
 968
 969         // make a KH entity for controlling the game
 970         kh_controller = spawn();
 971         kh_controller.think = kh_Controller_Think;
 972         kh_Controller_SetThink(0, kh_WaitForPlayers);
 973
 974         setmodel(kh_controller, "models/keyhunt/key.md3");
 975         kh_key_dropped = kh_controller.modelindex;
 976         /*
 977         dprint(vtos(kh_controller.mins));
 978         dprint(vtos(kh_controller.maxs));
 979         dprint("\n");
 980         */
 981 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 982         setmodel(kh_controller, "models/keyhunt/key-carried.md3");
 983         kh_key_carried = kh_controller.modelindex;
 984 #else
 985         kh_key_carried = kh_key_dropped;
 986 #endif
 987
 988         kh_controller.model = "";
 989         kh_controller.modelindex = 0;
 990
 991         addstat(STAT_KH_KEYS, AS_INT, kh_state);
 992
 993         ScoreRules_kh(kh_teams);
 994 }
 995
 996 void kh_finalize()
 997 {
 998         // to be called before intermission
 999         kh_FinishRound();
1000         remove(kh_controller);
1001         kh_controller = world;
1002 }
1003
1004 // register this as a mutator
1005
1006 MUTATOR_HOOKFUNCTION(kh_Key_DropAll)
1007 {
1008         kh_Key_DropAll(self, TRUE);
1009         return 0;
1010 }
1011
1012 MUTATOR_HOOKFUNCTION(kh_PlayerDies)
1013 {
1014         if(self == other)
1015                 kh_Key_DropAll(self, TRUE);
1016         else if(IS_PLAYER(other))
1017                 kh_Key_DropAll(self, FALSE);
1018         else
1019                 kh_Key_DropAll(self, TRUE);
1020         return 0;
1021 }
1022
1023 MUTATOR_HOOKFUNCTION(kh_GiveFragsForKill)
1024 {
1025         frag_score = kh_HandleFrags(frag_attacker, frag_target, frag_score);
1026         return 0;
1027 }
1028
1029 MUTATOR_HOOKFUNCTION(kh_finalize)
1030 {
1031         kh_finalize();
1032         return 0;
1033 }
1034
1035 MUTATOR_HOOKFUNCTION(kh_GetTeamCount)
1036 {
1037         ret_float = kh_teams;
1038         return 0;
1039 }
1040
1041 MUTATOR_HOOKFUNCTION(kh_SpectateCopy)
1042 {
1043         self.kh_state = other.kh_state;
1044         return 0;
1045 }
1046
1047 MUTATOR_HOOKFUNCTION(kh_PlayerUseKey)
1048 {
1049         if(MUTATOR_RETURNVALUE == 0)
1050         {
1051                 entity k;
1052                 k = self.kh_next;
1053                 if(k)
1054                 {
1055                         kh_Key_DropOne(k);
1056                         return 1;
1057                 }
1058         }
1059         return 0;
1060 }
1061
1062 MUTATOR_DEFINITION(gamemode_keyhunt)
1063 {
1064         MUTATOR_HOOK(MakePlayerObserver, kh_Key_DropAll, CBC_ORDER_ANY);
1065         MUTATOR_HOOK(ClientDisconnect, kh_Key_DropAll, CBC_ORDER_ANY);
1066         MUTATOR_HOOK(PlayerDies, kh_PlayerDies, CBC_ORDER_ANY);
1067         MUTATOR_HOOK(GiveFragsForKill, kh_GiveFragsForKill, CBC_ORDER_FIRST);
1068         MUTATOR_HOOK(MatchEnd, kh_finalize, CBC_ORDER_ANY);
1069         MUTATOR_HOOK(GetTeamCount, kh_GetTeamCount, CBC_ORDER_EXCLUSIVE);
1070         MUTATOR_HOOK(SpectateCopy, kh_SpectateCopy, CBC_ORDER_ANY);
1071         MUTATOR_HOOK(PlayerUseKey, kh_PlayerUseKey, CBC_ORDER_ANY);
1072
1073         MUTATOR_ONADD
1074         {
1075                 if(time > 1) // game loads at time 1
1076                         error("This is a game type and it cannot be added at runtime.");
1077                 kh_Initialize();
1078         }
1079
1080         MUTATOR_ONROLLBACK_OR_REMOVE
1081         {
1082                 // we actually cannot roll back kh_Initialize here
1083                 // BUT: we don't need to! If this gets called, adding always
1084                 // succeeds.
1085         }
1086
1087         MUTATOR_ONREMOVE
1088         {
1089                 print("This is a game type and it cannot be removed at runtime.");
1090                 return -1;
1091         }
1092
1093         return 0;
1094 }