qcsrc/server/mutators/sandbox.qc

   1 const float MAX_STORAGE_ATTACHMENTS = 16;
   2 float object_count;
   3 .string object_clipboard;
   4 .entity object_attach;
   5 .string material;
   6
   7 .float touch_timer;
   8 void sandbox_ObjectFunction_Touch()
   9 {
  10         // apply material impact effects
  11
  12         if(!self.material)
  13                 return;
  14         if(self.touch_timer > time)
  15                 return; // don't execute each frame
  16         self.touch_timer = time + 0.1;
  17
  18         // make particle count and sound volume depend on impact speed
  19         float intensity;
  20         intensity = vlen(self.velocity) + vlen(other.velocity);
  21         if(intensity) // avoid divisions by 0
  22                 intensity /= 2; // average the two velocities
  23         if not(intensity >= autocvar_g_sandbox_object_material_velocity_min)
  24                 return; // impact not strong enough to do anything
  25         // now offset intensity and apply it to the effects
  26         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
  27         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
  28
  29         sound(self, CH_TRIGGER, strcat("object/impact_", self.material, "_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE * intensity, ATTN_NORM);
  30         pointparticles(particleeffectnum(strcat("impact_", self.material)), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  31 }
  32
  33 entity sandbox_ObjectEdit_Get(float permissions)
  34 {
  35         // returns the traced entity if the player can edit it, and world if not
  36         // if permissions if FALSE, the object is returned regardless of editing rights
  37         // attached objects are SOLID_NOT and don't risk getting traced
  38
  39         makevectors(self.v_angle);
  40         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_edit, MOVE_NORMAL, self);
  41
  42         if(trace_ent.classname != "object")
  43                 return world; // entity is not an object
  44         if(!permissions)
  45                 return trace_ent; // don't check permissions, anyone can edit this object
  46         if(!trace_ent.crypto_idfp)
  47                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
  48         if not(trace_ent.crypto_idfp != self.crypto_idfp && autocvar_g_sandbox_editor_free < 2)
  49                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
  50         return world;
  51 }
  52
  53 void sandbox_ObjectEdit_Scale(entity e, float f)
  54 {
  55         e.scale = f;
  56         if(e.scale)
  57         {
  58                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
  59                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
  60         }
  61 }
  62
  63 void sandbox_ObjectAttach_Remove(entity e);
  64 void sandbox_ObjectAttach_Set(entity e, entity parent, string s)
  65 {
  66         // attaches e to parent on string s
  67
  68         // we can't attach to an attachment, for obvious reasons
  69         sandbox_ObjectAttach_Remove(e);
  70
  71         e.movetype = MOVETYPE_FOLLOW;
  72         e.solid = SOLID_NOT;
  73         e.takedamage = DAMAGE_NO;
  74
  75         setattachment(e, parent, s);
  76         e.owner = parent;
  77 }
  78
  79 void sandbox_ObjectAttach_Remove(entity e)
  80 {
  81         // detaches any object attached to e
  82
  83         entity head;
  84         for(head = world; (head = find(head, classname, "object")); )
  85         {
  86                 if(head.owner == e)
  87                 {
  88                         vector org;
  89                         head.movetype = MOVETYPE_TOSS; // default
  90                         head.solid = SOLID_BBOX;
  91                         head.takedamage = DAMAGE_AIM;
  92
  93                         org = gettaginfo(head, 0);
  94                         setattachment(head, world, "");
  95                         head.owner = world;
  96
  97                         // objects change origin and angles when detached, so apply previous position
  98                         setorigin(head, org);
  99                         head.angles = e.angles; // don't allow detached objects to spin or roll
 100                 }
 101         }
 102 }
 103
 104 entity sandbox_ObjectSpawn(float database)
 105 {
 106         // spawn a new object with default properties
 107
 108         entity e;
 109         e = spawn();
 110         e.classname = "object";
 111         e.takedamage = DAMAGE_AIM;
 112         e.damageforcescale = 1;
 113         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
 114         e.movetype = MOVETYPE_TOSS;
 115         e.frame = 0;
 116         e.skin = 0;
 117         e.material = string_null;
 118         e.touch = sandbox_ObjectFunction_Touch;
 119
 120         if(!database)
 121         {
 122                 // set the object's owner via player UID
 123                 // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
 124                 if(self.crypto_idfp != "")
 125                         e.crypto_idfp = strzone(self.crypto_idfp);
 126                 else
 127                         print_to(self, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
 128
 129                 // set origin and direction based on player position and view angle
 130                 makevectors(self.v_angle);
 131                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
 132                 setorigin(e, trace_endpos);
 133                 e.angles_y = self.v_angle_y;
 134         }
 135
 136         object_count += 1;
 137         return e;
 138 }
 139
 140 void sandbox_ObjectRemove(entity e)
 141 {
 142         sandbox_ObjectAttach_Remove(e); // detach child objects
 143         if(e.material)
 144         {
 145                 strunzone(e.material);
 146                 e.material = string_null;
 147         }
 148         if(e.crypto_idfp)
 149         {
 150                 strunzone(e.crypto_idfp);
 151                 e.crypto_idfp = string_null;
 152         }
 153         remove(e);
 154         e = world;
 155
 156         object_count -= 1;
 157 }
 158
 159 string port_string[MAX_STORAGE_ATTACHMENTS]; // fteqcc crashes if this isn't defined as a global
 160
 161 string sandbox_ObjectPort_Save(entity e, float database)
 162 {
 163         // save object properties, and return them as a string
 164         float i;
 165         string s;
 166         entity head;
 167
 168         for(head = world; (head = find(head, classname, "object")); )
 169         {
 170                 // the main object needs to be first in the array [0] with attached objects following
 171                 float slot;
 172                 string tagindex;
 173                 if(head == e) // this is the main object, place it first
 174                 {
 175                         slot = 0;
 176                         tagindex = string_null;
 177                 }
 178                 else if(head.owner == e) // child object, list them in order
 179                 {
 180                         i += 1; // children start from 1
 181                         slot = i;
 182
 183                         // get the name of the tag our object is attached to
 184                         gettaginfo(head.owner, head.tag_index);
 185                         tagindex = gettaginfo_name;
 186                 }
 187                 else
 188                         continue;
 189
 190                 port_string[slot] = strcat(port_string[slot], "\"", head.model, "\" ");
 191                 port_string[slot] = strcat(port_string[slot], ftos(head.skin), " ");
 192                 port_string[slot] = strcat(port_string[slot], ftos(head.alpha), " ");
 193                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.colormod), " ");
 194                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.glowmod), " ");
 195                 port_string[slot] = strcat(port_string[slot], ftos(head.frame), " ");
 196                 port_string[slot] = strcat(port_string[slot], ftos(head.scale), " ");
 197                 port_string[slot] = strcat(port_string[slot], ftos(head.movetype), " ");
 198                 port_string[slot] = strcat(port_string[slot], ftos(head.damageforcescale), " ");
 199                 if(head.material)       port_string[slot] = strcat(port_string[slot], "\"", head.material, "\" ");      else    port_string[slot] = strcat(port_string[slot], "- "); // none
 200                 if(tagindex)    port_string[slot] = strcat(port_string[slot], "\"", tagindex, "\" ");   else    port_string[slot] = strcat(port_string[slot], "- "); // none
 201                 if(database)
 202                 {
 203                         if(head.crypto_idfp)    port_string[slot] = strcat(port_string[slot], "\"", head.crypto_idfp, "\" ");   else    port_string[slot] = strcat(port_string[slot], "- "); // none
 204                         port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.origin), " ");
 205                         port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.angles), " ");
 206                 }
 207         }
 208
 209         // now apply the array to a simple string, with the ; symbol separating objects
 210         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 211         {
 212                 if(port_string[i])
 213                         s = strcat(s, port_string[i], "; ");
 214                 port_string[i] = string_null; // fully clear the string
 215         }
 216
 217         return s;
 218 }
 219
 220 entity sandbox_ObjectPort_Load(string s, float database)
 221 {
 222         // load object properties, and spawn a new object with them
 223         float n, i;
 224         entity e, parent;
 225
 226         // separate objects between the ; symbols
 227         n = tokenizebyseparator(s, "; ");
 228         for(i = 0; i < n; ++i)
 229                 port_string[i] = argv(i);
 230
 231         // now separate and apply the properties of each object
 232         for(i = 0; i < n; ++i)
 233         {
 234                 string taginfo;
 235                 tokenize_console(port_string[i]);
 236                 e = sandbox_ObjectSpawn(database);
 237
 238                 setmodel(e, argv(0));
 239                 e.skin = stof(argv(1));
 240                 e.alpha = stof(argv(2));
 241                 e.colormod = stov(argv(3));
 242                 e.glowmod = stov(argv(4));
 243                 e.frame = stof(argv(5));
 244                 sandbox_ObjectEdit_Scale(e, stof(argv(6)));
 245                 e.movetype = stof(argv(7));
 246                 e.damageforcescale = stof(argv(8));
 247                 if(e.material)  strunzone(e.material);  if(argv(9) != "-")      e.material = strzone(argv(9));  else    e.material = string_null;
 248                 if(argv(10) != "-")     taginfo = argv(10);     else    taginfo = string_null;
 249                 if(database)
 250                 {
 251                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);       if(argv(11) != "-")     e.crypto_idfp = strzone(argv(11));      else    e.crypto_idfp = string_null;
 252                         setorigin(e, stov(argv(12)));
 253                         e.angles = stov(argv(13));
 254                 }
 255
 256                 if(!i) // parent object, set it as such and leave it be
 257                         parent = e;
 258                 else // child object, attach it to the parent
 259                         sandbox_ObjectAttach_Set(e, parent, taginfo);
 260         }
 261
 262         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 263                 port_string[i] = string_null; // fully clear the string
 264
 265         return e;
 266 }
 267
 268 void sandbox_Database_Save()
 269 {
 270         // saves all objects to the database file
 271         entity head;
 272         string file_name;
 273         float file_get;
 274
 275         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 276         file_get = fopen(file_name, FILE_WRITE);
 277         fputs(file_get, strcat("// sandbox storage \"", autocvar_g_sandbox_storage_name, "\" for map \"", GetMapname(), "\" last updated ", strftime(TRUE, "%d-%m-%Y %H:%M:%S")));
 278         fputs(file_get, strcat(" containing ", ftos(object_count), " objects\n"));
 279
 280         for(head = world; (head = find(head, classname, "object")); )
 281         {
 282                 // attached objects are persisted separately, ignore them here
 283                 if(head.owner != world)
 284                         continue;
 285
 286                 // use a line of text for each object, listing all properties
 287                 fputs(file_get, strcat(sandbox_ObjectPort_Save(head, TRUE), "\n"));
 288         }
 289         fclose(file_get);
 290 }
 291
 292 void sandbox_Database_Load()
 293 {
 294         // loads all objects from the database file
 295         string file_read, file_name;
 296         float file_get, i;
 297
 298         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 299         file_get = fopen(file_name, FILE_READ);
 300         if(file_get < 0)
 301         {
 302                 if(autocvar_g_sandbox_info > 0)
 303                         print(strcat("^3SANDBOX - SERVER: ^7could not find storage file ^3", file_name, "^7, no objects were loaded\n"));
 304         }
 305         else
 306         {
 307                 for(;;)
 308                 {
 309                         file_read = fgets(file_get);
 310                         if(!file_read)
 311                                 break;
 312                         if(substring(file_read, 0, 2) == "//")
 313                                 continue;
 314                         if(substring(file_read, 0, 1) == "#")
 315                                 continue;
 316
 317                         entity e;
 318                         e = sandbox_ObjectPort_Load(file_read, TRUE);
 319
 320                         if(e.material)
 321                         {
 322                                 // since objects are being loaded for the first time, precache material sounds for each
 323                                 for (i = 1; i <= 5; i++) // 5 sounds in total
 324                                         precache_sound(strcat("object/impact_", e.material, "_", ftos(i), ".ogg"));
 325                         }
 326                 }
 327                 if(autocvar_g_sandbox_info > 0)
 328                         print(strcat("^3SANDBOX - SERVER: ^7successfully loaded storage file ^3", file_name, "\n"));
 329         }
 330 }
 331
 332 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
 333 {
 334         if(MUTATOR_RETURNVALUE) // command was already handled?
 335                 return FALSE;
 336         if(cmd_name == "g_sandbox")
 337         {
 338                 if(cmd_argc < 2)
 339                 {
 340                         print_to(self, "Sandbox mode is active. For usage information, type 'sandbox help'");
 341                         return TRUE;
 342                 }
 343
 344                 switch(argv(1))
 345                 {
 346                         entity e;
 347                         float i;
 348
 349                         // ---------------- COMMAND: HELP ----------------
 350                         case "help":
 351                                 print_to(self, "You can use the following sandbox commands:");
 352                                 print_to(self, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
 353                                 print_to(self, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
 354                                 print_to(self, "^7\"^2object_duplicate ^3value^7\" duplicates the object. 'copy' copies the object, 'paste' puts it in front of the player");
 355                                 print_to(self, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
 356                                 print_to(self, "^7Attachment properties for ^2object_attach^7:");
 357                                 print_to(self, "^3get ^7- selects the object you are facing as the object to be attached");
 358                                 print_to(self, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
 359                                 print_to(self, "^3remove ^7- detaches all objects from the object you are facing");
 360                                 print_to(self, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
 361                                 print_to(self, "^7Object properties for ^2object_edit^7:");
 362                                 print_to(self, "^3skin value ^7- changes the skin of the object");
 363                                 print_to(self, "^3alpha value ^7- sets object transparency");
 364                                 print_to(self, "^3colormod \"value_x value_y value_z\" ^7- main object color");
 365                                 print_to(self, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
 366                                 print_to(self, "^3frame value ^7- object animation frame, for self-animated models");
 367                                 print_to(self, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
 368                                 print_to(self, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
 369                                 print_to(self, "^3force value ^7- amount of force applied to objects that are shot");
 370                                 print_to(self, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
 371                                 print_to(self, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
 372                                 print_to(self, "^7\"^2object_info ^3value^7\" shows public information about the object. 'mesh' shows model information");
 373                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
 374                                 return TRUE;
 375
 376                         // ---------------- COMMAND: OBJECT, SPAWN ----------------
 377                         case "object_spawn":
 378                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 379                                 {
 380                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 381                                         return TRUE;
 382                                 }
 383                                 if(cmd_argc < 3)
 384                                 {
 385                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
 386                                         return TRUE;
 387                                 }
 388                                 else if not(fexists(argv(2)))
 389                                 {
 390                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 391                                         return TRUE;
 392                                 }
 393
 394                                 e = sandbox_ObjectSpawn(FALSE);
 395                                 setmodel(e, argv(2));
 396
 397                                 if(autocvar_g_sandbox_info > 0)
 398                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " spawned an object at origin ^3", vtos(e.origin), "\n"));
 399                                 return TRUE;
 400
 401                         // ---------------- COMMAND: OBJECT, REMOVE ----------------
 402                         case "object_remove":
 403                                 e = sandbox_ObjectEdit_Get(TRUE);
 404                                 if(e != world)
 405                                 {
 406                                         if(autocvar_g_sandbox_info > 0)
 407                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " removed an object at origin ^3", vtos(e.origin), "\n"));
 408                                         sandbox_ObjectRemove(e);
 409                                         return TRUE;
 410                                 }
 411
 412                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
 413                                 return TRUE;
 414
 415                         // ---------------- COMMAND: OBJECT, DUPLICATE ----------------
 416                         case "object_duplicate":
 417                                 switch(argv(2))
 418                                 {
 419                                         case "copy":
 420                                                 // copies customizable properties of the selected object to the clipboard
 421                                                 e = sandbox_ObjectEdit_Get(autocvar_g_sandbox_editor_free); // can we copy objects we can't edit?
 422                                                 if(e != world)
 423                                                 {
 424                                                         if(self.object_clipboard)
 425                                                                 strunzone(self.object_clipboard);
 426                                                         self.object_clipboard = strzone(sandbox_ObjectPort_Save(e, FALSE));
 427
 428                                                         print_to(self, "^2SANDBOX - INFO: ^7Object copied to clipboard");
 429                                                         return TRUE;
 430                                                 }
 431                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have copy rights over");
 432                                                 return TRUE;
 433
 434                                         case "paste":
 435                                                 // spawns a new object using the properties in the player's clipboard
 436                                                 if(!self.object_clipboard) // no object in clipboard
 437                                                 {
 438                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
 439                                                         return TRUE;
 440                                                 }
 441                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 442                                                 {
 443                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 444                                                         return TRUE;
 445                                                 }
 446
 447                                                 e = sandbox_ObjectPort_Load(self.object_clipboard, FALSE);
 448
 449                                                 print_to(self, "^2SANDBOX - INFO: ^7Object pasted successfully");
 450                                                 if(autocvar_g_sandbox_info > 0)
 451                                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " pasted an object at origin ^3", vtos(e.origin), "\n"));
 452                                                 return TRUE;
 453                                 }
 454                                 return TRUE;
 455
 456                         // ---------------- COMMAND: OBJECT, ATTACH ----------------
 457                         case "object_attach":
 458                                 switch(argv(2))
 459                                 {
 460                                         case "get":
 461                                                 // select e as the object as meant to be attached
 462                                                 e = sandbox_ObjectEdit_Get(TRUE);
 463                                                 if(e != world)
 464                                                 {
 465                                                         self.object_attach = e;
 466                                                         print_to(self, "^2SANDBOX - INFO: ^7Object selected for attachment");
 467                                                         return TRUE;
 468                                                 }
 469                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
 470                                                 return TRUE;
 471                                         case "set":
 472                                                 if(self.object_attach == world)
 473                                                 {
 474                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
 475                                                         return TRUE;
 476                                                 }
 477
 478                                                 // attaches the previously selected object to e
 479                                                 e = sandbox_ObjectEdit_Get(TRUE);
 480                                                 if(e != world)
 481                                                 {
 482                                                         sandbox_ObjectAttach_Set(self.object_attach, e, argv(3));
 483                                                         self.object_attach = world; // object was attached, no longer keep it scheduled for attachment
 484                                                         print_to(self, "^2SANDBOX - INFO: ^7Object attached successfully");
 485                                                         if(autocvar_g_sandbox_info > 1)
 486                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " attached objects at origin ^3", vtos(e.origin), "\n"));
 487                                                         return TRUE;
 488                                                 }
 489                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
 490                                                 return TRUE;
 491                                         case "remove":
 492                                                 // removes e if it was attached
 493                                                 e = sandbox_ObjectEdit_Get(TRUE);
 494                                                 if(e != world)
 495                                                 {
 496                                                         sandbox_ObjectAttach_Remove(e);
 497                                                         print_to(self, "^2SANDBOX - INFO: ^7Child objects detached successfully");
 498                                                         if(autocvar_g_sandbox_info > 1)
 499                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " detached objects at origin ^3", vtos(e.origin), "\n"));
 500                                                         return TRUE;
 501                                                 }
 502                                                 print_to(self, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
 503                                                 return TRUE;
 504                                 }
 505                                 return TRUE;
 506
 507                         // ---------------- COMMAND: OBJECT, EDIT ----------------
 508                         case "object_edit":
 509                                 if(!argv(2))
 510                                 {
 511                                         print_to(self, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
 512                                         return TRUE;
 513                                 }
 514
 515                                 e = sandbox_ObjectEdit_Get(TRUE);
 516                                 if(e != world)
 517                                 {
 518                                         switch(argv(2))
 519                                         {
 520                                                 case "skin":
 521                                                         e.skin = stof(argv(3));
 522                                                         break;
 523                                                 case "alpha":
 524                                                         e.alpha = stof(argv(3));
 525                                                         break;
 526                                                 case "color_main":
 527                                                         e.colormod = stov(argv(3));
 528                                                         break;
 529                                                 case "color_glow":
 530                                                         e.glowmod = stov(argv(3));
 531                                                         break;
 532                                                 case "frame":
 533                                                         e.frame = stof(argv(3));
 534                                                         break;
 535                                                 case "scale":
 536                                                         sandbox_ObjectEdit_Scale(e, stof(argv(3)));
 537                                                         break;
 538                                                 case "physics":
 539                                                         switch(argv(3))
 540                                                         {
 541                                                                 case "0": // static
 542                                                                         e.movetype = MOVETYPE_NONE;
 543                                                                         break;
 544                                                                 case "1": // movable
 545                                                                         e.movetype = MOVETYPE_TOSS;
 546                                                                         break;
 547                                                                 case "2": // physical
 548                                                                         e.movetype = MOVETYPE_PHYSICS;
 549                                                                         break;
 550                                                                 default:
 551                                                                         break;
 552                                                         }
 553                                                         break;
 554                                                 case "force":
 555                                                         e.damageforcescale = stof(argv(3));
 556                                                         break;
 557                                                 case "material":
 558                                                         if(e.material)
 559                                                                 strunzone(e.material);
 560                                                         if(argv(3))
 561                                                         {
 562                                                                 for (i = 1; i <= 5; i++) // precache material sounds, 5 in total
 563                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(i), ".ogg"));
 564                                                                 e.material = strzone(argv(3));
 565                                                         }
 566                                                         else
 567                                                                 e.material = string_null; // no material
 568                                                         break;
 569                                                 default:
 570                                                         print_to(self, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
 571                                                         break;
 572                                         }
 573                                         if(autocvar_g_sandbox_info > 1)
 574                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin), "\n"));
 575                                         return TRUE;
 576                                 }
 577
 578                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
 579                                 return TRUE;
 580
 581                         // ---------------- COMMAND: OBJECT, CLAIM ----------------
 582                         case "object_claim":
 583                                 // if the player can edit an object but is not its owner, this can be used to claim that object
 584                                 if(self.crypto_idfp == "")
 585                                 {
 586                                         print_to(self, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
 587                                         return TRUE;
 588                                 }
 589                                 e = sandbox_ObjectEdit_Get(TRUE);
 590                                 if(e != world)
 591                                 {
 592                                         if(e.crypto_idfp == self.crypto_idfp)
 593                                         {
 594                                                 print_to(self, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
 595                                                 return TRUE;
 596                                         }
 597
 598                                         if(e.crypto_idfp)
 599                                                 strunzone(e.crypto_idfp);
 600                                         e.crypto_idfp = self.crypto_idfp;
 601                                         print_to(self, "^2SANDBOX - INFO: ^7Object claimed successfully");
 602                                 }
 603                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
 604                                 return TRUE;
 605
 606                         // ---------------- COMMAND: OBJECT, INFO ----------------
 607                         case "object_info":
 608                                 // prints public information about the object to the player
 609                                 e = sandbox_ObjectEdit_Get(FALSE);
 610                                 if(e != world)
 611                                 {
 612                                         switch(argv(2))
 613                                         {
 614                                                 case "mesh":
 615                                                         string tags;
 616                                                         for(i = 1; gettaginfo(e, i); i++)
 617                                                                 tags = strcat(tags, "^5", gettaginfo_name, "^7, ");
 618                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object mesh is ^3", e.model, "^7 at animation frame ^3", ftos(e.frame), " ^7containing the following tags: ", tags));
 619                                                         return TRUE;
 620                                         }
 621                                 }
 622                                 print_to(self, "^1SANDBOX - WARNING: ^7No information could not be found. Make sure you are facing an object");
 623                                 return TRUE;
 624
 625                         // ---------------- COMMAND: DEFAULT ----------------
 626                         default:
 627                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
 628                                 return TRUE;
 629                 }
 630         }
 631         return FALSE;
 632 }
 633
 634 MUTATOR_HOOKFUNCTION(sandbox_PlayerPreThink)
 635 {
 636         // if the player is close enough to their object, they can drag it
 637
 638         if(autocvar_sv_cheats)
 639                 return FALSE; // cheat dragging is used instead
 640
 641         // grab is TRUE if the object can be picked up. While an object is being carried, the Drag() function
 642         // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 643         // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 644         // it goes out of range while slinging it around.
 645
 646         entity e;
 647         float grab;
 648
 649         e = sandbox_ObjectEdit_Get(TRUE);
 650         if(e != world && vlen(e.origin - self.origin) <= autocvar_g_sandbox_editor_distance_edit)
 651                 grab = TRUE;
 652
 653         if(Drag(e, grab)) // execute dragging
 654                 return TRUE;
 655
 656         return FALSE;
 657 }
 658
 659 MUTATOR_HOOKFUNCTION(sandbox_ClientDisconnect)
 660 {
 661         // unzone the player's clipboard if it's not empty
 662         if(self.object_clipboard)
 663         {
 664                 strunzone(self.object_clipboard);
 665                 self.object_clipboard = string_null;
 666         }
 667
 668         return FALSE;
 669 }
 670
 671 float autosave_time;
 672 MUTATOR_HOOKFUNCTION(sandbox_StartFrame)
 673 {
 674         if(!autocvar_g_sandbox_storage_autosave)
 675                 return FALSE;
 676         if(time < autosave_time)
 677                 return FALSE;
 678         autosave_time = time + autocvar_g_sandbox_storage_autosave;
 679
 680         sandbox_Database_Save();
 681
 682         return TRUE;
 683 }
 684
 685 MUTATOR_DEFINITION(sandbox)
 686 {
 687         MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
 688         MUTATOR_HOOK(SV_StartFrame, sandbox_StartFrame, CBC_ORDER_ANY);
 689         MUTATOR_HOOK(PlayerPreThink, sandbox_PlayerPreThink, CBC_ORDER_ANY);
 690         MUTATOR_HOOK(ClientDisconnect, sandbox_ClientDisconnect, CBC_ORDER_ANY);
 691
 692         MUTATOR_ONADD
 693         {
 694                 autosave_time = time + autocvar_g_sandbox_storage_autosave; // don't save the first server frame
 695                 if(autocvar_g_sandbox_storage_autoload)
 696                         sandbox_Database_Load();
 697         }
 698
 699         return FALSE;
 700 }
 701