qcsrc/server/mutators/mutator/gamemode_keyhunt.qc

   1 #include "gamemode_keyhunt.qh"
   2
   3 float autocvar_g_balance_keyhunt_damageforcescale;
   4 float autocvar_g_balance_keyhunt_delay_collect;
   5 float autocvar_g_balance_keyhunt_delay_damage_return;
   6 float autocvar_g_balance_keyhunt_delay_return;
   7 float autocvar_g_balance_keyhunt_delay_round;
   8 float autocvar_g_balance_keyhunt_delay_tracking;
   9 float autocvar_g_balance_keyhunt_return_when_unreachable;
  10 float autocvar_g_balance_keyhunt_dropvelocity;
  11 float autocvar_g_balance_keyhunt_maxdist;
  12 float autocvar_g_balance_keyhunt_protecttime;
  13
  14 int autocvar_g_balance_keyhunt_score_capture;
  15 int autocvar_g_balance_keyhunt_score_carrierfrag;
  16 int autocvar_g_balance_keyhunt_score_collect;
  17 int autocvar_g_balance_keyhunt_score_destroyed;
  18 int autocvar_g_balance_keyhunt_score_destroyed_ownfactor;
  19 int autocvar_g_balance_keyhunt_score_push;
  20 float autocvar_g_balance_keyhunt_throwvelocity;
  21
  22 //int autocvar_g_keyhunt_teams;
  23 int autocvar_g_keyhunt_teams_override;
  24
  25 // #define KH_PLAYER_USE_ATTACHMENT
  26 // #define KH_PLAYER_USE_CARRIEDMODEL
  27
  28 #ifdef KH_PLAYER_USE_ATTACHMENT
  29 const vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
  30 const vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  31 const vector KH_PLAYER_ATTACHMENT = '0 0 0';
  32 const vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  33 const string KH_PLAYER_ATTACHMENT_BONE = "";
  34 #else
  35 const float KH_KEY_ZSHIFT = 22;
  36 const float KH_KEY_XYDIST = 24;
  37 const float KH_KEY_XYSPEED = 45;
  38 #endif
  39 const float KH_KEY_WP_ZSHIFT = 20;
  40
  41 const vector KH_KEY_MIN = '-10 -10 -46';
  42 const vector KH_KEY_MAX = '10 10 3';
  43 const float KH_KEY_BRIGHTNESS = 2;
  44
  45 bool kh_no_radar_circles;
  46
  47 // kh_state
  48 //     bits  0- 4: team of key 1, or 0 for no such key, or 30 for dropped, or 31 for self
  49 //     bits  5- 9: team of key 2, or 0 for no such key, or 30 for dropped, or 31 for self
  50 //     bits 10-14: team of key 3, or 0 for no such key, or 30 for dropped, or 31 for self
  51 //     bits 15-19: team of key 4, or 0 for no such key, or 30 for dropped, or 31 for self
  52 .int kh_state = _STAT(KH_KEYS);
  53 .float siren_time;  //  time delay the siren
  54 //.float stuff_time;  //  time delay to stuffcmd a cvar
  55
  56 int kh_keystatus[17];
  57 //kh_keystatus[0] = status of dropped keys, kh_keystatus[1 - 16] = player #
  58 //replace 17 with cvar("maxplayers") or similar !!!!!!!!!
  59 //for(i = 0; i < maxplayers; ++i)
  60 //      kh_keystatus[i] = "0";
  61
  62 int kh_Team_ByID(int t)
  63 {
  64         if(t == 0) return NUM_TEAM_1;
  65         if(t == 1) return NUM_TEAM_2;
  66         if(t == 2) return NUM_TEAM_3;
  67         if(t == 3) return NUM_TEAM_4;
  68         return 0;
  69 }
  70
  71 //entity kh_worldkeylist;
  72 .entity kh_worldkeynext;
  73 entity kh_controller;
  74 //bool kh_tracking_enabled;
  75 int kh_teams;
  76 int kh_interferemsg_team;
  77 float kh_interferemsg_time;
  78 .entity kh_next, kh_prev; // linked list
  79 .float kh_droptime;
  80 .int kh_dropperteam;
  81 .entity kh_previous_owner;
  82 .int kh_previous_owner_playerid;
  83
  84 int kh_key_dropped, kh_key_carried;
  85
  86 int kh_Key_AllOwnedByWhichTeam();
  87
  88 const float ST_KH_CAPS = 1;
  89 void kh_ScoreRules(int teams)
  90 {
  91         ScoreRules_basics(teams, SFL_SORT_PRIO_PRIMARY, SFL_SORT_PRIO_PRIMARY, true);
  92         ScoreInfo_SetLabel_TeamScore(  ST_KH_CAPS,      "caps",      SFL_SORT_PRIO_SECONDARY);
  93         ScoreInfo_SetLabel_PlayerScore(SP_KH_CAPS,      "caps",      SFL_SORT_PRIO_SECONDARY);
  94         ScoreInfo_SetLabel_PlayerScore(SP_KH_PUSHES,    "pushes",    0);
  95         ScoreInfo_SetLabel_PlayerScore(SP_KH_DESTROYS,  "destroyed", SFL_LOWER_IS_BETTER);
  96         ScoreInfo_SetLabel_PlayerScore(SP_KH_PICKUPS,   "pickups",   0);
  97         ScoreInfo_SetLabel_PlayerScore(SP_KH_KCKILLS,   "kckills",   0);
  98         ScoreInfo_SetLabel_PlayerScore(SP_KH_LOSSES,    "losses",    SFL_LOWER_IS_BETTER);
  99         ScoreRules_basics_end();
 100 }
 101
 102 bool kh_KeyCarrier_waypointsprite_visible_for_player(entity this, entity player, entity view)  // runs all the time
 103 {
 104         if(!IS_PLAYER(view) || DIFF_TEAM(this, view))
 105                 if(!kh_tracking_enabled)
 106                         return false;
 107
 108         return true;
 109 }
 110
 111 bool kh_Key_waypointsprite_visible_for_player(entity this, entity player, entity view)
 112 {
 113         if(!kh_tracking_enabled)
 114                 return false;
 115         if(!this.owner)
 116                 return true;
 117         if(!this.owner.owner)
 118                 return true;
 119         return false;  // draw only when key is not owned
 120 }
 121
 122 void kh_update_state()
 123 {
 124         entity key;
 125         int f;
 126         int s = 0;
 127         FOR_EACH_KH_KEY(key)
 128         {
 129                 if(key.owner)
 130                         f = key.team;
 131                 else
 132                         f = 30;
 133                 s |= (32 ** key.count) * f;
 134         }
 135
 136         FOREACH_CLIENT(true, LAMBDA(it.kh_state = s));
 137
 138         FOR_EACH_KH_KEY(key)
 139         {
 140                 if(key.owner)
 141                         key.owner.kh_state |= (32 ** key.count) * 31;
 142         }
 143         //print(ftos((nextent(NULL)).kh_state), "\n");
 144 }
 145
 146
 147
 148
 149 var kh_Think_t kh_Controller_Thinkfunc;
 150 void kh_Controller_SetThink(float t, kh_Think_t func)  // runs occasionaly
 151 {
 152         kh_Controller_Thinkfunc = func;
 153         kh_controller.cnt = ceil(t);
 154         if(t == 0)
 155                 kh_controller.nextthink = time; // force
 156 }
 157 void kh_WaitForPlayers();
 158 void kh_Controller_Think(entity this)  // called a lot
 159 {
 160         if(game_stopped)
 161                 return;
 162         if(this.cnt > 0)
 163         {
 164                 if(getthink(this) != kh_WaitForPlayers)
 165                         this.cnt -= 1;
 166         }
 167         else if(this.cnt == 0)
 168         {
 169                 this.cnt -= 1;
 170                 kh_Controller_Thinkfunc();
 171         }
 172         this.nextthink = time + 1;
 173 }
 174
 175 // frags f: take from cvar * f
 176 // frags 0: no frags
 177 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)  // update the score when a key is captured
 178 {
 179         string s;
 180         if(game_stopped)
 181                 return;
 182
 183         if(frags_player)
 184                 UpdateFrags(player, frags_player);
 185
 186         if(key && key.owner && frags_owner)
 187                 UpdateFrags(key.owner, frags_owner);
 188
 189         if(!autocvar_sv_eventlog)  //output extra info to the console or text file
 190                 return;
 191
 192         s = strcat(":keyhunt:", what, ":", ftos(player.playerid), ":", ftos(frags_player));
 193
 194         if(key && key.owner)
 195                 s = strcat(s, ":", ftos(key.owner.playerid));
 196         else
 197                 s = strcat(s, ":0");
 198
 199         s = strcat(s, ":", ftos(frags_owner), ":");
 200
 201         if(key)
 202                 s = strcat(s, key.netname);
 203
 204         GameLogEcho(s);
 205 }
 206
 207 vector kh_AttachedOrigin(entity e)  // runs when a team captures the flag, it can run 2 or 3 times.
 208 {
 209         if(e.tag_entity)
 210         {
 211                 makevectors(e.tag_entity.angles);
 212                 return e.tag_entity.origin + e.origin.x * v_forward - e.origin.y * v_right + e.origin.z * v_up;
 213         }
 214         else
 215                 return e.origin;
 216 }
 217
 218 void kh_Key_Attach(entity key)  // runs when a player picks up a key and several times when a key is assigned to a player at the start of a round
 219 {
 220 #ifdef KH_PLAYER_USE_ATTACHMENT
 221         entity first = key.owner.kh_next;
 222         if(key == first)
 223         {
 224                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 225                 if(key.kh_next)
 226                 {
 227                         setattachment(key.kh_next, key, "");
 228                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 229                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 230                         key.kh_next.angles = '0 0 0';
 231                 }
 232                 else
 233                         setorigin(key, KH_PLAYER_ATTACHMENT);
 234                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 235         }
 236         else
 237         {
 238                 setattachment(key, key.kh_prev, "");
 239                 if(key.kh_next)
 240                         setattachment(key.kh_next, key, "");
 241                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 242                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 243                 key.angles = '0 0 0';
 244         }
 245 #else
 246         setattachment(key, key.owner, "");
 247         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT);  // fixing x, y in think
 248         key.angles_y -= key.owner.angles.y;
 249 #endif
 250         key.flags = 0;
 251         IL_REMOVE(g_items, key);
 252         key.solid = SOLID_NOT;
 253         set_movetype(key, MOVETYPE_NONE);
 254         key.team = key.owner.team;
 255         key.nextthink = time;
 256         key.damageforcescale = 0;
 257         key.takedamage = DAMAGE_NO;
 258         key.modelindex = kh_key_carried;
 259         navigation_dynamicgoal_unset(key);
 260 }
 261
 262 void kh_Key_Detach(entity key) // runs every time a key is dropped or lost. Runs several times times when all the keys are captured
 263 {
 264 #ifdef KH_PLAYER_USE_ATTACHMENT
 265         entity first = key.owner.kh_next;
 266         if(key == first)
 267         {
 268                 if(key.kh_next)
 269                 {
 270                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 271                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 272                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 273                 }
 274         }
 275         else
 276         {
 277                 if(key.kh_next)
 278                         setattachment(key.kh_next, key.kh_prev, "");
 279                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 280         }
 281         // in any case:
 282         setattachment(key, NULL, "");
 283         setorigin(key, key.owner.origin + '0 0 1' * (STAT(PL_MIN, key.owner).z - KH_KEY_MIN_z));
 284         key.angles = key.owner.angles;
 285 #else
 286         setorigin(key, key.owner.origin + key.origin.z * '0 0 1');
 287         setattachment(key, NULL, "");
 288         key.angles_y += key.owner.angles.y;
 289 #endif
 290         key.flags = FL_ITEM;
 291         IL_PUSH(g_items, key);
 292         key.solid = SOLID_TRIGGER;
 293         set_movetype(key, MOVETYPE_TOSS);
 294         key.pain_finished = time + autocvar_g_balance_keyhunt_delay_return;
 295         key.damageforcescale = autocvar_g_balance_keyhunt_damageforcescale;
 296         key.takedamage = DAMAGE_YES;
 297         // let key.team stay
 298         key.modelindex = kh_key_dropped;
 299         navigation_dynamicgoal_set(key);
 300         key.kh_previous_owner = key.owner;
 301         key.kh_previous_owner_playerid = key.owner.playerid;
 302 }
 303
 304 void kh_Key_AssignTo(entity key, entity player)  // runs every time a key is picked up or assigned. Runs prior to kh_key_attach
 305 {
 306         if(key.owner == player)
 307                 return;
 308
 309         int ownerteam0 = kh_Key_AllOwnedByWhichTeam();
 310
 311         if(key.owner)
 312         {
 313                 kh_Key_Detach(key);
 314
 315                 // remove from linked list
 316                 if(key.kh_next)
 317                         key.kh_next.kh_prev = key.kh_prev;
 318                 key.kh_prev.kh_next = key.kh_next;
 319                 key.kh_next = NULL;
 320                 key.kh_prev = NULL;
 321
 322                 if(key.owner.kh_next == NULL)
 323                 {
 324                         // No longer a key carrier
 325                         if(!kh_no_radar_circles)
 326                                 WaypointSprite_Ping(key.owner.waypointsprite_attachedforcarrier);
 327                         WaypointSprite_DetachCarrier(key.owner);
 328                 }
 329         }
 330
 331         key.owner = player;
 332
 333         if(player)
 334         {
 335                 // insert into linked list
 336                 key.kh_next = player.kh_next;
 337                 key.kh_prev = player;
 338                 player.kh_next = key;
 339                 if(key.kh_next)
 340                         key.kh_next.kh_prev = key;
 341
 342                 float i;
 343                 i = kh_keystatus[key.owner.playerid];
 344                         if(key.netname == "^1red key")
 345                                 i += 1;
 346                         if(key.netname == "^4blue key")
 347                                 i += 2;
 348                         if(key.netname == "^3yellow key")
 349                                 i += 4;
 350                         if(key.netname == "^6pink key")
 351                                 i += 8;
 352                 kh_keystatus[key.owner.playerid] = i;
 353
 354                 kh_Key_Attach(key);
 355
 356                 if(key.kh_next == NULL)
 357                 {
 358                         // player is now a key carrier
 359                         entity wp = WaypointSprite_AttachCarrier(WP_Null, player, RADARICON_FLAGCARRIER);
 360                         wp.colormod = colormapPaletteColor(player.team - 1, 0);
 361                         player.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_KeyCarrier_waypointsprite_visible_for_player;
 362                         WaypointSprite_UpdateRule(player.waypointsprite_attachedforcarrier, player.team, SPRITERULE_TEAMPLAY);
 363                         if(player.team == NUM_TEAM_1)
 364                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierRed, WP_KeyCarrierFriend, WP_KeyCarrierRed);
 365                         else if(player.team == NUM_TEAM_2)
 366                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierBlue, WP_KeyCarrierFriend, WP_KeyCarrierBlue);
 367                         else if(player.team == NUM_TEAM_3)
 368                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierYellow, WP_KeyCarrierFriend, WP_KeyCarrierYellow);
 369                         else if(player.team == NUM_TEAM_4)
 370                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierPink, WP_KeyCarrierFriend, WP_KeyCarrierPink);
 371                         if(!kh_no_radar_circles)
 372                                 WaypointSprite_Ping(player.waypointsprite_attachedforcarrier);
 373                 }
 374         }
 375
 376         // moved that here, also update if there's no player
 377         kh_update_state();
 378
 379         key.pusher = NULL;
 380
 381         int ownerteam = kh_Key_AllOwnedByWhichTeam();
 382         if(ownerteam != ownerteam0)
 383         {
 384                 entity k;
 385                 if(ownerteam != -1)
 386                 {
 387                         kh_interferemsg_time = time + 0.2;
 388                         kh_interferemsg_team = player.team;
 389
 390                         // audit all key carrier sprites, update them to "Run here"
 391                         FOR_EACH_KH_KEY(k)
 392                         {
 393                                 if (!k.owner) continue;
 394                                 entity first = WP_Null;
 395                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model1, LAMBDA(first = it; break));
 396                                 entity third = WP_Null;
 397                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model3, LAMBDA(third = it; break));
 398                                 WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, first, WP_KeyCarrierFinish, third);
 399                         }
 400                 }
 401                 else
 402                 {
 403                         kh_interferemsg_time = 0;
 404
 405                         // audit all key carrier sprites, update them to "Key Carrier"
 406                         FOR_EACH_KH_KEY(k)
 407                         {
 408                                 if (!k.owner) continue;
 409                                 entity first = WP_Null;
 410                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model1, LAMBDA(first = it; break));
 411                                 entity third = WP_Null;
 412                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model3, LAMBDA(third = it; break));
 413                                 WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, first, WP_KeyCarrierFriend, third);
 414                         }
 415                 }
 416         }
 417 }
 418
 419 void kh_Key_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 420 {
 421         if(this.owner)
 422                 return;
 423         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 424         {
 425                 this.pain_finished = bound(time, time + autocvar_g_balance_keyhunt_delay_damage_return, this.pain_finished);
 426                 return;
 427         }
 428         if(force == '0 0 0')
 429                 return;
 430         if(time > this.pushltime)
 431                 if(IS_PLAYER(attacker))
 432                         this.team = attacker.team;
 433 }
 434
 435 void kh_Key_Collect(entity key, entity player)  //a player picks up a dropped key
 436 {
 437         sound(player, CH_TRIGGER, SND_KH_COLLECT, VOL_BASE, ATTEN_NORM);
 438
 439         if(key.kh_dropperteam != player.team)
 440         {
 441                 kh_Scores_Event(player, key, "collect", autocvar_g_balance_keyhunt_score_collect, 0);
 442                 PlayerScore_Add(player, SP_KH_PICKUPS, 1);
 443         }
 444         key.kh_dropperteam = 0;
 445         int realteam = kh_Team_ByID(key.count);
 446         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_PICKUP), player.netname);
 447
 448         kh_Key_AssignTo(key, player); // this also updates .kh_state
 449 }
 450
 451 void kh_Key_Touch(entity this, entity toucher)  // runs many, many times when a key has been dropped and can be picked up
 452 {
 453         if(game_stopped)
 454                 return;
 455
 456         if(this.owner) // already carried
 457                 return;
 458
 459         if(ITEM_TOUCH_NEEDKILL())
 460         {
 461                 this.pain_finished = bound(time, time + autocvar_g_balance_keyhunt_delay_damage_return, this.pain_finished);
 462                 return;
 463         }
 464
 465         if (!IS_PLAYER(toucher))
 466                 return;
 467         if(IS_DEAD(toucher))
 468                 return;
 469         if(toucher == this.enemy)
 470                 if(time < this.kh_droptime + autocvar_g_balance_keyhunt_delay_collect)
 471                         return;  // you just dropped it!
 472         kh_Key_Collect(this, toucher);
 473 }
 474
 475 void kh_Key_Remove(entity key)  // runs after when all the keys have been collected or when a key has been dropped for more than X seconds
 476 {
 477         entity o = key.owner;
 478         kh_Key_AssignTo(key, NULL);
 479         if(o) // it was attached
 480                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 481         else // it was dropped
 482                 WaypointSprite_DetachCarrier(key);
 483
 484         // remove key from key list
 485         if (kh_worldkeylist == key)
 486                 kh_worldkeylist = kh_worldkeylist.kh_worldkeynext;
 487         else
 488         {
 489                 o = kh_worldkeylist;
 490                 while (o)
 491                 {
 492                         if (o.kh_worldkeynext == key)
 493                         {
 494                                 o.kh_worldkeynext = o.kh_worldkeynext.kh_worldkeynext;
 495                                 break;
 496                         }
 497                         o = o.kh_worldkeynext;
 498                 }
 499         }
 500
 501         delete(key);
 502
 503         kh_update_state();
 504 }
 505
 506 void kh_FinishRound()  // runs when a team captures the keys
 507 {
 508         // prepare next round
 509         kh_interferemsg_time = 0;
 510         entity key;
 511
 512         kh_no_radar_circles = true;
 513         FOR_EACH_KH_KEY(key)
 514                 kh_Key_Remove(key);
 515         kh_no_radar_circles = false;
 516
 517         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_ROUNDSTART, autocvar_g_balance_keyhunt_delay_round);
 518         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, kh_StartRound);
 519 }
 520
 521 void nades_GiveBonus(entity player, float score);
 522
 523 void kh_WinnerTeam(int winner_team)  // runs when a team wins
 524 {
 525         // all key carriers get some points
 526         entity key;
 527         float score = (NumTeams(kh_teams) - 1) * autocvar_g_balance_keyhunt_score_capture;
 528         DistributeEvenly_Init(score, NumTeams(kh_teams));
 529         // twice the score for 3 team games, three times the score for 4 team games!
 530         // note: for a win by destroying the key, this should NOT be applied
 531         FOR_EACH_KH_KEY(key)
 532         {
 533                 float f = DistributeEvenly_Get(1);
 534                 kh_Scores_Event(key.owner, key, "capture", f, 0);
 535                 PlayerTeamScore_Add(key.owner, SP_KH_CAPS, ST_KH_CAPS, 1);
 536                 nades_GiveBonus(key.owner, autocvar_g_nades_bonus_score_high);
 537         }
 538
 539         bool first = true;
 540         string keyowner = "";
 541         FOR_EACH_KH_KEY(key)
 542                 if(key.owner.kh_next == key)
 543                 {
 544                         if(!first)
 545                                 keyowner = strcat(keyowner, ", ");
 546                         keyowner = key.owner.netname;
 547                         first = false;
 548                 }
 549
 550         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
 551         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_KEYHUNT_CAPTURE), keyowner);
 552
 553         first = true;
 554         vector firstorigin = '0 0 0', lastorigin = '0 0 0', midpoint = '0 0 0';
 555         FOR_EACH_KH_KEY(key)
 556         {
 557                 vector thisorigin = kh_AttachedOrigin(key);
 558                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 559                 midpoint += thisorigin;
 560
 561                 if(!first)
 562                         te_lightning2(NULL, lastorigin, thisorigin);
 563                 lastorigin = thisorigin;
 564                 if(first)
 565                         firstorigin = thisorigin;
 566                 first = false;
 567         }
 568         if(NumTeams(kh_teams) > 2)
 569         {
 570                 te_lightning2(NULL, lastorigin, firstorigin);
 571         }
 572         midpoint = midpoint * (1 / NumTeams(kh_teams));
 573         te_customflash(midpoint, 1000, 1, Team_ColorRGB(winner_team) * 0.5 + '0.5 0.5 0.5');  // make the color >=0.5 in each component
 574
 575         play2all(SND(KH_CAPTURE));
 576         kh_FinishRound();
 577 }
 578
 579 void kh_LoserTeam(int loser_team, entity lostkey)  // runs when a player pushes a flag carrier off the map
 580 {
 581         float f;
 582         entity attacker = NULL;
 583         if(lostkey.pusher)
 584                 if(lostkey.pusher.team != loser_team)
 585                         if(IS_PLAYER(lostkey.pusher))
 586                                 attacker = lostkey.pusher;
 587
 588         if(attacker)
 589         {
 590                 if(lostkey.kh_previous_owner)
 591                         kh_Scores_Event(lostkey.kh_previous_owner, NULL, "pushed", 0, -autocvar_g_balance_keyhunt_score_push);
 592                         // don't actually GIVE him the -nn points, just log
 593                 kh_Scores_Event(attacker, NULL, "push", autocvar_g_balance_keyhunt_score_push, 0);
 594                 PlayerScore_Add(attacker, SP_KH_PUSHES, 1);
 595                 //centerprint(attacker, "Your push is the best!"); // does this really need to exist?
 596         }
 597         else
 598         {
 599                 int players = 0;
 600                 float of = autocvar_g_balance_keyhunt_score_destroyed_ownfactor;
 601
 602                 FOREACH_CLIENT(IS_PLAYER(it) && it.team != loser_team, LAMBDA(++players));
 603
 604                 entity key;
 605                 int keys = 0;
 606                 FOR_EACH_KH_KEY(key)
 607                         if(key.owner && key.team != loser_team)
 608                                 ++keys;
 609
 610                 if(lostkey.kh_previous_owner)
 611                         kh_Scores_Event(lostkey.kh_previous_owner, NULL, "destroyed", 0, -autocvar_g_balance_keyhunt_score_destroyed);
 612                         // don't actually GIVE him the -nn points, just log
 613
 614                 if(lostkey.kh_previous_owner.playerid == lostkey.kh_previous_owner_playerid)
 615                         PlayerScore_Add(lostkey.kh_previous_owner, SP_KH_DESTROYS, 1);
 616
 617                 DistributeEvenly_Init(autocvar_g_balance_keyhunt_score_destroyed, keys * of + players);
 618
 619                 FOR_EACH_KH_KEY(key)
 620                         if(key.owner && key.team != loser_team)
 621                         {
 622                                 f = DistributeEvenly_Get(of);
 623                                 kh_Scores_Event(key.owner, NULL, "destroyed_holdingkey", f, 0);
 624                         }
 625
 626                 int fragsleft = DistributeEvenly_Get(players);
 627
 628                 // Now distribute these among all other teams...
 629                 int j = NumTeams(kh_teams) - 1;
 630                 for(int i = 0; i < NumTeams(kh_teams); ++i)
 631                 {
 632                         int thisteam = kh_Team_ByID(i);
 633                         if(thisteam == loser_team) // bad boy, no cookie - this WILL happen
 634                                 continue;
 635
 636                         players = 0;
 637                         FOREACH_CLIENT(IS_PLAYER(it) && it.team == thisteam, LAMBDA(++players));
 638
 639                         DistributeEvenly_Init(fragsleft, j);
 640                         fragsleft = DistributeEvenly_Get(j - 1);
 641                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 642
 643                         FOREACH_CLIENT(IS_PLAYER(it) && it.team == thisteam, LAMBDA(
 644                                 f = DistributeEvenly_Get(1);
 645                                 kh_Scores_Event(it, NULL, "destroyed", f, 0);
 646                         ));
 647
 648                         --j;
 649                 }
 650         }
 651
 652         int realteam = kh_Team_ByID(lostkey.count);
 653         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(loser_team, CENTER_ROUND_TEAM_LOSS));
 654         if(attacker)
 655                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_PUSHED), attacker.netname, lostkey.kh_previous_owner.netname);
 656         else
 657                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_DESTROYED), lostkey.kh_previous_owner.netname);
 658
 659         play2all(SND(KH_DESTROY));
 660         te_tarexplosion(lostkey.origin);
 661
 662         kh_FinishRound();
 663 }
 664
 665 void kh_Key_Think(entity this)  // runs all the time
 666 {
 667         if(game_stopped)
 668                 return;
 669
 670         if(this.owner)
 671         {
 672 #ifndef KH_PLAYER_USE_ATTACHMENT
 673                 makevectors('0 1 0' * (this.cnt + (time % 360) * KH_KEY_XYSPEED));
 674                 setorigin(this, v_forward * KH_KEY_XYDIST + '0 0 1' * this.origin.z);
 675 #endif
 676         }
 677
 678         // if in nodrop or time over, end the round
 679         if(!this.owner)
 680                 if(time > this.pain_finished)
 681                         kh_LoserTeam(this.team, this);
 682
 683         if(this.owner)
 684         if(kh_Key_AllOwnedByWhichTeam() != -1)
 685         {
 686                 if(this.siren_time < time)
 687                 {
 688                         sound(this.owner, CH_TRIGGER, SND_KH_ALARM, VOL_BASE, ATTEN_NORM);  // play a simple alarm
 689                         this.siren_time = time + 2.5;  // repeat every 2.5 seconds
 690                 }
 691
 692                 entity key;
 693                 vector p = this.owner.origin;
 694                 FOR_EACH_KH_KEY(key)
 695                         if(vdist(key.owner.origin - p, >, autocvar_g_balance_keyhunt_maxdist))
 696                                 goto not_winning;
 697                 kh_WinnerTeam(this.team);
 698 LABEL(not_winning)
 699         }
 700
 701         if(kh_interferemsg_time && time > kh_interferemsg_time)
 702         {
 703                 kh_interferemsg_time = 0;
 704                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 705                         if(it.team == kh_interferemsg_team)
 706                                 if(it.kh_next)
 707                                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_KEYHUNT_MEET);
 708                                 else
 709                                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_KEYHUNT_HELP);
 710                         else
 711                                 Send_Notification(NOTIF_ONE, it, MSG_CENTER, APP_TEAM_NUM(kh_interferemsg_team, CENTER_KEYHUNT_INTERFERE));
 712                 ));
 713         }
 714
 715         this.nextthink = time + 0.05;
 716 }
 717
 718 void key_reset(entity this)
 719 {
 720         kh_Key_AssignTo(this, NULL);
 721         kh_Key_Remove(this);
 722 }
 723
 724 const string STR_ITEM_KH_KEY = "item_kh_key";
 725 void kh_Key_Spawn(entity initial_owner, float _angle, float i)  // runs every time a new flag is created, ie after all the keys have been collected
 726 {
 727         entity key = spawn();
 728         key.count = i;
 729         key.classname = STR_ITEM_KH_KEY;
 730         settouch(key, kh_Key_Touch);
 731         setthink(key, kh_Key_Think);
 732         key.nextthink = time;
 733         key.items = IT_KEY1 | IT_KEY2;
 734         key.cnt = _angle;
 735         key.angles = '0 360 0' * random();
 736         key.event_damage = kh_Key_Damage;
 737         key.takedamage = DAMAGE_YES;
 738         key.damagedbytriggers = autocvar_g_balance_keyhunt_return_when_unreachable;
 739         key.damagedbycontents = autocvar_g_balance_keyhunt_return_when_unreachable;
 740         key.modelindex = kh_key_dropped;
 741         key.model = "key";
 742         key.kh_dropperteam = 0;
 743         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 744         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 745         key.colormod = Team_ColorRGB(initial_owner.team) * KH_KEY_BRIGHTNESS;
 746         key.reset = key_reset;
 747         navigation_dynamicgoal_init(key, false);
 748
 749         switch(initial_owner.team)
 750         {
 751                 case NUM_TEAM_1:
 752                         key.netname = "^1red key";
 753                         break;
 754                 case NUM_TEAM_2:
 755                         key.netname = "^4blue key";
 756                         break;
 757                 case NUM_TEAM_3:
 758                         key.netname = "^3yellow key";
 759                         break;
 760                 case NUM_TEAM_4:
 761                         key.netname = "^6pink key";
 762                         break;
 763                 default:
 764                         key.netname = "NETGIER key";
 765                         break;
 766         }
 767
 768         // link into key list
 769         key.kh_worldkeynext = kh_worldkeylist;
 770         kh_worldkeylist = key;
 771
 772         Send_Notification(NOTIF_ONE, initial_owner, MSG_CENTER, APP_TEAM_NUM(initial_owner.team, CENTER_KEYHUNT_START));
 773
 774         WaypointSprite_Spawn(WP_KeyDropped, 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, NULL, key.team, key, waypointsprite_attachedforcarrier, false, RADARICON_FLAG);
 775         key.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_Key_waypointsprite_visible_for_player;
 776
 777         kh_Key_AssignTo(key, initial_owner);
 778 }
 779
 780 // -1 when no team completely owns all keys yet
 781 int kh_Key_AllOwnedByWhichTeam()  // constantly called. check to see if all the keys are owned by the same team
 782 {
 783         entity key;
 784         int teem = -1;
 785         int keys = NumTeams(kh_teams);
 786         FOR_EACH_KH_KEY(key)
 787         {
 788                 if(!key.owner)
 789                         return -1;
 790                 if(teem == -1)
 791                         teem = key.team;
 792                 else if(teem != key.team)
 793                         return -1;
 794                 --keys;
 795         }
 796         if(keys != 0)
 797                 return -1;
 798         return teem;
 799 }
 800
 801 void kh_Key_DropOne(entity key)
 802 {
 803         // prevent collecting this one for some time
 804         entity player = key.owner;
 805
 806         key.kh_droptime = time;
 807         key.enemy = player;
 808
 809         kh_Scores_Event(player, key, "dropkey", 0, 0);
 810         PlayerScore_Add(player, SP_KH_LOSSES, 1);
 811         int realteam = kh_Team_ByID(key.count);
 812         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_DROP), player.netname);
 813
 814         kh_Key_AssignTo(key, NULL);
 815         makevectors(player.v_angle);
 816         key.velocity = W_CalculateProjectileVelocity(player, player.velocity, autocvar_g_balance_keyhunt_throwvelocity * v_forward, false);
 817         key.pusher = NULL;
 818         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 819         key.kh_dropperteam = key.team;
 820
 821         sound(player, CH_TRIGGER, SND_KH_DROP, VOL_BASE, ATTEN_NORM);
 822 }
 823
 824 void kh_Key_DropAll(entity player, float suicide) // runs whenever a player dies
 825 {
 826         if(player.kh_next)
 827         {
 828                 entity mypusher = NULL;
 829                 if(player.pusher)
 830                         if(time < player.pushltime)
 831                                 mypusher = player.pusher;
 832
 833                 entity key;
 834                 while((key = player.kh_next))
 835                 {
 836                         kh_Scores_Event(player, key, "losekey", 0, 0);
 837                         PlayerScore_Add(player, SP_KH_LOSSES, 1);
 838                         int realteam = kh_Team_ByID(key.count);
 839                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_LOST), player.netname);
 840                         kh_Key_AssignTo(key, NULL);
 841                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 842                         key.velocity = W_CalculateProjectileVelocity(player, player.velocity, autocvar_g_balance_keyhunt_dropvelocity * v_forward, false);
 843                         key.pusher = mypusher;
 844                         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 845                         if(suicide)
 846                                 key.kh_dropperteam = player.team;
 847                 }
 848                 sound(player, CH_TRIGGER, SND_KH_DROP, VOL_BASE, ATTEN_NORM);
 849         }
 850 }
 851
 852 int kh_GetMissingTeams()
 853 {
 854         int missing_teams = 0;
 855         for(int i = 0; i < NumTeams(kh_teams); ++i)
 856         {
 857                 int teem = kh_Team_ByID(i);
 858                 int players = 0;
 859                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 860                         if(!IS_DEAD(it) && !PHYS_INPUT_BUTTON_CHAT(it) && it.team == teem)
 861                                 ++players;
 862                 ));
 863                 if (!players)
 864                         missing_teams |= (2 ** i);
 865         }
 866         return missing_teams;
 867 }
 868
 869 void kh_WaitForPlayers()  // delay start of the round until enough players are present
 870 {
 871         static int prev_missing_teams_mask;
 872         if(time < game_starttime)
 873         {
 874                 if (prev_missing_teams_mask > 0)
 875                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 876                 prev_missing_teams_mask = -1;
 877                 kh_Controller_SetThink(game_starttime - time + 0.1, kh_WaitForPlayers);
 878                 return;
 879         }
 880
 881         int missing_teams_mask = kh_GetMissingTeams();
 882         if(!missing_teams_mask)
 883         {
 884                 if(prev_missing_teams_mask > 0)
 885                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 886                 prev_missing_teams_mask = -1;
 887                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_ROUNDSTART, autocvar_g_balance_keyhunt_delay_round);
 888                 kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, kh_StartRound);
 889         }
 890         else
 891         {
 892                 if(player_count == 0)
 893                 {
 894                         if(prev_missing_teams_mask > 0)
 895                                 Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 896                         prev_missing_teams_mask = -1;
 897                 }
 898                 else
 899                 {
 900                         if(prev_missing_teams_mask != missing_teams_mask)
 901                         {
 902                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
 903                                 prev_missing_teams_mask = missing_teams_mask;
 904                         }
 905                 }
 906                 kh_Controller_SetThink(1, kh_WaitForPlayers);
 907         }
 908 }
 909
 910 void kh_EnableTrackingDevice()  // runs after each round
 911 {
 912         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT);
 913         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT_OTHER);
 914
 915         kh_tracking_enabled = true;
 916 }
 917
 918 void kh_StartRound()  // runs at the start of each round
 919 {
 920         if(time < game_starttime)
 921         {
 922                 kh_Controller_SetThink(game_starttime - time + 0.1, kh_WaitForPlayers);
 923                 return;
 924         }
 925
 926         if(kh_GetMissingTeams())
 927         {
 928                 kh_Controller_SetThink(1, kh_WaitForPlayers);
 929                 return;
 930         }
 931
 932         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT);
 933         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT_OTHER);
 934
 935         for(int i = 0; i < NumTeams(kh_teams); ++i)
 936         {
 937                 int teem = kh_Team_ByID(i);
 938                 int players = 0;
 939                 entity my_player = NULL;
 940                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 941                         if(!IS_DEAD(it) && !PHYS_INPUT_BUTTON_CHAT(it) && it.team == teem)
 942                         {
 943                                 ++players;
 944                                 if(random() * players <= 1)
 945                                         my_player = it;
 946                         }
 947                 ));
 948                 kh_Key_Spawn(my_player, 360 * i / NumTeams(kh_teams), i);
 949         }
 950
 951         kh_tracking_enabled = false;
 952         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_SCAN, autocvar_g_balance_keyhunt_delay_tracking);
 953         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_tracking, kh_EnableTrackingDevice);
 954 }
 955
 956 float kh_HandleFrags(entity attacker, entity targ, float f)  // adds to the player score
 957 {
 958         if(attacker == targ)
 959                 return f;
 960
 961         if(targ.kh_next)
 962         {
 963                 if(attacker.team == targ.team)
 964                 {
 965                         int nk = 0;
 966                         for(entity k = targ.kh_next; k != NULL; k = k.kh_next)
 967                                 ++nk;
 968                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * autocvar_g_balance_keyhunt_score_collect, 0);
 969                 }
 970                 else
 971                 {
 972                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", autocvar_g_balance_keyhunt_score_carrierfrag-1, 0);
 973                         PlayerScore_Add(attacker, SP_KH_KCKILLS, 1);
 974                         // the frag gets added later
 975                 }
 976         }
 977
 978         return f;
 979 }
 980
 981 void kh_Initialize()  // sets up th KH environment
 982 {
 983         // setup variables
 984         kh_teams = autocvar_g_keyhunt_teams_override;
 985         if(kh_teams < 2)
 986                 kh_teams = cvar("g_keyhunt_teams"); // read the cvar directly as it gets written earlier in the same frame
 987         kh_teams = bound(2, kh_teams, 4);
 988
 989         int teams = 0;
 990         if(kh_teams >= 1) teams |= BIT(0);
 991         if(kh_teams >= 2) teams |= BIT(1);
 992         if(kh_teams >= 3) teams |= BIT(2);
 993         if(kh_teams >= 4) teams |= BIT(3);
 994
 995         kh_teams = teams; // now set it?
 996
 997         // make a KH entity for controlling the game
 998         kh_controller = spawn();
 999         setthink(kh_controller, kh_Controller_Think);
1000         kh_Controller_SetThink(0, kh_WaitForPlayers);
1001
1002         setmodel(kh_controller, MDL_KH_KEY);
1003         kh_key_dropped = kh_controller.modelindex;
1004         /*
1005         dprint(vtos(kh_controller.mins));
1006         dprint(vtos(kh_controller.maxs));
1007         dprint("\n");
1008         */
1009 #ifdef KH_PLAYER_USE_CARRIEDMODEL
1010         setmodel(kh_controller, MDL_KH_KEY_CARRIED);
1011         kh_key_carried = kh_controller.modelindex;
1012 #else
1013         kh_key_carried = kh_key_dropped;
1014 #endif
1015
1016         kh_controller.model = "";
1017         kh_controller.modelindex = 0;
1018
1019         kh_ScoreRules(kh_teams);
1020 }
1021
1022 void kh_finalize()
1023 {
1024         // to be called before intermission
1025         kh_FinishRound();
1026         delete(kh_controller);
1027         kh_controller = NULL;
1028 }
1029
1030 // legacy bot role
1031
1032 void(entity this) havocbot_role_kh_carrier;
1033 void(entity this) havocbot_role_kh_defense;
1034 void(entity this) havocbot_role_kh_offense;
1035 void(entity this) havocbot_role_kh_freelancer;
1036
1037
1038 void havocbot_goalrating_kh(entity this, float ratingscale_team, float ratingscale_dropped, float ratingscale_enemy)
1039 {
1040         entity head;
1041         for (head = kh_worldkeylist; head; head = head.kh_worldkeynext)
1042         {
1043                 if(head.owner == this)
1044                         continue;
1045                 if(!kh_tracking_enabled)
1046                 {
1047                         // if it's carried by our team we know about it
1048                         // otherwise we have to see it to know about it
1049                         if(!head.owner || head.team != this.team)
1050                         {
1051                                 traceline(this.origin + this.view_ofs, head.origin, MOVE_NOMONSTERS, this);
1052                                 if (trace_fraction < 1 && trace_ent != head)
1053                                         continue; // skip what I can't see
1054                         }
1055                 }
1056                 if(!head.owner)
1057                         navigation_routerating(this, head, ratingscale_dropped * 10000, 100000);
1058                 else if(head.team == this.team)
1059                         navigation_routerating(this, head.owner, ratingscale_team * 10000, 100000);
1060                 else
1061                         navigation_routerating(this, head.owner, ratingscale_enemy * 10000, 100000);
1062         }
1063
1064         havocbot_goalrating_items(this, 1, this.origin, 10000);
1065 }
1066
1067 void havocbot_role_kh_carrier(entity this)
1068 {
1069         if(IS_DEAD(this))
1070                 return;
1071
1072         if (!(this.kh_next))
1073         {
1074                 LOG_TRACE("changing role to freelancer");
1075                 this.havocbot_role = havocbot_role_kh_freelancer;
1076                 this.havocbot_role_timeout = 0;
1077                 return;
1078         }
1079
1080         if (this.bot_strategytime < time)
1081         {
1082                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1083                 navigation_goalrating_start(this);
1084
1085                 if(kh_Key_AllOwnedByWhichTeam() == this.team)
1086                         havocbot_goalrating_kh(this, 10, 0.1, 0.1); // bring home
1087                 else
1088                         havocbot_goalrating_kh(this, 4, 4, 1); // play defensively
1089
1090                 navigation_goalrating_end(this);
1091         }
1092 }
1093
1094 void havocbot_role_kh_defense(entity this)
1095 {
1096         if(IS_DEAD(this))
1097                 return;
1098
1099         if (this.kh_next)
1100         {
1101                 LOG_TRACE("changing role to carrier");
1102                 this.havocbot_role = havocbot_role_kh_carrier;
1103                 this.havocbot_role_timeout = 0;
1104                 return;
1105         }
1106
1107         if (!this.havocbot_role_timeout)
1108                 this.havocbot_role_timeout = time + random() * 10 + 20;
1109         if (time > this.havocbot_role_timeout)
1110         {
1111                 LOG_TRACE("changing role to freelancer");
1112                 this.havocbot_role = havocbot_role_kh_freelancer;
1113                 this.havocbot_role_timeout = 0;
1114                 return;
1115         }
1116
1117         if (this.bot_strategytime < time)
1118         {
1119                 float key_owner_team;
1120                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1121                 navigation_goalrating_start(this);
1122
1123                 key_owner_team = kh_Key_AllOwnedByWhichTeam();
1124                 if(key_owner_team == this.team)
1125                         havocbot_goalrating_kh(this, 10, 0.1, 0.1); // defend key carriers
1126                 else if(key_owner_team == -1)
1127                         havocbot_goalrating_kh(this, 4, 1, 0.1); // play defensively
1128                 else
1129                         havocbot_goalrating_kh(this, 0.1, 0.1, 10); // ATTACK ANYWAY
1130
1131                 navigation_goalrating_end(this);
1132         }
1133 }
1134
1135 void havocbot_role_kh_offense(entity this)
1136 {
1137         if(IS_DEAD(this))
1138                 return;
1139
1140         if (this.kh_next)
1141         {
1142                 LOG_TRACE("changing role to carrier");
1143                 this.havocbot_role = havocbot_role_kh_carrier;
1144                 this.havocbot_role_timeout = 0;
1145                 return;
1146         }
1147
1148         if (!this.havocbot_role_timeout)
1149                 this.havocbot_role_timeout = time + random() * 10 + 20;
1150         if (time > this.havocbot_role_timeout)
1151         {
1152                 LOG_TRACE("changing role to freelancer");
1153                 this.havocbot_role = havocbot_role_kh_freelancer;
1154                 this.havocbot_role_timeout = 0;
1155                 return;
1156         }
1157
1158         if (this.bot_strategytime < time)
1159         {
1160                 float key_owner_team;
1161
1162                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1163                 navigation_goalrating_start(this);
1164
1165                 key_owner_team = kh_Key_AllOwnedByWhichTeam();
1166                 if(key_owner_team == this.team)
1167                         havocbot_goalrating_kh(this, 10, 0.1, 0.1); // defend anyway
1168                 else if(key_owner_team == -1)
1169                         havocbot_goalrating_kh(this, 0.1, 1, 4); // play offensively
1170                 else
1171                         havocbot_goalrating_kh(this, 0.1, 0.1, 10); // ATTACK! EMERGENCY!
1172
1173                 navigation_goalrating_end(this);
1174         }
1175 }
1176
1177 void havocbot_role_kh_freelancer(entity this)
1178 {
1179         if(IS_DEAD(this))
1180                 return;
1181
1182         if (this.kh_next)
1183         {
1184                 LOG_TRACE("changing role to carrier");
1185                 this.havocbot_role = havocbot_role_kh_carrier;
1186                 this.havocbot_role_timeout = 0;
1187                 return;
1188         }
1189
1190         if (!this.havocbot_role_timeout)
1191                 this.havocbot_role_timeout = time + random() * 10 + 10;
1192         if (time > this.havocbot_role_timeout)
1193         {
1194                 if (random() < 0.5)
1195                 {
1196                         LOG_TRACE("changing role to offense");
1197                         this.havocbot_role = havocbot_role_kh_offense;
1198                 }
1199                 else
1200                 {
1201                         LOG_TRACE("changing role to defense");
1202                         this.havocbot_role = havocbot_role_kh_defense;
1203                 }
1204                 this.havocbot_role_timeout = 0;
1205                 return;
1206         }
1207
1208         if (this.bot_strategytime < time)
1209         {
1210                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1211                 navigation_goalrating_start(this);
1212
1213                 int key_owner_team = kh_Key_AllOwnedByWhichTeam();
1214                 if(key_owner_team == this.team)
1215                         havocbot_goalrating_kh(this, 10, 0.1, 0.1); // defend anyway
1216                 else if(key_owner_team == -1)
1217                         havocbot_goalrating_kh(this, 1, 10, 4); // prefer dropped keys
1218                 else
1219                         havocbot_goalrating_kh(this, 0.1, 0.1, 10); // ATTACK ANYWAY
1220
1221                 navigation_goalrating_end(this);
1222         }
1223 }
1224
1225
1226 // register this as a mutator
1227
1228 MUTATOR_HOOKFUNCTION(kh, ClientDisconnect)
1229 {
1230         entity player = M_ARGV(0, entity);
1231
1232         kh_Key_DropAll(player, true);
1233 }
1234
1235 MUTATOR_HOOKFUNCTION(kh, MakePlayerObserver)
1236 {
1237         entity player = M_ARGV(0, entity);
1238
1239         kh_Key_DropAll(player, true);
1240 }
1241
1242 MUTATOR_HOOKFUNCTION(kh, PlayerDies)
1243 {
1244         entity frag_attacker = M_ARGV(1, entity);
1245         entity frag_target = M_ARGV(2, entity);
1246
1247         if(frag_target == frag_attacker)
1248                 kh_Key_DropAll(frag_target, true);
1249         else if(IS_PLAYER(frag_attacker))
1250                 kh_Key_DropAll(frag_target, false);
1251         else
1252                 kh_Key_DropAll(frag_target, true);
1253 }
1254
1255 MUTATOR_HOOKFUNCTION(kh, GiveFragsForKill, CBC_ORDER_FIRST)
1256 {
1257         entity frag_attacker = M_ARGV(0, entity);
1258         entity frag_target = M_ARGV(1, entity);
1259         float frag_score = M_ARGV(2, float);
1260         M_ARGV(2, float) = kh_HandleFrags(frag_attacker, frag_target, frag_score);
1261 }
1262
1263 MUTATOR_HOOKFUNCTION(kh, MatchEnd)
1264 {
1265         kh_finalize();
1266 }
1267
1268 MUTATOR_HOOKFUNCTION(kh, CheckAllowedTeams, CBC_ORDER_EXCLUSIVE)
1269 {
1270         M_ARGV(0, float) = kh_teams;
1271 }
1272
1273 MUTATOR_HOOKFUNCTION(kh, SpectateCopy)
1274 {
1275         entity spectatee = M_ARGV(0, entity);
1276         entity client = M_ARGV(1, entity);
1277
1278         client.kh_state = spectatee.kh_state;
1279 }
1280
1281 MUTATOR_HOOKFUNCTION(kh, PlayerUseKey)
1282 {
1283         entity player = M_ARGV(0, entity);
1284
1285         if(MUTATOR_RETURNVALUE == 0)
1286         {
1287                 entity k = player.kh_next;
1288                 if(k)
1289                 {
1290                         kh_Key_DropOne(k);
1291                         return true;
1292                 }
1293         }
1294 }
1295
1296 MUTATOR_HOOKFUNCTION(kh, HavocBot_ChooseRole)
1297 {
1298     entity bot = M_ARGV(0, entity);
1299
1300         if(IS_DEAD(bot))
1301                 return true;
1302
1303         float r = random() * 3;
1304         if (r < 1)
1305                 bot.havocbot_role = havocbot_role_kh_offense;
1306         else if (r < 2)
1307                 bot.havocbot_role = havocbot_role_kh_defense;
1308         else
1309                 bot.havocbot_role = havocbot_role_kh_freelancer;
1310
1311         return true;
1312 }
1313
1314 MUTATOR_HOOKFUNCTION(kh, DropSpecialItems)
1315 {
1316         entity frag_target = M_ARGV(0, entity);
1317
1318         kh_Key_DropAll(frag_target, false);
1319 }
1320
1321 MUTATOR_HOOKFUNCTION(kh, reset_map_global)
1322 {
1323         kh_WaitForPlayers(); // takes care of killing the "missing teams" message
1324 }