qcsrc/server/mutators/sandbox.qc

   1 .string object_clipboard;
   2
   3 entity sandbox_EditObject()
   4 {
   5         // returns the traced entity if the player can edit it, and world if not
   6
   7         makevectors(self.v_angle);
   8         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_edit, MOVE_NORMAL, self);
   9         if(trace_ent.classname == "object" && trace_ent.realowner == self)
  10                 return trace_ent;
  11         else
  12                 return world;
  13 }
  14
  15 entity sandbox_SpawnObject()
  16 {
  17         // spawn a new object with default properties
  18
  19         entity e;
  20         e = spawn();
  21         e.realowner = self;
  22         e.classname = "object";
  23         e.takedamage = DAMAGE_AIM;
  24         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
  25         e.movetype = MOVETYPE_TOSS;
  26         e.frame = 0;
  27         e.skin = 0;
  28
  29         // set origin and direction based on player position and view angle
  30         makevectors(self.v_angle);
  31         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
  32         setorigin(e, trace_endpos);
  33         e.angles_y = self.v_angle_y;
  34
  35         return e;
  36 }
  37
  38 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
  39 {
  40         if(MUTATOR_RETURNVALUE) // command was already handled?
  41                 return FALSE;
  42         if(cmd_name == "g_sandbox")
  43         {
  44                 if(cmd_argc < 2)
  45                 {
  46                         print_to(self, "Sandbox mode is active. For usage information, type 'sandbox help'");
  47                         return TRUE;
  48                 }
  49
  50                 switch(argv(1))
  51                 {
  52                         entity e;
  53
  54                         // ---------------- COMMAND: HELP ----------------
  55                         case "help":
  56                                 print_to(self, "You can use the following sandbox commands:");
  57                                 print_to(self, "^7\"^2spawn_item ^3item^7\" spawns the specified item in front of the player. Only weapons are currently supported");
  58                                 print_to(self, "^7\"^2spawn_object ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
  59                                 print_to(self, "^7\"^2remove_object^7\" removes the object the player is looking at. Players can only remove their own objects");
  60                                 print_to(self, "^7\"^2duplicate_object_copy^7\" copies the object the player is looking at. Players can only copy their own objects");
  61                                 print_to(self, "^7\"^2duplicate_object_paste^7\" pastes the copied object in front of the player");
  62                                 print_to(self, "^7\"^2edit_object ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
  63                                 print_to(self, "^7Object properties for ^2edit_object^7:");
  64                                 print_to(self, "^3skin ^7- changes the skin of the object");
  65                                 print_to(self, "^3alpha ^7- sets object transparency");
  66                                 print_to(self, "^3frame ^7- object animation frame, for self-animated models");
  67                                 print_to(self, "^3scale ^7- changes object scale. 0.5 is half size and 2 is double size");
  68                                 print_to(self, "^3physics ^7- object physics, 0 = static, 1 = movable, 2 = physical");
  69                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
  70                                 return TRUE;
  71
  72                         // ---------------- COMMAND: SPAWN ITEM ----------------
  73                         case "spawn_item":
  74                                 // only weapons are currently supported
  75
  76                                 if(cmd_argc < 3)
  77                                 {
  78                                         print_to(self, "WARNING: Attempted to spawn an item without specifying its type. Please specify the name of your item after the 'spawn_item' command");
  79                                         return TRUE;
  80                                 }
  81
  82                                 // spawn a new item
  83                                 float i;
  84                                 makevectors(self.v_angle);
  85                                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NOMONSTERS, self);
  86
  87                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  88                                 {
  89                                         e = get_weaponinfo(i);
  90                                         if(e.netname == argv(2))
  91                                         {
  92                                                 W_ThrowNewWeapon(self, i, FALSE, trace_endpos, '0 0 0');
  93                                                 if(autocvar_g_sandbox_info)
  94                                                         print(strcat(self.netname, " spawned a ^2", e.netname, "^7 at origin ", vtos(e.origin), "\n"));
  95                                                 return TRUE;
  96                                         }
  97                                 }
  98
  99                                 print_to(self, "WARNING: Attempted to spawn an invalid or unsupported item. See 'sandbox help' for allowed items");
 100                                 return TRUE;
 101
 102                         // ---------------- COMMAND: SPAWN OBJECT ----------------
 103                         case "spawn_object":
 104                                 // don't allow spawning objects without a model
 105                                 if(cmd_argc < 3)
 106                                 {
 107                                         print_to(self, "WARNING: Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'spawn_object' command");
 108                                         return TRUE;
 109                                 }
 110                                 else if not(fexists(argv(2)))
 111                                 {
 112                                         print_to(self, "WARNING: Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 113                                         return TRUE;
 114                                 }
 115
 116                                 e = sandbox_SpawnObject();
 117                                 setmodel(e, argv(2));
 118
 119                                 if(autocvar_g_sandbox_info)
 120                                         print(strcat(self.netname, " spawned an object at origin ", vtos(e.origin), "\n"));
 121
 122                                 return TRUE;
 123
 124                         // ---------------- COMMAND: REMOVE OBJECT ----------------
 125                         case "remove_object":
 126                                 e = sandbox_EditObject();
 127                                 if(e != world)
 128                                 {
 129                                         if(autocvar_g_sandbox_info)
 130                                                 print(strcat(self.netname, " removed an object at origin ", vtos(e.origin), "\n"));
 131                                         remove(e);
 132                                         e = world;
 133                                         return TRUE;
 134                                 }
 135
 136                                 print_to(self, "WARNING: Object could not be removed. Make sure you are facing an object that belongs to you");
 137                                 return TRUE;
 138
 139                         // ---------------- COMMAND: DUPLICATE OBJECT COPY ----------------
 140                         case "duplicate_object_copy":
 141                                 // copies customizable properties of the selected object to the clipboard
 142
 143                                 e = sandbox_EditObject(); // you can only copy objects you can edit, so this works
 144                                 if(e != world)
 145                                 {
 146                                         if(self.object_clipboard)
 147                                                 strunzone(self.object_clipboard);
 148
 149                                         // set clipboard properties
 150                                         self.object_clipboard = strcat(e.model, " ");
 151                                         self.object_clipboard = strcat(self.object_clipboard, ftos(e.skin), " ");
 152                                         self.object_clipboard = strcat(self.object_clipboard, ftos(e.alpha), " ");
 153                                         self.object_clipboard = strcat(self.object_clipboard, ftos(e.frame), " ");
 154                                         self.object_clipboard = strcat(self.object_clipboard, ftos(e.scale), " ");
 155                                         self.object_clipboard = strcat(self.object_clipboard, ftos(e.movetype), " ");
 156
 157                                         self.object_clipboard = strzone(self.object_clipboard);
 158                                         print_to(self, "Object copied to clipboard");
 159                                         return TRUE;
 160                                 }
 161
 162                                 print_to(self, "WARNING: Object could not be copied. Make sure you are facing an object that belongs to you");
 163                                 return TRUE;
 164
 165                         // ---------------- COMMAND: DUPLICATE OBJECT PASTE ----------------
 166                         case "duplicate_object_paste":
 167                                 // spawns a new object using the properties in the player's clipboard
 168
 169                                 if(!self.object_clipboard) // no object in clipboard
 170                                 {
 171                                         print_to(self, "WARNING: No object in clipboard. You must copy an object before you can paste it");
 172                                         return TRUE;
 173                                 }
 174
 175                                 e = sandbox_SpawnObject();
 176                                 tokenize_console(self.object_clipboard);
 177
 178                                 // apply clipboard properties
 179                                 setmodel(e, argv(0));
 180                                 e.skin = stof(argv(1));
 181                                 e.alpha = stof(argv(2));
 182                                 e.frame = stof(argv(3));
 183                                 e.scale = stof(argv(4));        setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
 184                                 e.movetype = stof(argv(5));
 185
 186                                 print_to(self, "Object pasted");
 187                                 if(autocvar_g_sandbox_info)
 188                                         print(strcat(self.netname, " pasted an object at origin ", vtos(e.origin), "\n"));
 189
 190                                 return TRUE;
 191
 192                         // ---------------- COMMAND: EDIT OBJECT ----------------
 193                         case "edit_object":
 194                                 if(!argv(2) || !argv(3))
 195                                 {
 196                                         print_to(self, "WARNING: Too few parameters. You must specify a property to edit, followed by its value");
 197                                         return TRUE;
 198                                 }
 199
 200                                 e = sandbox_EditObject();
 201                                 if(e != world)
 202                                 {
 203                                         switch(argv(2))
 204                                         {
 205                                                 case "skin":
 206                                                         e.skin = stof(argv(3));
 207                                                         break;
 208                                                 case "alpha":
 209                                                         e.alpha = stof(argv(3));
 210                                                         break;
 211                                                 case "frame":
 212                                                         e.frame = stof(argv(3));
 213                                                         break;
 214                                                 case "scale":
 215                                                         e.scale = stof(argv(3));
 216                                                         setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
 217                                                         break;
 218                                                 case "physics":
 219                                                         switch(argv(3))
 220                                                         {
 221                                                                 case "0": // static
 222                                                                         e.movetype = MOVETYPE_NONE;
 223                                                                         break;
 224                                                                 case "1": // movable
 225                                                                         e.movetype = MOVETYPE_TOSS;
 226                                                                         break;
 227                                                                 case "2": // physical
 228                                                                         e.movetype = MOVETYPE_PHYSICS;
 229                                                                         break;
 230                                                                 default:
 231                                                                         break;
 232                                                         }
 233                                                         break;
 234                                                 default:
 235                                                         print_to(self, "WARNING: Invalid object property. For usage information, type 'sandbox help'");
 236                                                         break;
 237                                         }
 238
 239                                         return TRUE;
 240                                 }
 241
 242                                 print_to(self, "WARNING: Object could not be edited. Make sure you are facing an object that belongs to you");
 243                                 return TRUE;
 244
 245                         // ---------------- COMMAND: DEFAULT ----------------
 246                         default:
 247                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
 248                                 return TRUE;
 249                 }
 250         }
 251         return FALSE;
 252 }
 253
 254 MUTATOR_HOOKFUNCTION(sandbox_PlayerPreThink)
 255 {
 256         // if the player is close enough to their object, they can drag it
 257
 258         if(autocvar_sv_cheats)
 259                 return FALSE; // cheat dragging is used instead
 260
 261         // grab is TRUE if the object can be picked up. While an object is being carried, the Drag() function
 262         // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 263         // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 264         // it goes out of range while slinging it around.
 265
 266         entity e;
 267         float grab;
 268
 269         e = sandbox_EditObject();
 270         if(e != world && vlen(e.origin - self.origin) <= autocvar_g_sandbox_editor_distance_edit)
 271                 grab = TRUE;
 272
 273         if(Drag(e, grab)) // execute dragging
 274         {
 275                 if(autocvar_g_sandbox_info)
 276                         print(strcat(self.netname, " grabbed an object at origin ", vtos(e.origin), "\n"));
 277                 return TRUE;
 278         }
 279
 280         return FALSE;
 281 }
 282
 283 MUTATOR_HOOKFUNCTION(sandbox_ClientDisconnect)
 284 {
 285         // unzone the player's clipboard if it's not empty
 286         if(self.object_clipboard)
 287         {
 288                 strunzone(self.object_clipboard);
 289                 self.object_clipboard = string_null;
 290         }
 291
 292         return FALSE;
 293 }
 294
 295 MUTATOR_DEFINITION(sandbox)
 296 {
 297         MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
 298         MUTATOR_HOOK(PlayerPreThink, sandbox_PlayerPreThink, CBC_ORDER_ANY);
 299         MUTATOR_HOOK(ClientDisconnect, sandbox_ClientDisconnect, CBC_ORDER_ANY);
 300
 301         return FALSE;
 302 }