qcsrc/server/mutators/gamemode_towerdefense.qc

   1 // Tower Defense
   2 // Gamemode by Mario
   3
   4 void spawnfunc_td_controller()
   5 {
   6         if not(g_td) { remove(self); return; }
   7
   8         if(autocvar_g_td_force_settings)
   9         {
  10                 // TODO: find a better way to do this?
  11                 self.dontend = FALSE;
  12                 self.maxwaves = 0;
  13                 self.monstercount = 0;
  14                 self.startwave = 0;
  15                 self.maxturrets = 0;
  16                 self.buildtime = 0;
  17                 self.mspeed_walk = 0;
  18                 self.mspeed_run = 0;
  19                 self.spawndelay = 0;
  20                 self.maxcurrent = 0;
  21                 self.ignoreturrets = 0;
  22         }
  23
  24         self.netname = "Tower Defense controller entity";
  25         self.classname = "td_controller";
  26
  27         gensurvived = FALSE;
  28
  29         td_dont_end = ((self.dontend == 0) ? autocvar_g_td_generator_dontend : self.dontend);
  30         max_waves = ((self.maxwaves == 0) ? autocvar_g_td_max_waves : self.maxwaves);
  31         totalmonsters = ((self.monstercount == 0) ? autocvar_g_td_monster_count : self.monstercount);
  32         wave_count = ((self.startwave == 0) ? autocvar_g_td_start_wave : self.startwave);
  33         max_turrets = ((self.maxturrets == 0) ? autocvar_g_td_turret_max : self.maxturrets);
  34         build_time = ((self.buildtime == 0) ? autocvar_g_td_buildphase_time : self.buildtime);
  35         m_speed_walk = ((self.mspeed_walk == 0) ? autocvar_g_td_monsters_speed_walk : self.mspeed_walk);
  36         m_speed_run = ((self.mspeed_run == 0) ? autocvar_g_td_monsters_speed_run : self.mspeed_run);
  37         spawn_delay = ((self.spawndelay == 0) ? autocvar_g_td_monsters_spawn_delay : self.spawndelay);
  38         max_current = ((self.maxcurrent == 0) ? autocvar_g_td_current_monsters : self.maxcurrent);
  39         ignore_turrets = ((self.ignoreturrets == 0) ? autocvar_g_td_monsters_ignore_turrets : self.ignoreturrets);
  40
  41         if(autocvar_g_td_monsters_skill_start)
  42                 monster_skill = autocvar_g_td_monsters_skill_start;
  43
  44         wave_end(TRUE);
  45 }
  46
  47 void td_generator_die()
  48 {
  49         if(autocvar_sv_eventlog)
  50                 GameLogEcho(":gendestroyed");
  51
  52         gendestroyed = TRUE;
  53
  54         pointparticles(particleeffectnum("explosion_medium"), self.origin, '0 0 0', 1);
  55         sound(self, CH_TRIGGER, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
  56
  57         Send_Notification(NOTIF_ALL, world, MSG_MULTI, MULTI_TD_GENDESTROYED);
  58
  59         self.solid                      = SOLID_NOT;
  60         self.takedamage         = DAMAGE_NO;
  61         self.event_damage   = func_null;
  62         self.enemy                      = world;
  63         td_gencount                     -= 1;
  64
  65         WaypointSprite_Kill(self.sprite);
  66 }
  67
  68 void td_generator_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  69 {
  70         if(IS_PLAYER(attacker) || attacker.turrcaps_flags & TFL_TURRCAPS_ISTURRET || attacker.vehicle_flags & VHF_ISVEHICLE || self.takedamage == DAMAGE_NO)
  71                 return;
  72
  73         if (time > self.pain_finished)
  74         {
  75                 self.pain_finished = time + 10;
  76                 play2all("onslaught/generator_underattack.wav");
  77         }
  78
  79         if (random() < 0.5)
  80                 spamsound(self, CH_TRIGGER, "onslaught/ons_hit1.wav", VOL_BASE, ATTN_NORM);
  81         else
  82                 spamsound(self, CH_TRIGGER, "onslaught/ons_hit2.wav", VOL_BASE, ATTN_NORM);
  83
  84         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_TD_GENDAMAGED);
  85
  86         self.health -= damage;
  87
  88         WaypointSprite_UpdateHealth(self.sprite, self.health);
  89
  90         if(self.health <= 0)
  91                 td_generator_die();
  92
  93         self.SendFlags |= GSF_STATUS;
  94 }
  95
  96 void td_generator_setup()
  97 {
  98         self.think                      = func_null;
  99         self.nextthink          = -1;
 100         self.solid                  = SOLID_BBOX;
 101         self.takedamage     = DAMAGE_AIM;
 102         self.event_damage   = td_generator_damage;
 103         self.enemy                  = world;
 104         self.movetype       = MOVETYPE_NONE;
 105         self.monster_attack = TRUE;
 106         self.netname            = "Generator";
 107         self.SendFlags          = GSF_SETUP;
 108
 109         WaypointSprite_SpawnFixed(self.netname, self.origin + '0 0 90', self, sprite, RADARICON_OBJECTIVE, '1 0.5 0');
 110         WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 111         WaypointSprite_UpdateHealth(self.sprite, self.health);
 112 }
 113
 114 void spawnfunc_td_generator()
 115 {
 116         if not(g_td) { remove(self); return; }
 117
 118         precache_sound("onslaught/generator_underattack.wav");
 119         precache_sound("onslaught/ons_hit1.wav");
 120         precache_sound("onslaught/ons_hit2.wav");
 121         precache_sound("weapons/rocket_impact.wav");
 122
 123         gendestroyed = FALSE;
 124
 125         if not(self.health)
 126                 self.health = autocvar_g_td_generator_health;
 127
 128         self.max_health = self.health;
 129
 130         self.classname = "td_generator";
 131         self.flags = FL_GENERATOR;
 132         td_gencount += 1;
 133
 134         setsize(self, GENERATOR_MIN, GENERATOR_MAX);
 135
 136         setorigin(self, self.origin + '0 0 20');
 137         droptofloor();
 138
 139         generator_link(td_generator_setup);
 140 }
 141
 142 entity PickGenerator()
 143 {
 144         entity generator, head;
 145         if(td_gencount == 1)
 146                 generator = findflags(world, flags, FL_GENERATOR);
 147         else
 148         {
 149                 RandomSelection_Init();
 150                 for(head = world;(head = findflags(head, flags, FL_GENERATOR)); )
 151                 {
 152                         RandomSelection_Add(head, 0, string_null, 1, 1);
 153                 }
 154                 generator = RandomSelection_chosen_ent;
 155         }
 156         return generator;
 157 }
 158
 159 void spawn_td_fuel(float fuel_size)
 160 {
 161         if not(g_td) {remove(self); return; }
 162
 163         self.ammo_fuel = fuel_size * monster_skill;
 164         StartItem("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Turret Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
 165
 166         self.velocity = randomvec() * 175 + '0 0 325';
 167 }
 168
 169 void spawnfunc_td_waypoint()
 170 {
 171         if not(g_td) { remove(self); return; }
 172
 173         self.classname = "td_waypoint";
 174 }
 175
 176 void spawnfunc_monster_swarm()
 177 {
 178         if not(g_td) { remove(self); return; }
 179
 180         self.flags = SWARM_NORMAL; // marked as a spawnpoint
 181         self.classname = "monster_swarm";
 182
 183         if(self.spawntype == SWARM_SWIM) waterspawns_count += 1;
 184         if(self.spawntype == SWARM_FLY) flyspawns_count += 1;
 185
 186         WaypointSprite_SpawnFixed("Monsters", self.origin + '0 0 60', self, sprite, RADARICON_HERE, '0 0 1');
 187
 188         if(self.target == "")
 189                 dprint("Warning: monster_swarm entity without a set target\n");
 190 }
 191
 192 void barricade_touch()
 193 {
 194         if not(other.flags & FL_MONSTER)
 195                 return;
 196
 197         if(time < self.dmg_time)
 198                 return;
 199
 200         Damage(other, self, self, autocvar_g_td_barricade_damage, DEATH_HURTTRIGGER, self.origin, '0 0 0');
 201
 202         self.dmg_time = time + 1;
 203 }
 204
 205 void barricade_die()
 206 {
 207         self.takedamage = DAMAGE_NO;
 208         self.event_damage = func_null;
 209
 210         WaypointSprite_Kill(self.sprite);
 211
 212         pointparticles(particleeffectnum("explosion_medium"), self.origin, '0 0 0', 1);
 213         sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 214
 215         if(self.realowner)
 216                 self.realowner.turret_cnt -= 1;
 217
 218         self.think = SUB_Remove;
 219         self.nextthink = time;
 220 }
 221
 222 void barricade_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 223 {
 224         if not(attacker.flags & FL_MONSTER) return;
 225
 226         self.health -= damage;
 227
 228         WaypointSprite_UpdateHealth(self.sprite, self.health);
 229
 230         if(self.health < 1)
 231                 barricade_die();
 232 }
 233
 234 void spawn_barricade()
 235 {
 236         self.health = 2000;
 237         self.max_health = self.health;
 238         self.dmg_time = time;
 239         self.touch = barricade_touch;
 240         self.think = func_null;
 241         self.nextthink = -1;
 242         self.takedamage = DAMAGE_AIM;
 243         self.turrcaps_flags = TFL_TURRCAPS_ISTURRET; // for turretremove commands etc.
 244         self.solid = SOLID_CORPSE; // hax
 245         self.event_damage = barricade_damage;
 246         self.netname = "Barricade";
 247
 248         WaypointSprite_Spawn(self.netname, 0, 1200, self, '0 0 110', world, 0, self, sprite, FALSE, RADARICON_DOMPOINT, '1 1 0');
 249         WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 250         WaypointSprite_UpdateHealth(self.sprite, self.health);
 251
 252         precache_model("models/td/barricade.md3");
 253         setmodel(self, "models/td/barricade.md3");
 254
 255         droptofloor();
 256
 257         self.movetype = MOVETYPE_NONE;
 258 }
 259
 260 float td_checkfuel(entity ent, string tur)
 261 {
 262         float turcost = cvar(strcat("g_td_turret_", tur, "_cost"));
 263
 264         if(ent.ammo_fuel < turcost)
 265         {
 266                 Send_Notification(NOTIF_ONE, ent, MSG_INFO, INFO_TD_NOFUEL);
 267                 return FALSE;
 268         }
 269
 270         ent.ammo_fuel -= turcost;
 271
 272         return TRUE;
 273 }
 274
 275 void spawnturret(entity spawnedby, entity own, string turet, vector orig)
 276 {
 277         if not(IS_PLAYER(spawnedby)) { dprint("Warning: A non-player entity tried to spawn a turret\n"); return; }
 278         if not(td_checkfuel(spawnedby, turet)) { return; }
 279
 280         entity oldself;
 281
 282         oldself = self;
 283         self = spawn();
 284
 285         setorigin(self, orig);
 286         self.spawnflags = TSL_NO_RESPAWN;
 287         self.monster_attack = TRUE;
 288         self.realowner = own;
 289         self.playerid = own.playerid;
 290         self.angles_y = spawnedby.v_angle_y;
 291         spawnedby.turret_cnt += 1;
 292         self.colormap = spawnedby.colormap;
 293         self.colormod = '1 1 1';
 294
 295         switch(turet)
 296         {
 297                 case "plasma": spawnfunc_turret_plasma(); break;
 298                 case "mlrs": spawnfunc_turret_mlrs(); break;
 299                 case "walker": spawnfunc_turret_walker(); break;
 300                 case "flac": spawnfunc_turret_flac(); break;
 301                 case "towerbuff": spawnfunc_turret_fusionreactor(); break;
 302                 case "barricade": spawn_barricade(); break;
 303                 default: Send_Notification(NOTIF_ONE, spawnedby, MSG_INFO, INFO_TD_INVALID); remove(self); self = oldself; return;
 304         }
 305
 306         Send_Notification(NOTIF_ONE, spawnedby, MSG_INFO, INFO_TD_SPAWN);
 307
 308         self = oldself;
 309 }
 310
 311 void buffturret (entity tur, float buff)
 312 {
 313         tur.turret_buff           += 1;
 314         tur.max_health            *= buff;
 315         tur.tur_health             = tur.max_health;
 316         tur.health                         = tur.max_health;
 317         tur.ammo_max              *= buff;
 318         tur.ammo_recharge     *= buff;
 319     tur.shot_dmg          *= buff;
 320     tur.shot_refire       -= buff * 0.2;
 321     tur.shot_radius       *= buff;
 322     tur.shot_speed        *= buff;
 323     tur.shot_spread       *= buff;
 324     tur.shot_force        *= buff;
 325 }
 326
 327 void AnnounceSpawn(string anounce)
 328 {
 329         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_TD_ANNOUNCE_SPAWN, anounce);
 330 }
 331
 332 entity PickSpawn (float strngth, float type)
 333 {
 334         entity e;
 335         RandomSelection_Init();
 336         for(e = world;(e = find(e, classname, "monster_swarm")); )
 337         {
 338                 if(flyspawns_count > 0 && type == SWARM_FLY && e.spawntype != SWARM_FLY) continue;
 339                 if(waterspawns_count > 0 && type == SWARM_SWIM && e.spawntype != SWARM_SWIM) continue;
 340
 341                 RandomSelection_Add(e, 0, string_null, 1, 1);
 342         }
 343
 344         return RandomSelection_chosen_ent;
 345 }
 346
 347 void TD_SpawnMonster(string mnster, float strngth, float type)
 348 {
 349         entity e, mon;
 350
 351         e = PickSpawn(strngth, type);
 352
 353         if(e == world) // couldn't find anything for our class, so check for normal spawns
 354                 e = PickSpawn(SWARM_NORMAL, SWARM_NORMAL);
 355
 356         if(e == world)
 357         {
 358                 dprint("Warning: couldn't find any monster_swarm spawnpoints, no monsters will spawn!\n");
 359                 return;
 360         }
 361
 362         mon = spawnmonster(mnster, e, e, e.origin, FALSE, 0);
 363         if(e.target2)
 364         {
 365                 if(random() > 0.5)
 366                         mon.target2 = e.target2;
 367                 else
 368                         mon.target2 = e.target;
 369         }
 370         else
 371                 mon.target2 = e.target;
 372 }
 373
 374 float Monster_GetStrength(float mnster)
 375 {
 376         switch(mnster)
 377         {
 378                 default:
 379                 case MONSTER_KNIGHT:
 380                 case MONSTER_MARINE:
 381                 case MONSTER_ZOMBIE:
 382                 case MONSTER_SPIDER:
 383                 case MONSTER_TARBABY:
 384                 case MONSTER_DOG:
 385                 case MONSTER_SCRAG:
 386                 case MONSTER_FISH:
 387                         return SWARM_WEAK;
 388                 case MONSTER_HELLKNIGHT:
 389                 case MONSTER_OGRE:
 390                 case MONSTER_SHAMBLER:
 391                 case MONSTER_MAGE:
 392                 case MONSTER_DEMON:
 393                         return SWARM_STRONG;
 394                 default: return SWARM_NORMAL;
 395         }
 396 }
 397
 398 string monster_type2string(float mnster)
 399 {
 400         switch(mnster)
 401         {
 402                 case MONSTER_ZOMBIE: return "zombie";
 403                 case MONSTER_OGRE: return "ogre";
 404                 case MONSTER_DEMON: return "demon";
 405                 case MONSTER_SHAMBLER: return "shambler";
 406                 case MONSTER_KNIGHT: return "knight";
 407                 case MONSTER_MARINE: return "soldier";
 408                 case MONSTER_SCRAG: return "scrag";
 409                 case MONSTER_DOG: return "dog";
 410                 case MONSTER_TARBABY: return "spawn";
 411                 case MONSTER_HELLKNIGHT: return "hellknight";
 412                 case MONSTER_FISH: return "fish";
 413                 case MONSTER_MAGE: return "vore";
 414                 case MONSTER_SPIDER: return "spider";
 415                 default: return "";
 416         }
 417 }
 418
 419 float Monster_GetType(float mnster)
 420 {
 421         switch(mnster)
 422         {
 423                 default:
 424                 case MONSTER_KNIGHT:
 425                 case MONSTER_MARINE:
 426                 case MONSTER_ZOMBIE:
 427                 case MONSTER_SPIDER:
 428                 case MONSTER_TARBABY:
 429                 case MONSTER_DOG:
 430                 case MONSTER_OGRE:
 431                 case MONSTER_SHAMBLER:
 432                 case MONSTER_MAGE:
 433                 case MONSTER_HELLKNIGHT:
 434                 case MONSTER_DEMON:
 435                         return SWARM_NORMAL;
 436                 case MONSTER_SCRAG:
 437                         return SWARM_FLY;
 438                 case MONSTER_FISH:
 439                         return SWARM_SWIM;
 440         }
 441 }
 442
 443 float RandomMonster()
 444 {
 445         RandomSelection_Init();
 446
 447         if(n_demons) RandomSelection_Add(world, MONSTER_DEMON, "", 1, 1);
 448         if(n_shalraths) RandomSelection_Add(world, MONSTER_MAGE, "", 1, 1);
 449         if(n_soldiers) RandomSelection_Add(world, MONSTER_MARINE, "", 1, 1);
 450         if(n_hknights) RandomSelection_Add(world, MONSTER_HELLKNIGHT, "", 1, 1);
 451         if(n_zombies) RandomSelection_Add(world, MONSTER_ZOMBIE, "", 1, 1);
 452         if(n_spiders) RandomSelection_Add(world, MONSTER_SPIDER, "", 1, 1);
 453         if(n_ogres) RandomSelection_Add(world, MONSTER_OGRE, "", 1, 1);
 454         if(n_dogs) RandomSelection_Add(world, MONSTER_DOG, "", 1, 1);
 455         if(n_knights) RandomSelection_Add(world, MONSTER_KNIGHT, "", 1, 1);
 456         if(n_shamblers) RandomSelection_Add(world, MONSTER_SHAMBLER, "", 0.2, 0.2);
 457         if(n_tarbabies) RandomSelection_Add(world, MONSTER_TARBABY, "", 0.2, 0.2);
 458         if(n_wizards && flyspawns_count) RandomSelection_Add(world, MONSTER_SCRAG, "", 1, 1);
 459         if(n_fish && waterspawns_count) RandomSelection_Add(world, MONSTER_FISH, "", 0.2, 0.2);
 460
 461         return RandomSelection_chosen_float;
 462 }
 463
 464 void combat_phase()
 465 {
 466         float mstrength, montype, whichmon;
 467
 468         current_phase = PHASE_COMBAT;
 469
 470         if(monster_count <= 0)
 471         {
 472                 wave_end(FALSE);
 473                 return;
 474         }
 475
 476         self.think = combat_phase;
 477
 478         whichmon = RandomMonster();
 479
 480         mstrength = Monster_GetStrength(whichmon);
 481         montype = Monster_GetType(whichmon);
 482
 483         if(current_monsters <= max_current && whichmon)
 484         {
 485                 TD_SpawnMonster(monster_type2string(whichmon), mstrength, montype);
 486                 self.nextthink = time + spawn_delay;
 487         }
 488         else
 489                 self.nextthink = time + 6;
 490 }
 491
 492 void queue_monsters(float maxmonsters)
 493 {
 494         float mc = 10; // note: shambler + tarbaby = 1
 495
 496         if(waterspawns_count > 0)
 497                 mc += 1;
 498         if(flyspawns_count > 0)
 499                 mc += 1;
 500
 501         DistributeEvenly_Init(maxmonsters, mc);
 502         n_demons        = DistributeEvenly_Get(1);
 503         n_ogres         = DistributeEvenly_Get(1);
 504         n_dogs          = DistributeEvenly_Get(1);
 505         n_knights   = DistributeEvenly_Get(1);
 506         n_shalraths = DistributeEvenly_Get(1);
 507         n_soldiers  = DistributeEvenly_Get(1);
 508         n_hknights  = DistributeEvenly_Get(1);
 509         n_zombies   = DistributeEvenly_Get(1);
 510         n_spiders   = DistributeEvenly_Get(1);
 511         n_tarbabies = DistributeEvenly_Get(0.7);
 512         n_shamblers = DistributeEvenly_Get(0.3);
 513         if(flyspawns_count > 0)
 514                 n_wizards = DistributeEvenly_Get(1);
 515         if(waterspawns_count > 0)
 516                 n_fish = DistributeEvenly_Get(1);
 517 }
 518
 519 void combat_phase_begin()
 520 {
 521         monster_count = totalmonsters;
 522         entity gen;
 523
 524         Send_Notification(NOTIF_ALL, world, MSG_MULTI, MULTI_TD_PHASE_COMBAT);
 525
 526         if(autocvar_sv_eventlog)
 527                 GameLogEcho(":combatphase");
 528
 529         self.think = combat_phase;
 530         self.nextthink = time + 1;
 531
 532         for(gen = world;(gen = findflags(gen, flags, FL_GENERATOR)); )
 533                 gen.takedamage = DAMAGE_AIM;
 534 }
 535
 536 float cphase_updates;
 537 void combat_phase_announce() // TODO: clean up these fail nextthinks...
 538 {
 539         cphase_updates += 1;
 540
 541         if(cphase_updates == 0)
 542                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_PREPARE);
 543         else if(cphase_updates == 3)
 544                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_NUM_3);
 545         else if(cphase_updates == 4)
 546                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_NUM_2);
 547         else if(cphase_updates == 5)
 548                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_NUM_1);
 549         else if(cphase_updates == 6)
 550         {
 551                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_BEGIN);
 552                 combat_phase_begin();
 553         }
 554
 555         if(cphase_updates >= 6)
 556                 return;
 557
 558         self.think = combat_phase_announce;
 559         self.nextthink = time + 1;
 560 }
 561
 562 void build_phase()
 563 {
 564         entity head;
 565         float n_players = 0, gen_washealed = FALSE, mcount, mskill;
 566
 567         current_phase = PHASE_BUILD;
 568
 569         for(head = world;(head = findflags(head, flags, FL_GENERATOR)); )
 570         {
 571                 if(head.health < head.max_health)
 572                 {
 573                         gen_washealed = TRUE;
 574                         pointparticles(particleeffectnum("healing_fx"), head.origin, '0 0 0', 1);
 575                         head.health = head.max_health;
 576                         WaypointSprite_UpdateHealth(head.sprite, head.health);
 577                         head.SendFlags |= GSF_STATUS;
 578                 }
 579                 head.takedamage = DAMAGE_NO;
 580         }
 581
 582         FOR_EACH_PLAYER(head)
 583         {
 584                 if(head.health < 100) head.health = 100;
 585                 if(gen_washealed) PlayerScore_Add(head, SP_TD_SCORE, -autocvar_g_td_generator_damaged_points);
 586
 587         n_players += 1;
 588         }
 589
 590         mcount = autocvar_g_td_monster_count_increment * wave_count;
 591         mskill = n_players * 0.02;
 592
 593         totalmonsters += mcount;
 594         monster_skill += autocvar_g_td_monsters_skill_increment;
 595         monster_skill += mskill;
 596
 597         if(monster_skill < 1) monster_skill = 1;
 598         if(totalmonsters < 1) totalmonsters = ((autocvar_g_td_monster_count > 0) ? autocvar_g_td_monster_count : 10);
 599         if(wave_count < 1) wave_count = 1;
 600
 601         Send_Notification(NOTIF_ALL, world, MSG_MULTI, MULTI_TD_PHASE_BUILD, wave_count, totalmonsters, build_time);
 602
 603     FOR_EACH_MONSTER(head)
 604     {
 605                 if(head.health <= 0)
 606                         continue;
 607
 608         dprint(strcat("Warning: Monster still alive during build phase! Monster name: ", head.netname, "\n"));
 609
 610                 WaypointSprite_Kill(head.sprite);
 611         remove(head);
 612     }
 613
 614         monsters_total = totalmonsters;
 615         monsters_killed = 0;
 616
 617         queue_monsters(totalmonsters);
 618
 619         cphase_updates = -1;
 620
 621         if(autocvar_sv_eventlog)
 622         GameLogEcho(strcat(":buildphase:", ftos(wave_count), ":", ftos(totalmonsters)));
 623
 624         self.think = combat_phase_announce;
 625         self.nextthink = time + build_time - 6;
 626 }
 627
 628 void wave_end(float starting)
 629 {
 630         if not(starting)
 631         {
 632                 Send_Notification(NOTIF_ALL, world, MSG_MULTI, MULTI_TD_VICTORY, ((wave_count >= max_waves) ? "Level" : "Wave"));
 633
 634                 if(autocvar_sv_eventlog)
 635             GameLogEcho(strcat(":wave:", ftos(wave_count), ":victory"));
 636         }
 637
 638         if(wave_count >= max_waves)
 639         {
 640                 gensurvived = TRUE;
 641                 return;
 642         }
 643
 644         if not(starting)
 645                 wave_count += 1;
 646
 647         self.think = build_phase;
 648         self.nextthink = time + 3;
 649 }
 650
 651 void td_ScoreRules()
 652 {
 653         ScoreInfo_SetLabel_PlayerScore(SP_TD_SCORE,             "score",         SFL_SORT_PRIO_PRIMARY);
 654         ScoreInfo_SetLabel_PlayerScore(SP_TD_KILLS,             "kills",         SFL_LOWER_IS_BETTER);
 655         ScoreInfo_SetLabel_PlayerScore(SP_TD_TURKILLS,  "frags",         SFL_LOWER_IS_BETTER);
 656         ScoreInfo_SetLabel_PlayerScore(SP_TD_DEATHS,    "deaths",    SFL_LOWER_IS_BETTER);
 657         ScoreInfo_SetLabel_PlayerScore(SP_TD_SUICIDES,  "suicides",  SFL_LOWER_IS_BETTER | SFL_ALLOW_HIDE);
 658         ScoreRules_basics_end();
 659 }
 660
 661 void td_SpawnController()
 662 {
 663         entity oldself = self;
 664         self = spawn();
 665         self.classname = "td_controller";
 666         spawnfunc_td_controller();
 667         self = oldself;
 668 }
 669
 670 void td_DelayedInit()
 671 {
 672         if(find(world, classname, "td_controller") == world)
 673         {
 674                 print("No ""td_controller"" entity found on this map, creating it anyway.\n");
 675                 td_SpawnController();
 676         }
 677
 678         td_ScoreRules();
 679 }
 680
 681 void td_Initialize()
 682 {
 683         InitializeEntity(world, td_DelayedInit, INITPRIO_GAMETYPE);
 684 }
 685
 686 MUTATOR_HOOKFUNCTION(td_TurretValidateTarget)
 687 {
 688         if(time < game_starttime || current_phase != PHASE_COMBAT || gameover)
 689         {
 690                 turret_target = world;
 691                 return FALSE; // battle hasn't started
 692         }
 693
 694         if(turret_flags & TFL_TARGETSELECT_MISSILESONLY)
 695     if(turret_target.flags & FL_PROJECTILE)
 696         if(turret_target.owner.flags & FL_MONSTER)
 697         return TRUE; // flac support
 698
 699         if(turret.turrcaps_flags & TFL_TURRCAPS_SUPPORT && turret_target.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 700                 return TRUE;
 701         if not(turret_target.flags & FL_MONSTER)
 702                 turret_target = world;
 703
 704         return FALSE;
 705 }
 706
 707 MUTATOR_HOOKFUNCTION(td_PlayerThink)
 708 {
 709         self.stat_current_wave = wave_count;
 710         self.stat_totalwaves = max_waves;
 711
 712         return FALSE;
 713 }
 714
 715 MUTATOR_HOOKFUNCTION(td_PlayerSpawn)
 716 {
 717         self.bot_attack = FALSE;
 718
 719         return FALSE;
 720 }
 721
 722 MUTATOR_HOOKFUNCTION(td_PlayerDies)
 723 {
 724         if(frag_attacker.flags & FL_MONSTER)
 725                 PlayerScore_Add(frag_target, SP_TD_DEATHS, 1);
 726
 727         if(frag_target == frag_attacker)
 728                 PlayerScore_Add(frag_attacker, SP_TD_SUICIDES, 1);
 729
 730         return FALSE;
 731 }
 732
 733 MUTATOR_HOOKFUNCTION(td_GiveFragsForKill)
 734 {
 735         frag_score = 0;
 736
 737         return TRUE; // no frags counted in td
 738 }
 739
 740 MUTATOR_HOOKFUNCTION(td_PlayerDamage)
 741 {
 742         if(frag_attacker.realowner == frag_target)
 743                 frag_damage = 0;
 744
 745         if(frag_target.flags & FL_MONSTER && time < frag_target.spawnshieldtime)
 746                 frag_damage = 0;
 747
 748         if(frag_target.vehicle_flags & VHF_ISVEHICLE && !(frag_attacker.flags & FL_MONSTER))
 749                 frag_damage = 0;
 750
 751         if(frag_attacker.vehicle_flags & VHF_ISVEHICLE && !(frag_target.flags & FL_MONSTER))
 752                 frag_damage = 0;
 753
 754         if(!autocvar_g_td_pvp && frag_attacker != frag_target && IS_PLAYER(frag_target) && IS_PLAYER(frag_attacker))
 755         {
 756                 frag_attacker.typehitsound += 1;
 757                 frag_damage = 0;
 758         }
 759
 760         if(frag_attacker.turrcaps_flags & TFL_TURRCAPS_ISTURRET && IS_PLAYER(frag_target))
 761                 frag_damage = 0;
 762
 763         if((frag_target.turrcaps_flags & TFL_TURRCAPS_ISTURRET) && !(frag_attacker.flags & FL_MONSTER || frag_attacker.turrcaps_flags & TFL_TURRCAPS_SUPPORT))
 764                 frag_damage = 0;
 765
 766         return TRUE;
 767 }
 768
 769 MUTATOR_HOOKFUNCTION(td_TurretDies)
 770 {
 771         if(self.realowner)
 772                 self.realowner.turret_cnt -= 1;
 773
 774         return FALSE;
 775 }
 776
 777 MUTATOR_HOOKFUNCTION(td_MonsterCheckBossFlag)
 778 {
 779         // No minibosses in tower defense
 780         return TRUE;
 781 }
 782
 783 MUTATOR_HOOKFUNCTION(td_MonsterMove)
 784 {
 785         if not(self.enemy) // don't change targets while attacking
 786         if((vlen(monster_target.origin - self.origin) <= 100 && monster_target.classname == "td_waypoint") || (vlen(monster_target.origin - self.origin) <= 200 && (self.flags & FL_FLY) && monster_target.classname == "td_waypoint"))
 787         {
 788                 if(monster_target.target2)
 789                 {
 790                         if(random() > 0.5)
 791                                 self.target2 = monster_target.target2;
 792                         else
 793                                 self.target2 = monster_target.target;
 794                 }
 795                 else
 796                         self.target2 = monster_target.target;
 797
 798                 monster_target = find(world, targetname, self.target2);
 799
 800                 if(monster_target == world)
 801                         monster_target = PickGenerator();
 802         }
 803
 804         monster_speed_run = (m_speed_run + random() * 4) * monster_skill;
 805         monster_speed_walk = (m_speed_walk + random() * 4) * monster_skill;
 806
 807         return FALSE;
 808 }
 809
 810 MUTATOR_HOOKFUNCTION(td_MonsterSpawn)
 811 {
 812         if(self.realowner == world) // nothing spawned it, so kill it
 813         {
 814                 WaypointSprite_Kill(self.sprite);
 815                 remove(self.weaponentity);
 816                 remove(self);
 817                 return TRUE;
 818         }
 819
 820         current_monsters += 1;
 821
 822         self.spawnshieldtime = time + autocvar_g_td_monsters_spawnshield_time;
 823
 824         self.drop_size = bound(5, self.health * 0.05, autocvar_g_pickup_fuel_max);
 825
 826         self.target_range = 600;
 827
 828         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_CORPSE | DPCONTENTS_MONSTERCLIP;
 829
 830         switch(self.monsterid)
 831         {
 832                 case MONSTER_ZOMBIE: n_zombies -= 1; break;
 833                 case MONSTER_OGRE: n_ogres -= 1; break;
 834                 case MONSTER_DEMON: n_demons -= 1; break;
 835                 case MONSTER_SHAMBLER: n_shamblers -= 1; break;
 836                 case MONSTER_KNIGHT: n_knights -= 1; break;
 837                 case MONSTER_MARINE: n_soldiers -= 1; break;
 838                 case MONSTER_SCRAG: n_wizards -= 1; break;
 839                 case MONSTER_DOG: n_dogs -= 1; break;
 840                 case MONSTER_TARBABY: n_tarbabies -= 1; break;
 841                 case MONSTER_HELLKNIGHT: n_hknights -= 1; break;
 842                 case MONSTER_FISH: n_fish -= 1; break;
 843                 case MONSTER_MAGE: n_shalraths -= 1; break;
 844                 case MONSTER_SPIDER: n_spiders -= 1; break;
 845         }
 846
 847         return TRUE;
 848 }
 849
 850 MUTATOR_HOOKFUNCTION(td_MonsterDies)
 851 {
 852         entity oldself;
 853         vector backuporigin;
 854
 855         monster_count -= 1;
 856         current_monsters -= 1;
 857         monsters_killed += 1;
 858
 859         if(IS_PLAYER(frag_attacker))
 860         {
 861                 PlayerScore_Add(frag_attacker, SP_TD_SCORE, autocvar_g_td_kill_points);
 862                 PlayerScore_Add(frag_attacker, SP_TD_KILLS, 1);
 863         }
 864         else if(IS_PLAYER(frag_attacker.realowner))
 865         if(frag_attacker.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 866         {
 867                 PlayerScore_Add(frag_attacker.realowner, SP_TD_SCORE, autocvar_g_td_turretkill_points);
 868                 PlayerScore_Add(frag_attacker.realowner, SP_TD_TURKILLS, 1);
 869         }
 870
 871         backuporigin = self.origin;
 872         oldself = self;
 873         self = spawn();
 874
 875         self.gravity = 1;
 876         setorigin(self, backuporigin + '0 0 5');
 877         spawn_td_fuel(oldself.drop_size);
 878         self.touch = M_Item_Touch;
 879         if(self == world)
 880         {
 881                 self = oldself;
 882                 return FALSE;
 883         }
 884         SUB_SetFade(self, time + 5, 1);
 885
 886         self = oldself;
 887
 888         return FALSE;
 889 }
 890
 891 MUTATOR_HOOKFUNCTION(td_MonsterFindTarget)
 892 {
 893         float n_players = 0;
 894         entity player;
 895         local entity e;
 896
 897         FOR_EACH_PLAYER(player) { ++n_players; }
 898
 899         if(n_players < 1) // no players online, so do nothing
 900         {
 901                 self.enemy = world;
 902                 return TRUE;
 903         }
 904
 905         for(e = world;(e = findflags(e, monster_attack, TRUE)); )
 906         {
 907                 if(ignore_turrets)
 908                 if(e.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 909                         continue;
 910
 911                 if(monster_isvalidtarget(e, self))
 912                 if((vlen(trace_endpos - self.origin) < 200 && e.turrcaps_flags & TFL_TURRCAPS_ISTURRET) || (vlen(trace_endpos - self.origin) < 200 && !(e.flags & FL_GENERATOR)) || (vlen(trace_endpos - self.origin) < 500 && e.flags & FL_GENERATOR))
 913                 {
 914                         self.enemy = e;
 915                 }
 916         }
 917
 918         return TRUE;
 919 }
 920
 921 MUTATOR_HOOKFUNCTION(td_SetStartItems)
 922 {
 923         start_ammo_fuel = 150; // to be nice...
 924
 925         return FALSE;
 926 }
 927
 928 MUTATOR_HOOKFUNCTION(td_TurretSpawn)
 929 {
 930         if(self.realowner == world)
 931                 return TRUE; // wasn't spawned by a player
 932
 933         self.bot_attack = FALSE;
 934         buffturret(self, 0.5);
 935
 936         return FALSE;
 937 }
 938
 939 MUTATOR_HOOKFUNCTION(td_DisableVehicles)
 940 {
 941         // you shall not spawn!
 942         return TRUE;
 943 }
 944
 945 MUTATOR_HOOKFUNCTION(td_PlayerCommand)
 946 {
 947         if(MUTATOR_RETURNVALUE) { return FALSE; } // command was already handled?
 948
 949         makevectors(self.v_angle);
 950         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_HITMODEL, self);
 951
 952         if(cmd_name == "turretspawn")
 953         {
 954                 if(argv(1) == "list")
 955                 {
 956                         Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TD_LIST, "mlrs walker plasma towerbuff flac barricade");
 957                         return TRUE;
 958                 }
 959                 if(!IS_PLAYER(self) || self.health <= 0)
 960                 {
 961                         Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TD_CANTSPAWN);
 962                         return TRUE;
 963                 }
 964                 if(max_turrets <= 0)
 965                 {
 966                         Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TD_TURRETS_DISABLED);
 967                         return TRUE;
 968                 }
 969                 if(self.turret_cnt >= max_turrets)
 970                 {
 971                         Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TD_MAXTURRETS, max_turrets);
 972                         return TRUE;
 973                 }
 974
 975                 spawnturret(self, self, argv(1), trace_endpos);
 976
 977                 return TRUE;
 978         }
 979         if(cmd_name == "repairturret")
 980         {
 981                 if((trace_ent.playerid != self.playerid || trace_ent.realowner != self) || !(trace_ent.turrcaps_flags & TFL_TURRCAPS_ISTURRET))
 982                 {
 983                         Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TD_AIM_REPAIR);
 984                         return TRUE;
 985                 }
 986                 if(self.ammo_fuel < autocvar_g_td_turret_repair_cost)
 987                 {
 988                         Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TD_NOFUEL_REPAIR, autocvar_g_td_turret_repair_cost);
 989                         return TRUE;
 990                 }
 991                 if(trace_ent.health >= trace_ent.max_health)
 992                 {
 993                         Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TD_MAXHEALTH);
 994                         return TRUE;
 995                 }
 996
 997                 self.ammo_fuel -= autocvar_g_td_turret_repair_cost;
 998                 trace_ent.SendFlags |= TNSF_STATUS;
 999                 trace_ent.health = bound(1, trace_ent.health + 100, trace_ent.max_health);
1000                 WaypointSprite_UpdateHealth(trace_ent.sprite, trace_ent.health);
1001                 Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TD_REPAIR);
1002
1003                 return TRUE;
1004         }
1005         if(cmd_name == "buffturret")
1006         {
1007                 if((trace_ent.playerid != self.playerid || trace_ent.realowner != self) || !(trace_ent.turrcaps_flags & TFL_TURRCAPS_ISTURRET))
1008                 {
1009                         Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TD_AIM_UPGRADE);
1010                         return TRUE;
1011                 }
1012                 if(self.ammo_fuel < autocvar_g_td_turret_upgrade_cost)
1013                 {
1014                         Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TD_NOFUEL_UPGRADE, autocvar_g_td_turret_upgrade_cost);
1015                         return TRUE;
1016                 }
1017                 if(trace_ent.turret_buff >= 5)
1018                 {
1019                         Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TD_MAXPOWER);
1020                         return TRUE;
1021                 }
1022
1023                 self.ammo_fuel -= autocvar_g_td_turret_upgrade_cost;
1024                 trace_ent.SendFlags |= TNSF_STATUS;
1025                 buffturret(trace_ent, 1.2);
1026                 WaypointSprite_UpdateHealth(trace_ent.sprite, trace_ent.health);
1027                 Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TD_UPGRADE);
1028
1029                 return TRUE;
1030         }
1031         if(cmd_name == "turretremove")
1032         {
1033                 if((trace_ent.turrcaps_flags & TFL_TURRCAPS_ISTURRET) && (trace_ent.playerid == self.playerid || trace_ent.realowner == self))
1034                 {
1035                         self.turret_cnt -= 1;
1036                         Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TD_REMOVE);
1037                         WaypointSprite_Kill(trace_ent.sprite);
1038                         remove(trace_ent.tur_head);
1039                         remove(trace_ent);
1040                         return TRUE;
1041                 }
1042                 Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TD_AIM_REMOVE);
1043                 return TRUE;
1044         }
1045
1046         return FALSE;
1047 }
1048
1049 MUTATOR_HOOKFUNCTION(td_ClientConnect)
1050 {
1051         entity t;
1052
1053         self.turret_cnt = 0;
1054
1055         for(t = world; (t = findflags(t, turrcaps_flags, TFL_TURRCAPS_ISTURRET)); )
1056         if(t.playerid == self.playerid)
1057         {
1058                 t.realowner = self;
1059                 self.turret_cnt += 1;
1060         }
1061
1062         return FALSE;
1063 }
1064
1065 MUTATOR_DEFINITION(gamemode_td)
1066 {
1067         MUTATOR_HOOK(MonsterSpawn, td_MonsterSpawn, CBC_ORDER_ANY);
1068         MUTATOR_HOOK(MonsterDies, td_MonsterDies, CBC_ORDER_ANY);
1069         MUTATOR_HOOK(MonsterMove, td_MonsterMove, CBC_ORDER_ANY);
1070         MUTATOR_HOOK(MonsterFindTarget, td_MonsterFindTarget, CBC_ORDER_ANY);
1071         MUTATOR_HOOK(MonsterCheckBossFlag, td_MonsterCheckBossFlag, CBC_ORDER_ANY);
1072         MUTATOR_HOOK(SetStartItems, td_SetStartItems, CBC_ORDER_ANY);
1073         MUTATOR_HOOK(TurretValidateTarget, td_TurretValidateTarget, CBC_ORDER_ANY);
1074         MUTATOR_HOOK(TurretSpawn, td_TurretSpawn, CBC_ORDER_ANY);
1075         MUTATOR_HOOK(TurretDies, td_TurretDies, CBC_ORDER_ANY);
1076         MUTATOR_HOOK(GiveFragsForKill, td_GiveFragsForKill, CBC_ORDER_ANY);
1077         MUTATOR_HOOK(PlayerPreThink, td_PlayerThink, CBC_ORDER_ANY);
1078         MUTATOR_HOOK(PlayerDies, td_PlayerDies, CBC_ORDER_ANY);
1079         MUTATOR_HOOK(PlayerDamage_Calculate, td_PlayerDamage, CBC_ORDER_ANY);
1080         MUTATOR_HOOK(PlayerSpawn, td_PlayerSpawn, CBC_ORDER_ANY);
1081         MUTATOR_HOOK(VehicleSpawn, td_DisableVehicles, CBC_ORDER_ANY);
1082         MUTATOR_HOOK(SV_ParseClientCommand, td_PlayerCommand, CBC_ORDER_ANY);
1083         MUTATOR_HOOK(ClientConnect, td_ClientConnect, CBC_ORDER_ANY);
1084
1085         MUTATOR_ONADD
1086         {
1087                 if(time > 1) // game loads at time 1
1088                         error("This is a game type and it cannot be added at runtime.");
1089                 cvar_settemp("g_monsters", "1");
1090                 cvar_settemp("g_turrets", "1");
1091                 td_Initialize();
1092         }
1093
1094         MUTATOR_ONROLLBACK_OR_REMOVE
1095         {
1096                 // we actually cannot roll back td_Initialize here
1097                 // BUT: we don't need to! If this gets called, adding always
1098                 // succeeds.
1099         }
1100
1101         MUTATOR_ONREMOVE
1102         {
1103                 error("This is a game type and it cannot be removed at runtime.");
1104                 return -1;
1105         }
1106
1107         return FALSE;
1108 }