qcsrc/server/sv_main.qc

   1 #include "sv_main.qh"
   2
   3 #include "anticheat.qh"
   4 #include "g_hook.qh"
   5 #include "g_world.qh"
   6
   7 #include "bot/api.qh"
   8
   9 #include "command/common.qh"
  10
  11 #include "mutators/_mod.qh"
  12 #include "weapons/csqcprojectile.qh"
  13
  14 #include "../common/constants.qh"
  15 #include "../common/deathtypes/all.qh"
  16 #include "../common/debug.qh"
  17 #include "../common/mapinfo.qh"
  18 #include "../common/util.qh"
  19
  20 #include "../common/vehicles/all.qh"
  21 #include <common/weapons/_all.qh>
  22
  23 #include "../lib/csqcmodel/sv_model.qh"
  24
  25 #include "../lib/warpzone/common.qh"
  26 #include "../lib/warpzone/server.qh"
  27
  28 .float lastground;
  29 .int state;
  30
  31 void CreatureFrame_hotliquids(entity this)
  32 {
  33         if (this.dmgtime < time)
  34         {
  35                 this.dmgtime = time + autocvar_g_balance_contents_damagerate;
  36
  37                 if (this.flags & FL_PROJECTILE)
  38                 {
  39                         if (this.watertype == CONTENT_LAVA)
  40                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, this.origin, '0 0 0');
  41                         else if (this.watertype == CONTENT_SLIME)
  42                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, this.origin, '0 0 0');
  43                 }
  44                 else
  45                 {
  46                         if (this.watertype == CONTENT_LAVA)
  47                         {
  48                                 if (this.watersound_finished < time)
  49                                 {
  50                                         this.watersound_finished = time + 0.5;
  51                                         sound (this, CH_PLAYER_SINGLE, SND_LAVA, VOL_BASE, ATTEN_NORM);
  52                                 }
  53                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, this.origin, '0 0 0');
  54                                 if(autocvar_g_balance_contents_playerdamage_lava_burn)
  55                                         Fire_AddDamage(this, NULL, autocvar_g_balance_contents_playerdamage_lava_burn * this.waterlevel, autocvar_g_balance_contents_playerdamage_lava_burn_time * this.waterlevel, DEATH_LAVA.m_id);
  56                         }
  57                         else if (this.watertype == CONTENT_SLIME)
  58                         {
  59                                 if (this.watersound_finished < time)
  60                                 {
  61                                         this.watersound_finished = time + 0.5;
  62                                         sound (this, CH_PLAYER_SINGLE, SND_SLIME, VOL_BASE, ATTEN_NORM);
  63                                 }
  64                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, this.origin, '0 0 0');
  65                         }
  66                 }
  67         }
  68 }
  69
  70 void CreatureFrame_Liquids(entity this)
  71 {
  72         if (this.watertype <= CONTENT_WATER && this.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
  73         {
  74                 if (!(this.flags & FL_INWATER))
  75                 {
  76                         this.flags |= FL_INWATER;
  77                         this.dmgtime = 0;
  78                 }
  79
  80                 CreatureFrame_hotliquids(this);
  81         }
  82         else
  83         {
  84                 if (this.flags & FL_INWATER)
  85                 {
  86                         // play leave water sound
  87                         this.flags &= ~FL_INWATER;
  88                         this.dmgtime = 0;
  89                 }
  90                 this.air_finished = time + 12;
  91                 this.dmg = 2;
  92         }
  93 }
  94
  95 void CreatureFrame_FallDamage(entity this)
  96 {
  97         if(!IS_VEHICLE(this) && !(this.flags & FL_PROJECTILE)) // vehicles don't get falling damage
  98         if(this.velocity || this.oldvelocity) // moving or has moved
  99         {
 100                 // check for falling damage
 101                 float velocity_len = vlen(this.velocity);
 102                 if(!this.hook.state)
 103                 {
 104                         float dm = vlen(this.oldvelocity) - velocity_len; // dm is now the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
 105                         if (IS_DEAD(this))
 106                                 dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
 107                         else
 108                                 dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
 109                         if (dm > 0)
 110                                 Damage (this, NULL, NULL, dm, DEATH_FALL.m_id, this.origin, '0 0 0');
 111                 }
 112
 113                 if(autocvar_g_maxspeed > 0 && velocity_len > autocvar_g_maxspeed)
 114                         Damage (this, NULL, NULL, 100000, DEATH_SHOOTING_STAR.m_id, this.origin, '0 0 0');
 115         }
 116 }
 117
 118 void CreatureFrame_All()
 119 {
 120         //IL_EACH(g_damagedbycontents, it.damagedbycontents,
 121         FOREACH_ENTITY_FLOAT(damagedbycontents, true,
 122         {
 123                 if (it.move_movetype == MOVETYPE_NOCLIP) continue;
 124                 CreatureFrame_Liquids(it);
 125                 CreatureFrame_FallDamage(it);
 126                 it.oldvelocity = it.velocity;
 127         });
 128 }
 129
 130 void Pause_TryPause(bool ispaused)
 131 {
 132         int n = 0;
 133         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(
 134                 if (PHYS_INPUT_BUTTON_CHAT(it) != ispaused) return;
 135                 ++n;
 136         ));
 137         if (!n) return;
 138         setpause(ispaused);
 139 }
 140
 141 void SV_PausedTic(float elapsedtime)
 142 {
 143         if (!server_is_dedicated) Pause_TryPause(false);
 144 }
 145
 146 /*
 147 =============
 148 StartFrame
 149
 150 Called before each frame by the server
 151 =============
 152 */
 153
 154 float game_delay;
 155 float game_delay_last;
 156
 157 bool autocvar_sv_autopause = false;
 158 float RedirectionThink();
 159 void systems_update();
 160 void sys_phys_update(entity this, float dt);
 161 void StartFrame()
 162 {
 163     // TODO: if move is more than 50ms, split it into two moves (this matches QWSV behavior and the client prediction)
 164     IL_EACH(g_players, IS_FAKE_CLIENT(it), sys_phys_update(it, frametime));
 165     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPreThink(it));
 166
 167         execute_next_frame();
 168         if (autocvar_sv_autopause && !server_is_dedicated) Pause_TryPause(true);
 169
 170         delete_fn = remove_unsafely; // not during spawning!
 171         serverprevtime = servertime;
 172         servertime = time;
 173         serverframetime = frametime;
 174
 175 #ifdef PROFILING
 176         if(time > client_cefc_accumulatortime + 1)
 177         {
 178                 float t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 179                 LOG_INFO("CEFC time: ", ftos(t * 1000), "ms; ");
 180                 int c_seeing = 0;
 181                 int c_seen = 0;
 182                 FOREACH_CLIENT(true, LAMBDA(
 183                         if(IS_REAL_CLIENT(it))
 184                                 ++c_seeing;
 185                         if(IS_PLAYER(it))
 186                                 ++c_seen;
 187                 ));
 188                 LOG_INFO("CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ");
 189                 LOG_INFO("CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0'), "\n");
 190
 191                 client_cefc_accumulatortime = time;
 192                 client_cefc_accumulator = 0;
 193         }
 194 #endif
 195
 196         IL_EACH(g_projectiles, it.csqcprojectile_clientanimate, CSQCProjectile_Check(it));
 197
 198         if (RedirectionThink()) return;
 199
 200         UncustomizeEntitiesRun();
 201         InitializeEntitiesRun();
 202
 203         WarpZone_StartFrame();
 204
 205         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
 206         if (sys_frametime <= 0) sys_frametime = 1.0 / 60.0; // somewhat safe fallback
 207
 208         if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
 209                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
 210
 211         skill = autocvar_skill;
 212
 213         // detect when the pre-game countdown (if any) has ended and the game has started
 214         game_delay = (time < game_starttime);
 215
 216         if (autocvar_sv_eventlog && game_delay_last && !game_delay)
 217                 GameLogEcho(":startdelay_ended");
 218
 219         game_delay_last = game_delay;
 220
 221         CreatureFrame_All();
 222         CheckRules_World();
 223
 224         if (warmup_stage && !gameover && warmup_limit > 0 && time >= warmup_limit) {
 225                 ReadyRestart();
 226                 return;
 227         }
 228
 229         bot_serverframe();
 230         anticheat_startframe();
 231         MUTATOR_CALLHOOK(SV_StartFrame);
 232
 233     FOREACH_CLIENT(true, GlobalStats_update(it));
 234     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPostThink(it));
 235 }
 236
 237 .vector originjitter;
 238 .vector anglesjitter;
 239 .float anglejitter;
 240 .string gametypefilter;
 241 .string cvarfilter;
 242 bool DoesQ3ARemoveThisEntity(entity this);
 243 void SV_OnEntityPreSpawnFunction(entity this)
 244 {
 245         __spawnfunc_expecting = true;
 246         __spawnfunc_expect = this;
 247         if (this)
 248         if (this.gametypefilter != "")
 249         if (!isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, this.gametypefilter))
 250         {
 251                 delete(this);
 252                 __spawnfunc_expecting = false;
 253                 return;
 254         }
 255         if(this.cvarfilter != "")
 256         {
 257                 float n, i, o, inv;
 258                 string s, k, v;
 259                 inv = 0;
 260
 261                 s = this.cvarfilter;
 262                 if(substring(s, 0, 1) == "+")
 263                 {
 264                         s = substring(s, 1, -1);
 265                 }
 266                 else if(substring(s, 0, 1) == "-")
 267                 {
 268                         inv = 1;
 269                         s = substring(s, 1, -1);
 270                 }
 271
 272                 n = tokenize_console(s);
 273                 for(i = 0; i < n; ++i)
 274                 {
 275                         s = argv(i);
 276                         // syntax:
 277                         // var>x
 278                         // var<x
 279                         // var>=x
 280                         // var<=x
 281                         // var==x
 282                         // var!=x
 283                         // var===x
 284                         // var!==x
 285                         if((o = strstrofs(s, ">=", 0)) >= 0)
 286                         {
 287                                 k = substring(s, 0, o);
 288                                 v = substring(s, o+2, -1);
 289                                 if(cvar(k) < stof(v))
 290                                         goto cvar_fail;
 291                         }
 292                         else if((o = strstrofs(s, "<=", 0)) >= 0)
 293                         {
 294                                 k = substring(s, 0, o);
 295                                 v = substring(s, o+2, -1);
 296                                 if(cvar(k) > stof(v))
 297                                         goto cvar_fail;
 298                         }
 299                         else if((o = strstrofs(s, ">", 0)) >= 0)
 300                         {
 301                                 k = substring(s, 0, o);
 302                                 v = substring(s, o+1, -1);
 303                                 if(cvar(k) <= stof(v))
 304                                         goto cvar_fail;
 305                         }
 306                         else if((o = strstrofs(s, "<", 0)) >= 0)
 307                         {
 308                                 k = substring(s, 0, o);
 309                                 v = substring(s, o+1, -1);
 310                                 if(cvar(k) >= stof(v))
 311                                         goto cvar_fail;
 312                         }
 313                         else if((o = strstrofs(s, "==", 0)) >= 0)
 314                         {
 315                                 k = substring(s, 0, o);
 316                                 v = substring(s, o+2, -1);
 317                                 if(cvar(k) != stof(v))
 318                                         goto cvar_fail;
 319                         }
 320                         else if((o = strstrofs(s, "!=", 0)) >= 0)
 321                         {
 322                                 k = substring(s, 0, o);
 323                                 v = substring(s, o+2, -1);
 324                                 if(cvar(k) == stof(v))
 325                                         goto cvar_fail;
 326                         }
 327                         else if((o = strstrofs(s, "===", 0)) >= 0)
 328                         {
 329                                 k = substring(s, 0, o);
 330                                 v = substring(s, o+2, -1);
 331                                 if(cvar_string(k) != v)
 332                                         goto cvar_fail;
 333                         }
 334                         else if((o = strstrofs(s, "!==", 0)) >= 0)
 335                         {
 336                                 k = substring(s, 0, o);
 337                                 v = substring(s, o+2, -1);
 338                                 if(cvar_string(k) == v)
 339                                         goto cvar_fail;
 340                         }
 341                         else if(substring(s, 0, 1) == "!")
 342                         {
 343                                 k = substring(s, 1, -1);
 344                                 if(cvar(k))
 345                                         goto cvar_fail;
 346                         }
 347                         else
 348                         {
 349                                 k = s;
 350                                 if (!cvar(k))
 351                                         goto cvar_fail;
 352                         }
 353                 }
 354                 inv = !inv;
 355 LABEL(cvar_fail)
 356                 // now inv is 1 if we want to keep the item, and 0 if we want to get rid of it
 357                 if (!inv)
 358                 {
 359                         //print("cvarfilter fail\n");
 360                         delete(this);
 361                         __spawnfunc_expecting = false;
 362                         return;
 363                 }
 364         }
 365
 366         if(DoesQ3ARemoveThisEntity(this))
 367         {
 368                 delete(this);
 369                 __spawnfunc_expecting = false;
 370                 return;
 371         }
 372
 373         set_movetype(this, this.movetype);
 374
 375         // support special -1 and -2 angle from radiant
 376         if (this.angles == '0 -1 0')
 377                 this.angles = '-90 0 0';
 378         else if (this.angles == '0 -2 0')
 379                 this.angles = '+90 0 0';
 380
 381         if(this.originjitter.x != 0)
 382                 this.origin_x = this.origin.x + (random() * 2 - 1) * this.originjitter.x;
 383         if(this.originjitter.y != 0)
 384                 this.origin_y = this.origin.y + (random() * 2 - 1) * this.originjitter.y;
 385         if(this.originjitter.z != 0)
 386                 this.origin_z = this.origin.z + (random() * 2 - 1) * this.originjitter.z;
 387         if(this.anglesjitter.x != 0)
 388                 this.angles_x = this.angles.x + (random() * 2 - 1) * this.anglesjitter.x;
 389         if(this.anglesjitter.y != 0)
 390                 this.angles_y = this.angles.y + (random() * 2 - 1) * this.anglesjitter.y;
 391         if(this.anglesjitter.z != 0)
 392                 this.angles_z = this.angles.z + (random() * 2 - 1) * this.anglesjitter.z;
 393         if(this.anglejitter != 0)
 394                 this.angles_y = this.angles.y + (random() * 2 - 1) * this.anglejitter;
 395
 396         if(MUTATOR_CALLHOOK(OnEntityPreSpawn, this))
 397         {
 398                 delete(this);
 399                 __spawnfunc_expecting = false;
 400                 return;
 401         }
 402 }
 403
 404 void WarpZone_PostInitialize_Callback()
 405 {
 406         // create waypoint links for warpzones
 407         for(entity e = warpzone_first; e; e = e.warpzone_next)
 408         //for(entity e = NULL; (e = find(e, classname, "trigger_warpzone")); )
 409         {
 410                 vector src, dst;
 411                 src = (e.absmin + e.absmax) * 0.5;
 412                 makevectors(e.warpzone_angles);
 413                 src = src + ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
 414                 dst = (e.enemy.absmin + e.enemy.absmax) * 0.5;
 415                 makevectors(e.enemy.warpzone_angles);
 416                 dst = dst + ((e.enemy.warpzone_origin - dst) * v_forward) * v_forward - 16 * v_right;
 417                 waypoint_spawnforteleporter_v(e, src, dst, 0);
 418         }
 419 }