qcsrc/server/spawnpoints.qc

   1 #include "spawnpoints.qh"
   2 #include "_all.qh"
   3
   4 #include "mutators/mutators_include.qh"
   5 #include "g_world.qh"
   6 #include "race.qh"
   7 #include "../common/constants.qh"
   8 #include "../common/teams.qh"
   9 #include "../common/util.qh"
  10 #include "../warpzonelib/util_server.qh"
  11
  12 float SpawnPoint_Send(entity to, int sf)
  13 {SELFPARAM();
  14         WriteByte(MSG_ENTITY, ENT_CLIENT_SPAWNPOINT);
  15
  16         WriteByte(MSG_ENTITY, self.team);
  17         WriteShort(MSG_ENTITY, self.origin.x);
  18         WriteShort(MSG_ENTITY, self.origin.y);
  19         WriteShort(MSG_ENTITY, self.origin.z);
  20
  21         return true;
  22 }
  23
  24 float SpawnEvent_Send(entity to, int sf)
  25 {SELFPARAM();
  26         float send;
  27
  28         WriteByte(MSG_ENTITY, ENT_CLIENT_SPAWNEVENT);
  29
  30         if(autocvar_g_spawn_alloweffects)
  31         {
  32                 WriteByte(MSG_ENTITY, num_for_edict(self.owner));
  33                 WriteShort(MSG_ENTITY, self.owner.origin.x);
  34                 WriteShort(MSG_ENTITY, self.owner.origin.y);
  35                 WriteShort(MSG_ENTITY, self.owner.origin.z);
  36                 send = true;
  37         }
  38         else if((to == self.owner) || (IS_SPEC(to) && (to.enemy == self.owner)) )
  39         {
  40                 WriteByte(MSG_ENTITY, 0);
  41                 send = true;
  42         }
  43         else { send = false; }
  44
  45         return send;
  46 }
  47
  48 void spawnpoint_use()
  49 {SELFPARAM();
  50         if(teamplay)
  51         if(have_team_spawns > 0)
  52         {
  53                 self.team = activator.team;
  54                 some_spawn_has_been_used = 1;
  55         }
  56         //LOG_INFO("spawnpoint was used!\n");
  57 }
  58
  59 void relocate_spawnpoint()
  60 {SELFPARAM();
  61     // nudge off the floor
  62     setorigin(self, self.origin + '0 0 1');
  63
  64     tracebox(self.origin, PL_MIN_CONST, PL_MAX_CONST, self.origin, true, self);
  65     if (trace_startsolid)
  66     {
  67         vector o;
  68         o = self.origin;
  69         self.mins = PL_MIN_CONST;
  70         self.maxs = PL_MAX_CONST;
  71         if (!move_out_of_solid(self))
  72             objerror("could not get out of solid at all!");
  73         LOG_INFO("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
  74         LOG_INFO(" needs to be moved out of solid, e.g. by '", ftos(self.origin.x - o.x));
  75         LOG_INFO(" ", ftos(self.origin.y - o.y));
  76         LOG_INFO(" ", ftos(self.origin.z - o.z), "'\n");
  77         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
  78         {
  79             if (!spawnpoint_nag)
  80                 LOG_INFO("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
  81             spawnpoint_nag = 1;
  82         }
  83         else
  84         {
  85             setorigin(self, o);
  86             self.mins = self.maxs = '0 0 0';
  87             objerror("player spawn point in solid, mapper sucks!\n");
  88             return;
  89         }
  90     }
  91
  92     self.use = spawnpoint_use;
  93     self.team_saved = self.team;
  94     if (!self.cnt)
  95         self.cnt = 1;
  96
  97     if (have_team_spawns != 0)
  98         if (self.team)
  99             have_team_spawns = 1;
 100     have_team_spawns_forteam[self.team] = 1;
 101
 102     if (autocvar_r_showbboxes)
 103     {
 104         // show where spawnpoints point at too
 105         makevectors(self.angles);
 106         entity e;
 107         e = spawn();
 108         e.classname = "info_player_foo";
 109         setorigin(e, self.origin + v_forward * 24);
 110         setsize(e, '-8 -8 -8', '8 8 8');
 111         e.solid = SOLID_TRIGGER;
 112     }
 113
 114         // Don't show team spawns in non-team matches,
 115         // and don't show non-team spawns in team matches.
 116         // (Unless useallspawns is activated)
 117         if(
 118                 !(
 119                         ( // if this passes, there is a DM spawn on a team match
 120                                 teamplay
 121                                 && (self.team != NUM_TEAM_1)
 122                                 && (self.team != NUM_TEAM_2)
 123                                 && (self.team != NUM_TEAM_3)
 124                                 && (self.team != NUM_TEAM_4)
 125                         )
 126                         ||
 127                         ( // if this passes, there is a team spawn on a DM match
 128                                 !teamplay
 129                                 &&
 130                                 (
 131                                         (self.team == NUM_TEAM_1)
 132                                         || (self.team == NUM_TEAM_2)
 133                                         || (self.team == NUM_TEAM_3)
 134                                         || (self.team == NUM_TEAM_4)
 135                                 )
 136                         )
 137                 )
 138                 ||
 139                 autocvar_g_spawn_useallspawns
 140         )
 141         { Net_LinkEntity(self, false, 0, SpawnPoint_Send); }
 142 }
 143
 144 spawnfunc(info_player_survivor)
 145 {
 146         spawnfunc_info_player_deathmatch(this);
 147 }
 148
 149 spawnfunc(info_player_start)
 150 {
 151         spawnfunc_info_player_deathmatch(this);
 152 }
 153
 154 spawnfunc(info_player_deathmatch)
 155 {
 156         self.classname = "info_player_deathmatch";
 157         relocate_spawnpoint();
 158 }
 159
 160 /*QUAKED spawnfunc_info_player_team1 (1 0 0) (-16 -16 -24) (16 16 24)
 161 Starting point for a player in team one (Red).
 162 Keys: "angle" viewing angle when spawning. */
 163 spawnfunc(info_player_team1)
 164 {
 165         if(g_assault) { remove(this); return; }
 166
 167         this.team = NUM_TEAM_1; // red
 168         spawnfunc_info_player_deathmatch(this);
 169 }
 170
 171
 172 /*QUAKED spawnfunc_info_player_team2 (1 0 0) (-16 -16 -24) (16 16 24)
 173 Starting point for a player in team two (Blue).
 174 Keys: "angle" viewing angle when spawning. */
 175 spawnfunc(info_player_team2)
 176 {
 177         if(g_assault) { remove(this); return; }
 178
 179         this.team = NUM_TEAM_2; // blue
 180         spawnfunc_info_player_deathmatch(this);
 181 }
 182
 183 /*QUAKED spawnfunc_info_player_team3 (1 0 0) (-16 -16 -24) (16 16 24)
 184 Starting point for a player in team three (Yellow).
 185 Keys: "angle" viewing angle when spawning. */
 186 spawnfunc(info_player_team3)
 187 {
 188         if(g_assault) { remove(this); return; }
 189
 190         this.team = NUM_TEAM_3; // yellow
 191         spawnfunc_info_player_deathmatch(this);
 192 }
 193
 194
 195 /*QUAKED spawnfunc_info_player_team4 (1 0 0) (-16 -16 -24) (16 16 24)
 196 Starting point for a player in team four (Purple).
 197 Keys: "angle" viewing angle when spawning. */
 198 spawnfunc(info_player_team4)
 199 {
 200         if(g_assault) { remove(this); return; }
 201
 202         this.team = NUM_TEAM_4; // purple
 203         spawnfunc_info_player_deathmatch(this);
 204 }
 205
 206 // Returns:
 207 //   _x: prio (-1 if unusable)
 208 //   _y: weight
 209 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 210 {SELFPARAM();
 211         float shortest, thisdist;
 212         float prio;
 213         entity player;
 214
 215         prio = 0;
 216
 217         // filter out spots for the wrong team
 218         if(teamcheck >= 0)
 219                 if(spot.team != teamcheck)
 220                         return '-1 0 0';
 221
 222         if(race_spawns)
 223                 if(spot.target == "")
 224                         return '-1 0 0';
 225
 226         if(IS_REAL_CLIENT(self))
 227         {
 228                 if(spot.restriction == 1)
 229                         return '-1 0 0';
 230         }
 231         else
 232         {
 233                 if(spot.restriction == 2)
 234                         return '-1 0 0';
 235         }
 236
 237         shortest = vlen(world.maxs - world.mins);
 238         FOR_EACH_PLAYER(player) if (player != self)
 239         {
 240                 thisdist = vlen(player.origin - spot.origin);
 241                 if (thisdist < shortest)
 242                         shortest = thisdist;
 243         }
 244         if(shortest > mindist)
 245                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 246
 247         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 248         spawn_spot = spot;
 249
 250         // filter out spots for assault
 251         if(spot.target != "") {
 252                 entity ent;
 253                 float found;
 254
 255                 found = 0;
 256                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 257                 {
 258                         ++found;
 259                         if(ent.spawn_evalfunc)
 260                         {
 261                                 WITH(entity, self, ent, {
 262                                         spawn_score = ent.spawn_evalfunc(this, spot, spawn_score);
 263                                 });
 264                                 if(spawn_score.x < 0)
 265                                         return spawn_score;
 266                         }
 267                 }
 268
 269                 if(!found)
 270                 {
 271                         LOG_TRACE("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 272                         return '-1 0 0';
 273                 }
 274         }
 275
 276         MUTATOR_CALLHOOK(Spawn_Score, self, spawn_spot, spawn_score);
 277         return spawn_score;
 278 }
 279
 280 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 281 {
 282         entity spot;
 283         for(spot = firstspot; spot; spot = spot.chain)
 284                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 285 }
 286
 287 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 288 {
 289         entity spot, spotlist, spotlistend;
 290
 291         spotlist = world;
 292         spotlistend = world;
 293
 294         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 295
 296         for(spot = firstspot; spot; spot = spot.chain)
 297         {
 298                 if(spot.spawnpoint_score.x >= 0) // spawning allowed here
 299                 {
 300                         if(spotlistend)
 301                                 spotlistend.chain = spot;
 302                         spotlistend = spot;
 303                         if(!spotlist)
 304                                 spotlist = spot;
 305                 }
 306         }
 307         if(spotlistend)
 308                 spotlistend.chain = world;
 309
 310         return spotlist;
 311 }
 312
 313 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 314 {
 315         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 316         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 317         entity spot;
 318
 319         RandomSelection_Init();
 320         for(spot = firstspot; spot; spot = spot.chain)
 321                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score.y, upper), exponent) * spot.cnt, (spot.spawnpoint_score.y >= lower) * 0.5 + spot.spawnpoint_score.x);
 322
 323         return RandomSelection_chosen_ent;
 324 }
 325
 326 /*
 327 =============
 328 SelectSpawnPoint
 329
 330 Finds a point to respawn
 331 =============
 332 */
 333 entity SelectSpawnPoint (float anypoint)
 334 {SELFPARAM();
 335         float teamcheck;
 336         entity spot, firstspot;
 337
 338         spot = find (world, classname, "testplayerstart");
 339         if (spot)
 340                 return spot;
 341
 342         if(anypoint || autocvar_g_spawn_useallspawns)
 343                 teamcheck = -1;
 344         else if(have_team_spawns > 0)
 345         {
 346                 if(have_team_spawns_forteam[self.team] == 0)
 347                 {
 348                         // we request a spawn for a team, and we have team
 349                         // spawns, but that team has no spawns?
 350                         if(have_team_spawns_forteam[0])
 351                                 // try noteam spawns
 352                                 teamcheck = 0;
 353                         else
 354                                 // if not, any spawn has to do
 355                                 teamcheck = -1;
 356                 }
 357                 else
 358                         teamcheck = self.team; // MUST be team
 359         }
 360         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 361                 teamcheck = 0; // MUST be noteam
 362         else
 363                 teamcheck = -1;
 364                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 365
 366
 367         // get the entire list of spots
 368         firstspot = findchain(classname, "info_player_deathmatch");
 369         // filter out the bad ones
 370         // (note this returns the original list if none survived)
 371         if(anypoint)
 372         {
 373                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 374         }
 375         else
 376         {
 377                 firstspot = Spawn_FilterOutBadSpots(firstspot, 100, teamcheck);
 378
 379                 // there is 50/50 chance of choosing a random spot or the furthest spot
 380                 // (this means that roughly every other spawn will be furthest, so you
 381                 // usually won't get fragged at spawn twice in a row)
 382                 if (random() > autocvar_g_spawn_furthest)
 383                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 384                 else
 385                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 386         }
 387
 388         if (!spot)
 389         {
 390                 if(autocvar_spawn_debug)
 391                         GotoNextMap(0);
 392                 else
 393                 {
 394                         if(some_spawn_has_been_used)
 395                                 return world; // team can't spawn any more, because of actions of other team
 396                         else
 397                                 error("Cannot find a spawn point - please fix the map!");
 398                 }
 399         }
 400
 401         return spot;
 402 }