qcsrc/server/portals.qc

   1 #if defined(CSQC)
   2 #elif defined(MENUQC)
   3 #elif defined(SVQC)
   4         #include "../dpdefs/progsdefs.qh"
   5     #include "../dpdefs/dpextensions.qh"
   6     #include "sys-post.qh"
   7     #include "../warpzonelib/anglestransform.qh"
   8     #include "../warpzonelib/util_server.qh"
   9     #include "../common/constants.qh"
  10     #include "../common/util.qh"
  11     #include "../common/weapons/weapons.qh"
  12     #include "autocvars.qh"
  13     #include "defs.qh"
  14     #include "../common/notifications.qh"
  15     #include "../common/deathtypes.qh"
  16     #include "mutators/mutators_include.qh"
  17     #include "../csqcmodellib/sv_model.qh"
  18     #include "portals.qh"
  19     #include "g_hook.qh"
  20 #endif
  21
  22 #define PORTALS_ARE_NOT_SOLID
  23
  24 const vector SAFENUDGE = '1 1 1';
  25 const vector SAFERNUDGE = '8 8 8';
  26
  27 .vector portal_transform;
  28 .vector portal_safe_origin;
  29 .float portal_wants_to_vanish;
  30 .float portal_activatetime;
  31 .float savemodelindex;
  32
  33 float PlayerEdgeDistance(entity p, vector v)
  34 {
  35         vector vbest;
  36
  37         if(v.x < 0) vbest_x = p.mins.x; else vbest_x = p.maxs.x;
  38         if(v.y < 0) vbest_y = p.mins.y; else vbest_y = p.maxs.y;
  39         if(v.z < 0) vbest_z = p.mins.z; else vbest_z = p.maxs.z;
  40
  41         return vbest * v;
  42 }
  43
  44 vector Portal_ApplyTransformToPlayerAngle(vector transform, vector vangle)
  45 {
  46         vector old_forward, old_up;
  47         vector old_yawforward;
  48         vector new_forward, new_up;
  49         vector new_yawforward;
  50
  51         vector ang;
  52         ang = vangle;
  53         /*
  54            ang_x = bound(-89, mod(-ang_x + 180, 360) - 180, 89);
  55            ang = AnglesTransform_ApplyToVAngles(transform, ang);
  56          */
  57
  58         // PLAYERS use different math
  59 #ifndef POSITIVE_PITCH_IS_DOWN
  60         ang_x = -ang.x;
  61 #endif
  62
  63         //print("reference: ", vtos(AnglesTransform_ApplyToVAngles(transform, ang)), "\n");
  64
  65         fixedmakevectors(ang);
  66         old_forward = v_forward;
  67         old_up = v_up;
  68         fixedmakevectors(ang.y * '0 1 0');
  69         old_yawforward = v_forward;
  70
  71         // their aiming directions are portalled...
  72         new_forward = AnglesTransform_Apply(transform, old_forward);
  73         new_up = AnglesTransform_Apply(transform, old_up);
  74         new_yawforward = AnglesTransform_Apply(transform, old_yawforward);
  75
  76         // but now find a new sense of direction
  77         // this is NOT easy!
  78         // assume new_forward points straight up.
  79         // What is our yaw?
  80         //
  81         // new_up could now point forward OR backward... which direction to choose?
  82
  83         if(new_forward.z > 0.7 || new_forward.z < -0.7) // far up; in this case, the "up" vector points backwards
  84         {
  85                 // new_yawforward and new_yawup define the new aiming half-circle
  86                 // we "just" need to find out whether new_up or -new_up is in that half circle
  87                 ang = fixedvectoangles(new_forward); // this still gets us a nice pitch value...
  88                 if(new_up * new_yawforward < 0)
  89                         new_up = -1 * new_up;
  90                 ang_y = vectoyaw(new_up); // this vector is the yaw we want
  91                 //print("UP/DOWN path: ", vtos(ang), "\n");
  92         }
  93         else
  94         {
  95                 // good angles; here, "forward" suffices
  96                 ang = fixedvectoangles(new_forward);
  97                 //print("GOOD path: ", vtos(ang), "\n");
  98         }
  99
 100 #ifndef POSITIVE_PITCH_IS_DOWN
 101         ang_x = -ang.x;
 102 #endif
 103         ang_z = vangle.z;
 104         return ang;
 105 }
 106
 107 .vector right_vector;
 108 float Portal_TeleportPlayer(entity teleporter, entity player)
 109 {
 110         vector from, to, safe, step, transform, ang, newvel;
 111         float planeshift, s, t;
 112
 113         if (!teleporter.enemy)
 114         {
 115                 backtrace("Portal_TeleportPlayer called without other portal being set. Stop.");
 116                 return 0;
 117         }
 118
 119         from = teleporter.origin;
 120         transform = teleporter.portal_transform;
 121
 122         to = teleporter.enemy.origin;
 123         to = to + AnglesTransform_Apply(teleporter.portal_transform, player.origin - from);
 124         newvel = AnglesTransform_Apply(transform, player.velocity);
 125         // this now is INSIDE the plane... can't use that
 126
 127         // shift it out
 128         fixedmakevectors(teleporter.enemy.mangle);
 129
 130         // first shift it ON the plane if needed
 131         planeshift = ((teleporter.enemy.origin - to) * v_forward) + PlayerEdgeDistance(player, v_forward) + 1;
 132         /*
 133         if(planeshift > 0 && (newvel * v_forward) > vlen(newvel) * 0.01)
 134                 // if we can't, let us not do the planeshift and do somewhat incorrect transformation in the end
 135                 to += newvel * (planeshift / (newvel * v_forward));
 136         else
 137         */
 138                 to += v_forward * planeshift;
 139
 140         s = (to - teleporter.enemy.origin) * v_right;
 141         t = (to - teleporter.enemy.origin) * v_up;
 142         s = bound(-48, s, 48);
 143         t = bound(-48, t, 48);
 144         to = teleporter.enemy.origin
 145            + ((to - teleporter.enemy.origin) * v_forward) * v_forward
 146            +     s                                        * v_right
 147            +     t                                        * v_up;
 148
 149         safe = teleporter.enemy.portal_safe_origin; // a valid player origin
 150         step = to + ((safe - to) * v_forward) * v_forward;
 151         tracebox(safe, player.mins - SAFENUDGE, player.maxs + SAFENUDGE, step, MOVE_NOMONSTERS, player);
 152         if(trace_startsolid)
 153         {
 154                 print("'safe' teleport location is not safe!\n");
 155                 // FAIL TODO why does this happen?
 156                 return 0;
 157         }
 158         safe = trace_endpos + normalize(safe - trace_endpos) * 0;
 159         tracebox(safe, player.mins - SAFENUDGE, player.maxs + SAFENUDGE, to, MOVE_NOMONSTERS, player);
 160         if(trace_startsolid)
 161         {
 162                 print("trace_endpos in solid, this can't be!\n");
 163                 // FAIL TODO why does this happen? (reported by MrBougo)
 164                 return 0;
 165         }
 166         to = trace_endpos + normalize(safe - trace_endpos) * 0;
 167         //print(vtos(to), "\n");
 168
 169         // ang_x stuff works around weird quake angles
 170         if(IS_PLAYER(player))
 171                 ang = Portal_ApplyTransformToPlayerAngle(transform, player.v_angle);
 172         else
 173                 ang = AnglesTransform_ApplyToAngles(transform, player.angles);
 174
 175         // factor -1 allows chaining portals, but may be weird
 176         player.right_vector = -1 * AnglesTransform_Apply(transform, player.right_vector);
 177
 178         entity oldself = self;
 179         self = player;
 180         MUTATOR_CALLHOOK(PortalTeleport);
 181         player = self;
 182         self = oldself;
 183
 184         if (!teleporter.enemy)
 185         {
 186                 backtrace("Portal_TeleportPlayer ended up without other portal being set BEFORE TeleportPlayer. Stop.");
 187                 return 0;
 188         }
 189
 190         tdeath_hit = 0;
 191         TeleportPlayer(teleporter, player, to, ang, newvel, teleporter.enemy.absmin, teleporter.enemy.absmax, TELEPORT_FLAGS_PORTAL);
 192         if(tdeath_hit)
 193         {
 194                 // telefrag within 1 second of portal creation = amazing
 195                 if(time < teleporter.teleport_time + 1)
 196                         Send_Notification(NOTIF_ONE, player, MSG_ANNCE, ANNCE_ACHIEVEMENT_AMAZING);
 197         }
 198
 199         if (!teleporter.enemy)
 200         {
 201                 backtrace("Portal_TeleportPlayer ended up without other portal being set AFTER TeleportPlayer. Stop.");
 202                 return 0;
 203         }
 204
 205         // reset fade counter
 206         teleporter.portal_wants_to_vanish = 0;
 207         teleporter.fade_time = time + autocvar_g_balance_portal_lifetime;
 208         teleporter.health = autocvar_g_balance_portal_health;
 209         teleporter.enemy.health = autocvar_g_balance_portal_health;
 210
 211         return 1;
 212 }
 213
 214 float Portal_FindSafeOrigin(entity portal)
 215 {
 216         vector o;
 217         o = portal.origin;
 218         portal.mins = PL_MIN - SAFERNUDGE;
 219         portal.maxs = PL_MAX + SAFERNUDGE;
 220         fixedmakevectors(portal.mangle);
 221         portal.origin += 16 * v_forward;
 222         if(!move_out_of_solid(portal))
 223         {
 224 #ifdef DEBUG
 225                 print("NO SAFE ORIGIN\n");
 226 #endif
 227                 return 0;
 228         }
 229         portal.portal_safe_origin = portal.origin;
 230         setorigin(portal, o);
 231         return 1;
 232 }
 233
 234 float Portal_WillHitPlane(vector eorg, vector emins, vector emaxs, vector evel, vector porg, vector pnorm, float psize)
 235 {
 236         float dist, distpersec, delta;
 237         vector v;
 238
 239         dist = (eorg - porg) * pnorm;
 240         dist += min(emins.x * pnorm.x, emaxs.x * pnorm.x);
 241         dist += min(emins.y * pnorm.y, emaxs.y * pnorm.y);
 242         dist += min(emins.z * pnorm.z, emaxs.z * pnorm.z);
 243         if(dist < -1) // other side?
 244                 return 0;
 245 #ifdef PORTALS_ARE_NOT_SOLID
 246         distpersec = evel * pnorm;
 247         if(distpersec >= 0) // going away from the portal?
 248                 return 0;
 249         // we don't need this check with solid portals, them being SOLID_BSP should suffice
 250         delta = dist / distpersec;
 251         v = eorg - evel * delta - porg;
 252         v = v - pnorm * (pnorm * v);
 253         return vlen(v) < psize;
 254 #else
 255         return 1;
 256 #endif
 257 }
 258
 259 void Portal_Touch()
 260 {
 261         vector g;
 262
 263 #ifdef PORTALS_ARE_NOT_SOLID
 264         // portal is being removed?
 265         if(self.solid != SOLID_TRIGGER)
 266                 return; // possibly engine bug
 267
 268         if(IS_PLAYER(other))
 269                 return; // handled by think
 270 #endif
 271
 272         if(other.classname == "item_flag_team")
 273                 return; // never portal these
 274
 275         if(other.classname == "grapplinghook")
 276                 return; // handled by think
 277
 278         if(!self.enemy)
 279                 error("Portal_Touch called for a broken portal\n");
 280
 281 #ifdef PORTALS_ARE_NOT_SOLID
 282         if(trace_fraction < 1)
 283                 return; // only handle TouchAreaGrid ones (only these can teleport)
 284 #else
 285         if(trace_fraction >= 1)
 286                 return; // only handle impacts
 287 #endif
 288
 289         if(other.classname == "porto")
 290         {
 291                 if(other.portal_id == self.portal_id)
 292                         return;
 293         }
 294         if(time < self.portal_activatetime)
 295                 if(other == self.aiment)
 296                 {
 297                         self.portal_activatetime = time + 0.1;
 298                         return;
 299                 }
 300         if(other != self.aiment)
 301                 if(IS_PLAYER(other))
 302                         if(IS_INDEPENDENT_PLAYER(other) || IS_INDEPENDENT_PLAYER(self.aiment))
 303                                 return; // cannot go through someone else's portal
 304         if(other.aiment != self.aiment)
 305                 if(IS_PLAYER(other.aiment))
 306                         if(IS_INDEPENDENT_PLAYER(other.aiment) || IS_INDEPENDENT_PLAYER(self.aiment))
 307                                 return; // cannot go through someone else's portal
 308         fixedmakevectors(self.mangle);
 309         g = frametime * '0 0 -1' * autocvar_sv_gravity;
 310         if(!Portal_WillHitPlane(other.origin, other.mins, other.maxs, other.velocity + g, self.origin, v_forward, self.maxs.x))
 311                 return;
 312
 313         /*
 314         if(other.mins_x < PL_MIN_x || other.mins_y < PL_MIN_y || other.mins_z < PL_MIN_z
 315         || other.maxs_x > PL_MAX_x || other.maxs_y > PL_MAX_y || other.maxs_z > PL_MAX_z)
 316         {
 317                 // can't teleport this
 318                 return;
 319         }
 320         */
 321
 322         if(Portal_TeleportPlayer(self, other))
 323                 if(other.classname == "porto")
 324                         if(other.effects & EF_RED)
 325                                 other.effects += EF_BLUE - EF_RED;
 326 }
 327
 328 void Portal_Think();
 329 void Portal_MakeBrokenPortal(entity portal)
 330 {
 331         portal.skin = 2;
 332         portal.solid = SOLID_NOT;
 333         portal.touch = func_null;
 334         portal.think = func_null;
 335         portal.effects = 0;
 336         portal.nextthink = 0;
 337         portal.takedamage = DAMAGE_NO;
 338 }
 339
 340 void Portal_MakeWaitingPortal(entity portal)
 341 {
 342         portal.skin = 2;
 343         portal.solid = SOLID_NOT;
 344         portal.touch = func_null;
 345         portal.think = func_null;
 346         portal.effects = EF_ADDITIVE;
 347         portal.nextthink = 0;
 348         portal.takedamage = DAMAGE_YES;
 349 }
 350
 351 void Portal_MakeInPortal(entity portal)
 352 {
 353         portal.skin = 0;
 354         portal.solid = SOLID_NOT; // this is done when connecting them!
 355         portal.touch = Portal_Touch;
 356         portal.think = Portal_Think;
 357         portal.effects = EF_RED;
 358         portal.nextthink = time;
 359         portal.takedamage = DAMAGE_NO;
 360 }
 361
 362 void Portal_MakeOutPortal(entity portal)
 363 {
 364         portal.skin = 1;
 365         portal.solid = SOLID_NOT;
 366         portal.touch = func_null;
 367         portal.think = func_null;
 368         portal.effects = EF_STARDUST | EF_BLUE;
 369         portal.nextthink = 0;
 370         portal.takedamage = DAMAGE_YES;
 371 }
 372
 373 void Portal_Disconnect(entity teleporter, entity destination)
 374 {
 375         teleporter.enemy = world;
 376         destination.enemy = world;
 377         Portal_MakeBrokenPortal(teleporter);
 378         Portal_MakeBrokenPortal(destination);
 379 }
 380
 381 void Portal_Connect(entity teleporter, entity destination)
 382 {
 383         teleporter.portal_transform = AnglesTransform_RightDivide(AnglesTransform_TurnDirectionFR(destination.mangle), teleporter.mangle);
 384
 385         teleporter.enemy = destination;
 386         destination.enemy = teleporter;
 387         Portal_MakeInPortal(teleporter);
 388         Portal_MakeOutPortal(destination);
 389         teleporter.fade_time = time + autocvar_g_balance_portal_lifetime;
 390         destination.fade_time = teleporter.fade_time;
 391         teleporter.portal_wants_to_vanish = 0;
 392         destination.portal_wants_to_vanish = 0;
 393         teleporter.teleport_time = time;
 394 #ifdef PORTALS_ARE_NOT_SOLID
 395         teleporter.solid = SOLID_TRIGGER;
 396 #else
 397         teleporter.solid = SOLID_BSP;
 398 #endif
 399 }
 400
 401 void Portal_Remove(entity portal, float killed)
 402 {
 403         entity e;
 404         e = portal.enemy;
 405
 406         if(e)
 407         {
 408                 Portal_Disconnect(portal, e);
 409                 Portal_Remove(e, killed);
 410         }
 411
 412         if(portal == portal.aiment.portal_in)
 413                 portal.aiment.portal_in = world;
 414         if(portal == portal.aiment.portal_out)
 415                 portal.aiment.portal_out = world;
 416         //portal.aiment = world;
 417
 418         // makes the portal vanish
 419         if(killed)
 420         {
 421                 fixedmakevectors(portal.mangle);
 422                 sound(portal, CH_SHOTS, "porto/explode.wav", VOL_BASE, ATTEN_NORM);
 423                 pointparticles(particleeffectnum("rocket_explode"), portal.origin + v_forward * 16, v_forward * 1024, 4);
 424                 remove(portal);
 425         }
 426         else
 427         {
 428                 Portal_MakeBrokenPortal(portal);
 429                 sound(portal, CH_SHOTS, "porto/expire.wav", VOL_BASE, ATTEN_NORM);
 430                 SUB_SetFade(portal, time, 0.5);
 431         }
 432 }
 433
 434 void Portal_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 435 {
 436         if(deathtype == DEATH_TELEFRAG)
 437                 return;
 438         if(attacker != self.aiment)
 439                 if(IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(self.aiment))
 440                         return;
 441         self.health -= damage;
 442         if(self.health < 0)
 443                 Portal_Remove(self, 1);
 444 }
 445
 446 void Portal_Think_TryTeleportPlayer(entity e, vector g)
 447 {
 448         if(!Portal_WillHitPlane(e.origin, e.mins, e.maxs, e.velocity + g, self.origin, v_forward, self.maxs.x))
 449                 return;
 450
 451         // if e would hit the portal in a frame...
 452         // already teleport him
 453         tracebox(e.origin, e.mins, e.maxs, e.origin + e.velocity * 2 * frametime, MOVE_NORMAL, e);
 454         if(trace_ent == self)
 455                 Portal_TeleportPlayer(self, e);
 456 }
 457
 458 void Portal_Think()
 459 {
 460         entity e, o;
 461         vector g;
 462
 463 #ifdef PORTALS_ARE_NOT_SOLID
 464         // portal is being removed?
 465         if(self.solid != SOLID_TRIGGER)
 466                 return; // possibly engine bug
 467
 468         if(!self.enemy)
 469                 error("Portal_Think called for a broken portal\n");
 470
 471         o = self.aiment;
 472         self.solid = SOLID_BBOX;
 473         self.aiment = world;
 474
 475         g = frametime * '0 0 -1' * autocvar_sv_gravity;
 476
 477         fixedmakevectors(self.mangle);
 478
 479         FOR_EACH_PLAYER(e)
 480         {
 481                 if(e != o)
 482                         if(IS_INDEPENDENT_PLAYER(e) || IS_INDEPENDENT_PLAYER(o))
 483                                 continue; // cannot go through someone else's portal
 484
 485                 if(e != o || time >= self.portal_activatetime)
 486                         Portal_Think_TryTeleportPlayer(e, g);
 487
 488                 if(e.hook)
 489                         Portal_Think_TryTeleportPlayer(e.hook, g);
 490         }
 491         self.solid = SOLID_TRIGGER;
 492         self.aiment = o;
 493 #endif
 494
 495         self.nextthink = time;
 496
 497         if(time > self.fade_time)
 498                 Portal_Remove(self, 0);
 499 }
 500
 501 float Portal_Customize()
 502 {
 503         if(IS_SPEC(other))
 504                 other = other.enemy;
 505         if(other == self.aiment)
 506         {
 507                 self.modelindex = self.savemodelindex;
 508         }
 509         else if(IS_INDEPENDENT_PLAYER(other) || IS_INDEPENDENT_PLAYER(self.aiment))
 510         {
 511                 self.modelindex = 0;
 512         }
 513         else
 514         {
 515                 self.modelindex = self.savemodelindex;
 516         }
 517         return true;
 518 }
 519
 520 // cleanup:
 521 //   when creating in-portal:
 522 //     disconnect
 523 //     clear existing in-portal
 524 //     set as in-portal
 525 //     connect
 526 //   when creating out-portal:
 527 //     disconnect
 528 //     clear existing out-portal
 529 //     set as out-portal
 530 //   when player dies:
 531 //     disconnect portals
 532 //     clear both portals
 533 //   after timeout of in-portal:
 534 //     disconnect portals
 535 //     clear both portals
 536 //   TODO: ensure only one portal shot at once
 537 float Portal_SetInPortal(entity own, entity portal)
 538 {
 539         if(own.portal_in)
 540         {
 541                 if(own.portal_out)
 542                         Portal_Disconnect(own.portal_in, own.portal_out);
 543                 Portal_Remove(own.portal_in, 0);
 544         }
 545         own.portal_in = portal;
 546         if(own.portal_out)
 547         {
 548                 own.portal_out.portal_id = portal.portal_id;
 549                 Portal_Connect(own.portal_in, own.portal_out);
 550         }
 551         return 2;
 552 }
 553 float Portal_SetOutPortal(entity own, entity portal)
 554 {
 555         if(own.portal_out)
 556         {
 557                 if(own.portal_in)
 558                         Portal_Disconnect(own.portal_in, own.portal_out);
 559                 Portal_Remove(own.portal_out, 0);
 560         }
 561         own.portal_out = portal;
 562         if(own.portal_in)
 563         {
 564                 own.portal_in.portal_id = portal.portal_id;
 565                 Portal_Connect(own.portal_in, own.portal_out);
 566         }
 567         return 1;
 568 }
 569 void Portal_ClearAll_PortalsOnly(entity own)
 570 {
 571         if(own.portal_in)
 572                 Portal_Remove(own.portal_in, 0);
 573         if(own.portal_out)
 574                 Portal_Remove(own.portal_out, 0);
 575 }
 576 void Portal_ClearAll(entity own)
 577 {
 578         Portal_ClearAll_PortalsOnly(own);
 579         W_Porto_Remove(own);
 580 }
 581 void Portal_RemoveLater_Think()
 582 {
 583         Portal_Remove(self, self.cnt);
 584 }
 585 void Portal_RemoveLater(entity portal, float kill)
 586 {
 587         Portal_MakeBrokenPortal(portal);
 588         portal.cnt = kill;
 589         portal.think = Portal_RemoveLater_Think;
 590         portal.nextthink = time;
 591 }
 592 void Portal_ClearAllLater_PortalsOnly(entity own)
 593 {
 594         if(own.portal_in)
 595                 Portal_RemoveLater(own.portal_in, 0);
 596         if(own.portal_out)
 597                 Portal_RemoveLater(own.portal_out, 0);
 598 }
 599 void Portal_ClearAllLater(entity own)
 600 {
 601         Portal_ClearAllLater_PortalsOnly(own);
 602         W_Porto_Remove(own);
 603 }
 604 void Portal_ClearWithID(entity own, float id)
 605 {
 606         if(own.portal_in)
 607                 if(own.portal_in.portal_id == id)
 608                 {
 609                         if(own.portal_out)
 610                                 Portal_Disconnect(own.portal_in, own.portal_out);
 611                         Portal_Remove(own.portal_in, 0);
 612                 }
 613         if(own.portal_out)
 614                 if(own.portal_out.portal_id == id)
 615                 {
 616                         if(own.portal_in)
 617                                 Portal_Disconnect(own.portal_in, own.portal_out);
 618                         Portal_Remove(own.portal_out, 0);
 619                 }
 620 }
 621
 622 entity Portal_Spawn(entity own, vector org, vector ang)
 623 {
 624         entity portal;
 625
 626         fixedmakevectors(ang);
 627         if(!CheckWireframeBox(own, org - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 628                 return world;
 629
 630         portal = spawn();
 631         portal.classname = "portal";
 632         portal.aiment = own;
 633         setorigin(portal, org);
 634         portal.mangle = ang;
 635         portal.angles = ang;
 636         portal.angles_x = -portal.angles.x; // is a bmodel
 637         portal.think = Portal_Think;
 638         portal.nextthink = 0;
 639         portal.portal_activatetime = time + 0.1;
 640         portal.takedamage = DAMAGE_AIM;
 641         portal.event_damage = Portal_Damage;
 642         portal.fade_time = time + autocvar_g_balance_portal_lifetime;
 643         portal.health = autocvar_g_balance_portal_health;
 644         setmodel(portal, "models/portal.md3");
 645         portal.savemodelindex = portal.modelindex;
 646         portal.customizeentityforclient = Portal_Customize;
 647
 648         if(!Portal_FindSafeOrigin(portal))
 649         {
 650                 remove(portal);
 651                 return world;
 652         }
 653
 654         setsize(portal, '-48 -48 -48', '48 48 48');
 655         Portal_MakeWaitingPortal(portal);
 656
 657         return portal;
 658 }
 659
 660 float Portal_SpawnInPortalAtTrace(entity own, vector dir, float portal_id_val)
 661 {
 662         entity portal;
 663         vector ang;
 664         vector org;
 665
 666         org = trace_endpos;
 667         ang = fixedvectoangles2(trace_plane_normal, dir);
 668         fixedmakevectors(ang);
 669
 670         portal = Portal_Spawn(own, org, ang);
 671         if(!portal)
 672                 return 0;
 673
 674         portal.portal_id = portal_id_val;
 675         Portal_SetInPortal(own, portal);
 676
 677         return 1;
 678 }
 679
 680 float Portal_SpawnOutPortalAtTrace(entity own, vector dir, float portal_id_val)
 681 {
 682         entity portal;
 683         vector ang;
 684         vector org;
 685
 686         org = trace_endpos;
 687         ang = fixedvectoangles2(trace_plane_normal, dir);
 688         fixedmakevectors(ang);
 689
 690         portal = Portal_Spawn(own, org, ang);
 691         if(!portal)
 692                 return 0;
 693
 694         portal.portal_id = portal_id_val;
 695         Portal_SetOutPortal(own, portal);
 696
 697         return 1;
 698 }