qcsrc/server/mutators/mutator_spawn_near_teammate.qc

   1
   2 #include "mutator.qh"
   3
   4 .entity msnt_lookat;
   5
   6 .float msnt_timer;
   7 .vector msnt_deathloc;
   8
   9 .float cvar_cl_spawn_near_teammate;
  10
  11 MUTATOR_HOOKFUNCTION(msnt_Spawn_Score)
  12 {SELFPARAM();
  13         if(autocvar_g_spawn_near_teammate_ignore_spawnpoint == 1 || (autocvar_g_spawn_near_teammate_ignore_spawnpoint == 2 && self.cvar_cl_spawn_near_teammate))
  14                 return 0;
  15
  16         entity p;
  17
  18         spawn_spot.msnt_lookat = world;
  19
  20         if(!teamplay)
  21                 return 0;
  22
  23         RandomSelection_Init();
  24         FOR_EACH_PLAYER(p) if(p != self) if(p.team == self.team) if(!p.deadflag)
  25         {
  26                 float l = vlen(spawn_spot.origin - p.origin);
  27                 if(l > autocvar_g_spawn_near_teammate_distance)
  28                         continue;
  29                 if(l < 48)
  30                         continue;
  31                 if(!checkpvs(spawn_spot.origin, p))
  32                         continue;
  33                 RandomSelection_Add(p, 0, string_null, 1, 1);
  34         }
  35
  36         if(RandomSelection_chosen_ent)
  37         {
  38                 spawn_spot.msnt_lookat = RandomSelection_chosen_ent;
  39                 spawn_score.x += SPAWN_PRIO_NEAR_TEAMMATE_FOUND;
  40         }
  41         else if(self.team == spawn_spot.team)
  42                 spawn_score.x += SPAWN_PRIO_NEAR_TEAMMATE_SAMETEAM; // prefer same team, if we can't find a spawn near teammate
  43
  44         return 0;
  45 }
  46
  47 MUTATOR_HOOKFUNCTION(msnt_PlayerSpawn)
  48 {SELFPARAM();
  49         // Note: when entering this, fixangle is already set.
  50         if(autocvar_g_spawn_near_teammate_ignore_spawnpoint == 1 || (autocvar_g_spawn_near_teammate_ignore_spawnpoint == 2 && self.cvar_cl_spawn_near_teammate))
  51         {
  52                 if(autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay_death)
  53                         self.msnt_timer = time + autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay_death;
  54
  55                 entity team_mate, best_mate = world;
  56                 vector best_spot = '0 0 0';
  57                 float pc = 0, best_dist = 0, dist = 0;
  58                 FOR_EACH_PLAYER(team_mate)
  59                 {
  60                         if((autocvar_g_spawn_near_teammate_ignore_spawnpoint_check_health >= 0 && team_mate.health >= autocvar_g_balance_health_regenstable) || autocvar_g_spawn_near_teammate_ignore_spawnpoint_check_health == 0)
  61                         if(team_mate.deadflag == DEAD_NO)
  62                         if(team_mate.msnt_timer < time)
  63                         if(SAME_TEAM(self, team_mate))
  64                         if(time > team_mate.spawnshieldtime) // spawn shielding
  65                         if(team_mate.frozen == 0)
  66                         if(team_mate != self)
  67                         {
  68                                 tracebox(team_mate.origin, PL_MIN, PL_MAX, team_mate.origin - '0 0 100', MOVE_WORLDONLY, team_mate);
  69                                 if(trace_fraction != 1.0)
  70                                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
  71                                 {
  72                                         pc = pointcontents(trace_endpos + '0 0 1');
  73                                         if(pc == CONTENT_EMPTY)
  74                                         {
  75                                                 if(vlen(team_mate.velocity) > 5)
  76                                                         fixedmakevectors(vectoangles(team_mate.velocity));
  77                                                 else
  78                                                         fixedmakevectors(team_mate.angles);
  79
  80                                                 for(pc = 0; pc != 5; ++pc) // test 5 diffrent spots close to mate
  81                                                 {
  82                                                         switch(pc)
  83                                                         {
  84                                                                 case 0:
  85                                                                         tracebox(team_mate.origin , PL_MIN, PL_MAX, team_mate.origin + v_right * 128, MOVE_NORMAL, team_mate);
  86                                                                         break;
  87                                                                 case 1:
  88                                                                         tracebox(team_mate.origin , PL_MIN, PL_MAX, team_mate.origin - v_right * 128 , MOVE_NORMAL, team_mate);
  89                                                                         break;
  90                                                                 case 2:
  91                                                                         tracebox(team_mate.origin , PL_MIN, PL_MAX, team_mate.origin + v_right * 64 - v_forward * 64, MOVE_NORMAL, team_mate);
  92                                                                         break;
  93                                                                 case 3:
  94                                                                         tracebox(team_mate.origin , PL_MIN, PL_MAX, team_mate.origin - v_right * 64 - v_forward * 64, MOVE_NORMAL, team_mate);
  95                                                                         break;
  96                                                                 case 4:
  97                                                                         tracebox(team_mate.origin , PL_MIN, PL_MAX, team_mate.origin - v_forward * 128, MOVE_NORMAL, team_mate);
  98                                                                         break;
  99                                                         }
 100
 101                                                         if(trace_fraction == 1.0)
 102                                                         {
 103                                                                 traceline(trace_endpos + '0 0 4', trace_endpos - '0 0 100', MOVE_NORMAL, team_mate);
 104                                                                 if(trace_fraction != 1.0)
 105                                                                 {
 106                                                                         if(autocvar_g_spawn_near_teammate_ignore_spawnpoint_closetodeath)
 107                                                                         {
 108                                                                                 dist = vlen(trace_endpos - self.msnt_deathloc);
 109                                                                                 if(dist < best_dist || best_dist == 0)
 110                                                                                 {
 111                                                                                         best_dist = dist;
 112                                                                                         best_spot = trace_endpos;
 113                                                                                         best_mate = team_mate;
 114                                                                                 }
 115                                                                         }
 116                                                                         else
 117                                                                         {
 118                                                                                 setorigin(self, trace_endpos);
 119                                                                                 self.angles = team_mate.angles;
 120                                                                                 self.angles_z = 0; // never spawn tilted even if the spot says to
 121                                                                                 team_mate.msnt_timer = time + autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay;
 122                                                                                 return 0;
 123                                                                         }
 124                                                                 }
 125                                                         }
 126                                                 }
 127                                         }
 128                                 }
 129                         }
 130                 }
 131
 132                 if(autocvar_g_spawn_near_teammate_ignore_spawnpoint_closetodeath)
 133                 if(best_dist)
 134                 {
 135                         setorigin(self, best_spot);
 136                         self.angles = best_mate.angles;
 137                         self.angles_z = 0; // never spawn tilted even if the spot says to
 138                         best_mate.msnt_timer = time + autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay;
 139                 }
 140         }
 141         else if(spawn_spot.msnt_lookat)
 142         {
 143                 self.angles = vectoangles(spawn_spot.msnt_lookat.origin - self.origin);
 144                 self.angles_x = -self.angles.x;
 145                 self.angles_z = 0; // never spawn tilted even if the spot says to
 146                 /*
 147                 sprint(self, "You should be looking at ", spawn_spot.msnt_lookat.netname, "^7.\n");
 148                 sprint(self, "distance: ", vtos(spawn_spot.msnt_lookat.origin - self.origin), "\n");
 149                 sprint(self, "angles: ", vtos(self.angles), "\n");
 150                 */
 151         }
 152
 153         return 0;
 154 }
 155
 156 MUTATOR_HOOKFUNCTION(msnt_PlayerDies)
 157 {SELFPARAM();
 158         self.msnt_deathloc = self.origin;
 159         return 0;
 160 }
 161
 162 MUTATOR_HOOKFUNCTION(msnt_GetCvars)
 163 {
 164         GetCvars_handleFloat(get_cvars_s, get_cvars_f, cvar_cl_spawn_near_teammate, "cl_spawn_near_teammate");
 165         return false;
 166 }
 167
 168 MUTATOR_DEFINITION(mutator_spawn_near_teammate)
 169 {
 170         MUTATOR_HOOK(Spawn_Score, msnt_Spawn_Score, CBC_ORDER_ANY);
 171         MUTATOR_HOOK(PlayerSpawn, msnt_PlayerSpawn, CBC_ORDER_ANY);
 172         MUTATOR_HOOK(PlayerDies, msnt_PlayerDies, CBC_ORDER_ANY);
 173         MUTATOR_HOOK(GetCvars, msnt_GetCvars, CBC_ORDER_ANY);
 174
 175         return 0;
 176 }