qcsrc/server/mutators/sandbox.qc

   1 .string object_clipboard;
   2
   3 entity sandbox_EditObject()
   4 {
   5         // returns the traced entity if the player can edit it, and world if not
   6
   7         makevectors(self.v_angle);
   8         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_edit, MOVE_NORMAL, self);
   9         if(trace_ent.classname == "object" && trace_ent.realowner == self)
  10                 return trace_ent;
  11         else
  12                 return world;
  13 }
  14
  15 entity sandbox_SpawnObject()
  16 {
  17         // spawn a new object with default properties
  18
  19         entity e;
  20         e = spawn();
  21         e.realowner = self;
  22         e.classname = "object";
  23         e.takedamage = DAMAGE_AIM;
  24         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
  25         e.movetype = MOVETYPE_TOSS;
  26         e.frame = 0;
  27         e.skin = 0;
  28
  29         // set origin and direction based on player position and view angle
  30         makevectors(self.v_angle);
  31         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
  32         setorigin(e, trace_endpos);
  33         e.angles_y = self.v_angle_y;
  34
  35         return e;
  36 }
  37
  38 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
  39 {
  40         if(MUTATOR_RETURNVALUE) // command was already handled?
  41                 return FALSE;
  42         if(cmd_name == "g_sandbox")
  43         {
  44                 if(cmd_argc < 2)
  45                 {
  46                         print_to(self, "Sandbox mode is active. For usage information, type 'sandbox help'");
  47                         return TRUE;
  48                 }
  49
  50                 switch(argv(1))
  51                 {
  52                         entity e;
  53
  54                         // ---------------- COMMAND: HELP ----------------
  55                         case "help":
  56                                 print_to(self, "You can use the following sandbox commands:");
  57                                 print_to(self, "^7\"^2spawn_item ^3item^7\" spawns the specified item in front of the player. Only weapons are currently supported");
  58                                 print_to(self, "^7\"^2spawn_object ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
  59                                 print_to(self, "^7\"^2remove_object^7\" removes the object the player is looking at. Players can only remove their own objects");
  60                                 print_to(self, "^7\"^2duplicate_object_copy^7\" copies the object the player is looking at. Players can only copy their own objects");
  61                                 print_to(self, "^7\"^2duplicate_object_paste^7\" pastes the copied object in front of the player");
  62                                 print_to(self, "^7\"^2edit_object ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
  63                                 print_to(self, "^7Object properties for ^2edit_object^7:");
  64                                 print_to(self, "^3skin ^7- changes the skin of the object");
  65                                 print_to(self, "^3frame ^7- object animation frame, for self-animated models");
  66                                 print_to(self, "^3scale ^7- changes object scale. 0.5 is half size and 2 is double size");
  67                                 print_to(self, "^3physics ^7- object physics, 0 = static, 1 = movable, 2 = physical");
  68                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
  69                                 return TRUE;
  70
  71                         // ---------------- COMMAND: SPAWN ITEM ----------------
  72                         case "spawn_item":
  73                                 // only weapons are currently supported
  74
  75                                 if(cmd_argc < 3)
  76                                 {
  77                                         print_to(self, "WARNING: Attempted to spawn an item without specifying its type. Please specify the name of your item after the 'spawn_item' command");
  78                                         return TRUE;
  79                                 }
  80
  81                                 // spawn a new item
  82                                 float i;
  83                                 makevectors(self.v_angle);
  84                                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NOMONSTERS, self);
  85
  86                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  87                                 {
  88                                         e = get_weaponinfo(i);
  89                                         if(e.netname == argv(2))
  90                                         {
  91                                                 W_ThrowNewWeapon(self, i, FALSE, trace_endpos, '0 0 0');
  92                                                 if(autocvar_g_sandbox_info)
  93                                                         print(strcat(self.netname, " spawned a ^2", e.netname, "^7 at origin ", vtos(e.origin), "\n"));
  94                                                 return TRUE;
  95                                         }
  96                                 }
  97
  98                                 print_to(self, "WARNING: Attempted to spawn an invalid or unsupported item. See 'sandbox help' for allowed items");
  99                                 return TRUE;
 100
 101                         // ---------------- COMMAND: SPAWN OBJECT ----------------
 102                         case "spawn_object":
 103                                 // don't allow spawning objects without a model
 104                                 if(cmd_argc < 3)
 105                                 {
 106                                         print_to(self, "WARNING: Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'spawn_object' command");
 107                                         return TRUE;
 108                                 }
 109                                 else if not(fexists(argv(2)))
 110                                 {
 111                                         print_to(self, "WARNING: Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 112                                         return TRUE;
 113                                 }
 114
 115                                 e = sandbox_SpawnObject();
 116                                 setmodel(e, argv(2));
 117
 118                                 if(autocvar_g_sandbox_info)
 119                                         print(strcat(self.netname, " spawned an object at origin ", vtos(e.origin), "\n"));
 120
 121                                 return TRUE;
 122
 123                         // ---------------- COMMAND: REMOVE OBJECT ----------------
 124                         case "remove_object":
 125                                 e = sandbox_EditObject();
 126                                 if(e != world)
 127                                 {
 128                                         if(autocvar_g_sandbox_info)
 129                                                 print(strcat(self.netname, " removed an object at origin ", vtos(e.origin), "\n"));
 130                                         remove(e);
 131                                         e = world;
 132                                         return TRUE;
 133                                 }
 134
 135                                 print_to(self, "WARNING: Object could not be removed. Make sure you are facing an object that belongs to you");
 136                                 return TRUE;
 137
 138                         // ---------------- COMMAND: DUPLICATE OBJECT COPY ----------------
 139                         case "duplicate_object_copy":
 140                                 // copies customizable properties of the selected object to the clipboard
 141
 142                                 e = sandbox_EditObject(); // you can only copy objects you can edit, so this works
 143                                 if(e != world)
 144                                 {
 145                                         if(self.object_clipboard)
 146                                                 strunzone(self.object_clipboard);
 147
 148                                         // set clipboard properties
 149                                         self.object_clipboard = strcat(e.model, " ");
 150                                         self.object_clipboard = strcat(self.object_clipboard, ftos(e.skin), " ");
 151                                         self.object_clipboard = strcat(self.object_clipboard, ftos(e.frame), " ");
 152                                         self.object_clipboard = strcat(self.object_clipboard, ftos(e.scale), " ");
 153                                         self.object_clipboard = strcat(self.object_clipboard, ftos(e.movetype), " ");
 154
 155                                         self.object_clipboard = strzone(self.object_clipboard);
 156                                         print_to(self, "Object copied to clipboard");
 157                                         return TRUE;
 158                                 }
 159
 160                                 print_to(self, "WARNING: Object could not be copied. Make sure you are facing an object that belongs to you");
 161                                 return TRUE;
 162
 163                         // ---------------- COMMAND: DUPLICATE OBJECT PASTE ----------------
 164                         case "duplicate_object_paste":
 165                                 // spawns a new object using the properties in the player's clipboard
 166
 167                                 if(!self.object_clipboard) // no object in clipboard
 168                                 {
 169                                         print_to(self, "WARNING: No object in clipboard. You must copy an object before you can paste it");
 170                                         return TRUE;
 171                                 }
 172
 173                                 e = sandbox_SpawnObject();
 174                                 tokenize_console(self.object_clipboard);
 175
 176                                 // apply clipboard properties
 177                                 setmodel(e, argv(0));
 178                                 e.skin = stof(argv(1));
 179                                 e.frame = stof(argv(2));
 180                                 e.scale = stof(argv(3));        setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
 181                                 e.movetype = stof(argv(4));
 182
 183                                 print_to(self, "Object pasted");
 184                                 if(autocvar_g_sandbox_info)
 185                                         print(strcat(self.netname, " pasted an object at origin ", vtos(e.origin), "\n"));
 186
 187                                 return TRUE;
 188
 189                         // ---------------- COMMAND: EDIT OBJECT ----------------
 190                         case "edit_object":
 191                                 if(!argv(2) || !argv(3))
 192                                 {
 193                                         print_to(self, "WARNING: Too few parameters. You must specify a property to edit, followed by its value");
 194                                         return TRUE;
 195                                 }
 196
 197                                 e = sandbox_EditObject();
 198                                 if(e != world)
 199                                 {
 200                                         switch(argv(2))
 201                                         {
 202                                                 case "skin":
 203                                                         e.skin = stof(argv(3));
 204                                                         break;
 205                                                 case "frame":
 206                                                         e.frame = stof(argv(3));
 207                                                         break;
 208                                                 case "scale":
 209                                                         e.scale = stof(argv(3));
 210                                                         setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
 211                                                         break;
 212                                                 case "physics":
 213                                                         switch(argv(3))
 214                                                         {
 215                                                                 case "0": // static
 216                                                                         e.movetype = MOVETYPE_NONE;
 217                                                                         break;
 218                                                                 case "1": // movable
 219                                                                         e.movetype = MOVETYPE_TOSS;
 220                                                                         break;
 221                                                                 case "2": // physical
 222                                                                         e.movetype = MOVETYPE_PHYSICS;
 223                                                                         break;
 224                                                                 default:
 225                                                                         break;
 226                                                         }
 227                                                         break;
 228                                                 default:
 229                                                         print_to(self, "WARNING: Invalid object property. For usage information, type 'sandbox help'");
 230                                                         break;
 231                                         }
 232
 233                                         return TRUE;
 234                                 }
 235
 236                                 print_to(self, "WARNING: Object could not be edited. Make sure you are facing an object that belongs to you");
 237                                 return TRUE;
 238
 239                         // ---------------- COMMAND: DEFAULT ----------------
 240                         default:
 241                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
 242                                 return TRUE;
 243                 }
 244         }
 245         return FALSE;
 246 }
 247
 248 MUTATOR_HOOKFUNCTION(sandbox_PlayerPreThink)
 249 {
 250         // if the player is close enough to their object, they can drag it
 251
 252         if(autocvar_sv_cheats)
 253                 return FALSE; // cheat dragging is used instead
 254
 255         // grab is TRUE if the object can be picked up. While an object is being carried, the Drag() function
 256         // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 257         // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 258         // it goes out of range while slinging it around.
 259
 260         entity e;
 261         float grab;
 262
 263         e = sandbox_EditObject();
 264         if(e != world && vlen(e.origin - self.origin) <= autocvar_g_sandbox_editor_distance_edit)
 265                 grab = TRUE;
 266
 267         if(Drag(e, grab)) // execute dragging
 268         {
 269                 if(autocvar_g_sandbox_info)
 270                         print(strcat(self.netname, " grabbed an object at origin ", vtos(e.origin), "\n"));
 271                 return TRUE;
 272         }
 273
 274         return FALSE;
 275 }
 276
 277 MUTATOR_HOOKFUNCTION(sandbox_ClientDisconnect)
 278 {
 279         // unzone the player's clipboard if it's not empty
 280         if(self.object_clipboard)
 281         {
 282                 strunzone(self.object_clipboard);
 283                 self.object_clipboard = string_null;
 284         }
 285
 286         return FALSE;
 287 }
 288
 289 MUTATOR_DEFINITION(sandbox)
 290 {
 291         MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
 292         MUTATOR_HOOK(PlayerPreThink, sandbox_PlayerPreThink, CBC_ORDER_ANY);
 293         MUTATOR_HOOK(ClientDisconnect, sandbox_ClientDisconnect, CBC_ORDER_ANY);
 294
 295         return FALSE;
 296 }