qcsrc/server/t_items.qc

   1 #define ISF_LOCATION 2
   2 #define ISF_MODEL    4
   3 #define ISF_STATUS   8
   4     #define ITS_STAYWEP   1
   5     #define ITS_ANIMATE1  2
   6     #define ITS_ANIMATE2  4
   7     #define ITS_AVAILABLE 8
   8     #define ITS_ALLOWFB   16
   9     #define ITS_ALLOWSI   32
  10     #define ITS_POWERUP   64
  11 #define ISF_COLORMAP 16
  12 #define ISF_DROP 32
  13 #define ISF_ANGLES 64
  14
  15 .float ItemStatus;
  16
  17 #ifdef CSQC
  18
  19 var float  autocvar_cl_animate_items = 1;
  20 var float  autocvar_cl_ghost_items = 0.45;
  21 var vector autocvar_cl_ghost_items_color = '-1 -1 -1';
  22 var float  autocvar_cl_fullbright_items = 0;
  23 var vector autocvar_cl_weapon_stay_color = '2 0.5 0.5';
  24 var float  autocvar_cl_weapon_stay_alpha = 0.75;
  25 var float  autocvar_cl_simple_items = 0;
  26 var string autocvr_cl_simpleitems_postfix = "_simple";
  27 .float  spawntime;
  28 .float  gravity;
  29 .vector colormod;
  30 void ItemDraw()
  31 {
  32     if(self.gravity)
  33     {
  34         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  35         if(self.move_flags & FL_ONGROUND)
  36         { // For some reason move_avelocity gets set to '0 0 0' here ...
  37             self.oldorigin = self.origin;
  38             self.gravity = 0;
  39
  40             if(autocvar_cl_animate_items)
  41             { // ... so reset it if animations are requested.
  42                 if(self.ItemStatus & ITS_ANIMATE1)
  43                     self.move_avelocity = '0 180 0';
  44
  45                 if(self.ItemStatus & ITS_ANIMATE2)
  46                     self.move_avelocity = '0 -90 0';
  47             }
  48         }
  49     }
  50     else if (autocvar_cl_animate_items)
  51     {
  52         if(self.ItemStatus & ITS_ANIMATE1)
  53         {
  54             self.angles += self.move_avelocity * frametime;
  55             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));
  56         }
  57
  58         if(self.ItemStatus & ITS_ANIMATE2)
  59         {
  60             self.angles += self.move_avelocity * frametime;
  61             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));
  62         }
  63     }
  64 }
  65
  66 void ItemDrawSimple()
  67 {
  68     if(self.gravity)
  69     {
  70         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  71
  72         if(self.move_flags & FL_ONGROUND)
  73             self.gravity = 0;
  74     }
  75 }
  76
  77 void ItemRead(float _IsNew)
  78 {
  79     float sf = ReadByte();
  80
  81     if(sf & ISF_LOCATION)
  82     {
  83         self.origin_x = ReadCoord();
  84         self.origin_y = ReadCoord();
  85         self.origin_z = ReadCoord();
  86         setorigin(self, self.origin);
  87         self.oldorigin = self.origin;
  88     }
  89
  90     if(sf & ISF_ANGLES)
  91     {
  92         self.angles_x = ReadCoord();
  93         self.angles_y = ReadCoord();
  94         self.angles_z = ReadCoord();
  95         self.move_angles = self.angles;
  96     }
  97
  98     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
  99     {
 100         self.ItemStatus = ReadByte();
 101
 102         if(self.ItemStatus & ITS_AVAILABLE)
 103         {
 104             self.alpha = 1;
 105             self.colormod = self.glowmod = '1 1 1';
 106         }
 107         else
 108         {
 109             if (autocvar_cl_ghost_items_color)
 110             {
 111                 self.alpha = autocvar_cl_ghost_items;
 112                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
 113             }
 114             else
 115                 self.alpha = -1;
 116         }
 117
 118         if(autocvar_cl_fullbright_items)
 119             if(self.ItemStatus & ITS_ALLOWFB)
 120                 self.effects |= EF_FULLBRIGHT;
 121
 122         if(self.ItemStatus & ITS_STAYWEP)
 123         {
 124             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
 125             self.alpha = autocvar_cl_weapon_stay_alpha;
 126
 127         }
 128
 129         if(self.ItemStatus & ITS_POWERUP)
 130         {
 131             if(self.ItemStatus & ITS_AVAILABLE)
 132                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 133             else
 134                  self.effects &~= (EF_ADDITIVE | EF_FULLBRIGHT);
 135         }
 136     }
 137
 138     if(sf & ISF_MODEL)
 139     {
 140         self.drawmask  = MASK_NORMAL;
 141         self.movetype  = MOVETYPE_NOCLIP;
 142         self.draw       = ItemDraw;
 143
 144         if(self.mdl)
 145             strunzone(self.mdl);
 146
 147         self.mdl = "";
 148         string _fn = ReadString();
 149
 150         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
 151         {
 152             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 153             self.draw = ItemDrawSimple;
 154
 155
 156
 157             if(fexists(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix)))
 158                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix));
 159             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix)))
 160                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix));
 161             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix)))
 162                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix));
 163             else if(fexists(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix)))
 164                 self.mdl = strzone(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix));
 165             else
 166             {
 167                 self.draw = ItemDraw;
 168                 dprint("Simple item requested for ", _fn, " but no model exsist for it\n");
 169             }
 170         }
 171
 172         if(self.draw != ItemDrawSimple)
 173             self.mdl = strzone(_fn);
 174
 175
 176         if(self.mdl == "")
 177             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
 178
 179         precache_model(self.mdl);
 180         setmodel(self, self.mdl);
 181     }
 182
 183     if(sf & ISF_COLORMAP)
 184         self.colormap = ReadShort();
 185
 186     if(sf & ISF_DROP)
 187     {
 188         self.gravity = 1;
 189         self.move_angles = '0 0 0';
 190         self.move_movetype = MOVETYPE_TOSS;
 191         self.move_velocity_x = ReadCoord();
 192         self.move_velocity_y = ReadCoord();
 193         self.move_velocity_z = ReadCoord();
 194         self.velocity = self.move_velocity;
 195         self.move_origin = self.oldorigin;
 196
 197         if(!self.move_time)
 198         {
 199             self.move_time = time;
 200             self.spawntime = time;
 201         }
 202         else
 203             self.move_time = max(self.move_time, time);
 204     }
 205
 206     if(autocvar_cl_animate_items)
 207     {
 208         if(self.ItemStatus & ITS_ANIMATE1)
 209             self.move_avelocity = '0 180 0';
 210
 211         if(self.ItemStatus & ITS_ANIMATE2)
 212             self.move_avelocity = '0 -90 0';
 213     }
 214 }
 215
 216 #endif
 217
 218 #ifdef SVQC
 219 float autocvar_sv_simple_items;
 220 float ItemSend(entity to, float sf)
 221 {
 222     if(self.gravity)
 223         sf |= ISF_DROP;
 224     else
 225         sf &~= ISF_DROP;
 226
 227         WriteByte(MSG_ENTITY, ENT_CLIENT_ITEM);
 228         WriteByte(MSG_ENTITY, sf);
 229
 230         //WriteByte(MSG_ENTITY, self.cnt);
 231     if(sf & ISF_LOCATION)
 232     {
 233         WriteCoord(MSG_ENTITY, self.origin_x);
 234         WriteCoord(MSG_ENTITY, self.origin_y);
 235         WriteCoord(MSG_ENTITY, self.origin_z);
 236     }
 237
 238     if(sf & ISF_ANGLES)
 239     {
 240         WriteCoord(MSG_ENTITY, self.angles_x);
 241         WriteCoord(MSG_ENTITY, self.angles_y);
 242         WriteCoord(MSG_ENTITY, self.angles_z);
 243     }
 244
 245     if(sf & ISF_STATUS)
 246         WriteByte(MSG_ENTITY, self.ItemStatus);
 247
 248     if(sf & ISF_MODEL)
 249     {
 250
 251         if(self.mdl == "")
 252             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
 253
 254         WriteString(MSG_ENTITY, self.mdl);
 255     }
 256
 257
 258     if(sf & ISF_COLORMAP)
 259         WriteShort(MSG_ENTITY, self.colormap);
 260
 261     if(sf & ISF_DROP)
 262     {
 263         WriteCoord(MSG_ENTITY, self.velocity_x);
 264         WriteCoord(MSG_ENTITY, self.velocity_y);
 265         WriteCoord(MSG_ENTITY, self.velocity_z);
 266     }
 267
 268     return TRUE;
 269 }
 270
 271
 272 float have_pickup_item(void)
 273 {
 274         if(self.flags & FL_POWERUP)
 275         {
 276                 if(autocvar_g_powerups > 0)
 277                         return TRUE;
 278                 if(autocvar_g_powerups == 0)
 279                         return FALSE;
 280                 if(g_lms)
 281                         return FALSE;
 282                 if(g_ca)
 283                         return FALSE;
 284                 if(g_arena)
 285                         return FALSE;
 286         }
 287         else
 288         {
 289                 if(autocvar_g_pickup_items > 0)
 290                         return TRUE;
 291                 if(autocvar_g_pickup_items == 0)
 292                         return FALSE;
 293                 if(g_lms)
 294                         return FALSE;
 295                 if(g_ca)
 296                         return FALSE;
 297                 if(g_weaponarena)
 298                         if(!WEPSET_EMPTY_E(self) || (self.items & IT_AMMO))
 299                                 return FALSE;
 300         }
 301         return TRUE;
 302 }
 303
 304 #define ITEM_RESPAWN_TICKS 10
 305
 306 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
 307         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
 308 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
 309         // range: 10 .. respawntime + respawntimejitter
 310
 311 floatfield Item_CounterField(float it)
 312 {
 313         switch(it)
 314         {
 315                 case IT_SHELLS:      return ammo_shells;
 316                 case IT_NAILS:       return ammo_nails;
 317                 case IT_ROCKETS:     return ammo_rockets;
 318                 case IT_CELLS:       return ammo_cells;
 319                 case IT_FUEL:        return ammo_fuel;
 320                 case IT_5HP:         return health;
 321                 case IT_25HP:        return health;
 322                 case IT_HEALTH:      return health;
 323                 case IT_ARMOR_SHARD: return armorvalue;
 324                 case IT_ARMOR:       return armorvalue;
 325                 // add more things here (health, armor)
 326                 default:             error("requested item has no counter field");
 327         }
 328 }
 329
 330 string Item_CounterFieldName(float it)
 331 {
 332         switch(it)
 333         {
 334                 case IT_SHELLS:      return "shells";
 335                 case IT_NAILS:       return "nails";
 336                 case IT_ROCKETS:     return "rockets";
 337                 case IT_CELLS:       return "cells";
 338                 case IT_FUEL:        return "fuel";
 339
 340                 // add more things here (health, armor)
 341                 default:             error("requested item has no counter field name");
 342         }
 343 }
 344
 345 .float max_armorvalue;
 346 .float pickup_anyway;
 347 /*
 348 float Item_Customize()
 349 {
 350         if(self.spawnshieldtime)
 351                 return TRUE;
 352         if(!WEPSET_CONTAINS_ALL_EE(other, self))
 353         {
 354                 self.colormod = '0 0 0';
 355                 self.glowmod = self.colormod;
 356                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 357                 return TRUE;
 358         }
 359         else
 360         {
 361                 if(g_ghost_items)
 362                 {
 363                         self.colormod = stov(autocvar_g_ghost_items_color);
 364                         self.glowmod = self.colormod;
 365                         self.alpha = g_ghost_items;
 366                         return TRUE;
 367                 }
 368                 else
 369                         return FALSE;
 370         }
 371 }
 372 */
 373
 374 void Item_Show (entity e, float mode)
 375 {
 376         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 377         e.ItemStatus &~= ITS_STAYWEP;
 378         if (mode > 0)
 379         {
 380                 // make the item look normal, and be touchable
 381                 e.model = e.mdl;
 382                 e.solid = SOLID_TRIGGER;
 383                 e.spawnshieldtime = 1;
 384                 e.ItemStatus |= ITS_AVAILABLE;
 385         }
 386         else if (mode < 0)
 387         {
 388                 // hide the item completely
 389                 e.model = string_null;
 390                 e.solid = SOLID_NOT;
 391                 e.spawnshieldtime = 1;
 392                 e.ItemStatus &~= ITS_AVAILABLE;
 393         }
 394         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 395         {
 396                 // make the item translucent and not touchable
 397                 e.model = e.mdl;
 398                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 399                 e.effects |= EF_STARDUST;
 400                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 401                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 402         }
 403         else
 404         {
 405                 //setmodel(e, "null");
 406                 e.solid = SOLID_NOT;
 407                 e.colormod = '0 0 0';
 408                 e.glowmod = e.colormod;
 409                 e.spawnshieldtime = 1;
 410                 e.ItemStatus &~= ITS_AVAILABLE;
 411         }
 412
 413         if (e.items & IT_STRENGTH || e.items & IT_INVINCIBLE)
 414             e.ItemStatus |= ITS_POWERUP;
 415
 416         if (autocvar_g_nodepthtestitems)
 417                 e.effects |= EF_NODEPTHTEST;
 418
 419
 420     if (autocvar_g_fullbrightitems)
 421                 e.ItemStatus |= ITS_ALLOWFB;
 422
 423         if (autocvar_sv_simple_items)
 424         e.ItemStatus |= ITS_ALLOWSI;
 425
 426         // relink entity (because solid may have changed)
 427         setorigin(e, e.origin);
 428     e.SendFlags |= ISF_STATUS;
 429 }
 430
 431 void Item_Respawn (void)
 432 {
 433         Item_Show(self, 1);
 434         // this is ugly...
 435         if(self.items == IT_STRENGTH)
 436                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 437         else if(self.items == IT_INVINCIBLE)
 438                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 439         else
 440                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 441         setorigin (self, self.origin);
 442
 443         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 444         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 445 }
 446
 447 void Item_RespawnCountdown (void)
 448 {
 449         if(self.count >= ITEM_RESPAWN_TICKS)
 450         {
 451                 if(self.waypointsprite_attached)
 452                         WaypointSprite_Kill(self.waypointsprite_attached);
 453                 Item_Respawn();
 454         }
 455         else
 456         {
 457                 self.nextthink = time + 1;
 458                 self.count += 1;
 459                 if(self.count == 1)
 460                 {
 461                         string name;
 462                         vector rgb = '1 0 1';
 463                         name = string_null;
 464                         switch(self.items)
 465                         {
 466                                 case IT_FUEL_REGEN: name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 467                                 case IT_JETPACK:    name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 468                                 case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 469                                 case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 470                         }
 471                         item_name = name;
 472                         item_color = rgb;
 473                         MUTATOR_CALLHOOK(Item_RespawnCountdown);
 474                         name = item_name;
 475                         rgb = item_color;
 476                         if(self.flags & FL_WEAPON)
 477                         {
 478                                 entity wi = get_weaponinfo(self.weapon);
 479                                 if(wi)
 480                                 {
 481                                         name = wi.model2;
 482                                         rgb = '1 0 0';
 483                                 }
 484                         }
 485                         if(!name)
 486                         {
 487                                 print("Unknown powerup-marked item is wanting to respawn\n");
 488                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 489                         }
 490                         if(name)
 491                         {
 492                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 493                                 if(self.waypointsprite_attached)
 494                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 495                         }
 496                 }
 497                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 498                 if(self.waypointsprite_attached)
 499                 {
 500                         WaypointSprite_Ping(self.waypointsprite_attached);
 501                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 502                 }
 503         }
 504 }
 505
 506 void Item_ScheduleRespawnIn(entity e, float t)
 507 {
 508         if((e.flags & FL_POWERUP) || WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
 509         {
 510                 e.think = Item_RespawnCountdown;
 511                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 512                 e.count = 0;
 513         }
 514         else
 515         {
 516                 e.think = Item_Respawn;
 517                 e.nextthink = time + t;
 518         }
 519 }
 520
 521 void Item_ScheduleRespawn(entity e)
 522 {
 523         if(e.respawntime > 0)
 524         {
 525                 Item_Show(e, 0);
 526                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 527         }
 528         else // if respawntime is -1, this item does not respawn
 529                 Item_Show(e, -1);
 530 }
 531
 532 void Item_ScheduleInitialRespawn(entity e)
 533 {
 534         Item_Show(e, 0);
 535         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 536 }
 537
 538 float ITEM_MODE_NONE = 0;
 539 float ITEM_MODE_HEALTH = 1;
 540 float ITEM_MODE_ARMOR = 2;
 541 float ITEM_MODE_FUEL = 3;
 542 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
 543 {
 544         if (!item.ammofield)
 545                 return FALSE;
 546
 547         if (item.spawnshieldtime)
 548         {
 549                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 550                 {
 551                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
 552                         goto YEAH;
 553                 }
 554         }
 555         else if(g_weapon_stay == 2)
 556         {
 557                 float mi = min(item.ammofield, ammomax);
 558                 if (player.ammofield < mi)
 559                 {
 560                         player.ammofield = mi;
 561                         goto YEAH;
 562                 }
 563         }
 564
 565         return FALSE;
 566
 567 :YEAH
 568         switch(mode)
 569         {
 570                 case ITEM_MODE_FUEL:
 571                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 572                         break;
 573                 case ITEM_MODE_HEALTH:
 574                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 575                         break;
 576                 case ITEM_MODE_ARMOR:
 577                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 578                         break;
 579                 default:
 580                         break;
 581         }
 582         return TRUE;
 583 }
 584
 585 float Item_GiveTo(entity item, entity player)
 586 {
 587         float _switchweapon;
 588         float pickedup;
 589         float it;
 590         float i;
 591
 592         // if nothing happens to player, just return without taking the item
 593         pickedup = FALSE;
 594         _switchweapon = FALSE;
 595
 596                 // in case the player has autoswitch enabled do the following:
 597                 // if the player is using their best weapon before items are given, they
 598                 // probably want to switch to an even better weapon after items are given
 599                 if (player.autoswitch)
 600                 if (player.switchweapon == w_getbestweapon(player))
 601                         _switchweapon = TRUE;
 602
 603                 if not(WEPSET_CONTAINS_EW(player, player.switchweapon))
 604                         _switchweapon = TRUE;
 605
 606                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 607                 pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 608                 pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 609                 pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 610                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 611                 pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 612                 pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 613
 614                 if (item.flags & FL_WEAPON)
 615                 {
 616                         WEPSET_DECLARE_A(it);
 617                         WEPSET_COPY_AE(it, item);
 618                         WEPSET_ANDNOT_AE(it, player);
 619
 620                         if (!WEPSET_EMPTY_A(it) || (item.spawnshieldtime && self.pickup_anyway))
 621                         {
 622                                 pickedup = TRUE;
 623                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 624                                         if(WEPSET_CONTAINS_AW(it, i))
 625                                                 W_GiveWeapon (player, i, item.netname);
 626                         }
 627                 }
 628
 629                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 630                 {
 631                         pickedup = TRUE;
 632                         player.items |= it;
 633                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 634                 }
 635
 636                 if (item.strength_finished)
 637                 {
 638                         pickedup = TRUE;
 639                         player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 640                 }
 641                 if (item.invincible_finished)
 642                 {
 643                         pickedup = TRUE;
 644                         player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 645                 }
 646                 if (item.superweapons_finished)
 647                 {
 648                         pickedup = TRUE;
 649                         player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 650                 }
 651
 652 :skip
 653
 654         giveplayer = player;
 655         giveitem = item;
 656         player_wswitch = _switchweapon;
 657         player_pickedup = pickedup;
 658         MUTATOR_CALLHOOK(Item_GiveTo);
 659         _switchweapon = player_wswitch;
 660         pickedup = player_pickedup;
 661
 662         // always eat teamed entities
 663         if(item.team)
 664                 pickedup = TRUE;
 665
 666         if (!pickedup)
 667                 return 0;
 668
 669         if (_switchweapon)
 670                 if (player.switchweapon != w_getbestweapon(player))
 671                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 672
 673         return 1;
 674 }
 675
 676 void Item_Touch (void)
 677 {
 678         entity e, head;
 679
 680         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 681         if(self.classname == "droppedweapon")
 682         {
 683                 if (ITEM_TOUCH_NEEDKILL())
 684                 {
 685                         remove(self);
 686                         return;
 687                 }
 688         }
 689
 690         if (other.classname != "player")
 691                 return;
 692         if (other.deadflag)
 693                 return;
 694         if (self.solid != SOLID_TRIGGER)
 695                 return;
 696         if (self.owner == other)
 697                 return;
 698         if(MUTATOR_CALLHOOK(ItemTouch))
 699                 return;
 700
 701         if (self.classname == "droppedweapon")
 702         {
 703                 self.strength_finished = max(0, self.strength_finished - time);
 704                 self.invincible_finished = max(0, self.invincible_finished - time);
 705                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 706         }
 707
 708         if(!Item_GiveTo(self, other))
 709         {
 710                 if (self.classname == "droppedweapon")
 711                 {
 712                         // undo what we did above
 713                         self.strength_finished += time;
 714                         self.invincible_finished += time;
 715                         self.superweapons_finished += time;
 716                 }
 717                 return;
 718         }
 719
 720         other.last_pickup = time;
 721
 722         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 723         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTN_NORM);
 724
 725         if (self.classname == "droppedweapon")
 726                 remove (self);
 727         else if not(self.spawnshieldtime)
 728                 return;
 729         else
 730         {
 731                 if(self.team)
 732                 {
 733                         RandomSelection_Init();
 734                         for(head = world; (head = findfloat(head, team, self.team)); )
 735                         {
 736                                 if(head.flags & FL_ITEM)
 737                                 {
 738                                         Item_Show(head, -1);
 739                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 740                                 }
 741                         }
 742                         e = RandomSelection_chosen_ent;
 743
 744                 }
 745                 else
 746                         e = self;
 747                 Item_ScheduleRespawn(e);
 748         }
 749 }
 750
 751 void Item_Reset()
 752 {
 753         Item_Show(self, !self.state);
 754         setorigin (self, self.origin);
 755
 756         if(self.classname != "droppedweapon")
 757         {
 758                 self.think = SUB_Null;
 759                 self.nextthink = 0;
 760
 761                 if(self.waypointsprite_attached)
 762                         WaypointSprite_Kill(self.waypointsprite_attached);
 763
 764                 if((self.flags & FL_POWERUP) | WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // do not spawn powerups initially!
 765                         Item_ScheduleInitialRespawn(self);
 766         }
 767 }
 768
 769 void Item_FindTeam()
 770 {
 771         entity head, e;
 772
 773         if(self.effects & EF_NODRAW)
 774         {
 775                 // marker for item team search
 776                 dprint("Initializing item team ", ftos(self.team), "\n");
 777                 RandomSelection_Init();
 778                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 779                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 780                 e = RandomSelection_chosen_ent;
 781                 e.state = 0;
 782                 Item_Show(e, 1);
 783
 784                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 785                 {
 786                         if(head != e)
 787                         {
 788                                 // make it a non-spawned item
 789                                 Item_Show(head, -1);
 790                                 head.state = 1; // state 1 = initially hidden item
 791                         }
 792                         head.effects &~= EF_NODRAW;
 793                 }
 794
 795                 Item_Reset();
 796         }
 797 }
 798
 799 // Savage: used for item garbage-collection
 800 // TODO: perhaps nice special effect?
 801 void RemoveItem(void)
 802 {
 803         remove(self);
 804 }
 805
 806 // pickup evaluation functions
 807 // these functions decide how desirable an item is to the bots
 808
 809 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 810
 811 float weapon_pickupevalfunc(entity player, entity item)
 812 {
 813         float c, j, position;
 814
 815         // See if I have it already
 816         if(!WEPSET_CONTAINS_ALL_EE(player, item))
 817         {
 818                 // If I can pick it up
 819                 if(!item.spawnshieldtime)
 820                         c = 0;
 821                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 822                 {
 823                         // Skilled bots will grab more
 824                         c = bound(0, skill / 10, 1) * 0.5;
 825                 }
 826                 else
 827                         c = 0;
 828         }
 829         else
 830                 c = 1;
 831
 832         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 833         if( bot_custom_weapon && c )
 834         {
 835                 // Find the highest position on any range
 836                 position = -1;
 837                 for(j = 0; j < WEP_LAST ; ++j){
 838                         if(
 839                                         bot_weapons_far[j] == item.weapon ||
 840                                         bot_weapons_mid[j] == item.weapon ||
 841                                         bot_weapons_close[j] == item.weapon
 842                           )
 843                         {
 844                                 position = j;
 845                                 break;
 846                         }
 847                 }
 848
 849                 // Rate it
 850                 if (position >= 0 )
 851                 {
 852                         position = WEP_LAST - position;
 853                         // item.bot_pickupbasevalue is overwritten here
 854                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 855                 }
 856         }
 857
 858         return item.bot_pickupbasevalue * c;
 859 }
 860
 861 float commodity_pickupevalfunc(entity player, entity item)
 862 {
 863         float c, i;
 864         float need_shells = FALSE, need_nails = FALSE, need_rockets = FALSE, need_cells = FALSE, need_fuel = FALSE;
 865         entity wi;
 866         c = 0;
 867
 868         // Detect needed ammo
 869         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 870         {
 871                 wi = get_weaponinfo(i);
 872
 873                 if not(WEPSET_CONTAINS_EW(player, i))
 874                         continue;
 875
 876                 if(wi.items & IT_SHELLS)
 877                         need_shells = TRUE;
 878                 else if(wi.items & IT_NAILS)
 879                         need_nails = TRUE;
 880                 else if(wi.items & IT_ROCKETS)
 881                         need_rockets = TRUE;
 882                 else if(wi.items & IT_CELLS)
 883                         need_cells = TRUE;
 884                 else if(wi.items & IT_FUEL)
 885                         need_cells = TRUE;
 886         }
 887
 888         // TODO: figure out if the player even has the weapon this ammo is for?
 889         // may not affect strategy much though...
 890         // find out how much more ammo/armor/health the player can hold
 891         if (need_shells)
 892         if (item.ammo_shells)
 893         if (player.ammo_shells < g_pickup_shells_max)
 894                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 895         if (need_nails)
 896         if (item.ammo_nails)
 897         if (player.ammo_nails < g_pickup_nails_max)
 898                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 899         if (need_rockets)
 900         if (item.ammo_rockets)
 901         if (player.ammo_rockets < g_pickup_rockets_max)
 902                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 903         if (need_cells)
 904         if (item.ammo_cells)
 905         if (player.ammo_cells < g_pickup_cells_max)
 906                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 907         if (need_fuel)
 908         if (item.ammo_fuel)
 909         if (player.ammo_fuel < g_pickup_fuel_max)
 910                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 911         if (item.armorvalue)
 912         if (player.armorvalue < item.max_armorvalue)
 913                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 914         if (item.health)
 915         if (player.health < item.max_health)
 916                 c = c + max(0, 1 - player.health / item.max_health);
 917
 918         return item.bot_pickupbasevalue * c;
 919 }
 920
 921 void Item_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 922 {
 923         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 924                 RemoveItem();
 925 }
 926
 927 .float is_item;
 928 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 929 {
 930         startitem_failed = FALSE;
 931
 932         if(self.model == "")
 933                 self.model = itemmodel;
 934
 935         if(self.model == "")
 936     {
 937         error(strcat("^1Tried to spawn ", itemname, " with no model!\n"));
 938         return;
 939     }
 940
 941         if(self.item_pickupsound == "")
 942                 self.item_pickupsound = pickupsound;
 943
 944         if(!self.respawntime) // both need to be set
 945         {
 946                 self.respawntime = defaultrespawntime;
 947                 self.respawntimejitter = defaultrespawntimejitter;
 948         }
 949
 950         self.items = itemid;
 951         self.weapon = weaponid;
 952
 953         if(weaponid)
 954                 WEPSET_COPY_EW(self, weaponid);
 955
 956         self.flags = FL_ITEM | itemflags;
 957
 958         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 959         {
 960                 startitem_failed = TRUE;
 961                 remove(self);
 962                 return;
 963         }
 964
 965         // is it a dropped weapon?
 966         if (self.classname == "droppedweapon")
 967         {
 968                 self.reset = SUB_Remove;
 969                 // it's a dropped weapon
 970                 self.movetype = MOVETYPE_TOSS;
 971
 972                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 973                 self.think = RemoveItem;
 974                 self.nextthink = time + 20;
 975
 976                 self.takedamage = DAMAGE_YES;
 977                 self.event_damage = Item_Damage;
 978
 979                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
 980                 /*
 981                 if(self.items == 0)
 982                 if(WEPSET_CONTAINS_ALL_AE(WEPBIT_SUPERWEAPONS, self)) // only superweapons
 983                 if(self.ammo_nails == 0)
 984                 if(self.ammo_cells == 0)
 985                 if(self.ammo_rockets == 0)
 986                 if(self.ammo_shells == 0)
 987                 if(self.ammo_fuel == 0)
 988                 if(self.health == 0)
 989                 if(self.armorvalue == 0)
 990                 */
 991                 {
 992                         // if item is worthless after a timer, have it expire then
 993                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
 994                 }
 995
 996                 // don't drop if in a NODROP zone (such as lava)
 997                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 998                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 999                 {
1000                         startitem_failed = TRUE;
1001                         remove(self);
1002                         return;
1003                 }
1004         }
1005         else
1006         {
1007                 if(!have_pickup_item())
1008                 {
1009                         startitem_failed = TRUE;
1010                         remove (self);
1011                         return;
1012                 }
1013
1014                 if(self.angles != '0 0 0')
1015             self.SendFlags |= ISF_ANGLES;
1016
1017                 self.reset = Item_Reset;
1018                 // it's a level item
1019                 if(self.spawnflags & 1)
1020                         self.noalign = 1;
1021                 if (self.noalign)
1022                         self.movetype = MOVETYPE_NONE;
1023                 else
1024                         self.movetype = MOVETYPE_TOSS;
1025                 // do item filtering according to game mode and other things
1026                 if (!self.noalign)
1027                 {
1028                         // first nudge it off the floor a little bit to avoid math errors
1029                         setorigin(self, self.origin + '0 0 1');
1030                         // set item size before we spawn a spawnfunc_waypoint
1031                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1032                                 setsize (self, '-16 -16 0', '16 16 48');
1033                         else
1034                                 setsize (self, '-16 -16 0', '16 16 32');
1035                         // note droptofloor returns FALSE if stuck/or would fall too far
1036                         droptofloor();
1037                         waypoint_spawnforitem(self);
1038                 }
1039
1040                 /*
1041                  * can't do it that way, as it would break maps
1042                  * TODO make a target_give like entity another way, that perhaps has
1043                  * the weapon name in a key
1044                 if(self.targetname)
1045                 {
1046                         // target_give not yet supported; maybe later
1047                         print("removed targeted ", self.classname, "\n");
1048                         startitem_failed = TRUE;
1049                         remove (self);
1050                         return;
1051                 }
1052                 */
1053
1054                 if(autocvar_spawn_debug >= 2)
1055                 {
1056                         entity otheritem;
1057                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
1058                         {
1059                             // why not flags & fl_item?
1060                                 if(otheritem.is_item)
1061                                 {
1062                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
1063                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1064                                         error("Mapper sucks.");
1065                                 }
1066                         }
1067                         self.is_item = TRUE;
1068                 }
1069
1070                 WEPSET_OR_AW(weaponsInMap, weaponid);
1071
1072                 precache_model (self.model);
1073                 precache_sound (self.item_pickupsound);
1074
1075                 precache_sound ("misc/itemrespawncountdown.wav");
1076                 if(itemid == IT_STRENGTH)
1077                         precache_sound ("misc/strength_respawn.wav");
1078                 else if(itemid == IT_INVINCIBLE)
1079                         precache_sound ("misc/shield_respawn.wav");
1080                 else
1081                         precache_sound ("misc/itemrespawn.wav");
1082
1083                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
1084                         self.target = "###item###"; // for finding the nearest item using find()
1085         }
1086
1087         self.bot_pickup = TRUE;
1088         self.bot_pickupevalfunc = pickupevalfunc;
1089         self.bot_pickupbasevalue = pickupbasevalue;
1090         self.mdl = self.model;
1091         self.netname = itemname;
1092         self.touch = Item_Touch;
1093         setmodel(self, "null"); // precision set below
1094         //self.effects |= EF_LOWPRECISION;
1095
1096         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1097     {
1098         self.pos1 = '-16 -16 0';
1099         self.pos2 = '16 16 48';
1100     }
1101         else
1102     {
1103         self.pos1 = '-16 -16 0';
1104         self.pos2 = '16 16 32';
1105     }
1106     setsize (self, self.pos1, self.pos2);
1107
1108     if(itemflags & FL_POWERUP)
1109         self.ItemStatus |= ITS_ANIMATE1;
1110
1111         if(self.armorvalue || self.health)
1112         self.ItemStatus |= ITS_ANIMATE2;
1113
1114         if(itemflags & FL_WEAPON)
1115         {
1116                 if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1117             self.colormap = 1024; // color shirt=0 pants=0 grey
1118         else
1119             self.gravity = 1;
1120
1121                 self.ItemStatus |= ITS_ANIMATE1;
1122                 self.ItemStatus |= ISF_COLORMAP;
1123         }
1124
1125         self.state = 0;
1126         if(self.team) // broken, no idea why.
1127         {
1128                 if(!self.cnt)
1129                         self.cnt = 1; // item probability weight
1130
1131                 self.effects |= EF_NODRAW; // marker for item team search
1132                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
1133         }
1134         else
1135                 Item_Reset();
1136
1137     Net_LinkEntity(self, FALSE, 0, ItemSend);
1138 }
1139
1140 float weaponswapping;
1141 float internalteam;
1142
1143 void weapon_defaultspawnfunc(float wpn)
1144 {
1145         entity e;
1146         float t;
1147         var .float ammofield;
1148         string s;
1149         entity oldself;
1150         float i, j;
1151         float f;
1152
1153         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
1154         {
1155                 e = get_weaponinfo(wpn);
1156
1157                 if(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1158                 {
1159                         print("Attempted to spawn a mutator-blocked weapon; these guns will in the future require a mutator\n");
1160                         /*
1161                         objerror("Attempted to spawn a mutator-blocked weapon rejected");
1162                         startitem_failed = TRUE;
1163                         return;
1164                         */
1165                 }
1166
1167                 s = W_Apply_Weaponreplace(e.netname);
1168                 ret_string = s;
1169                 other = e;
1170                 MUTATOR_CALLHOOK(SetWeaponreplace);
1171                 s = ret_string;
1172                 if(s == "")
1173                 {
1174                         remove(self);
1175                         startitem_failed = TRUE;
1176                         return;
1177                 }
1178                 t = tokenize_console(s);
1179                 if(t >= 2)
1180                 {
1181                         self.team = --internalteam;
1182                         oldself = self;
1183                         for(i = 1; i < t; ++i)
1184                         {
1185                                 s = argv(i);
1186                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1187                                 {
1188                                         e = get_weaponinfo(j);
1189                                         if(e.netname == s)
1190                                         {
1191                                                 self = spawn();
1192                                                 copyentity(oldself, self);
1193                                                 self.classname = "replacedweapon";
1194                                                 weapon_defaultspawnfunc(j);
1195                                                 break;
1196                                         }
1197                                 }
1198                                 if(j > WEP_LAST)
1199                                 {
1200                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1201                                 }
1202                         }
1203                         self = oldself;
1204                 }
1205                 if(t >= 1) // always the case!
1206                 {
1207                         s = argv(0);
1208                         wpn = 0;
1209                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1210                         {
1211                                 e = get_weaponinfo(j);
1212                                 if(e.netname == s)
1213                                 {
1214                                         wpn = j;
1215                                         break;
1216                                 }
1217                         }
1218                         if(j > WEP_LAST)
1219                         {
1220                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1221                         }
1222                 }
1223                 if(wpn == 0)
1224                 {
1225                         remove(self);
1226                         startitem_failed = TRUE;
1227                         return;
1228                 }
1229         }
1230
1231         e = get_weaponinfo(wpn);
1232
1233         if(!self.respawntime)
1234         {
1235                 if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1236                 {
1237                         self.respawntime = g_pickup_respawntime_superweapon;
1238                         self.respawntimejitter = g_pickup_respawntimejitter_superweapon;
1239                 }
1240                 else
1241                 {
1242                         self.respawntime = g_pickup_respawntime_weapon;
1243                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1244                 }
1245         }
1246
1247         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1248                 if(!self.superweapons_finished)
1249                         self.superweapons_finished = autocvar_g_balance_superweapons_time;
1250
1251         if(e.items)
1252         {
1253                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1254                 {
1255                         if(e.items & j)
1256                         {
1257                                 ammofield = Item_CounterField(j);
1258                                 if(!self.ammofield)
1259                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1260                         }
1261                 }
1262         }
1263
1264         // pickup anyway
1265         if(g_pickup_weapons_anyway)
1266                 self.pickup_anyway = TRUE;
1267
1268         f = FL_WEAPON;
1269
1270         // no weapon-stay on superweapons
1271         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1272                 f |= FL_NO_WEAPON_STAY;
1273
1274         // weapon stay isn't supported for teamed weapons
1275         if(self.team)
1276                 f |= FL_NO_WEAPON_STAY;
1277
1278         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapon, f, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1279         if (self.modelindex) // don't precache if self was removed
1280                 weapon_action(e.weapon, WR_PRECACHE);
1281 }
1282
1283 void spawnfunc_weapon_shotgun (void);
1284 void spawnfunc_weapon_uzi (void) {
1285         if(autocvar_sv_q3acompat_machineshotgunswap)
1286         if(self.classname != "droppedweapon")
1287         {
1288                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1289                 return;
1290         }
1291         weapon_defaultspawnfunc(WEP_UZI);
1292 }
1293
1294 void spawnfunc_weapon_shotgun (void) {
1295         if(autocvar_sv_q3acompat_machineshotgunswap)
1296         if(self.classname != "droppedweapon")
1297         {
1298                 weapon_defaultspawnfunc(WEP_UZI);
1299                 return;
1300         }
1301         weapon_defaultspawnfunc(WEP_SHOTGUN);
1302 }
1303
1304 void spawnfunc_weapon_nex (void)
1305 {
1306         weapon_defaultspawnfunc(WEP_NEX);
1307 }
1308
1309 void spawnfunc_weapon_minstanex (void)
1310 {
1311         weapon_defaultspawnfunc(WEP_MINSTANEX);
1312 }
1313
1314 void spawnfunc_weapon_rocketlauncher (void)
1315 {
1316         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1317 }
1318
1319 void spawnfunc_item_rockets (void) {
1320         if(!self.ammo_rockets)
1321                 self.ammo_rockets = g_pickup_rockets;
1322         if(!self.pickup_anyway)
1323                 self.pickup_anyway = g_pickup_ammo_anyway;
1324         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1325 }
1326
1327 void spawnfunc_item_shells (void);
1328 void spawnfunc_item_bullets (void) {
1329         if(!weaponswapping)
1330         if(autocvar_sv_q3acompat_machineshotgunswap)
1331         if(self.classname != "droppedweapon")
1332         {
1333                 weaponswapping = TRUE;
1334                 spawnfunc_item_shells();
1335                 weaponswapping = FALSE;
1336                 return;
1337         }
1338
1339         if(!self.ammo_nails)
1340                 self.ammo_nails = g_pickup_nails;
1341         if(!self.pickup_anyway)
1342                 self.pickup_anyway = g_pickup_ammo_anyway;
1343         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1344 }
1345
1346 void spawnfunc_item_cells (void) {
1347         if(!self.ammo_cells)
1348                 self.ammo_cells = g_pickup_cells;
1349         if(!self.pickup_anyway)
1350                 self.pickup_anyway = g_pickup_ammo_anyway;
1351         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1352 }
1353
1354 void spawnfunc_item_shells (void) {
1355         if(!weaponswapping)
1356         if(autocvar_sv_q3acompat_machineshotgunswap)
1357         if(self.classname != "droppedweapon")
1358         {
1359                 weaponswapping = TRUE;
1360                 spawnfunc_item_bullets();
1361                 weaponswapping = FALSE;
1362                 return;
1363         }
1364
1365         if(!self.ammo_shells)
1366                 self.ammo_shells = g_pickup_shells;
1367         if(!self.pickup_anyway)
1368                 self.pickup_anyway = g_pickup_ammo_anyway;
1369         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1370 }
1371
1372 void spawnfunc_item_armor_small (void) {
1373         if(!self.armorvalue)
1374                 self.armorvalue = g_pickup_armorsmall;
1375         if(!self.max_armorvalue)
1376                 self.max_armorvalue = g_pickup_armorsmall_max;
1377         if(!self.pickup_anyway)
1378                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1379         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1380 }
1381
1382 void spawnfunc_item_armor_medium (void) {
1383         if(!self.armorvalue)
1384                 self.armorvalue = g_pickup_armormedium;
1385         if(!self.max_armorvalue)
1386                 self.max_armorvalue = g_pickup_armormedium_max;
1387         if(!self.pickup_anyway)
1388                 self.pickup_anyway = g_pickup_armormedium_anyway;
1389         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1390 }
1391
1392 void spawnfunc_item_armor_big (void) {
1393         if(!self.armorvalue)
1394                 self.armorvalue = g_pickup_armorbig;
1395         if(!self.max_armorvalue)
1396                 self.max_armorvalue = g_pickup_armorbig_max;
1397         if(!self.pickup_anyway)
1398                 self.pickup_anyway = g_pickup_armorbig_anyway;
1399         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1400 }
1401
1402 void spawnfunc_item_armor_large (void) {
1403         if(!self.armorvalue)
1404                 self.armorvalue = g_pickup_armorlarge;
1405         if(!self.max_armorvalue)
1406                 self.max_armorvalue = g_pickup_armorlarge_max;
1407         if(!self.pickup_anyway)
1408                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1409         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1410 }
1411
1412 void spawnfunc_item_health_small (void) {
1413         if(!self.max_health)
1414                 self.max_health = g_pickup_healthsmall_max;
1415         if(!self.health)
1416                 self.health = g_pickup_healthsmall;
1417         if(!self.pickup_anyway)
1418                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1419         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1420 }
1421
1422 void spawnfunc_item_health_medium (void) {
1423         if(!self.max_health)
1424                 self.max_health = g_pickup_healthmedium_max;
1425         if(!self.health)
1426                 self.health = g_pickup_healthmedium;
1427         if(!self.pickup_anyway)
1428                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1429         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1430 }
1431
1432 void spawnfunc_item_health_large (void) {
1433         if(!self.max_health)
1434                 self.max_health = g_pickup_healthlarge_max;
1435         if(!self.health)
1436                 self.health = g_pickup_healthlarge;
1437         if(!self.pickup_anyway)
1438                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1439         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1440 }
1441
1442 void spawnfunc_item_health_mega (void) {
1443                 if(!self.max_health)
1444                         self.max_health = g_pickup_healthmega_max;
1445                 if(!self.health)
1446                         self.health = g_pickup_healthmega;
1447                 if(!self.pickup_anyway)
1448                         self.pickup_anyway = g_pickup_healthmega_anyway;
1449                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1450 }
1451
1452 // support old misnamed entities
1453 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1454 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1455 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1456 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1457 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1458
1459 void spawnfunc_item_strength (void) {
1460                 precache_sound("weapons/strength_fire.wav");
1461                 if(!self.strength_finished)
1462                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1463                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1464 }
1465
1466 void spawnfunc_item_invincible (void) {
1467                 if(!self.invincible_finished)
1468                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1469                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1470 }
1471
1472 // compatibility:
1473 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1474
1475 float GiveItems(entity e, float beginarg, float endarg);
1476 void target_items_use (void)
1477 {
1478         if(activator.classname == "droppedweapon")
1479         {
1480                 EXACTTRIGGER_TOUCH;
1481                 remove(activator);
1482                 return;
1483         }
1484
1485         if(activator.classname != "player")
1486                 return;
1487         if(activator.deadflag != DEAD_NO)
1488                 return;
1489         EXACTTRIGGER_TOUCH;
1490
1491         entity e;
1492         for(e = world; (e = find(e, classname, "droppedweapon")); )
1493                 if(e.enemy == activator)
1494                         remove(e);
1495
1496         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1497                 centerprint(activator, self.message);
1498 }
1499
1500 void spawnfunc_target_items (void)
1501 {
1502         float n, i, j;
1503         entity e;
1504
1505         self.use = target_items_use;
1506         if(!self.strength_finished)
1507                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1508         if(!self.invincible_finished)
1509                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1510         if(!self.superweapons_finished)
1511                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1512
1513         precache_sound("misc/itempickup.wav");
1514         precache_sound("misc/megahealth.wav");
1515         precache_sound("misc/armor25.wav");
1516         precache_sound("misc/powerup.wav");
1517         precache_sound("misc/poweroff.wav");
1518         precache_sound("weapons/weaponpickup.wav");
1519
1520         n = tokenize_console(self.netname);
1521         if(argv(0) == "give")
1522         {
1523                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1524         }
1525         else
1526         {
1527                 for(i = 0; i < n; ++i)
1528                 {
1529                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1530                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1531                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1532                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1533                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1534                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1535                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1536                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1537                         else
1538                         {
1539                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1540                                 {
1541                                         e = get_weaponinfo(j);
1542                                         if(argv(i) == e.netname)
1543                                         {
1544                                                 WEPSET_OR_EW(self, j);
1545                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1546                                                         weapon_action(e.weapon, WR_PRECACHE);
1547                                                 break;
1548                                         }
1549                                 }
1550                                 if(j > WEP_LAST)
1551                                         print("target_items: invalid item ", argv(i), "\n");
1552                         }
1553                 }
1554
1555                 string itemprefix, valueprefix;
1556                 if(self.spawnflags == 0)
1557                 {
1558                         itemprefix = "";
1559                         valueprefix = "";
1560                 }
1561                 else if(self.spawnflags == 1)
1562                 {
1563                         itemprefix = "max ";
1564                         valueprefix = "max ";
1565                 }
1566                 else if(self.spawnflags == 2)
1567                 {
1568                         itemprefix = "min ";
1569                         valueprefix = "min ";
1570                 }
1571                 else if(self.spawnflags == 4)
1572                 {
1573                         itemprefix = "minus ";
1574                         valueprefix = "max ";
1575                 }
1576                 else
1577                         error("invalid spawnflags");
1578
1579                 self.netname = "";
1580                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1581                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1582                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1583                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1584                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1585                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1586                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1587                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1588                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1589                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1590                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1591                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1592                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1593                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1594                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1595                 {
1596                         e = get_weaponinfo(j);
1597                         if(e.weapon)
1598                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, WEPSET_CONTAINS_EW(self, j), e.netname);
1599                 }
1600         }
1601         self.netname = strzone(self.netname);
1602         //print(self.netname, "\n");
1603
1604         n = tokenize_console(self.netname);
1605         for(i = 0; i < n; ++i)
1606         {
1607                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1608                 {
1609                         e = get_weaponinfo(j);
1610                         if(argv(i) == e.netname)
1611                         {
1612                                 weapon_action(e.weapon, WR_PRECACHE);
1613                                 break;
1614                         }
1615                 }
1616         }
1617 }
1618
1619 void spawnfunc_item_fuel(void)
1620 {
1621         if(!self.ammo_fuel)
1622                 self.ammo_fuel = g_pickup_fuel;
1623         if(!self.pickup_anyway)
1624                 self.pickup_anyway = g_pickup_ammo_anyway;
1625         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1626 }
1627
1628 void spawnfunc_item_fuel_regen(void)
1629 {
1630         if(start_items & IT_FUEL_REGEN)
1631         {
1632                 spawnfunc_item_fuel();
1633                 return;
1634         }
1635         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1636 }
1637
1638 void spawnfunc_item_jetpack(void)
1639 {
1640         if(g_grappling_hook)
1641                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1642         if(!self.ammo_fuel)
1643                 self.ammo_fuel = g_pickup_fuel_jetpack;
1644         if(start_items & IT_JETPACK)
1645         {
1646                 spawnfunc_item_fuel();
1647                 return;
1648         }
1649         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1650 }
1651
1652
1653 #define OP_SET 0
1654 #define OP_MIN 1
1655 #define OP_MAX 2
1656 #define OP_PLUS 3
1657 #define OP_MINUS 4
1658
1659 float GiveWeapon(entity e, float wpn, float op, float val)
1660 {
1661         float v0, v1;
1662         v0 = WEPSET_CONTAINS_EW(e, wpn);
1663         switch(op)
1664         {
1665                 case OP_SET:
1666                         if(val > 0)
1667                                 WEPSET_OR_EW(e, wpn);
1668                         else
1669                                 WEPSET_ANDNOT_EW(e, wpn);
1670                         break;
1671                 case OP_MIN:
1672                 case OP_PLUS:
1673                         if(val > 0)
1674                                 WEPSET_OR_EW(e, wpn);
1675                         break;
1676                 case OP_MAX:
1677                         if(val <= 0)
1678                                 WEPSET_ANDNOT_EW(e, wpn);
1679                         break;
1680                 case OP_MINUS:
1681                         if(val > 0)
1682                                 WEPSET_ANDNOT_EW(e, wpn);
1683                         break;
1684         }
1685         v1 = WEPSET_CONTAINS_EW(e, wpn);
1686         return (v0 != v1);
1687 }
1688
1689 float GiveBit(entity e, .float fld, float bit, float op, float val)
1690 {
1691         float v0, v1;
1692         v0 = (e.fld & bit);
1693         switch(op)
1694         {
1695                 case OP_SET:
1696                         if(val > 0)
1697                                 e.fld |= bit;
1698                         else
1699                                 e.fld &~= bit;
1700                         break;
1701                 case OP_MIN:
1702                 case OP_PLUS:
1703                         if(val > 0)
1704                                 e.fld |= bit;
1705                         break;
1706                 case OP_MAX:
1707                         if(val <= 0)
1708                                 e.fld &~= bit;
1709                         break;
1710                 case OP_MINUS:
1711                         if(val > 0)
1712                                 e.fld &~= bit;
1713                         break;
1714         }
1715         v1 = (e.fld & bit);
1716         return (v0 != v1);
1717 }
1718
1719 float GiveValue(entity e, .float fld, float op, float val)
1720 {
1721         float v0, v1;
1722         v0 = e.fld;
1723         switch(op)
1724         {
1725                 case OP_SET:
1726                         e.fld = val;
1727                         break;
1728                 case OP_MIN:
1729                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1730                         break;
1731                 case OP_MAX:
1732                         e.fld = min(e.fld, val);
1733                         break;
1734                 case OP_PLUS:
1735                         e.fld += val;
1736                         break;
1737                 case OP_MINUS:
1738                         e.fld -= val;
1739                         break;
1740         }
1741         v1 = e.fld;
1742         return (v0 != v1);
1743 }
1744
1745 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1746 {
1747         if(v1 == v0)
1748                 return;
1749         if(v1 <= v0 - t)
1750         {
1751                 if(snd_decr != "")
1752                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1753         }
1754         else if(v0 >= v0 + t)
1755         {
1756                 if(snd_incr != "")
1757                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1758         }
1759 }
1760
1761 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1762 {
1763         if(v0 < v1)
1764                 e.rotfield = max(e.rotfield, time + rottime);
1765         else if(v0 > v1)
1766                 e.regenfield = max(e.regenfield, time + regentime);
1767 }
1768
1769 #define PREGIVE_WEAPONS(e) WEPSET_DECLARE_A(save_weapons); WEPSET_COPY_AE(save_weapons, e)
1770 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1771 #define POSTGIVE_WEAPON(e,b,snd_incr,snd_decr) GiveSound((e), WEPSET_CONTAINS_AW(save_weapons, b), WEPSET_CONTAINS_EW(e, b), 0, snd_incr, snd_decr)
1772 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1773 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1774 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1775
1776 float GiveItems(entity e, float beginarg, float endarg)
1777 {
1778         float got, i, j, val, op;
1779         float _switchweapon;
1780         entity wi;
1781         string cmd;
1782
1783         val = 999;
1784         op = OP_SET;
1785
1786         got = 0;
1787
1788         _switchweapon = FALSE;
1789         if (e.autoswitch)
1790                 if (e.switchweapon == w_getbestweapon(e))
1791                         _switchweapon = TRUE;
1792
1793         e.strength_finished = max(0, e.strength_finished - time);
1794         e.invincible_finished = max(0, e.invincible_finished - time);
1795         e.superweapons_finished = max(0, e.superweapons_finished - time);
1796
1797         PREGIVE(e, items);
1798         PREGIVE_WEAPONS(e);
1799         PREGIVE(e, strength_finished);
1800         PREGIVE(e, invincible_finished);
1801         PREGIVE(e, superweapons_finished);
1802         PREGIVE(e, ammo_nails);
1803         PREGIVE(e, ammo_cells);
1804         PREGIVE(e, ammo_shells);
1805         PREGIVE(e, ammo_rockets);
1806         PREGIVE(e, ammo_fuel);
1807         PREGIVE(e, armorvalue);
1808         PREGIVE(e, health);
1809
1810         for(i = beginarg; i < endarg; ++i)
1811         {
1812                 cmd = argv(i);
1813
1814                 if(cmd == "0" || stof(cmd))
1815                 {
1816                         val = stof(cmd);
1817                         continue;
1818                 }
1819                 switch(cmd)
1820                 {
1821                         case "no":
1822                                 op = OP_MAX;
1823                                 val = 0;
1824                                 continue;
1825                         case "max":
1826                                 op = OP_MAX;
1827                                 continue;
1828                         case "min":
1829                                 op = OP_MIN;
1830                                 continue;
1831                         case "plus":
1832                                 op = OP_PLUS;
1833                                 continue;
1834                         case "minus":
1835                                 op = OP_MINUS;
1836                                 continue;
1837                         case "ALL":
1838                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1839                                 got += GiveValue(e, strength_finished, op, val);
1840                                 got += GiveValue(e, invincible_finished, op, val);
1841                                 got += GiveValue(e, superweapons_finished, op, val);
1842                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1843                         case "all":
1844                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1845                                 got += GiveValue(e, health, op, val);
1846                                 got += GiveValue(e, armorvalue, op, val);
1847                         case "allweapons":
1848                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1849                                 {
1850                                         wi = get_weaponinfo(j);
1851                                         if(wi.weapon)
1852                                                 if not(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1853                                                         got += GiveWeapon(e, j, op, val);
1854                                 }
1855                         case "allammo":
1856                                 got += GiveValue(e, ammo_cells, op, val);
1857                                 got += GiveValue(e, ammo_shells, op, val);
1858                                 got += GiveValue(e, ammo_nails, op, val);
1859                                 got += GiveValue(e, ammo_rockets, op, val);
1860                                 got += GiveValue(e, ammo_fuel, op, val);
1861                                 break;
1862                         case "unlimited_ammo":
1863                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1864                                 break;
1865                         case "unlimited_weapon_ammo":
1866                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1867                                 break;
1868                         case "unlimited_superweapons":
1869                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1870                                 break;
1871                         case "jetpack":
1872                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1873                                 break;
1874                         case "fuel_regen":
1875                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1876                                 break;
1877                         case "strength":
1878                                 got += GiveValue(e, strength_finished, op, val);
1879                                 break;
1880                         case "invincible":
1881                                 got += GiveValue(e, invincible_finished, op, val);
1882                                 break;
1883                         case "superweapons":
1884                                 got += GiveValue(e, superweapons_finished, op, val);
1885                                 break;
1886                         case "cells":
1887                                 got += GiveValue(e, ammo_cells, op, val);
1888                                 break;
1889                         case "shells":
1890                                 got += GiveValue(e, ammo_shells, op, val);
1891                                 break;
1892                         case "nails":
1893                         case "bullets":
1894                                 got += GiveValue(e, ammo_nails, op, val);
1895                                 break;
1896                         case "rockets":
1897                                 got += GiveValue(e, ammo_rockets, op, val);
1898                                 break;
1899                         case "health":
1900                                 got += GiveValue(e, health, op, val);
1901                                 break;
1902                         case "armor":
1903                                 got += GiveValue(e, armorvalue, op, val);
1904                                 break;
1905                         case "fuel":
1906                                 got += GiveValue(e, ammo_fuel, op, val);
1907                                 break;
1908                         default:
1909                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1910                                 {
1911                                         wi = get_weaponinfo(j);
1912                                         if(cmd == wi.netname)
1913                                         {
1914                                                 got += GiveWeapon(e, j, op, val);
1915                                                 break;
1916                                         }
1917                                 }
1918                                 if(j > WEP_LAST)
1919                                         print("give: invalid item ", cmd, "\n");
1920                                 break;
1921                 }
1922                 val = 999;
1923                 op = OP_SET;
1924         }
1925
1926         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1927         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1928         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1929         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1930         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1931         {
1932                 wi = get_weaponinfo(j);
1933                 if(wi.weapon)
1934                 {
1935                         POSTGIVE_WEAPON(e, j, "weapons/weaponpickup.wav", string_null);
1936                         if not(WEPSET_CONTAINS_AW(save_weapons, j))
1937                                 if(WEPSET_CONTAINS_EW(e, j))
1938                                         weapon_action(wi.weapon, WR_PRECACHE);
1939                 }
1940         }
1941         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1942         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1943         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1944         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1945         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1946         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1947         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1948         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1949         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1950
1951         if(e.superweapons_finished <= 0)
1952                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1953                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1954
1955         if(e.strength_finished <= 0)
1956                 e.strength_finished = 0;
1957         else
1958                 e.strength_finished += time;
1959         if(e.invincible_finished <= 0)
1960                 e.invincible_finished = 0;
1961         else
1962                 e.invincible_finished += time;
1963         if(e.superweapons_finished <= 0)
1964                 e.superweapons_finished = 0;
1965         else
1966                 e.superweapons_finished += time;
1967
1968         if not(WEPSET_CONTAINS_EW(e, e.switchweapon))
1969                 _switchweapon = TRUE;
1970         if(_switchweapon)
1971                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1972
1973         return got;
1974 }
1975 #endif