qcsrc/server/mutators/mutator/sandbox.qc

   1 #ifdef IMPLEMENTATION
   2 float autosave_time;
   3 void sandbox_Database_Load();
   4
   5 REGISTER_MUTATOR(sandbox, cvar("g_sandbox"))
   6 {
   7         MUTATOR_ONADD
   8         {
   9                 autosave_time = time + autocvar_g_sandbox_storage_autosave; // don't save the first server frame
  10                 if(autocvar_g_sandbox_storage_autoload)
  11                         sandbox_Database_Load();
  12         }
  13
  14         MUTATOR_ONROLLBACK_OR_REMOVE
  15         {
  16                 // nothing to roll back
  17         }
  18
  19         MUTATOR_ONREMOVE
  20         {
  21                 // nothing to remove
  22         }
  23
  24         return false;
  25 }
  26
  27 const float MAX_STORAGE_ATTACHMENTS = 16;
  28 float object_count;
  29 .float object_flood;
  30 .entity object_attach;
  31 .string material;
  32
  33 .float touch_timer;
  34 void sandbox_ObjectFunction_Touch()
  35 {SELFPARAM();
  36         // apply material impact effects
  37
  38         if(!self.material)
  39                 return;
  40         if(self.touch_timer > time)
  41                 return; // don't execute each frame
  42         self.touch_timer = time + 0.1;
  43
  44         // make particle count and sound volume depend on impact speed
  45         float intensity;
  46         intensity = vlen(self.velocity) + vlen(other.velocity);
  47         if(intensity) // avoid divisions by 0
  48                 intensity /= 2; // average the two velocities
  49         if (!(intensity >= autocvar_g_sandbox_object_material_velocity_min))
  50                 return; // impact not strong enough to do anything
  51         // now offset intensity and apply it to the effects
  52         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
  53         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
  54
  55         _sound(self, CH_TRIGGER, strcat("object/impact_", self.material, "_", ftos(ceil(random() * 5)) , ".wav"), VOL_BASE * intensity, ATTEN_NORM);
  56         Send_Effect_(strcat("impact_", self.material), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  57 }
  58
  59 void sandbox_ObjectFunction_Think()
  60 {SELFPARAM();
  61         entity e;
  62
  63         // decide if and how this object can be grabbed
  64         if(autocvar_g_sandbox_readonly)
  65                 self.grab = 0; // no grabbing
  66         else if(autocvar_g_sandbox_editor_free < 2 && self.crypto_idfp)
  67                 self.grab = 1; // owner only
  68         else
  69                 self.grab = 3; // anyone
  70
  71         // Object owner is stored via player UID, but we also need the owner as an entity (if the player is available on the server).
  72         // Therefore, scan for all players, and update the owner as long as the player is present. We must always do this,
  73         // since if the owning player disconnects, the object's owner should also be reset.
  74         FOR_EACH_REALPLAYER(e) // bots can't have objects
  75         {
  76                 if(self.crypto_idfp == e.crypto_idfp)
  77                 {
  78                         self.realowner = e;
  79                         break;
  80                 }
  81                 self.realowner = world;
  82         }
  83
  84         self.nextthink = time;
  85
  86         CSQCMODEL_AUTOUPDATE(self);
  87 }
  88
  89 .float old_solid, old_movetype;
  90 entity sandbox_ObjectEdit_Get(float permissions)
  91 {SELFPARAM();
  92         // Returns the traced entity if the player can edit it, and world if not.
  93         // If permissions if false, the object is returned regardless of editing rights.
  94         // Attached objects are SOLID_NOT and do not get traced.
  95
  96         crosshair_trace_plusvisibletriggers(self);
  97         if(vlen(self.origin - trace_ent.origin) > autocvar_g_sandbox_editor_distance_edit)
  98                 return world; // out of trace range
  99         if(trace_ent.classname != "object")
 100                 return world; // entity is not an object
 101         if(!permissions)
 102                 return trace_ent; // don't check permissions, anyone can edit this object
 103         if(trace_ent.crypto_idfp == "")
 104                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
 105         if (!(trace_ent.realowner != self && autocvar_g_sandbox_editor_free < 2))
 106                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
 107         return world;
 108 }
 109
 110 void sandbox_ObjectEdit_Scale(entity e, float f)
 111 {
 112         e.scale = f;
 113         if(e.scale)
 114         {
 115                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
 116                 _setmodel(e, e.model); // reset mins and maxs based on mesh
 117                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
 118         }
 119 }
 120
 121 void sandbox_ObjectAttach_Remove(entity e);
 122 void sandbox_ObjectAttach_Set(entity e, entity parent, string s)
 123 {
 124         // attaches e to parent on string s
 125
 126         // we can't attach to an attachment, for obvious reasons
 127         sandbox_ObjectAttach_Remove(e);
 128
 129         e.old_solid = e.solid; // persist solidity
 130         e.old_movetype = e.movetype; // persist physics
 131         e.movetype = MOVETYPE_FOLLOW;
 132         e.solid = SOLID_NOT;
 133         e.takedamage = DAMAGE_NO;
 134
 135         setattachment(e, parent, s);
 136         e.owner = parent;
 137 }
 138
 139 void sandbox_ObjectAttach_Remove(entity e)
 140 {
 141         // detaches any object attached to e
 142
 143         entity head;
 144         for(head = world; (head = find(head, classname, "object")); )
 145         {
 146                 if(head.owner == e)
 147                 {
 148                         vector org;
 149                         org = gettaginfo(head, 0);
 150                         setattachment(head, world, "");
 151                         head.owner = world;
 152
 153                         // objects change origin and angles when detached, so apply previous position
 154                         setorigin(head, org);
 155                         head.angles = e.angles; // don't allow detached objects to spin or roll
 156
 157                         head.solid = head.old_solid; // restore persisted solidity
 158                         head.movetype = head.old_movetype; // restore persisted physics
 159                         head.takedamage = DAMAGE_AIM;
 160                 }
 161         }
 162 }
 163
 164 entity sandbox_ObjectSpawn(float database)
 165 {SELFPARAM();
 166         // spawn a new object with default properties
 167
 168         entity e = new(object);
 169         e.takedamage = DAMAGE_AIM;
 170         e.damageforcescale = 1;
 171         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
 172         e.movetype = MOVETYPE_TOSS;
 173         e.frame = 0;
 174         e.skin = 0;
 175         e.material = string_null;
 176         e.touch = sandbox_ObjectFunction_Touch;
 177         e.think = sandbox_ObjectFunction_Think;
 178         e.nextthink = time;
 179         //e.effects |= EF_SELECTABLE; // don't do this all the time, maybe just when editing objects?
 180
 181         if(!database)
 182         {
 183                 // set the object's owner via player UID
 184                 // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
 185                 if(self.crypto_idfp != "")
 186                         e.crypto_idfp = strzone(self.crypto_idfp);
 187                 else
 188                         print_to(self, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
 189
 190                 // set public object information
 191                 e.netname = strzone(self.netname); // name of the owner
 192                 e.message = strzone(strftime(true, "%d-%m-%Y %H:%M:%S")); // creation time
 193                 e.message2 = strzone(strftime(true, "%d-%m-%Y %H:%M:%S")); // last editing time
 194
 195                 // set origin and direction based on player position and view angle
 196                 makevectors(self.v_angle);
 197                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
 198                 setorigin(e, trace_endpos);
 199                 e.angles_y = self.v_angle.y;
 200         }
 201
 202         WITH(entity, self, e, CSQCMODEL_AUTOINIT(e));
 203
 204         object_count += 1;
 205         return e;
 206 }
 207
 208 void sandbox_ObjectRemove(entity e)
 209 {
 210         sandbox_ObjectAttach_Remove(e); // detach child objects
 211
 212         // if the object being removed has been selected for attachment by a player, unset it
 213         entity head;
 214         FOR_EACH_REALPLAYER(head) // bots can't have objects
 215         {
 216                 if(head.object_attach == e)
 217                         head.object_attach = world;
 218         }
 219
 220         if(e.material)  {       strunzone(e.material);  e.material = string_null;       }
 221         if(e.crypto_idfp)       {       strunzone(e.crypto_idfp);       e.crypto_idfp = string_null;    }
 222         if(e.netname)   {       strunzone(e.netname);   e.netname = string_null;        }
 223         if(e.message)   {       strunzone(e.message);   e.message = string_null;        }
 224         if(e.message2)  {       strunzone(e.message2);  e.message2 = string_null;       }
 225         remove(e);
 226         e = world;
 227
 228         object_count -= 1;
 229 }
 230
 231 string port_string[MAX_STORAGE_ATTACHMENTS]; // fteqcc crashes if this isn't defined as a global
 232
 233 string sandbox_ObjectPort_Save(entity e, float database)
 234 {
 235         // save object properties, and return them as a string
 236         float i = 0;
 237         string s;
 238         entity head;
 239
 240         for(head = world; (head = find(head, classname, "object")); )
 241         {
 242                 // the main object needs to be first in the array [0] with attached objects following
 243                 float slot, physics, solidity;
 244                 if(head == e) // this is the main object, place it first
 245                 {
 246                         slot = 0;
 247                         solidity = head.solid; // applied solidity is normal solidity for children
 248                         physics = head.movetype; // applied physics are normal physics for parents
 249                 }
 250                 else if(head.owner == e) // child object, list them in order
 251                 {
 252                         i += 1; // children start from 1
 253                         slot = i;
 254                         solidity = head.old_solid; // persisted solidity is normal solidity for children
 255                         physics = head.old_movetype; // persisted physics are normal physics for children
 256                         gettaginfo(head.owner, head.tag_index); // get the name of the tag our object is attached to, used further below
 257                 }
 258                 else
 259                         continue;
 260
 261                 // ---------------- OBJECT PROPERTY STORAGE: SAVE ----------------
 262                 if(slot)
 263                 {
 264                         // properties stored only for child objects
 265                         if(gettaginfo_name)     port_string[slot] = strcat(port_string[slot], "\"", gettaginfo_name, "\" ");    else    port_string[slot] = strcat(port_string[slot], "\"\" "); // none
 266                 }
 267                 else
 268                 {
 269                         // properties stored only for parent objects
 270                         if(database)
 271                         {
 272                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.origin), " ");
 273                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.angles), " ");
 274                         }
 275                 }
 276                 // properties stored for all objects
 277                 port_string[slot] = strcat(port_string[slot], "\"", head.model, "\" ");
 278                 port_string[slot] = strcat(port_string[slot], ftos(head.skin), " ");
 279                 port_string[slot] = strcat(port_string[slot], ftos(head.alpha), " ");
 280                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.colormod), " ");
 281                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.glowmod), " ");
 282                 port_string[slot] = strcat(port_string[slot], ftos(head.frame), " ");
 283                 port_string[slot] = strcat(port_string[slot], ftos(head.scale), " ");
 284                 port_string[slot] = strcat(port_string[slot], ftos(solidity), " ");
 285                 port_string[slot] = strcat(port_string[slot], ftos(physics), " ");
 286                 port_string[slot] = strcat(port_string[slot], ftos(head.damageforcescale), " ");
 287                 if(head.material)       port_string[slot] = strcat(port_string[slot], "\"", head.material, "\" ");      else    port_string[slot] = strcat(port_string[slot], "\"\" "); // none
 288                 if(database)
 289                 {
 290                         // properties stored only for the database
 291                         if(head.crypto_idfp)    port_string[slot] = strcat(port_string[slot], "\"", head.crypto_idfp, "\" ");   else    port_string[slot] = strcat(port_string[slot], "\"\" "); // none
 292                         port_string[slot] = strcat(port_string[slot], "\"", e.netname, "\" ");
 293                         port_string[slot] = strcat(port_string[slot], "\"", e.message, "\" ");
 294                         port_string[slot] = strcat(port_string[slot], "\"", e.message2, "\" ");
 295                 }
 296         }
 297
 298         // now apply the array to a simple string, with the ; symbol separating objects
 299         s = "";
 300         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 301         {
 302                 if(port_string[i])
 303                         s = strcat(s, port_string[i], "; ");
 304                 port_string[i] = string_null; // fully clear the string
 305         }
 306
 307         return s;
 308 }
 309
 310 entity sandbox_ObjectPort_Load(string s, float database)
 311 {
 312         // load object properties, and spawn a new object with them
 313         float n, i;
 314         entity e = world, parent = world;
 315
 316         // separate objects between the ; symbols
 317         n = tokenizebyseparator(s, "; ");
 318         for(i = 0; i < n; ++i)
 319                 port_string[i] = argv(i);
 320
 321         // now separate and apply the properties of each object
 322         for(i = 0; i < n; ++i)
 323         {
 324                 float argv_num;
 325                 string tagname = string_null;
 326                 argv_num = 0;
 327                 tokenize_console(port_string[i]);
 328                 e = sandbox_ObjectSpawn(database);
 329
 330                 // ---------------- OBJECT PROPERTY STORAGE: LOAD ----------------
 331                 if(i)
 332                 {
 333                         // properties stored only for child objects
 334                         if(argv(argv_num) != "")        tagname = argv(argv_num);       else tagname = string_null;     ++argv_num;
 335                 }
 336                 else
 337                 {
 338                         // properties stored only for parent objects
 339                         if(database)
 340                         {
 341                                 setorigin(e, stov(argv(argv_num)));     ++argv_num;
 342                                 e.angles = stov(argv(argv_num));        ++argv_num;
 343                         }
 344                         parent = e; // mark parent objects as such
 345                 }
 346                 // properties stored for all objects
 347                 _setmodel(e, argv(argv_num));   ++argv_num;
 348                 e.skin = stof(argv(argv_num));  ++argv_num;
 349                 e.alpha = stof(argv(argv_num)); ++argv_num;
 350                 e.colormod = stov(argv(argv_num));      ++argv_num;
 351                 e.glowmod = stov(argv(argv_num));       ++argv_num;
 352                 e.frame = stof(argv(argv_num)); ++argv_num;
 353                 sandbox_ObjectEdit_Scale(e, stof(argv(argv_num)));      ++argv_num;
 354                 e.solid = e.old_solid = stof(argv(argv_num));   ++argv_num;
 355                 e.movetype = e.old_movetype = stof(argv(argv_num));     ++argv_num;
 356                 e.damageforcescale = stof(argv(argv_num));      ++argv_num;
 357                 if(e.material)  strunzone(e.material);  if(argv(argv_num) != "")        e.material = strzone(argv(argv_num));   else    e.material = string_null;       ++argv_num;
 358                 if(database)
 359                 {
 360                         // properties stored only for the database
 361                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);       if(argv(argv_num) != "")        e.crypto_idfp = strzone(argv(argv_num));        else    e.crypto_idfp = string_null;    ++argv_num;
 362                         if(e.netname)   strunzone(e.netname);   e.netname = strzone(argv(argv_num));    ++argv_num;
 363                         if(e.message)   strunzone(e.message);   e.message = strzone(argv(argv_num));    ++argv_num;
 364                         if(e.message2)  strunzone(e.message2);  e.message2 = strzone(argv(argv_num));   ++argv_num;
 365                 }
 366
 367                 // attach last
 368                 if(i)
 369                         sandbox_ObjectAttach_Set(e, parent, tagname);
 370         }
 371
 372         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 373                 port_string[i] = string_null; // fully clear the string
 374
 375         return e;
 376 }
 377
 378 void sandbox_Database_Save()
 379 {
 380         // saves all objects to the database file
 381         entity head;
 382         string file_name;
 383         float file_get;
 384
 385         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 386         file_get = fopen(file_name, FILE_WRITE);
 387         fputs(file_get, strcat("// sandbox storage \"", autocvar_g_sandbox_storage_name, "\" for map \"", GetMapname(), "\" last updated ", strftime(true, "%d-%m-%Y %H:%M:%S")));
 388         fputs(file_get, strcat(" containing ", ftos(object_count), " objects\n"));
 389
 390         for(head = world; (head = find(head, classname, "object")); )
 391         {
 392                 // attached objects are persisted separately, ignore them here
 393                 if(head.owner != world)
 394                         continue;
 395
 396                 // use a line of text for each object, listing all properties
 397                 fputs(file_get, strcat(sandbox_ObjectPort_Save(head, true), "\n"));
 398         }
 399         fclose(file_get);
 400 }
 401
 402 void sandbox_Database_Load()
 403 {
 404         // loads all objects from the database file
 405         string file_read, file_name;
 406         float file_get, i;
 407
 408         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 409         file_get = fopen(file_name, FILE_READ);
 410         if(file_get < 0)
 411         {
 412                 if(autocvar_g_sandbox_info > 0)
 413                         LOG_INFO(strcat("^3SANDBOX - SERVER: ^7could not find storage file ^3", file_name, "^7, no objects were loaded\n"));
 414         }
 415         else
 416         {
 417                 for (;;)
 418                 {
 419                         file_read = fgets(file_get);
 420                         if(file_read == "")
 421                                 break;
 422                         if(substring(file_read, 0, 2) == "//")
 423                                 continue;
 424                         if(substring(file_read, 0, 1) == "#")
 425                                 continue;
 426
 427                         entity e;
 428                         e = sandbox_ObjectPort_Load(file_read, true);
 429
 430                         if(e.material)
 431                         {
 432                                 // since objects are being loaded for the first time, precache material sounds for each
 433                                 for (i = 1; i <= 5; i++) // 5 sounds in total
 434                                         precache_sound(strcat("object/impact_", e.material, "_", ftos(i), ".wav"));
 435                         }
 436                 }
 437                 if(autocvar_g_sandbox_info > 0)
 438                         LOG_INFO(strcat("^3SANDBOX - SERVER: ^7successfully loaded storage file ^3", file_name, "\n"));
 439         }
 440         fclose(file_get);
 441 }
 442
 443 MUTATOR_HOOKFUNCTION(sandbox, SV_ParseClientCommand)
 444 {SELFPARAM();
 445         if(MUTATOR_RETURNVALUE) // command was already handled?
 446                 return false;
 447         if(cmd_name == "g_sandbox")
 448         {
 449                 if(autocvar_g_sandbox_readonly)
 450                 {
 451                         print_to(self, "^2SANDBOX - INFO: ^7Sandbox mode is active, but in read-only mode. Sandbox commands cannot be used");
 452                         return true;
 453                 }
 454                 if(cmd_argc < 2)
 455                 {
 456                         print_to(self, "^2SANDBOX - INFO: ^7Sandbox mode is active. For usage information, type 'sandbox help'");
 457                         return true;
 458                 }
 459
 460                 switch(argv(1))
 461                 {
 462                         entity e;
 463                         float i;
 464                         string s;
 465
 466                         // ---------------- COMMAND: HELP ----------------
 467                         case "help":
 468                                 print_to(self, "You can use the following sandbox commands:");
 469                                 print_to(self, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
 470                                 print_to(self, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
 471                                 print_to(self, "^7\"^2object_duplicate ^3value^7\" duplicates the object, if the player has copying rights over the original");
 472                                 print_to(self, "^3copy value ^7- copies the properties of the object to the specified client cvar");
 473                                 print_to(self, "^3paste value ^7- spawns an object with the given properties. Properties or cvars must be specified as follows; eg1: \"0 1 2 ...\", eg2: \"$cl_cvar\"");
 474                                 print_to(self, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
 475                                 print_to(self, "^3get ^7- selects the object you are facing as the object to be attached");
 476                                 print_to(self, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
 477                                 print_to(self, "^3remove ^7- detaches all objects from the object you are facing");
 478                                 print_to(self, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
 479                                 print_to(self, "^3skin value ^7- changes the skin of the object");
 480                                 print_to(self, "^3alpha value ^7- sets object transparency");
 481                                 print_to(self, "^3colormod \"value_x value_y value_z\" ^7- main object color");
 482                                 print_to(self, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
 483                                 print_to(self, "^3frame value ^7- object animation frame, for self-animated models");
 484                                 print_to(self, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
 485                                 print_to(self, "^3solidity value ^7- object collisions, 0 = non-solid, 1 = solid");
 486                                 print_to(self, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
 487                                 print_to(self, "^3force value ^7- amount of force applied to objects that are shot");
 488                                 print_to(self, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
 489                                 print_to(self, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
 490                                 print_to(self, "^7\"^2object_info ^3value^7\" shows public information about the object");
 491                                 print_to(self, "^3object ^7- prints general information about the object, such as owner and creation / editing date");
 492                                 print_to(self, "^3mesh ^7- prints information about the object's mesh, including skeletal bones");
 493                                 print_to(self, "^3attachments ^7- prints information about the object's attachments");
 494                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
 495                                 return true;
 496
 497                         // ---------------- COMMAND: OBJECT, SPAWN ----------------
 498                         case "object_spawn":
 499                                 if(time < self.object_flood)
 500                                 {
 501                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Flood protection active. Please wait ^3", ftos(self.object_flood - time), " ^7seconds beofore spawning another object"));
 502                                         return true;
 503                                 }
 504                                 self.object_flood = time + autocvar_g_sandbox_editor_flood;
 505                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 506                                 {
 507                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 508                                         return true;
 509                                 }
 510                                 if(cmd_argc < 3)
 511                                 {
 512                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
 513                                         return true;
 514                                 }
 515                                 if (!(fexists(argv(2))))
 516                                 {
 517                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 518                                         return true;
 519                                 }
 520
 521                                 e = sandbox_ObjectSpawn(false);
 522                                 _setmodel(e, argv(2));
 523
 524                                 if(autocvar_g_sandbox_info > 0)
 525                                         LOG_INFO(strcat("^3SANDBOX - SERVER: ^7", self.netname, " spawned an object at origin ^3", vtos(e.origin), "\n"));
 526                                 return true;
 527
 528                         // ---------------- COMMAND: OBJECT, REMOVE ----------------
 529                         case "object_remove":
 530                                 e = sandbox_ObjectEdit_Get(true);
 531                                 if(e != world)
 532                                 {
 533                                         if(autocvar_g_sandbox_info > 0)
 534                                                 LOG_INFO(strcat("^3SANDBOX - SERVER: ^7", self.netname, " removed an object at origin ^3", vtos(e.origin), "\n"));
 535                                         sandbox_ObjectRemove(e);
 536                                         return true;
 537                                 }
 538
 539                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
 540                                 return true;
 541
 542                         // ---------------- COMMAND: OBJECT, DUPLICATE ----------------
 543                         case "object_duplicate":
 544                                 switch(argv(2))
 545                                 {
 546                                         case "copy":
 547                                                 // copies customizable properties of the selected object to the clipboard cvar
 548                                                 e = sandbox_ObjectEdit_Get(autocvar_g_sandbox_editor_free); // can we copy objects we can't edit?
 549                                                 if(e != world)
 550                                                 {
 551                                                         s = sandbox_ObjectPort_Save(e, false);
 552                                                         s = strreplace("\"", "\\\"", s);
 553                                                         stuffcmd(self, strcat("set ", argv(3), " \"", s, "\""));
 554
 555                                                         print_to(self, "^2SANDBOX - INFO: ^7Object copied to clipboard");
 556                                                         return true;
 557                                                 }
 558                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have copy rights over");
 559                                                 return true;
 560
 561                                         case "paste":
 562                                                 // spawns a new object using the properties in the player's clipboard cvar
 563                                                 if(time < self.object_flood)
 564                                                 {
 565                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Flood protection active. Please wait ^3", ftos(self.object_flood - time), " ^7seconds beofore spawning another object"));
 566                                                         return true;
 567                                                 }
 568                                                 self.object_flood = time + autocvar_g_sandbox_editor_flood;
 569                                                 if(argv(3) == "") // no object in clipboard
 570                                                 {
 571                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
 572                                                         return true;
 573                                                 }
 574                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 575                                                 {
 576                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 577                                                         return true;
 578                                                 }
 579                                                 e = sandbox_ObjectPort_Load(argv(3), false);
 580
 581                                                 print_to(self, "^2SANDBOX - INFO: ^7Object pasted successfully");
 582                                                 if(autocvar_g_sandbox_info > 0)
 583                                                         LOG_INFO(strcat("^3SANDBOX - SERVER: ^7", self.netname, " pasted an object at origin ^3", vtos(e.origin), "\n"));
 584                                                 return true;
 585                                 }
 586                                 return true;
 587
 588                         // ---------------- COMMAND: OBJECT, ATTACH ----------------
 589                         case "object_attach":
 590                                 switch(argv(2))
 591                                 {
 592                                         case "get":
 593                                                 // select e as the object as meant to be attached
 594                                                 e = sandbox_ObjectEdit_Get(true);
 595                                                 if(e != world)
 596                                                 {
 597                                                         self.object_attach = e;
 598                                                         print_to(self, "^2SANDBOX - INFO: ^7Object selected for attachment");
 599                                                         return true;
 600                                                 }
 601                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
 602                                                 return true;
 603                                         case "set":
 604                                                 if(self.object_attach == world)
 605                                                 {
 606                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
 607                                                         return true;
 608                                                 }
 609
 610                                                 // attaches the previously selected object to e
 611                                                 e = sandbox_ObjectEdit_Get(true);
 612                                                 if(e != world)
 613                                                 {
 614                                                         sandbox_ObjectAttach_Set(self.object_attach, e, argv(3));
 615                                                         self.object_attach = world; // object was attached, no longer keep it scheduled for attachment
 616                                                         print_to(self, "^2SANDBOX - INFO: ^7Object attached successfully");
 617                                                         if(autocvar_g_sandbox_info > 1)
 618                                                                 LOG_INFO(strcat("^3SANDBOX - SERVER: ^7", self.netname, " attached objects at origin ^3", vtos(e.origin), "\n"));
 619                                                         return true;
 620                                                 }
 621                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
 622                                                 return true;
 623                                         case "remove":
 624                                                 // removes e if it was attached
 625                                                 e = sandbox_ObjectEdit_Get(true);
 626                                                 if(e != world)
 627                                                 {
 628                                                         sandbox_ObjectAttach_Remove(e);
 629                                                         print_to(self, "^2SANDBOX - INFO: ^7Child objects detached successfully");
 630                                                         if(autocvar_g_sandbox_info > 1)
 631                                                                 LOG_INFO(strcat("^3SANDBOX - SERVER: ^7", self.netname, " detached objects at origin ^3", vtos(e.origin), "\n"));
 632                                                         return true;
 633                                                 }
 634                                                 print_to(self, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
 635                                                 return true;
 636                                 }
 637                                 return true;
 638
 639                         // ---------------- COMMAND: OBJECT, EDIT ----------------
 640                         case "object_edit":
 641                                 if(argv(2) == "")
 642                                 {
 643                                         print_to(self, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
 644                                         return true;
 645                                 }
 646
 647                                 e = sandbox_ObjectEdit_Get(true);
 648                                 if(e != world)
 649                                 {
 650                                         switch(argv(2))
 651                                         {
 652                                                 case "skin":
 653                                                         e.skin = stof(argv(3));
 654                                                         break;
 655                                                 case "alpha":
 656                                                         e.alpha = stof(argv(3));
 657                                                         break;
 658                                                 case "color_main":
 659                                                         e.colormod = stov(argv(3));
 660                                                         break;
 661                                                 case "color_glow":
 662                                                         e.glowmod = stov(argv(3));
 663                                                         break;
 664                                                 case "frame":
 665                                                         e.frame = stof(argv(3));
 666                                                         break;
 667                                                 case "scale":
 668                                                         sandbox_ObjectEdit_Scale(e, stof(argv(3)));
 669                                                         break;
 670                                                 case "solidity":
 671                                                         switch(argv(3))
 672                                                         {
 673                                                                 case "0": // non-solid
 674                                                                         e.solid = SOLID_TRIGGER;
 675                                                                         break;
 676                                                                 case "1": // solid
 677                                                                         e.solid = SOLID_BBOX;
 678                                                                         break;
 679                                                                 default:
 680                                                                         break;
 681                                                         }
 682                                                 case "physics":
 683                                                         switch(argv(3))
 684                                                         {
 685                                                                 case "0": // static
 686                                                                         e.movetype = MOVETYPE_NONE;
 687                                                                         break;
 688                                                                 case "1": // movable
 689                                                                         e.movetype = MOVETYPE_TOSS;
 690                                                                         break;
 691                                                                 case "2": // physical
 692                                                                         e.movetype = MOVETYPE_PHYSICS;
 693                                                                         break;
 694                                                                 default:
 695                                                                         break;
 696                                                         }
 697                                                         break;
 698                                                 case "force":
 699                                                         e.damageforcescale = stof(argv(3));
 700                                                         break;
 701                                                 case "material":
 702                                                         if(e.material)  strunzone(e.material);
 703                                                         if(argv(3))
 704                                                         {
 705                                                                 for (i = 1; i <= 5; i++) // precache material sounds, 5 in total
 706                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(i), ".wav"));
 707                                                                 e.material = strzone(argv(3));
 708                                                         }
 709                                                         else
 710                                                                 e.material = string_null; // no material
 711                                                         break;
 712                                                 default:
 713                                                         print_to(self, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
 714                                                         return true;
 715                                         }
 716
 717                                         // update last editing time
 718                                         if(e.message2)  strunzone(e.message2);
 719                                         e.message2 = strzone(strftime(true, "%d-%m-%Y %H:%M:%S"));
 720
 721                                         if(autocvar_g_sandbox_info > 1)
 722                                                 LOG_INFO(strcat("^3SANDBOX - SERVER: ^7", self.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin), "\n"));
 723                                         return true;
 724                                 }
 725
 726                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
 727                                 return true;
 728
 729                         // ---------------- COMMAND: OBJECT, CLAIM ----------------
 730                         case "object_claim":
 731                                 // if the player can edit an object but is not its owner, this can be used to claim that object
 732                                 if(self.crypto_idfp == "")
 733                                 {
 734                                         print_to(self, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
 735                                         return true;
 736                                 }
 737                                 e = sandbox_ObjectEdit_Get(true);
 738                                 if(e != world)
 739                                 {
 740                                         // update the owner's name
 741                                         // Do this before checking if you're already the owner and skipping if such, so we
 742                                         // also update the player's nickname if he changed it (but has the same player UID)
 743                                         if(e.netname != self.netname)
 744                                         {
 745                                                 if(e.netname)   strunzone(e.netname);
 746                                                 e.netname = strzone(self.netname);
 747                                                 print_to(self, "^2SANDBOX - INFO: ^7Object owner name updated");
 748                                         }
 749
 750                                         if(e.crypto_idfp == self.crypto_idfp)
 751                                         {
 752                                                 print_to(self, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
 753                                                 return true;
 754                                         }
 755
 756                                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);
 757                                         e.crypto_idfp = strzone(self.crypto_idfp);
 758
 759                                         print_to(self, "^2SANDBOX - INFO: ^7Object claimed successfully");
 760                                 }
 761                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
 762                                 return true;
 763
 764                         // ---------------- COMMAND: OBJECT, INFO ----------------
 765                         case "object_info":
 766                                 // prints public information about the object to the player
 767                                 e = sandbox_ObjectEdit_Get(false);
 768                                 if(e != world)
 769                                 {
 770                                         switch(argv(2))
 771                                         {
 772                                                 case "object":
 773                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object is owned by \"^7", e.netname, "^7\", created \"^3", e.message, "^7\", last edited \"^3", e.message2, "^7\""));
 774                                                         return true;
 775                                                 case "mesh":
 776                                                         s = "";
 777                                                         FOR_EACH_TAG(e)
 778                                                                 s = strcat(s, "^7\"^5", gettaginfo_name, "^7\", ");
 779                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object mesh is \"^3", e.model, "^7\" at animation frame ^3", ftos(e.frame), " ^7containing the following tags: ", s));
 780                                                         return true;
 781                                                 case "attachments":
 782                                                         // this should show the same info as 'mesh' but for attachments
 783                                                         s = "";
 784                                                         entity head;
 785                                                         i = 0;
 786                                                         for(head = world; (head = find(head, classname, "object")); )
 787                                                         {
 788                                                                 if(head.owner == e)
 789                                                                 {
 790                                                                         ++i; // start from 1
 791                                                                         gettaginfo(e, head.tag_index);
 792                                                                         s = strcat(s, "^1attachment ", ftos(i), "^7 has mesh \"^3", head.model, "^7\" at animation frame ^3", ftos(head.frame));
 793                                                                         s = strcat(s, "^7 and is attached to bone \"^5", gettaginfo_name, "^7\", ");
 794                                                                 }
 795                                                         }
 796                                                         if(i) // object contains attachments
 797                                                                 print_to(self, strcat("^2SANDBOX - INFO: ^7Object contains the following ^1", ftos(i), "^7 attachment(s): ", s));
 798                                                         else
 799                                                                 print_to(self, "^2SANDBOX - INFO: ^7Object contains no attachments");
 800                                                         return true;
 801                                         }
 802                                 }
 803                                 print_to(self, "^1SANDBOX - WARNING: ^7No information could be found. Make sure you are facing an object");
 804                                 return true;
 805
 806                         // ---------------- COMMAND: DEFAULT ----------------
 807                         default:
 808                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
 809                                 return true;
 810                 }
 811         }
 812         return false;
 813 }
 814
 815 MUTATOR_HOOKFUNCTION(sandbox, SV_StartFrame)
 816 {
 817         if(!autocvar_g_sandbox_storage_autosave)
 818                 return false;
 819         if(time < autosave_time)
 820                 return false;
 821         autosave_time = time + autocvar_g_sandbox_storage_autosave;
 822
 823         sandbox_Database_Save();
 824
 825         return true;
 826 }
 827 #endif