qcsrc/server/sv_main.qc

   1 #include "sv_main.qh"
   2
   3 #include "anticheat.qh"
   4 #include "g_hook.qh"
   5 #include "g_world.qh"
   6
   7 #include "bot/bot.qh"
   8 #include "bot/waypoints.qh"
   9
  10 #include "command/common.qh"
  11
  12 #include "mutators/all.qh"
  13 #include "weapons/csqcprojectile.qh"
  14
  15 #include "../common/constants.qh"
  16 #include "../common/deathtypes/all.qh"
  17 #include "../common/debug.qh"
  18 #include "../common/mapinfo.qh"
  19 #include "../common/util.qh"
  20
  21 #include "../common/vehicles/all.qh"
  22 #include "../common/weapons/all.qh"
  23
  24 #include "../lib/csqcmodel/sv_model.qh"
  25
  26 #include "../lib/warpzone/common.qh"
  27 #include "../lib/warpzone/server.qh"
  28
  29 .float lastground;
  30 .int state;
  31
  32 void CreatureFrame_hotliquids(entity this)
  33 {
  34         if (this.dmgtime < time)
  35         {
  36                 this.dmgtime = time + autocvar_g_balance_contents_damagerate;
  37
  38                 if (this.flags & FL_PROJECTILE)
  39                 {
  40                         if (this.watertype == CONTENT_LAVA)
  41                                 Damage (this, world, world, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, this.origin, '0 0 0');
  42                         else if (this.watertype == CONTENT_SLIME)
  43                                 Damage (this, world, world, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, this.origin, '0 0 0');
  44                 }
  45                 else
  46                 {
  47                         if (this.watertype == CONTENT_LAVA)
  48                         {
  49                                 if (this.watersound_finished < time)
  50                                 {
  51                                         this.watersound_finished = time + 0.5;
  52                                         sound (this, CH_PLAYER_SINGLE, SND_LAVA, VOL_BASE, ATTEN_NORM);
  53                                 }
  54                                 Damage (this, world, world, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, this.origin, '0 0 0');
  55                                 if(autocvar_g_balance_contents_playerdamage_lava_burn)
  56                                         Fire_AddDamage(this, world, autocvar_g_balance_contents_playerdamage_lava_burn * this.waterlevel, autocvar_g_balance_contents_playerdamage_lava_burn_time * this.waterlevel, DEATH_LAVA.m_id);
  57                         }
  58                         else if (this.watertype == CONTENT_SLIME)
  59                         {
  60                                 if (this.watersound_finished < time)
  61                                 {
  62                                         this.watersound_finished = time + 0.5;
  63                                         sound (this, CH_PLAYER_SINGLE, SND_SLIME, VOL_BASE, ATTEN_NORM);
  64                                 }
  65                                 Damage (this, world, world, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, this.origin, '0 0 0');
  66                         }
  67                 }
  68         }
  69 }
  70
  71 void CreatureFrame_Liquids(entity this)
  72 {
  73         if (this.watertype <= CONTENT_WATER && this.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
  74         {
  75                 if (!(this.flags & FL_INWATER))
  76                 {
  77                         this.flags |= FL_INWATER;
  78                         this.dmgtime = 0;
  79                 }
  80
  81                 CreatureFrame_hotliquids(this);
  82         }
  83         else
  84         {
  85                 if (this.flags & FL_INWATER)
  86                 {
  87                         // play leave water sound
  88                         this.flags &= ~FL_INWATER;
  89                         this.dmgtime = 0;
  90                 }
  91                 this.air_finished = time + 12;
  92                 this.dmg = 2;
  93         }
  94 }
  95
  96 void CreatureFrame_FallDamage(entity this)
  97 {
  98         if(!IS_VEHICLE(this) && !(this.flags & FL_PROJECTILE)) // vehicles don't get falling damage
  99         {
 100                 // check for falling damage
 101                 float velocity_len = vlen(this.velocity);
 102                 if(!this.hook.state)
 103                 {
 104                         float dm = vlen(this.oldvelocity) - velocity_len; // dm is now the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
 105                         if (IS_DEAD(this))
 106                                 dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
 107                         else
 108                                 dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
 109                         if (dm > 0)
 110                                 Damage (this, world, world, dm, DEATH_FALL.m_id, this.origin, '0 0 0');
 111                 }
 112
 113                 if(autocvar_g_maxspeed > 0 && velocity_len > autocvar_g_maxspeed)
 114                         Damage (this, world, world, 100000, DEATH_SHOOTING_STAR.m_id, this.origin, '0 0 0');
 115         }
 116 }
 117
 118 void CreatureFrame_All()
 119 {
 120         FOREACH_ENTITY_FLOAT(damagedbycontents, true, LAMBDA(
 121                 if(it.movetype == MOVETYPE_NOCLIP) continue;
 122                 CreatureFrame_Liquids(it);
 123                 CreatureFrame_FallDamage(it);
 124                 it.oldvelocity = it.velocity;
 125         ));
 126 }
 127
 128 void Pause_TryPause(bool ispaused)
 129 {
 130         int n = 0;
 131         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(
 132                 if (PHYS_INPUT_BUTTON_CHAT(it) != ispaused) return;
 133                 ++n;
 134         ));
 135         if (!n) return;
 136         setpause(ispaused);
 137 }
 138
 139 void SV_PausedTic(float elapsedtime)
 140 {
 141         if (!server_is_dedicated) Pause_TryPause(false);
 142 }
 143
 144 /*
 145 =============
 146 StartFrame
 147
 148 Called before each frame by the server
 149 =============
 150 */
 151
 152 float game_delay;
 153 float game_delay_last;
 154
 155 bool autocvar_sv_autopause = true;
 156 float RedirectionThink();
 157 void PM_Main(Client this);
 158 void StartFrame()
 159 {
 160     // TODO: if move is more than 50ms, split it into two moves (this matches QWSV behavior and the client prediction)
 161     FOREACH_ENTITY_CLASS(STR_PLAYER, IS_NOT_A_CLIENT(it), PM_Main(it));
 162     FOREACH_ENTITY_CLASS(STR_PLAYER, IS_NOT_A_CLIENT(it), WITH(entity, self, it, PlayerPreThink()));
 163
 164         execute_next_frame();
 165         if (autocvar_sv_autopause && !server_is_dedicated) Pause_TryPause(true);
 166
 167         remove = remove_unsafely; // not during spawning!
 168         serverprevtime = servertime;
 169         servertime = time;
 170         serverframetime = frametime;
 171
 172 #ifdef PROFILING
 173         if(time > client_cefc_accumulatortime + 1)
 174         {
 175                 float t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 176                 LOG_INFO("CEFC time: ", ftos(t * 1000), "ms; ");
 177                 int c_seeing = 0;
 178                 int c_seen = 0;
 179                 FOREACH_CLIENT(true, LAMBDA(
 180                         if(IS_REAL_CLIENT(it))
 181                                 ++c_seeing;
 182                         if(IS_PLAYER(it))
 183                                 ++c_seen;
 184                 ));
 185                 LOG_INFO("CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ");
 186                 LOG_INFO("CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0'), "\n");
 187
 188                 client_cefc_accumulatortime = time;
 189                 client_cefc_accumulator = 0;
 190         }
 191 #endif
 192
 193         FOREACH_ENTITY_FLOAT(csqcprojectile_clientanimate, true, LAMBDA(CSQCProjectile_Check(it)));
 194
 195         if(RedirectionThink())
 196                 return;
 197
 198         UncustomizeEntitiesRun();
 199         InitializeEntitiesRun();
 200
 201         WarpZone_StartFrame();
 202
 203         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
 204         if(sys_frametime <= 0)
 205                 sys_frametime = 1.0 / 60.0; // somewhat safe fallback
 206
 207         if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
 208                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
 209
 210         skill = autocvar_skill;
 211
 212         // detect when the pre-game countdown (if any) has ended and the game has started
 213         game_delay = (time < game_starttime);
 214
 215         if(autocvar_sv_eventlog && game_delay_last && !game_delay)
 216                 GameLogEcho(":startdelay_ended");
 217
 218         game_delay_last = game_delay;
 219
 220         CreatureFrame_All();
 221         CheckRules_World();
 222
 223         // if in warmup stage and limit for warmup is hit start match
 224         if(warmup_stage)
 225         if(!gameover)
 226         if((g_warmup_limit > 0 && time >= g_warmup_limit)
 227          || (g_warmup_limit == 0 && autocvar_timelimit != 0 && time >= autocvar_timelimit * 60))
 228         {
 229                 ReadyRestart();
 230                 return;
 231         }
 232
 233         bot_serverframe();
 234         anticheat_startframe();
 235         MUTATOR_CALLHOOK(SV_StartFrame);
 236
 237     FOREACH_CLIENT(true, LAMBDA(GlobalStats_update(it)));
 238     FOREACH_ENTITY_CLASS(STR_PLAYER, IS_NOT_A_CLIENT(it), WITH(entity, self, it, PlayerPostThink()));
 239 }
 240
 241 .vector originjitter;
 242 .vector anglesjitter;
 243 .float anglejitter;
 244 .string gametypefilter;
 245 .string cvarfilter;
 246 float DoesQ3ARemoveThisEntity();
 247 void SV_OnEntityPreSpawnFunction()
 248 {SELFPARAM();
 249         __spawnfunc_expect = this;
 250         if (self)
 251         if (self.gametypefilter != "")
 252         if (!isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, self.gametypefilter))
 253         {
 254                 remove(self);
 255                 return;
 256         }
 257         if(self.cvarfilter != "")
 258         {
 259                 float n, i, o, inv;
 260                 string s, k, v;
 261                 inv = 0;
 262
 263                 s = self.cvarfilter;
 264                 if(substring(s, 0, 1) == "+")
 265                 {
 266                         s = substring(s, 1, -1);
 267                 }
 268                 else if(substring(s, 0, 1) == "-")
 269                 {
 270                         inv = 1;
 271                         s = substring(s, 1, -1);
 272                 }
 273
 274                 n = tokenize_console(s);
 275                 for(i = 0; i < n; ++i)
 276                 {
 277                         s = argv(i);
 278                         // syntax:
 279                         // var>x
 280                         // var<x
 281                         // var>=x
 282                         // var<=x
 283                         // var==x
 284                         // var!=x
 285                         // var===x
 286                         // var!==x
 287                         if((o = strstrofs(s, ">=", 0)) >= 0)
 288                         {
 289                                 k = substring(s, 0, o);
 290                                 v = substring(s, o+2, -1);
 291                                 if(cvar(k) < stof(v))
 292                                         goto cvar_fail;
 293                         }
 294                         else if((o = strstrofs(s, "<=", 0)) >= 0)
 295                         {
 296                                 k = substring(s, 0, o);
 297                                 v = substring(s, o+2, -1);
 298                                 if(cvar(k) > stof(v))
 299                                         goto cvar_fail;
 300                         }
 301                         else if((o = strstrofs(s, ">", 0)) >= 0)
 302                         {
 303                                 k = substring(s, 0, o);
 304                                 v = substring(s, o+1, -1);
 305                                 if(cvar(k) <= stof(v))
 306                                         goto cvar_fail;
 307                         }
 308                         else if((o = strstrofs(s, "<", 0)) >= 0)
 309                         {
 310                                 k = substring(s, 0, o);
 311                                 v = substring(s, o+1, -1);
 312                                 if(cvar(k) >= stof(v))
 313                                         goto cvar_fail;
 314                         }
 315                         else if((o = strstrofs(s, "==", 0)) >= 0)
 316                         {
 317                                 k = substring(s, 0, o);
 318                                 v = substring(s, o+2, -1);
 319                                 if(cvar(k) != stof(v))
 320                                         goto cvar_fail;
 321                         }
 322                         else if((o = strstrofs(s, "!=", 0)) >= 0)
 323                         {
 324                                 k = substring(s, 0, o);
 325                                 v = substring(s, o+2, -1);
 326                                 if(cvar(k) == stof(v))
 327                                         goto cvar_fail;
 328                         }
 329                         else if((o = strstrofs(s, "===", 0)) >= 0)
 330                         {
 331                                 k = substring(s, 0, o);
 332                                 v = substring(s, o+2, -1);
 333                                 if(cvar_string(k) != v)
 334                                         goto cvar_fail;
 335                         }
 336                         else if((o = strstrofs(s, "!==", 0)) >= 0)
 337                         {
 338                                 k = substring(s, 0, o);
 339                                 v = substring(s, o+2, -1);
 340                                 if(cvar_string(k) == v)
 341                                         goto cvar_fail;
 342                         }
 343                         else if(substring(s, 0, 1) == "!")
 344                         {
 345                                 k = substring(s, 1, -1);
 346                                 if(cvar(k))
 347                                         goto cvar_fail;
 348                         }
 349                         else
 350                         {
 351                                 k = s;
 352                                 if (!cvar(k))
 353                                         goto cvar_fail;
 354                         }
 355                 }
 356                 inv = !inv;
 357 LABEL(cvar_fail)
 358                 // now inv is 1 if we want to keep the item, and 0 if we want to get rid of it
 359                 if (!inv)
 360                 {
 361                         //print("cvarfilter fail\n");
 362                         remove(self);
 363                         return;
 364                 }
 365         }
 366
 367         if(DoesQ3ARemoveThisEntity())
 368         {
 369                 remove(self);
 370                 return;
 371         }
 372
 373         // support special -1 and -2 angle from radiant
 374         if (self.angles == '0 -1 0')
 375                 self.angles = '-90 0 0';
 376         else if (self.angles == '0 -2 0')
 377                 self.angles = '+90 0 0';
 378
 379         if(self.originjitter.x != 0)
 380                 self.origin_x = self.origin.x + (random() * 2 - 1) * self.originjitter.x;
 381         if(self.originjitter.y != 0)
 382                 self.origin_y = self.origin.y + (random() * 2 - 1) * self.originjitter.y;
 383         if(self.originjitter.z != 0)
 384                 self.origin_z = self.origin.z + (random() * 2 - 1) * self.originjitter.z;
 385         if(self.anglesjitter.x != 0)
 386                 self.angles_x = self.angles.x + (random() * 2 - 1) * self.anglesjitter.x;
 387         if(self.anglesjitter.y != 0)
 388                 self.angles_y = self.angles.y + (random() * 2 - 1) * self.anglesjitter.y;
 389         if(self.anglesjitter.z != 0)
 390                 self.angles_z = self.angles.z + (random() * 2 - 1) * self.anglesjitter.z;
 391         if(self.anglejitter != 0)
 392                 self.angles_y = self.angles.y + (random() * 2 - 1) * self.anglejitter;
 393
 394         if(MUTATOR_CALLHOOK(OnEntityPreSpawn))
 395         {
 396                 remove(self);
 397                 return;
 398         }
 399 }
 400
 401 void WarpZone_PostInitialize_Callback()
 402 {
 403         // create waypoint links for warpzones
 404         entity e;
 405         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 406         {
 407                 vector src, dst;
 408                 src = (e.absmin + e.absmax) * 0.5;
 409                 makevectors(e.warpzone_angles);
 410                 src = src + ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
 411                 dst = (e.enemy.absmin + e.enemy.absmax) * 0.5;
 412                 makevectors(e.enemy.warpzone_angles);
 413                 dst = dst + ((e.enemy.warpzone_origin - dst) * v_forward) * v_forward - 16 * v_right;
 414                 waypoint_spawnforteleporter_v(e, src, dst, 0);
 415         }
 416 }