qcsrc/server/mutators/mutator_overkill.qc

   1 MUTATOR_HOOKFUNCTION(ok_PlayerDamage_Calculate)
   2 {
   3         if(DEATH_ISWEAPON(frag_deathtype, WEP_LASER) && frag_target == frag_attacker)
   4                 frag_damage = 0;
   5
   6         if(!IS_PLAYER(frag_target) || frag_target == frag_attacker)
   7                 return FALSE;
   8
   9         if not (DEATH_ISWEAPON(frag_deathtype, WEP_LASER))
  10                 return FALSE;
  11
  12         frag_damage = 0;
  13         if(frag_target.health >= 1 && !frag_target.freezetag_frozen)
  14                 Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_MINSTA_SECONDARY);
  15
  16         frag_force = '0 0 0';
  17
  18         return FALSE;
  19 }
  20
  21 MUTATOR_HOOKFUNCTION(ok_BuildMutatorsString)
  22 {
  23         ret_string = strcat(ret_string, ":OK");
  24         return FALSE;
  25 }
  26
  27 MUTATOR_HOOKFUNCTION(ok_BuildMutatorsPrettyString)
  28 {
  29         ret_string = strcat(ret_string, ", Overkill");
  30         return FALSE;
  31 }
  32
  33 void ok_Item_Touch()
  34 {
  35         if(IS_PLAYER(other) && other.deadflag == DEAD_NO && !other.freezetag_frozen)
  36         {
  37                 Item_Touch();
  38                 remove(self);
  39         }
  40 }
  41
  42 MUTATOR_HOOKFUNCTION(ok_PlayerDies)
  43 {
  44         self.ok_lastwep = self.weapon;
  45         self.ok_deathloc = self.origin;
  46
  47         entity oldself = self;
  48         float gpi = autocvar_g_pickup_items;
  49
  50         cvar_set("g_pickup_items", "1");
  51         self = spawn();
  52         self.noalign = TRUE;
  53         self.ok_item = TRUE;
  54         spawnfunc_item_armor_small();
  55         self.movetype = MOVETYPE_TOSS;
  56         self.gravity = 1;
  57         setorigin(self, frag_target.origin + '0 0 32');
  58         self.velocity = '0 0 200' + normalize(frag_attacker.origin - self.origin) * 500;
  59         self.touch = ok_Item_Touch;
  60         SUB_SetFade(self, time + 5, 1);
  61         self = oldself;
  62         cvar_set("g_pickup_items", ftos(gpi));
  63
  64         return FALSE;
  65 }
  66
  67 MUTATOR_HOOKFUNCTION(ok_ForbidThrowCurrentWeapon)
  68 {
  69         return TRUE;
  70 }
  71
  72 MUTATOR_HOOKFUNCTION(ok_PlayerPreThink)
  73 {
  74         if(intermission_running || gameover)
  75                 return FALSE;
  76
  77         if(self.deadflag != DEAD_NO || !IS_PLAYER(self))
  78                 return FALSE;
  79
  80         if(self.freezetag_frozen)
  81                 return FALSE;
  82
  83         if(self.BUTTON_ATCK2)
  84                 if(self.jump_interval <= time)
  85                 {
  86                         self.jump_interval = time + autocvar_g_balance_laser_primary_refire * W_WeaponRateFactor();
  87                         makevectors(self.v_angle);
  88                         float w = self.weapon;
  89                         self.weapon = WEP_LASER;
  90                         W_Laser_Attack(3);
  91                         self.weapon = w;
  92                 }
  93
  94         self.BUTTON_ATCK2 = 0;
  95         return FALSE;
  96 }
  97
  98 MUTATOR_HOOKFUNCTION(ok_PlayerSpawn)
  99 {
 100         if(autocvar_g_overkill_spawnsystem_delay_death)
 101                 self.ok_spawnsys_timer = time + autocvar_g_overkill_spawnsystem_delay_death;
 102
 103         if(teamplay == 0 || autocvar_g_overkill_spawnsystem == 0)
 104                 return FALSE;
 105
 106         entity team_mate, best_mate = world;
 107         vector best_spot = '0 0 0';
 108         float pc = 0., best_dist = 0., dist = 0.;
 109         FOR_EACH_PLAYER(team_mate)
 110         {
 111                 if((autocvar_g_overkill_spawnsystem_check_health != 0 && team_mate.health >= 100) || autocvar_g_overkill_spawnsystem_check_health == 0)
 112                         if(team_mate.deadflag == DEAD_NO)
 113                                 if(team_mate.ok_spawnsys_timer < time)
 114                                         if(team_mate.team == self.team && (g_ctf || g_tdm || g_keyhunt))
 115                                                 if(team_mate != self)
 116                                                 {
 117                                                         tracebox(team_mate.origin, PL_MIN, PL_MAX, team_mate.origin - '0 0 100', MOVE_WORLDONLY, team_mate);
 118                                                         if(trace_fraction != 1.0)
 119                                                                 if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
 120                                                                 {
 121                                                                         pc = pointcontents(trace_endpos + '0 0 1');
 122                                                                         if(pc == CONTENT_EMPTY)
 123                                                                         {
 124                                                                                 if(vlen(team_mate.velocity) > 5)
 125                                                                                         fixedmakevectors(vectoangles(team_mate.velocity));
 126                                                                                 else
 127                                                                                         fixedmakevectors(team_mate.angles);
 128
 129                                                                                 for(pc = 0; pc != 5; ++pc) // test 5 diffrent spots close to mate
 130                                                                                 {
 131                                                                                         switch(pc)
 132                                                                                         {
 133                                                                                         case 0:
 134                                                                                                 tracebox(team_mate.origin , PL_MIN, PL_MAX, team_mate.origin + v_right * 128, MOVE_NORMAL, team_mate);
 135                                                                                                 break;
 136                                                                                         case 1:
 137                                                                                                 tracebox(team_mate.origin , PL_MIN, PL_MAX,team_mate.origin - v_right * 128 , MOVE_NORMAL, team_mate);
 138                                                                                                 break;
 139                                                                                         case 2:
 140                                                                                                 tracebox(team_mate.origin , PL_MIN, PL_MAX, team_mate.origin + v_right * 64 - v_forward * 64, MOVE_NORMAL, team_mate);
 141                                                                                                 break;
 142                                                                                         case 3:
 143                                                                                                 tracebox(team_mate.origin , PL_MIN, PL_MAX, team_mate.origin - v_right * 64 - v_forward * 64, MOVE_NORMAL, team_mate);
 144                                                                                                 break;
 145                                                                                         case 4:
 146                                                                                                 tracebox(team_mate.origin , PL_MIN, PL_MAX, team_mate.origin - v_forward * 128, MOVE_NORMAL, team_mate);
 147                                                                                                 break;
 148                                                                                         }
 149
 150                                                                                         if(trace_fraction == 1.0)
 151                                                                                         {
 152                                                                                                 traceline(trace_endpos + '0 0 4', trace_endpos - '0 0 100', MOVE_NORMAL, team_mate);
 153                                                                                                 if(trace_fraction != 1.0)
 154                                                                                                 {
 155                                                                                                         if(autocvar_g_overkill_spawnsystem_close2death)
 156                                                                                                         {
 157                                                                                                                 dist = vlen(trace_endpos - self.ok_deathloc);
 158                                                                                                                 if(dist < best_dist || best_dist == 0)
 159                                                                                                                 {
 160                                                                                                                         best_dist = dist;
 161                                                                                                                         best_spot = trace_endpos;
 162                                                                                                                         best_mate = team_mate;
 163                                                                                                                 }
 164                                                                                                         }
 165                                                                                                         else
 166                                                                                                         {
 167                                                                                                                 setorigin(self, trace_endpos);
 168                                                                                                                 self.angles = team_mate.angles;
 169                                                                                                                 team_mate.ok_spawnsys_timer = time + autocvar_g_overkill_spawnsystem_delay;
 170                                                                                                                 return FALSE;
 171                                                                                                         }
 172                                                                                                 }
 173                                                                                         }
 174                                                                                 }
 175                                                                         }
 176                                                                 }
 177                                                 }
 178         }
 179
 180         if(autocvar_g_overkill_spawnsystem_close2death)
 181                 if(best_dist)
 182                 {
 183                         setorigin(self, best_spot);
 184                         self.angles = best_mate.angles;
 185                         best_mate.ok_spawnsys_timer = time + autocvar_g_overkill_spawnsystem_delay;
 186                 }
 187
 188         return 0;
 189 }
 190
 191 void start_hmg()
 192 {
 193         float gpi = autocvar_g_pickup_items;
 194         cvar_set("g_pickup_items", "1");
 195         self.classname = "weapon_hmg";
 196         self.ok_item = TRUE;
 197         //self.weapons = WEP_HMG;
 198         //self.flags |= FL_POWERUP;
 199         self.respawntime = autocvar_g_overkill_superguns_respawn_time;
 200         setmodel(self, "models/weapons/g_ok_hmg.md3");
 201         spawnfunc_weapon_hmg();
 202
 203         cvar_set("g_pickup_items", ftos(gpi));
 204 }
 205
 206 void start_rpc()
 207 {
 208         float gpi = autocvar_g_pickup_items;
 209         cvar_set("g_pickup_items", "1");
 210         self.classname = "weapon_rpc";
 211         self.respawntime = autocvar_g_overkill_superguns_respawn_time;
 212         self.ok_item = TRUE;
 213         //self.weapons = WEP_RPC;
 214         //self.flags |= FL_POWERUP;
 215         setmodel(self, "models/weapons/g_ok_rl.md3");
 216         spawnfunc_weapon_rpc();
 217         cvar_set("g_pickup_items", ftos(gpi));
 218 }
 219
 220 void start_mh_anyway()
 221 {
 222         cvar_set("g_pickup_items", "1");
 223         self.classname = "item_health_mega";
 224         self.ok_item = TRUE;
 225         spawnfunc_item_health_mega();
 226         cvar_set("g_pickup_items", "0");
 227 }
 228
 229 void start_ma_anyway()
 230 {
 231         cvar_set("g_pickup_items", "1");
 232         self.classname = "item_armor_large";
 233         self.ok_item = TRUE;
 234         spawnfunc_item_armor_large();
 235         cvar_set("g_pickup_items", "0");
 236 }
 237
 238 MUTATOR_HOOKFUNCTION(ok_OnEntityPreSpawn)
 239 {
 240         if(autocvar_g_powerups != 0)
 241         if(autocvar_g_overkill_powerups_replace)
 242         if(self.classname == "item_strength")
 243         {
 244                 entity wep = spawn();
 245                 setorigin(wep, self.origin);
 246                 wep.think = start_hmg;
 247                 wep.nextthink = time + 0.1;
 248                 return TRUE;
 249         }
 250
 251         if(autocvar_g_powerups != 0)
 252         if(autocvar_g_overkill_powerups_replace)
 253         if(self.classname == "item_invincible")
 254         {
 255                 entity wep = spawn();
 256                 setorigin(wep, self.origin);
 257                 wep.think = start_rpc;
 258                 wep.nextthink = time + 0.1;
 259                 return TRUE;
 260         }
 261
 262         return FALSE;
 263 }
 264
 265 MUTATOR_HOOKFUNCTION(ok_ItemRemove)
 266 {
 267         if(self.ok_item)
 268                 return FALSE;
 269
 270         switch(self.items)
 271         {
 272                 case IT_HEALTH: return !(autocvar_g_overkill_100h_anyway);
 273                 case IT_ARMOR: return !(autocvar_g_overkill_100a_anyway);
 274         }
 275
 276         return TRUE;
 277 }
 278
 279 MUTATOR_HOOKFUNCTION(ok_SetModname)
 280 {
 281         modname = "Overkill";
 282         return TRUE;
 283 }
 284
 285 MUTATOR_HOOKFUNCTION(ok_StartItems)
 286 {
 287         start_items |= IT_UNLIMITED_WEAPON_AMMO;
 288         start_weapons = (WEPSET_UZI | WEPSET_NEX | WEPSET_SHOTGUN);
 289
 290         start_ammo_nails = start_ammo_cells = start_ammo_shells = start_ammo_rockets =
 291         warmup_start_ammo_nails = warmup_start_ammo_cells = warmup_start_ammo_shells = warmup_start_ammo_rockets = autocvar_g_overkill_ammo_start;
 292
 293         return FALSE;
 294 }
 295
 296 void ok_Initialize()
 297 {
 298         precache_all_playermodels("models/ok_player/*.dpm");
 299
 300         precache_model("models/weapons/h_ok_rl.iqm");
 301         precache_model("models/weapons/v_ok_rl.md3");
 302         precache_model("models/weapons/g_ok_rl.md3");
 303         precache_model("models/weapons/ok_rocket.md3");
 304
 305         precache_model("models/weapons/h_ok_mg.iqm");
 306         precache_model("models/weapons/v_ok_mg.md3");
 307         precache_model("models/weapons/g_ok_mg.md3");
 308
 309         precache_model("models/weapons/h_ok_hmg.iqm");
 310         precache_model("models/weapons/v_ok_hmg.md3");
 311         precache_model("models/weapons/g_ok_hmg.md3");
 312
 313         precache_model("models/weapons/h_ok_shotgun.iqm");
 314         precache_model("models/weapons/v_ok_shotgun.md3");
 315         precache_model("models/weapons/g_ok_shotgun.md3");
 316
 317         precache_model("models/weapons/h_ok_sniper.iqm");
 318         precache_model("models/weapons/v_ok_sniper.md3");
 319         precache_model("models/weapons/g_ok_sniper.md3");
 320
 321         w_uzi(WR_PRECACHE);
 322         w_nex(WR_PRECACHE);
 323         w_shotgun(WR_PRECACHE);
 324         w_laser(WR_PRECACHE);
 325
 326         (get_weaponinfo(WEP_RPC)).spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 327         (get_weaponinfo(WEP_HMG)).spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 328
 329         (get_weaponinfo(WEP_SHOTGUN)).mdl = "ok_shotgun";
 330         (get_weaponinfo(WEP_UZI)).mdl = "ok_mg";
 331         (get_weaponinfo(WEP_NEX)).mdl = "ok_sniper";
 332
 333         string s;
 334         float fh = fopen("overkill.cfg", FILE_READ);
 335         if(fh >= 0)
 336         {
 337                 while((s = fgets(fh)))
 338                 {
 339                         tokenize_console(s);
 340                         if not(argv(0) == "" || argv(1) == "//" || argv(1) == "")
 341                                 cvar_settemp(argv(0), argv(1));
 342                 }
 343                 fclose(fh);
 344         }
 345         else
 346                 dprint("^1Mutator Overkill: WARNING! overkill.cfg NOT found, things will be strange!\n");
 347 }
 348
 349 MUTATOR_DEFINITION(mutator_overkill)
 350 {
 351         MUTATOR_HOOK(ForbidThrowCurrentWeapon, ok_ForbidThrowCurrentWeapon, CBC_ORDER_ANY);
 352         MUTATOR_HOOK(BuildMutatorsString, ok_BuildMutatorsString, CBC_ORDER_ANY);
 353         MUTATOR_HOOK(BuildMutatorsPrettyString, ok_BuildMutatorsPrettyString, CBC_ORDER_ANY);
 354         MUTATOR_HOOK(PlayerPreThink, ok_PlayerPreThink, CBC_ORDER_LAST);
 355         MUTATOR_HOOK(PlayerSpawn, ok_PlayerSpawn, CBC_ORDER_LAST);
 356         MUTATOR_HOOK(PlayerDamage_Calculate, ok_PlayerDamage_Calculate, CBC_ORDER_LAST);
 357         MUTATOR_HOOK(PlayerDies, ok_PlayerDies, CBC_ORDER_ANY);
 358         MUTATOR_HOOK(OnEntityPreSpawn, ok_OnEntityPreSpawn, CBC_ORDER_ANY);
 359         MUTATOR_HOOK(SetModname, ok_SetModname, CBC_ORDER_ANY);
 360         MUTATOR_HOOK(FilterItem, ok_ItemRemove, CBC_ORDER_ANY);
 361         MUTATOR_HOOK(SetStartItems, ok_StartItems, CBC_ORDER_ANY);
 362
 363         MUTATOR_ONADD
 364         {
 365                 ok_Initialize();
 366         }
 367
 368         MUTATOR_ONREMOVE
 369         {
 370                 (get_weaponinfo(WEP_RPC)).spawnflags |= WEP_FLAG_MUTATORBLOCKED;
 371                 (get_weaponinfo(WEP_HMG)).spawnflags |= WEP_FLAG_MUTATORBLOCKED;
 372         }
 373
 374         return FALSE;
 375 }