qcsrc/server/mutators/mutator/mutator_overkill.qc

   1 #ifdef IMPLEMENTATION
   2 .vector ok_deathloc;
   3 .float ok_spawnsys_timer;
   4 .float ok_lastwep;
   5 .float ok_item;
   6
   7 .float ok_notice_time;
   8 .float ammo_charge[Weapons_MAX];
   9 .float ok_use_ammocharge;
  10 .float ok_ammo_charge;
  11
  12 .float ok_pauseregen_finished;
  13
  14 void(entity ent, float wep) ok_DecreaseCharge;
  15
  16 void ok_Initialize();
  17
  18 REGISTER_MUTATOR(ok, cvar("g_overkill") && !cvar("g_instagib") && !g_nexball && cvar_string("g_mod_balance") == "Overkill")
  19 {
  20         MUTATOR_ONADD
  21         {
  22                 ok_Initialize();
  23         }
  24
  25         MUTATOR_ONREMOVE
  26         {
  27                 WEP_RPC.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
  28                 WEP_HMG.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
  29         }
  30
  31         return false;
  32 }
  33
  34 void W_Blaster_Attack(entity, float, float, float, float, float, float, float, float, float, float);
  35 spawnfunc(weapon_hmg);
  36 spawnfunc(weapon_rpc);
  37
  38 void ok_DecreaseCharge(entity ent, int wep)
  39 {
  40         if(!ent.ok_use_ammocharge) return;
  41
  42         entity wepent = get_weaponinfo(wep);
  43
  44         if(wepent.weapon == 0)
  45                 return; // dummy
  46
  47         ent.ammo_charge[wep] -= max(0, cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname)));
  48 }
  49
  50 void ok_IncreaseCharge(entity ent, int wep)
  51 {
  52         entity wepent = get_weaponinfo(wep);
  53
  54         if(wepent.weapon == 0)
  55                 return; // dummy
  56
  57         if(ent.ok_use_ammocharge)
  58         if(!ent.BUTTON_ATCK) // not while attacking?
  59                 ent.ammo_charge[wep] = min(autocvar_g_overkill_ammo_charge_limit, ent.ammo_charge[wep] + cvar(sprintf("g_overkill_ammo_charge_rate_%s", wepent.netname)) * frametime / W_TICSPERFRAME);
  60 }
  61
  62 float ok_CheckWeaponCharge(entity ent, int wep)
  63 {
  64         if(!ent.ok_use_ammocharge) return true;
  65
  66         entity wepent = get_weaponinfo(wep);
  67
  68         if(wepent.weapon == 0)
  69                 return 0; // dummy
  70
  71         return (ent.ammo_charge[wep] >= cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname)));
  72 }
  73
  74 MUTATOR_HOOKFUNCTION(ok, PlayerDamage_Calculate, CBC_ORDER_LAST)
  75 {
  76         if(IS_PLAYER(frag_attacker) && IS_PLAYER(frag_target))
  77         if(DEATH_ISWEAPON(frag_deathtype, WEP_BLASTER))
  78         {
  79                 frag_damage = 0;
  80
  81                 if(frag_attacker != frag_target)
  82                 if(frag_target.health > 0)
  83                 if(frag_target.frozen == 0)
  84                 if(frag_target.deadflag == DEAD_NO)
  85                 {
  86                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_SECONDARY_NODAMAGE);
  87                         frag_force = '0 0 0';
  88                 }
  89         }
  90
  91         return false;
  92 }
  93
  94 MUTATOR_HOOKFUNCTION(ok, PlayerDamage_SplitHealthArmor)
  95 {SELFPARAM();
  96         if(damage_take)
  97                 self.ok_pauseregen_finished = max(self.ok_pauseregen_finished, time + 2);
  98         return false;
  99 }
 100
 101 MUTATOR_HOOKFUNCTION(ok, PlayerDies)
 102 {SELFPARAM();
 103         entity targ = ((frag_attacker) ? frag_attacker : frag_target);
 104
 105         if(IS_MONSTER(self))
 106         {
 107                 remove(other); // remove default item
 108                 other = world;
 109         }
 110
 111         setself(spawn());
 112         self.ok_item = true;
 113         self.noalign = true;
 114         self.pickup_anyway = true;
 115         spawnfunc_item_armor_small(this);
 116         self.movetype = MOVETYPE_TOSS;
 117         self.gravity = 1;
 118         self.reset = SUB_Remove;
 119         setorigin(self, frag_target.origin + '0 0 32');
 120         self.velocity = '0 0 200' + normalize(targ.origin - self.origin) * 500;
 121         self.classname = "droppedweapon"; // hax
 122         SUB_SetFade(self, time + 5, 1);
 123         setself(this);
 124
 125         self.ok_lastwep = self.switchweapon;
 126
 127         return false;
 128 }
 129 MUTATOR_HOOKFUNCTION(ok, MonsterDropItem) { ok_PlayerDies(); }
 130
 131 MUTATOR_HOOKFUNCTION(ok, PlayerRegen)
 132 {SELFPARAM();
 133         // overkill's values are different, so use custom regen
 134         if(!self.frozen)
 135         {
 136                 self.armorvalue = CalcRotRegen(self.armorvalue, autocvar_g_balance_armor_regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, 1 * frametime * (time > self.ok_pauseregen_finished), 0, 0, 1, 1 * frametime * (time > self.pauserotarmor_finished), autocvar_g_balance_armor_limit);
 137                 self.health = CalcRotRegen(self.health, autocvar_g_balance_health_regenstable, 0, 100, 1 * frametime * (time > self.ok_pauseregen_finished), 200, 0, autocvar_g_balance_health_rotlinear, 1 * frametime * (time > self.pauserothealth_finished), autocvar_g_balance_health_limit);
 138
 139                 float minf, maxf, limitf;
 140
 141                 maxf = autocvar_g_balance_fuel_rotstable;
 142                 minf = autocvar_g_balance_fuel_regenstable;
 143                 limitf = autocvar_g_balance_fuel_limit;
 144
 145                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
 146         }
 147         return true; // return true anyway, as frozen uses no regen
 148 }
 149
 150 MUTATOR_HOOKFUNCTION(ok, ForbidThrowCurrentWeapon)
 151 {
 152         return true;
 153 }
 154
 155 MUTATOR_HOOKFUNCTION(ok, PlayerPreThink)
 156 {SELFPARAM();
 157         if(intermission_running || gameover)
 158                 return false;
 159
 160         if(self.deadflag != DEAD_NO || !IS_PLAYER(self) || self.frozen)
 161                 return false;
 162
 163         if(self.ok_lastwep)
 164         {
 165                 self.switchweapon = self.ok_lastwep;
 166                 self.ok_lastwep = 0;
 167         }
 168
 169         ok_IncreaseCharge(self, self.weapon);
 170
 171         if(self.BUTTON_ATCK2)
 172         if(!forbidWeaponUse(self) || self.weapon_blocked) // allow if weapon is blocked
 173         if(time >= self.jump_interval)
 174         {
 175                 self.jump_interval = time + WEP_CVAR_PRI(blaster, refire) * W_WeaponRateFactor();
 176                 makevectors(self.v_angle);
 177
 178                 int oldwep = self.weapon;
 179                 self.weapon = WEP_BLASTER.m_id;
 180                 W_Blaster_Attack(
 181                         self,
 182                         WEP_BLASTER.m_id | HITTYPE_SECONDARY,
 183                         WEP_CVAR_SEC(vaporizer, shotangle),
 184                         WEP_CVAR_SEC(vaporizer, damage),
 185                         WEP_CVAR_SEC(vaporizer, edgedamage),
 186                         WEP_CVAR_SEC(vaporizer, radius),
 187                         WEP_CVAR_SEC(vaporizer, force),
 188                         WEP_CVAR_SEC(vaporizer, speed),
 189                         WEP_CVAR_SEC(vaporizer, spread),
 190                         WEP_CVAR_SEC(vaporizer, delay),
 191                         WEP_CVAR_SEC(vaporizer, lifetime)
 192                 );
 193                 self.weapon = oldwep;
 194         }
 195
 196         self.weapon_blocked = false;
 197
 198         self.ok_ammo_charge = self.ammo_charge[self.weapon];
 199
 200         if(self.ok_use_ammocharge)
 201         if(!ok_CheckWeaponCharge(self, self.weapon))
 202         {
 203                 if(autocvar_g_overkill_ammo_charge_notice && time > self.ok_notice_time && self.BUTTON_ATCK && IS_REAL_CLIENT(self) && self.weapon == self.switchweapon)
 204                 {
 205                         //Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_OVERKILL_CHARGE);
 206                         self.ok_notice_time = time + 2;
 207                         play2(self, SND(DRYFIRE));
 208                 }
 209                 Weapon wpn = get_weaponinfo(self.weapon);
 210                 int slot = 0; // TODO: unhardcode
 211                 if(self.weaponentity[slot].state != WS_CLEAR)
 212                         w_ready(wpn, self, slot, (self.BUTTON_ATCK ? 1 : 0) | (self.BUTTON_ATCK2 ? 2 : 0));
 213
 214                 self.weapon_blocked = true;
 215         }
 216
 217         self.BUTTON_ATCK2 = 0;
 218
 219         return false;
 220 }
 221
 222 MUTATOR_HOOKFUNCTION(ok, PlayerSpawn)
 223 {SELFPARAM();
 224         if(autocvar_g_overkill_ammo_charge)
 225         {
 226                 for(int i = WEP_FIRST; i <= WEP_LAST; ++i)
 227                         self.ammo_charge[i] = autocvar_g_overkill_ammo_charge_limit;
 228
 229                 self.ok_use_ammocharge = 1;
 230                 self.ok_notice_time = time;
 231         }
 232         else
 233                 self.ok_use_ammocharge = 0;
 234
 235         self.ok_pauseregen_finished = time + 2;
 236
 237         return false;
 238 }
 239
 240 void _spawnfunc_weapon_hmg() { SELFPARAM(); spawnfunc_weapon_hmg(this); }
 241 void _spawnfunc_weapon_rpc() { SELFPARAM(); spawnfunc_weapon_rpc(this); }
 242
 243 MUTATOR_HOOKFUNCTION(ok, OnEntityPreSpawn)
 244 {SELFPARAM();
 245         if(autocvar_g_powerups)
 246         if(autocvar_g_overkill_powerups_replace)
 247         {
 248                 if(self.classname == "item_strength")
 249                 {
 250                         entity wep = spawn();
 251                         setorigin(wep, self.origin);
 252                         setmodel(wep, MDL_OK_HMG);
 253                         wep.classname = "weapon_hmg";
 254                         wep.ok_item = true;
 255                         wep.noalign = self.noalign;
 256                         wep.cnt = self.cnt;
 257                         wep.team = self.team;
 258                         wep.respawntime = autocvar_g_overkill_superguns_respawn_time;
 259                         wep.pickup_anyway = true;
 260                         wep.think = _spawnfunc_weapon_hmg;
 261                         wep.nextthink = time + 0.1;
 262                         return true;
 263                 }
 264
 265                 if(self.classname == "item_invincible")
 266                 {
 267                         entity wep = spawn();
 268                         setorigin(wep, self.origin);
 269                         setmodel(wep, MDL_OK_RPC);
 270                         wep.classname = "weapon_rpc";
 271                         wep.ok_item = true;
 272                         wep.noalign = self.noalign;
 273                         wep.cnt = self.cnt;
 274                         wep.team = self.team;
 275                         wep.respawntime = autocvar_g_overkill_superguns_respawn_time;
 276                         wep.pickup_anyway = true;
 277                         wep.think = _spawnfunc_weapon_rpc;
 278                         wep.nextthink = time + 0.1;
 279                         return true;
 280                 }
 281         }
 282
 283         return false;
 284 }
 285
 286 MUTATOR_HOOKFUNCTION(ok, FilterItem)
 287 {SELFPARAM();
 288         if(self.ok_item)
 289                 return false;
 290
 291         switch(self.items)
 292         {
 293                 case ITEM_HealthMega.m_itemid: return !(autocvar_g_overkill_100h_anyway);
 294                 case ITEM_ArmorMega.m_itemid: return !(autocvar_g_overkill_100a_anyway);
 295         }
 296
 297         return true;
 298 }
 299
 300 MUTATOR_HOOKFUNCTION(ok, SpectateCopy)
 301 {SELFPARAM();
 302         self.ammo_charge[self.weapon] = other.ammo_charge[other.weapon];
 303         self.ok_use_ammocharge = other.ok_use_ammocharge;
 304
 305         return false;
 306 }
 307
 308 MUTATOR_HOOKFUNCTION(ok, SetStartItems)
 309 {
 310         WepSet ok_start_items = (WEPSET(MACHINEGUN) | WEPSET(VORTEX) | WEPSET(SHOTGUN));
 311
 312         if(WEP_RPC.weaponstart > 0) { ok_start_items |= WEPSET(RPC); }
 313         if(WEP_HMG.weaponstart > 0) { ok_start_items |= WEPSET(HMG); }
 314
 315         start_items |= IT_UNLIMITED_WEAPON_AMMO;
 316         start_weapons = warmup_start_weapons = ok_start_items;
 317
 318         return false;
 319 }
 320
 321 MUTATOR_HOOKFUNCTION(ok, BuildMutatorsString)
 322 {
 323         ret_string = strcat(ret_string, ":OK");
 324         return false;
 325 }
 326
 327 MUTATOR_HOOKFUNCTION(ok, BuildMutatorsPrettyString)
 328 {
 329         ret_string = strcat(ret_string, ", Overkill");
 330         return false;
 331 }
 332
 333 MUTATOR_HOOKFUNCTION(ok, SetModname)
 334 {
 335         modname = "Overkill";
 336         return true;
 337 }
 338
 339 void ok_SetCvars()
 340 {
 341         // hack to force overkill playermodels
 342         cvar_settemp("sv_defaultcharacter", "1");
 343         cvar_settemp("sv_defaultplayermodel", "models/ok_player/okrobot1.dpm models/ok_player/okrobot2.dpm models/ok_player/okrobot3.dpm models/ok_player/okrobot4.dpm models/ok_player/okmale1.dpm models/ok_player/okmale2.dpm models/ok_player/okmale3.dpm models/ok_player/okmale4.dpm");
 344         cvar_settemp("sv_defaultplayermodel_red", "models/ok_player/okrobot1.dpm models/ok_player/okrobot2.dpm models/ok_player/okrobot3.dpm models/ok_player/okrobot4.dpm");
 345         cvar_settemp("sv_defaultplayermodel_blue", "models/ok_player/okmale1.dpm models/ok_player/okmale2.dpm models/ok_player/okmale3.dpm models/ok_player/okmale4.dpm");
 346 }
 347
 348 void ok_Initialize()
 349 {
 350         ok_SetCvars();
 351
 352         precache_all_playermodels("models/ok_player/*.dpm");
 353
 354         addstat(STAT_OK_AMMO_CHARGE, AS_FLOAT, ok_use_ammocharge);
 355         addstat(STAT_OK_AMMO_CHARGEPOOL, AS_FLOAT, ok_ammo_charge);
 356
 357         WEP_RPC.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 358         WEP_HMG.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 359
 360         WEP_SHOTGUN.mdl = "ok_shotgun";
 361         WEP_MACHINEGUN.mdl = "ok_mg";
 362         WEP_VORTEX.mdl = "ok_sniper";
 363 }
 364 #endif