qcsrc/server/mutators/sandbox.qc

   1 const float MAX_STORAGE_ATTACHMENTS = 16;
   2 float object_count;
   3 .string object_clipboard;
   4 .entity object_attach;
   5 .string material;
   6
   7 .float touch_timer;
   8 void sandbox_ObjectFunction_Touch()
   9 {
  10         // apply material impact effects
  11
  12         if(!self.material)
  13                 return;
  14         if(self.touch_timer > time)
  15                 return; // don't execute each frame
  16         self.touch_timer = time + 0.1;
  17
  18         // make particle count and sound volume depend on impact speed
  19         float intensity;
  20         intensity = vlen(self.velocity) + vlen(other.velocity);
  21         if(intensity) // avoid divisions by 0
  22                 intensity /= 2; // average the two velocities
  23         if not(intensity >= autocvar_g_sandbox_object_material_velocity_min)
  24                 return; // impact not strong enough to do anything
  25         // now offset intensity and apply it to the effects
  26         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
  27         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
  28
  29         sound(self, CH_TRIGGER, strcat("object/impact_", self.material, "_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE * intensity, ATTN_NORM);
  30         pointparticles(particleeffectnum(strcat("impact_", self.material)), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  31 }
  32
  33 entity sandbox_ObjectEdit_Get(float permissions)
  34 {
  35         // returns the traced entity if the player can edit it, and world if not
  36         // if permissions if FALSE, the object is returned regardless of editing rights
  37         // attached objects are SOLID_NOT and don't risk getting traced
  38
  39         makevectors(self.v_angle);
  40         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_edit, MOVE_NORMAL, self);
  41
  42         if(trace_ent.classname != "object")
  43                 return world; // entity is not an object
  44         if(!permissions)
  45                 return trace_ent; // don't check permissions, anyone can edit this object
  46         if(!trace_ent.crypto_idfp)
  47                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
  48         if not(trace_ent.crypto_idfp != self.crypto_idfp && autocvar_g_sandbox_editor_free < 2)
  49                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
  50         return world;
  51 }
  52
  53 void sandbox_ObjectEdit_Scale(entity e, float f)
  54 {
  55         e.scale = f;
  56         if(e.scale)
  57         {
  58                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
  59                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
  60         }
  61 }
  62
  63 .float old_movetype;
  64 void sandbox_ObjectAttach_Remove(entity e);
  65 void sandbox_ObjectAttach_Set(entity e, entity parent, string s)
  66 {
  67         // attaches e to parent on string s
  68
  69         // we can't attach to an attachment, for obvious reasons
  70         sandbox_ObjectAttach_Remove(e);
  71
  72         e.old_movetype = e.movetype; // persist physics
  73         e.movetype = MOVETYPE_FOLLOW;
  74         e.solid = SOLID_NOT;
  75         e.takedamage = DAMAGE_NO;
  76
  77         setattachment(e, parent, s);
  78         e.owner = parent;
  79 }
  80
  81 void sandbox_ObjectAttach_Remove(entity e)
  82 {
  83         // detaches any object attached to e
  84
  85         entity head;
  86         for(head = world; (head = find(head, classname, "object")); )
  87         {
  88                 if(head.owner == e)
  89                 {
  90                         vector org;
  91                         head.movetype = head.old_movetype; // restore persisted physics
  92                         head.solid = SOLID_BBOX;
  93                         head.takedamage = DAMAGE_AIM;
  94
  95                         org = gettaginfo(head, 0);
  96                         setattachment(head, world, "");
  97                         head.owner = world;
  98
  99                         // objects change origin and angles when detached, so apply previous position
 100                         setorigin(head, org);
 101                         head.angles = e.angles; // don't allow detached objects to spin or roll
 102                 }
 103         }
 104 }
 105
 106 entity sandbox_ObjectSpawn(float database)
 107 {
 108         // spawn a new object with default properties
 109
 110         entity e;
 111         e = spawn();
 112         e.classname = "object";
 113         e.takedamage = DAMAGE_AIM;
 114         e.damageforcescale = 1;
 115         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
 116         e.movetype = MOVETYPE_TOSS;
 117         e.frame = 0;
 118         e.skin = 0;
 119         e.material = string_null;
 120         e.touch = sandbox_ObjectFunction_Touch;
 121
 122         if(!database)
 123         {
 124                 // set the object's owner via player UID
 125                 // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
 126                 if(self.crypto_idfp != "")
 127                         e.crypto_idfp = strzone(self.crypto_idfp);
 128                 else
 129                         print_to(self, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
 130
 131                 // set origin and direction based on player position and view angle
 132                 makevectors(self.v_angle);
 133                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
 134                 setorigin(e, trace_endpos);
 135                 e.angles_y = self.v_angle_y;
 136         }
 137
 138         object_count += 1;
 139         return e;
 140 }
 141
 142 void sandbox_ObjectRemove(entity e)
 143 {
 144         sandbox_ObjectAttach_Remove(e); // detach child objects
 145         if(e.material)
 146         {
 147                 strunzone(e.material);
 148                 e.material = string_null;
 149         }
 150         if(e.crypto_idfp)
 151         {
 152                 strunzone(e.crypto_idfp);
 153                 e.crypto_idfp = string_null;
 154         }
 155         remove(e);
 156         e = world;
 157
 158         object_count -= 1;
 159 }
 160
 161 string port_string[MAX_STORAGE_ATTACHMENTS]; // fteqcc crashes if this isn't defined as a global
 162
 163 string sandbox_ObjectPort_Save(entity e, float database)
 164 {
 165         // save object properties, and return them as a string
 166         float i;
 167         string s;
 168         entity head;
 169
 170         for(head = world; (head = find(head, classname, "object")); )
 171         {
 172                 // the main object needs to be first in the array [0] with attached objects following
 173                 float slot, physics;
 174                 string tagname;
 175                 if(head == e) // this is the main object, place it first
 176                 {
 177                         slot = 0;
 178                         physics = head.movetype; // applied physics are normal physics for parents
 179                 }
 180                 else if(head.owner == e) // child object, list them in order
 181                 {
 182                         i += 1; // children start from 1
 183                         slot = i;
 184                         physics = head.old_movetype; // persisted physics are normal physics for children
 185
 186                         // get the name of the tag our object is attached to
 187                         gettaginfo(head.owner, head.tag_index);
 188                         tagname = gettaginfo_name;
 189                 }
 190                 else
 191                         continue;
 192
 193                 // ---------------- OBJECT PROPERTY STORAGE: SAVE ----------------
 194                 if(slot)
 195                 {
 196                         // properties stored only for child objects
 197                         if(tagname)     port_string[slot] = strcat(port_string[slot], "\"", tagname, "\" ");    else    port_string[slot] = strcat(port_string[slot], "- "); // none
 198                 }
 199                 else
 200                 {
 201                         // properties stored only for parent objects
 202                         if(database)
 203                         {
 204                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.origin), " ");
 205                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.angles), " ");
 206                         }
 207                 }
 208                 // properties stored for all objects
 209                 port_string[slot] = strcat(port_string[slot], "\"", head.model, "\" ");
 210                 port_string[slot] = strcat(port_string[slot], ftos(head.skin), " ");
 211                 port_string[slot] = strcat(port_string[slot], ftos(head.alpha), " ");
 212                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.colormod), " ");
 213                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.glowmod), " ");
 214                 port_string[slot] = strcat(port_string[slot], ftos(head.frame), " ");
 215                 port_string[slot] = strcat(port_string[slot], ftos(head.scale), " ");
 216                 port_string[slot] = strcat(port_string[slot], ftos(physics), " ");
 217                 port_string[slot] = strcat(port_string[slot], ftos(head.damageforcescale), " ");
 218                 if(head.material)       port_string[slot] = strcat(port_string[slot], "\"", head.material, "\" ");      else    port_string[slot] = strcat(port_string[slot], "- "); // none
 219                 if(database)
 220                 {
 221                         // properties stored only for the database
 222                         if(head.crypto_idfp)    port_string[slot] = strcat(port_string[slot], "\"", head.crypto_idfp, "\" ");   else    port_string[slot] = strcat(port_string[slot], "- "); // none
 223                 }
 224         }
 225
 226         // now apply the array to a simple string, with the ; symbol separating objects
 227         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 228         {
 229                 if(port_string[i])
 230                         s = strcat(s, port_string[i], "; ");
 231                 port_string[i] = string_null; // fully clear the string
 232         }
 233
 234         return s;
 235 }
 236
 237 entity sandbox_ObjectPort_Load(string s, float database)
 238 {
 239         // load object properties, and spawn a new object with them
 240         float n, i;
 241         entity e, parent;
 242
 243         // separate objects between the ; symbols
 244         n = tokenizebyseparator(s, "; ");
 245         for(i = 0; i < n; ++i)
 246                 port_string[i] = argv(i);
 247
 248         // now separate and apply the properties of each object
 249         for(i = 0; i < n; ++i)
 250         {
 251                 float argv_num;
 252                 string tagname;
 253                 argv_num = 0;
 254                 tokenize_console(port_string[i]);
 255                 e = sandbox_ObjectSpawn(database);
 256
 257                 // ---------------- OBJECT PROPERTY STORAGE: LOAD ----------------
 258                 if(i)
 259                 {
 260                         // properties stored only for child objects
 261                         if(argv(argv_num) != "-")       tagname = argv(argv_num);       else tagname = string_null;     ++argv_num;
 262                 }
 263                 else
 264                 {
 265                         // properties stored only for parent objects
 266                         if(database)
 267                         {
 268                                 setorigin(e, stov(argv(argv_num)));     ++argv_num;
 269                                 e.angles = stov(argv(argv_num));        ++argv_num;
 270                         }
 271                         parent = e; // mark parent objects as such
 272                 }
 273                 // properties stored for all objects
 274                 setmodel(e, argv(argv_num));    ++argv_num;
 275                 e.skin = stof(argv(argv_num));  ++argv_num;
 276                 e.alpha = stof(argv(argv_num)); ++argv_num;
 277                 e.colormod = stov(argv(argv_num));      ++argv_num;
 278                 e.glowmod = stov(argv(argv_num));       ++argv_num;
 279                 e.frame = stof(argv(argv_num)); ++argv_num;
 280                 sandbox_ObjectEdit_Scale(e, stof(argv(argv_num)));      ++argv_num;
 281                 e.movetype = e.old_movetype = stof(argv(argv_num));     ++argv_num;
 282                 e.damageforcescale = stof(argv(argv_num));      ++argv_num;
 283                 if(e.material)  strunzone(e.material);  if(argv(argv_num) != "-")       e.material = strzone(argv(argv_num));   else    e.material = string_null;       ++argv_num;
 284                 if(database)
 285                 {
 286                         // properties stored only for the database
 287                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);       if(argv(argv_num) != "-")       e.crypto_idfp = strzone(argv(argv_num));        else    e.crypto_idfp = string_null;    ++argv_num;
 288                 }
 289
 290                 // attach last
 291                 sandbox_ObjectAttach_Set(e, parent, tagname);
 292         }
 293
 294         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 295                 port_string[i] = string_null; // fully clear the string
 296
 297         return e;
 298 }
 299
 300 void sandbox_Database_Save()
 301 {
 302         // saves all objects to the database file
 303         entity head;
 304         string file_name;
 305         float file_get;
 306
 307         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 308         file_get = fopen(file_name, FILE_WRITE);
 309         fputs(file_get, strcat("// sandbox storage \"", autocvar_g_sandbox_storage_name, "\" for map \"", GetMapname(), "\" last updated ", strftime(TRUE, "%d-%m-%Y %H:%M:%S")));
 310         fputs(file_get, strcat(" containing ", ftos(object_count), " objects\n"));
 311
 312         for(head = world; (head = find(head, classname, "object")); )
 313         {
 314                 // attached objects are persisted separately, ignore them here
 315                 if(head.owner != world)
 316                         continue;
 317
 318                 // use a line of text for each object, listing all properties
 319                 fputs(file_get, strcat(sandbox_ObjectPort_Save(head, TRUE), "\n"));
 320         }
 321         fclose(file_get);
 322 }
 323
 324 void sandbox_Database_Load()
 325 {
 326         // loads all objects from the database file
 327         string file_read, file_name;
 328         float file_get, i;
 329
 330         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 331         file_get = fopen(file_name, FILE_READ);
 332         if(file_get < 0)
 333         {
 334                 if(autocvar_g_sandbox_info > 0)
 335                         print(strcat("^3SANDBOX - SERVER: ^7could not find storage file ^3", file_name, "^7, no objects were loaded\n"));
 336         }
 337         else
 338         {
 339                 for(;;)
 340                 {
 341                         file_read = fgets(file_get);
 342                         if(!file_read)
 343                                 break;
 344                         if(substring(file_read, 0, 2) == "//")
 345                                 continue;
 346                         if(substring(file_read, 0, 1) == "#")
 347                                 continue;
 348
 349                         entity e;
 350                         e = sandbox_ObjectPort_Load(file_read, TRUE);
 351
 352                         if(e.material)
 353                         {
 354                                 // since objects are being loaded for the first time, precache material sounds for each
 355                                 for (i = 1; i <= 5; i++) // 5 sounds in total
 356                                         precache_sound(strcat("object/impact_", e.material, "_", ftos(i), ".ogg"));
 357                         }
 358                 }
 359                 if(autocvar_g_sandbox_info > 0)
 360                         print(strcat("^3SANDBOX - SERVER: ^7successfully loaded storage file ^3", file_name, "\n"));
 361         }
 362 }
 363
 364 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
 365 {
 366         if(MUTATOR_RETURNVALUE) // command was already handled?
 367                 return FALSE;
 368         if(cmd_name == "g_sandbox")
 369         {
 370                 if(cmd_argc < 2)
 371                 {
 372                         print_to(self, "Sandbox mode is active. For usage information, type 'sandbox help'");
 373                         return TRUE;
 374                 }
 375
 376                 switch(argv(1))
 377                 {
 378                         entity e;
 379                         float i;
 380
 381                         // ---------------- COMMAND: HELP ----------------
 382                         case "help":
 383                                 print_to(self, "You can use the following sandbox commands:");
 384                                 print_to(self, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
 385                                 print_to(self, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
 386                                 print_to(self, "^7\"^2object_duplicate ^3value^7\" duplicates the object. 'copy' copies the object, 'paste' puts it in front of the player");
 387                                 print_to(self, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
 388                                 print_to(self, "^7Attachment properties for ^2object_attach^7:");
 389                                 print_to(self, "^3get ^7- selects the object you are facing as the object to be attached");
 390                                 print_to(self, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
 391                                 print_to(self, "^3remove ^7- detaches all objects from the object you are facing");
 392                                 print_to(self, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
 393                                 print_to(self, "^7Object properties for ^2object_edit^7:");
 394                                 print_to(self, "^3skin value ^7- changes the skin of the object");
 395                                 print_to(self, "^3alpha value ^7- sets object transparency");
 396                                 print_to(self, "^3colormod \"value_x value_y value_z\" ^7- main object color");
 397                                 print_to(self, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
 398                                 print_to(self, "^3frame value ^7- object animation frame, for self-animated models");
 399                                 print_to(self, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
 400                                 print_to(self, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
 401                                 print_to(self, "^3force value ^7- amount of force applied to objects that are shot");
 402                                 print_to(self, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
 403                                 print_to(self, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
 404                                 print_to(self, "^7\"^2object_info ^3value^7\" shows public information about the object. 'mesh' shows model information");
 405                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
 406                                 return TRUE;
 407
 408                         // ---------------- COMMAND: OBJECT, SPAWN ----------------
 409                         case "object_spawn":
 410                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 411                                 {
 412                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 413                                         return TRUE;
 414                                 }
 415                                 if(cmd_argc < 3)
 416                                 {
 417                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
 418                                         return TRUE;
 419                                 }
 420                                 else if not(fexists(argv(2)))
 421                                 {
 422                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 423                                         return TRUE;
 424                                 }
 425
 426                                 e = sandbox_ObjectSpawn(FALSE);
 427                                 setmodel(e, argv(2));
 428
 429                                 if(autocvar_g_sandbox_info > 0)
 430                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " spawned an object at origin ^3", vtos(e.origin), "\n"));
 431                                 return TRUE;
 432
 433                         // ---------------- COMMAND: OBJECT, REMOVE ----------------
 434                         case "object_remove":
 435                                 e = sandbox_ObjectEdit_Get(TRUE);
 436                                 if(e != world)
 437                                 {
 438                                         if(autocvar_g_sandbox_info > 0)
 439                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " removed an object at origin ^3", vtos(e.origin), "\n"));
 440                                         sandbox_ObjectRemove(e);
 441                                         return TRUE;
 442                                 }
 443
 444                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
 445                                 return TRUE;
 446
 447                         // ---------------- COMMAND: OBJECT, DUPLICATE ----------------
 448                         case "object_duplicate":
 449                                 switch(argv(2))
 450                                 {
 451                                         case "copy":
 452                                                 // copies customizable properties of the selected object to the clipboard
 453                                                 e = sandbox_ObjectEdit_Get(autocvar_g_sandbox_editor_free); // can we copy objects we can't edit?
 454                                                 if(e != world)
 455                                                 {
 456                                                         if(self.object_clipboard)
 457                                                                 strunzone(self.object_clipboard);
 458                                                         self.object_clipboard = strzone(sandbox_ObjectPort_Save(e, FALSE));
 459
 460                                                         print_to(self, "^2SANDBOX - INFO: ^7Object copied to clipboard");
 461                                                         return TRUE;
 462                                                 }
 463                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have copy rights over");
 464                                                 return TRUE;
 465
 466                                         case "paste":
 467                                                 // spawns a new object using the properties in the player's clipboard
 468                                                 if(!self.object_clipboard) // no object in clipboard
 469                                                 {
 470                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
 471                                                         return TRUE;
 472                                                 }
 473                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 474                                                 {
 475                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 476                                                         return TRUE;
 477                                                 }
 478
 479                                                 e = sandbox_ObjectPort_Load(self.object_clipboard, FALSE);
 480
 481                                                 print_to(self, "^2SANDBOX - INFO: ^7Object pasted successfully");
 482                                                 if(autocvar_g_sandbox_info > 0)
 483                                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " pasted an object at origin ^3", vtos(e.origin), "\n"));
 484                                                 return TRUE;
 485                                 }
 486                                 return TRUE;
 487
 488                         // ---------------- COMMAND: OBJECT, ATTACH ----------------
 489                         case "object_attach":
 490                                 switch(argv(2))
 491                                 {
 492                                         case "get":
 493                                                 // select e as the object as meant to be attached
 494                                                 e = sandbox_ObjectEdit_Get(TRUE);
 495                                                 if(e != world)
 496                                                 {
 497                                                         self.object_attach = e;
 498                                                         print_to(self, "^2SANDBOX - INFO: ^7Object selected for attachment");
 499                                                         return TRUE;
 500                                                 }
 501                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
 502                                                 return TRUE;
 503                                         case "set":
 504                                                 if(self.object_attach == world)
 505                                                 {
 506                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
 507                                                         return TRUE;
 508                                                 }
 509
 510                                                 // attaches the previously selected object to e
 511                                                 e = sandbox_ObjectEdit_Get(TRUE);
 512                                                 if(e != world)
 513                                                 {
 514                                                         sandbox_ObjectAttach_Set(self.object_attach, e, argv(3));
 515                                                         self.object_attach = world; // object was attached, no longer keep it scheduled for attachment
 516                                                         print_to(self, "^2SANDBOX - INFO: ^7Object attached successfully");
 517                                                         if(autocvar_g_sandbox_info > 1)
 518                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " attached objects at origin ^3", vtos(e.origin), "\n"));
 519                                                         return TRUE;
 520                                                 }
 521                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
 522                                                 return TRUE;
 523                                         case "remove":
 524                                                 // removes e if it was attached
 525                                                 e = sandbox_ObjectEdit_Get(TRUE);
 526                                                 if(e != world)
 527                                                 {
 528                                                         sandbox_ObjectAttach_Remove(e);
 529                                                         print_to(self, "^2SANDBOX - INFO: ^7Child objects detached successfully");
 530                                                         if(autocvar_g_sandbox_info > 1)
 531                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " detached objects at origin ^3", vtos(e.origin), "\n"));
 532                                                         return TRUE;
 533                                                 }
 534                                                 print_to(self, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
 535                                                 return TRUE;
 536                                 }
 537                                 return TRUE;
 538
 539                         // ---------------- COMMAND: OBJECT, EDIT ----------------
 540                         case "object_edit":
 541                                 if(!argv(2))
 542                                 {
 543                                         print_to(self, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
 544                                         return TRUE;
 545                                 }
 546
 547                                 e = sandbox_ObjectEdit_Get(TRUE);
 548                                 if(e != world)
 549                                 {
 550                                         switch(argv(2))
 551                                         {
 552                                                 case "skin":
 553                                                         e.skin = stof(argv(3));
 554                                                         break;
 555                                                 case "alpha":
 556                                                         e.alpha = stof(argv(3));
 557                                                         break;
 558                                                 case "color_main":
 559                                                         e.colormod = stov(argv(3));
 560                                                         break;
 561                                                 case "color_glow":
 562                                                         e.glowmod = stov(argv(3));
 563                                                         break;
 564                                                 case "frame":
 565                                                         e.frame = stof(argv(3));
 566                                                         break;
 567                                                 case "scale":
 568                                                         sandbox_ObjectEdit_Scale(e, stof(argv(3)));
 569                                                         break;
 570                                                 case "physics":
 571                                                         switch(argv(3))
 572                                                         {
 573                                                                 case "0": // static
 574                                                                         e.movetype = MOVETYPE_NONE;
 575                                                                         break;
 576                                                                 case "1": // movable
 577                                                                         e.movetype = MOVETYPE_TOSS;
 578                                                                         break;
 579                                                                 case "2": // physical
 580                                                                         e.movetype = MOVETYPE_PHYSICS;
 581                                                                         break;
 582                                                                 default:
 583                                                                         break;
 584                                                         }
 585                                                         break;
 586                                                 case "force":
 587                                                         e.damageforcescale = stof(argv(3));
 588                                                         break;
 589                                                 case "material":
 590                                                         if(e.material)
 591                                                                 strunzone(e.material);
 592                                                         if(argv(3))
 593                                                         {
 594                                                                 for (i = 1; i <= 5; i++) // precache material sounds, 5 in total
 595                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(i), ".ogg"));
 596                                                                 e.material = strzone(argv(3));
 597                                                         }
 598                                                         else
 599                                                                 e.material = string_null; // no material
 600                                                         break;
 601                                                 default:
 602                                                         print_to(self, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
 603                                                         break;
 604                                         }
 605                                         if(autocvar_g_sandbox_info > 1)
 606                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin), "\n"));
 607                                         return TRUE;
 608                                 }
 609
 610                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
 611                                 return TRUE;
 612
 613                         // ---------------- COMMAND: OBJECT, CLAIM ----------------
 614                         case "object_claim":
 615                                 // if the player can edit an object but is not its owner, this can be used to claim that object
 616                                 if(self.crypto_idfp == "")
 617                                 {
 618                                         print_to(self, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
 619                                         return TRUE;
 620                                 }
 621                                 e = sandbox_ObjectEdit_Get(TRUE);
 622                                 if(e != world)
 623                                 {
 624                                         if(e.crypto_idfp == self.crypto_idfp)
 625                                         {
 626                                                 print_to(self, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
 627                                                 return TRUE;
 628                                         }
 629
 630                                         if(e.crypto_idfp)
 631                                                 strunzone(e.crypto_idfp);
 632                                         e.crypto_idfp = self.crypto_idfp;
 633                                         print_to(self, "^2SANDBOX - INFO: ^7Object claimed successfully");
 634                                 }
 635                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
 636                                 return TRUE;
 637
 638                         // ---------------- COMMAND: OBJECT, INFO ----------------
 639                         case "object_info":
 640                                 // prints public information about the object to the player
 641                                 e = sandbox_ObjectEdit_Get(FALSE);
 642                                 if(e != world)
 643                                 {
 644                                         switch(argv(2))
 645                                         {
 646                                                 case "mesh":
 647                                                         string tags;
 648                                                         for(i = 1; gettaginfo(e, i); i++)
 649                                                                 tags = strcat(tags, "^5", gettaginfo_name, "^7, ");
 650                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object mesh is ^3", e.model, "^7 at animation frame ^3", ftos(e.frame), " ^7containing the following tags: ", tags));
 651                                                         return TRUE;
 652                                         }
 653                                 }
 654                                 print_to(self, "^1SANDBOX - WARNING: ^7No information could not be found. Make sure you are facing an object");
 655                                 return TRUE;
 656
 657                         // ---------------- COMMAND: DEFAULT ----------------
 658                         default:
 659                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
 660                                 return TRUE;
 661                 }
 662         }
 663         return FALSE;
 664 }
 665
 666 MUTATOR_HOOKFUNCTION(sandbox_PlayerPreThink)
 667 {
 668         // if the player is close enough to their object, they can drag it
 669
 670         if(autocvar_sv_cheats)
 671                 return FALSE; // cheat dragging is used instead
 672
 673         // grab is TRUE if the object can be picked up. While an object is being carried, the Drag() function
 674         // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 675         // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 676         // it goes out of range while slinging it around.
 677
 678         entity e;
 679         float grab;
 680
 681         e = sandbox_ObjectEdit_Get(TRUE);
 682         if(e != world && vlen(e.origin - self.origin) <= autocvar_g_sandbox_editor_distance_edit)
 683                 grab = TRUE;
 684
 685         if(Drag(e, grab)) // execute dragging
 686                 return TRUE;
 687
 688         return FALSE;
 689 }
 690
 691 MUTATOR_HOOKFUNCTION(sandbox_ClientDisconnect)
 692 {
 693         // unzone the player's clipboard if it's not empty
 694         if(self.object_clipboard)
 695         {
 696                 strunzone(self.object_clipboard);
 697                 self.object_clipboard = string_null;
 698         }
 699
 700         return FALSE;
 701 }
 702
 703 float autosave_time;
 704 MUTATOR_HOOKFUNCTION(sandbox_StartFrame)
 705 {
 706         if(!autocvar_g_sandbox_storage_autosave)
 707                 return FALSE;
 708         if(time < autosave_time)
 709                 return FALSE;
 710         autosave_time = time + autocvar_g_sandbox_storage_autosave;
 711
 712         sandbox_Database_Save();
 713
 714         return TRUE;
 715 }
 716
 717 MUTATOR_DEFINITION(sandbox)
 718 {
 719         MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
 720         MUTATOR_HOOK(SV_StartFrame, sandbox_StartFrame, CBC_ORDER_ANY);
 721         MUTATOR_HOOK(PlayerPreThink, sandbox_PlayerPreThink, CBC_ORDER_ANY);
 722         MUTATOR_HOOK(ClientDisconnect, sandbox_ClientDisconnect, CBC_ORDER_ANY);
 723
 724         MUTATOR_ONADD
 725         {
 726                 autosave_time = time + autocvar_g_sandbox_storage_autosave; // don't save the first server frame
 727                 if(autocvar_g_sandbox_storage_autoload)
 728                         sandbox_Database_Load();
 729         }
 730
 731         return FALSE;
 732 }
 733