qcsrc/server/mutators/sandbox.qc

   1 .string object_clipboard;
   2 .float material;
   3
   4 const float MATERIAL_METAL = 1;
   5 const float MATERIAL_STONE = 2;
   6 const float MATERIAL_WOOD = 3;
   7 const float MATERIAL_FLESH = 4;
   8
   9 .float touch_timer;
  10 void sandbox_Object_Touch()
  11 {
  12         // apply material impact effects
  13
  14         if(self.touch_timer > time)
  15                 return; // don't execute each frame
  16         self.touch_timer = time + 0.1;
  17         if not(vlen(self.velocity) >= autocvar_g_sandbox_object_matvel || vlen(other.velocity) >= autocvar_g_sandbox_object_matvel)
  18                 return; // impact not strong enough
  19
  20         switch(self.material)
  21         {
  22                 case MATERIAL_METAL:
  23                         sound(self, CH_TRIGGER, strcat("object/impact_metal_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE, ATTN_NORM);
  24                         break;
  25                 case MATERIAL_STONE:
  26                         sound(self, CH_TRIGGER, strcat("object/impact_stone_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE, ATTN_NORM);
  27                         break;
  28                 case MATERIAL_WOOD:
  29                         sound(self, CH_TRIGGER, strcat("object/impact_wood_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE, ATTN_NORM);
  30                         break;
  31                 case MATERIAL_FLESH:
  32                         sound(self, CH_TRIGGER, strcat("object/impact_flesh_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE, ATTN_NORM);
  33                         break;
  34                 default:
  35                         break;
  36         }
  37 }
  38
  39 entity sandbox_EditObject_Get()
  40 {
  41         // returns the traced entity if the player can edit it, and world if not
  42
  43         makevectors(self.v_angle);
  44         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_edit, MOVE_NORMAL, self);
  45         if(trace_ent.classname == "object" && trace_ent.realowner == self)
  46                 return trace_ent;
  47         else
  48                 return world;
  49 }
  50
  51 void sandbox_EditObject_Scale(entity e, float f)
  52 {
  53         e.scale = f;
  54         if(e.scale)
  55         {
  56                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
  57                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
  58         }
  59 }
  60
  61 entity sandbox_SpawnObject()
  62 {
  63         // spawn a new object with default properties
  64
  65         entity e;
  66         e = spawn();
  67         e.realowner = self;
  68         e.classname = "object";
  69         e.takedamage = DAMAGE_AIM;
  70         e.damageforcescale = 1;
  71         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
  72         e.movetype = MOVETYPE_TOSS;
  73         e.frame = 0;
  74         e.skin = 0;
  75         e.material = MATERIAL_METAL;
  76
  77         e.touch = sandbox_Object_Touch;
  78
  79         // set origin and direction based on player position and view angle
  80         makevectors(self.v_angle);
  81         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
  82         setorigin(e, trace_endpos);
  83         e.angles_y = self.v_angle_y;
  84
  85         return e;
  86 }
  87
  88 string sandbox_Storage_Save(entity e)
  89 {
  90         // save object properties
  91         string s;
  92
  93         s = strcat(e.model, " ");
  94         s = strcat(s, ftos(e.skin), " ");
  95         s = strcat(s, ftos(e.alpha), " ");
  96         s = strcat(s, sprintf("\"%.9v\"", e.colormod), " ");
  97         s = strcat(s, sprintf("\"%.9v\"", e.glowmod), " ");
  98         s = strcat(s, ftos(e.frame), " ");
  99         s = strcat(s, ftos(e.scale), " ");
 100         s = strcat(s, ftos(e.movetype), " ");
 101         s = strcat(s, ftos(e.damageforcescale), " ");
 102         s = strcat(s, ftos(e.material), " ");
 103
 104         return s;
 105 }
 106
 107 void sandbox_Storage_Load(entity e, string s)
 108 {
 109         // load object properties
 110         tokenize_console(s);
 111
 112         setmodel(e, argv(0));
 113         e.skin = stof(argv(1));
 114         e.alpha = stof(argv(2));
 115         e.colormod = stov(argv(3));
 116         e.glowmod = stov(argv(4));
 117         e.frame = stof(argv(5));
 118         sandbox_EditObject_Scale(e, stof(argv(6)));
 119         e.movetype = stof(argv(7));
 120         e.damageforcescale = stof(argv(8));
 121         e.material = stof(argv(9));
 122 }
 123
 124 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
 125 {
 126         if(MUTATOR_RETURNVALUE) // command was already handled?
 127                 return FALSE;
 128         if(cmd_name == "g_sandbox")
 129         {
 130                 if(cmd_argc < 2)
 131                 {
 132                         print_to(self, "Sandbox mode is active. For usage information, type 'sandbox help'");
 133                         return TRUE;
 134                 }
 135
 136                 switch(argv(1))
 137                 {
 138                         entity e;
 139
 140                         // ---------------- COMMAND: HELP ----------------
 141                         case "help":
 142                                 print_to(self, "You can use the following sandbox commands:");
 143                                 print_to(self, "^7\"^2spawn_item ^3item^7\" spawns the specified item in front of the player. Only weapons are currently supported");
 144                                 print_to(self, "^7\"^2spawn_object ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
 145                                 print_to(self, "^7\"^2remove_object^7\" removes the object the player is looking at. Players can only remove their own objects");
 146                                 print_to(self, "^7\"^2duplicate_object_copy^7\" copies the object the player is looking at. Players can only copy their own objects");
 147                                 print_to(self, "^7\"^2duplicate_object_paste^7\" pastes the copied object in front of the player");
 148                                 print_to(self, "^7\"^2edit_object ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
 149                                 print_to(self, "^7Object properties for ^2edit_object^7:");
 150                                 print_to(self, "^3skin value ^7- changes the skin of the object");
 151                                 print_to(self, "^3alpha value ^7- sets object transparency");
 152                                 print_to(self, "^3colormod \"value_x value_y value_z\" ^7- main object color");
 153                                 print_to(self, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
 154                                 print_to(self, "^3frame value ^7- object animation frame, for self-animated models");
 155                                 print_to(self, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
 156                                 print_to(self, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
 157                                 print_to(self, "^3force value ^7- amount of force applied to objects that are shot");
 158                                 print_to(self, "^3material value ^7- sets the material of the object. Valid materials are: 1 (metal), 2 (stone), 3 (wood), 4 (flesh)");
 159                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
 160                                 return TRUE;
 161
 162                         // ---------------- COMMAND: SPAWN ITEM ----------------
 163                         case "spawn_item":
 164                                 // only weapons are currently supported
 165
 166                                 if(cmd_argc < 3)
 167                                 {
 168                                         print_to(self, "WARNING: Attempted to spawn an item without specifying its type. Please specify the name of your item after the 'spawn_item' command");
 169                                         return TRUE;
 170                                 }
 171
 172                                 // spawn a new item
 173                                 float i;
 174                                 makevectors(self.v_angle);
 175                                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NOMONSTERS, self);
 176
 177                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 178                                 {
 179                                         e = get_weaponinfo(i);
 180                                         if(e.netname == argv(2))
 181                                         {
 182                                                 W_ThrowNewWeapon(self, i, FALSE, trace_endpos, '0 0 0');
 183                                                 if(autocvar_g_sandbox_info)
 184                                                         print(strcat(self.netname, " spawned a ^2", e.netname, "^7 at origin ", vtos(e.origin), "\n"));
 185                                                 return TRUE;
 186                                         }
 187                                 }
 188
 189                                 print_to(self, "WARNING: Attempted to spawn an invalid or unsupported item. See 'sandbox help' for allowed items");
 190                                 return TRUE;
 191
 192                         // ---------------- COMMAND: SPAWN OBJECT ----------------
 193                         case "spawn_object":
 194                                 // don't allow spawning objects without a model
 195                                 if(cmd_argc < 3)
 196                                 {
 197                                         print_to(self, "WARNING: Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'spawn_object' command");
 198                                         return TRUE;
 199                                 }
 200                                 else if not(fexists(argv(2)))
 201                                 {
 202                                         print_to(self, "WARNING: Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 203                                         return TRUE;
 204                                 }
 205
 206                                 e = sandbox_SpawnObject();
 207                                 setmodel(e, argv(2));
 208
 209                                 if(autocvar_g_sandbox_info)
 210                                         print(strcat(self.netname, " spawned an object at origin ", vtos(e.origin), "\n"));
 211
 212                                 return TRUE;
 213
 214                         // ---------------- COMMAND: REMOVE OBJECT ----------------
 215                         case "remove_object":
 216                                 e = sandbox_EditObject_Get();
 217                                 if(e != world)
 218                                 {
 219                                         if(autocvar_g_sandbox_info)
 220                                                 print(strcat(self.netname, " removed an object at origin ", vtos(e.origin), "\n"));
 221                                         remove(e);
 222                                         e = world;
 223                                         return TRUE;
 224                                 }
 225
 226                                 print_to(self, "WARNING: Object could not be removed. Make sure you are facing an object that belongs to you");
 227                                 return TRUE;
 228
 229                         // ---------------- COMMAND: DUPLICATE OBJECT COPY ----------------
 230                         case "duplicate_object_copy":
 231                                 // copies customizable properties of the selected object to the clipboard
 232
 233                                 e = sandbox_EditObject_Get(); // you can only copy objects you can edit, so this works
 234                                 if(e != world)
 235                                 {
 236                                         if(self.object_clipboard)
 237                                                 strunzone(self.object_clipboard);
 238                                         self.object_clipboard = strzone(sandbox_Storage_Save(e));
 239
 240                                         print_to(self, "Object copied to clipboard");
 241                                         return TRUE;
 242                                 }
 243
 244                                 print_to(self, "WARNING: Object could not be copied. Make sure you are facing an object that belongs to you");
 245                                 return TRUE;
 246
 247                         // ---------------- COMMAND: DUPLICATE OBJECT PASTE ----------------
 248                         case "duplicate_object_paste":
 249                                 // spawns a new object using the properties in the player's clipboard
 250
 251                                 if(!self.object_clipboard) // no object in clipboard
 252                                 {
 253                                         print_to(self, "WARNING: No object in clipboard. You must copy an object before you can paste it");
 254                                         return TRUE;
 255                                 }
 256
 257                                 e = sandbox_SpawnObject();
 258                                 sandbox_Storage_Load(e, self.object_clipboard);
 259
 260                                 print_to(self, "Object pasted");
 261                                 if(autocvar_g_sandbox_info)
 262                                         print(strcat(self.netname, " pasted an object at origin ", vtos(e.origin), "\n"));
 263
 264                                 return TRUE;
 265
 266                         // ---------------- COMMAND: EDIT OBJECT ----------------
 267                         case "edit_object":
 268                                 if(!argv(2) || !argv(3))
 269                                 {
 270                                         print_to(self, "WARNING: Too few parameters. You must specify a property to edit, followed by its value");
 271                                         return TRUE;
 272                                 }
 273
 274                                 e = sandbox_EditObject_Get();
 275                                 if(e != world)
 276                                 {
 277                                         switch(argv(2))
 278                                         {
 279                                                 case "skin":
 280                                                         e.skin = stof(argv(3));
 281                                                         break;
 282                                                 case "alpha":
 283                                                         e.alpha = stof(argv(3));
 284                                                         break;
 285                                                 case "color_main":
 286                                                         e.colormod = stov(argv(3));
 287                                                         break;
 288                                                 case "color_glow":
 289                                                         e.glowmod = stov(argv(3));
 290                                                         break;
 291                                                 case "frame":
 292                                                         e.frame = stof(argv(3));
 293                                                         break;
 294                                                 case "scale":
 295                                                         sandbox_EditObject_Scale(e, stof(argv(3)));
 296                                                         break;
 297                                                 case "physics":
 298                                                         switch(argv(3))
 299                                                         {
 300                                                                 case "0": // static
 301                                                                         e.movetype = MOVETYPE_NONE;
 302                                                                         break;
 303                                                                 case "1": // movable
 304                                                                         e.movetype = MOVETYPE_TOSS;
 305                                                                         break;
 306                                                                 case "2": // physical
 307                                                                         e.movetype = MOVETYPE_PHYSICS;
 308                                                                         break;
 309                                                                 default:
 310                                                                         break;
 311                                                         }
 312                                                         break;
 313                                                 case "force":
 314                                                         e.damageforcescale = stof(argv(3));
 315                                                         break;
 316                                                 case "material":
 317                                                         e.material = stof(argv(3));
 318                                                         break;
 319                                                 default:
 320                                                         print_to(self, "WARNING: Invalid object property. For usage information, type 'sandbox help'");
 321                                                         break;
 322                                         }
 323
 324                                         return TRUE;
 325                                 }
 326
 327                                 print_to(self, "WARNING: Object could not be edited. Make sure you are facing an object that belongs to you");
 328                                 return TRUE;
 329
 330                         // ---------------- COMMAND: DEFAULT ----------------
 331                         default:
 332                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
 333                                 return TRUE;
 334                 }
 335         }
 336         return FALSE;
 337 }
 338
 339 MUTATOR_HOOKFUNCTION(sandbox_PlayerPreThink)
 340 {
 341         // if the player is close enough to their object, they can drag it
 342
 343         if(autocvar_sv_cheats)
 344                 return FALSE; // cheat dragging is used instead
 345
 346         // grab is TRUE if the object can be picked up. While an object is being carried, the Drag() function
 347         // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 348         // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 349         // it goes out of range while slinging it around.
 350
 351         entity e;
 352         float grab;
 353
 354         e = sandbox_EditObject_Get();
 355         if(e != world && vlen(e.origin - self.origin) <= autocvar_g_sandbox_editor_distance_edit)
 356                 grab = TRUE;
 357
 358         if(Drag(e, grab)) // execute dragging
 359         {
 360                 if(autocvar_g_sandbox_info)
 361                         print(strcat(self.netname, " grabbed an object at origin ", vtos(e.origin), "\n"));
 362                 return TRUE;
 363         }
 364
 365         return FALSE;
 366 }
 367
 368 MUTATOR_HOOKFUNCTION(sandbox_ClientDisconnect)
 369 {
 370         // unzone the player's clipboard if it's not empty
 371         if(self.object_clipboard)
 372         {
 373                 strunzone(self.object_clipboard);
 374                 self.object_clipboard = string_null;
 375         }
 376
 377         return FALSE;
 378 }
 379
 380 MUTATOR_DEFINITION(sandbox)
 381 {
 382         MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
 383         MUTATOR_HOOK(PlayerPreThink, sandbox_PlayerPreThink, CBC_ORDER_ANY);
 384         MUTATOR_HOOK(ClientDisconnect, sandbox_ClientDisconnect, CBC_ORDER_ANY);
 385
 386         MUTATOR_ONADD
 387         {
 388                 float i;
 389                 for (i = 1; i <= 5; i++)
 390                 {
 391                         // precache material sounds
 392                         precache_sound(strcat("objects/impact_metal_", ftos(i), ".ogg"));
 393                         precache_sound(strcat("objects/impact_stone_", ftos(i), ".ogg"));
 394                         precache_sound(strcat("objects/impact_wood_", ftos(i), ".ogg"));
 395                         precache_sound(strcat("objects/impact_flesh_", ftos(i), ".ogg"));
 396                 }
 397         }
 398
 399         return FALSE;
 400 }
 401