qcsrc/server/mutators/mutator_nades.qc

   1 .entity nade_spawnloc;
   2
   3 void nade_timer_think()
   4 {
   5         self.skin = 8 - (self.owner.wait - time) / (autocvar_g_nades_nade_lifetime / 10);
   6         self.nextthink = time;
   7         if(!self.owner || wasfreed(self.owner))
   8                 remove(self);
   9 }
  10
  11 void nade_burn_spawn(entity _nade)
  12 {
  13         CSQCProjectile(_nade, TRUE, Nade_ProjectileFromID(_nade.nade_type, TRUE), TRUE);
  14 }
  15
  16 void nade_spawn(entity _nade)
  17 {
  18         entity timer = spawn();
  19         setmodel(timer, "models/ok_nade_counter/ok_nade_counter.md3");
  20         setattachment(timer, _nade, "");
  21         timer.classname = "nade_timer";
  22         timer.colormap = _nade.colormap;
  23         timer.glowmod = _nade.glowmod;
  24         timer.think = nade_timer_think;
  25         timer.nextthink = time;
  26         timer.wait = _nade.wait;
  27         timer.owner = _nade;
  28         timer.skin = 10;
  29
  30         _nade.effects |= EF_LOWPRECISION;
  31
  32         CSQCProjectile(_nade, TRUE, Nade_ProjectileFromID(_nade.nade_type, FALSE), TRUE);
  33 }
  34
  35 void napalm_damage(float dist, float damage, float edgedamage, float burntime)
  36 {
  37         entity e;
  38         float d;
  39         vector p;
  40
  41         if ( damage < 0 )
  42                 return;
  43
  44         RandomSelection_Init();
  45         for(e = WarpZone_FindRadius(self.origin, dist, TRUE); e; e = e.chain)
  46                 if(e.takedamage == DAMAGE_AIM)
  47                 if(self.realowner != e || autocvar_g_nades_napalm_selfdamage)
  48                 if(!IS_PLAYER(e) || !self.realowner || DIFF_TEAM(e, self))
  49                 if(!e.frozen)
  50                 {
  51                         p = e.origin;
  52                         p_x += e.mins_x + random() * (e.maxs_x - e.mins_x);
  53                         p_y += e.mins_y + random() * (e.maxs_y - e.mins_y);
  54                         p_z += e.mins_z + random() * (e.maxs_z - e.mins_z);
  55                         d = vlen(WarpZone_UnTransformOrigin(e, self.origin) - p);
  56                         if(d < dist)
  57                         {
  58                                 e.fireball_impactvec = p;
  59                                 RandomSelection_Add(e, 0, string_null, 1 / (1 + d), !Fire_IsBurning(e));
  60                         }
  61                 }
  62         if(RandomSelection_chosen_ent)
  63         {
  64                 d = vlen(WarpZone_UnTransformOrigin(RandomSelection_chosen_ent, self.origin) - RandomSelection_chosen_ent.fireball_impactvec);
  65                 d = damage + (edgedamage - damage) * (d / dist);
  66                 Fire_AddDamage(RandomSelection_chosen_ent, self.realowner, d * burntime, burntime, self.projectiledeathtype | HITTYPE_BOUNCE);
  67                 //trailparticles(self, particleeffectnum("fireball_laser"), self.origin, RandomSelection_chosen_ent.fireball_impactvec);
  68                 pointparticles(particleeffectnum("fireball_laser"), self.origin, RandomSelection_chosen_ent.fireball_impactvec - self.origin, 1);
  69         }
  70 }
  71
  72
  73 void napalm_ball_think()
  74 {
  75         if(round_handler_IsActive())
  76         if(!round_handler_IsRoundStarted())
  77         {
  78                 remove(self);
  79                 return;
  80         }
  81
  82         if(time > self.pushltime)
  83         {
  84                 remove(self);
  85                 return;
  86         }
  87
  88         vector midpoint = ((self.absmin + self.absmax) * 0.5);
  89         if(pointcontents(midpoint) == CONTENT_WATER)
  90         {
  91                 self.velocity = self.velocity * 0.5;
  92
  93                 if(pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
  94                         { self.velocity_z = 200; }
  95         }
  96
  97         self.angles = vectoangles(self.velocity);
  98
  99         napalm_damage(autocvar_g_nades_napalm_ball_radius,autocvar_g_nades_napalm_ball_damage,
 100                                   autocvar_g_nades_napalm_ball_damage,autocvar_g_nades_napalm_burntime);
 101
 102         self.nextthink = time + 0.1;
 103 }
 104
 105
 106 void nade_napalm_ball()
 107 {
 108         entity proj;
 109         vector kick;
 110
 111         spamsound(self, CH_SHOTS, "weapons/fireball_fire.wav", VOL_BASE, ATTEN_NORM);
 112
 113         proj = spawn ();
 114         proj.owner = self.owner;
 115         proj.realowner = self.realowner;
 116         proj.team = self.owner.team;
 117         proj.classname = "grenade";
 118         proj.bot_dodge = TRUE;
 119         proj.bot_dodgerating = autocvar_g_nades_napalm_ball_damage;
 120         proj.movetype = MOVETYPE_BOUNCE;
 121         proj.projectiledeathtype = DEATH_NADE_NAPALM;
 122         PROJECTILE_MAKETRIGGER(proj);
 123         setmodel(proj, "null");
 124         proj.scale = 1;//0.5;
 125         setsize(proj, '-4 -4 -4', '4 4 4');
 126         setorigin(proj, self.origin);
 127         proj.think = napalm_ball_think;
 128         proj.nextthink = time;
 129         proj.damageforcescale = autocvar_g_nades_napalm_ball_damageforcescale;
 130         proj.effects = EF_LOWPRECISION | EF_FLAME;
 131
 132         kick_x =(random() - 0.5) * 2 * autocvar_g_nades_napalm_ball_spread;
 133         kick_y = (random() - 0.5) * 2 * autocvar_g_nades_napalm_ball_spread;
 134         kick_z = (random()/2+0.5) * autocvar_g_nades_napalm_ball_spread;
 135         proj.velocity = kick;
 136
 137         proj.pushltime = time + autocvar_g_nades_napalm_ball_lifetime;
 138
 139         proj.angles = vectoangles(proj.velocity);
 140         proj.flags = FL_PROJECTILE;
 141         proj.missile_flags = MIF_SPLASH | MIF_PROXY | MIF_ARC;
 142
 143         //CSQCProjectile(proj, TRUE, PROJECTILE_NAPALM_FIRE, TRUE);
 144 }
 145
 146
 147 void napalm_fountain_think()
 148 {
 149
 150         if(round_handler_IsActive())
 151         if(!round_handler_IsRoundStarted())
 152         {
 153                 remove(self);
 154                 return;
 155         }
 156
 157         if(time >= self.ltime)
 158         {
 159                 remove(self);
 160                 return;
 161         }
 162
 163         vector midpoint = ((self.absmin + self.absmax) * 0.5);
 164         if(pointcontents(midpoint) == CONTENT_WATER)
 165         {
 166                 self.velocity = self.velocity * 0.5;
 167
 168                 if(pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
 169                         { self.velocity_z = 200; }
 170
 171                 UpdateCSQCProjectile(self);
 172         }
 173
 174         napalm_damage(autocvar_g_nades_napalm_fountain_radius, autocvar_g_nades_napalm_fountain_damage,
 175                 autocvar_g_nades_napalm_fountain_edgedamage, autocvar_g_nades_napalm_burntime);
 176
 177         self.nextthink = time + 0.1;
 178         if(time >= self.nade_special_time)
 179         {
 180                 self.nade_special_time = time + autocvar_g_nades_napalm_fountain_delay;
 181                 nade_napalm_ball();
 182         }
 183 }
 184
 185 void nade_napalm_boom()
 186 {
 187         entity fountain;
 188         local float c;
 189         for (c = 0; c < autocvar_g_nades_napalm_ball_count; c ++)
 190                 nade_napalm_ball();
 191
 192
 193         fountain = spawn();
 194         fountain.owner = self.owner;
 195         fountain.realowner = self.realowner;
 196         fountain.origin = self.origin;
 197         setorigin(fountain, fountain.origin);
 198         fountain.think = napalm_fountain_think;
 199         fountain.nextthink = time;
 200         fountain.ltime = time + autocvar_g_nades_napalm_fountain_lifetime;
 201         fountain.pushltime = fountain.ltime;
 202         fountain.team = self.team;
 203         fountain.movetype = MOVETYPE_TOSS;
 204         fountain.projectiledeathtype = DEATH_NADE_NAPALM;
 205         fountain.bot_dodge = TRUE;
 206         fountain.bot_dodgerating = autocvar_g_nades_napalm_fountain_damage;
 207         fountain.nade_special_time = time;
 208         setsize(fountain, '-16 -16 -16', '16 16 16');
 209         CSQCProjectile(fountain, TRUE, PROJECTILE_NAPALM_FOUNTAIN, TRUE);
 210 }
 211
 212 void nade_ice_freeze(entity freezefield, entity frost_target, float freeze_time)
 213 {
 214         frost_target.frozen_by = freezefield.realowner;
 215         pointparticles(particleeffectnum("electro_impact"), frost_target.origin, '0 0 0', 1);
 216         Freeze(frost_target, 1/freeze_time, 3, FALSE);
 217         if(frost_target.ballcarried)
 218         if(g_keepaway) { ka_DropEvent(frost_target); }
 219         else { DropBall(frost_target.ballcarried, frost_target.origin, frost_target.velocity);}
 220         if(frost_target.flagcarried) { ctf_Handle_Throw(frost_target, world, DROP_THROW); }
 221         if(frost_target.nade) { toss_nade(frost_target, '0 0 0', time + 0.05); }
 222
 223         kh_Key_DropAll(frost_target, FALSE);
 224 }
 225
 226 void nade_ice_think()
 227 {
 228
 229         if(round_handler_IsActive())
 230         if(!round_handler_IsRoundStarted())
 231         {
 232                 remove(self);
 233                 return;
 234         }
 235
 236         if(time >= self.ltime)
 237         {
 238                 if ( autocvar_g_nades_ice_explode )
 239                 {
 240                         string expef;
 241                         switch(self.realowner.team)
 242                         {
 243                                 case NUM_TEAM_1: expef = "nade_red_explode"; break;
 244                                 case NUM_TEAM_2: expef = "nade_blue_explode"; break;
 245                                 case NUM_TEAM_3: expef = "nade_yellow_explode"; break;
 246                                 case NUM_TEAM_4: expef = "nade_pink_explode"; break;
 247                                 default:                 expef = "nade_neutral_explode"; break;
 248                         }
 249                         pointparticles(particleeffectnum(expef), self.origin + '0 0 1', '0 0 0', 1);
 250                         sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
 251
 252                         RadiusDamage(self, self.realowner, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 253                                 autocvar_g_nades_nade_radius, self, world, autocvar_g_nades_nade_force, self.projectiledeathtype, self.enemy);
 254                         Damage_DamageInfo(self.origin, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 255                                 autocvar_g_nades_nade_radius, '1 1 1' * autocvar_g_nades_nade_force, self.projectiledeathtype, 0, self);
 256                 }
 257                 remove(self);
 258                 return;
 259         }
 260
 261
 262         self.nextthink = time+0.1;
 263
 264         // gaussian
 265         float randomr;
 266         randomr = random();
 267         randomr = exp(-5*randomr*randomr)*autocvar_g_nades_nade_radius;
 268         float randomw;
 269         randomw = random()*M_PI*2;
 270         vector randomp;
 271         randomp_x = randomr*cos(randomw);
 272         randomp_y = randomr*sin(randomw);
 273         randomp_z = 1;
 274         pointparticles(particleeffectnum("electro_muzzleflash"), self.origin + randomp, '0 0 0', 1);
 275
 276         if(time >= self.nade_special_time)
 277         {
 278                 self.nade_special_time = time+0.7;
 279
 280
 281                 pointparticles(particleeffectnum("electro_impact"), self.origin, '0 0 0', 1);
 282                 pointparticles(particleeffectnum("icefield"), self.origin, '0 0 0', 1);
 283         }
 284
 285
 286         float current_freeze_time = self.ltime - time - 0.1;
 287
 288         entity e;
 289         for(e = findradius(self.origin, autocvar_g_nades_nade_radius); e; e = e.chain)
 290         if(e != self)
 291         if(!autocvar_g_nades_ice_teamcheck || (DIFF_TEAM(e, self.realowner) || e == self.realowner))
 292         if(e.takedamage && e.deadflag == DEAD_NO)
 293         if(e.health > 0)
 294         if(!e.revival_time || ((time - e.revival_time) >= 1.5))
 295         if(!e.frozen)
 296         if(current_freeze_time > 0)
 297                 nade_ice_freeze(self, e, current_freeze_time);
 298 }
 299
 300 void nade_ice_boom()
 301 {
 302         entity fountain;
 303         fountain = spawn();
 304         fountain.owner = self.owner;
 305         fountain.realowner = self.realowner;
 306         fountain.origin = self.origin;
 307         setorigin(fountain, fountain.origin);
 308         fountain.think = nade_ice_think;
 309         fountain.nextthink = time;
 310         fountain.ltime = time + autocvar_g_nades_ice_freeze_time;
 311         fountain.pushltime = fountain.wait = fountain.ltime;
 312         fountain.team = self.team;
 313         fountain.movetype = MOVETYPE_TOSS;
 314         fountain.projectiledeathtype = DEATH_NADE_ICE;
 315         fountain.bot_dodge = FALSE;
 316         setsize(fountain, '-16 -16 -16', '16 16 16');
 317         fountain.nade_special_time = time+0.3;
 318         fountain.angles = self.angles;
 319
 320         if ( autocvar_g_nades_ice_explode )
 321         {
 322                 setmodel(fountain, "models/grenademodel.md3");
 323                 entity timer = spawn();
 324                 setmodel(timer, "models/ok_nade_counter/ok_nade_counter.md3");
 325                 setattachment(timer, fountain, "");
 326                 timer.classname = "nade_timer";
 327                 timer.colormap = self.colormap;
 328                 timer.glowmod = self.glowmod;
 329                 timer.think = nade_timer_think;
 330                 timer.nextthink = time;
 331                 timer.wait = fountain.ltime;
 332                 timer.owner = fountain;
 333                 timer.skin = 10;
 334         }
 335         else
 336                 setmodel(fountain, "null");
 337 }
 338
 339 void nade_translocate_boom()
 340 {
 341         if(self.realowner.vehicle)
 342                 return;
 343
 344         vector locout = self.origin + '0 0 1' * (1 - self.realowner.mins_z - 24);
 345         tracebox(locout, self.realowner.mins, self.realowner.maxs, locout, MOVE_NOMONSTERS, self.realowner);
 346         locout = trace_endpos;
 347
 348         makevectors(self.realowner.angles);
 349
 350         entity oldself = self;
 351         self = self.realowner;
 352         MUTATOR_CALLHOOK(PortalTeleport);
 353         self.realowner = self;
 354         self = oldself;
 355
 356         TeleportPlayer(self, self.realowner, locout, self.realowner.mangle, v_forward * vlen(self.realowner.velocity), '0 0 0', '0 0 0', TELEPORT_FLAGS_TELEPORTER);
 357 }
 358
 359 void nade_spawn_boom()
 360 {
 361         entity spawnloc = spawn();
 362         setorigin(spawnloc, self.origin);
 363         setsize(spawnloc, self.realowner.mins, self.realowner.maxs);
 364         spawnloc.movetype = MOVETYPE_NONE;
 365         spawnloc.solid = SOLID_NOT;
 366         spawnloc.drawonlytoclient = self.realowner;
 367         spawnloc.effects = EF_STARDUST;
 368         spawnloc.cnt = autocvar_g_nades_spawn_count;
 369
 370         if(self.realowner.nade_spawnloc)
 371         {
 372                 remove(self.realowner.nade_spawnloc);
 373                 self.realowner.nade_spawnloc = world;
 374         }
 375
 376         self.realowner.nade_spawnloc = spawnloc;
 377 }
 378
 379 void nade_heal_think()
 380 {
 381         if(time >= self.ltime)
 382         {
 383                 remove(self);
 384                 return;
 385         }
 386
 387         self.nextthink = time;
 388
 389         if(time >= self.nade_special_time)
 390         {
 391                 self.nade_special_time = time+0.25;
 392                 self.nade_show_particles = 1;
 393         }
 394         else
 395                 self.nade_show_particles = 0;
 396 }
 397
 398 void nade_heal_touch()
 399 {
 400         float maxhealth;
 401         float health_factor;
 402         if(IS_PLAYER(other) || (other.flags & FL_MONSTER))
 403         if(other.deadflag == DEAD_NO)
 404         if(!other.frozen)
 405         {
 406                 health_factor = autocvar_g_nades_heal_rate*frametime/2;
 407                 if ( other != self.realowner )
 408                 {
 409                         if ( SAME_TEAM(other,self) )
 410                                 health_factor *= autocvar_g_nades_heal_friend;
 411                         else
 412                                 health_factor *= autocvar_g_nades_heal_foe;
 413                 }
 414                 if ( health_factor > 0 )
 415                 {
 416                         maxhealth = (other.flags & FL_MONSTER) ? other.max_health : g_pickup_healthmega_max;
 417                         if ( other.health < maxhealth )
 418                         {
 419                                 if ( self.nade_show_particles )
 420                                         pointparticles(particleeffectnum("healing_fx"), other.origin, '0 0 0', 1);
 421                                 other.health = min(other.health+health_factor, maxhealth);
 422                         }
 423                         other.pauserothealth_finished = max(other.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 424                 }
 425                 else if ( health_factor < 0 )
 426                 {
 427                         Damage(other,self,self.realowner,-health_factor,DEATH_NADE_HEAL,other.origin,'0 0 0');
 428                 }
 429
 430         }
 431
 432         if ( IS_REAL_CLIENT(other) || (other.vehicle_flags & VHF_ISVEHICLE) )
 433         {
 434                 entity show_red = (other.vehicle_flags & VHF_ISVEHICLE) ? other.owner : other;
 435                 show_red.stat_healing_orb = time+0.1;
 436                 show_red.stat_healing_orb_alpha = 0.75 * (self.ltime - time) / self.healer_lifetime;
 437         }
 438 }
 439
 440 void nade_heal_boom()
 441 {
 442         entity healer;
 443         healer = spawn();
 444         healer.owner = self.owner;
 445         healer.realowner = self.realowner;
 446         setorigin(healer, self.origin);
 447         healer.healer_lifetime = autocvar_g_nades_heal_time; // save the cvar
 448         healer.ltime = time + healer.healer_lifetime;
 449         healer.team = self.realowner.team;
 450         healer.bot_dodge = FALSE;
 451         healer.solid = SOLID_TRIGGER;
 452         healer.touch = nade_heal_touch;
 453
 454         setmodel(healer, "models/ctf/shield.md3");
 455         healer.healer_radius = autocvar_g_nades_nade_radius;
 456         vector size = '1 1 1' * healer.healer_radius / 2;
 457         setsize(healer,-size,size);
 458
 459         Net_LinkEntity(healer, TRUE, 0, healer_send);
 460
 461         healer.think = nade_heal_think;
 462         healer.nextthink = time;
 463         healer.SendFlags |= 1;
 464 }
 465
 466 void nade_monster_boom()
 467 {
 468         entity e = spawnmonster(self.pokenade_type, 0, self.realowner, self.realowner, self.origin, FALSE, FALSE, 1);
 469
 470         if(autocvar_g_nades_pokenade_monster_lifetime > 0)
 471                 e.monster_lifetime = time + autocvar_g_nades_pokenade_monster_lifetime;
 472         e.monster_skill = MONSTER_SKILL_INSANE;
 473 }
 474
 475 void nade_boom()
 476 {
 477         string expef;
 478         float nade_blast = 1;
 479
 480         switch ( self.nade_type )
 481         {
 482                 case NADE_TYPE_NAPALM:
 483                         nade_blast = autocvar_g_nades_napalm_blast;
 484                         expef = "explosion_medium";
 485                         break;
 486                 case NADE_TYPE_ICE:
 487                         nade_blast = 0;
 488                         expef = "electro_combo"; // hookbomb_explode electro_combo bigplasma_impact
 489                         break;
 490                 case NADE_TYPE_TRANSLOCATE:
 491                         nade_blast = 0;
 492                         expef = "";
 493                         break;
 494                 case NADE_TYPE_MONSTER:
 495                 case NADE_TYPE_SPAWN:
 496                         nade_blast = 0;
 497                         switch(self.realowner.team)
 498                         {
 499                                 case NUM_TEAM_1: expef = "spawn_event_red"; break;
 500                                 case NUM_TEAM_2: expef = "spawn_event_blue"; break;
 501                                 case NUM_TEAM_3: expef = "spawn_event_yellow"; break;
 502                                 case NUM_TEAM_4: expef = "spawn_event_pink"; break;
 503                                 default: expef = "spawn_event_neutral"; break;
 504                         }
 505                         break;
 506                 case NADE_TYPE_HEAL:
 507                         nade_blast = 0;
 508                         expef = "spawn_event_red";
 509                         break;
 510
 511                 default:
 512                 case NADE_TYPE_NORMAL:
 513                         switch(self.realowner.team)
 514                         {
 515                                 case NUM_TEAM_1: expef = "nade_red_explode"; break;
 516                                 case NUM_TEAM_2: expef = "nade_blue_explode"; break;
 517                                 case NUM_TEAM_3: expef = "nade_yellow_explode"; break;
 518                                 case NUM_TEAM_4: expef = "nade_pink_explode"; break;
 519                                 default:                 expef = "nade_neutral_explode"; break;
 520                         }
 521         }
 522
 523         if(expef != "")
 524                 pointparticles(particleeffectnum(expef), findbetterlocation(self.origin, 8), '0 0 0', 1);
 525
 526         sound(self, CH_SHOTS_SINGLE, "misc/null.wav", VOL_BASE, ATTEN_NORM);
 527         sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
 528
 529         self.event_damage = func_null; // prevent somehow calling damage in the next call
 530
 531         if(nade_blast)
 532         {
 533                 RadiusDamage(self, self.realowner, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 534                                  autocvar_g_nades_nade_radius, self, world, autocvar_g_nades_nade_force, self.projectiledeathtype, self.enemy);
 535                 Damage_DamageInfo(self.origin, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage, autocvar_g_nades_nade_radius, '1 1 1' * autocvar_g_nades_nade_force, self.projectiledeathtype, 0, self);
 536         }
 537
 538         if(self.takedamage)
 539         switch ( self.nade_type )
 540         {
 541                 case NADE_TYPE_NAPALM: nade_napalm_boom(); break;
 542                 case NADE_TYPE_ICE: nade_ice_boom(); break;
 543                 case NADE_TYPE_TRANSLOCATE: nade_translocate_boom(); break;
 544                 case NADE_TYPE_SPAWN: nade_spawn_boom(); break;
 545                 case NADE_TYPE_HEAL: nade_heal_boom(); break;
 546                 case NADE_TYPE_MONSTER: nade_monster_boom(); break;
 547         }
 548
 549         remove(self);
 550 }
 551
 552 void nade_touch()
 553 {
 554         float is_weapclip = 0;
 555         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
 556         if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
 557         if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
 558                 is_weapclip = 1;
 559         if(ITEM_TOUCH_NEEDKILL() || is_weapclip)
 560         {
 561                 remove(self);
 562                 return;
 563         }
 564
 565         PROJECTILE_TOUCH;
 566
 567         //setsize(self, '-2 -2 -2', '2 2 2');
 568         //UpdateCSQCProjectile(self);
 569         if(self.health == self.max_health)
 570         {
 571                 spamsound(self, CH_SHOTS, strcat("weapons/grenade_bounce", ftos(1 + rint(random() * 5)), ".wav"), VOL_BASE, ATTEN_NORM);
 572                 return;
 573         }
 574
 575         self.enemy = other;
 576         nade_boom();
 577 }
 578
 579 void nade_beep()
 580 {
 581         sound(self, CH_SHOTS_SINGLE, "overkill/grenadebip.ogg", VOL_BASE, 0.5 *(ATTEN_LARGE + ATTEN_MAX));
 582         self.think = nade_boom;
 583         self.nextthink = max(self.wait, time);
 584 }
 585
 586 void nade_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 587 {
 588         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 589         {
 590                 self.takedamage = DAMAGE_NO;
 591                 nade_boom();
 592                 return;
 593         }
 594
 595         if(self.nade_type == NADE_TYPE_TRANSLOCATE || self.nade_type == NADE_TYPE_SPAWN)
 596                 return;
 597
 598         if(DEATH_ISWEAPON(deathtype, WEP_BLASTER) || (DEATH_ISWEAPON(deathtype, WEP_VAPORIZER) && (deathtype & HITTYPE_SECONDARY)))
 599         {
 600                 force *= 1.5;
 601                 damage = 0;
 602         }
 603
 604         if(DEATH_ISWEAPON(deathtype, WEP_VORTEX) || DEATH_ISWEAPON(deathtype, WEP_VAPORIZER))
 605         {
 606                 force *= 6;
 607                 damage = self.max_health * 0.55;
 608         }
 609
 610         if(DEATH_ISWEAPON(deathtype, WEP_MACHINEGUN) || DEATH_ISWEAPON(deathtype, WEP_HMG))
 611                 damage = self.max_health * 0.1;
 612
 613         if(DEATH_ISWEAPON(deathtype, WEP_SHOCKWAVE) || DEATH_ISWEAPON(deathtype, WEP_SHOTGUN)) // WEAPONTODO
 614         if(deathtype & HITTYPE_SECONDARY)
 615         {
 616                 damage = self.max_health * 0.1;
 617                 force *= 10;
 618         }
 619         else
 620                 damage = self.max_health * 1.15;
 621
 622         self.velocity += force;
 623         UpdateCSQCProjectile(self);
 624
 625         if(damage <= 0 || ((self.flags & FL_ONGROUND) && IS_PLAYER(attacker)))
 626                 return;
 627
 628         if(self.health == self.max_health)
 629         {
 630                 sound(self, CH_SHOTS_SINGLE, "misc/null.wav", VOL_BASE, 0.5 *(ATTEN_LARGE + ATTEN_MAX));
 631                 self.nextthink = max(time + autocvar_g_nades_nade_lifetime, time);
 632                 self.think = nade_beep;
 633         }
 634
 635         self.health -= damage;
 636
 637         if ( self.nade_type != NADE_TYPE_HEAL || IS_PLAYER(attacker) )
 638                 self.realowner = attacker;
 639
 640         if(self.health <= 0)
 641                 W_PrepareExplosionByDamage(attacker, nade_boom);
 642         else
 643                 nade_burn_spawn(self);
 644 }
 645
 646 void toss_nade(entity e, vector _velocity, float _time)
 647 {
 648         if(e.nade == world)
 649                 return;
 650
 651         entity _nade = e.nade;
 652         e.nade = world;
 653
 654         remove(e.fake_nade);
 655         e.fake_nade = world;
 656
 657         makevectors(e.v_angle);
 658
 659         W_SetupShot(e, FALSE, FALSE, "", CH_WEAPON_A, 0);
 660
 661         Kill_Notification(NOTIF_ONE_ONLY, e, MSG_CENTER_CPID, CPID_NADES);
 662
 663         setorigin(_nade, w_shotorg + (v_right * 25) * -1);
 664         //setmodel(_nade, "models/weapons/v_ok_grenade.md3");
 665         //setattachment(_nade, world, "");
 666         PROJECTILE_MAKETRIGGER(_nade);
 667         setsize(_nade, '-16 -16 -16', '16 16 16');
 668         _nade.movetype = MOVETYPE_BOUNCE;
 669
 670         tracebox(_nade.origin, _nade.mins, _nade.maxs, _nade.origin, FALSE, _nade);
 671         if (trace_startsolid)
 672                 setorigin(_nade, e.origin);
 673
 674         if(self.v_angle_x >= 70 && self.v_angle_x <= 110)
 675                 _nade.velocity = '0 0 100';
 676         else if(autocvar_g_nades_nade_newton_style == 1)
 677                 _nade.velocity = e.velocity + _velocity;
 678         else if(autocvar_g_nades_nade_newton_style == 2)
 679                 _nade.velocity = _velocity;
 680         else
 681                 _nade.velocity = W_CalculateProjectileVelocity(e.velocity, _velocity, TRUE);
 682
 683         _nade.touch = nade_touch;
 684         _nade.health = autocvar_g_nades_nade_health;
 685         _nade.max_health = _nade.health;
 686         _nade.takedamage = DAMAGE_AIM;
 687         _nade.event_damage = nade_damage;
 688         _nade.customizeentityforclient = func_null;
 689         _nade.exteriormodeltoclient = world;
 690         _nade.traileffectnum = 0;
 691         _nade.teleportable = TRUE;
 692         _nade.pushable = TRUE;
 693         _nade.gravity = 1;
 694         _nade.missile_flags = MIF_SPLASH | MIF_ARC;
 695         _nade.damagedbycontents = TRUE;
 696         _nade.angles = vectoangles(_nade.velocity);
 697         _nade.flags = FL_PROJECTILE;
 698         _nade.projectiledeathtype = DEATH_NADE;
 699         _nade.toss_time = time;
 700         _nade.solid = SOLID_CORPSE; //((_nade.nade_type == NADE_TYPE_TRANSLOCATE) ? SOLID_CORPSE : SOLID_BBOX);
 701
 702         if(_nade.nade_type == NADE_TYPE_TRANSLOCATE || _nade.nade_type == NADE_TYPE_SPAWN)
 703                 _nade.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 704         else
 705                 _nade.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 706
 707         nade_spawn(_nade);
 708
 709         if(_time)
 710         {
 711                 _nade.think = nade_boom;
 712                 _nade.nextthink = _time;
 713         }
 714
 715         e.nade_refire = time + autocvar_g_nades_nade_refire;
 716         e.nade_timer = 0;
 717 }
 718
 719 void nades_GiveBonus(entity player, float score)
 720 {
 721         if (autocvar_g_nades)
 722         if (autocvar_g_nades_bonus)
 723         if (IS_REAL_CLIENT(player))
 724         if (IS_PLAYER(player) && player.bonus_nades < autocvar_g_nades_bonus_max)
 725         if (player.frozen == 0)
 726         if (player.deadflag == DEAD_NO)
 727         {
 728                 if ( player.bonus_nade_score < 1 )
 729                         player.bonus_nade_score += score/autocvar_g_nades_bonus_score_max;
 730
 731                 if ( player.bonus_nade_score >= 1 )
 732                 {
 733                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_NADE_BONUS);
 734                         play2(player,"kh/alarm.wav");
 735                         player.bonus_nades++;
 736                         player.bonus_nade_score -= 1;
 737                 }
 738         }
 739 }
 740
 741 void nades_RemoveBonus(entity player)
 742 {
 743         player.bonus_nades = player.bonus_nade_score = 0;
 744 }
 745
 746 float nade_customize()
 747 {
 748         //if(IS_SPEC(other)) { return FALSE; }
 749         if(other == self.realowner || (IS_SPEC(other) && other.enemy == self.realowner))
 750         {
 751                 // somewhat hide the model, but keep the glow
 752                 //self.effects = 0;
 753                 if(self.traileffectnum)
 754                         self.traileffectnum = 0;
 755                 self.alpha = -1;
 756         }
 757         else
 758         {
 759                 //self.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 760                 if(!self.traileffectnum)
 761                         self.traileffectnum = particleeffectnum(Nade_TrailEffect(Nade_ProjectileFromID(self.nade_type, FALSE), self.team));
 762                 self.alpha = 1;
 763         }
 764
 765         return TRUE;
 766 }
 767
 768 void nade_prime()
 769 {
 770         if(self.nade)
 771                 remove(self.nade);
 772
 773         if(self.fake_nade)
 774                 remove(self.fake_nade);
 775
 776         entity n = spawn(), fn = spawn();
 777
 778         n.classname = "nade";
 779         fn.classname = "fake_nade";
 780
 781         if(self.items & IT_STRENGTH && autocvar_g_nades_bonus_onstrength)
 782                 n.nade_type = self.nade_type;
 783         else if (self.bonus_nades >= 1)
 784         {
 785                 n.nade_type = self.nade_type;
 786                 n.pokenade_type = self.pokenade_type;
 787                 self.bonus_nades -= 1;
 788         }
 789         else
 790         {
 791                 n.nade_type = ((autocvar_g_nades_client_select) ? self.cvar_cl_nade_type : autocvar_g_nades_nade_type);
 792                 n.pokenade_type = ((autocvar_g_nades_client_select) ? self.cvar_cl_pokenade_type : autocvar_g_nades_pokenade_monster_type);
 793         }
 794
 795         n.nade_type = bound(1, n.nade_type, NADE_TYPE_LAST);
 796
 797         setmodel(n, "models/weapons/v_ok_grenade.md3");
 798         //setattachment(n, self, "bip01 l hand");
 799         n.exteriormodeltoclient = self;
 800         n.customizeentityforclient = nade_customize;
 801         n.traileffectnum = particleeffectnum(Nade_TrailEffect(Nade_ProjectileFromID(n.nade_type, FALSE), self.team));
 802         n.colormod = Nade_Color(n.nade_type);
 803         n.realowner = self;
 804         n.colormap = self.colormap;
 805         n.glowmod = self.glowmod;
 806         n.wait = time + autocvar_g_nades_nade_lifetime;
 807         n.lifetime = time;
 808         n.think = nade_beep;
 809         n.nextthink = max(n.wait - 3, time);
 810         n.projectiledeathtype = DEATH_NADE;
 811
 812         setmodel(fn, "models/weapons/h_ok_grenade.iqm");
 813         setattachment(fn, self.weaponentity, "");
 814         fn.realowner = fn.owner = self;
 815         fn.colormod = Nade_Color(n.nade_type);
 816         fn.colormap = self.colormap;
 817         fn.glowmod = self.glowmod;
 818         fn.think = SUB_Remove;
 819         fn.nextthink = n.wait;
 820
 821         self.nade = n;
 822         self.fake_nade = fn;
 823 }
 824
 825 float CanThrowNade()
 826 {
 827         if(self.vehicle)
 828                 return FALSE;
 829
 830         if(gameover)
 831                 return FALSE;
 832
 833         if(self.deadflag != DEAD_NO)
 834                 return FALSE;
 835
 836         if (!autocvar_g_nades)
 837                 return FALSE; // allow turning them off mid match
 838
 839         if(forbidWeaponUse())
 840                 return FALSE;
 841
 842         if (!IS_PLAYER(self))
 843                 return FALSE;
 844
 845         return TRUE;
 846 }
 847
 848 void nades_CheckThrow()
 849 {
 850         if(!CanThrowNade())
 851                 return;
 852
 853         if(!self.nade)
 854         {
 855                 if(self.nade_refire < time)
 856                 {
 857                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_NADE_THROW);
 858                         nade_prime();
 859                         self.nade_refire = time + autocvar_g_nades_nade_refire;
 860                 }
 861         }
 862         else
 863         {
 864                 if(time - self.nade.lifetime >= 1)
 865                 {
 866                         makevectors(self.v_angle);
 867                         float _force = time - self.nade.lifetime;
 868                         _force /= autocvar_g_nades_nade_lifetime;
 869                         _force = autocvar_g_nades_nade_minforce + (_force * (autocvar_g_nades_nade_maxforce - autocvar_g_nades_nade_minforce));
 870                         toss_nade(self, (v_forward * 0.75 + v_up * 0.2 + v_right * 0.05) * _force, 0);
 871                 }
 872         }
 873 }
 874
 875 void nades_Clear(entity player)
 876 {
 877         if(player.nade)
 878                 remove(player.nade);
 879         if(player.fake_nade)
 880                 remove(player.fake_nade);
 881
 882         player.nade = player.fake_nade = world;
 883         player.nade_timer = 0;
 884 }
 885
 886 MUTATOR_HOOKFUNCTION(nades_CheckThrow)
 887 {
 888         if(MUTATOR_RETURNVALUE) { nades_CheckThrow(); }
 889         return FALSE;
 890 }
 891
 892 MUTATOR_HOOKFUNCTION(nades_VehicleEnter)
 893 {
 894         if(vh_player.nade)
 895                 toss_nade(vh_player, '0 0 100', max(vh_player.nade.wait, time + 0.05));
 896
 897         return FALSE;
 898 }
 899
 900 MUTATOR_HOOKFUNCTION(nades_PlayerPreThink)
 901 {
 902         if(!IS_PLAYER(self)) { return FALSE; }
 903
 904         float key_pressed = self.BUTTON_HOOK;
 905         float time_score;
 906
 907         if(g_grappling_hook || client_hasweapon(self, WEP_HOOK, FALSE, FALSE) || (weaponsInMap & WEPSET_HOOK) || g_jetpack || self.items & IT_JETPACK)
 908                 key_pressed = self.button16; // if hook/jetpack is enabled, use an alternate key
 909
 910         if(self.nade)
 911         {
 912                 self.nade_timer = bound(0, (time - self.nade.lifetime) / autocvar_g_nades_nade_lifetime, 1);
 913                 //print(sprintf("%d %d\n", self.nade_timer, time - self.nade.lifetime));
 914                 makevectors(self.angles);
 915                 self.nade.velocity = self.velocity;
 916
 917                 setorigin(self.nade, self.origin + self.view_ofs + v_forward * 8 + v_right * -8 + v_up * 0);
 918                 self.nade.angles_y = self.angles_y;
 919         }
 920
 921         if(self.nade)
 922         if(self.nade.wait - 0.1 <= time)
 923                 toss_nade(self, '0 0 0', time + 0.05);
 924
 925         if(CanThrowNade())
 926         if(self.nade_refire < time)
 927         {
 928                 if(key_pressed)
 929                 {
 930                         if(!self.nade)
 931                                 nade_prime();
 932                 }
 933                 else if(time - self.nade.lifetime >= 1)
 934                 {
 935                         if(self.nade)
 936                         {
 937                                 makevectors(self.v_angle);
 938                                 float _force = time - self.nade.lifetime;
 939                                 _force /= autocvar_g_nades_nade_lifetime;
 940                                 _force = autocvar_g_nades_nade_minforce + (_force * (autocvar_g_nades_nade_maxforce - autocvar_g_nades_nade_minforce));
 941                                 toss_nade(self, (v_forward * 0.7 + v_up * 0.2 + v_right * 0.1) * _force, 0);
 942                         }
 943                 }
 944         }
 945
 946         if(IS_PLAYER(self))
 947         {
 948                 if ( autocvar_g_nades_bonus && autocvar_g_nades )
 949                 {
 950                         entity key;
 951                         float key_count = 0;
 952                         FOR_EACH_KH_KEY(key) if(key.owner == self) { ++key_count; }
 953
 954                         if(self.flagcarried || self.ballcarried) // this player is important
 955                                 time_score = autocvar_g_nades_bonus_score_time_flagcarrier;
 956                         else
 957                                 time_score = autocvar_g_nades_bonus_score_time;
 958
 959                         if(key_count)
 960                                 time_score = autocvar_g_nades_bonus_score_time_flagcarrier * key_count; // multiply by the number of keys the player is holding
 961
 962                         if(autocvar_g_nades_bonus_client_select)
 963                         {
 964                                 self.nade_type = self.cvar_cl_nade_type;
 965                                 self.pokenade_type = self.cvar_cl_pokenade_type;
 966                         }
 967                         else
 968                         {
 969                                 self.nade_type = autocvar_g_nades_bonus_type;
 970                                 self.pokenade_type = autocvar_g_nades_pokenade_monster_type;
 971                         }
 972
 973                         self.nade_type = bound(1, self.nade_type, NADE_TYPE_LAST);
 974
 975                         if(self.bonus_nade_score >= 0 && autocvar_g_nades_bonus_score_max)
 976                                 nades_GiveBonus(self, time_score / autocvar_g_nades_bonus_score_max);
 977                 }
 978                 else
 979                 {
 980                         self.bonus_nades = self.bonus_nade_score = 0;
 981                 }
 982         }
 983
 984         float n = 0;
 985         entity o = world;
 986         if(self.freezetag_frozen_timeout > 0 && time >= self.freezetag_frozen_timeout)
 987                 n = -1;
 988         else
 989         {
 990                 vector revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
 991                 n = 0;
 992                 FOR_EACH_PLAYER(other) if(self != other)
 993                 {
 994                         if(other.deadflag == DEAD_NO)
 995                         if(other.frozen == 0)
 996                         if(SAME_TEAM(other, self))
 997                         if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 998                         {
 999                                 if(!o)
1000                                         o = other;
1001                                 if(self.frozen == 1)
1002                                         other.reviving = TRUE;
1003                                 ++n;
1004                         }
1005                 }
1006         }
1007
1008         if(n && self.frozen == 3) // OK, there is at least one teammate reviving us
1009         {
1010                 self.revive_progress = bound(0, self.revive_progress + frametime * max(1/60, autocvar_g_freezetag_revive_speed), 1);
1011                 self.health = max(1, self.revive_progress * start_health);
1012
1013                 if(self.revive_progress >= 1)
1014                 {
1015                         Unfreeze(self);
1016
1017                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_FREEZETAG_REVIVED, o.netname);
1018                         Send_Notification(NOTIF_ONE, o, MSG_CENTER, CENTER_FREEZETAG_REVIVE, self.netname);
1019                 }
1020
1021                 FOR_EACH_PLAYER(other) if(other.reviving)
1022                 {
1023                         other.revive_progress = self.revive_progress;
1024                         other.reviving = FALSE;
1025                 }
1026         }
1027
1028         return FALSE;
1029 }
1030
1031 MUTATOR_HOOKFUNCTION(nades_PlayerSpawn)
1032 {
1033         if(autocvar_g_nades_spawn)
1034                 self.nade_refire = time + autocvar_g_spawnshieldtime;
1035         else
1036                 self.nade_refire  = time + autocvar_g_nades_nade_refire;
1037
1038         if(autocvar_g_nades_bonus_client_select)
1039                 self.nade_type = self.cvar_cl_nade_type;
1040
1041         self.nade_timer = 0;
1042
1043         if(self.nade_spawnloc)
1044         {
1045                 setorigin(self, self.nade_spawnloc.origin);
1046                 self.nade_spawnloc.cnt -= 1;
1047
1048                 if(self.nade_spawnloc.cnt <= 0)
1049                 {
1050                         remove(self.nade_spawnloc);
1051                         self.nade_spawnloc = world;
1052                 }
1053         }
1054
1055         return FALSE;
1056 }
1057
1058 MUTATOR_HOOKFUNCTION(nades_PlayerDies)
1059 {
1060         if(frag_target.nade)
1061         if(!frag_target.frozen || !autocvar_g_freezetag_revive_nade)
1062                 toss_nade(frag_target, '0 0 100', max(frag_target.nade.wait, time + 0.05));
1063
1064         float killcount_bonus = ((frag_attacker.killcount >= 1) ? bound(0, autocvar_g_nades_bonus_score_minor * frag_attacker.killcount, autocvar_g_nades_bonus_score_medium) : autocvar_g_nades_bonus_score_minor);
1065
1066         if(IS_PLAYER(frag_attacker))
1067         {
1068                 if (SAME_TEAM(frag_attacker, frag_target) || frag_attacker == frag_target)
1069                         nades_RemoveBonus(frag_attacker);
1070                 else if(frag_target.flagcarried)
1071                         nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_medium);
1072                 else if(autocvar_g_nades_bonus_score_spree && frag_attacker.killcount > 1)
1073                 {
1074                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
1075                                 case counta: { nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_spree); break; }
1076                         switch(frag_attacker.killcount)
1077                         {
1078                                 KILL_SPREE_LIST
1079                                 default: nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_minor); break;
1080                         }
1081                         #undef SPREE_ITEM
1082                 }
1083                 else
1084                         nades_GiveBonus(frag_attacker, killcount_bonus);
1085         }
1086
1087         nades_RemoveBonus(frag_target);
1088
1089         return FALSE;
1090 }
1091
1092 MUTATOR_HOOKFUNCTION(nades_PlayerDamage)
1093 {
1094         if(frag_target.frozen)
1095         if(autocvar_g_freezetag_revive_nade)
1096         if(frag_attacker == frag_target)
1097         if(frag_deathtype == DEATH_NADE)
1098         if(time - frag_inflictor.toss_time <= 0.1)
1099         {
1100                 Unfreeze(frag_target);
1101                 frag_target.health = autocvar_g_freezetag_revive_nade_health;
1102                 pointparticles(particleeffectnum("iceorglass"), frag_target.origin, '0 0 0', 3);
1103                 frag_damage = 0;
1104                 frag_force = '0 0 0';
1105                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_FREEZETAG_REVIVED_NADE, frag_target.netname);
1106                 Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_FREEZETAG_REVIVE_SELF);
1107         }
1108
1109         return FALSE;
1110 }
1111
1112 MUTATOR_HOOKFUNCTION(nades_MonsterDies)
1113 {
1114         if(IS_PLAYER(frag_attacker))
1115         if(DIFF_TEAM(frag_attacker, self))
1116         if(!(self.spawnflags & MONSTERFLAG_SPAWNED))
1117                 nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_minor);
1118
1119         return FALSE;
1120 }
1121
1122 MUTATOR_HOOKFUNCTION(nades_RemovePlayer)
1123 {
1124         nades_Clear(self);
1125         nades_RemoveBonus(self);
1126         return FALSE;
1127 }
1128
1129 MUTATOR_HOOKFUNCTION(nades_SpectateCopy)
1130 {
1131         self.nade_timer = other.nade_timer;
1132         self.nade_type = other.nade_type;
1133         self.pokenade_type = other.pokenade_type;
1134         self.bonus_nades = other.bonus_nades;
1135         self.bonus_nade_score = other.bonus_nade_score;
1136         self.stat_healing_orb = other.stat_healing_orb;
1137         self.stat_healing_orb_alpha = other.stat_healing_orb_alpha;
1138         return FALSE;
1139 }
1140
1141 MUTATOR_HOOKFUNCTION(nades_GetCvars)
1142 {
1143         GetCvars_handleFloat(get_cvars_s, get_cvars_f, cvar_cl_nade_type, "cl_nade_type");
1144         GetCvars_handleString(get_cvars_s, get_cvars_f, cvar_cl_pokenade_type, "cl_pokenade_type");
1145
1146         return FALSE;
1147 }
1148
1149 MUTATOR_HOOKFUNCTION(nades_BuildMutatorsString)
1150 {
1151         ret_string = strcat(ret_string, ":Nades");
1152         return FALSE;
1153 }
1154
1155 MUTATOR_HOOKFUNCTION(nades_BuildMutatorsPrettyString)
1156 {
1157         ret_string = strcat(ret_string, ", Nades");
1158         return FALSE;
1159 }
1160
1161 void nades_Initialize()
1162 {
1163         addstat(STAT_NADE_TIMER, AS_FLOAT, nade_timer);
1164         addstat(STAT_NADE_BONUS, AS_FLOAT, bonus_nades);
1165         addstat(STAT_NADE_BONUS_TYPE, AS_INT, nade_type);
1166         addstat(STAT_NADE_BONUS_SCORE, AS_FLOAT, bonus_nade_score);
1167         addstat(STAT_HEALING_ORB, AS_FLOAT, stat_healing_orb);
1168         addstat(STAT_HEALING_ORB_ALPHA, AS_FLOAT, stat_healing_orb_alpha);
1169
1170         precache_model("models/ok_nade_counter/ok_nade_counter.md3");
1171         precache_model("models/weapons/h_ok_grenade.iqm");
1172         precache_model("models/weapons/v_ok_grenade.md3");
1173         precache_model("models/ctf/shield.md3");
1174
1175         precache_sound("weapons/rocket_impact.wav");
1176         precache_sound("weapons/grenade_bounce1.wav");
1177         precache_sound("weapons/grenade_bounce2.wav");
1178         precache_sound("weapons/grenade_bounce3.wav");
1179         precache_sound("weapons/grenade_bounce4.wav");
1180         precache_sound("weapons/grenade_bounce5.wav");
1181         precache_sound("weapons/grenade_bounce6.wav");
1182         precache_sound("overkill/grenadebip.ogg");
1183 }
1184
1185 MUTATOR_DEFINITION(mutator_nades)
1186 {
1187         MUTATOR_HOOK(ForbidThrowCurrentWeapon, nades_CheckThrow, CBC_ORDER_LAST);
1188         MUTATOR_HOOK(VehicleEnter, nades_VehicleEnter, CBC_ORDER_ANY);
1189         MUTATOR_HOOK(PlayerPreThink, nades_PlayerPreThink, CBC_ORDER_ANY);
1190         MUTATOR_HOOK(PlayerSpawn, nades_PlayerSpawn, CBC_ORDER_ANY);
1191         MUTATOR_HOOK(PlayerDies, nades_PlayerDies, CBC_ORDER_LAST);
1192         MUTATOR_HOOK(PlayerDamage_Calculate, nades_PlayerDamage, CBC_ORDER_ANY);
1193         MUTATOR_HOOK(MonsterDies, nades_MonsterDies, CBC_ORDER_ANY);
1194         MUTATOR_HOOK(MakePlayerObserver, nades_RemovePlayer, CBC_ORDER_ANY);
1195         MUTATOR_HOOK(ClientDisconnect, nades_RemovePlayer, CBC_ORDER_ANY);
1196         MUTATOR_HOOK(SpectateCopy, nades_SpectateCopy, CBC_ORDER_ANY);
1197         MUTATOR_HOOK(GetCvars, nades_GetCvars, CBC_ORDER_ANY);
1198         MUTATOR_HOOK(reset_map_global, nades_RemovePlayer, CBC_ORDER_ANY);
1199         MUTATOR_HOOK(BuildMutatorsString, nades_BuildMutatorsString, CBC_ORDER_ANY);
1200         MUTATOR_HOOK(BuildMutatorsPrettyString, nades_BuildMutatorsPrettyString, CBC_ORDER_ANY);
1201
1202         MUTATOR_ONADD
1203         {
1204                 nades_Initialize();
1205         }
1206
1207         return FALSE;
1208 }