qcsrc/server/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "../common/items/all.qc"
   4
   5 #if defined(SVQC)
   6     #include "_all.qh"
   7
   8     #include "bot/bot.qh"
   9     #include "bot/waypoints.qh"
  10
  11     #include "mutators/mutators_include.qh"
  12
  13     #include "weapons/common.qh"
  14     #include "weapons/selection.qh"
  15     #include "weapons/weaponsystem.qh"
  16
  17     #include "../common/constants.qh"
  18     #include "../common/deathtypes.qh"
  19     #include "../common/notifications.qh"
  20         #include "../common/triggers/subs.qh"
  21     #include "../common/util.qh"
  22
  23     #include "../common/monsters/all.qh"
  24
  25     #include "../common/weapons/all.qh"
  26
  27     #include "../warpzonelib/util_server.qh"
  28 #endif
  29
  30 #ifdef CSQC
  31 void ItemDraw()
  32 {
  33     if(self.gravity)
  34     {
  35         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  36         if(self.move_flags & FL_ONGROUND)
  37         { // For some reason move_avelocity gets set to '0 0 0' here ...
  38             self.oldorigin = self.origin;
  39             self.gravity = 0;
  40
  41             if(autocvar_cl_animate_items)
  42             { // ... so reset it if animations are requested.
  43                 if(self.ItemStatus & ITS_ANIMATE1)
  44                     self.move_avelocity = '0 180 0';
  45
  46                 if(self.ItemStatus & ITS_ANIMATE2)
  47                     self.move_avelocity = '0 -90 0';
  48             }
  49         }
  50     }
  51     else if (autocvar_cl_animate_items)
  52     {
  53         if(self.ItemStatus & ITS_ANIMATE1)
  54         {
  55             self.angles += self.move_avelocity * frametime;
  56             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));
  57         }
  58
  59         if(self.ItemStatus & ITS_ANIMATE2)
  60         {
  61             self.angles += self.move_avelocity * frametime;
  62             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));
  63         }
  64     }
  65 }
  66
  67 void ItemDrawSimple()
  68 {
  69     if(self.gravity)
  70     {
  71         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  72
  73         if(self.move_flags & FL_ONGROUND)
  74             self.gravity = 0;
  75     }
  76 }
  77
  78 void Item_PreDraw()
  79 {
  80         vector org;
  81         float alph;
  82         org = getpropertyvec(VF_ORIGIN);
  83         if(!checkpvs(org, self)) // this makes sense as long as we don't support recursive warpzones
  84                 alph = 0;
  85         else if(self.fade_start)
  86                 alph = bound(0, (self.fade_end - vlen(org - self.origin - 0.5 * (self.mins + self.maxs))) / (self.fade_end - self.fade_start), 1);
  87         else
  88                 alph = 1;
  89         //printf("%v <-> %v\n", view_origin, self.origin + 0.5 * (self.mins + self.maxs));
  90         if(self.ItemStatus & ITS_AVAILABLE)
  91                 self.alpha = alph;
  92         if(alph <= 0)
  93                 self.drawmask = 0;
  94         else
  95                 self.drawmask = MASK_NORMAL;
  96 }
  97
  98 void ItemRead(float _IsNew)
  99 {
 100     int sf = ReadByte();
 101
 102     if(sf & ISF_LOCATION)
 103     {
 104         self.origin_x = ReadCoord();
 105         self.origin_y = ReadCoord();
 106         self.origin_z = ReadCoord();
 107         setorigin(self, self.origin);
 108         self.oldorigin = self.origin;
 109     }
 110
 111     if(sf & ISF_ANGLES)
 112     {
 113         self.angles_x = ReadAngle();
 114         self.angles_y = ReadAngle();
 115         self.angles_z = ReadAngle();
 116         self.move_angles = self.angles;
 117     }
 118
 119     if(sf & ISF_SIZE)
 120     {
 121         float use_bigsize = ReadByte();
 122         setsize(self, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 123     }
 124
 125     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
 126     {
 127         self.ItemStatus = ReadByte();
 128
 129         if(self.ItemStatus & ITS_AVAILABLE)
 130         {
 131             self.alpha = 1;
 132             self.colormod = self.glowmod = '1 1 1';
 133         }
 134         else
 135         {
 136             if (autocvar_cl_ghost_items_color)
 137             {
 138                 self.alpha = autocvar_cl_ghost_items;
 139                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
 140             }
 141             else
 142                 self.alpha = -1;
 143         }
 144
 145         if(autocvar_cl_fullbright_items)
 146             if(self.ItemStatus & ITS_ALLOWFB)
 147                 self.effects |= EF_FULLBRIGHT;
 148
 149         if(self.ItemStatus & ITS_STAYWEP)
 150         {
 151             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
 152             self.alpha = autocvar_cl_weapon_stay_alpha;
 153
 154         }
 155
 156         if(self.ItemStatus & ITS_POWERUP)
 157         {
 158             if(self.ItemStatus & ITS_AVAILABLE)
 159                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 160             else
 161                  self.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 162         }
 163     }
 164
 165     if(sf & ISF_MODEL)
 166     {
 167         self.drawmask  = MASK_NORMAL;
 168                 self.move_movetype = self.movetype = MOVETYPE_TOSS;
 169                 //self.renderflags |= RF_DEPTHHACK;
 170         self.draw       = ItemDraw;
 171
 172         self.fade_end = ReadShort();
 173         self.fade_start = ReadShort();
 174         if(self.fade_start && !autocvar_cl_items_nofade)
 175                 self.predraw = Item_PreDraw;
 176
 177         if(self.mdl)
 178             strunzone(self.mdl);
 179
 180         self.mdl = "";
 181         string _fn = ReadString();
 182
 183         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
 184         {
 185             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 186             self.draw = ItemDrawSimple;
 187
 188             if(fexists(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix)))
 189                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix));
 190             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix)))
 191                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix));
 192             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix)))
 193                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix));
 194             else if(fexists(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix)))
 195                 self.mdl = strzone(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix));
 196             else
 197             {
 198                 self.draw = ItemDraw;
 199                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it\n");
 200             }
 201         }
 202
 203         if(self.draw != ItemDrawSimple)
 204             self.mdl = strzone(_fn);
 205
 206
 207         if(self.mdl == "")
 208             LOG_TRACE("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
 209
 210         precache_model(self.mdl);
 211         setmodel(self, self.mdl);
 212     }
 213
 214     if(sf & ISF_COLORMAP)
 215         self.colormap = ReadShort();
 216
 217     if(sf & ISF_DROP)
 218     {
 219         self.gravity = 1;
 220         //self.move_angles = '0 0 0';
 221         self.move_movetype = MOVETYPE_TOSS;
 222         self.move_velocity_x = ReadCoord();
 223         self.move_velocity_y = ReadCoord();
 224         self.move_velocity_z = ReadCoord();
 225         self.velocity = self.move_velocity;
 226         self.move_origin = self.oldorigin;
 227
 228         if(!self.move_time)
 229         {
 230             self.move_time = time;
 231             self.spawntime = time;
 232         }
 233         else
 234             self.move_time = max(self.move_time, time);
 235     }
 236
 237     if(autocvar_cl_animate_items)
 238     {
 239         if(self.ItemStatus & ITS_ANIMATE1)
 240             self.move_avelocity = '0 180 0';
 241
 242         if(self.ItemStatus & ITS_ANIMATE2)
 243             self.move_avelocity = '0 -90 0';
 244     }
 245 }
 246
 247 #endif
 248
 249 #ifdef SVQC
 250 bool ItemSend(entity to, int sf)
 251 {
 252         if(self.gravity)
 253                 sf |= ISF_DROP;
 254         else
 255                 sf &= ~ISF_DROP;
 256
 257         WriteByte(MSG_ENTITY, ENT_CLIENT_ITEM);
 258         WriteByte(MSG_ENTITY, sf);
 259
 260         //WriteByte(MSG_ENTITY, self.cnt);
 261         if(sf & ISF_LOCATION)
 262         {
 263                 WriteCoord(MSG_ENTITY, self.origin.x);
 264                 WriteCoord(MSG_ENTITY, self.origin.y);
 265                 WriteCoord(MSG_ENTITY, self.origin.z);
 266         }
 267
 268         if(sf & ISF_ANGLES)
 269         {
 270                 WriteAngle(MSG_ENTITY, self.angles_x);
 271                 WriteAngle(MSG_ENTITY, self.angles_y);
 272                 WriteAngle(MSG_ENTITY, self.angles_z);
 273         }
 274
 275         if(sf & ISF_SIZE)
 276         {
 277                 WriteByte(MSG_ENTITY, ((self.flags & FL_POWERUP) || self.health || self.armorvalue));
 278         }
 279
 280         if(sf & ISF_STATUS)
 281                 WriteByte(MSG_ENTITY, self.ItemStatus);
 282
 283         if(sf & ISF_MODEL)
 284         {
 285                 WriteShort(MSG_ENTITY, self.fade_end);
 286                 WriteShort(MSG_ENTITY, self.fade_start);
 287
 288                 if(self.mdl == "")
 289                         LOG_TRACE("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
 290
 291                 WriteString(MSG_ENTITY, self.mdl);
 292         }
 293
 294
 295         if(sf & ISF_COLORMAP)
 296                 WriteShort(MSG_ENTITY, self.colormap);
 297
 298         if(sf & ISF_DROP)
 299         {
 300                 WriteCoord(MSG_ENTITY, self.velocity.x);
 301                 WriteCoord(MSG_ENTITY, self.velocity.y);
 302                 WriteCoord(MSG_ENTITY, self.velocity.z);
 303         }
 304
 305         return true;
 306 }
 307
 308 void ItemUpdate(entity item)
 309 {
 310         item.SendFlags |= ISF_LOCATION;
 311 }
 312
 313 float have_pickup_item(void)
 314 {
 315         if(self.flags & FL_POWERUP)
 316         {
 317                 if(autocvar_g_powerups > 0)
 318                         return true;
 319                 if(autocvar_g_powerups == 0)
 320                         return false;
 321         }
 322         else
 323         {
 324                 if(autocvar_g_pickup_items > 0)
 325                         return true;
 326                 if(autocvar_g_pickup_items == 0)
 327                         return false;
 328                 if(g_weaponarena)
 329                         if(self.weapons || (self.items & IT_AMMO)) // no item or ammo pickups in weaponarena
 330                                 return false;
 331         }
 332         return true;
 333 }
 334
 335 /*
 336 float Item_Customize()
 337 {
 338         if(self.spawnshieldtime)
 339                 return true;
 340         if(self.weapons & ~other.weapons)
 341         {
 342                 self.colormod = '0 0 0';
 343                 self.glowmod = self.colormod;
 344                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 345                 return true;
 346         }
 347         else
 348         {
 349                 if(g_ghost_items)
 350                 {
 351                         self.colormod = stov(autocvar_g_ghost_items_color);
 352                         self.glowmod = self.colormod;
 353                         self.alpha = g_ghost_items;
 354                         return true;
 355                 }
 356                 else
 357                         return false;
 358         }
 359 }
 360 */
 361
 362 void Item_Show (entity e, float mode)
 363 {
 364         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 365         e.ItemStatus &= ~ITS_STAYWEP;
 366         if (mode > 0)
 367         {
 368                 // make the item look normal, and be touchable
 369                 e.model = e.mdl;
 370                 e.solid = SOLID_TRIGGER;
 371                 e.spawnshieldtime = 1;
 372                 e.ItemStatus |= ITS_AVAILABLE;
 373         }
 374         else if (mode < 0)
 375         {
 376                 // hide the item completely
 377                 e.model = string_null;
 378                 e.solid = SOLID_NOT;
 379                 e.spawnshieldtime = 1;
 380                 e.ItemStatus &= ~ITS_AVAILABLE;
 381         }
 382         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 383         {
 384                 // make the item translucent and not touchable
 385                 e.model = e.mdl;
 386                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 387                 e.effects |= EF_STARDUST;
 388                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 389                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 390         }
 391         else
 392         {
 393                 //setmodel(e, "null");
 394                 e.solid = SOLID_NOT;
 395                 e.colormod = '0 0 0';
 396                 e.glowmod = e.colormod;
 397                 e.spawnshieldtime = 1;
 398                 e.ItemStatus &= ~ITS_AVAILABLE;
 399         }
 400
 401         if (e.items & ITEM_Strength.m_itemid || e.items & ITEM_Shield.m_itemid)
 402                 e.ItemStatus |= ITS_POWERUP;
 403
 404         if (autocvar_g_nodepthtestitems)
 405                 e.effects |= EF_NODEPTHTEST;
 406
 407
 408         if (autocvar_g_fullbrightitems)
 409                 e.ItemStatus |= ITS_ALLOWFB;
 410
 411         if (autocvar_sv_simple_items)
 412                 e.ItemStatus |= ITS_ALLOWSI;
 413
 414         // relink entity (because solid may have changed)
 415         setorigin(e, e.origin);
 416         e.SendFlags |= ISF_STATUS;
 417 }
 418
 419 void Item_Think()
 420 {
 421         self.nextthink = time;
 422         if(self.origin != self.oldorigin)
 423         {
 424                 self.oldorigin = self.origin;
 425                 ItemUpdate(self);
 426         }
 427 }
 428
 429 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 430 bool Item_ItemsTime_Allow(GameItem it, WepSet _weapons);
 431 float Item_ItemsTime_UpdateTime(entity e, float t);
 432 void Item_ItemsTime_SetTime(entity e, float t);
 433 void Item_ItemsTime_SetTimesForAllPlayers();
 434
 435 void Item_Respawn (void)
 436 {
 437         Item_Show(self, 1);
 438         // this is ugly...
 439         if(self.items == ITEM_Strength.m_itemid)
 440                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTEN_NORM);    // play respawn sound
 441         else if(self.items == ITEM_Shield.m_itemid)
 442                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTEN_NORM);      // play respawn sound
 443         else
 444                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTEN_NORM); // play respawn sound
 445         setorigin (self, self.origin);
 446
 447     if (Item_ItemsTime_Allow(self.itemdef, self.weapons))
 448         {
 449                 float t = Item_ItemsTime_UpdateTime(self, 0);
 450                 Item_ItemsTime_SetTime(self, t);
 451                 Item_ItemsTime_SetTimesForAllPlayers();
 452         }
 453
 454         self.think = Item_Think;
 455         self.nextthink = time;
 456
 457         //Send_Effect(EFFECT_ITEM_RESPAWN, self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 458         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 459 }
 460
 461 void Item_RespawnCountdown (void)
 462 {
 463         if(self.count >= ITEM_RESPAWN_TICKS)
 464         {
 465                 if(self.waypointsprite_attached)
 466                         WaypointSprite_Kill(self.waypointsprite_attached);
 467                 Item_Respawn();
 468         }
 469         else
 470         {
 471                 self.nextthink = time + 1;
 472                 self.count += 1;
 473                 if(self.count == 1)
 474                 {
 475                         MUTATOR_CALLHOOK(Item_RespawnCountdown, string_null, '0 0 0');
 476                         int wpextra = 0;
 477             entity e = self.itemdef;
 478             if (e) wpextra = e.m_id;
 479                         if (self.flags & FL_WEAPON) {
 480                                 entity wi = get_weaponinfo(self.weapon);
 481                                 if (wi) wpextra = wi.m_id;
 482                         }
 483             entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, true, RADARICON_POWERUP);
 484             wp.wp_extra = wpextra;
 485             if(self.waypointsprite_attached)
 486             {
 487                 GameItem def = self.itemdef;
 488                 if (Item_ItemsTime_SpectatorOnly(def))
 489                     WaypointSprite_UpdateRule(self.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 490                 WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 491             }
 492                 }
 493
 494                 if(self.waypointsprite_attached)
 495                 {
 496                         entity e;
 497                         entity it = self;
 498                         self = self.waypointsprite_attached;
 499                         FOR_EACH_REALCLIENT(e)
 500                                 if(self.waypointsprite_visible_for_player(e))
 501                                 {
 502                                         msg_entity = e;
 503                                         soundto(MSG_ONE, it, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTEN_NORM);        // play respawn sound
 504                                 }
 505                         self = it;
 506
 507                         WaypointSprite_Ping(self.waypointsprite_attached);
 508                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 509                 }
 510                 else
 511                         sound(self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTEN_NORM); // play respawn sound
 512         }
 513 }
 514
 515 void Item_RespawnThink()
 516 {
 517         self.nextthink = time;
 518         if(self.origin != self.oldorigin)
 519         {
 520                 self.oldorigin = self.origin;
 521                 ItemUpdate(self);
 522         }
 523
 524         if(time >= self.wait)
 525                 Item_Respawn();
 526 }
 527
 528 void Item_ScheduleRespawnIn(entity e, float t)
 529 {
 530         if (Item_ItemsTime_Allow(e.itemdef, e.weapons))
 531         {
 532                 e.think = Item_RespawnCountdown;
 533                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 534                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 535                 e.count = 0;
 536                 t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 537                 Item_ItemsTime_SetTime(e, t);
 538                 Item_ItemsTime_SetTimesForAllPlayers();
 539         }
 540         else
 541         {
 542                 e.think = Item_RespawnThink;
 543                 e.nextthink = time;
 544                 e.scheduledrespawntime = time + t;
 545                 e.wait = time + t;
 546         }
 547 }
 548
 549 void Item_ScheduleRespawn(entity e)
 550 {
 551         if(e.respawntime > 0)
 552         {
 553                 Item_Show(e, 0);
 554                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 555         }
 556         else // if respawntime is -1, this item does not respawn
 557                 Item_Show(e, -1);
 558 }
 559
 560 void Item_ScheduleInitialRespawn(entity e)
 561 {
 562         Item_Show(e, 0);
 563         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 564 }
 565
 566 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
 567 {
 568         if (!item.(ammotype))
 569                 return false;
 570
 571         if (item.spawnshieldtime)
 572         {
 573                 if ((player.(ammotype) < ammomax) || item.pickup_anyway)
 574                 {
 575                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
 576                         goto YEAH;
 577                 }
 578         }
 579         else if(g_weapon_stay == 2)
 580         {
 581                 float mi = min(item.(ammotype), ammomax);
 582                 if (player.(ammotype) < mi)
 583                 {
 584                         player.(ammotype) = mi;
 585                         goto YEAH;
 586                 }
 587         }
 588
 589         return false;
 590
 591 :YEAH
 592         switch(mode)
 593         {
 594                 case ITEM_MODE_FUEL:
 595                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 596                         break;
 597                 case ITEM_MODE_HEALTH:
 598                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 599                         break;
 600                 case ITEM_MODE_ARMOR:
 601                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 602                         break;
 603                 default:
 604                         break;
 605         }
 606         return true;
 607 }
 608
 609 float Item_GiveTo(entity item, entity player)
 610 {
 611         float _switchweapon;
 612         float pickedup;
 613         float it;
 614         float i;
 615
 616         // if nothing happens to player, just return without taking the item
 617         pickedup = false;
 618         _switchweapon = false;
 619         // in case the player has autoswitch enabled do the following:
 620         // if the player is using their best weapon before items are given, they
 621         // probably want to switch to an even better weapon after items are given
 622         if (player.autoswitch)
 623         if (player.switchweapon == w_getbestweapon(player))
 624                 _switchweapon = true;
 625
 626         if (!(player.weapons & WepSet_FromWeapon(player.switchweapon)))
 627                 _switchweapon = true;
 628
 629         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 630         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 631         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 632         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 633         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 634         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
 635         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 636         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 637
 638         if (item.flags & FL_WEAPON)
 639         {
 640                 WepSet it;
 641                 it = item.weapons;
 642                 it &= ~player.weapons;
 643
 644                 if (it || (item.spawnshieldtime && item.pickup_anyway))
 645                 {
 646                         pickedup = true;
 647                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 648                         if(it & WepSet_FromWeapon(i))
 649                         {
 650                                 W_DropEvent(WR_PICKUP, player, i, item);
 651                                 W_GiveWeapon(player, i);
 652                         }
 653                 }
 654         }
 655
 656         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 657         {
 658                 pickedup = true;
 659                 player.items |= it;
 660                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 661         }
 662
 663         if (item.strength_finished)
 664         {
 665                 pickedup = true;
 666                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 667         }
 668         if (item.invincible_finished)
 669         {
 670                 pickedup = true;
 671                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 672         }
 673         if (item.superweapons_finished)
 674         {
 675                 pickedup = true;
 676                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 677         }
 678
 679 :skip
 680
 681         // always eat teamed entities
 682         if(item.team)
 683                 pickedup = true;
 684
 685         if (!pickedup)
 686                 return 0;
 687
 688         // crude hack to enforce switching weapons
 689         if(g_cts && (item.flags & FL_WEAPON))
 690         {
 691                 W_SwitchWeapon_Force(player, item.weapon);
 692                 return 1;
 693         }
 694
 695         if (_switchweapon)
 696                 if (player.switchweapon != w_getbestweapon(player))
 697                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 698
 699         return 1;
 700 }
 701
 702 void Item_Touch (void)
 703 {
 704         entity e, head;
 705
 706         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 707         if(self.classname == "droppedweapon")
 708         {
 709                 if (ITEM_TOUCH_NEEDKILL())
 710                 {
 711                         remove(self);
 712                         return;
 713                 }
 714         }
 715
 716         if(!(other.flags & FL_PICKUPITEMS)
 717         || other.frozen
 718         || other.deadflag
 719         || (self.solid != SOLID_TRIGGER)
 720         || (self.owner == other)
 721         || (time < self.item_spawnshieldtime)
 722         ) { return;}
 723
 724         switch(MUTATOR_CALLHOOK(ItemTouch, self, other))
 725         {
 726                 case MUT_ITEMTOUCH_RETURN: { return; }
 727                 case MUT_ITEMTOUCH_PICKUP: { goto pickup; }
 728         }
 729
 730         if (self.classname == "droppedweapon")
 731         {
 732                 self.strength_finished = max(0, self.strength_finished - time);
 733                 self.invincible_finished = max(0, self.invincible_finished - time);
 734                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 735         }
 736         entity it = self.itemdef;
 737         bool gave = (it && it.instanceOfPickup) ? ITEM_HANDLE(Pickup, it, self, other) : Item_GiveTo(self, other);
 738         if (!gave)
 739         {
 740                 if (self.classname == "droppedweapon")
 741                 {
 742                         // undo what we did above
 743                         self.strength_finished += time;
 744                         self.invincible_finished += time;
 745                         self.superweapons_finished += time;
 746                 }
 747                 return;
 748         }
 749
 750         :pickup
 751
 752         other.last_pickup = time;
 753
 754         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 755         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTEN_NORM);
 756
 757         if (self.classname == "droppedweapon")
 758                 remove (self);
 759         else if (self.spawnshieldtime)
 760         {
 761                 if(self.team)
 762                 {
 763                         RandomSelection_Init();
 764                         for(head = world; (head = findfloat(head, team, self.team)); )
 765                         {
 766                                 if(head.flags & FL_ITEM)
 767                                 if(head.classname != "item_flag_team" && head.classname != "item_key_team")
 768                                 {
 769                                         Item_Show(head, -1);
 770                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 771                                 }
 772                         }
 773                         e = RandomSelection_chosen_ent;
 774
 775                 }
 776                 else
 777                         e = self;
 778                 Item_ScheduleRespawn(e);
 779         }
 780 }
 781
 782 void Item_Reset()
 783 {
 784         Item_Show(self, !self.state);
 785         setorigin (self, self.origin);
 786
 787         if(self.classname != "droppedweapon")
 788         {
 789                 self.think = Item_Think;
 790                 self.nextthink = time;
 791
 792                 if(self.waypointsprite_attached)
 793                         WaypointSprite_Kill(self.waypointsprite_attached);
 794
 795                 if((self.flags & FL_POWERUP) || (self.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 796                         Item_ScheduleInitialRespawn(self);
 797         }
 798 }
 799
 800 void Item_FindTeam()
 801 {
 802         entity head, e;
 803
 804         if(self.effects & EF_NODRAW)
 805         {
 806                 // marker for item team search
 807                 LOG_TRACE("Initializing item team ", ftos(self.team), "\n");
 808                 RandomSelection_Init();
 809                 for(head = world; (head = findfloat(head, team, self.team)); )
 810                 if(head.flags & FL_ITEM)
 811                 if(head.classname != "item_flag_team" && head.classname != "item_key_team")
 812                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 813                 e = RandomSelection_chosen_ent;
 814                 e.state = 0;
 815                 Item_Show(e, 1);
 816
 817                 for(head = world; (head = findfloat(head, team, self.team)); )
 818                 if(head.flags & FL_ITEM)
 819                 if(head.classname != "item_flag_team" && head.classname != "item_key_team")
 820                 {
 821                         if(head != e)
 822                         {
 823                                 // make it a non-spawned item
 824                                 Item_Show(head, -1);
 825                                 head.state = 1; // state 1 = initially hidden item
 826                         }
 827                         head.effects &= ~EF_NODRAW;
 828                 }
 829
 830                 Item_Reset();
 831         }
 832 }
 833
 834 // Savage: used for item garbage-collection
 835 // TODO: perhaps nice special effect?
 836 void RemoveItem(void)
 837 {
 838         if(wasfreed(self) || !self) { return; }
 839         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 840         remove(self);
 841 }
 842
 843 // pickup evaluation functions
 844 // these functions decide how desirable an item is to the bots
 845
 846 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 847
 848 float weapon_pickupevalfunc(entity player, entity item)
 849 {
 850         float c;
 851
 852         // See if I have it already
 853         if(item.weapons & ~player.weapons)
 854         {
 855                 // If I can pick it up
 856                 if(!item.spawnshieldtime)
 857                         c = 0;
 858                 else if(player.ammo_cells || player.ammo_shells || player.ammo_plasma || player.ammo_nails || player.ammo_rockets)
 859                 {
 860                         // Skilled bots will grab more
 861                         c = bound(0, skill / 10, 1) * 0.5;
 862                 }
 863                 else
 864                         c = 0;
 865         }
 866         else
 867                 c = 1;
 868
 869         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 870         if( bot_custom_weapon && c )
 871         {
 872                 // Find the highest position on any range
 873                 int position = -1;
 874                 for (int j = 0; j < WEP_LAST ; ++j){
 875                         if(
 876                                         bot_weapons_far[j] == item.weapon ||
 877                                         bot_weapons_mid[j] == item.weapon ||
 878                                         bot_weapons_close[j] == item.weapon
 879                           )
 880                         {
 881                                 position = j;
 882                                 break;
 883                         }
 884                 }
 885
 886                 // Rate it
 887                 if (position >= 0 )
 888                 {
 889                         position = WEP_LAST - position;
 890                         // item.bot_pickupbasevalue is overwritten here
 891                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 892                 }
 893         }
 894
 895         return item.bot_pickupbasevalue * c;
 896 }
 897
 898 float commodity_pickupevalfunc(entity player, entity item)
 899 {
 900         float c, i;
 901         float need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
 902         entity wi;
 903         c = 0;
 904
 905         // Detect needed ammo
 906         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 907         {
 908                 wi = get_weaponinfo(i);
 909
 910                 if (!(player.weapons & WepSet_FromWeapon(i)))
 911                         continue;
 912
 913                 if(wi.items & ITEM_Shells.m_itemid)
 914                         need_shells = true;
 915                 else if(wi.items & ITEM_Bullets.m_itemid)
 916                         need_nails = true;
 917                 else if(wi.items & ITEM_Rockets.m_itemid)
 918                         need_rockets = true;
 919                 else if(wi.items & ITEM_Cells.m_itemid)
 920                         need_cells = true;
 921                 else if(wi.items & ITEM_Plasma.m_itemid)
 922                         need_plasma = true;
 923                 else if(wi.items & ITEM_JetpackFuel.m_itemid)
 924                         need_fuel = true;
 925         }
 926
 927         // TODO: figure out if the player even has the weapon this ammo is for?
 928         // may not affect strategy much though...
 929         // find out how much more ammo/armor/health the player can hold
 930         if (need_shells)
 931         if (item.ammo_shells)
 932         if (player.ammo_shells < g_pickup_shells_max)
 933                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 934         if (need_nails)
 935         if (item.ammo_nails)
 936         if (player.ammo_nails < g_pickup_nails_max)
 937                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 938         if (need_rockets)
 939         if (item.ammo_rockets)
 940         if (player.ammo_rockets < g_pickup_rockets_max)
 941                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 942         if (need_cells)
 943         if (item.ammo_cells)
 944         if (player.ammo_cells < g_pickup_cells_max)
 945                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 946         if (need_plasma)
 947         if (item.ammo_plasma)
 948         if (player.ammo_plasma < g_pickup_plasma_max)
 949                 c = c + max(0, 1 - player.ammo_plasma / g_pickup_plasma_max);
 950         if (need_fuel)
 951         if (item.ammo_fuel)
 952         if (player.ammo_fuel < g_pickup_fuel_max)
 953                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 954         if (item.armorvalue)
 955         if (player.armorvalue < item.max_armorvalue)
 956                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 957         if (item.health)
 958         if (player.health < item.max_health)
 959                 c = c + max(0, 1 - player.health / item.max_health);
 960
 961         return item.bot_pickupbasevalue * c;
 962 }
 963
 964 void Item_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 965 {
 966         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 967                 RemoveItem();
 968 }
 969
 970 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 971 {
 972         startitem_failed = false;
 973
 974         if(self.model == "")
 975                 self.model = itemmodel;
 976
 977         if(self.model == "")
 978     {
 979         error(strcat("^1Tried to spawn ", itemname, " with no model!\n"));
 980         return;
 981     }
 982
 983         if(self.item_pickupsound == "")
 984                 self.item_pickupsound = pickupsound;
 985
 986         if(!self.respawntime) // both need to be set
 987         {
 988                 self.respawntime = defaultrespawntime;
 989                 self.respawntimejitter = defaultrespawntimejitter;
 990         }
 991
 992         self.items = itemid;
 993         self.weapon = weaponid;
 994
 995         if(!self.fade_end)
 996         {
 997                 self.fade_start = autocvar_g_items_mindist;
 998                 self.fade_end = autocvar_g_items_maxdist;
 999         }
1000
1001         if(weaponid)
1002                 self.weapons = WepSet_FromWeapon(weaponid);
1003
1004         self.flags = FL_ITEM | itemflags;
1005
1006         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
1007         {
1008                 startitem_failed = true;
1009                 remove(self);
1010                 return;
1011         }
1012
1013         // is it a dropped weapon?
1014         if (self.classname == "droppedweapon")
1015         {
1016                 self.reset = SUB_Remove;
1017                 // it's a dropped weapon
1018                 self.movetype = MOVETYPE_TOSS;
1019
1020                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1021                 self.think = RemoveItem;
1022                 self.nextthink = time + 20;
1023
1024                 self.takedamage = DAMAGE_YES;
1025                 self.event_damage = Item_Damage;
1026
1027                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
1028                 /*
1029                 if(self.items == 0)
1030                 if(!(self.weapons & ~WEPSET_SUPERWEAPONS)) // only superweapons
1031                 if(self.ammo_nails == 0)
1032                 if(self.ammo_cells == 0)
1033                 if(self.ammo_rockets == 0)
1034                 if(self.ammo_shells == 0)
1035                 if(self.ammo_fuel == 0)
1036                 if(self.health == 0)
1037                 if(self.armorvalue == 0)
1038                 */
1039                 {
1040                         // if item is worthless after a timer, have it expire then
1041                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
1042                 }
1043
1044                 // don't drop if in a NODROP zone (such as lava)
1045                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
1046                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1047                 {
1048                         startitem_failed = true;
1049                         remove(self);
1050                         return;
1051                 }
1052         }
1053         else
1054         {
1055                 if(!have_pickup_item())
1056                 {
1057                         startitem_failed = true;
1058                         remove (self);
1059                         return;
1060                 }
1061
1062                 if(self.angles != '0 0 0')
1063                         self.SendFlags |= ISF_ANGLES;
1064
1065                 self.reset = Item_Reset;
1066                 // it's a level item
1067                 if(self.spawnflags & 1)
1068                         self.noalign = 1;
1069                 if (self.noalign)
1070                         self.movetype = MOVETYPE_NONE;
1071                 else
1072                         self.movetype = MOVETYPE_TOSS;
1073                 // do item filtering according to game mode and other things
1074                 if (!self.noalign)
1075                 {
1076                         // first nudge it off the floor a little bit to avoid math errors
1077                         setorigin(self, self.origin + '0 0 1');
1078                         // set item size before we spawn a spawnfunc_waypoint
1079                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1080                                 setsize (self, '-16 -16 0', '16 16 48');
1081                         else
1082                                 setsize (self, '-16 -16 0', '16 16 32');
1083                         self.SendFlags |= ISF_SIZE;
1084                         // note droptofloor returns false if stuck/or would fall too far
1085                         droptofloor();
1086                         waypoint_spawnforitem(self);
1087                 }
1088
1089                 /*
1090                  * can't do it that way, as it would break maps
1091                  * TODO make a target_give like entity another way, that perhaps has
1092                  * the weapon name in a key
1093                 if(self.targetname)
1094                 {
1095                         // target_give not yet supported; maybe later
1096                         print("removed targeted ", self.classname, "\n");
1097                         startitem_failed = true;
1098                         remove (self);
1099                         return;
1100                 }
1101                 */
1102
1103                 if(autocvar_spawn_debug >= 2)
1104                 {
1105                         entity otheritem;
1106                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
1107                         {
1108                             // why not flags & fl_item?
1109                                 if(otheritem.is_item)
1110                                 {
1111                                         LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(self.origin));
1112                                         LOG_TRACE(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1113                                         error("Mapper sucks.");
1114                                 }
1115                         }
1116                         self.is_item = true;
1117                 }
1118
1119                 weaponsInMap |= WepSet_FromWeapon(weaponid);
1120
1121                 precache_model (self.model);
1122                 precache_sound (self.item_pickupsound);
1123
1124                 precache_sound ("misc/itemrespawncountdown.wav");
1125                 if(itemid == ITEM_Strength.m_itemid)
1126                         precache_sound ("misc/strength_respawn.wav");
1127                 else if(itemid == ITEM_Shield.m_itemid)
1128                         precache_sound ("misc/shield_respawn.wav");
1129                 else
1130                         precache_sound ("misc/itemrespawn.wav");
1131
1132                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
1133                         self.target = "###item###"; // for finding the nearest item using find()
1134
1135                 Item_ItemsTime_SetTime(self, 0);
1136         }
1137
1138         self.bot_pickup = true;
1139         self.bot_pickupevalfunc = pickupevalfunc;
1140         self.bot_pickupbasevalue = pickupbasevalue;
1141         self.mdl = self.model;
1142         self.netname = itemname;
1143         self.touch = Item_Touch;
1144         setmodel(self, "null"); // precision set below
1145         //self.effects |= EF_LOWPRECISION;
1146
1147         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1148         {
1149                 self.pos1 = '-16 -16 0';
1150                 self.pos2 = '16 16 48';
1151         }
1152         else
1153         {
1154                 self.pos1 = '-16 -16 0';
1155                 self.pos2 = '16 16 32';
1156         }
1157         setsize (self, self.pos1, self.pos2);
1158
1159         self.SendFlags |= ISF_SIZE;
1160
1161         if(itemflags & FL_POWERUP)
1162                 self.ItemStatus |= ITS_ANIMATE1;
1163
1164         if(self.armorvalue || self.health)
1165                 self.ItemStatus |= ITS_ANIMATE2;
1166
1167         if(itemflags & FL_WEAPON)
1168         {
1169                 if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1170                         self.colormap = 1024; // color shirt=0 pants=0 grey
1171                 else
1172                         self.gravity = 1;
1173
1174                 self.ItemStatus |= ITS_ANIMATE1;
1175                 self.ItemStatus |= ISF_COLORMAP;
1176         }
1177
1178         self.state = 0;
1179         if(self.team) // broken, no idea why.
1180         {
1181                 if(!self.cnt)
1182                         self.cnt = 1; // item probability weight
1183
1184                 self.effects |= EF_NODRAW; // marker for item team search
1185                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
1186         }
1187         else
1188                 Item_Reset();
1189
1190         Net_LinkEntity(self, !((itemflags & FL_POWERUP) || self.health || self.armorvalue), 0, ItemSend);
1191
1192         // call this hook after everything else has been done
1193         if(MUTATOR_CALLHOOK(Item_Spawn, self))
1194         {
1195                 startitem_failed = true;
1196                 remove(self);
1197                 return;
1198         }
1199 }
1200
1201 string Item_Model(string item_mdl)
1202 {
1203         string output = strcat("models/items/", item_mdl);
1204         MUTATOR_CALLHOOK(ItemModel, item_mdl, output);
1205         return strzone(item_model_output);
1206 }
1207
1208 void StartItemA (entity a)
1209 {
1210     self.itemdef = a;
1211     StartItem(Item_Model(a.m_model), a.m_sound, a.m_respawntime(), a.m_respawntimejitter(), a.m_name, a.m_itemid, 0, a.m_itemflags, a.m_pickupevalfunc, a.m_botvalue);
1212 }
1213
1214 void spawnfunc_item_rockets (void) {
1215         if(!self.ammo_rockets)
1216                 self.ammo_rockets = g_pickup_rockets;
1217         if(!self.pickup_anyway)
1218                 self.pickup_anyway = g_pickup_ammo_anyway;
1219     StartItemA (ITEM_Rockets);
1220 }
1221
1222 void spawnfunc_item_bullets (void) {
1223         if(!weaponswapping)
1224         if(autocvar_sv_q3acompat_machineshotgunswap)
1225         if(self.classname != "droppedweapon")
1226         {
1227                 weaponswapping = true;
1228                 spawnfunc_item_shells();
1229                 weaponswapping = false;
1230                 return;
1231         }
1232
1233         if(!self.ammo_nails)
1234                 self.ammo_nails = g_pickup_nails;
1235         if(!self.pickup_anyway)
1236                 self.pickup_anyway = g_pickup_ammo_anyway;
1237     StartItemA (ITEM_Bullets);
1238 }
1239
1240 void spawnfunc_item_cells (void) {
1241         if(!self.ammo_cells)
1242                 self.ammo_cells = g_pickup_cells;
1243         if(!self.pickup_anyway)
1244                 self.pickup_anyway = g_pickup_ammo_anyway;
1245         StartItemA (ITEM_Cells);
1246 }
1247
1248 void spawnfunc_item_plasma()
1249 {
1250         if(!self.ammo_plasma)
1251                 self.ammo_plasma = g_pickup_plasma;
1252         if(!self.pickup_anyway)
1253                 self.pickup_anyway = g_pickup_ammo_anyway;
1254         StartItemA (ITEM_Plasma);
1255 }
1256
1257 void spawnfunc_item_shells (void) {
1258         if(!weaponswapping)
1259         if(autocvar_sv_q3acompat_machineshotgunswap)
1260         if(self.classname != "droppedweapon")
1261         {
1262                 weaponswapping = true;
1263                 spawnfunc_item_bullets();
1264                 weaponswapping = false;
1265                 return;
1266         }
1267
1268         if(!self.ammo_shells)
1269                 self.ammo_shells = g_pickup_shells;
1270         if(!self.pickup_anyway)
1271                 self.pickup_anyway = g_pickup_ammo_anyway;
1272         StartItemA (ITEM_Shells);
1273 }
1274
1275 void spawnfunc_item_armor_small (void) {
1276         if(!self.armorvalue)
1277                 self.armorvalue = g_pickup_armorsmall;
1278         if(!self.max_armorvalue)
1279                 self.max_armorvalue = g_pickup_armorsmall_max;
1280         if(!self.pickup_anyway)
1281                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1282         StartItemA (ITEM_ArmorSmall);
1283 }
1284
1285 void spawnfunc_item_armor_medium (void) {
1286         if(!self.armorvalue)
1287                 self.armorvalue = g_pickup_armormedium;
1288         if(!self.max_armorvalue)
1289                 self.max_armorvalue = g_pickup_armormedium_max;
1290         if(!self.pickup_anyway)
1291                 self.pickup_anyway = g_pickup_armormedium_anyway;
1292         StartItemA (ITEM_ArmorMedium);
1293 }
1294
1295 void spawnfunc_item_armor_big (void) {
1296         if(!self.armorvalue)
1297                 self.armorvalue = g_pickup_armorbig;
1298         if(!self.max_armorvalue)
1299                 self.max_armorvalue = g_pickup_armorbig_max;
1300         if(!self.pickup_anyway)
1301                 self.pickup_anyway = g_pickup_armorbig_anyway;
1302         StartItemA (ITEM_ArmorLarge);
1303 }
1304
1305 void spawnfunc_item_armor_large (void) {
1306         if(!self.armorvalue)
1307                 self.armorvalue = g_pickup_armorlarge;
1308         if(!self.max_armorvalue)
1309                 self.max_armorvalue = g_pickup_armorlarge_max;
1310         if(!self.pickup_anyway)
1311                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1312         StartItemA (ITEM_ArmorMega);
1313 }
1314
1315 void spawnfunc_item_health_small (void) {
1316         if(!self.max_health)
1317                 self.max_health = g_pickup_healthsmall_max;
1318         if(!self.health)
1319                 self.health = g_pickup_healthsmall;
1320         if(!self.pickup_anyway)
1321                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1322         StartItemA (ITEM_HealthSmall);
1323 }
1324
1325 void spawnfunc_item_health_medium (void) {
1326         if(!self.max_health)
1327                 self.max_health = g_pickup_healthmedium_max;
1328         if(!self.health)
1329                 self.health = g_pickup_healthmedium;
1330         if(!self.pickup_anyway)
1331                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1332     StartItemA (ITEM_HealthMedium);
1333 }
1334
1335 void spawnfunc_item_health_large (void) {
1336         if(!self.max_health)
1337                 self.max_health = g_pickup_healthlarge_max;
1338         if(!self.health)
1339                 self.health = g_pickup_healthlarge;
1340         if(!self.pickup_anyway)
1341                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1342         StartItemA (ITEM_HealthLarge);
1343 }
1344
1345 void spawnfunc_item_health_mega (void) {
1346     if(!self.max_health)
1347         self.max_health = g_pickup_healthmega_max;
1348     if(!self.health)
1349         self.health = g_pickup_healthmega;
1350     if(!self.pickup_anyway)
1351         self.pickup_anyway = g_pickup_healthmega_anyway;
1352     StartItemA (ITEM_HealthMega);
1353 }
1354
1355 // support old misnamed entities
1356 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1357 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1358 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1359 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1360 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1361
1362 void spawnfunc_item_strength (void) {
1363                 precache_sound("weapons/strength_fire.wav");
1364                 if(!self.strength_finished)
1365                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1366                 StartItemA (ITEM_Strength);
1367 }
1368
1369 void spawnfunc_item_invincible (void) {
1370                 if(!self.invincible_finished)
1371                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1372                 StartItemA (ITEM_Shield);
1373 }
1374
1375 // compatibility:
1376 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1377
1378 void target_items_use (void)
1379 {
1380         if(activator.classname == "droppedweapon")
1381         {
1382                 EXACTTRIGGER_TOUCH;
1383                 remove(activator);
1384                 return;
1385         }
1386
1387         if (!IS_PLAYER(activator))
1388                 return;
1389         if(activator.deadflag != DEAD_NO)
1390                 return;
1391         EXACTTRIGGER_TOUCH;
1392
1393         entity e;
1394         for(e = world; (e = find(e, classname, "droppedweapon")); )
1395                 if(e.enemy == activator)
1396                         remove(e);
1397
1398         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1399                 centerprint(activator, self.message);
1400 }
1401
1402 void spawnfunc_target_items (void)
1403 {
1404         float n, i, j;
1405         entity e;
1406         string s;
1407
1408         self.use = target_items_use;
1409         if(!self.strength_finished)
1410                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1411         if(!self.invincible_finished)
1412                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1413         if(!self.superweapons_finished)
1414                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1415
1416         precache_sound("misc/itempickup.wav");
1417         precache_sound("misc/megahealth.wav");
1418         precache_sound("misc/armor25.wav");
1419         precache_sound("misc/powerup.wav");
1420         precache_sound("misc/poweroff.wav");
1421         precache_sound(W_Sound("weaponpickup"));
1422
1423         n = tokenize_console(self.netname);
1424         if(argv(0) == "give")
1425         {
1426                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1427         }
1428         else
1429         {
1430                 for(i = 0; i < n; ++i)
1431                 {
1432                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1433                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1434                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1435                         else if(argv(i) == "strength")               self.items |= ITEM_Strength.m_itemid;
1436                         else if(argv(i) == "invincible")             self.items |= ITEM_Shield.m_itemid;
1437                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1438                         else if(argv(i) == "jetpack")                self.items |= ITEM_Jetpack.m_itemid;
1439                         else if(argv(i) == "fuel_regen")             self.items |= ITEM_JetpackRegen.m_itemid;
1440                         else
1441                         {
1442                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1443                                 {
1444                                         e = get_weaponinfo(j);
1445                                         s = W_UndeprecateName(argv(i));
1446                                         if(s == e.netname)
1447                                         {
1448                                                 self.weapons |= WepSet_FromWeapon(j);
1449                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1450                                                         WEP_ACTION(e.weapon, WR_INIT);
1451                                                 break;
1452                                         }
1453                                 }
1454                                 if(j > WEP_LAST)
1455                                         LOG_INFO("target_items: invalid item ", argv(i), "\n");
1456                         }
1457                 }
1458
1459                 string itemprefix, valueprefix;
1460                 if(self.spawnflags == 0)
1461                 {
1462                         itemprefix = "";
1463                         valueprefix = "";
1464                 }
1465                 else if(self.spawnflags == 1)
1466                 {
1467                         itemprefix = "max ";
1468                         valueprefix = "max ";
1469                 }
1470                 else if(self.spawnflags == 2)
1471                 {
1472                         itemprefix = "min ";
1473                         valueprefix = "min ";
1474                 }
1475                 else if(self.spawnflags == 4)
1476                 {
1477                         itemprefix = "minus ";
1478                         valueprefix = "max ";
1479                 }
1480                 else
1481                 {
1482                         error("invalid spawnflags");
1483                         itemprefix = valueprefix = string_null;
1484                 }
1485
1486                 self.netname = "";
1487                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1488                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1489                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & ITEM_Strength.m_itemid), "strength");
1490                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & ITEM_Shield.m_itemid), "invincible");
1491                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1492                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & ITEM_Jetpack.m_itemid), "jetpack");
1493                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1494                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1495                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1496                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1497                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1498                 if(self.ammo_plasma != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_plasma), "plasma");
1499                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1500                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1501                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1502                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1503                 {
1504                         e = get_weaponinfo(j);
1505                         if(e.weapon)
1506                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & WepSet_FromWeapon(j)), e.netname);
1507                 }
1508         }
1509         self.netname = strzone(self.netname);
1510         //print(self.netname, "\n");
1511
1512         n = tokenize_console(self.netname);
1513         for(i = 0; i < n; ++i)
1514         {
1515                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1516                 {
1517                         e = get_weaponinfo(j);
1518                         if(argv(i) == e.netname)
1519                         {
1520                                 WEP_ACTION(e.weapon, WR_INIT);
1521                                 break;
1522                         }
1523                 }
1524         }
1525 }
1526
1527 void spawnfunc_item_fuel(void)
1528 {
1529         if(!self.ammo_fuel)
1530                 self.ammo_fuel = g_pickup_fuel;
1531         if(!self.pickup_anyway)
1532                 self.pickup_anyway = g_pickup_ammo_anyway;
1533         StartItemA (ITEM_JetpackFuel);
1534 }
1535
1536 void spawnfunc_item_fuel_regen(void)
1537 {
1538         if(start_items & ITEM_JetpackRegen.m_itemid)
1539         {
1540                 spawnfunc_item_fuel();
1541                 return;
1542         }
1543         StartItemA (ITEM_JetpackRegen);
1544 }
1545
1546 void spawnfunc_item_jetpack(void)
1547 {
1548         if(!self.ammo_fuel)
1549                 self.ammo_fuel = g_pickup_fuel_jetpack;
1550         if(start_items & ITEM_Jetpack.m_itemid)
1551         {
1552                 spawnfunc_item_fuel();
1553                 return;
1554         }
1555         StartItemA (ITEM_Jetpack);
1556 }
1557
1558 float GiveWeapon(entity e, float wpn, float op, float val)
1559 {
1560         WepSet v0, v1;
1561         v0 = (e.weapons & WepSet_FromWeapon(wpn));
1562         switch(op)
1563         {
1564                 case OP_SET:
1565                         if(val > 0)
1566                                 e.weapons |= WepSet_FromWeapon(wpn);
1567                         else
1568                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1569                         break;
1570                 case OP_MIN:
1571                 case OP_PLUS:
1572                         if(val > 0)
1573                                 e.weapons |= WepSet_FromWeapon(wpn);
1574                         break;
1575                 case OP_MAX:
1576                         if(val <= 0)
1577                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1578                         break;
1579                 case OP_MINUS:
1580                         if(val > 0)
1581                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1582                         break;
1583         }
1584         v1 = (e.weapons & WepSet_FromWeapon(wpn));
1585         return (v0 != v1);
1586 }
1587
1588 float GiveBit(entity e, .float fld, float bit, float op, float val)
1589 {
1590         float v0, v1;
1591         v0 = (e.(fld) & bit);
1592         switch(op)
1593         {
1594                 case OP_SET:
1595                         if(val > 0)
1596                                 e.(fld) |= bit;
1597                         else
1598                                 e.(fld) &= ~bit;
1599                         break;
1600                 case OP_MIN:
1601                 case OP_PLUS:
1602                         if(val > 0)
1603                                 e.(fld) |= bit;
1604                         break;
1605                 case OP_MAX:
1606                         if(val <= 0)
1607                                 e.(fld) &= ~bit;
1608                         break;
1609                 case OP_MINUS:
1610                         if(val > 0)
1611                                 e.(fld) &= ~bit;
1612                         break;
1613         }
1614         v1 = (e.(fld) & bit);
1615         return (v0 != v1);
1616 }
1617
1618 float GiveValue(entity e, .float fld, float op, float val)
1619 {
1620         float v0, v1;
1621         v0 = e.(fld);
1622         switch(op)
1623         {
1624                 case OP_SET:
1625                         e.(fld) = val;
1626                         break;
1627                 case OP_MIN:
1628                         e.(fld) = max(e.(fld), val); // min 100 cells = at least 100 cells
1629                         break;
1630                 case OP_MAX:
1631                         e.(fld) = min(e.(fld), val);
1632                         break;
1633                 case OP_PLUS:
1634                         e.(fld) += val;
1635                         break;
1636                 case OP_MINUS:
1637                         e.(fld) -= val;
1638                         break;
1639         }
1640         v1 = e.(fld);
1641         return (v0 != v1);
1642 }
1643
1644 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1645 {
1646         if(v1 == v0)
1647                 return;
1648         if(v1 <= v0 - t)
1649         {
1650                 if(snd_decr != "")
1651                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1652         }
1653         else if(v0 >= v0 + t)
1654         {
1655                 if(snd_incr != "")
1656                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1657         }
1658 }
1659
1660 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1661 {
1662         if(v0 < v1)
1663                 e.(rotfield) = max(e.(rotfield), time + rottime);
1664         else if(v0 > v1)
1665                 e.(regenfield) = max(e.(regenfield), time + regentime);
1666 }
1667 float GiveItems(entity e, float beginarg, float endarg)
1668 {
1669         float got, i, j, val, op;
1670         float _switchweapon;
1671         entity wi;
1672         string cmd;
1673
1674         val = 999;
1675         op = OP_SET;
1676
1677         got = 0;
1678
1679         _switchweapon = false;
1680         if (e.autoswitch)
1681                 if (e.switchweapon == w_getbestweapon(e))
1682                         _switchweapon = true;
1683
1684         e.strength_finished = max(0, e.strength_finished - time);
1685         e.invincible_finished = max(0, e.invincible_finished - time);
1686         e.superweapons_finished = max(0, e.superweapons_finished - time);
1687
1688         PREGIVE(e, items);
1689         PREGIVE_WEAPONS(e);
1690         PREGIVE(e, strength_finished);
1691         PREGIVE(e, invincible_finished);
1692         PREGIVE(e, superweapons_finished);
1693         PREGIVE(e, ammo_nails);
1694         PREGIVE(e, ammo_cells);
1695         PREGIVE(e, ammo_plasma);
1696         PREGIVE(e, ammo_shells);
1697         PREGIVE(e, ammo_rockets);
1698         PREGIVE(e, ammo_fuel);
1699         PREGIVE(e, armorvalue);
1700         PREGIVE(e, health);
1701
1702         for(i = beginarg; i < endarg; ++i)
1703         {
1704                 cmd = argv(i);
1705
1706                 if(cmd == "0" || stof(cmd))
1707                 {
1708                         val = stof(cmd);
1709                         continue;
1710                 }
1711                 switch(cmd)
1712                 {
1713                         case "no":
1714                                 op = OP_MAX;
1715                                 val = 0;
1716                                 continue;
1717                         case "max":
1718                                 op = OP_MAX;
1719                                 continue;
1720                         case "min":
1721                                 op = OP_MIN;
1722                                 continue;
1723                         case "plus":
1724                                 op = OP_PLUS;
1725                                 continue;
1726                         case "minus":
1727                                 op = OP_MINUS;
1728                                 continue;
1729                         case "ALL":
1730                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1731                                 got += GiveValue(e, strength_finished, op, val);
1732                                 got += GiveValue(e, invincible_finished, op, val);
1733                                 got += GiveValue(e, superweapons_finished, op, val);
1734                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1735                         case "all":
1736                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1737                                 got += GiveValue(e, health, op, val);
1738                                 got += GiveValue(e, armorvalue, op, val);
1739                         case "allweapons":
1740                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1741                                 {
1742                                         wi = get_weaponinfo(j);
1743                                         if(wi.weapon)
1744                                                 if (!(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED))
1745                                                         got += GiveWeapon(e, j, op, val);
1746                                 }
1747                         case "allammo":
1748                                 got += GiveValue(e, ammo_cells, op, val);
1749                                 got += GiveValue(e, ammo_plasma, op, val);
1750                                 got += GiveValue(e, ammo_shells, op, val);
1751                                 got += GiveValue(e, ammo_nails, op, val);
1752                                 got += GiveValue(e, ammo_rockets, op, val);
1753                                 got += GiveValue(e, ammo_fuel, op, val);
1754                                 break;
1755                         case "unlimited_ammo":
1756                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1757                                 break;
1758                         case "unlimited_weapon_ammo":
1759                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1760                                 break;
1761                         case "unlimited_superweapons":
1762                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1763                                 break;
1764                         case "jetpack":
1765                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1766                                 break;
1767                         case "fuel_regen":
1768                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1769                                 break;
1770                         case "strength":
1771                                 got += GiveValue(e, strength_finished, op, val);
1772                                 break;
1773                         case "invincible":
1774                                 got += GiveValue(e, invincible_finished, op, val);
1775                                 break;
1776                         case "superweapons":
1777                                 got += GiveValue(e, superweapons_finished, op, val);
1778                                 break;
1779                         case "cells":
1780                                 got += GiveValue(e, ammo_cells, op, val);
1781                                 break;
1782                         case "plasma":
1783                                 got += GiveValue(e, ammo_plasma, op, val);
1784                                 break;
1785                         case "shells":
1786                                 got += GiveValue(e, ammo_shells, op, val);
1787                                 break;
1788                         case "nails":
1789                         case "bullets":
1790                                 got += GiveValue(e, ammo_nails, op, val);
1791                                 break;
1792                         case "rockets":
1793                                 got += GiveValue(e, ammo_rockets, op, val);
1794                                 break;
1795                         case "health":
1796                                 got += GiveValue(e, health, op, val);
1797                                 break;
1798                         case "armor":
1799                                 got += GiveValue(e, armorvalue, op, val);
1800                                 break;
1801                         case "fuel":
1802                                 got += GiveValue(e, ammo_fuel, op, val);
1803                                 break;
1804                         default:
1805                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1806                                 {
1807                                         wi = get_weaponinfo(j);
1808                                         if(cmd == wi.netname)
1809                                         {
1810                                                 got += GiveWeapon(e, j, op, val);
1811                                                 break;
1812                                         }
1813                                 }
1814                                 if(j > WEP_LAST)
1815                                         LOG_INFO("give: invalid item ", cmd, "\n");
1816                                 break;
1817                 }
1818                 val = 999;
1819                 op = OP_SET;
1820         }
1821
1822         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, "misc/itempickup.wav", string_null);
1823         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1824         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1825         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, "misc/itempickup.wav", string_null);
1826         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1827         {
1828                 wi = get_weaponinfo(j);
1829                 if(wi.weapon)
1830                 {
1831                         POSTGIVE_WEAPON(e, j, W_Sound("weaponpickup"), string_null);
1832                         if (!(save_weapons & WepSet_FromWeapon(j)))
1833                                 if(e.weapons & WepSet_FromWeapon(j))
1834                                         WEP_ACTION(wi.weapon, WR_INIT);
1835                 }
1836         }
1837         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1838         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1839         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1840         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1841         POSTGIVE_VALUE(e, ammo_plasma, 0, "misc/itempickup.wav", string_null);
1842         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1843         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1844         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1845         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1846         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1847
1848         if(e.superweapons_finished <= 0)
1849                 if(self.weapons & WEPSET_SUPERWEAPONS)
1850                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1851
1852         if(e.strength_finished <= 0)
1853                 e.strength_finished = 0;
1854         else
1855                 e.strength_finished += time;
1856         if(e.invincible_finished <= 0)
1857                 e.invincible_finished = 0;
1858         else
1859                 e.invincible_finished += time;
1860         if(e.superweapons_finished <= 0)
1861                 e.superweapons_finished = 0;
1862         else
1863                 e.superweapons_finished += time;
1864
1865         if (!(e.weapons & WepSet_FromWeapon(e.switchweapon)))
1866                 _switchweapon = true;
1867         if(_switchweapon)
1868                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1869
1870         return got;
1871 }
1872 #endif