qcsrc/server/mutators/mutator_overkill.qc

   1 void ok_DecreaseCharge(entity ent, float wep)
   2 {
   3         if not(autocvar_g_overkill_ammo_charge) return;
   4
   5         entity wepent = get_weaponinfo(wep);
   6
   7         if(wepent.netname == "")
   8                 return; // dummy
   9
  10         ent.ammo_charge[wep] -= cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname));
  11 }
  12
  13 void ok_IncreaseCharge(entity ent, float wep)
  14 {
  15         entity wepent = get_weaponinfo(wep);
  16
  17         if(wepent.netname == "")
  18                 return; // dummy
  19
  20         if(autocvar_g_overkill_ammo_charge)
  21         if not(ent.BUTTON_ATCK)
  22         if(ent.ammo_charge[wep] <= autocvar_g_overkill_ammo_charge_limit)
  23                 ent.ammo_charge[wep] = min(autocvar_g_overkill_ammo_charge_limit, ent.ammo_charge[wep] + cvar(sprintf("g_overkill_ammo_charge_rate_%s", wepent.netname)) * frametime / W_TICSPERFRAME);
  24 }
  25
  26 float ok_CheckWeaponCharge(entity ent, float wep)
  27 {
  28         if not(autocvar_g_overkill_ammo_charge) return TRUE;
  29         //if(wep != swep) return TRUE; // switching, don't even bother checking
  30
  31         entity wepent = get_weaponinfo(wep);
  32
  33         if(wepent.netname == "")
  34                 return 0; // dummy
  35
  36         return !(ent.ammo_charge[wep] < cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname)));
  37 }
  38
  39 MUTATOR_HOOKFUNCTION(ok_PlayerDamage_Calculate)
  40 {
  41         if(DEATH_ISWEAPON(frag_deathtype, WEP_LASER) && frag_target == frag_attacker)
  42                 frag_damage = 0;
  43
  44         if(!IS_PLAYER(frag_target) || frag_target == frag_attacker)
  45                 return FALSE;
  46
  47         if not (DEATH_ISWEAPON(frag_deathtype, WEP_LASER))
  48                 return FALSE;
  49
  50         frag_damage = 0;
  51         if(frag_target.health >= 1 && !frag_target.freezetag_frozen)
  52                 Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_MINSTA_SECONDARY);
  53
  54         frag_force = '0 0 0';
  55
  56         return FALSE;
  57 }
  58
  59 MUTATOR_HOOKFUNCTION(ok_BuildMutatorsString)
  60 {
  61         ret_string = strcat(ret_string, ":OK");
  62         return FALSE;
  63 }
  64
  65 MUTATOR_HOOKFUNCTION(ok_BuildMutatorsPrettyString)
  66 {
  67         ret_string = strcat(ret_string, ", Overkill");
  68         return FALSE;
  69 }
  70
  71 MUTATOR_HOOKFUNCTION(ok_PlayerDies)
  72 {
  73         self.ok_lastwep = self.weapon;
  74         self.ok_deathloc = self.origin;
  75
  76         entity oldself = self;
  77         float gpi = autocvar_g_pickup_items;
  78
  79         cvar_set("g_pickup_items", "1");
  80         self = spawn();
  81         self.ok_item = TRUE;
  82         self.noalign = TRUE;
  83         spawnfunc_item_armor_small();
  84         self.movetype = MOVETYPE_TOSS;
  85         self.gravity = 1;
  86         self.reset = SUB_Remove;
  87         setorigin(self, frag_target.origin + '0 0 32');
  88         self.velocity = '0 0 200' + normalize(frag_attacker.origin - self.origin) * 500;
  89         self.classname = "droppedweapon"; // hax
  90         SUB_SetFade(self, time + 5, 1);
  91         self = oldself;
  92         cvar_set("g_pickup_items", ftos(gpi));
  93
  94         return FALSE;
  95 }
  96
  97 MUTATOR_HOOKFUNCTION(ok_ForbidThrowCurrentWeapon)
  98 {
  99         return TRUE;
 100 }
 101
 102 MUTATOR_HOOKFUNCTION(ok_PlayerPreThink)
 103 {
 104         if(intermission_running || gameover)
 105                 return FALSE;
 106
 107         if(self.deadflag != DEAD_NO || !IS_PLAYER(self))
 108                 return FALSE;
 109
 110         if(self.freezetag_frozen)
 111                 return FALSE;
 112
 113         ok_IncreaseCharge(self, self.weapon);
 114
 115         if(self.BUTTON_ATCK2)
 116         if(!forbidWeaponUse() || self.weapon_blocked) // allow if weapon is blocked
 117         if(self.jump_interval <= time)
 118         {
 119                 self.jump_interval = time + autocvar_g_balance_laser_primary_refire * W_WeaponRateFactor();
 120                 makevectors(self.v_angle);
 121                 float w = self.weapon;
 122                 self.weapon = WEP_LASER;
 123                 W_Laser_Attack(3);
 124                 self.weapon = w;
 125         }
 126
 127         self.weapon_blocked = FALSE;
 128
 129         self.stat_ok_ammo_charge = self.ammo_charge[self.weapon];
 130
 131         if(autocvar_g_overkill_ammo_charge)
 132         if(!ok_CheckWeaponCharge(self, self.weapon))
 133         {
 134                 if(autocvar_g_overkill_ammo_charge_notice && time > self.ok_notice_time && self.BUTTON_ATCK && IS_REAL_CLIENT(self))
 135                 {
 136                         //Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_OVERKILL_CHARGE);
 137                         self.ok_notice_time = time + 2;
 138                         play2(self, "weapons/dryfire.wav");
 139                 }
 140                 if(self.weaponentity.state != WS_CLEAR)
 141                         w_ready();
 142
 143                 self.weapon_blocked = TRUE;
 144         }
 145
 146         self.BUTTON_ATCK2 = 0;
 147
 148         return FALSE;
 149 }
 150
 151 MUTATOR_HOOKFUNCTION(ok_PlayerSpawn)
 152 {
 153         if(autocvar_g_overkill_ammo_charge)
 154         {
 155                 float i;
 156
 157                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 158                         self.ammo_charge[i] = autocvar_g_overkill_ammo_charge_limit;
 159
 160                 self.ok_use_ammocharge = 1;
 161                 self.ok_notice_time = time;
 162         }
 163         else
 164                 self.ok_use_ammocharge = 0;
 165
 166         return FALSE;
 167 }
 168
 169 void start_hmg()
 170 {
 171         float gpi = autocvar_g_pickup_items;
 172         cvar_set("g_pickup_items", "1");
 173         self.classname = "weapon_hmg";
 174         self.ok_item = TRUE;
 175         self.respawntime = autocvar_g_overkill_superguns_respawn_time;
 176         setmodel(self, "models/weapons/g_ok_hmg.md3");
 177         spawnfunc_weapon_hmg();
 178
 179         cvar_set("g_pickup_items", ftos(gpi));
 180 }
 181
 182 void start_rpc()
 183 {
 184         float gpi = autocvar_g_pickup_items;
 185         cvar_set("g_pickup_items", "1");
 186         self.classname = "weapon_rpc";
 187         self.respawntime = autocvar_g_overkill_superguns_respawn_time;
 188         self.ok_item = TRUE;
 189         setmodel(self, "models/weapons/g_ok_rl.md3");
 190         spawnfunc_weapon_rpc();
 191         cvar_set("g_pickup_items", ftos(gpi));
 192 }
 193
 194 void start_mh_anyway()
 195 {
 196         cvar_set("g_pickup_items", "1");
 197         self.classname = "item_health_mega";
 198         self.ok_item = TRUE;
 199         spawnfunc_item_health_mega();
 200         cvar_set("g_pickup_items", "0");
 201 }
 202
 203 void start_ma_anyway()
 204 {
 205         cvar_set("g_pickup_items", "1");
 206         self.classname = "item_armor_large";
 207         self.ok_item = TRUE;
 208         spawnfunc_item_armor_large();
 209         cvar_set("g_pickup_items", "0");
 210 }
 211
 212 MUTATOR_HOOKFUNCTION(ok_OnEntityPreSpawn)
 213 {
 214         if(autocvar_g_powerups)
 215         if(autocvar_g_overkill_powerups_replace)
 216         if(self.classname == "item_strength")
 217         {
 218                 entity wep = spawn();
 219                 setorigin(wep, self.origin);
 220                 wep.ok_item = TRUE;
 221                 wep.think = start_hmg;
 222                 wep.nextthink = time + 0.1;
 223                 wep.noalign = self.noalign;
 224                 return TRUE;
 225         }
 226
 227         if(autocvar_g_powerups)
 228         if(autocvar_g_overkill_powerups_replace)
 229         if(self.classname == "item_invincible")
 230         {
 231                 entity wep = spawn();
 232                 setorigin(wep, self.origin);
 233                 wep.ok_item = TRUE;
 234                 wep.think = start_rpc;
 235                 wep.nextthink = time + 0.1;
 236                 wep.noalign = self.noalign;
 237                 return TRUE;
 238         }
 239
 240         return FALSE;
 241 }
 242
 243 MUTATOR_HOOKFUNCTION(ok_ItemRemove)
 244 {
 245         if(self.ok_item)
 246                 return FALSE;
 247
 248         switch(self.items)
 249         {
 250                 case IT_HEALTH: return !(autocvar_g_overkill_100h_anyway);
 251                 case IT_ARMOR: return !(autocvar_g_overkill_100a_anyway);
 252         }
 253
 254         return TRUE;
 255 }
 256
 257 MUTATOR_HOOKFUNCTION(ok_SpectateCopy)
 258 {
 259         self.ammo_charge[self.weapon] = other.ammo_charge[other.weapon];
 260         self.ok_use_ammocharge = other.ok_use_ammocharge;
 261
 262         return FALSE;
 263 }
 264
 265 MUTATOR_HOOKFUNCTION(ok_SetModname)
 266 {
 267         modname = "Overkill";
 268         return TRUE;
 269 }
 270
 271 MUTATOR_HOOKFUNCTION(ok_StartItems)
 272 {
 273         start_items |= IT_UNLIMITED_WEAPON_AMMO;
 274         start_weapons = (WEPSET_UZI | WEPSET_NEX | WEPSET_SHOTGUN);
 275
 276         start_ammo_nails = start_ammo_cells = start_ammo_shells = start_ammo_rockets =
 277         warmup_start_ammo_nails = warmup_start_ammo_cells = warmup_start_ammo_shells = warmup_start_ammo_rockets = autocvar_g_overkill_ammo_start;
 278
 279         return FALSE;
 280 }
 281
 282 void ok_Initialize()
 283 {
 284         precache_all_playermodels("models/ok_player/*.dpm");
 285
 286         precache_model("models/weapons/h_ok_rl.iqm");
 287         precache_model("models/weapons/v_ok_rl.md3");
 288         precache_model("models/weapons/g_ok_rl.md3");
 289         precache_model("models/weapons/ok_rocket.md3");
 290
 291         precache_model("models/weapons/h_ok_mg.iqm");
 292         precache_model("models/weapons/v_ok_mg.md3");
 293         precache_model("models/weapons/g_ok_mg.md3");
 294
 295         precache_model("models/weapons/h_ok_hmg.iqm");
 296         precache_model("models/weapons/v_ok_hmg.md3");
 297         precache_model("models/weapons/g_ok_hmg.md3");
 298
 299         precache_model("models/weapons/h_ok_shotgun.iqm");
 300         precache_model("models/weapons/v_ok_shotgun.md3");
 301         precache_model("models/weapons/g_ok_shotgun.md3");
 302
 303         precache_model("models/weapons/h_ok_sniper.iqm");
 304         precache_model("models/weapons/v_ok_sniper.md3");
 305         precache_model("models/weapons/g_ok_sniper.md3");
 306
 307         precache_sound("weapons/dryfire.wav");
 308
 309         addstat(STAT_OK_AMMO_CHARGE, AS_FLOAT, ok_use_ammocharge);
 310         addstat(STAT_OK_AMMO_CHARGEPOOl, AS_FLOAT, stat_ok_ammo_charge);
 311
 312         w_uzi(WR_PRECACHE);
 313         w_nex(WR_PRECACHE);
 314         w_shotgun(WR_PRECACHE);
 315         w_laser(WR_PRECACHE);
 316
 317         (get_weaponinfo(WEP_RPC)).spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 318         (get_weaponinfo(WEP_HMG)).spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 319
 320         (get_weaponinfo(WEP_SHOTGUN)).mdl = "ok_shotgun";
 321         (get_weaponinfo(WEP_UZI)).mdl = "ok_mg";
 322         (get_weaponinfo(WEP_NEX)).mdl = "ok_sniper";
 323
 324         string s;
 325         float fh = fopen("overkill.cfg", FILE_READ);
 326         if(fh >= 0)
 327         {
 328                 while((s = fgets(fh)))
 329                 {
 330                         tokenize_console(s);
 331                         if not(argv(0) == "" || argv(1) == "//" || argv(1) == "")
 332                                 cvar_settemp(argv(0), argv(1));
 333                 }
 334                 fclose(fh);
 335         }
 336         else
 337                 dprint("^1Mutator Overkill: WARNING! overkill.cfg NOT found, things will be strange!\n");
 338 }
 339
 340 MUTATOR_DEFINITION(mutator_overkill)
 341 {
 342         MUTATOR_HOOK(ForbidThrowCurrentWeapon, ok_ForbidThrowCurrentWeapon, CBC_ORDER_ANY);
 343         MUTATOR_HOOK(BuildMutatorsString, ok_BuildMutatorsString, CBC_ORDER_ANY);
 344         MUTATOR_HOOK(BuildMutatorsPrettyString, ok_BuildMutatorsPrettyString, CBC_ORDER_ANY);
 345         MUTATOR_HOOK(PlayerPreThink, ok_PlayerPreThink, CBC_ORDER_LAST);
 346         MUTATOR_HOOK(PlayerSpawn, ok_PlayerSpawn, CBC_ORDER_LAST);
 347         MUTATOR_HOOK(PlayerDamage_Calculate, ok_PlayerDamage_Calculate, CBC_ORDER_LAST);
 348         MUTATOR_HOOK(PlayerDies, ok_PlayerDies, CBC_ORDER_ANY);
 349         MUTATOR_HOOK(OnEntityPreSpawn, ok_OnEntityPreSpawn, CBC_ORDER_ANY);
 350         MUTATOR_HOOK(SetModname, ok_SetModname, CBC_ORDER_ANY);
 351         MUTATOR_HOOK(FilterItem, ok_ItemRemove, CBC_ORDER_ANY);
 352         MUTATOR_HOOK(SpectateCopy, ok_SpectateCopy, CBC_ORDER_ANY);
 353         MUTATOR_HOOK(SetStartItems, ok_StartItems, CBC_ORDER_ANY);
 354
 355         MUTATOR_ONADD
 356         {
 357                 ok_Initialize();
 358         }
 359
 360         MUTATOR_ONREMOVE
 361         {
 362                 (get_weaponinfo(WEP_RPC)).spawnflags |= WEP_FLAG_MUTATORBLOCKED;
 363                 (get_weaponinfo(WEP_HMG)).spawnflags |= WEP_FLAG_MUTATORBLOCKED;
 364         }
 365
 366         return FALSE;
 367 }