qcsrc/server/t_items.qc

   1 float have_pickup_item(void)
   2 {
   3         // minstagib: only allow filtered items
   4         if(g_minstagib)
   5                 if(self.classname != "minstagib")
   6                         return FALSE;
   7
   8         if(self.flags & FL_POWERUP)
   9         {
  10                 if(autocvar_g_powerups > 0)
  11                         return TRUE;
  12                 if(autocvar_g_powerups == 0)
  13                         return FALSE;
  14                 if(g_lms)
  15                         return FALSE;
  16                 if(g_ca)
  17                         return FALSE;
  18                 if(g_arena)
  19                         return FALSE;
  20         }
  21         else
  22         {
  23                 if(autocvar_g_pickup_items > 0)
  24                         return TRUE;
  25                 if(autocvar_g_pickup_items == 0)
  26                         return FALSE;
  27                 if(g_lms)
  28                         return FALSE;
  29                 if(g_ca)
  30                         return FALSE;
  31                 if(g_weaponarena)
  32                         if(!WEPSET_EMPTY_E(self) || (self.items & IT_AMMO))
  33                                 return FALSE;
  34         }
  35         return TRUE;
  36 }
  37
  38 #define ITEM_RESPAWN_TICKS 10
  39
  40 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
  41         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
  42 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
  43         // range: 10 .. respawntime + respawntimejitter
  44
  45 floatfield Item_CounterField(float it)
  46 {
  47         switch(it)
  48         {
  49                 case IT_SHELLS:      return ammo_shells;
  50                 case IT_NAILS:       return ammo_nails;
  51                 case IT_ROCKETS:     return ammo_rockets;
  52                 case IT_CELLS:       return ammo_cells;
  53                 case IT_FUEL:        return ammo_fuel;
  54                 case IT_5HP:         return health;
  55                 case IT_25HP:        return health;
  56                 case IT_HEALTH:      return health;
  57                 case IT_ARMOR_SHARD: return armorvalue;
  58                 case IT_ARMOR:       return armorvalue;
  59                 // add more things here (health, armor)
  60                 default:             error("requested item has no counter field");
  61         }
  62 }
  63
  64 string Item_CounterFieldName(float it)
  65 {
  66         switch(it)
  67         {
  68                 case IT_SHELLS:      return "shells";
  69                 case IT_NAILS:       return "nails";
  70                 case IT_ROCKETS:     return "rockets";
  71                 case IT_CELLS:       return "cells";
  72                 case IT_FUEL:        return "fuel";
  73
  74                 // add more things here (health, armor)
  75                 default:             error("requested item has no counter field name");
  76         }
  77 }
  78
  79 .float max_armorvalue;
  80 .float pickup_anyway;
  81
  82 float Item_Customize()
  83 {
  84         if(self.spawnshieldtime)
  85                 return TRUE;
  86         if(!WEPSET_CONTAINS_ALL_EE(other, self))
  87         {
  88                 self.colormod = '0 0 0';
  89                 self.glowmod = self.colormod;
  90                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  91                 return TRUE;
  92         }
  93         else
  94         {
  95                 if(g_ghost_items)
  96                 {
  97                         self.colormod = stov(autocvar_g_ghost_items_color);
  98                         self.glowmod = self.colormod;
  99                         self.alpha = g_ghost_items;
 100                         return TRUE;
 101                 }
 102                 else
 103                         return FALSE;
 104         }
 105 }
 106
 107 void Item_Show (entity e, float mode)
 108 {
 109         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 110         if (mode > 0)
 111         {
 112                 // make the item look normal, and be touchable
 113                 e.model = e.mdl;
 114                 e.solid = SOLID_TRIGGER;
 115                 e.colormod = '0 0 0';
 116                 self.glowmod = self.colormod;
 117                 e.alpha = 0;
 118                 e.customizeentityforclient = func_null;
 119
 120                 e.spawnshieldtime = 1;
 121         }
 122         else if (mode < 0)
 123         {
 124                 // hide the item completely
 125                 e.model = string_null;
 126                 e.solid = SOLID_NOT;
 127                 e.colormod = '0 0 0';
 128                 self.glowmod = self.colormod;
 129                 e.alpha = 0;
 130                 e.customizeentityforclient = func_null;
 131
 132                 e.spawnshieldtime = 1;
 133         }
 134         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 135         {
 136                 // make the item translucent and not touchable
 137                 e.model = e.mdl;
 138                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 139                 e.colormod = '0 0 0';
 140                 self.glowmod = self.colormod;
 141                 e.effects |= EF_STARDUST;
 142                 e.customizeentityforclient = Item_Customize;
 143
 144                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 145         }
 146         else if(g_ghost_items)
 147         {
 148                 // make the item translucent and not touchable
 149                 e.model = e.mdl;
 150                 e.solid = SOLID_NOT;
 151                 e.colormod = stov(autocvar_g_ghost_items_color);
 152                 e.glowmod = e.colormod;
 153                 e.alpha = g_ghost_items;
 154                 e.customizeentityforclient = func_null;
 155
 156                 e.spawnshieldtime = 1;
 157         }
 158         else
 159         {
 160                 // hide the item completely
 161                 e.model = string_null;
 162                 e.solid = SOLID_NOT;
 163                 e.colormod = '0 0 0';
 164                 e.glowmod = e.colormod;
 165                 e.alpha = 0;
 166                 e.customizeentityforclient = func_null;
 167
 168                 e.spawnshieldtime = 1;
 169         }
 170
 171         if (e.items & (IT_STRENGTH | IT_INVINCIBLE))
 172                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 173         if (autocvar_g_nodepthtestitems)
 174                 e.effects |= EF_NODEPTHTEST;
 175         if (autocvar_g_fullbrightitems)
 176                 e.effects |= EF_FULLBRIGHT;
 177
 178         // relink entity (because solid may have changed)
 179         setorigin(e, e.origin);
 180 }
 181
 182 void Item_Respawn (void)
 183 {
 184         Item_Show(self, 1);
 185         if(!g_minstagib && self.items == IT_STRENGTH)
 186                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 187         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 188                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 189         else
 190                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 191         setorigin (self, self.origin);
 192
 193         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 194         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 195 }
 196
 197 void Item_RespawnCountdown (void)
 198 {
 199         if(self.count >= ITEM_RESPAWN_TICKS)
 200         {
 201                 if(self.waypointsprite_attached)
 202                         WaypointSprite_Kill(self.waypointsprite_attached);
 203                 Item_Respawn();
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 self.count += 1;
 209                 if(self.count == 1)
 210                 {
 211                         string name;
 212                         vector rgb;
 213                         name = string_null;
 214                         if(g_minstagib)
 215                         {
 216                                 switch(self.items)
 217                                 {
 218                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 219                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 220                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 221                                 }
 222                         }
 223                         else
 224                         {
 225                                 switch(self.items)
 226                                 {
 227                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 228                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 229                                 }
 230                         }
 231                         switch(self.items)
 232                         {
 233                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 234                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 235                         }
 236                         if(self.flags & FL_WEAPON)
 237                         {
 238                                 entity wi = get_weaponinfo(self.weapon);
 239                                 if(wi)
 240                                 {
 241                                         name = wi.model2;
 242                                         rgb = '1 0 0';
 243                                 }
 244                         }
 245                         if(!name)
 246                         {
 247                                 print("Unknown powerup-marked item is wanting to respawn\n");
 248                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 249                         }
 250                         if(name)
 251                         {
 252                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 253                                 if(self.waypointsprite_attached)
 254                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 255                         }
 256                 }
 257                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 258                 if(self.waypointsprite_attached)
 259                 {
 260                         WaypointSprite_Ping(self.waypointsprite_attached);
 261                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 262                 }
 263         }
 264 }
 265
 266 void Item_ScheduleRespawnIn(entity e, float t)
 267 {
 268         if((e.flags & FL_POWERUP) || WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
 269         {
 270                 e.think = Item_RespawnCountdown;
 271                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 272                 e.count = 0;
 273         }
 274         else
 275         {
 276                 e.think = Item_Respawn;
 277                 e.nextthink = time + t;
 278         }
 279 }
 280
 281 void Item_ScheduleRespawn(entity e)
 282 {
 283         if(e.respawntime > 0)
 284         {
 285                 Item_Show(e, 0);
 286                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 287         }
 288         else // if respawntime is -1, this item does not respawn
 289                 Item_Show(e, -1);
 290 }
 291
 292 void Item_ScheduleInitialRespawn(entity e)
 293 {
 294         Item_Show(e, 0);
 295         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 296 }
 297
 298 float ITEM_MODE_NONE = 0;
 299 float ITEM_MODE_HEALTH = 1;
 300 float ITEM_MODE_ARMOR = 2;
 301 float ITEM_MODE_FUEL = 3;
 302 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
 303 {
 304         if (!item.ammofield)
 305                 return FALSE;
 306
 307         if (item.spawnshieldtime)
 308         {
 309                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 310                 {
 311                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
 312                         goto YEAH;
 313                 }
 314         }
 315         else if(g_weapon_stay == 2)
 316         {
 317                 float mi = min(item.ammofield, ammomax);
 318                 if (player.ammofield < mi)
 319                 {
 320                         player.ammofield = mi;
 321                         goto YEAH;
 322                 }
 323         }
 324
 325         return FALSE;
 326
 327 :YEAH
 328         switch(mode)
 329         {
 330                 case ITEM_MODE_FUEL:
 331                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 332                         break;
 333                 case ITEM_MODE_HEALTH:
 334                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 335                         break;
 336                 case ITEM_MODE_ARMOR:
 337                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 338                         break;
 339                 default:
 340                         break;
 341         }
 342         return TRUE;
 343 }
 344
 345 float Item_GiveTo(entity item, entity player)
 346 {
 347         float _switchweapon;
 348         float pickedup;
 349         float it;
 350         float i;
 351
 352         // if nothing happens to player, just return without taking the item
 353         pickedup = FALSE;
 354         _switchweapon = FALSE;
 355
 356         if (g_minstagib)
 357         {
 358                 float prevcells = player.ammo_cells;
 359
 360                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 361                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, 999, ITEM_MODE_NONE);
 362
 363                 if(player.ammo_cells > prevcells)
 364                 {
 365                         _switchweapon = TRUE;
 366
 367                         // play some cool sounds ;)
 368                         if (clienttype(player) == CLIENTTYPE_REAL)
 369                         {
 370                                 if(player.health <= 5)
 371                                         AnnounceTo(player, "lastsecond");
 372                                 else if(player.health < 50)
 373                                         AnnounceTo(player, "narrowly");
 374                         }
 375                         // sound not available
 376                         // else if(item.items == IT_CELLS)
 377                         //      AnnounceTo(player, "ammo");
 378
 379                         if (WEPSET_CONTAINS_EW(item, WEP_MINSTANEX))
 380                                 W_GiveWeapon (player, WEP_MINSTANEX, item.netname);
 381                         player.health = 100;
 382                 }
 383
 384                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 385                 {
 386                         pickedup = TRUE;
 387                         player.items |= it;
 388                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 389                 }
 390
 391                 // extralife powerup
 392                 if (item.max_health)
 393                 {
 394                         pickedup = TRUE;
 395                         // sound not available
 396                         // AnnounceTo(player, "_lives");
 397                         player.armorvalue = bound(player.armorvalue, 999, player.armorvalue + autocvar_g_minstagib_extralives);
 398                         sprint(player, "^3You picked up some extra lives\n");
 399                 }
 400
 401                 // invis powerup
 402                 if (item.strength_finished)
 403                 {
 404                         pickedup = TRUE;
 405                         // sound not available
 406                         // AnnounceTo(player, "invisible");
 407                         player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 408                 }
 409
 410                 // speed powerup
 411                 if (item.invincible_finished)
 412                 {
 413                         pickedup = TRUE;
 414                         // sound not available
 415                         // AnnounceTo(player, "speed");
 416                         player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_strength_time;
 417                 }
 418         }
 419         else
 420         {
 421                 // in case the player has autoswitch enabled do the following:
 422                 // if the player is using their best weapon before items are given, they
 423                 // probably want to switch to an even better weapon after items are given
 424                 if (player.autoswitch)
 425                 if (player.switchweapon == w_getbestweapon(player))
 426                         _switchweapon = TRUE;
 427
 428                 if not(WEPSET_CONTAINS_EW(player, player.switchweapon))
 429                         _switchweapon = TRUE;
 430
 431                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 432                 pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 433                 pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 434                 pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 435                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 436                 pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 437                 pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 438
 439                 if (item.flags & FL_WEAPON)
 440                 {
 441                         WEPSET_DECLARE_A(it);
 442                         WEPSET_COPY_AE(it, item);
 443                         WEPSET_ANDNOT_AE(it, player);
 444
 445                         if (!WEPSET_EMPTY_A(it) || (item.spawnshieldtime && self.pickup_anyway))
 446                         {
 447                                 pickedup = TRUE;
 448                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 449                                         if(WEPSET_CONTAINS_AW(it, i))
 450                                                 W_GiveWeapon (player, i, item.netname);
 451                         }
 452                 }
 453
 454                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 455                 {
 456                         pickedup = TRUE;
 457                         player.items |= it;
 458                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 459                 }
 460
 461                 if (item.strength_finished)
 462                 {
 463                         pickedup = TRUE;
 464                         player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 465                 }
 466                 if (item.invincible_finished)
 467                 {
 468                         pickedup = TRUE;
 469                         player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 470                 }
 471                 if (item.superweapons_finished)
 472                 {
 473                         pickedup = TRUE;
 474                         player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 475                 }
 476         }
 477
 478 :skip
 479         // always eat teamed entities
 480         if(item.team)
 481                 pickedup = TRUE;
 482
 483         if (!pickedup)
 484                 return 0;
 485
 486         if (_switchweapon)
 487                 if (player.switchweapon != w_getbestweapon(player))
 488                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 489
 490         return 1;
 491 }
 492
 493 void Item_Touch (void)
 494 {
 495         entity e, head;
 496
 497         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 498         if(self.classname == "droppedweapon")
 499         {
 500                 if (ITEM_TOUCH_NEEDKILL())
 501                 {
 502                         remove(self);
 503                         return;
 504                 }
 505         }
 506
 507         if (other.classname != "player")
 508                 return;
 509         if (other.deadflag)
 510                 return;
 511         if (self.solid != SOLID_TRIGGER)
 512                 return;
 513         if (self.owner == other)
 514                 return;
 515
 516         if (self.classname == "droppedweapon")
 517         {
 518                 self.strength_finished = max(0, self.strength_finished - time);
 519                 self.invincible_finished = max(0, self.invincible_finished - time);
 520                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 521         }
 522
 523         if(!Item_GiveTo(self, other))
 524         {
 525                 if (self.classname == "droppedweapon")
 526                 {
 527                         // undo what we did above
 528                         self.strength_finished += time;
 529                         self.invincible_finished += time;
 530                         self.superweapons_finished += time;
 531                 }
 532                 return;
 533         }
 534
 535         other.last_pickup = time;
 536
 537         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 538         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTN_NORM);
 539
 540         if (self.classname == "droppedweapon")
 541                 remove (self);
 542         else if not(self.spawnshieldtime)
 543                 return;
 544         else
 545         {
 546                 if(self.team)
 547                 {
 548                         RandomSelection_Init();
 549                         for(head = world; (head = findfloat(head, team, self.team)); )
 550                         {
 551                                 if(head.flags & FL_ITEM)
 552                                 {
 553                                         Item_Show(head, -1);
 554                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 555                                 }
 556                         }
 557                         e = RandomSelection_chosen_ent;
 558                 }
 559                 else
 560                         e = self;
 561                 Item_ScheduleRespawn(e);
 562         }
 563 }
 564
 565 void Item_Reset()
 566 {
 567         Item_Show(self, !self.state);
 568         setorigin (self, self.origin);
 569
 570         if(self.classname != "droppedweapon")
 571         {
 572                 self.think = SUB_Null;
 573                 self.nextthink = 0;
 574
 575                 if(self.waypointsprite_attached)
 576                         WaypointSprite_Kill(self.waypointsprite_attached);
 577
 578                 if((self.flags & FL_POWERUP) | WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // do not spawn powerups initially!
 579                         Item_ScheduleInitialRespawn(self);
 580         }
 581 }
 582
 583 void Item_FindTeam()
 584 {
 585         entity head, e;
 586
 587         if(self.effects & EF_NODRAW)
 588         {
 589                 // marker for item team search
 590                 dprint("Initializing item team ", ftos(self.team), "\n");
 591                 RandomSelection_Init();
 592                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 593                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 594                 e = RandomSelection_chosen_ent;
 595                 e.state = 0;
 596                 Item_Show(e, 1);
 597
 598                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 599                 {
 600                         if(head != e)
 601                         {
 602                                 // make it a non-spawned item
 603                                 Item_Show(head, -1);
 604                                 head.state = 1; // state 1 = initially hidden item
 605                         }
 606                         head.effects &~= EF_NODRAW;
 607                 }
 608
 609                 Item_Reset();
 610         }
 611 }
 612
 613 // Savage: used for item garbage-collection
 614 // TODO: perhaps nice special effect?
 615 void RemoveItem(void)
 616 {
 617         remove(self);
 618 }
 619
 620 // pickup evaluation functions
 621 // these functions decide how desirable an item is to the bots
 622
 623 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 624
 625 float weapon_pickupevalfunc(entity player, entity item)
 626 {
 627         float c, j, position;
 628
 629         // See if I have it already
 630         if(!WEPSET_CONTAINS_ALL_EE(player, item))
 631         {
 632                 // If I can pick it up
 633                 if(!item.spawnshieldtime)
 634                         c = 0;
 635                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 636                 {
 637                         // Skilled bots will grab more
 638                         c = bound(0, skill / 10, 1) * 0.5;
 639                 }
 640                 else
 641                         c = 0;
 642         }
 643         else
 644                 c = 1;
 645
 646         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 647         if( bot_custom_weapon && c )
 648         {
 649                 // Find the highest position on any range
 650                 position = -1;
 651                 for(j = 0; j < WEP_LAST ; ++j){
 652                         if(
 653                                         bot_weapons_far[j] == item.weapon ||
 654                                         bot_weapons_mid[j] == item.weapon ||
 655                                         bot_weapons_close[j] == item.weapon
 656                           )
 657                         {
 658                                 position = j;
 659                                 break;
 660                         }
 661                 }
 662
 663                 // Rate it
 664                 if (position >= 0 )
 665                 {
 666                         position = WEP_LAST - position;
 667                         // item.bot_pickupbasevalue is overwritten here
 668                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 669                 }
 670         }
 671
 672         return item.bot_pickupbasevalue * c;
 673 }
 674
 675 float commodity_pickupevalfunc(entity player, entity item)
 676 {
 677         float c, i, need_shells, need_nails, need_rockets, need_cells, need_fuel;
 678         entity wi;
 679         c = 0;
 680
 681         // Detect needed ammo
 682         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 683         {
 684                 wi = get_weaponinfo(i);
 685
 686                 if not(WEPSET_CONTAINS_EW(player, i))
 687                         continue;
 688
 689                 if(wi.items & IT_SHELLS)
 690                         need_shells = TRUE;
 691                 else if(wi.items & IT_NAILS)
 692                         need_nails = TRUE;
 693                 else if(wi.items & IT_ROCKETS)
 694                         need_rockets = TRUE;
 695                 else if(wi.items & IT_CELLS)
 696                         need_cells = TRUE;
 697                 else if(wi.items & IT_FUEL)
 698                         need_cells = TRUE;
 699         }
 700
 701         // TODO: figure out if the player even has the weapon this ammo is for?
 702         // may not affect strategy much though...
 703         // find out how much more ammo/armor/health the player can hold
 704         if (need_shells)
 705         if (item.ammo_shells)
 706         if (player.ammo_shells < g_pickup_shells_max)
 707                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 708         if (need_nails)
 709         if (item.ammo_nails)
 710         if (player.ammo_nails < g_pickup_nails_max)
 711                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 712         if (need_rockets)
 713         if (item.ammo_rockets)
 714         if (player.ammo_rockets < g_pickup_rockets_max)
 715                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 716         if (need_cells)
 717         if (item.ammo_cells)
 718         if (player.ammo_cells < g_pickup_cells_max)
 719                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 720         if (need_fuel)
 721         if (item.ammo_fuel)
 722         if (player.ammo_fuel < g_pickup_fuel_max)
 723                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 724         if (item.armorvalue)
 725         if (player.armorvalue < item.max_armorvalue)
 726                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 727         if (item.health)
 728         if (player.health < item.max_health)
 729                 c = c + max(0, 1 - player.health / item.max_health);
 730
 731         return item.bot_pickupbasevalue * c;
 732 }
 733
 734 void Item_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 735 {
 736         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 737                 RemoveItem();
 738 }
 739
 740 .float is_item;
 741 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 742 {
 743         startitem_failed = FALSE;
 744
 745         if(self.model == "")
 746                 self.model = itemmodel;
 747         if(self.item_pickupsound == "")
 748                 self.item_pickupsound = pickupsound;
 749         if(!self.respawntime) // both need to be set
 750         {
 751                 self.respawntime = defaultrespawntime;
 752                 self.respawntimejitter = defaultrespawntimejitter;
 753         }
 754
 755         self.items = itemid;
 756         self.weapon = weaponid;
 757
 758         if(weaponid)
 759                 WEPSET_COPY_EW(self, weaponid);
 760         self.flags = FL_ITEM | itemflags;
 761
 762         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 763         {
 764                 startitem_failed = TRUE;
 765                 remove(self);
 766                 return;
 767         }
 768
 769         // is it a dropped weapon?
 770         if (self.classname == "droppedweapon")
 771         {
 772                 self.reset = SUB_Remove;
 773                 // it's a dropped weapon
 774                 self.movetype = MOVETYPE_TOSS;
 775
 776                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 777                 self.think = RemoveItem;
 778                 self.nextthink = time + 20;
 779
 780                 self.takedamage = DAMAGE_YES;
 781                 self.event_damage = Item_Damage;
 782
 783                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
 784                 /*
 785                 if(self.items == 0)
 786                 if(WEPSET_CONTAINS_ALL_AE(WEPBIT_SUPERWEAPONS, self)) // only superweapons
 787                 if(self.ammo_nails == 0)
 788                 if(self.ammo_cells == 0)
 789                 if(self.ammo_rockets == 0)
 790                 if(self.ammo_shells == 0)
 791                 if(self.ammo_fuel == 0)
 792                 if(self.health == 0)
 793                 if(self.armorvalue == 0)
 794                 */
 795                 {
 796                         // if item is worthless after a timer, have it expire then
 797                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
 798                 }
 799
 800                 // don't drop if in a NODROP zone (such as lava)
 801                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 802                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 803                 {
 804                         startitem_failed = TRUE;
 805                         remove(self);
 806                         return;
 807                 }
 808         }
 809         else
 810         {
 811                 if(!have_pickup_item())
 812                 {
 813                         startitem_failed = TRUE;
 814                         remove (self);
 815                         return;
 816                 }
 817
 818                 self.reset = Item_Reset;
 819                 // it's a level item
 820                 if(self.spawnflags & 1)
 821                         self.noalign = 1;
 822                 if (self.noalign)
 823                         self.movetype = MOVETYPE_NONE;
 824                 else
 825                         self.movetype = MOVETYPE_TOSS;
 826                 // do item filtering according to game mode and other things
 827                 if (!self.noalign)
 828                 {
 829                         // first nudge it off the floor a little bit to avoid math errors
 830                         setorigin(self, self.origin + '0 0 1');
 831                         // set item size before we spawn a spawnfunc_waypoint
 832                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 833                                 setsize (self, '-16 -16 0', '16 16 48');
 834                         else
 835                                 setsize (self, '-16 -16 0', '16 16 32');
 836                         // note droptofloor returns FALSE if stuck/or would fall too far
 837                         droptofloor();
 838                         waypoint_spawnforitem(self);
 839                 }
 840
 841                 /*
 842                  * can't do it that way, as it would break maps
 843                  * TODO make a target_give like entity another way, that perhaps has
 844                  * the weapon name in a key
 845                 if(self.targetname)
 846                 {
 847                         // target_give not yet supported; maybe later
 848                         print("removed targeted ", self.classname, "\n");
 849                         startitem_failed = TRUE;
 850                         remove (self);
 851                         return;
 852                 }
 853                 */
 854
 855                 if(autocvar_spawn_debug >= 2)
 856                 {
 857                         entity otheritem;
 858                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 859                         {
 860                                 if(otheritem.is_item)
 861                                 {
 862                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 863                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 864                                         error("Mapper sucks.");
 865                                 }
 866                         }
 867                         self.is_item = TRUE;
 868                 }
 869
 870                 WEPSET_OR_AW(weaponsInMap, weaponid);
 871
 872                 precache_model (self.model);
 873                 precache_sound (self.item_pickupsound);
 874
 875                 precache_sound ("misc/itemrespawncountdown.wav");
 876                 if(!g_minstagib && itemid == IT_STRENGTH)
 877                         precache_sound ("misc/strength_respawn.wav");
 878                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
 879                         precache_sound ("misc/shield_respawn.wav");
 880                 else
 881                         precache_sound ("misc/itemrespawn.wav");
 882
 883                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
 884                         self.target = "###item###"; // for finding the nearest item using find()
 885         }
 886
 887         self.bot_pickup = TRUE;
 888         self.bot_pickupevalfunc = pickupevalfunc;
 889         self.bot_pickupbasevalue = pickupbasevalue;
 890         self.mdl = self.model;
 891         self.netname = itemname;
 892         self.touch = Item_Touch;
 893         setmodel (self, self.mdl); // precision set below
 894         self.effects |= EF_LOWPRECISION;
 895         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 896                 setsize (self, '-16 -16 0', '16 16 48');
 897         else
 898                 setsize (self, '-16 -16 0', '16 16 32');
 899         if(itemflags & FL_WEAPON)
 900                 self.modelflags |= MF_ROTATE;
 901
 902         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 903         if (itemflags & FL_WEAPON)
 904         {
 905                 // neutral team color for pickup weapons
 906                 self.colormap = 1024; // color shirt=0 pants=0 grey
 907         }
 908
 909         self.state = 0;
 910         if(self.team)
 911         {
 912                 if(!self.cnt)
 913                         self.cnt = 1; // item probability weight
 914                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 915                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 916         }
 917         else
 918                 Item_Reset();
 919 }
 920
 921 /* replace items in minstagib
 922  * IT_STRENGTH   = invisibility
 923  * IT_NAILS      = extra lives
 924  * IT_INVINCIBLE = speed
 925  */
 926 void minstagib_items (float itemid)
 927 {
 928         float rnd;
 929         self.classname = "minstagib";
 930
 931         // replace rocket launchers and nex guns with ammo cells
 932         if (itemid == IT_CELLS)
 933         {
 934                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
 935                 StartItem ("models/items/a_cells.md3",
 936                         "misc/itempickup.wav", 45, 0,
 937                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 938                 return;
 939         }
 940
 941         // randomize
 942         rnd = random() * 3;
 943         if (rnd <= 1)
 944                 itemid = IT_STRENGTH;
 945         else if (rnd <= 2)
 946                 itemid = IT_NAILS;
 947         else
 948                 itemid = IT_INVINCIBLE;
 949
 950         // replace with invis
 951         if (itemid == IT_STRENGTH)
 952         {
 953                 if(!self.strength_finished)
 954                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
 955                 StartItem ("models/items/g_strength.md3",
 956                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 957                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 958         }
 959         // replace with extra lives
 960         if (itemid == IT_NAILS)
 961         {
 962                 self.max_health = 1;
 963                 StartItem ("models/items/g_h100.md3",
 964                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 965                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 966         }
 967         // replace with speed
 968         if (itemid == IT_INVINCIBLE)
 969         {
 970                 if(!self.invincible_finished)
 971                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
 972                 StartItem ("models/items/g_invincible.md3",
 973                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 974                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 975         }
 976 }
 977
 978 float minst_no_auto_cells;
 979 void minst_remove_item (void) {
 980         if(minst_no_auto_cells)
 981                 remove(self);
 982 }
 983
 984 float weaponswapping;
 985 float internalteam;
 986
 987 void weapon_defaultspawnfunc(float wpn)
 988 {
 989         entity e;
 990         float t;
 991         var .float ammofield;
 992         string s;
 993         entity oldself;
 994         float i, j;
 995         float f;
 996
 997         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 998         {
 999                 e = get_weaponinfo(wpn);
1000
1001                 if(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1002                 {
1003                         objerror("Attempted to spawn a mutator-blocked weapon rejected");
1004                         startitem_failed = TRUE;
1005                         return;
1006                 }
1007
1008                 s = W_Apply_Weaponreplace(e.netname);
1009                 ret_string = s;
1010                 other = e;
1011                 MUTATOR_CALLHOOK(SetWeaponreplace);
1012                 s = ret_string;
1013                 if(s == "")
1014                 {
1015                         remove(self);
1016                         startitem_failed = TRUE;
1017                         return;
1018                 }
1019                 t = tokenize_console(s);
1020                 if(t >= 2)
1021                 {
1022                         self.team = --internalteam;
1023                         oldself = self;
1024                         for(i = 1; i < t; ++i)
1025                         {
1026                                 s = argv(i);
1027                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1028                                 {
1029                                         e = get_weaponinfo(j);
1030                                         if(e.netname == s)
1031                                         {
1032                                                 self = spawn();
1033                                                 copyentity(oldself, self);
1034                                                 self.classname = "replacedweapon";
1035                                                 weapon_defaultspawnfunc(j);
1036                                                 break;
1037                                         }
1038                                 }
1039                                 if(j > WEP_LAST)
1040                                 {
1041                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1042                                 }
1043                         }
1044                         self = oldself;
1045                 }
1046                 if(t >= 1) // always the case!
1047                 {
1048                         s = argv(0);
1049                         wpn = 0;
1050                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1051                         {
1052                                 e = get_weaponinfo(j);
1053                                 if(e.netname == s)
1054                                 {
1055                                         wpn = j;
1056                                         break;
1057                                 }
1058                         }
1059                         if(j > WEP_LAST)
1060                         {
1061                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1062                         }
1063                 }
1064                 if(wpn == 0)
1065                 {
1066                         remove(self);
1067                         startitem_failed = TRUE;
1068                         return;
1069                 }
1070         }
1071
1072         e = get_weaponinfo(wpn);
1073
1074         if(!self.respawntime)
1075         {
1076                 if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1077                 {
1078                         self.respawntime = g_pickup_respawntime_superweapon;
1079                         self.respawntimejitter = g_pickup_respawntimejitter_superweapon;
1080                 }
1081                 else
1082                 {
1083                         self.respawntime = g_pickup_respawntime_weapon;
1084                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1085                 }
1086         }
1087
1088         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1089                 if(!self.superweapons_finished)
1090                         self.superweapons_finished = autocvar_g_balance_superweapons_time;
1091
1092         if(e.items)
1093         {
1094                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1095                 {
1096                         if(e.items & j)
1097                         {
1098                                 ammofield = Item_CounterField(j);
1099                                 if(!self.ammofield)
1100                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1101                         }
1102                 }
1103         }
1104
1105         // pickup anyway
1106         if(g_pickup_weapons_anyway)
1107                 self.pickup_anyway = TRUE;
1108
1109         f = FL_WEAPON;
1110
1111         // no weapon-stay on superweapons
1112         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1113                 f |= FL_NO_WEAPON_STAY;
1114
1115         // weapon stay isn't supported for teamed weapons
1116         if(self.team)
1117                 f |= FL_NO_WEAPON_STAY;
1118
1119         // stupid minstagib hack, don't ask
1120         if(g_minstagib)
1121                 if(self.ammo_cells)
1122                         self.ammo_cells = autocvar_g_minstagib_ammo_drop;
1123
1124         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapon, f, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1125         if (self.modelindex) // don't precache if self was removed
1126                 weapon_action(e.weapon, WR_PRECACHE);
1127 }
1128
1129 void spawnfunc_weapon_shotgun (void);
1130 void spawnfunc_weapon_uzi (void) {
1131         if(autocvar_sv_q3acompat_machineshotgunswap)
1132         if(self.classname != "droppedweapon")
1133         {
1134                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1135                 return;
1136         }
1137         weapon_defaultspawnfunc(WEP_UZI);
1138 }
1139
1140 void spawnfunc_weapon_shotgun (void) {
1141         if(autocvar_sv_q3acompat_machineshotgunswap)
1142         if(self.classname != "droppedweapon")
1143         {
1144                 weapon_defaultspawnfunc(WEP_UZI);
1145                 return;
1146         }
1147         weapon_defaultspawnfunc(WEP_SHOTGUN);
1148 }
1149
1150 void spawnfunc_weapon_nex (void)
1151 {
1152         if (g_minstagib)
1153         {
1154                 minstagib_items(IT_CELLS);
1155                 self.think = minst_remove_item;
1156                 self.nextthink = time;
1157                 return;
1158         }
1159         weapon_defaultspawnfunc(WEP_NEX);
1160 }
1161
1162 void spawnfunc_weapon_minstanex (void)
1163 {
1164         if (g_minstagib)
1165         {
1166                 minstagib_items(IT_CELLS);
1167                 self.think = minst_remove_item;
1168                 self.nextthink = time;
1169                 return;
1170         }
1171         weapon_defaultspawnfunc(WEP_MINSTANEX);
1172 }
1173
1174 void spawnfunc_weapon_rocketlauncher (void)
1175 {
1176         if (g_minstagib)
1177         {
1178                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1179                 self.think = minst_remove_item;
1180                 self.nextthink = time;
1181                 return;
1182         }
1183         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1184 }
1185
1186 void spawnfunc_item_rockets (void) {
1187         if(!self.ammo_rockets)
1188                 self.ammo_rockets = g_pickup_rockets;
1189         if(!self.pickup_anyway)
1190                 self.pickup_anyway = g_pickup_ammo_anyway;
1191         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1192 }
1193
1194 void spawnfunc_item_shells (void);
1195 void spawnfunc_item_bullets (void) {
1196         if(!weaponswapping)
1197         if(autocvar_sv_q3acompat_machineshotgunswap)
1198         if(self.classname != "droppedweapon")
1199         {
1200                 weaponswapping = TRUE;
1201                 spawnfunc_item_shells();
1202                 weaponswapping = FALSE;
1203                 return;
1204         }
1205
1206         if(!self.ammo_nails)
1207                 self.ammo_nails = g_pickup_nails;
1208         if(!self.pickup_anyway)
1209                 self.pickup_anyway = g_pickup_ammo_anyway;
1210         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1211 }
1212
1213 void spawnfunc_item_cells (void) {
1214         if(!self.ammo_cells)
1215                 self.ammo_cells = g_pickup_cells;
1216         if(!self.pickup_anyway)
1217                 self.pickup_anyway = g_pickup_ammo_anyway;
1218         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1219 }
1220
1221 void spawnfunc_item_shells (void) {
1222         if(!weaponswapping)
1223         if(autocvar_sv_q3acompat_machineshotgunswap)
1224         if(self.classname != "droppedweapon")
1225         {
1226                 weaponswapping = TRUE;
1227                 spawnfunc_item_bullets();
1228                 weaponswapping = FALSE;
1229                 return;
1230         }
1231
1232         if(!self.ammo_shells)
1233                 self.ammo_shells = g_pickup_shells;
1234         if(!self.pickup_anyway)
1235                 self.pickup_anyway = g_pickup_ammo_anyway;
1236         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1237 }
1238
1239 void spawnfunc_item_armor_small (void) {
1240         if(!self.armorvalue)
1241                 self.armorvalue = g_pickup_armorsmall;
1242         if(!self.max_armorvalue)
1243                 self.max_armorvalue = g_pickup_armorsmall_max;
1244         if(!self.pickup_anyway)
1245                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1246         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1247 }
1248
1249 void spawnfunc_item_armor_medium (void) {
1250         if(!self.armorvalue)
1251                 self.armorvalue = g_pickup_armormedium;
1252         if(!self.max_armorvalue)
1253                 self.max_armorvalue = g_pickup_armormedium_max;
1254         if(!self.pickup_anyway)
1255                 self.pickup_anyway = g_pickup_armormedium_anyway;
1256         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1257 }
1258
1259 void spawnfunc_item_armor_big (void) {
1260         if(!self.armorvalue)
1261                 self.armorvalue = g_pickup_armorbig;
1262         if(!self.max_armorvalue)
1263                 self.max_armorvalue = g_pickup_armorbig_max;
1264         if(!self.pickup_anyway)
1265                 self.pickup_anyway = g_pickup_armorbig_anyway;
1266         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1267 }
1268
1269 void spawnfunc_item_armor_large (void) {
1270         if(!self.armorvalue)
1271                 self.armorvalue = g_pickup_armorlarge;
1272         if(!self.max_armorvalue)
1273                 self.max_armorvalue = g_pickup_armorlarge_max;
1274         if(!self.pickup_anyway)
1275                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1276         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1277 }
1278
1279 void spawnfunc_item_health_small (void) {
1280         if(!self.max_health)
1281                 self.max_health = g_pickup_healthsmall_max;
1282         if(!self.health)
1283                 self.health = g_pickup_healthsmall;
1284         if(!self.pickup_anyway)
1285                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1286         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1287 }
1288
1289 void spawnfunc_item_health_medium (void) {
1290         if(!self.max_health)
1291                 self.max_health = g_pickup_healthmedium_max;
1292         if(!self.health)
1293                 self.health = g_pickup_healthmedium;
1294         if(!self.pickup_anyway)
1295                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1296         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1297 }
1298
1299 void spawnfunc_item_health_large (void) {
1300         if(!self.max_health)
1301                 self.max_health = g_pickup_healthlarge_max;
1302         if(!self.health)
1303                 self.health = g_pickup_healthlarge;
1304         if(!self.pickup_anyway)
1305                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1306         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1307 }
1308
1309 void spawnfunc_item_health_mega (void) {
1310         if(g_minstagib) {
1311                 minstagib_items(IT_NAILS);
1312         } else {
1313                 if(!self.max_health)
1314                         self.max_health = g_pickup_healthmega_max;
1315                 if(!self.health)
1316                         self.health = g_pickup_healthmega;
1317                 if(!self.pickup_anyway)
1318                         self.pickup_anyway = g_pickup_healthmega_anyway;
1319                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1320         }
1321 }
1322
1323 // support old misnamed entities
1324 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1325 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1326 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1327 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1328 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1329
1330 void spawnfunc_item_strength (void) {
1331         if(g_minstagib) {
1332                 minstagib_items(IT_STRENGTH);
1333         } else {
1334                 precache_sound("weapons/strength_fire.wav");
1335                 if(!self.strength_finished)
1336                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1337                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1338         }
1339 }
1340
1341 void spawnfunc_item_invincible (void) {
1342         if(g_minstagib) {
1343                 minstagib_items(IT_INVINCIBLE);
1344         } else {
1345                 if(!self.invincible_finished)
1346                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1347                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1348         }
1349 }
1350
1351 void spawnfunc_item_minst_cells (void) {
1352         if (g_minstagib)
1353         {
1354                 minst_no_auto_cells = 1;
1355                 minstagib_items(IT_CELLS);
1356         }
1357         else
1358                 remove(self);
1359 }
1360
1361 // compatibility:
1362 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1363
1364 float GiveItems(entity e, float beginarg, float endarg);
1365 void target_items_use (void)
1366 {
1367         if(activator.classname == "droppedweapon")
1368         {
1369                 EXACTTRIGGER_TOUCH;
1370                 remove(activator);
1371                 return;
1372         }
1373
1374         if(activator.classname != "player")
1375                 return;
1376         if(activator.deadflag != DEAD_NO)
1377                 return;
1378         EXACTTRIGGER_TOUCH;
1379
1380         entity e;
1381         for(e = world; (e = find(e, classname, "droppedweapon")); )
1382                 if(e.enemy == activator)
1383                         remove(e);
1384
1385         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1386                 centerprint(activator, self.message);
1387 }
1388
1389 void spawnfunc_target_items (void)
1390 {
1391         float n, i, j;
1392         entity e;
1393
1394         self.use = target_items_use;
1395         if(!self.strength_finished)
1396                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1397         if(!self.invincible_finished)
1398                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1399         if(!self.superweapons_finished)
1400                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1401
1402         precache_sound("misc/itempickup.wav");
1403         precache_sound("misc/megahealth.wav");
1404         precache_sound("misc/armor25.wav");
1405         precache_sound("misc/powerup.wav");
1406         precache_sound("misc/poweroff.wav");
1407         precache_sound("weapons/weaponpickup.wav");
1408
1409         n = tokenize_console(self.netname);
1410         if(argv(0) == "give")
1411         {
1412                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1413         }
1414         else
1415         {
1416                 for(i = 0; i < n; ++i)
1417                 {
1418                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1419                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1420                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1421                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1422                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1423                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1424                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1425                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1426                         else
1427                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1428                         {
1429                                 e = get_weaponinfo(j);
1430                                 if(argv(i) == e.netname)
1431                                 {
1432                                         WEPSET_OR_EW(self, j);
1433                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1434                                                 weapon_action(e.weapon, WR_PRECACHE);
1435                                         break;
1436                                 }
1437                         }
1438                         if(j > WEP_LAST)
1439                                 print("target_items: invalid item ", argv(i), "\n");
1440                 }
1441
1442                 string itemprefix, valueprefix;
1443                 if(self.spawnflags == 0)
1444                 {
1445                         itemprefix = "";
1446                         valueprefix = "";
1447                 }
1448                 else if(self.spawnflags == 1)
1449                 {
1450                         itemprefix = "max ";
1451                         valueprefix = "max ";
1452                 }
1453                 else if(self.spawnflags == 2)
1454                 {
1455                         itemprefix = "min ";
1456                         valueprefix = "min ";
1457                 }
1458                 else if(self.spawnflags == 4)
1459                 {
1460                         itemprefix = "minus ";
1461                         valueprefix = "max ";
1462                 }
1463                 else
1464                         error("invalid spawnflags");
1465
1466                 self.netname = "";
1467                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1468                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1469                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1470                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1471                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1472                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1473                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1474                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1475                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1476                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1477                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1478                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1479                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1480                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1481                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1482                 {
1483                         e = get_weaponinfo(j);
1484                         if(e.weapon)
1485                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, WEPSET_CONTAINS_EW(self, j), e.netname);
1486                 }
1487         }
1488         self.netname = strzone(self.netname);
1489         //print(self.netname, "\n");
1490
1491         n = tokenize_console(self.netname);
1492         for(i = 0; i < n; ++i)
1493         {
1494                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1495                 {
1496                         e = get_weaponinfo(j);
1497                         if(argv(i) == e.netname)
1498                         {
1499                                 weapon_action(e.weapon, WR_PRECACHE);
1500                                 break;
1501                         }
1502                 }
1503         }
1504 }
1505
1506 void spawnfunc_item_fuel(void)
1507 {
1508         if(!self.ammo_fuel)
1509                 self.ammo_fuel = g_pickup_fuel;
1510         if(!self.pickup_anyway)
1511                 self.pickup_anyway = g_pickup_ammo_anyway;
1512         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1513 }
1514
1515 void spawnfunc_item_fuel_regen(void)
1516 {
1517         if(start_items & IT_FUEL_REGEN)
1518         {
1519                 spawnfunc_item_fuel();
1520                 return;
1521         }
1522         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1523 }
1524
1525 void spawnfunc_item_jetpack(void)
1526 {
1527         if(g_grappling_hook)
1528                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1529         if(!self.ammo_fuel)
1530                 self.ammo_fuel = g_pickup_fuel_jetpack;
1531         if(start_items & IT_JETPACK)
1532         {
1533                 spawnfunc_item_fuel();
1534                 return;
1535         }
1536         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1537 }
1538
1539
1540 #define OP_SET 0
1541 #define OP_MIN 1
1542 #define OP_MAX 2
1543 #define OP_PLUS 3
1544 #define OP_MINUS 4
1545
1546 float GiveWeapon(entity e, float wpn, float op, float val)
1547 {
1548         float v0, v1;
1549         v0 = WEPSET_CONTAINS_EW(e, wpn);
1550         switch(op)
1551         {
1552                 case OP_SET:
1553                         if(val > 0)
1554                                 WEPSET_OR_EW(e, wpn);
1555                         else
1556                                 WEPSET_ANDNOT_EW(e, wpn);
1557                         break;
1558                 case OP_MIN:
1559                 case OP_PLUS:
1560                         if(val > 0)
1561                                 WEPSET_OR_EW(e, wpn);
1562                         break;
1563                 case OP_MAX:
1564                         if(val <= 0)
1565                                 WEPSET_ANDNOT_EW(e, wpn);
1566                         break;
1567                 case OP_MINUS:
1568                         if(val > 0)
1569                                 WEPSET_ANDNOT_EW(e, wpn);
1570                         break;
1571         }
1572         v1 = WEPSET_CONTAINS_EW(e, wpn);
1573         return (v0 != v1);
1574 }
1575
1576 float GiveBit(entity e, .float fld, float bit, float op, float val)
1577 {
1578         float v0, v1;
1579         v0 = (e.fld & bit);
1580         switch(op)
1581         {
1582                 case OP_SET:
1583                         if(val > 0)
1584                                 e.fld |= bit;
1585                         else
1586                                 e.fld &~= bit;
1587                         break;
1588                 case OP_MIN:
1589                 case OP_PLUS:
1590                         if(val > 0)
1591                                 e.fld |= bit;
1592                         break;
1593                 case OP_MAX:
1594                         if(val <= 0)
1595                                 e.fld &~= bit;
1596                         break;
1597                 case OP_MINUS:
1598                         if(val > 0)
1599                                 e.fld &~= bit;
1600                         break;
1601         }
1602         v1 = (e.fld & bit);
1603         return (v0 != v1);
1604 }
1605
1606 float GiveValue(entity e, .float fld, float op, float val)
1607 {
1608         float v0, v1;
1609         v0 = e.fld;
1610         switch(op)
1611         {
1612                 case OP_SET:
1613                         e.fld = val;
1614                         break;
1615                 case OP_MIN:
1616                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1617                         break;
1618                 case OP_MAX:
1619                         e.fld = min(e.fld, val);
1620                         break;
1621                 case OP_PLUS:
1622                         e.fld += val;
1623                         break;
1624                 case OP_MINUS:
1625                         e.fld -= val;
1626                         break;
1627         }
1628         v1 = e.fld;
1629         return (v0 != v1);
1630 }
1631
1632 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1633 {
1634         if(v1 == v0)
1635                 return;
1636         if(v1 <= v0 - t)
1637         {
1638                 if(snd_decr != "")
1639                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1640         }
1641         else if(v0 >= v0 + t)
1642         {
1643                 if(snd_incr != "")
1644                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1645         }
1646 }
1647
1648 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1649 {
1650         if(v0 < v1)
1651                 e.rotfield = max(e.rotfield, time + rottime);
1652         else if(v0 > v1)
1653                 e.regenfield = max(e.regenfield, time + regentime);
1654 }
1655
1656 #define PREGIVE_WEAPONS(e) WEPSET_DECLARE_A(save_weapons); WEPSET_COPY_AE(save_weapons, e)
1657 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1658 #define POSTGIVE_WEAPON(e,b,snd_incr,snd_decr) GiveSound((e), WEPSET_CONTAINS_AW(save_weapons, b), WEPSET_CONTAINS_EW(e, b), 0, snd_incr, snd_decr)
1659 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1660 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1661 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1662
1663 float GiveItems(entity e, float beginarg, float endarg)
1664 {
1665         float got, i, j, val, op;
1666         float _switchweapon;
1667         entity wi;
1668         string cmd;
1669
1670         val = 999;
1671         op = OP_SET;
1672
1673         got = 0;
1674
1675         _switchweapon = FALSE;
1676         if (e.autoswitch)
1677                 if (e.switchweapon == w_getbestweapon(e))
1678                         _switchweapon = TRUE;
1679
1680         e.strength_finished = max(0, e.strength_finished - time);
1681         e.invincible_finished = max(0, e.invincible_finished - time);
1682         e.superweapons_finished = max(0, e.superweapons_finished - time);
1683
1684         PREGIVE(e, items);
1685         PREGIVE_WEAPONS(e);
1686         PREGIVE(e, strength_finished);
1687         PREGIVE(e, invincible_finished);
1688         PREGIVE(e, superweapons_finished);
1689         PREGIVE(e, ammo_nails);
1690         PREGIVE(e, ammo_cells);
1691         PREGIVE(e, ammo_shells);
1692         PREGIVE(e, ammo_rockets);
1693         PREGIVE(e, ammo_fuel);
1694         PREGIVE(e, armorvalue);
1695         PREGIVE(e, health);
1696
1697         for(i = beginarg; i < endarg; ++i)
1698         {
1699                 cmd = argv(i);
1700
1701                 if(cmd == "0" || stof(cmd))
1702                 {
1703                         val = stof(cmd);
1704                         continue;
1705                 }
1706                 switch(cmd)
1707                 {
1708                         case "no":
1709                                 op = OP_MAX;
1710                                 val = 0;
1711                                 continue;
1712                         case "max":
1713                                 op = OP_MAX;
1714                                 continue;
1715                         case "min":
1716                                 op = OP_MIN;
1717                                 continue;
1718                         case "plus":
1719                                 op = OP_PLUS;
1720                                 continue;
1721                         case "minus":
1722                                 op = OP_MINUS;
1723                                 continue;
1724                         case "ALL":
1725                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1726                                 got += GiveValue(e, strength_finished, op, val);
1727                                 got += GiveValue(e, invincible_finished, op, val);
1728                                 got += GiveValue(e, superweapons_finished, op, val);
1729                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1730                         case "all":
1731                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1732                                 got += GiveValue(e, health, op, val);
1733                                 got += GiveValue(e, armorvalue, op, val);
1734                         case "allweapons":
1735                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1736                                 {
1737                                         wi = get_weaponinfo(j);
1738                                         if(wi.weapon)
1739                                                 if not(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1740                                                         got += GiveWeapon(e, j, op, val);
1741                                 }
1742                         case "allammo":
1743                                 got += GiveValue(e, ammo_cells, op, val);
1744                                 got += GiveValue(e, ammo_shells, op, val);
1745                                 got += GiveValue(e, ammo_nails, op, val);
1746                                 got += GiveValue(e, ammo_rockets, op, val);
1747                                 got += GiveValue(e, ammo_fuel, op, val);
1748                                 break;
1749                         case "unlimited_ammo":
1750                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1751                                 break;
1752                         case "unlimited_weapon_ammo":
1753                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1754                                 break;
1755                         case "unlimited_superweapons":
1756                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1757                                 break;
1758                         case "jetpack":
1759                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1760                                 break;
1761                         case "fuel_regen":
1762                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1763                                 break;
1764                         case "strength":
1765                                 got += GiveValue(e, strength_finished, op, val);
1766                                 break;
1767                         case "invincible":
1768                                 got += GiveValue(e, invincible_finished, op, val);
1769                                 break;
1770                         case "superweapons":
1771                                 got += GiveValue(e, superweapons_finished, op, val);
1772                                 break;
1773                         case "cells":
1774                                 got += GiveValue(e, ammo_cells, op, val);
1775                                 break;
1776                         case "shells":
1777                                 got += GiveValue(e, ammo_shells, op, val);
1778                                 break;
1779                         case "nails":
1780                         case "bullets":
1781                                 got += GiveValue(e, ammo_nails, op, val);
1782                                 break;
1783                         case "rockets":
1784                                 got += GiveValue(e, ammo_rockets, op, val);
1785                                 break;
1786                         case "health":
1787                                 got += GiveValue(e, health, op, val);
1788                                 break;
1789                         case "armor":
1790                                 got += GiveValue(e, armorvalue, op, val);
1791                                 break;
1792                         case "fuel":
1793                                 got += GiveValue(e, ammo_fuel, op, val);
1794                                 break;
1795                         default:
1796                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1797                                 {
1798                                         wi = get_weaponinfo(j);
1799                                         if(cmd == wi.netname)
1800                                         {
1801                                                 got += GiveWeapon(e, j, op, val);
1802                                                 break;
1803                                         }
1804                                 }
1805                                 if(j > WEP_LAST)
1806                                         print("give: invalid item ", cmd, "\n");
1807                                 break;
1808                 }
1809                 val = 999;
1810                 op = OP_SET;
1811         }
1812
1813         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1814         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1815         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1816         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1817         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1818         {
1819                 wi = get_weaponinfo(j);
1820                 if(wi.weapon)
1821                 {
1822                         POSTGIVE_WEAPON(e, j, "weapons/weaponpickup.wav", string_null);
1823                         if not(WEPSET_CONTAINS_AW(save_weapons, j))
1824                                 if(WEPSET_CONTAINS_EW(e, j))
1825                                         weapon_action(wi.weapon, WR_PRECACHE);
1826                 }
1827         }
1828         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1829         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1830         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1831         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1832         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1833         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1834         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1835         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1836         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1837
1838         if(e.superweapons_finished <= 0)
1839                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1840                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1841
1842         if (g_minstagib)
1843         {
1844                 e.health = bound(0, e.health, 100);
1845                 e.armorvalue = bound(0, e.armorvalue, 999);
1846         }
1847
1848         if(e.strength_finished <= 0)
1849                 e.strength_finished = 0;
1850         else
1851                 e.strength_finished += time;
1852         if(e.invincible_finished <= 0)
1853                 e.invincible_finished = 0;
1854         else
1855                 e.invincible_finished += time;
1856         if(e.superweapons_finished <= 0)
1857                 e.superweapons_finished = 0;
1858         else
1859                 e.superweapons_finished += time;
1860
1861         if not(WEPSET_CONTAINS_EW(e, e.switchweapon))
1862                 _switchweapon = TRUE;
1863         if(_switchweapon)
1864                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1865
1866         return got;
1867 }